1 AC_INIT([libxml++], [2.34.2],
2 [https://bugzilla.gnome.org/enter_bug.cgi?product=libxml%2B%2B],
3 [libxml++], [http://libxmlplusplus.sourceforge.net/])
6 AC_CONFIG_SRCDIR([libxml++/libxml++.h])
7 AC_CONFIG_AUX_DIR([macros])
8 AC_CONFIG_MACRO_DIR([macros])
9 AC_CONFIG_HEADERS([config.h libxml++config.h])
11 AM_INIT_AUTOMAKE([1.9 -Wno-portability dist-bzip2 no-define nostdinc subdir-objects])
12 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
13 AM_MAINTAINER_MODE([disable])
14 AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
17 MM_INIT_MODULE([libxml++-2.6])
19 # Copy the mm-common .pl scripts into docs/,
20 # and use them from there,
21 # so we can dist them to avoid a tarball-build dependency.
22 MM_CONFIG_DOCTOOL_DIR([docs])
24 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
25 AC_SUBST([LIBXMLXX_SO_VERSION], [2:7:0])
29 LT_INIT([dlopen win32-dll disable-static])
31 AC_SUBST([LIBXMLXX_MODULES], ['libxml-2.0 >= 2.6.1 glibmm-2.4 >= 2.4.0'])
32 PKG_CHECK_MODULES([LIBXMLXX], [$LIBXMLXX_MODULES])
35 AC_CHECK_HEADERS([string list map], [], [AC_MSG_ERROR([required headers not found])])
37 AC_ARG_ENABLE([examples],
38 [AS_HELP_STRING([--enable-examples],
39 [build the examples])],
40 [enable_examples=$enableval],
41 [enable_examples=yes])
43 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = xyes])
45 # Offer the ability to omit some API from the library, to reduce the code size:
46 LIBXMLCPP_ARG_ENABLE_API_EXCEPTIONS
48 MM_ARG_ENABLE_DOCUMENTATION
49 MM_ARG_WITH_TAGFILE_DOC([glibmm-2.4.tag], [glibmm-2.4])
51 MM_ARG_ENABLE_WARNINGS([LIBXMLXX_WXXFLAGS],
53 [-pedantic -Wall -Wextra -Wno-long-long])
55 AC_PATH_PROG([XMLLINT], [xmllint], [xmllint])
56 AC_ARG_VAR([XMLLINT], [path to xmllint utility])
57 AC_PATH_PROGS([DB2LATEX], [db2latex docbook2latex], [db2latex])
58 AC_ARG_VAR([DB2LATEX], [path to db2latex utility])
61 AC_CONFIG_FILES([Makefile
62 docs/reference/Doxyfile
63 MSVC_Net2005/libxml++/libxml++.rc
64 MSVC_Net2008/libxml++/libxml++.rc
65 MSVC_Net2010/libxml++/libxml++.rc
68 AC_CONFIG_COMMANDS([MSVC_Net2005/libxml++/libxml++config.h],
69 [cp -f libxml++config.h MSVC_Net2005/libxml++/libxml++config.h])
70 AC_CONFIG_COMMANDS([MSVC_Net2008/libxml++/libxml++config.h],
71 [cp -f libxml++config.h MSVC_Net2008/libxml++/libxml++config.h])
72 AC_CONFIG_COMMANDS([MSVC_Net2010/libxml++/libxml++config.h],
73 [cp -f libxml++config.h MSVC_Net2010/libxml++/libxml++config.h])