configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 dnl
   7 AC_INIT(GStreamer, 1.0.0,
   8     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   9     gstreamer)
  10 AG_GST_INIT
  11
  12 dnl initialize automake (we require GNU make)
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/gst.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl GStreamer versioning, this is mostly informational
  39 dnl GST_VERSION_MAJOR=$PACKAGE_VERSION_MAJOR
  40 dnl GST_VERSION_MINOR=$PACKAGE_VERSION_MINOR
  41 dnl GST_VERSION_MICRO=$PACKAGE_VERSION_MICRO
  42 dnl GST_VERSION_NANO=$PACKAGE_VERSION_NANO
  43 dnl Change this to the above for non-pre
  44 GST_VERSION_MAJOR=1
  45 GST_VERSION_MINOR=0
  46 GST_VERSION_MICRO=0
  47 GST_VERSION_NANO=0
  48 AC_SUBST(GST_VERSION_MAJOR)
  49 AC_SUBST(GST_VERSION_MINOR)
  50 AC_SUBST(GST_VERSION_MICRO)
  51 AC_SUBST(GST_VERSION_NANO)
  52
  53 dnl our libraries and install dirs use GST_API_VERSION in the filename
  54 dnl to allow side-by-side installation of different API versions
  55 GST_API_VERSION=1.0
  56 AC_SUBST(GST_API_VERSION)
  57 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  58   [GStreamer API Version])
  59
  60 dnl CURRENT, REVISION, AGE
  61 dnl - library source changed -> increment REVISION
  62 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  63 dnl - interfaces added -> increment AGE
  64 dnl - interfaces removed -> AGE = 0
  65 dnl sets GST_LT_LDFLAGS
  66 AS_LIBTOOL(GST, 0, 0, 0)
  67
  68 dnl *** autotools stuff ****
  69
  70 dnl allow for different autotools
  71 AS_AUTOTOOLS_ALTERNATE
  72
  73 dnl Add parameters for aclocal (keep in sync with Makefile.am)
  74 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  75
  76 dnl set up gettext
  77 dnl the version check needs to stay here because autopoint greps for it
  78 AM_GNU_GETTEXT_VERSION([0.17])
  79 AM_GNU_GETTEXT([external])
  80 AG_GST_GETTEXT([gstreamer-$GST_API_VERSION])
  81
  82 dnl *** check for arguments to configure ***
  83
  84 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  85
  86 dnl subsystems - can influence other decisions so needs to be high up
  87 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  88 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  89 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  90 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  91 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  92 if test "x$GST_DISABLE_PARSE" = xyes; then
  93   AC_DEFINE(GST_DISABLE_PARSE, 1,
  94     [Define if pipeline parsing code is disabled])
  95 fi
  96 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  97 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  98 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  99   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
 100     [Define if option parsing is disabled])
 101 fi
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
 103 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 104 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 105 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 106 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 107 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 108 dnl define a substitution to use in docs/gst/gstreamer.types
 109 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 110 then
 111   GST_REGISTRY_DOC_TYPES="%"
 112 else
 113   GST_REGISTRY_DOC_TYPES=
 114 fi
 115 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 116 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 117 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 118
 119 AG_GST_ARG_DEBUG
 120 AG_GST_ARG_PROFILING
 121 AG_GST_ARG_VALGRIND
 122 AG_GST_ARG_GCOV
 123
 124 AG_GST_ARG_EXAMPLES
 125
 126 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 127 AG_GST_ARG_WITH_PACKAGE_NAME
 128 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 129
 130 AG_GST_PKG_CONFIG_PATH
 131
 132 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 133   ["${srcdir}/gstreamer.doap"],
 134   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 135
 136 dnl building of tests
 137 AC_ARG_ENABLE(tests,
 138   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 139   [
 140     case "${enableval}" in
 141       yes) BUILD_TESTS=yes ;;
 142       no)  BUILD_TESTS=no ;;
 143       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 144     esac
 145   ],
 146 [BUILD_TESTS=yes]) dnl Default value
 147 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 148
 149 dnl tests known to fail
 150 AC_ARG_ENABLE(failing-tests,
 151   AC_HELP_STRING([--disable-failing-tests],
 152     [disable building tests known to fail]),
 153   [
 154     case "${enableval}" in
 155       yes) BUILD_FAILING_TESTS=yes ;;
 156       no)  BUILD_FAILING_TESTS=no ;;
 157       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 158     esac
 159   ],
 160   [BUILD_FAILING_TESTS=no]) dnl Default value
 161 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 162 if test x$BUILD_FAILING_TESTS = xyes; then
 163   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 164 else
 165   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 166 fi
 167
 168 dnl building of benchmarks
 169 AC_ARG_ENABLE(benchmarks,
 170   AC_HELP_STRING([--disable-benchmarks], [disable building benchmarks apps]),
 171   [
 172     case "${enableval}" in
 173       yes) BUILD_BENCHMARKS=yes ;;
 174       no)  BUILD_BENCHMARKS=no ;;
 175       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-benchmarks) ;;
 176     esac
 177   ],
 178 [BUILD_BENCHMARKS=yes]) dnl Default value
 179 AM_CONDITIONAL(BUILD_BENCHMARKS, test "x$BUILD_BENCHMARKS" = "xyes")
 180
 181 dnl building of tools
 182 AC_ARG_ENABLE(tools,
 183   AC_HELP_STRING([--disable-tools], [disable building tools]),
 184   [
 185     case "${enableval}" in
 186       yes) BUILD_TOOLS=yes ;;
 187       no)  BUILD_TOOLS=no ;;
 188       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tools) ;;
 189     esac
 190   ],
 191 [BUILD_TOOLS=yes]) dnl Default value
 192 AM_CONDITIONAL(BUILD_TOOLS, test "x$BUILD_TOOLS" = "xyes")
 193
 194 dnl poison destroyed objects
 195 AC_ARG_ENABLE(poisoning,
 196   AC_HELP_STRING([--enable-poisoning],
 197     [enable poisoning of deallocated objects]),
 198   [
 199     case "${enableval}" in
 200       yes) USE_POISONING=yes ;;
 201       no)  USE_POISONING=no ;;
 202       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 203     esac
 204   ],
 205   [USE_POISONING=no]) dnl Default value
 206 if test "x$USE_POISONING" = xyes; then
 207   AC_DEFINE(USE_POISONING, 1,
 208     [Define if we should poison deallocated memory])
 209 fi
 210
 211 dnl *** checks for platform ***
 212
 213 dnl * hardware/architecture *
 214
 215 dnl common/m4/gst-arch.m4
 216 dnl check CPU type
 217 AG_GST_ARCH
 218 dnl substitution for win32/common/config.h
 219 HOST_CPU=$host_cpu
 220 AC_SUBST(HOST_CPU)
 221
 222 dnl common/m4/gst-arch.m4
 223 dnl check for unaligned access
 224 AG_GST_UNALIGNED_ACCESS
 225 dnl create a configure variable for gst/gstconfig.h
 226 if test x${as_cv_unaligned_access} = xyes ; then
 227   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 228 else
 229   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 230 fi
 231 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 232
 233 dnl check for platform specific settings
 234 AG_GST_PLATFORM
 235
 236 dnl * software *
 237
 238 dnl check for large file support
 239 dnl affected plugins must include config.h
 240 AC_SYS_LARGEFILE
 241
 242 dnl *** checks for programs ***
 243
 244 dnl find a compiler
 245 AC_PROG_CC
 246 AC_PROG_CC_STDC
 247
 248 dnl check if the compiler supports '-c' and '-o' options
 249 AM_PROG_CC_C_O
 250
 251 dnl find an assembler
 252 AM_PROG_AS
 253
 254 dnl determine if c++ is available on this system
 255 AC_PROG_CXX
 256 dnl CXX may be set to some default even if no c++ compiler is available
 257 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 258 AC_LANG_PUSH([C++])
 259 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 260 AC_LANG_POP([C++])
 261 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 262 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 263
 264 dnl Perl is used in building documentation and in the version checks
 265 AC_PATH_PROG(PERL_PATH, perl, no)
 266 if test x$PERL_PATH = xno; then
 267   AC_MSG_ERROR(Could not find perl)
 268 fi
 269
 270 dnl we require flex and bison for building the parser
 271 if test "x$GST_DISABLE_PARSE" != xyes; then
 272   AG_GST_BISON_CHECK
 273   AG_GST_FLEX_CHECK
 274 fi
 275
 276 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 277 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 278
 279 dnl check for gobject-introspection
 280 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 281
 282 dnl check for documentation tools
 283 AG_GST_DOCBOOK_CHECK
 284 GTK_DOC_CHECK([1.12])
 285 AS_PATH_PYTHON([2.1])
 286 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 287
 288 dnl *** checks for libraries ***
 289
 290 dnl check for libm, for sin()
 291 LT_LIB_M
 292 AC_SUBST(LIBM)
 293
 294 dnl *** checks for header files ***
 295
 296 dnl check if we have ANSI C header files
 297 AC_HEADER_STDC
 298
 299 dnl Check for ucontext.h
 300 AC_CHECK_HEADERS([ucontext.h], [], [], [AC_INCLUDES_DEFAULT])
 301
 302 dnl Check for sys/socket.h
 303 AC_CHECK_HEADERS([sys/socket.h], [HAVE_SYS_SOCKET_H=yes], [HAVE_SYS_SOCKET_H=no], [AC_INCLUDES_DEFAULT])
 304 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 305
 306 dnl check for sys/times.h for tests/examples/adapter/
 307 AC_CHECK_HEADERS([sys/times.h], [HAVE_SYS_TIMES_H=yes], [HAVE_SYS_TIME_H=no], [AC_INCLUDES_DEFAULT])
 308 AC_CHECK_HEADERS([unistd.h], [HAVE_UNISTD_H=yes], [HAVE_UNISTD_H=no], [AC_INCLUDES_DEFAULT])
 309 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 310
 311 dnl Check for process.h for getpid() on win32
 312 AC_CHECK_HEADERS([process.h], [], [], [AC_INCLUDES_DEFAULT])
 313
 314 dnl Check for sys/utsname.h for uname
 315 AC_CHECK_HEADERS([sys/utsname.h], [], [], [AC_INCLUDES_DEFAULT])
 316
 317 dnl Check for stdio_ext.f for __fbufsize
 318 AC_CHECK_HEADERS([stdio_ext.h], [], [], [AC_INCLUDES_DEFAULT])
 319
 320 dnl check for pthreads
 321 AC_CHECK_HEADERS([pthread.h], [HAVE_PTHREAD_H=yes], [HAVE_PTHREAD_H=no], [AC_INCLUDES_DEFAULT])
 322 AM_CONDITIONAL(HAVE_PTHREAD_H, test "x$HAVE_PTHREAD_H" = "xyes")
 323
 324 dnl check for sys/prctl for setting thread name on Linux
 325 AC_CHECK_HEADERS([sys/prctl.h], [], [], [AC_INCLUDES_DEFAULT])
 326
 327 dnl Check for valgrind.h
 328 dnl separate from HAVE_VALGRIND because you can have the program, but not
 329 dnl the dev package
 330 AC_CHECK_HEADERS([valgrind/valgrind.h], [], [], [AC_INCLUDES_DEFAULT])
 331
 332 dnl used in gst/gstpoll.c
 333 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 334 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 335 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 336   WIN32_LIBS="-lws2_32"
 337   AC_SUBST(WIN32_LIBS)
 338 fi
 339
 340 dnl check for GMP/GSL, used by the gst_util_uint64_scale unit test only
 341 if test "x$BUILD_TESTS" = "xyes"; then
 342   AG_GST_CHECK_LIBHEADER(GMP, gmp,
 343                          __gmpz_init_set_d, ,
 344                          gmp.h,
 345                          GMP_LIBS="-lgmp"
 346                          AC_SUBST(GMP_LIBS)
 347                          AC_DEFINE(HAVE_GMP, [1],[Have GMP library]))
 348   AG_GST_CHECK_LIBHEADER(GSL, gsl,
 349                          gsl_rng_uniform_int, -lgslcblas,
 350                          gsl/gsl_rng.h,
 351                          GSL_LIBS="-lgsl -lgslcblas"
 352                          AC_SUBST(GSL_LIBS)
 353                          AC_DEFINE(HAVE_GSL, [1],[Have GSL library]))
 354 fi
 355
 356 dnl *** checks for types/defines ***
 357
 358 dnl *** checks for structures ***
 359
 360 dnl *** checks for compiler characteristics ***
 361
 362 dnl check if the compiler supports __uint128_t (gcc)
 363 dnl Actually check for 128-bit division, since that's what we use
 364 dnl uint128_t for.
 365 AC_CACHE_CHECK(for __uint128_t, gst_cv_uint128_t,
 366     AC_TRY_LINK([ ], [
 367       static __uint128_t v1 = 100;
 368       static __uint128_t v2 = 10;
 369       static __uint128_t u;
 370       u = v1 / v2;
 371     ], [
 372       gst_cv_uint128_t=yes
 373     ], [
 374       gst_cv_uint128_t=no
 375     ])
 376 )
 377 if test x$gst_cv_uint128_t = xyes; then
 378   AC_DEFINE(HAVE_UINT128_T, 1, [Have __uint128_t type])
 379 fi
 380
 381 dnl *** checking for tm_gmtoff ***
 382 AC_MSG_CHECKING([for tm_gmtoff])
 383 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 384         #include <time.h>
 385         int main(void) {
 386           struct tm t;
 387           t.tm_gmtoff = 0;
 388           exit(0);
 389         }]])],
 390   [have_tm_gmtoff=yes
 391    AC_DEFINE(HAVE_TM_GMTOFF,1,[Have tm_gmtoff field in struct tm])],
 392   [have_tm_gmtoff=no],
 393   [have_tm_gmtoff="no (cross compiling)"])
 394 AC_MSG_RESULT($have_tm_gmtoff)
 395
 396
 397 dnl *** checks for library functions ***
 398
 399 AC_CHECK_FUNCS([gmtime_r])
 400 AC_CHECK_FUNCS([localtime_r])
 401 AC_CHECK_FUNCS([sigaction])
 402
 403 dnl check for fseeko()
 404 AC_FUNC_FSEEKO
 405 dnl check for ftello()
 406 AC_CHECK_FUNCS([ftello])
 407
 408 AC_CHECK_FUNCS([fgetpos])
 409 AC_CHECK_FUNCS([fsetpos])
 410
 411 dnl check for poll(), ppoll() and pselect()
 412 AC_CHECK_HEADERS([sys/poll.h], [], [], [AC_INCLUDES_DEFAULT])
 413 AC_CHECK_HEADERS([poll.h], [], [], [AC_INCLUDES_DEFAULT])
 414 AC_CHECK_FUNCS([poll])
 415 AC_CHECK_FUNCS([ppoll])
 416 AC_CHECK_FUNCS([pselect])
 417
 418 dnl ****************************************
 419 dnl *** GLib POLL* compatibility defines ***
 420 dnl ****************************************
 421
 422 AC_MSG_CHECKING([for broken poll])
 423 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 424         #include <stdlib.h>
 425         #include <fcntl.h>
 426         #ifdef HAVE_SYS_POLL_H
 427         #include <sys/poll.h>
 428         #endif
 429         #ifdef HAVE_POLL_H
 430         #include <poll.h>
 431         #endif
 432         int main(void) {
 433           struct pollfd fds[1];
 434           int fd;
 435           fd = open("/dev/null", 1);
 436           fds[0].fd = fd;
 437           fds[0].events = POLLIN;
 438           fds[0].revents = 0;
 439           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 440                 exit(1);  /* Does not work for devices -- fail */
 441           }
 442           exit(0);
 443         }]])],
 444   [broken_poll=no],
 445   [broken_poll=yes
 446    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 447   [broken_poll="no (cross compiling)"])
 448 AC_MSG_RESULT($broken_poll)
 449
 450 dnl check for mmap()
 451 AC_FUNC_MMAP
 452 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 453
 454 dnl check for posix_memalign(), getpagesize()
 455 AC_CHECK_FUNCS([posix_memalign])
 456 AC_CHECK_FUNCS([getpagesize])
 457
 458 dnl Check for POSIX timers
 459 AC_CHECK_FUNCS(clock_gettime, [], [
 460   AC_CHECK_LIB(rt, clock_gettime, [
 461     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 462     LIBS="$LIBS -lrt"
 463   ])
 464 ])
 465
 466 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 467     AC_TRY_COMPILE([
 468 #include <time.h>
 469 #ifdef HAVE_UNISTD_H
 470 #include <unistd.h>
 471 #endif
 472     ], [
 473 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 474 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 475 #endif
 476     ], [
 477       gst_cv_posix_timers=yes
 478     ], [
 479       gst_cv_posix_timers=no
 480     ])
 481 )
 482
 483 if test "$gst_cv_posix_timers" = "yes"; then
 484   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 485   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 486 else
 487   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 488 fi
 489 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 490 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 491
 492 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 493     AC_TRY_COMPILE([
 494 #include <time.h>
 495 #ifdef HAVE_UNISTD_H
 496 #include <unistd.h>
 497 #endif
 498     ], [
 499 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 500 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 501 #endif
 502     ], [
 503       gst_cv_monotonic_clock=yes
 504     ], [
 505       gst_cv_monotonic_clock=no
 506     ])
 507 )
 508
 509 if test "$gst_cv_monotonic_clock" = "yes"; then
 510   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 511   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 512 else
 513   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 514 fi
 515 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 516 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 517
 518 dnl Check for a way to display the function name in debug output
 519 AG_GST_CHECK_FUNCTION
 520
 521 dnl test for register_printf_specifier or register_printf_function
 522 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 523     [HAVE_PRINTF_EXTENSION=yes])
 524
 525 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 526   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 527   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 528   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 529   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 530       [Defined if we have printf specifier extensions available])
 531 else
 532     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 533     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 534     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 535 fi
 536 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 537 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 538 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 539
 540 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 541 save_cflags="$CFLAGS"
 542 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 543 AC_CHECK_LIB(dl, dladdr,
 544    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 545    LIBS="$LIBS -ldl")
 546 CFLAGS="$save_cflags"
 547
 548 dnl *** checks for dependency libraries ***
 549
 550 dnl GLib
 551 GLIB_REQ=2.32.0
 552 AG_GST_GLIB_CHECK([$GLIB_REQ])
 553
 554 dnl Check for documentation xrefs
 555 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 556 AC_SUBST(GLIB_PREFIX)
 557
 558 dnl building of unit test libraries
 559 AC_ARG_ENABLE(check,
 560   AC_HELP_STRING([--disable-check], [disable building unit test libraries]),
 561   [
 562     case "${enableval}" in
 563       yes) BUILD_CHECK=yes ;;
 564       no)  BUILD_CHECK=no ;;
 565       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-check) ;;
 566     esac
 567   ], [
 568     dnl Default value
 569     case $host_os in
 570       mingw* | msvc* | mks*) BUILD_CHECK=no ;;
 571       *) BUILD_CHECK=yes ;;
 572     esac
 573 ])
 574 dnl bit of a misnomer, but keep the conditional named like this so we don't
 575 dnl have to change too much elsewhere
 576 AM_CONDITIONAL(HAVE_CHECK, test "x$BUILD_CHECK" = "xyes")
 577
 578 dnl configure the desired memory alignment
 579 AC_ARG_WITH([memory-alignment],
 580   AS_HELP_STRING([--with-memory-alignment],[8,N,malloc,pagesize (default is 32)]),
 581   [
 582     if test "x$withval" = "xyes"
 583     then
 584       AC_DEFINE(MEMORY_ALIGNMENT, 32, [Memory alignment to use])
 585     else
 586       case "${withval}" in
 587         malloc) AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default]) ;;
 588         pagesize)  AC_DEFINE(MEMORY_ALIGNMENT_PAGESIZE, 1, [Memory alignment by pagesize]) ;;
 589         *)   AC_DEFINE_UNQUOTED(MEMORY_ALIGNMENT, ${withval}, [Memory alignment to use]) ;;
 590       esac
 591     fi
 592   ], [
 593     AC_DEFINE(MEMORY_ALIGNMENT_MALLOC, 1, [Memory alignment by malloc default])
 594   ]
 595 )
 596
 597 dnl Check for -Bsymbolic-functions linker flag used to avoid
 598 dnl intra-library PLT jumps, if available.
 599 AC_ARG_ENABLE(Bsymbolic,
 600               [AC_HELP_STRING([--disable-Bsymbolic],
 601                               [avoid linking with -Bsymbolic])],,
 602               [SAVED_LDFLAGS="${LDFLAGS}"
 603                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 604                LDFLAGS=-Wl,-Bsymbolic-functions
 605                AC_TRY_LINK([], [int main (void) { return 0; }],
 606                            AC_MSG_RESULT(yes)
 607                            enable_Bsymbolic=yes,
 608                            AC_MSG_RESULT(no)
 609                            enable_Bsymbolic=no)
 610                LDFLAGS="${SAVED_LDFLAGS}"])
 611
 612
 613 dnl *** set variables based on configure arguments
 614
 615 dnl set license and copyright notice
 616 GST_LICENSE="LGPL"
 617 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 618 AC_SUBST(GST_LICENSE)
 619
 620 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 621 AS_AC_EXPAND(LIBDIR, $libdir)
 622 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 623 AS_AC_EXPAND(DATADIR, $datadir)
 624 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 625
 626 dnl set location of plugin directory
 627 AG_GST_SET_PLUGINDIR
 628
 629 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 630 AC_SUBST(GST_PKG_DEPS)
 631
 632 dnl make sure it doesn't complain about unused variables if debugging is disabled
 633 NO_WARNINGS=""
 634 if test "x${GST_DISABLE_GST_DEBUG}" = "xyes"; then
 635   NO_WARNINGS="-Wno-unused"
 636 fi
 637
 638 dnl define an ERROR_CFLAGS Makefile variable
 639 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return -Wno-multichar -Wnested-externs $NO_WARNINGS])
 640
 641 dnl define correct level for debugging messages
 642 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 643
 644 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 645
 646 dnl Overview:
 647 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 648 dnl GST_ALL_*:          vars shared by all built objects
 649 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 650 dnl GST_OBJ_*:          additional vars to link to the core library
 651 dnl                     include GST_ALL_*
 652 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 653 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 654
 655 dnl GST_OPTION_CFLAGS
 656 if test "x$USE_DEBUG" = xyes; then
 657    PROFILE_CFLAGS="-g"
 658 fi
 659 AC_SUBST(PROFILE_CFLAGS)
 660
 661 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 662 # functionality from the API that gstreamer uses
 663 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 664 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 665   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 666   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 667 else
 668   DEPRECATED_CFLAGS=""
 669 fi
 670 AC_SUBST(DEPRECATED_CFLAGS)
 671
 672 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 673 dnl make DEPRECATED_CFLAGS=''
 674 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 675 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 676 GST_OPTION_CFLAGS="$GST_OPTION_CFLAGS"
 677 GST_OPTION_CXXFLAGS="$GST_OPTION_CXXFLAGS"
 678 AC_SUBST(GST_OPTION_CFLAGS)
 679 AC_SUBST(GST_OPTION_CXXFLAGS)
 680
 681 dnl GST_ALL_*
 682 dnl vars common to for all internal objects (core libs, elements, applications)
 683 dnl CFLAGS:
 684 dnl - src and build dirs need to be added because every piece that gets built
 685 dnl   will need the GStreamer source and generated headers
 686 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 687 dnl       from LibXML except for in the core library
 688 GST_ALL_CXXFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CXXFLAGS) \$(ERROR_CXXFLAGS)"
 689 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir)/libs -I\$(top_builddir) $GLIB_CFLAGS \$(GLIB_EXTRA_CFLAGS) $XML_CFLAGS \$(GST_OPTION_CFLAGS) \$(ERROR_CFLAGS)"
 690
 691 dnl FIXME: check if LTLIBINTL is needed everywhere
 692 dnl I presume it is given that it contains the symbols that _() stuff maps to
 693 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 694
 695 dnl LDFLAGS really should only contain flags, not libs - they get added before
 696 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 697 GST_ALL_LDFLAGS="-no-undefined"
 698 if test "x${enable_Bsymbolic}" = "xyes"; then
 699   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 700 fi
 701
 702 AC_SUBST(GST_ALL_CFLAGS)
 703 AC_SUBST(GST_ALL_CXXFLAGS)
 704 AC_SUBST(GST_ALL_LIBS)
 705 AC_SUBST(GST_ALL_LDFLAGS)
 706
 707 dnl GST_LIB_LDFLAGS
 708 dnl linker flags shared by all libraries
 709 dnl LDFLAGS modifier defining exported symbols from built libraries
 710 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]?\(gst_\|Gst\|GST_\).*"
 711 AC_SUBST(GST_LIB_LDFLAGS)
 712
 713 dnl GST_OBJ_*
 714 dnl default vars for all internal objects built on libgstreamer
 715 dnl includes GST_ALL_*
 716 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 717 GST_OBJ_CXXFLAGS="\$(GST_ALL_CXXFLAGS)"
 718 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_API_VERSION.la \$(GST_ALL_LIBS)"
 719 AC_SUBST(GST_OBJ_CFLAGS)
 720 AC_SUBST(GST_OBJ_CXXFLAGS)
 721 AC_SUBST(GST_OBJ_LIBS)
 722
 723 dnl GST_PLUGIN_LDFLAGS
 724 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 725 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 726 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 727
 728 dnl plugin scanner locations
 729 AS_AC_EXPAND(GST_PLUGIN_SCANNER_INSTALLED,${libexecdir}/gstreamer-$GST_API_VERSION/gst-plugin-scanner)
 730 AC_DEFINE_UNQUOTED(GST_PLUGIN_SCANNER_INSTALLED,
 731     "$GST_PLUGIN_SCANNER_INSTALLED", [location of the installed gst-plugin-scanner])
 732 AC_SUBST(GST_PLUGIN_SCANNER_INSTALLED)
 733
 734 dnl things for our internal libcheck (must be called even if building
 735 dnl libcheck is disabled because it defines conditionals)
 736 AG_GST_CHECK_CHECKS()
 737
 738 AC_CONFIG_FILES(
 739 Makefile
 740 gst/Makefile
 741 gst/gstconfig.h
 742 gst/gstversion.h
 743 gst/parse/Makefile
 744 libs/Makefile
 745 libs/gst/Makefile
 746 libs/gst/base/Makefile
 747 libs/gst/check/Makefile
 748 libs/gst/check/libcheck/Makefile
 749 libs/gst/check/libcheck/check.h
 750 libs/gst/controller/Makefile
 751 libs/gst/helpers/Makefile
 752 libs/gst/net/Makefile
 753 plugins/Makefile
 754 plugins/elements/Makefile
 755 po/Makefile.in
 756 tests/Makefile
 757 tests/benchmarks/Makefile
 758 tests/check/Makefile
 759 tests/misc/Makefile
 760 tests/examples/Makefile
 761 tests/examples/adapter/Makefile
 762 tests/examples/controller/Makefile
 763 tests/examples/stepping/Makefile
 764 tests/examples/helloworld/Makefile
 765 tests/examples/launch/Makefile
 766 tests/examples/manual/Makefile
 767 tests/examples/memory/Makefile
 768 tests/examples/metadata/Makefile
 769 tests/examples/queue/Makefile
 770 tests/examples/streams/Makefile
 771 tests/examples/typefind/Makefile
 772 tools/Makefile
 773 common/Makefile
 774 common/m4/Makefile
 775 docs/Makefile
 776 docs/design/Makefile
 777 docs/faq/Makefile
 778 docs/gst/Makefile
 779 docs/gst/gstreamer.types
 780 docs/libs/Makefile
 781 docs/plugins/Makefile
 782 docs/manual/Makefile
 783 docs/pwg/Makefile
 784 docs/slides/Makefile
 785 docs/xsl/Makefile
 786 docs/version.entities
 787 m4/Makefile
 788 pkgconfig/Makefile
 789 stamp.h
 790 pkgconfig/gstreamer.pc
 791 pkgconfig/gstreamer-uninstalled.pc
 792 pkgconfig/gstreamer-base.pc
 793 pkgconfig/gstreamer-base-uninstalled.pc
 794 pkgconfig/gstreamer-check.pc
 795 pkgconfig/gstreamer-check-uninstalled.pc
 796 pkgconfig/gstreamer-controller.pc
 797 pkgconfig/gstreamer-controller-uninstalled.pc
 798 pkgconfig/gstreamer-net.pc
 799 pkgconfig/gstreamer-net-uninstalled.pc
 800 gstreamer.spec
 801 )
 802
 803 dnl Create the config.h file for Visual Studio builds
 804 dnl Beware of spaces and /'s in some of the shell variable contents.
 805 sed \
 806     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 807     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 808     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 809     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 810     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 811     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 812     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 813     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 814     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 815     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 816     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 817     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 818     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 819     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 820     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 821     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 822     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 823     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 824     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 825     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 826     -e 's/.* MEMORY_ALIGNMENT_MALLOC/#define MEMORY_ALIGNMENT_MALLOC 1/' \
 827     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 828     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 829     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 830     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 831     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 832     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 833     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 834     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 835     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-1.0"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-1.0"\n#endif/' \
 836     -e 's/.* GST_PLUGIN_SCANNER_INSTALLED$/#define GST_PLUGIN_SCANNER_INSTALLED LIBDIR "\\\\gst-plugin-scanner"/' \
 837     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 838     config.h.in >win32/common/config.h-new
 839
 840 AC_OUTPUT
 841
 842 dnl negate for output
 843 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 844 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 845 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 846 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 847 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 848 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 849 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 850
 851 echo "
 852
 853 Configuration
 854         Version                    : ${VERSION}
 855         Source code location       : ${srcdir}
 856         Prefix                     : ${prefix}
 857         Compiler                   : ${CC}
 858         Package name               : ${GST_PACKAGE_NAME}
 859         Package origin             : ${GST_PACKAGE_ORIGIN}
 860
 861         Documentation (manuals)    : ${enable_docbook}
 862         Documentation (API)        : ${enable_gtk_doc}
 863
 864         Debug Logging              : ${enable_gst_debug}
 865         Command-line parser        : ${enable_parse}
 866         Option parsing in gst_init : ${enable_option_parsing}
 867         Tracing subsystem          : ${enable_trace}
 868         Allocation tracing         : ${enable_alloc_trace}
 869         Plugin registry            : ${enable_registry}
 870         Plugin support             : ${enable_plugin}
 871         Unit testing support       : ${BUILD_CHECK}
 872
 873         Debug                      : ${USE_DEBUG}
 874         Profiling                  : ${USE_PROFILING}
 875
 876         Building benchmarks        : ${BUILD_BENCHMARKS}
 877         Building examples          : ${BUILD_EXAMPLES}
 878         Building test apps         : ${BUILD_TESTS}
 879         Building tests that fail   : ${BUILD_FAILING_TESTS}
 880         Building tools             : ${BUILD_TOOLS}
 881 "