configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [2])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 dnl m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-pre-svn-07])
  12 m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])],
  15 [m4_define([v_ver], [v_maj.v_min.v_mic])])
  16 m4_define([lt_rev], m4_eval(v_maj + v_min))
  17 m4_define([lt_cur], v_mic)
  18 m4_define([lt_age], v_min)
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  21
  22 AC_INIT([emotion], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  23 AC_PREREQ([2.60])
  24 AC_CONFIG_SRCDIR([configure.ac])
  25 AC_CONFIG_MACRO_DIR([m4])
  26 AC_CANONICAL_BUILD
  27 AC_CANONICAL_HOST
  28 AC_ISC_POSIX
  29
  30 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  31 AM_CONFIG_HEADER([config.h])
  32 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  33
  34 AC_LIBTOOL_WIN32_DLL
  35 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  36 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  37 AC_PROG_LIBTOOL
  38
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  41 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  42 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  43 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  44 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  45 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  46 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  47 version_info="lt_rev:lt_cur:lt_age"
  48 release_info="v_rel"
  49 AC_SUBST(version_info)
  50 AC_SUBST(release_info)
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  53 VMAJ=v_maj
  54 AC_SUBST(VMAJ)
  55
  56 want_generic="yes"
  57 case "$host_os" in
  58    mingw* | cegcc*)
  59       want_xine="no"
  60       want_gstreamer="yes"
  61       want_generic_vlc="no"
  62       ;;
  63    *)
  64       want_xine="yes"
  65       want_gstreamer="yes"
  66       want_generic_vlc="yes"
  67       ;;
  68 esac
  69
  70 requirement_emotion=""
  71
  72 ### Additional options to configure
  73
  74 EFL_ENABLE_BIN([emotion-test])
  75
  76 # edje_cc
  77
  78 AC_ARG_WITH([edje-cc],
  79    [AC_HELP_STRING([--with-edje-cc=PATH], [specify a specific path to edje_cc])],
  80    [
  81     v=$withval;
  82     edje_cc=$v
  83     echo "  Enlightenment edje_cc explicitly set to "$edje_cc;
  84    ],
  85    [edje_cc=$(pkg-config --variable=prefix edje)/bin/edje_cc])
  86 AC_SUBST(edje_cc)
  87
  88
  89 ### Checks for programs
  90 AC_PROG_CC
  91
  92 # pkg-config
  93 PKG_PROG_PKG_CONFIG
  94
  95 # Check whether pkg-config supports Requires.private
  96 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
  97    pkgconfig_requires_private="Requires.private"
  98 else
  99    pkgconfig_requires_private="Requires"
 100 fi
 101 AC_SUBST(pkgconfig_requires_private)
 102
 103 # doxygen program for documentation building
 104
 105 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 106
 107
 108 ### Checks for libraries
 109
 110 PKG_CHECK_MODULES(EMOTION, [eina >= 1.0.0 evas >= 1.0.0 ecore >= 1.0.0])
 111 requirement_emotion="ecore >= 1.0.0 evas >= 1.0.0 eina >= 1.0.0"
 112
 113 if test "x${have_emotion_test}" = "xyes" ; then
 114    PKG_CHECK_MODULES(EMOTION_BIN, [eina >= 1.0.0 evas >= 1.0.0 ecore >= 1.0.0 ecore-evas >= 1.0.0 edje >= 1.0.0])
 115 fi
 116
 117 PKG_CHECK_MODULES(ECORE_X, [ecore-x >= 1.0.0], [have_ecore_x="yes"], [have_ecore_x="no"])
 118
 119 PKG_CHECK_MODULES(ECORE_FB, [ecore-fb >= 1.0.0], [have_ecore_fb="yes"], [have_ecore_fb="no"])
 120
 121 if test "x${have_ecore_x}" = "xyes" ; then
 122    AC_DEFINE(EMOTION_HAVE_ECORE_X, 1, [Define to 1 if Ecore_X is enabled])
 123 fi
 124
 125 if test "x${have_ecore_fb}" = "xyes" ; then
 126    AC_DEFINE(EMOTION_HAVE_ECORE_FB, 1, [Define to 1 if Ecore_Fb is enabled])
 127 fi
 128
 129 PKG_CHECK_EXISTS([evas-software-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_SOFWARE_X11, 1, [Evas Software Xlib Engine Support])])
 130
 131 PKG_CHECK_EXISTS([evas-xrender-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_XRENDER_X11, 1, [Evas Software Xlib Engine Support])])
 132
 133 PKG_CHECK_EXISTS([evas-opengl-x11 >= 1.0.0], [AC_DEFINE(HAVE_EVAS_OPENGL_X11, 1, [Evas OpenGL Xlib Engine Support])])
 134
 135 PKG_CHECK_EXISTS([evas-fb >= 1.0.0], [AC_DEFINE(HAVE_EVAS_FB, 1, [Evas Framebuffer Engine Support])])
 136
 137 EFL_EDJE_EXTERNAL([have_edje_external="yes"], [have_edje_external="no"])
 138
 139 PKG_CHECK_MODULES(EEZE, [eeze >= 1.0.99], [have_eeze="yes"], [have_eeze="no"])
 140
 141 if test "x${have_eeze}" = "xyes"; then
 142    AC_DEFINE(EMOTION_HAVE_EEZE, 1, [Define to 1 if Eeze is available])
 143    requirement_emotion="${requirement_emotion} eeze >= 1.0.99"
 144 fi
 145
 146 ### Checks for header files
 147 AC_HEADER_STDC
 148
 149 ### Checks for types
 150
 151
 152 ### Checks for structures
 153
 154
 155 ### Checks for compiler characteristics
 156 AC_C_CONST
 157 AC_C_BIGENDIAN
 158 AM_PROG_CC_STDC
 159 AC_C___ATTRIBUTE__
 160
 161 EFL_EMOTION_BUILD=""
 162 case "$host_os" in
 163    mingw32ce* | cegcc*)
 164       EMOTION_CPPFLAGS="-D_WIN32_WCE=0x0420"
 165       EFL_EMOTION_BUILD="-DEFL_EMOTION_BUILD"
 166       ;;
 167    mingw*)
 168       EMOTION_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 169       EFL_EMOTION_BUILD="-DEFL_EMOTION_BUILD"
 170       ;;
 171 esac
 172 AC_SUBST(EFL_EMOTION_BUILD)
 173 AC_SUBST(EMOTION_CPPFLAGS)
 174
 175
 176 ### Checks for linker characteristics
 177
 178 # use --enable-auto-import on Windows
 179
 180 lt_enable_auto_import=""
 181 case "$host_os" in
 182    mingw* | cegcc*)
 183       lt_enable_auto_import="-Wl,--enable-auto-import"
 184       ;;
 185 esac
 186 AC_SUBST(lt_enable_auto_import)
 187
 188 ### Check for extended attribute
 189
 190 AC_COMPILE_IFELSE(
 191    [AC_LANG_PROGRAM(
 192        [[
 193 #include <stdlib.h>
 194 #include <sys/types.h>
 195 #include <sys/xattr.h>
 196        ]],
 197        [[
 198 size_t tmp = listxattr("/", NULL, 0);
 199 tmp = getxattr("/", "user.ethumb.md5", NULL, 0);
 200 setxattr("/", "user.ethumb.md5", NULL, 0, 0);
 201        ]])],
 202     [
 203       AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if you have 'listxattr', 'setxattr' and 'getxattr'])
 204       have_xattr="yes"
 205     ],
 206     [have_xattr="no"])
 207
 208 AC_MSG_CHECKING([for Xattr])
 209 AC_MSG_RESULT([${have_xattr}])
 210
 211 ### Check for video4linux
 212
 213 AC_COMPILE_IFELSE(
 214    [AC_LANG_PROGRAM(
 215        [[
 216 #include <stdio.h>
 217 #include <linux/videodev2.h>
 218        ]],
 219        [[
 220 fprintf(stdout, "%i\n", V4L2_CAP_VIDEO_CAPTURE);
 221        ]])],
 222    [
 223      AC_DEFINE(HAVE_V4L2, 1, [Define to 1 if you have Video4Linux 2 available])
 224      have_v4l2="yes"
 225    ],
 226    [have_v4l2="no"])
 227 AC_MSG_CHECKING([for V4L2])
 228 AC_MSG_RESULT([${have_v4l2}])
 229
 230 ### Modules
 231
 232 EMOTION_CHECK_MODULE([Xine], [${want_xine}])
 233 EMOTION_CHECK_MODULE([Gstreamer], [${want_gstreamer}])
 234 EMOTION_CHECK_MODULE([Generic], [${want_generic}])
 235
 236 EMOTION_CHECK_GENERIC_PLAYER([VLC], [${want_generic_vlc}])
 237
 238 if test "x${enable_xine}" = "xno" && test "x${enable_gstreamer}" = "xno" && test "x${enable_generic}" = "xno" ; then
 239    AC_MSG_ERROR([Xine, Gstreamer or Generic backends must be selected to build Emotion])
 240 fi
 241
 242
 243 PKG_CHECK_MODULES([EIO],
 244         [eio],
 245         [
 246          have_eio="yes"
 247          AC_DEFINE(HAVE_EIO, 1, [Use EIO for asynchronous file access])
 248          requirement_emotion="eio ${requirement_emotion}"
 249         ],
 250         [have_eio="no"])
 251
 252 AM_CONDITIONAL([HAVE_EIO], [test "x${have_eio}" = "xyes"])
 253
 254 ### install and build examples
 255
 256 EFL_CHECK_BUILD_EXAMPLES([enable_build_examples="yes"], [enable_build_examples="no"])
 257 EFL_CHECK_INSTALL_EXAMPLES([enable_install_examples="yes"], [enable_install_examples="no"])
 258
 259 AC_SUBST(requirement_emotion)
 260
 261 AC_OUTPUT([
 262 Makefile
 263 emotion.pc
 264 emotion.spec
 265 src/Makefile
 266 src/lib/Makefile
 267 src/modules/Makefile
 268 src/modules/xine/Makefile
 269 src/modules/gstreamer/Makefile
 270 src/modules/generic/Makefile
 271 src/edje_external/Makefile
 272 src/generic_players/Makefile
 273 src/generic_players/vlc/Makefile
 274 src/bin/Makefile
 275 src/examples/Makefile
 276 doc/Makefile
 277 doc/Doxyfile
 278 data/Makefile
 279 ])
 280
 281
 282 #####################################################################
 283 ## Info
 284
 285 echo
 286 echo
 287 echo
 288 echo "------------------------------------------------------------------------"
 289 echo "$PACKAGE $VERSION"
 290 echo "------------------------------------------------------------------------"
 291 echo
 292 echo "Configuration Options Summary:"
 293 echo
 294 echo "  Modules:"
 295 echo "    Xine...............: ${enable_xine}"
 296 echo "    Gstreamer..........: ${enable_gstreamer}"
 297 echo "    Generic............: ${enable_generic}"
 298
 299 if test "x${enable_generic}" = "xyes" || test "x${enable_generic}" = "xstatic"; then
 300 echo
 301 echo "  Generic Players:"
 302 echo "    VLC................: ${enable_generic_vlc}"
 303 fi
 304
 305 echo
 306 echo "  Build emotion_test...: $have_emotion_test"
 307 echo "  edje_cc..............: ${edje_cc}"
 308 echo
 309 echo "  Edje EXTERNAL support: ${have_edje_external}"
 310 echo
 311 echo "  Xattr................: ${have_xattr}"
 312 echo "  Eio..................: ${have_eio}"
 313 echo "  V4L2.................: ${have_v4l2}"
 314 echo
 315 echo "Documentation..........: ${build_doc}"
 316 echo "Examples.............: ${enable_build_examples}"
 317 echo "Examples installed...: ${enable_install_examples}"
 318 echo
 319 echo "Compilation............: make (or gmake)"
 320 echo "  CPPFLAGS.............: $CPPFLAGS"
 321 echo "  CFLAGS...............: $CFLAGS"
 322 echo "  LDFLAGS..............: $LDFLAGS"
 323 echo
 324 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 325 echo "  prefix...............: $prefix"
 326 echo
 327 if test "x${have_static_module}" = "xyes" ; then
 328 echo -e "\0033\01331;31mWarning\0033\01331;0m: You are trying to link statically one or more modules to Emotion."
 329 echo "         You must know what you are doing, or else you will have a lot of problems."
 330 echo "         And asparagus will disappear from the earth."
 331 echo "         Think about that."
 332 echo
 333 fi