configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl ------------------------------------------------
   4 dnl Initialization and Versioning
   5 dnl ------------------------------------------------
   6
   7
   8 AC_INIT([libvorbis],[1.2.2],[vorbis-dev@xiph.org])
   9
  10 AC_CONFIG_SRCDIR([lib/mdct.c])
  11
  12 AC_CANONICAL_TARGET([])
  13
  14 AM_INIT_AUTOMAKE($PACKAGE_NAME,$PACKAGE_VERSION)
  15 AM_CONFIG_HEADER([config.h])
  16
  17 dnl Add parameters for aclocal
  18 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4")
  19
  20 dnl Library versioning
  21 dnl - library source changed -> increment REVISION
  22 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  23 dnl - interfaces added -> increment AGE
  24 dnl - interfaces removed -> AGE = 0
  25
  26 V_LIB_CURRENT=4
  27 V_LIB_REVISION=1
  28 V_LIB_AGE=4
  29 VF_LIB_CURRENT=6
  30 VF_LIB_REVISION=0
  31 VF_LIB_AGE=3
  32 VE_LIB_CURRENT=2
  33 VE_LIB_REVISION=4
  34 VE_LIB_AGE=0
  35 AC_SUBST(V_LIB_CURRENT)
  36 AC_SUBST(V_LIB_REVISION)
  37 AC_SUBST(V_LIB_AGE)
  38 AC_SUBST(VF_LIB_CURRENT)
  39 AC_SUBST(VF_LIB_REVISION)
  40 AC_SUBST(VF_LIB_AGE)
  41 AC_SUBST(VE_LIB_CURRENT)
  42 AC_SUBST(VE_LIB_REVISION)
  43 AC_SUBST(VE_LIB_AGE)
  44
  45 dnl --------------------------------------------------
  46 dnl Check for programs
  47 dnl --------------------------------------------------
  48
  49 dnl save $CFLAGS since AC_PROG_CC likes to insert "-g -O2"
  50 dnl if $CFLAGS is blank
  51 cflags_save="$CFLAGS"
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 CFLAGS="$cflags_save"
  55
  56 AC_C_INLINE
  57
  58 AC_LIBTOOL_WIN32_DLL
  59 AC_PROG_LIBTOOL
  60 AM_PROG_CC_C_O
  61
  62 dnl docbook xml transform and processing tools
  63 AC_ARG_ENABLE(docs,
  64         AC_HELP_STRING([--enable-docs], [build the documentation]))
  65
  66 dnl ideally we'd look for other tools and support them
  67 if test x$enable_docs = xyes; then
  68   AC_CHECK_PROGS([XSLTPROC], xsltproc, [/bin/false])
  69   AC_CHECK_PROGS([PDFXMLTEX], pdfxmltex, [/bin/false])
  70   if test "x$XSLTPROC" = "x/bin/false" || test "x$PDFXMLTEX" = "x/bin/false"; then
  71     enable_docs=no
  72     AC_MSG_WARN([Documentation will not be built!])
  73   fi
  74 fi
  75
  76 AM_CONDITIONAL(BUILD_DOCS, [test x$enable_docs = xyes])
  77
  78 dnl --------------------------------------------------
  79 dnl Set build flags based on environment
  80 dnl --------------------------------------------------
  81
  82 dnl Set some target options
  83
  84 cflags_save="$CFLAGS"
  85 if test -z "$GCC"; then
  86         case $host in
  87         *-*-irix*)
  88                 dnl If we're on IRIX, we wanna use cc even if gcc
  89                 dnl is there (unless the user has overriden us)...
  90                 if test -z "$CC"; then
  91                         CC=cc
  92                 fi
  93                 DEBUG="-g -signed"
  94                 CFLAGS="-O2 -w -signed"
  95                 PROFILE="-p -g3 -O2 -signed" ;;
  96         sparc-sun-solaris*)
  97                 DEBUG="-v -g"
  98                 CFLAGS="-xO4 -fast -w -fsimple -native -xcg92"
  99                 PROFILE="-v -xpg -g -xO4 -fast -native -fsimple -xcg92 -Dsuncc" ;;
 100         *)
 101                 DEBUG="-g"
 102                 CFLAGS="-O"
 103                 PROFILE="-g -p" ;;
 104         esac
 105 else
 106
 107         AC_MSG_CHECKING([GCC version])
 108         GCC_VERSION=`$CC -dumpversion`
 109         AC_MSG_RESULT([$GCC_VERSION])
 110         case $host in
 111         *86-*-linux*)
 112                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 113                 CFLAGS="-O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char"
 114 #               PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char -fno-inline -static"
 115                 PROFILE="-Wall -Wextra -pg -g -O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char -fno-inline"
 116
 117                 # glibc < 2.1.3 has a serious FP bug in the math inline header
 118                 # that will cripple Vorbis.  Look to see if the magic FP stack
 119                 # clobber is missing in the mathinline header, thus indicating
 120                 # the buggy version
 121
 122                 AC_EGREP_CPP(log10.*fldlg2.*fxch,[
 123                                 #define __LIBC_INTERNAL_MATH_INLINES 1
 124                                 #define __OPTIMIZE__
 125                                 #include <math.h>
 126                                 ],bad=maybe,bad=no)
 127                 if test ${bad} = "maybe" ;then
 128                       AC_EGREP_CPP(log10.*fldlg2.*fxch.*st\([[0123456789]]*\),
 129                                         [
 130                                         #define __LIBC_INTERNAL_MATH_INLINES 1
 131                                         #define __OPTIMIZE__
 132                                         #include <math.h>
 133                                         ],bad=no,bad=yes)
 134                 fi
 135                 if test ${bad} = "yes" ;then
 136  AC_MSG_WARN([                                                        ])
 137  AC_MSG_WARN([********************************************************])
 138  AC_MSG_WARN([* The glibc headers on this machine have a serious bug *])
 139  AC_MSG_WARN([* in /usr/include/bits/mathinline.h  This bug affects  *])
 140  AC_MSG_WARN([* all floating point code, not just Ogg, built on this *])
 141  AC_MSG_WARN([* machine.  Upgrading to glibc 2.1.3 is strongly urged *])
 142  AC_MSG_WARN([* to correct the problem.  Note that upgrading glibc   *])
 143  AC_MSG_WARN([* will not fix any previously built programs; this is  *])
 144  AC_MSG_WARN([* a compile-time time bug.                             *])
 145  AC_MSG_WARN([* To work around the problem for this build of Ogg,    *])
 146  AC_MSG_WARN([* autoconf is disabling all math inlining.  This will  *])
 147  AC_MSG_WARN([* hurt Ogg performace but is necessary for an Ogg that *])
 148  AC_MSG_WARN([* will actually work.  Once glibc is upgraded, rerun   *])
 149  AC_MSG_WARN([* configure and make to build with inlining.           *])
 150  AC_MSG_WARN([********************************************************])
 151  AC_MSG_WARN([                                                        ])
 152
 153                 CFLAGS=${OPT}" -D__NO_MATH_INLINES"
 154                 PROFILE=${PROFILE}" -D__NO_MATH_INLINES"
 155                 fi;;
 156         powerpc-*-linux*)
 157                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES"
 158                 CFLAGS="-O3 -Wall -Wextra -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT"
 159                 PROFILE="-pg -g -O3 -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT";;
 160         *-*-linux*)
 161                 DEBUG="-g -Wall -Wextra -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 162                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D_REENTRANT -fsigned-char"
 163                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 164         sparc-sun-*)
 165                 sparc_cpu=""
 166                 AC_MSG_CHECKING([if gcc supports -mv8])
 167                 old_cflags="$CFLAGS"
 168                 CFLAGS="$CFLAGS -mv8"
 169                 AC_TRY_COMPILE(, [return 0;], [
 170                         AC_MSG_RESULT([yes])
 171                         sparc_cpu="-mv8"
 172                 ])
 173                 CFLAGS="$old_cflags"
 174                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char $sparc_cpu"
 175                 CFLAGS="-O20 -Wall -Wextra -ffast-math -D__NO_MATH_INLINES -fsigned-char $sparc_cpu"
 176                 PROFILE="-pg -g -O20 -D__NO_MATH_INLINES -fsigned-char $sparc_cpu" ;;
 177         *-*-darwin*)
 178                 DEBUG="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O0 -fsigned-char"
 179                 CFLAGS="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O4 -ffast-math -fsigned-char"
 180                 PROFILE="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -pg -O4 -ffast-math -fsigned-char";;
 181         *-*-os2*)
 182                 # Use -W instead of -Wextra because gcc on OS/2 is an old version.
 183                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 184                 CFLAGS="-O20 -Wall -W -ffast-math -D_REENTRANT -fsigned-char"
 185                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 186         *)
 187                 DEBUG="-g -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 188                 CFLAGS="-O20 -Wall -Wextra -D__NO_MATH_INLINES -fsigned-char"
 189                 PROFILE="-O20 -g -pg -D__NO_MATH_INLINES -fsigned-char" ;;
 190         esac
 191
 192         AC_ADD_CFLAGS([-Wdeclaration-after-statement])
 193 fi
 194 CFLAGS="$CFLAGS $cflags_save"
 195
 196 dnl --------------------------------------------------
 197 dnl Check for headers
 198 dnl --------------------------------------------------
 199
 200 AC_CHECK_HEADER(memory.h,CFLAGS="$CFLAGS -DUSE_MEMORY_H",:)
 201
 202 dnl --------------------------------------------------
 203 dnl Check for typedefs, structures, etc
 204 dnl --------------------------------------------------
 205
 206 dnl none
 207
 208 dnl --------------------------------------------------
 209 dnl Check for libraries
 210 dnl --------------------------------------------------
 211
 212 AC_CHECK_LIB(m, cos, VORBIS_LIBS="-lm", VORBIS_LIBS="")
 213 AC_CHECK_LIB(pthread, pthread_create, pthread_lib="-lpthread", :)
 214
 215 PKG_PROG_PKG_CONFIG
 216
 217 HAVE_OGG=no
 218 if test "x$PKG_CONFIG" != "x"
 219 then
 220   PKG_CHECK_MODULES(OGG, ogg >= 1.0, HAVE_OGG=yes, HAVE_OGG=no)
 221 fi
 222 if test "x$HAVE_OGG" = "xno"
 223 then
 224   dnl fall back to the old school test
 225   XIPH_PATH_OGG(, AC_MSG_ERROR(must have Ogg installed!))
 226   libs_save=$LIBS
 227   LIBS="$OGG_LIBS $VORBIS_LIBS"
 228   AC_CHECK_FUNC(oggpack_writealign, , AC_MSG_ERROR(Ogg >= 1.0 required !))
 229   LIBS=$libs_save
 230 fi
 231
 232 dnl --------------------------------------------------
 233 dnl Check for library functions
 234 dnl --------------------------------------------------
 235
 236 AC_FUNC_ALLOCA
 237 AC_FUNC_MEMCMP
 238
 239 dnl --------------------------------------------------
 240 dnl Do substitutions
 241 dnl --------------------------------------------------
 242
 243 AC_SUBST(VORBIS_LIBS)
 244 AC_SUBST(DEBUG)
 245 AC_SUBST(PROFILE)
 246 AC_SUBST(pthread_lib)
 247
 248 dnl The following line causes the libtool distributed with the source
 249 dnl to be replaced if the build system has a more recent version.
 250 AC_SUBST(LIBTOOL_DEPS)
 251
 252 AC_OUTPUT([
 253 Makefile
 254 m4/Makefile
 255 lib/Makefile
 256 lib/modes/Makefile
 257 lib/books/Makefile
 258 lib/books/coupled/Makefile
 259 lib/books/uncoupled/Makefile
 260 lib/books/floor/Makefile
 261 doc/Makefile doc/vorbisfile/Makefile doc/vorbisenc/Makefile
 262 include/Makefile include/vorbis/Makefile
 263 examples/Makefile
 264 test/Makefile
 265 vq/Makefile
 266 libvorbis.spec
 267 vorbis.pc
 268 vorbisenc.pc
 269 vorbisfile.pc
 270 vorbis-uninstalled.pc
 271 vorbisenc-uninstalled.pc
 272 vorbisfile-uninstalled.pc
 273 ])