configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [7])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153
 154     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 155     ;;
 156   *)
 157     glib_native_win32=no
 158     glib_pid_type=int
 159     ;;
 160 esac
 161 case $host in
 162   *-*-linux*)
 163     glib_os_linux=yes
 164     ;;
 165 esac
 166
 167 AC_MSG_RESULT([$glib_native_win32])
 168
 169 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 170
 171 glib_have_carbon=no
 172 AC_MSG_CHECKING([for Mac OS X Carbon support])
 173 AC_TRY_CPP([
 174 #include <Carbon/Carbon.h>
 175 #include <CoreServices/CoreServices.h>
 176 ], glib_have_carbon=yes)
 177
 178 AC_MSG_RESULT([$glib_have_carbon])
 179
 180 glib_have_cocoa=no
 181 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 182 AC_TRY_CPP([
 183 #include <Cocoa/Cocoa.h>
 184 #ifdef GNUSTEP_BASE_VERSION
 185 #error "Detected GNUstep, not Cocoa"
 186 #endif
 187 ], glib_have_cocoa=yes)
 188
 189 AC_MSG_RESULT([$glib_have_cocoa])
 190
 191 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 192 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 193 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 194 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 195 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 196 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 197
 198 AS_IF([test "$glib_native_win32" = "yes"], [
 199   AC_CHECK_TOOL(WINDRES, windres, no)
 200   if test "$WINDRES" = no; then
 201     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 202   fi
 203   AC_CHECK_TOOL(NM, nm, no)
 204   if test "$NM" = no; then
 205     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 206   fi
 207   AC_CHECK_TOOL(RANLIB, ranlib, :)
 208   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 209   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 210 ])
 211 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 212
 213 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 214   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 215   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 216 ])
 217
 218 if test "x$glib_have_cocoa" = "xyes"; then
 219   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 220   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 221 fi
 222
 223 gl_GLIBC21
 224 AS_IF([test "x$GLIBC21" = "xyes"], [
 225   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 226 ])
 227
 228 dnl declare --enable-* args and collect ac_help strings
 229 AC_ARG_ENABLE(debug,
 230               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 231                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 232               enable_debug=glib_debug_default)
 233
 234 AC_ARG_ENABLE(gc_friendly,
 235               [AS_HELP_STRING([--enable-gc-friendly],
 236                               [turn on garbage collector friendliness [default=no]])],,
 237               [enable_gc_friendly=no])
 238 AC_ARG_ENABLE(mem_pools,
 239               [AS_HELP_STRING([--disable-mem-pools],
 240                               [disable all glib memory pools])],,
 241               [disable_mem_pools=no])
 242 AC_ARG_ENABLE(rebuilds,
 243               [AS_HELP_STRING([--disable-rebuilds],
 244                               [disable all source autogeneration rules])],,
 245               [enable_rebuilds=yes])
 246 AC_ARG_ENABLE(modular_tests,
 247               AS_HELP_STRING([--disable-modular-tests],
 248                              [Disable build of test programs (default: no)]),,
 249               [enable_modular_tests=yes])
 250 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 251
 252 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 253 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 254   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 255   AC_MSG_RESULT([yes])
 256 ], [ AC_MSG_RESULT([no]) ])
 257
 258 AC_MSG_CHECKING([whether to disable memory pools])
 259 AS_IF([test "x$disable_mem_pools" = "xno"], [
 260   AC_MSG_RESULT([no])
 261 ], [
 262   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 263   AC_MSG_RESULT([yes])
 264 ])
 265
 266 dnl location to install runtime libraries, e.g. ../../lib to install
 267 dnl to /lib if libdir is /usr/lib
 268 AC_ARG_WITH(runtime-libdir,
 269            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 270                            [install runtime libraries relative to libdir])],
 271            [],
 272            [with_runtime_libdir=""])
 273 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 274 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 275 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 276 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 277 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 278
 279 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 280 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 281 AC_LANG_SAVE
 282 AC_LANG_CPLUSPLUS
 283 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 284 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 285 AC_LANG_RESTORE
 286
 287 AM_PROG_CC_C_O
 288 AC_PROG_INSTALL
 289
 290 AC_SYS_LARGEFILE
 291
 292 PKG_PROG_PKG_CONFIG(0.16)
 293
 294 if test "x$enable_debug" = "xyes"; then
 295   if test x$cflags_set != xset ; then
 296       case " $CFLAGS " in
 297       *[[\ \    ]]-g[[\ \       ]]*) ;;
 298       *) CFLAGS="$CFLAGS -g" ;;
 299       esac
 300   fi
 301   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 302 else
 303   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 304
 305   if test "x$enable_debug" = "xno"; then
 306     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 307   fi
 308 fi
 309
 310 # Ensure MSVC-compatible struct packing convention is used when
 311 # compiling for Win32 with gcc.
 312 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 313 # gcc2 uses "-fnative-struct".
 314 if test x"$glib_native_win32" = xyes; then
 315   if test x"$GCC" = xyes; then
 316     msnative_struct=''
 317     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 318     if test -z "$ac_cv_prog_CC"; then
 319       our_gcc="$CC"
 320     else
 321       our_gcc="$ac_cv_prog_CC"
 322     fi
 323     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 324       2.)
 325         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 326           msnative_struct='-fnative-struct'
 327         fi
 328         ;;
 329       *)
 330         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 331           msnative_struct='-mms-bitfields'
 332         fi
 333         ;;
 334     esac
 335     if test x"$msnative_struct" = x ; then
 336       AC_MSG_RESULT([no way])
 337       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 338     else
 339       CFLAGS="$CFLAGS $msnative_struct"
 340       AC_MSG_RESULT([${msnative_struct}])
 341     fi
 342   fi
 343 fi
 344 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 345 AC_SUBST(GLIB_EXTRA_CFLAGS)
 346
 347 AC_EXEEXT
 348
 349 # define a MAINT-like variable REBUILD which is set if Perl
 350 # and awk are found, so autogenerated sources can be rebuilt
 351 AC_PROG_AWK
 352 AC_CHECK_PROGS(PERL, [perl5 perl])
 353 # We would like indent, but don't require it.
 354 AC_CHECK_PROG(INDENT, indent, indent)
 355 REBUILD=\#
 356 if test "x$enable_rebuilds" = "xyes" && \
 357      test -n "$PERL" && \
 358      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 359      test -n "$AWK" ; then
 360   REBUILD=
 361 fi
 362 AC_SUBST(REBUILD)
 363
 364 # Need full path to Perl for glib-mkenums
 365 #
 366 if test "x$PERL" != x ; then
 367   AC_PATH_PROG(PERL_PATH, [$PERL])
 368 fi
 369 if test "x$PERL_PATH" = x ; then
 370   PERL_PATH="/usr/bin/env perl"
 371 fi
 372 AC_SUBST(PERL_PATH)
 373
 374 # option to specify python interpreter to use; this just sets $PYTHON, so that
 375 # we will fallback to reading $PYTHON if --with-python is not given, and
 376 # python.m4 will get the expected input
 377 AC_ARG_WITH(python,
 378             AS_HELP_STRING([--with-python=PATH],
 379                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 380             [PYTHON="$withval"], [])
 381 if test x"$PYTHON" = xyes; then
 382   AC_MSG_ERROR([--with-python option requires a path or program argument])
 383 fi
 384 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 385
 386
 387 dnl ***********************
 388 dnl *** Tests for iconv ***
 389 dnl ***********************
 390 dnl
 391 dnl We do this before the gettext checks, to avoid distortion
 392
 393 dnl On Windows we use a native implementation
 394
 395 AS_IF([ test x"$glib_native_win32" = xyes], [
 396   with_libiconv=native
 397 ], [
 398   AC_ARG_WITH(libiconv,
 399               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 400                               [use the libiconv library])],,
 401               [with_libiconv=maybe])
 402
 403   found_iconv=no
 404   case $with_libiconv in
 405     maybe)
 406       # Check in the C library first
 407       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 408       # Check if we have GNU libiconv
 409       if test $found_iconv = "no"; then
 410         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 411       fi
 412       # Check if we have a iconv in -liconv, possibly from vendor
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 415       fi
 416       ;;
 417     no)
 418       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 419       ;;
 420     gnu|yes)
 421       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 422       ;;
 423     native)
 424       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 425       ;;
 426   esac
 427
 428   if test "x$found_iconv" = "xno" ; then
 429      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 430   fi
 431 ])
 432
 433 AC_ARG_ENABLE(iconv-cache,
 434               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 435                               [cache iconv descriptors [default=auto]])],,
 436               [enable_iconv_cache=auto])
 437
 438 AC_MSG_CHECKING([whether to cache iconv descriptors])
 439 case $enable_iconv_cache in
 440   auto)
 441     if test $ac_cv_gnu_library_2_1 = yes; then
 442       enable_iconv_cache=no
 443     else
 444       enable_iconv_cache=yes
 445     fi
 446   ;;
 447   yes|no)
 448   ;;
 449   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 450   ;;
 451 esac
 452
 453 if test $enable_iconv_cache = yes; then
 454    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 455 fi
 456
 457 AC_MSG_RESULT($enable_iconv_cache)
 458
 459
 460 dnl
 461 dnl zlib support
 462 dnl
 463 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 464 AS_IF([test "x$found_zlib" = "xno"], [
 465   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 466   if test "x$found_zlib" = "xno" ; then
 467     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 468   fi
 469   ZLIB_LIBS='-lz'
 470   AC_SUBST(ZLIB_LIBS)
 471 ])
 472
 473 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 474 AC_SUBST(LIBFFI_CFLAGS)
 475 AC_SUBST(LIBFFI_LIBS)
 476
 477 dnl
 478 dnl gettext support
 479 dnl
 480
 481 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 482 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 483 GLIB_GNU_GETTEXT
 484
 485 if test "$gt_cv_have_gettext" != "yes" ; then
 486   AC_MSG_ERROR([
 487 *** You must have either have gettext support in your C library, or use the
 488 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 489 ])
 490 fi
 491
 492 LIBS="$INTLLIBS $LIBS"
 493
 494 GETTEXT_PACKAGE=glib20
 495 AC_SUBST(GETTEXT_PACKAGE)
 496 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 497   [Define the gettext package to be used])
 498
 499 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 500
 501 dnl
 502 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 503 dnl
 504
 505 AS_IF([test x"$glib_native_win32" != xyes], [
 506   if test x$with_libiconv != xno ; then
 507     case " $INTLLIBS " in
 508     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 509     *) ICONV_LIBS="-liconv" ;;
 510     esac
 511   fi
 512 ])
 513 AC_SUBST(ICONV_LIBS)
 514
 515 case $with_libiconv in
 516   gnu)
 517     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 518     ;;
 519   native)
 520     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 521     ;;
 522 esac
 523
 524 dnl Initialize libtool
 525 LT_PREREQ([2.2])
 526 LT_INIT([disable-static win32-dll])
 527 dnl when using libtool 2.x create libtool early, because it's used in configure
 528 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 529
 530
 531 AS_IF([test "$glib_native_win32" = "yes"], [
 532   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 533     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 534   fi
 535   if test x$enable_static = xyes; then
 536     glib_win32_static_compilation=yes
 537     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 538 #define GOBJECT_STATIC_COMPILATION 1"
 539     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 540   fi
 541 ])
 542 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 543
 544 dnl
 545 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 546 dnl
 547 AS_IF([test $cross_compiling != yes], [
 548     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 549     glib_save_LIBS=$LIBS
 550     LIBS="$LIBS -lm"
 551     AC_TRY_RUN([#include <math.h>
 552                  int main (void) { return (log(1) != log(1.)); }],
 553          AC_MSG_RESULT(none needed),
 554          glib_save_CFLAGS=$CFLAGS
 555          CFLAGS="$CFLAGS -std1"
 556          AC_TRY_RUN([#include <math.h>
 557                      int main (void) { return (log(1) != log(1.)); }],
 558              AC_MSG_RESULT(-std1),
 559              AC_MSG_RESULT()
 560              CFLAGS=$glib_save_CFLAGS
 561              AC_MSG_WARN(
 562                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 563          )
 564     )
 565     LIBS=$glib_save_LIBS
 566 ])
 567
 568 dnl NeXTStep cc seems to need this
 569 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 570 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 571   AC_MSG_RESULT(none needed),
 572   glib_save_CFLAGS=$CFLAGS
 573   CFLAGS="$CFLAGS -posix"
 574   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 575     AC_MSG_RESULT(-posix),
 576     AC_MSG_RESULT()
 577     CFLAGS=$glib_save_CFLAGS
 578     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 579
 580 # Checks for library functions.
 581 AC_FUNC_VPRINTF
 582 AC_FUNC_ALLOCA
 583 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 584 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 585
 586 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 587   [AC_TRY_LINK([#include <unistd.h>
 588     extern int __libc_enable_secure;],
 589     [return __libc_enable_secure;],
 590    glib_cv_have_libc_enable_secure=yes,
 591    glib_cv_have_libc_enable_secure=no)])
 592 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 593    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 594      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 595 ])
 596
 597 AC_CHECK_SIZEOF(char)
 598 AC_CHECK_SIZEOF(short)
 599 AC_CHECK_SIZEOF(long)
 600 AC_CHECK_SIZEOF(int)
 601 AC_CHECK_SIZEOF(void *)
 602 AC_CHECK_SIZEOF(long long)
 603 AC_CHECK_SIZEOF(__int64)
 604
 605 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 606   [AC_TRY_LINK([#include <signal.h>
 607      #include <sys/types.h>
 608      sig_atomic_t val = 42;],
 609     [return val == 42 ? 0 : 1],
 610    ac_cv_type_sig_atomic_t=yes,
 611    ac_cv_type_sig_atomic_t=no)])
 612 if test x$ac_cv_type_sig_atomic_t = xyes; then
 613    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 614      [Define if you have the 'sig_atomic_t' type.])
 615 fi
 616
 617 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 618   :
 619 else
 620   AC_MSG_ERROR([
 621 *** GLib requires a 64 bit type. You might want to consider
 622 *** using the GNU C compiler.
 623 ])
 624 fi
 625
 626 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 627         # long long is a 64 bit integer.
 628         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 629         AC_CACHE_VAL(glib_cv_long_long_format,[
 630                 for format in ll q I64; do
 631                   AC_TRY_RUN([#include <stdio.h>
 632                         int main()
 633                         {
 634                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 635                           char buffer[1000];
 636                           sprintf (buffer, "%${format}u", a);
 637                           sscanf (buffer, "%${format}u", &b);
 638                           exit (b!=a);
 639                         }
 640                         ],
 641                         [glib_cv_long_long_format=${format}
 642                         break],
 643                         [],[:])
 644                 done])
 645         AS_IF([ test -n "$glib_cv_long_long_format"], [
 646           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 647           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 648           if test x"$glib_cv_long_long_format" = xI64; then
 649             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 650           fi
 651         ], [AC_MSG_RESULT(none)])
 652 ],[ test x$ac_cv_sizeof___int64 = x8], [
 653         # __int64 is a 64 bit integer.
 654         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 655         # We know this is MSVCRT.DLL, and what the formats are
 656         glib_cv_long_long_format=I64
 657         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 660 ])
 661
 662 AC_C_CONST
 663
 664 dnl ok, here we try to check whether the systems prototypes for
 665 dnl malloc and friends actually match the prototypes provided
 666 dnl by gmem.h (keep in sync). i currently only know how to check
 667 dnl this reliably with gcc (-Werror), improvements for other
 668 dnl compilers are apprechiated.
 669 SANE_MALLOC_PROTOS=no
 670 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 671 glib_save_CFLAGS=$CFLAGS
 672 AS_IF([test "x$GCC" = "xyes"], [
 673   CFLAGS="$CFLAGS -Werror"
 674   AC_TRY_COMPILE([#include <stdlib.h>], [
 675     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 676     void* (*my_malloc_p)  (size_t)         = malloc;
 677     void  (*my_free_p)    (void*)          = free;
 678     void* (*my_realloc_p) (void*, size_t)  = realloc;
 679     my_calloc_p = 0;
 680     my_malloc_p = 0;
 681     my_free_p = 0;
 682     my_realloc_p = 0;
 683   ],
 684     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 685       [Define if you have correct malloc prototypes])
 686     SANE_MALLOC_PROTOS=yes)
 687 ])
 688 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 689 CFLAGS=$glib_save_CFLAGS
 690
 691 dnl
 692 dnl check in which direction the stack grows
 693 dnl
 694 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 695         AC_TRY_RUN([
 696         volatile int *a = 0, *b = 0;
 697         void foo (void);
 698         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 699         void foo (void) { volatile int x = 5; b = &x; }
 700         ],
 701         glib_cv_stack_grows=no
 702         ,
 703         glib_cv_stack_grows=yes
 704         ,)
 705 ])
 706
 707 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 708 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 709 dnl actually supported.
 710 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 711         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 712         __inline int foo () { return 0; }
 713         int main () { return foo (); }
 714         ]])],
 715         glib_cv_has__inline=yes
 716         ,
 717         glib_cv_has__inline=no
 718         ,)
 719 ])
 720 case x$glib_cv_has__inline in
 721 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 722 esac
 723 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline__ int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline__=yes
 729         ,
 730         glib_cv_has__inline__=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline__ in
 734 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 735 esac
 736 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         #undef inline
 739         inline int foo () { return 0; }
 740         int main () { return foo (); }
 741         ]])],
 742         glib_cv_hasinline=yes
 743         ,
 744         glib_cv_hasinline=no
 745         ,)
 746 ])
 747 case x$glib_cv_hasinline in
 748 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 749 esac
 750
 751 # if we can use inline functions in headers
 752 AC_MSG_CHECKING(if inline functions in headers work)
 753 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 754 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 755 #  undef inline
 756 #  define inline __inline__
 757 #elif !defined (G_HAVE_INLINE)
 758 #  undef inline
 759 #  if defined (G_HAVE___INLINE__)
 760 #    define inline __inline__
 761 #  elif defined (G_HAVE___INLINE)
 762 #    define inline __inline
 763 #  endif
 764 #endif
 765
 766 int glib_test_func2 (int);
 767
 768 static inline int
 769 glib_test_func1 (void) {
 770   return glib_test_func2 (1);
 771 }
 772
 773 int
 774 main (void) {
 775   int i = 1;
 776 }]])],[g_can_inline=yes],[g_can_inline=no])
 777 AC_MSG_RESULT($g_can_inline)
 778
 779 dnl *** check for working do while(0) macros ***
 780 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 781         AC_TRY_COMPILE([],[
 782         #define STMT_START do
 783         #define STMT_END while(0)
 784         #define STMT_TEST STMT_START { i = 0; } STMT_END
 785         int main(void) { int i = 1; STMT_TEST; return i; }],
 786         [g_cv_support_dowhile_macros=yes],
 787         [g_cv_support_dowhile_macros=no],
 788         [g_cv_support_dowhile_macros=yes])
 789 ])
 790 if test x$g_cv_support_dowhile_macros = xyes; then
 791   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 792 fi
 793
 794 # check for flavours of varargs macros
 795 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 796 AC_TRY_COMPILE([],[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(...) a(1,__VA_ARGS__)
 799 call_a(2,3);
 800 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 801 AC_MSG_RESULT($g_have_iso_c_varargs)
 802
 803 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 804 AS_IF([test "$CXX" = ""], [
 805 dnl No C++ compiler
 806   g_have_iso_cxx_varargs=no
 807 else
 808   AC_LANG_CPLUSPLUS
 809   AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 814   AC_LANG_C
 815 ])
 816 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 817
 818 AC_MSG_CHECKING(for GNUC varargs macros)
 819 AC_TRY_COMPILE([],[
 820 int a(int p1, int p2, int p3);
 821 #define call_a(params...) a(1,params)
 822 call_a(2,3);
 823 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 824 AC_MSG_RESULT($g_have_gnuc_varargs)
 825
 826 # check for GNUC visibility support
 827 AC_MSG_CHECKING(for GNUC visibility attribute)
 828 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 829 void
 830 __attribute__ ((visibility ("hidden")))
 831      f_hidden (void)
 832 {
 833 }
 834 void
 835 __attribute__ ((visibility ("internal")))
 836      f_internal (void)
 837 {
 838 }
 839 void
 840 __attribute__ ((visibility ("protected")))
 841      f_protected (void)
 842 {
 843 }
 844 void
 845 __attribute__ ((visibility ("default")))
 846      f_default (void)
 847 {
 848 }
 849 int main (void)
 850 {
 851         f_hidden();
 852         f_internal();
 853         f_protected();
 854         f_default();
 855         return 0;
 856 }
 857 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 858 AC_MSG_RESULT($g_have_gnuc_visibility)
 859 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 860
 861 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 862 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 863 #else
 864 # include "error: this is not Sun Studio."
 865 #endif
 866 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 867 AC_MSG_RESULT($g_have_sunstudio_visibility)
 868 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 869
 870 # check for bytesex stuff
 871 AC_C_BIGENDIAN
 872 if test x$ac_cv_c_bigendian = xuniversal ; then
 873 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 874 #else
 875 #error Not a big endian.
 876 #endif],
 877     ac_cv_c_bigendian=yes
 878     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 879 #else
 880 #error Not a little endian.
 881 #endif],
 882     ac_cv_c_bigendian=no
 883     ,AC_MSG_WARN([Could not determine endianness.])))
 884 fi
 885
 886
 887 # check for header files
 888 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 889 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 890 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 891 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 892 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 893 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 894 AC_CHECK_HEADERS([linux/magic.h])
 895 AC_CHECK_HEADERS([sys/prctl.h])
 896
 897 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 898 [#if HAVE_SYS_PARAM_H
 899  #include <sys/param.h>
 900  #endif
 901 ])
 902 AC_CHECK_FUNCS(sysctlbyname)
 903
 904 AC_CHECK_HEADERS([xlocale.h])
 905
 906 # check for structure fields
 907 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 908 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 909 #include <sys/stat.h>
 910 #include <unistd.h>
 911 #ifdef HAVE_SYS_STATFS_H
 912 #include <sys/statfs.h>
 913 #endif
 914 #ifdef HAVE_SYS_PARAM_H
 915 #include <sys/param.h>
 916 #endif
 917 #ifdef HAVE_SYS_MOUNT_H
 918 #include <sys/mount.h>
 919 #endif])
 920 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 921 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 922 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 923 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 924
 925 AC_STRUCT_DIRENT_D_TYPE
 926
 927 # Checks for libcharset
 928 AM_LANGINFO_CODESET
 929 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 930 AC_CHECK_FUNCS(setlocale)
 931
 932 # check additional type sizes
 933 AC_CHECK_SIZEOF(size_t)
 934
 935 dnl Try to figure out whether gsize, gssize should be long or int
 936 AC_MSG_CHECKING([for the appropriate definition for size_t])
 937
 938 case $ac_cv_sizeof_size_t in
 939   $ac_cv_sizeof_short)
 940       glib_size_type=short
 941       ;;
 942   $ac_cv_sizeof_int)
 943       glib_size_type=int
 944       ;;
 945   $ac_cv_sizeof_long)
 946       glib_size_type=long
 947       ;;
 948   $ac_cv_sizeof_long_long)
 949       glib_size_type='long long'
 950       ;;
 951   $ac_cv_sizeof__int64)
 952       glib_size_type='__int64'
 953       ;;
 954   *)  AC_MSG_ERROR([No type matching size_t in size])
 955       ;;
 956 esac
 957
 958 dnl If int/long are the same size, we see which one produces
 959 dnl warnings when used in the location as size_t. (This matters
 960 dnl on AIX with xlc)
 961 dnl
 962 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 963        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 964   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 965 #if defined(_AIX) && !defined(__GNUC__)
 966 #pragma options langlvl=stdc89
 967 #endif
 968 #include <stddef.h>
 969 int main ()
 970 {
 971   size_t s = 1;
 972   unsigned int *size_int = &s;
 973   return (int)*size_int;
 974 }
 975     ]])],glib_size_type=int,
 976       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 977 #if defined(_AIX) && !defined(__GNUC__)
 978 #pragma options langlvl=stdc89
 979 #endif
 980 #include <stddef.h>
 981 int main ()
 982 {
 983    size_t s = 1;
 984    unsigned long *size_long = &s;
 985    return (int)*size_long;
 986 }
 987         ]])],glib_size_type=long)])
 988 ])
 989
 990 AC_MSG_RESULT(unsigned $glib_size_type)
 991
 992 # Check for some functions
 993 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 994 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 995 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 996 # Check for high-resolution sleep functions
 997 AC_CHECK_FUNCS(splice)
 998 AC_CHECK_FUNCS(prlimit)
 999
1000 # To avoid finding a compatibility unusable statfs, which typically
1001 # successfully compiles, but warns to use the newer statvfs interface:
1002 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1003 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1004
1005 AC_MSG_CHECKING([whether to use statfs or statvfs])
1006 # Some systems have both statfs and statvfs, pick the most "native" for these
1007 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1008    [
1009    # on solaris and irix, statfs doesn't even have the f_bavail field
1010    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1011       [ac_cv_func_statfs=no],
1012    # else, at least on linux, statfs is the actual syscall
1013       [ac_cv_func_statvfs=no])
1014    ])
1015
1016 AS_IF([test x$ac_cv_func_statfs = xyes],
1017       [
1018          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1019          AC_MSG_RESULT([statfs])
1020       ],
1021       [test x$ac_cv_func_statvfs = xyes],
1022       [
1023          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1024          AC_MSG_RESULT([statvfs])
1025       ],
1026       [  AC_MSG_RESULT([neither])])
1027
1028 AC_CHECK_HEADERS(crt_externs.h)
1029 AC_CHECK_FUNCS(_NSGetEnviron)
1030
1031 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1032
1033 AC_FUNC_VSNPRINTF_C99
1034 AC_FUNC_PRINTF_UNIX98
1035
1036 # Internet address families
1037 if test $glib_native_win32 = yes; then
1038   glib_inet_includes=["
1039 #include <winsock2.h>
1040   "]
1041 else
1042   glib_inet_includes=["
1043 #include <sys/types.h>
1044 #include <sys/socket.h>
1045   "]
1046 fi
1047
1048 glib_failed=false
1049 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1051 # winsock defines this even though it doesn't support it
1052 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1053 if $glib_failed ; then
1054   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1061 if $glib_failed ; then
1062   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1063 fi
1064
1065 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1066
1067 AS_IF([test $glib_native_win32 = yes], [
1068   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1069   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1070   # they aren't present at run-time (on Windows 2000).
1071   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1072   AC_SUBST(WSPIAPI_INCLUDE)
1073 ], [
1074   AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1075   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1076                                       #include <arpa/nameser.h>],
1077                                      [int qclass = C_IN;])],
1078                     [AC_MSG_RESULT([no])],
1079                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1080                                                          #include <arpa/nameser.h>
1081                                                          #include <arpa/nameser_compat.h>],
1082                                                         [int qclass = C_IN;])],
1083                                        [AC_MSG_RESULT([yes])
1084                                         NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1085                                        [AC_MSG_ERROR([could not compile test program either way])])])
1086   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1087
1088   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1089   NETWORK_LIBS=""
1090   AC_MSG_CHECKING([for res_query])
1091   AC_TRY_LINK([#include <sys/types.h>
1092                #include <netinet/in.h>
1093                #include <arpa/nameser.h>
1094                #include <resolv.h>
1095               ],[
1096                res_query("test", 0, 0, (void *)0, 0);
1097               ],[AC_MSG_RESULT([yes])],
1098               [save_libs="$LIBS"
1099                LIBS="-lresolv $LIBS"
1100                AC_TRY_LINK([#include <sys/types.h>
1101                             #include <netinet/in.h>
1102                             #include <arpa/nameser.h>
1103                             #include <resolv.h>
1104                            ],[
1105                             res_query("test", 0, 0, (void *)0, 0);
1106                            ],[AC_MSG_RESULT([in -lresolv])
1107                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1108                            [LIBS="-lbind $save_libs"
1109                             AC_TRY_LINK([#include <resolv.h>],
1110                                         [res_query("test", 0, 0, (void *)0, 0);],
1111                                         [AC_MSG_RESULT([in -lbind])
1112                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1113                                         [AC_MSG_ERROR(not found)])])
1114                LIBS="$save_libs"])
1115   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1116                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1117                                         [AC_MSG_ERROR(Could not find socket())]))
1118 ])
1119 AC_SUBST(NETWORK_LIBS)
1120
1121 AC_CHECK_HEADER([linux/netlink.h],
1122                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1123                 [#include <sys/socket.h>])
1124 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1125
1126 AC_CHECK_TYPE([struct ip_mreqn], [
1127               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1128               [#include <netinet/in.h>])
1129
1130 case $host in
1131   *-*-solaris* )
1132      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1133      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1134      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1135      ;;
1136 esac
1137
1138 dnl
1139 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1140 dnl
1141 AS_IF([test "$ac_cv_func_statfs" = yes], [
1142   AC_MSG_CHECKING([number of arguments to statfs()])
1143   AC_TRY_COMPILE([#include <unistd.h>
1144   #ifdef HAVE_SYS_PARAM_H
1145   #include <sys/param.h>
1146   #endif
1147   #ifdef HAVE_SYS_VFS_H
1148   #include <sys/vfs.h>
1149   #endif
1150   #ifdef HAVE_SYS_MOUNT_H
1151   #include <sys/mount.h>
1152   #endif
1153   #ifdef HAVE_SYS_STATFS_H
1154   #include <sys/statfs.h>
1155   #endif], [struct statfs st;
1156   statfs(NULL, &st);],[
1157     AC_MSG_RESULT([2])
1158     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1159     AC_TRY_COMPILE([#include <unistd.h>
1160   #ifdef HAVE_SYS_PARAM_H
1161   #include <sys/param.h>
1162   #endif
1163   #ifdef HAVE_SYS_VFS_H
1164   #include <sys/vfs.h>
1165   #endif
1166   #ifdef HAVE_SYS_MOUNT_H
1167   #include <sys/mount.h>
1168   #endif
1169   #ifdef HAVE_SYS_STATFS_H
1170   #include <sys/statfs.h>
1171   #endif], [struct statfs st;
1172   statfs(NULL, &st, sizeof (st), 0);],[
1173       AC_MSG_RESULT([4])
1174       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1175       AC_MSG_RESULT(unknown)
1176       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1177 ])
1178
1179 #
1180 # Check whether to use an included printf
1181 #
1182
1183 AC_ARG_ENABLE(included-printf,
1184               [AS_HELP_STRING([--enable-included-printf],
1185                               [use included printf [default=auto]])],
1186               enable_included_printf="$enableval")
1187
1188 need_included_printf=no
1189 if test "x$enable_included_printf" = "xyes" ; then
1190   need_included_printf=yes
1191 fi
1192 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1193   need_included_printf=yes
1194 fi
1195 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1196   need_included_printf=yes
1197 fi
1198 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1199    test -z "$glib_cv_long_long_format" ; then
1200   need_included_printf=yes
1201 fi
1202
1203 if test "x$enable_included_printf" = "xno" &&
1204    test "x$need_included_printf" = "xyes" ; then
1205   AC_MSG_ERROR([
1206 *** Your C library's printf doesn't appear to have the features that
1207 *** GLib needs, but you specified --enable-included-printf=no.])
1208 fi
1209
1210 enable_included_printf=$need_included_printf
1211
1212 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1213 AS_IF([test "$enable_included_printf" != "yes"], [
1214   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1215 ], [
1216   if test -z "$glib_cv_long_long_format" ; then
1217     glib_cv_long_long_format="ll"
1218   fi
1219   AC_DEFINE(HAVE_VASPRINTF,1)
1220 ])
1221
1222 # Checks needed for gnulib vasnprintf
1223 bh_C_SIGNED
1224 jm_AC_TYPE_LONG_LONG
1225 gt_TYPE_LONGDOUBLE
1226 gt_TYPE_WCHAR_T
1227 gt_TYPE_WINT_T
1228 AC_TYPE_SIZE_T
1229 AC_CHECK_TYPES(ptrdiff_t)
1230 jm_AC_TYPE_INTMAX_T
1231 AC_CHECK_FUNCS([snprintf wcslen])
1232 AC_FUNC_SNPRINTF_C99
1233
1234 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1235 # The check is borrowed from the PERL Configure script.
1236 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1237   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1238     glib_cv_working_bcopy,[AC_TRY_RUN([
1239       int main() {
1240         char buf[128], abc[128], *b;
1241         int len, off, align;
1242         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1243         for (align = 7; align >= 0; align--) {
1244           for (len = 36; len; len--) {
1245             b = buf+align; bcopy(abc, b, len);
1246             for (off = 1; off <= len; off++) {
1247               bcopy(b, b+off, len); bcopy(b+off, b, len);
1248                 if (bcmp(b, abc, len)) return(1);
1249             }
1250           }
1251         }
1252         return(0);
1253       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1254
1255   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1256   if test "$glib_cv_working_bcopy" = "yes"; then
1257     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1258   fi
1259 ])
1260
1261 # Check if <sys/select.h> needs to be included for fd_set
1262 AC_MSG_CHECKING([for fd_set])
1263 AC_TRY_COMPILE([#include <sys/types.h>],
1264         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1265 AS_IF([test "$gtk_ok" = "yes"], [
1266     AC_MSG_RESULT([yes, found in sys/types.h])
1267 ], [
1268     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1269     if test "$gtk_ok" = "yes"; then
1270         # *** FIXME: give it a different name
1271         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1272         AC_MSG_RESULT([yes, found in sys/select.h])
1273     else
1274         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1275         AC_MSG_RESULT(no)
1276     fi
1277 ])
1278
1279 dnl *** check for sane realloc() ***
1280 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1281         AC_TRY_RUN([#include <stdlib.h>
1282         int main() {
1283           return realloc (0, sizeof (int)) == 0;
1284         }],
1285         [glib_cv_sane_realloc=yes],
1286         [glib_cv_sane_realloc=no],
1287         [glib_cv_sane_realloc=yes])
1288 ])
1289 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1290   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1291 ])
1292
1293 dnl Check for nl_langinfo and CODESET
1294 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1295         AC_TRY_COMPILE([#include <langinfo.h>],
1296                 [char *codeset = nl_langinfo (CODESET);],
1297                 [glib_cv_langinfo_codeset=yes],
1298                 [glib_cv_langinfo_codeset=no])])
1299 if test x$glib_cv_langinfo_codeset = xyes; then
1300   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1301 fi
1302
1303 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1304 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1305         AC_TRY_COMPILE([#include <langinfo.h>],
1306                 [char *str;
1307                  str = nl_langinfo (PM_STR);
1308                  str = nl_langinfo (D_T_FMT);
1309                  str = nl_langinfo (D_FMT);
1310                  str = nl_langinfo (T_FMT);
1311                  str = nl_langinfo (T_FMT_AMPM);
1312                  str = nl_langinfo (MON_1);
1313                  str = nl_langinfo (ABMON_12);
1314                  str = nl_langinfo (DAY_1);
1315                  str = nl_langinfo (ABDAY_7);],
1316                 [glib_cv_langinfo_time=yes],
1317                 [glib_cv_langinfo_time=no])])
1318 if test x$glib_cv_langinfo_time = xyes; then
1319   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1320 fi
1321
1322 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1323 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1324         AC_TRY_COMPILE([#include <langinfo.h>],
1325                 [char *str;
1326                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1327                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1328                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1329                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1336                 [glib_cv_langinfo_outdigit=yes],
1337                 [glib_cv_langinfo_outdigit=no])])
1338 if test x$glib_cv_langinfo_outdigit = xyes; then
1339   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1340 fi
1341
1342 dnl ****************************************
1343 dnl *** posix_memalign                   ***
1344 dnl ****************************************
1345 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1346 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1347     glib_cv_compliant_posix_memalign=0
1348     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1349         AC_TRY_RUN([
1350                 #define _XOPEN_SOURCE 600
1351                 #include <stdlib.h> /* posix_memalign() should be defined here */
1352                 /* some systems break if #include <malloc.h> used */
1353                 static void test_memalign (size_t boundary, size_t size) {
1354                     void *mem = 0;
1355                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1356                         exit (1);
1357                     else
1358                       free (mem);
1359                 }
1360                 int main() {
1361                     test_memalign (  128,   128 - 2 * sizeof (void*));
1362                     test_memalign (  256,   256 - 2 * sizeof (void*));
1363                     test_memalign (  512,   512 - 2 * sizeof (void*));
1364                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1365                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1366                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1367                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1368                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1369                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1370                     exit (0); /* success */
1371                 }
1372                 ],
1373             [glib_cv_compliant_posix_memalign=1], [], [:])
1374       :
1375     fi
1376     ])
1377 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1378     AC_MSG_RESULT(yes)
1379     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1380 ], [
1381     AC_MSG_RESULT(no)
1382 ])
1383
1384
1385 dnl ****************************************
1386 dnl *** strlcpy/strlcat                  ***
1387 dnl ****************************************
1388 # Check for strlcpy
1389 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1390 AC_TRY_RUN([#include <stdlib.h>
1391 #include <string.h>
1392 int main() {
1393   char p[10];
1394   (void) strlcpy (p, "hi", 10);
1395   if (strlcat (p, "bye", 0) != 3)
1396     return 1;
1397   return 0;
1398 }], glib_cv_have_strlcpy=yes,
1399     glib_cv_have_strlcpy=no,
1400     glib_cv_have_strlcpy=no)])
1401 if test "$glib_cv_have_strlcpy" = "yes"; then
1402     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1403 fi
1404
1405
1406 dnl **********************
1407 dnl *** va_copy checks ***
1408 dnl **********************
1409 dnl we currently check for all three va_copy possibilities, so we get
1410 dnl all results in config.log for bug reports.
1411 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1412         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1413 #include <stdlib.h>
1414         void f (int i, ...) {
1415         va_list args1, args2;
1416         va_start (args1, i);
1417         va_copy (args2, args1);
1418         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1419           exit (1);
1420         va_end (args1); va_end (args2);
1421         }
1422         int main() {
1423           f (0, 42);
1424           return 0;
1425         }]])],
1426         [glib_cv_va_copy=yes],
1427         [glib_cv_va_copy=no])
1428 ])
1429 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1430         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1431 #include <stdlib.h>
1432         void f (int i, ...) {
1433         va_list args1, args2;
1434         va_start (args1, i);
1435         __va_copy (args2, args1);
1436         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1437           exit (1);
1438         va_end (args1); va_end (args2);
1439         }
1440         int main() {
1441           f (0, 42);
1442           return 0;
1443         }]])],
1444         [glib_cv___va_copy=yes],
1445         [glib_cv___va_copy=no])
1446 ])
1447
1448 if test "x$glib_cv_va_copy" = "xyes"; then
1449   g_va_copy_func=va_copy
1450 else if test "x$glib_cv___va_copy" = "xyes"; then
1451   g_va_copy_func=__va_copy
1452 fi
1453 fi
1454
1455 if test -n "$g_va_copy_func"; then
1456   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1457 fi
1458
1459 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1460         AC_TRY_RUN([#include <stdarg.h>
1461 #include <stdlib.h>
1462         void f (int i, ...) {
1463         va_list args1, args2;
1464         va_start (args1, i);
1465         args2 = args1;
1466         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1467           exit (1);
1468         va_end (args1); va_end (args2);
1469         }
1470         int main() {
1471           f (0, 42);
1472           return 0;
1473         }],
1474         [glib_cv_va_val_copy=yes],
1475         [glib_cv_va_val_copy=no],
1476         [glib_cv_va_val_copy=yes])
1477 ])
1478
1479 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1480   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1481 ])
1482
1483 dnl ***********************
1484 dnl *** g_module checks ***
1485 dnl ***********************
1486 G_MODULE_LIBS=
1487 G_MODULE_LIBS_EXTRA=
1488 G_MODULE_PLUGIN_LIBS=
1489 if test x"$glib_native_win32" = xyes; then
1490   dnl No use for this on Win32
1491   G_MODULE_LDFLAGS=
1492 else
1493   export SED
1494   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1495 fi
1496 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1497 G_MODULE_NEED_USCORE=0
1498 G_MODULE_BROKEN_RTLD_GLOBAL=0
1499 G_MODULE_HAVE_DLERROR=0
1500 dnl *** force native WIN32 shared lib loader
1501 if test -z "$G_MODULE_IMPL"; then
1502   case "$host" in
1503   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1504   esac
1505 fi
1506 dnl *** force native AIX library loader
1507 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1508 if test -z "$G_MODULE_IMPL"; then
1509   case "$host" in
1510   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1511   esac
1512 fi
1513 dnl *** dlopen() and dlsym() in system libraries
1514 AS_IF([ test -z "$G_MODULE_IMPL"], [
1515         AC_CHECK_FUNC(dlopen,
1516                       [AC_CHECK_FUNC(dlsym,
1517                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1518                       [])
1519 ])
1520 dnl *** load_image (BeOS)
1521 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1522   AC_CHECK_LIB(root, load_image,
1523       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1524       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1525       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1526       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1527       [])
1528 ])
1529 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1530 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1531         AC_CHECK_FUNC(NSLinkModule,
1532                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1533                        G_MODULE_NEED_USCORE=1],
1534                       [])
1535 ])
1536 dnl *** dlopen() and dlsym() in libdl
1537 AS_IF([ test -z "$G_MODULE_IMPL"], [
1538         AC_CHECK_LIB(dl, dlopen,
1539                      [AC_CHECK_LIB(dl, dlsym,
1540                                    [G_MODULE_LIBS=-ldl
1541                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1542                      [])
1543 ])
1544 dnl *** shl_load() in libdld (HP-UX)
1545 AS_IF([ test -z "$G_MODULE_IMPL"], [
1546         AC_CHECK_LIB(dld, shl_load,
1547                 [G_MODULE_LIBS=-ldld
1548                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1549                 [])
1550 ])
1551 dnl *** additional checks for G_MODULE_IMPL_DL
1552 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1553         LIBS_orig="$LIBS"
1554         LDFLAGS_orig="$LDFLAGS"
1555         LIBS="$G_MODULE_LIBS $LIBS"
1556         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1557 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1558         echo "void glib_plugin_test(void) { }" > plugin.c
1559         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1560                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1561         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1562                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1563                 -shrext ".o" -avoid-version plugin.lo \
1564                 -rpath /dont/care >/dev/null 2>&1
1565         eval `./libtool --config | grep ^objdir`
1566         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1567                 glib_cv_rtldglobal_broken,[
1568                 AC_TRY_RUN([
1569 #include <dlfcn.h>
1570 #ifndef RTLD_GLOBAL
1571 #  define RTLD_GLOBAL 0
1572 #endif
1573 #ifndef RTLD_LAZY
1574 #  define RTLD_LAZY 0
1575 #endif
1576 int glib_plugin_test;
1577 int main () {
1578     void *handle, *global, *local;
1579     global = &glib_plugin_test;
1580     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1581     if (!handle) return 0;
1582     local = dlsym (handle, "glib_plugin_test");
1583     return global == local;
1584 }                       ],
1585                         [glib_cv_rtldglobal_broken=no],
1586                         [glib_cv_rtldglobal_broken=yes],
1587                         [glib_cv_rtldglobal_broken=no])
1588                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1589                 rmdir ${objdir} 2>/dev/null
1590         ])
1591         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1592                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1593         else
1594                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1595         fi
1596 dnl *** check whether we need preceeding underscores
1597         AC_CACHE_CHECK([for preceeding underscore in symbols],
1598                 glib_cv_uscore,[
1599                 AC_TRY_RUN([#include <dlfcn.h>
1600                 int glib_underscore_test (void) { return 42; }
1601                 int main() {
1602                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1603                   handle = dlopen ((void*)0, 0);
1604                   if (handle) {
1605                     f1 = dlsym (handle, "glib_underscore_test");
1606                     f2 = dlsym (handle, "_glib_underscore_test");
1607                   } return (!f2 || f1);
1608                 }],
1609                         [glib_cv_uscore=yes],
1610                         [glib_cv_uscore=no],
1611                         [])
1612                 rm -f plugin.c plugin.$ac_objext plugin.lo
1613         ])
1614         GLIB_ASSERT_SET(glib_cv_uscore)
1615         if test "x$glib_cv_uscore" = "xyes"; then
1616                 G_MODULE_NEED_USCORE=1
1617         else
1618                 G_MODULE_NEED_USCORE=0
1619         fi
1620
1621         LDFLAGS="$LDFLAGS_orig"
1622 dnl *** check for having dlerror()
1623         AC_CHECK_FUNC(dlerror,
1624                 [G_MODULE_HAVE_DLERROR=1],
1625                 [G_MODULE_HAVE_DLERROR=0])
1626         LIBS="$LIBS_orig"
1627 ])
1628 dnl *** done, have we got an implementation?
1629 if test -z "$G_MODULE_IMPL"; then
1630         G_MODULE_IMPL=0
1631         G_MODULE_SUPPORTED=false
1632 else
1633         G_MODULE_SUPPORTED=true
1634 fi
1635
1636 AC_MSG_CHECKING(for the suffix of module shared libraries)
1637 export SED
1638 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1639 eval $shrext_cmds
1640 module=yes eval std_shrext=$shrext_cmds
1641 # chop the initial dot
1642 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1643 AC_MSG_RESULT(.$glib_gmodule_suffix)
1644 # any reason it may fail?
1645 if test "x$glib_gmodule_suffix" = x; then
1646         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1647 fi
1648
1649 AC_SUBST(G_MODULE_SUPPORTED)
1650 AC_SUBST(G_MODULE_IMPL)
1651 AC_SUBST(G_MODULE_LIBS)
1652 AC_SUBST(G_MODULE_LIBS_EXTRA)
1653 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1654 AC_SUBST(G_MODULE_LDFLAGS)
1655 AC_SUBST(G_MODULE_HAVE_DLERROR)
1656 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1657 AC_SUBST(G_MODULE_NEED_USCORE)
1658 AC_SUBST(GLIB_DEBUG_FLAGS)
1659
1660 dnl **********************
1661 dnl *** g_spawn checks ***
1662 dnl **********************
1663
1664 AC_MSG_CHECKING(for gspawn implementation)
1665 case "$host" in
1666   *-*-mingw*)
1667     GSPAWN=gspawn-win32.lo
1668     ;;
1669   *)
1670     GSPAWN=gspawn.lo
1671     ;;
1672 esac
1673 AC_MSG_RESULT($GSPAWN)
1674 AC_SUBST(GSPAWN)
1675
1676 dnl *************************
1677 dnl *** GIOChannel checks ***
1678 dnl *************************
1679
1680 AC_MSG_CHECKING(for GIOChannel implementation)
1681 case "$host" in
1682   *-*-mingw*)
1683     GIO=giowin32.lo
1684     ;;
1685   *)
1686     GIO=giounix.lo
1687     ;;
1688 esac
1689 AC_MSG_RESULT($GIO)
1690 AC_SUBST(GIO)
1691
1692 dnl *********************************
1693 dnl *** Directory for GIO modules ***
1694 dnl *********************************
1695
1696 AC_ARG_WITH(gio-module-dir,
1697            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1698                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1699            [],
1700            [with_gio_module_dir='${libdir}/gio/modules'])
1701 GIO_MODULE_DIR=$with_gio_module_dir
1702 AC_SUBST(GIO_MODULE_DIR)
1703
1704 dnl **********************************
1705 dnl *** Check for libselinux (GIO) ***
1706 dnl **********************************
1707 AC_ARG_ENABLE(selinux,
1708               AS_HELP_STRING([--disable-selinux],
1709                              [build without selinux support]))
1710 msg_selinux=no
1711 SELINUX_LIBS=
1712 AS_IF([ test "x$enable_selinux" != "xno"], [
1713
1714  AC_CHECK_LIB(selinux, is_selinux_enabled,
1715    [AC_CHECK_HEADERS(selinux/selinux.h,
1716      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1717        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1718         SELINUX_LIBS="-lselinux"
1719         msg_selinux=yes])
1720      ])
1721    ])
1722 ])
1723 AC_SUBST(SELINUX_LIBS)
1724
1725 dnl *****************************
1726 dnl ** Check for inotify (GIO) **
1727 dnl *****************************
1728 inotify_support=no
1729 AC_CHECK_HEADERS([sys/inotify.h],
1730 [
1731         inotify_support=yes
1732         AC_CHECK_FUNCS(inotify_init1)
1733 ])
1734
1735 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1736
1737 dnl ****************************
1738 dnl ** Check for kqueue (GIO) **
1739 dnl ****************************
1740 kqueue_support=no
1741 AC_CHECK_HEADERS([sys/event.h],
1742 [
1743         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1744 ])
1745
1746 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1747
1748 dnl *********************************
1749 dnl ** Check for Solaris FEN (GIO) **
1750 dnl *********************************
1751 fen_support=no
1752 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1753 #include <port.h>
1754 #ifndef PORT_SOURCE_FILE
1755 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1756 #endif
1757 int main() { return 0; } ]])],
1758 [
1759         fen_support=yes
1760 ],)
1761
1762 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1763
1764 dnl ****************************
1765 dnl *** Checks for FAM (GIO) ***
1766 dnl ****************************
1767
1768 should_disable_fam=no
1769
1770 AC_ARG_ENABLE(fam,
1771               AS_HELP_STRING([--disable-fam],
1772                              [don't use fam for file system monitoring]),
1773                          [
1774                                 if test "x$enable_fam" = "xno"; then
1775                                         should_disable_fam=yes
1776                                 fi
1777                          ]
1778                          )
1779 fam_support=no
1780 FAM_LIBS=
1781 if test "x$should_disable_fam" = "xno"; then
1782 AC_CHECK_LIB(fam, FAMOpen,
1783   [AC_CHECK_HEADERS(fam.h,
1784     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1785      AC_CHECK_LIB(fam, FAMNoExists,
1786                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1787      FAM_LIBS="-lfam"]
1788      fam_support=yes,
1789     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1790   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1791 AC_SUBST(FAM_LIBS)
1792 fi
1793 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1794
1795
1796 dnl *****************************
1797 dnl *** Check for xattr (GIO) ***
1798 dnl *****************************
1799 AC_ARG_ENABLE(xattr,
1800               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1801 msg_xattr=no
1802 XATTR_LIBS=
1803 AS_IF([ test "x$enable_xattr" != "xno"], [
1804
1805 dnl either glibc or libattr can provide xattr support
1806
1807 dnl for both of them, we check for getxattr being in
1808 dnl the library and a valid xattr header.
1809
1810 dnl try glibc
1811  AC_CHECK_LIB(c, getxattr,
1812    [AC_CHECK_HEADERS(sys/xattr.h,
1813      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1814       msg_xattr=yes])
1815    ])
1816
1817   AS_IF([ test "x$msg_xattr" != "xyes"], [
1818 dnl   failure. try libattr
1819    AC_CHECK_LIB(attr, getxattr,
1820       [AC_CHECK_HEADERS(attr/xattr.h,
1821        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1822         XATTR_LIBS="-lattr"
1823         msg_xattr=yes])
1824       ])
1825   ])
1826
1827   AS_IF([ test "x$msg_xattr" = "xyes"], [
1828     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1829     AC_TRY_COMPILE([
1830       #include <stdio.h>
1831       #ifdef HAVE_SYS_TYPES_H
1832       #include <sys/types.h>
1833       #endif
1834       #ifdef HAVE_SYS_XATTR_H
1835       #include <sys/xattr.h>
1836       #elif HAVE_ATTR_XATTR_H
1837       #include <attr/xattr.h>
1838       #endif
1839     ],
1840     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1841     [
1842       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1843       AC_MSG_RESULT([yes])
1844     ],
1845     [AC_MSG_RESULT([no])]
1846     )
1847   ])
1848 ])
1849 AC_SUBST(XATTR_LIBS)
1850
1851 dnl ************************
1852 dnl *** check for libelf ***
1853 dnl ************************
1854 AC_ARG_ENABLE(libelf,
1855               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1856 AS_IF([ test "x$enable_libelf" != "xno"],[
1857 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1858 AS_IF([ test $have_libelf = maybe ], [
1859   glib_save_LIBS=$LIBS
1860   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1861   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1862   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1863   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1864   LIBS=$glib_save_LIBS
1865
1866   if test $have_libelf != no; then
1867     LIBELF_LIBS=-lelf
1868     have_libelf=yes
1869   fi
1870 ])
1871 ])
1872
1873 if test x$have_libelf = xyes; then
1874   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1875 fi
1876
1877 dnl ****************************************
1878 dnl *** platform dependent source checks ***
1879 dnl ****************************************
1880
1881 AC_MSG_CHECKING(for platform-dependent source)
1882 case "$host" in
1883   *-*-cygwin*|*-*-mingw*)
1884     PLATFORMDEP=gwin32.lo
1885     ;;
1886   *)
1887     PLATFORMDEP=
1888     ;;
1889 esac
1890 AC_MSG_RESULT($PLATFORMDEP)
1891 AC_SUBST(PLATFORMDEP)
1892
1893 AC_MSG_CHECKING([whether to compile timeloop])
1894 case "$host" in
1895   *-*-cygwin*|*-*-mingw*|*-*-minix)
1896     enable_timeloop=no
1897     ;;
1898   *)
1899     enable_timeloop=yes
1900     ;;
1901 esac
1902 AC_MSG_RESULT($enable_timeloop)
1903 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1904
1905 AC_MSG_CHECKING([if building for some Win32 platform])
1906 case "$host" in
1907   *-*-mingw*|*-*-cygwin*)
1908     platform_win32=yes
1909     ;;
1910   *)
1911     platform_win32=no
1912     ;;
1913 esac
1914 AC_MSG_RESULT($platform_win32)
1915 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1916
1917 dnl ***********************
1918 dnl *** g_thread checks ***
1919 dnl ***********************
1920
1921 AC_ARG_WITH(threads,
1922            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1923                            [specify a thread implementation to use])],
1924            [],
1925            [with_threads=yes])
1926
1927 dnl error and warning message
1928 dnl *************************
1929
1930 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1931
1932 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1933                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1934                 compilation now, but then your programs might not work.
1935                 Please provide information on how it is done on your system."
1936
1937 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1938                  "
1939
1940 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1941                   provide information on your thread implementation."
1942
1943 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1944                 functions will not be MT-safe during their first call because
1945                 there is no working 'getpwuid_r' on your system."
1946
1947 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1948                 because there is no 'localtime_r' on your system."
1949
1950 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1951                 linking threaded applications. As GLib cannot do that
1952                 automatically, you will get an linkg error everytime you are
1953                 not using the right compiler. In that case you have to relink
1954                 with the right compiler. Ususally just '_r' is appended
1955                 to the compiler name."
1956
1957 dnl determination of thread implementation
1958 dnl ***************************************
1959
1960 AC_MSG_CHECKING(for thread implementation)
1961
1962 have_threads=no
1963 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1964         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1965         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1966         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1967         glib_save_CPPFLAGS="$CPPFLAGS"
1968         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1969         AS_IF([ test "x$have_threads" = xno], [
1970                 AC_TRY_COMPILE([#include <pthread.h>],
1971                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1972                         have_threads=posix)
1973         ])
1974         # Tru64Unix requires -pthread to find pthread.h. See #103020
1975         CPPFLAGS="$CPPFLAGS -pthread"
1976         if test "x$have_threads" = xno; then
1977         AC_TRY_COMPILE([#include <pthread.h>],
1978                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1979                        have_threads=posix)
1980         fi
1981         CPPFLAGS="$glib_save_CPPFLAGS"
1982 ])
1983 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1984         case $host in
1985                 *-*-mingw*)
1986                 have_threads=win32
1987                 ;;
1988         esac
1989 fi
1990
1991 if test "x$have_threads" = xno; then
1992         AC_MSG_RESULT(none available)
1993         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1994 else
1995         AC_MSG_RESULT($have_threads)
1996 fi
1997
1998
1999 dnl determination of G_THREAD_CFLAGS
2000 dnl ********************************
2001
2002 G_THREAD_LIBS=
2003 G_THREAD_LIBS_EXTRA=
2004 G_THREAD_CFLAGS=
2005
2006 dnl
2007 dnl Test program for basic POSIX threads functionality
2008 dnl
2009 m4_define([glib_thread_test],[
2010 #include <pthread.h>
2011 int check_me = 0;
2012 void* func(void* data) {check_me = 42; return &check_me;}
2013 int main()
2014  { pthread_t t;
2015    void *ret;
2016    pthread_create (&t, $1, func, 0);
2017    pthread_join (t, &ret);
2018    return (check_me != 42 || ret != &check_me);
2019 }])
2020
2021 AS_IF([ test x"$have_threads" = xposix], [
2022   # First we test for posix, whether -pthread or -pthreads do the trick as
2023   # both CPPFLAG and LIBS.
2024   # One of them does for most gcc versions and some other platforms/compilers
2025   # too and could be considered as the canonical way to go.
2026   case $host in
2027     *-*-cygwin*|*-*-darwin*)
2028        # skip cygwin and darwin -pthread or -pthreads test
2029        ;;
2030     *-solaris*)
2031       # These compiler/linker flags work with both Sun Studio and gcc
2032       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2033       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2034       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2035       G_THREAD_LIBS="-lpthread -lthread"
2036       ;;
2037     *)
2038       for flag in pthread pthreads mt; do
2039         glib_save_CFLAGS="$CFLAGS"
2040         CFLAGS="$CFLAGS -$flag"
2041         AC_TRY_RUN(glib_thread_test(0),
2042                    glib_flag_works=yes,
2043                    glib_flag_works=no,
2044                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2045                                    glib_flag_works=yes,
2046                                    glib_flag_works=no)])
2047         CFLAGS="$glib_save_CFLAGS"
2048         if test $glib_flag_works = yes ; then
2049            G_THREAD_CFLAGS=-$flag
2050         G_THREAD_LIBS=-$flag
2051         break;
2052         fi
2053       done
2054        ;;
2055   esac
2056 ])
2057
2058 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2059
2060   # The canonical -pthread[s] does not work. Try something different.
2061
2062   case $host in
2063         *-aix*)
2064                 if test x"$GCC" = xyes; then
2065                         # GCC 3.0 and above needs -pthread.
2066                         # Should be coverd by the case above.
2067                         # GCC 2.x and below needs -mthreads
2068                         G_THREAD_CFLAGS="-mthreads"
2069                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2070                 else
2071                         # We are probably using the aix compiler. Normaly a
2072                         # program would have to be compiled with the _r variant
2073                         # of the corresponding compiler, but we as GLib cannot
2074                         # do that: but the good news is that for compiling the
2075                         # only difference is the added -D_THREAD_SAFE compile
2076                         # option. This is according to the "C for AIX User's
2077                         # Guide".
2078                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2079                 fi
2080                 ;;
2081         *-dg-dgux*)  # DG/UX
2082                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2083                 ;;
2084         *-sysv5uw7*) # UnixWare 7
2085                 # We are not using gcc with -pthread. Catched above.
2086                 G_THREAD_CFLAGS="-Kthread"
2087                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2088                 ;;
2089         *-mingw*)
2090                 # No flag needed when using MSVCRT.DLL
2091                 G_THREAD_CFLAGS=""
2092                 ;;
2093         *)
2094                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2095                 ;;
2096   esac
2097 ])
2098
2099 # if we are not finding the localtime_r function, then we probably are
2100 # not using the proper multithread flag
2101
2102 glib_save_CPPFLAGS="$CPPFLAGS"
2103 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2104
2105 # First we test, whether localtime_r is declared in time.h
2106 # directly. Then we test whether a macro localtime_r exists, in
2107 # which case localtime_r in the test program is replaced and thus
2108 # if we still find localtime_r in the output, it is not defined as
2109 # a macro.
2110
2111 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2112   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2113                                                            localtime_r(a,b)],
2114                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2115
2116 CPPFLAGS="$glib_save_CPPFLAGS"
2117
2118 AC_MSG_CHECKING(thread related cflags)
2119 AC_MSG_RESULT($G_THREAD_CFLAGS)
2120 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2121
2122 dnl determination of G_THREAD_LIBS
2123 dnl ******************************
2124
2125 AS_IF([test x$have_threads = xposix], [
2126           glib_save_CPPFLAGS="$CPPFLAGS"
2127           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2128           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2129             case $host in
2130               *-aix*)
2131                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2132                 # probably using the aix compiler.
2133                 AC_MSG_WARN($AIX_COMPILE_INFO)
2134                 ;;
2135               *)
2136                 G_THREAD_LIBS=error
2137                 glib_save_LIBS="$LIBS"
2138                 for thread_lib in "" pthread pthread32 pthreads thread; do
2139                         if test x"$thread_lib" = x; then
2140                                 add_thread_lib=""
2141                                 IN=""
2142                         else
2143                                 add_thread_lib="-l$thread_lib"
2144                                 IN=" in -l$thread_lib"
2145                         fi
2146                         if test x"$have_threads" = xposix; then
2147                                 defattr=0
2148                         else
2149                                 defattr=pthread_attr_default
2150                         fi
2151
2152                         LIBS="$add_thread_lib $glib_save_LIBS"
2153
2154                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2155                         AC_TRY_RUN(glib_thread_test($defattr),
2156                                    glib_result=yes,
2157                                    glib_result=no,
2158                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2159                                                    glib_result=yes,
2160                                                    glib_result=no)])
2161                         AC_MSG_RESULT($glib_result)
2162
2163                         if test "$glib_result" = "yes" ; then
2164                           G_THREAD_LIBS="$add_thread_lib"
2165                           break
2166                         fi
2167                 done
2168                 if test "x$G_THREAD_LIBS" = xerror; then
2169                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2170                 fi
2171                 LIBS="$glib_save_LIBS"
2172                 ;;
2173             esac
2174           ])
2175
2176           g_threads_impl="POSIX"
2177           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2178           CPPFLAGS="$glib_save_CPPFLAGS"
2179 ], [test x$have_threads = xwin32], [
2180            g_threads_impl="WIN32"
2181 ], [
2182            g_threads_impl="NONE"
2183            G_THREAD_LIBS=error
2184 ])
2185
2186 if test "x$G_THREAD_LIBS" = xerror; then
2187         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2188 fi
2189
2190 case $host in
2191   *-*-beos*)
2192     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2193     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2194     ;;
2195   *)
2196     ;;
2197 esac
2198
2199 AC_MSG_CHECKING(thread related libraries)
2200 AC_MSG_RESULT($G_THREAD_LIBS)
2201
2202 dnl check for mt safe function variants and some posix functions
2203 dnl ************************************************************
2204
2205 glib_save_LIBS="$LIBS"
2206 # we are not doing the following for now, as this might require glib
2207 # to always be linked with the thread libs on some platforms.
2208 # LIBS="$LIBS $G_THREAD_LIBS"
2209 AC_CHECK_FUNCS(localtime_r gmtime_r)
2210 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2211         AC_CACHE_CHECK([for posix getpwuid_r],
2212                 ac_cv_func_posix_getpwuid_r,
2213                 [AC_TRY_RUN([
2214 #include <errno.h>
2215 #include <pwd.h>
2216 int main () {
2217     char buffer[10000];
2218     struct passwd pwd, *pwptr = &pwd;
2219     int error;
2220     errno = 0;
2221     error = getpwuid_r (0, &pwd, buffer,
2222                         sizeof (buffer), &pwptr);
2223    return (error < 0 && errno == ENOSYS)
2224            || error == ENOSYS;
2225 }                               ],
2226                         [ac_cv_func_posix_getpwuid_r=yes],
2227                         [ac_cv_func_posix_getpwuid_r=no])])
2228         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2229         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2230                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2231                         [Have POSIX function getpwuid_r])
2232         else
2233                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2234                         ac_cv_func_nonposix_getpwuid_r,
2235                         [AC_TRY_LINK([#include <pwd.h>],
2236                                 [char buffer[10000];
2237                                 struct passwd pwd;
2238                                 getpwuid_r (0, &pwd, buffer,
2239                                                 sizeof (buffer));],
2240                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2241                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2242                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2243                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2244                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2245                                 [Have non-POSIX function getpwuid_r])
2246                 fi
2247         fi
2248 ])
2249 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2250         AC_CACHE_CHECK([for posix getgrgid_r],
2251                 ac_cv_func_posix_getgrgid_r,
2252                 [AC_TRY_RUN([
2253 #include <errno.h>
2254 #include <grp.h>
2255 int main () {
2256     char buffer[10000];
2257     struct group grp, *grpptr = &grp;
2258     int error;
2259     errno = 0;
2260     error = getgrgid_r (0, &grp, buffer,
2261                         sizeof (buffer), &grpptr);
2262    return (error < 0 && errno == ENOSYS)
2263            || error == ENOSYS;
2264 }                              ],
2265                        [ac_cv_func_posix_getgrgid_r=yes],
2266                        [ac_cv_func_posix_getgrgid_r=no])])
2267         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2268         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2269                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2270                         [Have POSIX function getgrgid_r])
2271         ], [
2272                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2273                         ac_cv_func_nonposix_getgrgid_r,
2274                         [AC_TRY_LINK([#include <grp.h>],
2275                                 [char buffer[10000];
2276                                 struct group grp;
2277                                 getgrgid_r (0, &grp, buffer,
2278                                 sizeof (buffer));],
2279                         [ac_cv_func_nonposix_getgrgid_r=yes],
2280                         [ac_cv_func_nonposix_getgrgid_r=no])])
2281                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2282                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2283                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2284                                 [Have non-POSIX function getgrgid_r])
2285                 fi
2286         ])
2287 ])
2288 LIBS="$G_THREAD_LIBS $LIBS"
2289 AS_IF([ test x"$have_threads" = xposix], [
2290         glib_save_CPPFLAGS="$CPPFLAGS"
2291         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2292         # This is not AC_CHECK_FUNC to also work with function
2293         # name mangling in header files.
2294         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2295         AC_LINK_IFELSE(
2296             [AC_LANG_PROGRAM(
2297                 [#include <pthread.h>],
2298                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2299             [AC_MSG_RESULT(yes)
2300              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2301                 [Have function pthread_attr_setstacksize])],
2302             [AC_MSG_RESULT(no)])
2303         AC_MSG_CHECKING(for pthread_condattr_setclock)
2304         AC_LINK_IFELSE(
2305             [AC_LANG_PROGRAM(
2306                 [#include <pthread.h>],
2307                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2308             [AC_MSG_RESULT(yes)
2309              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2310                 [Have function pthread_condattr_setclock])],
2311             [AC_MSG_RESULT(no)])
2312         CPPFLAGS="$glib_save_CPPFLAGS"
2313 ])
2314
2315 LIBS="$glib_save_LIBS"
2316
2317 # now spit out all the warnings.
2318 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2319    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2320         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2321 fi
2322 if test "$ac_cv_func_localtime_r" != "yes"; then
2323         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2324 fi
2325
2326 #
2327 # Hack to deal with:
2328 #
2329 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2330 #     building shared libraries with linux.
2331 #  b) FreeBSD doesn't do this either.
2332 #
2333 case $host in
2334   *-*-freebsd*|*-*-linux*)
2335     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2336     ;;
2337   *-*-openbsd*)
2338     LDFLAGS="$LDFLAGS -pthread"
2339     ;;
2340   *)
2341     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2342     ;;
2343 esac
2344
2345 AC_SUBST(G_THREAD_CFLAGS)
2346 AC_SUBST(G_THREAD_LIBS)
2347 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2348 AC_SUBST(G_THREAD_LIBS_EXTRA)
2349
2350 AC_CHECK_FUNCS(clock_gettime, [], [
2351   AC_CHECK_LIB(rt, clock_gettime, [
2352     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2353     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2354     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2355   ])
2356 ])
2357
2358
2359 dnl ************************
2360 dnl *** g_atomic_* tests ***
2361 dnl ************************
2362
2363 dnl We need to decide at configure time if GLib will use real atomic
2364 dnl operations ("lock free") or emulated ones with a mutex.  This is
2365 dnl because we must put this information in glibconfig.h so we know if
2366 dnl it is safe or not to inline using compiler intrinsics directly from
2367 dnl the header.
2368 dnl
2369 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2370 dnl user is interested in knowing if they can use the atomic ops across
2371 dnl processes.
2372 dnl
2373 dnl We can currently support the atomic ops natively when building GLib
2374 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2375 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2376 dnl we are using GCC.
2377 dnl
2378 dnl Note that the atomic ops are only available with GCC on x86 when
2379 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2380 dnl not available but would be available given the right flags, we want
2381 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2382 dnl that then to silently fall back on emulated atomic ops just because
2383 dnl the user had the wrong build environment.
2384
2385 dnl We may add other compilers here in the future...
2386
2387 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2388   AC_TRY_COMPILE([],
2389                  [volatile int atomic = 2;\
2390                   __sync_bool_compare_and_swap (&atomic, 2, 3);],
2391                  [glib_cv_g_atomic_lock_free=yes],
2392                  [glib_cv_g_atomic_lock_free=no])])
2393
2394 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2395   SAVE_CFLAGS="${CFLAGS}"
2396   CFLAGS="-march=i486"
2397   AC_TRY_COMPILE([],
2398                  [volatile int atomic = 2;\
2399                   __sync_bool_compare_and_swap (&atomic, 2, 3);],
2400                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2401                  [])
2402   CFLAGS="${SAVE_CFLAGS}"
2403 fi
2404
2405 # Some compilers support atomic operations but do not define
2406 # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2407 if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2408   AC_TRY_COMPILE([],
2409                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2410                  [],
2411                  [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2412 fi
2413
2414 dnl We need a more robust approach here...
2415 case $host_cpu in
2416   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2417     glib_memory_barrier_needed=no
2418     ;;
2419   sparc*|alpha*|powerpc*|ia64)
2420     glib_memory_barrier_needed=yes
2421     ;;
2422   *)
2423     glib_memory_barrier_needed=yes
2424     ;;
2425 esac
2426
2427 dnl ************************
2428 dnl ** Check for futex(2) **
2429 dnl ************************
2430 AC_CACHE_CHECK(for futex(2) system call,
2431     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2432 #include <linux/futex.h>
2433 #include <sys/syscall.h>
2434 #include <unistd.h>
2435 ],[
2436 int
2437 main (void)
2438 {
2439   /* it is not like this actually runs or anything... */
2440   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2441   return 0;
2442 }
2443 ])],glib_cv_futex=yes,glib_cv_futex=no))
2444 if test x"$glib_cv_futex" = xyes; then
2445   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2446 fi
2447
2448 AC_CACHE_CHECK(for eventfd(2) system call,
2449     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2450 #include <sys/eventfd.h>
2451 #include <unistd.h>
2452 ],[
2453 int
2454 main (void)
2455 {
2456   eventfd (0, EFD_CLOEXEC);
2457   return 0;
2458 }
2459 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2460 if test x"$glib_cv_eventfd" = x"yes"; then
2461   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2462 fi
2463 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2464
2465 dnl ****************************************
2466 dnl *** GLib POLL* compatibility defines ***
2467 dnl ****************************************
2468
2469 glib_poll_includes=["
2470 #include <sys/types.h>
2471 #include <sys/poll.h>
2472 "]
2473
2474 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2475    test $ac_cv_header_sys_poll_h = yes ], [
2476   glib_failed=false
2477   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2478   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2479   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2480   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2481   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2482   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2483   if $glib_failed ; then
2484     AC_MSG_ERROR([Could not determine values for POLL* constants])
2485   fi
2486 ], [
2487   glib_cv_value_POLLIN=1
2488   glib_cv_value_POLLOUT=4
2489   glib_cv_value_POLLPRI=2
2490   glib_cv_value_POLLERR=8
2491   glib_cv_value_POLLHUP=16
2492   glib_cv_value_POLLNVAL=32
2493 ])
2494
2495 AC_MSG_CHECKING([for broken poll])
2496 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2497         #include <stdlib.h>
2498         #include <fcntl.h>
2499         #include <poll.h>
2500         #ifdef HAVE_SYS_POLL_H
2501         #include <sys/poll.h>
2502         #endif
2503         int main(void) {
2504           struct pollfd fds[1];
2505           int fd;
2506           fd = open("/dev/null", 1);
2507           fds[0].fd = fd;
2508           fds[0].events = POLLIN;
2509           fds[0].revents = 0;
2510           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2511                 exit(1);  /* Does not work for devices -- fail */
2512           }
2513           exit(0);
2514         }]])],
2515   [broken_poll=no],
2516   [broken_poll=yes
2517    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2518   [broken_poll="no (cross compiling)"])
2519 AC_MSG_RESULT($broken_poll)
2520
2521 dnl *********************
2522 dnl *** GRegex checks ***
2523 dnl *********************
2524
2525 PCRE_REQUIRED_VERSION=8.13
2526
2527 # Check if we should use the internal or the system-supplied pcre
2528 AC_ARG_WITH(pcre,
2529             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2530                             [whether to use system PCRE [default=internal]])])
2531
2532 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2533
2534 AS_IF([ test "x$with_pcre" = xsystem], [
2535   PKG_CHECK_MODULES(PCRE,
2536                     libpcre >= $PCRE_REQUIRED_VERSION)
2537   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2538                   glib_save_CFLAGS="$CFLAGS"
2539                   glib_save_LIBS="$LIBS"
2540                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2541                   AC_TRY_RUN([#include <pcre.h>
2542                               int main () {
2543                                 int support;
2544                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2545                                 if (!support)
2546                                   return 1;
2547                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2548                                 if (!support)
2549                                   return 1;
2550                                 return 0;
2551                               }],
2552                   glib_cv_pcre_has_unicode=yes,
2553                   glib_cv_pcre_has_unicode=no,
2554                   glib_cv_pcre_has_unicode=yes)
2555                   CFLAGS="$glib_save_CFLAGS"
2556                   LIBS="$glib_save_LIBS"
2557       ])
2558   if test "$glib_cv_pcre_has_unicode" = "no"; then
2559     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2560   fi
2561   AC_SUBST(PCRE_CFLAGS)
2562   AC_SUBST(PCRE_LIBS)
2563   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2564   PCRE_REQUIRES=libpcre
2565   AC_SUBST(PCRE_REQUIRES)
2566 ], [
2567   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2568   AS_IF([ test x"$GCC" = xyes], [
2569     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2570     save_CFLAGS="$CFLAGS"
2571     CFLAGS="$CFLAGS -Wno-pointer-sign"
2572     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2573                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2574     CFLAGS="$save_CFLAGS"
2575   ])
2576 ])
2577 AC_SUBST(PCRE_WARN_CFLAGS)
2578
2579 dnl **********************
2580 dnl *** Win32 API libs ***
2581 dnl **********************
2582
2583 case $host in
2584   *-*-cygwin*)
2585         G_LIBS_EXTRA="-luser32 -lkernel32"
2586     ;;
2587   *-*-mingw*)
2588         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2589     ;;
2590   *)
2591         G_LIBS_EXTRA=""
2592     ;;
2593 esac
2594 AC_SUBST(G_LIBS_EXTRA)
2595
2596 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2597 dnl since we need it for g_iconv()
2598
2599 AC_MSG_CHECKING([for EILSEQ])
2600 AC_TRY_COMPILE([
2601 #include <errno.h>
2602 ],
2603 [
2604 int error = EILSEQ;
2605 ], have_eilseq=yes, have_eilseq=no);
2606 AC_MSG_RESULT($have_eilseq)
2607
2608 dnl ******************************************************************
2609 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2610 dnl *** glib-compile-schemas in PATH                               ***
2611 dnl ******************************************************************
2612
2613 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2614
2615 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2616   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2617   if test x$GLIB_GENMARSHAL = xno; then
2618     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2619   fi
2620
2621   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2622   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2623     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2624   fi
2625
2626   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2627   if test x$GLIB_COMPILE_RESOURCES = xno; then
2628     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2629   fi
2630 ])
2631
2632 dnl **************************
2633 dnl *** Checks for gtk-doc ***
2634 dnl **************************
2635 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2636 # it on it's own line.
2637 m4_ifdef([GTK_DOC_CHECK], [
2638 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2639 ],[
2640 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2641 ])
2642
2643 AC_ARG_ENABLE(man,
2644               [AS_HELP_STRING([--enable-man],
2645                               [generate man pages [default=auto]])],,
2646               enable_man=maybe)
2647
2648 AS_IF([test "$enable_man" != no], [
2649   AC_PATH_PROG([XSLTPROC], [xsltproc])
2650   AS_IF([test -z "$XSLTPROC"], [
2651     AS_IF([test "$enable_man" = yes], [
2652       AC_MSG_ERROR([xsltproc is required for --enable-man])
2653     ])
2654     enable_man=no
2655   ])
2656 ])
2657
2658 AS_IF([ test "$enable_man" != no ], [
2659   dnl check for DocBook DTD in the local catalog
2660   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2661      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2662   AS_IF([test "$have_docbook_dtd" != yes], [
2663     AS_IF([test "$enable_man" = yes ], [
2664       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2665     ])
2666     enable_man=no
2667   ])
2668 ])
2669
2670 AS_IF([test "$enable_man" != no], [
2671   dnl check for DocBook XSL stylesheets in the local catalog
2672   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2673      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2674   AS_IF([ test "$have_docbook_dtd" != yes ], [
2675     AS_IF([ test "$enable_man" = yes ], [
2676       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2677     ])
2678     enable_man=no
2679   ])
2680 ])
2681
2682 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2683
2684 AC_MSG_CHECKING([whether to generate man pages])
2685 AS_IF([ test "$enable_man" != no ], [
2686   AC_MSG_RESULT([yes])
2687 ], [
2688   AC_MSG_RESULT([no])
2689 ])
2690
2691 dnl
2692 dnl Tracing
2693 dnl
2694
2695 AC_ARG_ENABLE([dtrace],
2696              [AS_HELP_STRING([--enable-dtrace],
2697                               [include tracing support for dtrace])])
2698 have_dtrace=no
2699 AC_MSG_CHECKING([whether to include dtrace tracing support])
2700 AS_IF([ test "x$enable_dtrace" != xno], [
2701   if test x$glib_have_carbon = xyes; then
2702     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2703   else
2704     AC_MSG_RESULT([yes])
2705     AC_CHECK_PROGS(DTRACE, dtrace)
2706     if test -z "$DTRACE"; then
2707       if test "x$enable_dtrace" = xyes; then
2708         AC_MSG_ERROR([dtrace not found])
2709       fi
2710     else
2711       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2712                       [if test "x$enable_dtrace" = xyes; then
2713                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2714                        fi])
2715     fi
2716   fi
2717 ], [
2718   AC_MSG_RESULT([no])
2719 ])
2720 if test "x$have_dtrace" = xyes; then
2721   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2722 fi
2723 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2724
2725 AC_MSG_CHECKING([whether to include systemtap tracing support])
2726 AC_ARG_ENABLE([systemtap],
2727              [AS_HELP_STRING([--enable-systemtap],
2728                               [include tracing support for systemtap])])
2729 have_systemtap=no
2730 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2731   have_systemtap=yes
2732 fi
2733 AC_MSG_RESULT(${have_systemtap})
2734
2735 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2736
2737 AC_ARG_WITH([tapset-install-dir],
2738             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2739                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2740             [if test "x${withval}" = x; then
2741                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2742              else
2743                ABS_TAPSET_DIR="${withval}"
2744               fi],
2745             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2746 AC_SUBST(ABS_TAPSET_DIR)
2747
2748 dnl ************************************
2749 dnl *** Enable lcov coverage reports ***
2750 dnl ************************************
2751
2752 AC_ARG_ENABLE(gcov,
2753   AS_HELP_STRING([--enable-gcov],
2754                  [enable coverage testing with gcov]),
2755   [use_gcov=$enableval], [use_gcov=no])
2756
2757 AS_IF([ test "x$use_gcov" = "xyes"], [
2758   dnl we need gcc:
2759   if test "$GCC" != "yes"; then
2760     AC_MSG_ERROR([GCC is required for --enable-gcov])
2761   fi
2762
2763   dnl Check if ccache is being used
2764   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2765   case `$SHTOOL path $CC` in
2766     *ccache*[)] gcc_ccache=yes;;
2767     *[)] gcc_ccache=no;;
2768   esac
2769
2770   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2771     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2772   fi
2773
2774   ltp_version_list="1.6 1.7 1.8 1.9"
2775   AC_CHECK_PROG(LTP, lcov, lcov)
2776   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2777
2778   AS_IF([ test "$LTP" ], [
2779     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2780       glib_cv_ltp_version=invalid
2781       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2782       for ltp_check_version in $ltp_version_list; do
2783         if test "$ltp_version" = "$ltp_check_version"; then
2784           glib_cv_ltp_version="$ltp_check_version (ok)"
2785         fi
2786       done
2787     ])
2788   ], [
2789     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2790     AC_MSG_ERROR([$ltp_msg])
2791   ])
2792
2793   case $glib_cv_ltp_version in
2794     ""|invalid[)]
2795       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2796       AC_MSG_ERROR([$ltp_msg])
2797       LTP="exit 0;"
2798       ;;
2799   esac
2800
2801   if test -z "$LTP_GENHTML"; then
2802     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2803   fi
2804
2805   dnl Remove all optimization flags from CFLAGS
2806   changequote({,})
2807   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2808   changequote([,])
2809
2810   dnl Add the special gcc flags
2811   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2812   LDFLAGS="$LDFLAGS -lgcov"
2813 ])
2814
2815 dnl ******************************
2816 dnl *** output the whole stuff ***
2817 dnl ******************************
2818
2819 dnl this section will only be run if config.status is invoked with no
2820 dnl arguments, or with "glib/glibconfig.h" as an argument.
2821 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2822 [
2823         outfile=glib/glibconfig.h-tmp
2824         cat > $outfile <<\_______EOF
2825 /* glibconfig.h
2826  *
2827  * This is a generated file.  Please modify 'configure.ac'
2828  */
2829
2830 #ifndef __GLIBCONFIG_H__
2831 #define __GLIBCONFIG_H__
2832
2833 #include <glib/gmacros.h>
2834
2835 _______EOF
2836
2837         if test x$glib_limits_h = xyes; then
2838           echo '#include <limits.h>' >> $outfile
2839         fi
2840         if test x$glib_float_h = xyes; then
2841           echo '#include <float.h>' >> $outfile
2842         fi
2843         if test x$glib_values_h = xyes; then
2844           echo '#include <values.h>' >> $outfile
2845         fi
2846         if test "$glib_header_alloca_h" = "yes"; then
2847           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2848         fi
2849         if test x$glib_sys_poll_h = xyes; then
2850           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2851         fi
2852         if test x$glib_included_printf != xyes; then
2853           echo "
2854 /* Specifies that GLib's g_print*() functions wrap the
2855  * system printf functions.  This is useful to know, for example,
2856  * when using glibc's register_printf_function().
2857  */" >> $outfile
2858           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2859         fi
2860
2861         cat >> $outfile <<_______EOF
2862
2863 G_BEGIN_DECLS
2864
2865 #define G_MINFLOAT      $glib_mf
2866 #define G_MAXFLOAT      $glib_Mf
2867 #define G_MINDOUBLE     $glib_md
2868 #define G_MAXDOUBLE     $glib_Md
2869 #define G_MINSHORT      $glib_ms
2870 #define G_MAXSHORT      $glib_Ms
2871 #define G_MAXUSHORT     $glib_Mus
2872 #define G_MININT        $glib_mi
2873 #define G_MAXINT        $glib_Mi
2874 #define G_MAXUINT       $glib_Mui
2875 #define G_MINLONG       $glib_ml
2876 #define G_MAXLONG       $glib_Ml
2877 #define G_MAXULONG      $glib_Mul
2878
2879 _______EOF
2880
2881
2882         ### this should always be true in a modern C/C++ compiler
2883         cat >>$outfile <<_______EOF
2884 typedef signed char gint8;
2885 typedef unsigned char guint8;
2886 _______EOF
2887
2888
2889         if test -n "$gint16"; then
2890           cat >>$outfile <<_______EOF
2891 typedef signed $gint16 gint16;
2892 typedef unsigned $gint16 guint16;
2893 #define G_GINT16_MODIFIER $gint16_modifier
2894 #define G_GINT16_FORMAT $gint16_format
2895 #define G_GUINT16_FORMAT $guint16_format
2896 _______EOF
2897         fi
2898
2899
2900         if test -n "$gint32"; then
2901           cat >>$outfile <<_______EOF
2902 typedef signed $gint32 gint32;
2903 typedef unsigned $gint32 guint32;
2904 #define G_GINT32_MODIFIER $gint32_modifier
2905 #define G_GINT32_FORMAT $gint32_format
2906 #define G_GUINT32_FORMAT $guint32_format
2907 _______EOF
2908         fi
2909
2910         cat >>$outfile <<_______EOF
2911 #define G_HAVE_GINT64 1          /* deprecated, always true */
2912
2913 ${glib_extension}typedef signed $gint64 gint64;
2914 ${glib_extension}typedef unsigned $gint64 guint64;
2915
2916 #define G_GINT64_CONSTANT(val)  $gint64_constant
2917 #define G_GUINT64_CONSTANT(val) $guint64_constant
2918 _______EOF
2919
2920         if test x$gint64_format != x ; then
2921           cat >>$outfile <<_______EOF
2922 #define G_GINT64_MODIFIER $gint64_modifier
2923 #define G_GINT64_FORMAT $gint64_format
2924 #define G_GUINT64_FORMAT $guint64_format
2925 _______EOF
2926         else
2927           cat >>$outfile <<_______EOF
2928 #undef G_GINT64_MODIFIER
2929 #undef G_GINT64_FORMAT
2930 #undef G_GUINT64_FORMAT
2931 _______EOF
2932         fi
2933
2934         cat >>$outfile <<_______EOF
2935
2936 #define GLIB_SIZEOF_VOID_P $glib_void_p
2937 #define GLIB_SIZEOF_LONG   $glib_long
2938 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2939
2940 _______EOF
2941
2942         cat >>$outfile <<_______EOF
2943 typedef signed $glib_size_type_define gssize;
2944 typedef unsigned $glib_size_type_define gsize;
2945 #define G_GSIZE_MODIFIER $gsize_modifier
2946 #define G_GSSIZE_FORMAT $gssize_format
2947 #define G_GSIZE_FORMAT $gsize_format
2948
2949 #define G_MAXSIZE       G_MAXU$glib_msize_type
2950 #define G_MINSSIZE      G_MIN$glib_msize_type
2951 #define G_MAXSSIZE      G_MAX$glib_msize_type
2952
2953 typedef gint64 goffset;
2954 #define G_MINOFFSET     G_MININT64
2955 #define G_MAXOFFSET     G_MAXINT64
2956
2957 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2958 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2959 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2960
2961 _______EOF
2962
2963         if test -z "$glib_unknown_void_p"; then
2964           cat >>$outfile <<_______EOF
2965
2966 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2967 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2968
2969 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2970 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2971
2972 typedef signed $glib_intptr_type_define gintptr;
2973 typedef unsigned $glib_intptr_type_define guintptr;
2974
2975 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2976 #define G_GINTPTR_FORMAT        $gintptr_format
2977 #define G_GUINTPTR_FORMAT       $guintptr_format
2978 _______EOF
2979         else
2980           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2981         fi
2982
2983
2984
2985         cat >>$outfile <<_______EOF
2986 $glib_atexit
2987 $glib_memmove
2988 $glib_defines
2989 $glib_os
2990 $glib_static_compilation
2991
2992 $glib_vacopy
2993
2994 #ifdef  __cplusplus
2995 #define G_HAVE_INLINE   1
2996 #else   /* !__cplusplus */
2997 $glib_inline
2998 #endif  /* !__cplusplus */
2999
3000 #ifdef  __cplusplus
3001 #define G_CAN_INLINE    1
3002 _______EOF
3003
3004         if test x$g_can_inline = xyes ; then
3005                 cat >>$outfile <<_______EOF
3006 #else   /* !__cplusplus */
3007 #define G_CAN_INLINE    1
3008 _______EOF
3009         fi
3010
3011         cat >>$outfile <<_______EOF
3012 #endif
3013
3014 _______EOF
3015
3016         if test x$g_have_iso_c_varargs = xyes ; then
3017                 cat >>$outfile <<_______EOF
3018 #ifndef __cplusplus
3019 # define G_HAVE_ISO_VARARGS 1
3020 #endif
3021 _______EOF
3022         fi
3023         if test x$g_have_iso_cxx_varargs = xyes ; then
3024                 cat >>$outfile <<_______EOF
3025 #ifdef __cplusplus
3026 # define G_HAVE_ISO_VARARGS 1
3027 #endif
3028 _______EOF
3029         fi
3030         if test x$g_have_gnuc_varargs = xyes ; then
3031                 cat >>$outfile <<_______EOF
3032
3033 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3034  * is passed ISO vararg support is turned off, and there is no work
3035  * around to turn it on, so we unconditionally turn it off.
3036  */
3037 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3038 #  undef G_HAVE_ISO_VARARGS
3039 #endif
3040
3041 #define G_HAVE_GNUC_VARARGS 1
3042 _______EOF
3043         fi
3044
3045         case x$g_stack_grows in
3046         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3047         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3048         esac
3049
3050
3051         echo >>$outfile
3052         if test x$g_have_eilseq = xno; then
3053                 cat >>$outfile <<_______EOF
3054 #ifndef EILSEQ
3055 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3056  * The correspondence between this and the corresponding definition
3057  * in libiconv is essential.
3058  */
3059 #  define EILSEQ ENOENT
3060 #endif
3061 _______EOF
3062
3063         fi
3064
3065         if test x$g_have_gnuc_visibility = xyes; then
3066                 cat >>$outfile <<_______EOF
3067 #define G_HAVE_GNUC_VISIBILITY 1
3068 _______EOF
3069         fi
3070                 cat >>$outfile <<_______EOF
3071 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3072 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3073 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3074 #define G_GNUC_INTERNAL __hidden
3075 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3076 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3077 #else
3078 #define G_GNUC_INTERNAL
3079 #endif
3080 _______EOF
3081
3082         echo >>$outfile
3083         cat >>$outfile <<_______EOF
3084 #define G_THREADS_ENABLED
3085 #define G_THREADS_IMPL_$g_threads_impl_def
3086 _______EOF
3087
3088         if test x"$g_memory_barrier_needed" != xno; then
3089           echo >>$outfile
3090           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3091         fi
3092         if test x"$g_atomic_lock_free" = xyes; then
3093           echo >>$outfile
3094           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3095         fi
3096         echo >>$outfile
3097         g_bit_sizes="16 32 64"
3098         for bits in $g_bit_sizes; do
3099           cat >>$outfile <<_______EOF
3100 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3101 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3102 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3103 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3104 _______EOF
3105         done
3106
3107         cat >>$outfile <<_______EOF
3108 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3109 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3110 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3111 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3112 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3113 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3114 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3115 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3116 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3117 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3118 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3119 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3120 #define G_BYTE_ORDER $g_byte_order
3121
3122 #define GLIB_SYSDEF_POLLIN =$g_pollin
3123 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3124 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3125 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3126 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3127 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3128
3129 #define G_MODULE_SUFFIX "$g_module_suffix"
3130
3131 typedef $g_pid_type GPid;
3132
3133 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3134 #define GLIB_SYSDEF_AF_INET $g_af_inet
3135 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3136
3137 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3138 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3139 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3140
3141 G_END_DECLS
3142
3143 #endif /* __GLIBCONFIG_H__ */
3144 _______EOF
3145
3146
3147         if cmp -s $outfile glib/glibconfig.h; then
3148           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3149           rm -f $outfile
3150         else
3151           mv $outfile glib/glibconfig.h
3152         fi
3153 ],[
3154
3155 # Note that if two cases are the same, case goes with the first one.
3156 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3157 # on variable expansion in case labels.  Look at the generated config.status
3158 # for a hint.
3159
3160 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3161   glib_header_alloca_h="$ac_cv_working_alloca_h"
3162 else
3163   glib_header_alloca_h="$ac_cv_header_alloca_h"
3164 fi
3165
3166 case xyes in
3167 x$ac_cv_header_float_h)
3168   glib_float_h=yes
3169   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3170   glib_md=DBL_MIN glib_Md=DBL_MAX
3171   ;;
3172 x$ac_cv_header_values_h)
3173   glib_values_h=yes
3174   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3175   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3176   ;;
3177 esac
3178
3179 case xyes in
3180 x$ac_cv_header_limits_h)
3181   glib_limits_h=yes
3182   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3183   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3184   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3185   ;;
3186 x$ac_cv_header_values_h)
3187   glib_values_h=yes
3188   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3189   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3190   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3191   ;;
3192 esac
3193
3194 if test x$ac_cv_header_sys_poll_h = xyes ; then
3195   glib_sys_poll_h=yes
3196 fi
3197
3198 if test x$enable_included_printf = xyes ; then
3199   glib_included_printf=yes
3200 fi
3201
3202 case 2 in
3203 $ac_cv_sizeof_short)
3204   gint16=short
3205   gint16_modifier='"h"'
3206   gint16_format='"hi"'
3207   guint16_format='"hu"'
3208   ;;
3209 $ac_cv_sizeof_int)
3210   gint16=int
3211   gint16_modifier='""'
3212   gint16_format='"i"'
3213   guint16_format='"u"'
3214   ;;
3215 esac
3216 case 4 in
3217 $ac_cv_sizeof_short)
3218   gint32=short
3219   gint32_modifier='"h"'
3220   gint32_format='"hi"'
3221   guint32_format='"hu"'
3222   ;;
3223 $ac_cv_sizeof_int)
3224   gint32=int
3225   gint32_modifier='""'
3226   gint32_format='"i"'
3227   guint32_format='"u"'
3228   ;;
3229 $ac_cv_sizeof_long)
3230   gint32=long
3231   gint32_modifier='"l"'
3232   gint32_format='"li"'
3233   guint32_format='"lu"'
3234   ;;
3235 esac
3236 case 8 in
3237 $ac_cv_sizeof_int)
3238   gint64=int
3239   gint64_modifier='""'
3240   gint64_format='"i"'
3241   guint64_format='"u"'
3242   glib_extension=
3243   gint64_constant='(val)'
3244   guint64_constant='(val)'
3245   ;;
3246 $ac_cv_sizeof_long)
3247   gint64=long
3248   gint64_modifier='"l"'
3249   gint64_format='"li"'
3250   guint64_format='"lu"'
3251   glib_extension=
3252   gint64_constant='(val##L)'
3253   guint64_constant='(val##UL)'
3254   ;;
3255 $ac_cv_sizeof_long_long)
3256   gint64='long long'
3257   if test -n "$glib_cv_long_long_format"; then
3258     gint64_modifier='"'$glib_cv_long_long_format'"'
3259     gint64_format='"'$glib_cv_long_long_format'i"'
3260     guint64_format='"'$glib_cv_long_long_format'u"'
3261   fi
3262   glib_extension='G_GNUC_EXTENSION '
3263   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3264   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3265   ;;
3266 $ac_cv_sizeof___int64)
3267   gint64='__int64'
3268   if test -n "$glib_cv_long_long_format"; then
3269     gint64_modifier='"'$glib_cv_long_long_format'"'
3270     gint64_format='"'$glib_cv_long_long_format'i"'
3271     guint64_format='"'$glib_cv_long_long_format'u"'
3272   fi
3273   glib_extension=
3274   gint64_constant='(val##i64)'
3275   guint64_constant='(val##ui64)'
3276   ;;
3277 esac
3278 glib_size_t=$ac_cv_sizeof_size_t
3279 glib_size_type_define="$glib_size_type"
3280 glib_void_p=$ac_cv_sizeof_void_p
3281 glib_long=$ac_cv_sizeof_long
3282
3283 case "$glib_size_type" in
3284 short)
3285   gsize_modifier='"h"'
3286   gsize_format='"hu"'
3287   gssize_format='"hi"'
3288   glib_msize_type='SHRT'
3289   ;;
3290 int)
3291   gsize_modifier='""'
3292   gsize_format='"u"'
3293   gssize_format='"i"'
3294   glib_msize_type='INT'
3295   ;;
3296 long)
3297   gsize_modifier='"l"'
3298   gsize_format='"lu"'
3299   gssize_format='"li"'
3300   glib_msize_type='LONG'
3301   ;;
3302 "long long"|__int64)
3303   gsize_modifier='"I64"'
3304   gsize_format='"I64u"'
3305   gssize_format='"I64i"'
3306   glib_msize_type='INT64'
3307   ;;
3308 esac
3309
3310 gintbits=`expr $ac_cv_sizeof_int \* 8`
3311 glongbits=`expr $ac_cv_sizeof_long \* 8`
3312 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3313
3314 case $ac_cv_sizeof_void_p in
3315 $ac_cv_sizeof_int)
3316   glib_intptr_type_define=int
3317   gintptr_modifier='""'
3318   gintptr_format='"i"'
3319   guintptr_format='"u"'
3320   glib_gpi_cast='(gint)'
3321   glib_gpui_cast='(guint)'
3322   ;;
3323 $ac_cv_sizeof_long)
3324   glib_intptr_type_define=long
3325   gintptr_modifier='"l"'
3326   gintptr_format='"li"'
3327   guintptr_format='"lu"'
3328   glib_gpi_cast='(glong)'
3329   glib_gpui_cast='(gulong)'
3330   ;;
3331 $ac_cv_sizeof_long_long)
3332   glib_intptr_type_define='long long'
3333   gintptr_modifier='"I64"'
3334   gintptr_format='"I64i"'
3335   guintptr_format='"I64u"'
3336   glib_gpi_cast='(gint64)'
3337   glib_gpui_cast='(guint64)'
3338   ;;
3339 $ac_cv_sizeof___int64)
3340   glib_intptr_type_define=__int64
3341   gintptr_modifier='"I64"'
3342   gintptr_format='"I64i"'
3343   guintptr_format='"I64u"'
3344   glib_gpi_cast='(gint64)'
3345   glib_gpui_cast='(guint64)'
3346   ;;
3347 *)
3348   glib_unknown_void_p=yes
3349   ;;
3350 esac
3351
3352
3353 case xyes in
3354 x$ac_cv_func_atexit)
3355   glib_atexit="
3356 #ifdef NeXT /* @#%@! NeXTStep */
3357 # define g_ATEXIT(proc) (!atexit (proc))
3358 #else
3359 # define g_ATEXIT(proc) (atexit (proc))
3360 #endif"
3361   ;;
3362 x$ac_cv_func_on_exit)
3363   glib_atexit="
3364 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3365   ;;
3366 esac
3367
3368 case xyes in
3369 x$ac_cv_func_memmove)
3370   glib_memmove='
3371 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3372   ;;
3373 x$glib_cv_working_bcopy)
3374   glib_memmove="
3375 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3376 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3377   ;;
3378 *)
3379   glib_memmove="
3380 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3381  * so we have to roll our own copy routine. */
3382 void g_memmove (void* dest, const void * src, unsigned long len);"
3383   ;;
3384 esac
3385
3386 glib_defines="
3387 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3388 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3389 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3390 "
3391
3392 case xyes in
3393 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3394 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3395 *)                      glib_vacopy=''
3396 esac
3397
3398 if test x$glib_cv_va_val_copy = xno; then
3399   glib_vacopy="\$glib_vacopy
3400 #define G_VA_COPY_AS_ARRAY 1"
3401 fi
3402
3403 if test x$glib_cv_hasinline = xyes; then
3404     glib_inline='#define G_HAVE_INLINE 1'
3405 fi
3406 if test x$glib_cv_has__inline = xyes; then
3407     glib_inline="\$glib_inline
3408 #define G_HAVE___INLINE 1"
3409 fi
3410 if test x$glib_cv_has__inline__ = xyes; then
3411     glib_inline="\$glib_inline
3412 #define G_HAVE___INLINE__ 1"
3413 fi
3414
3415 g_have_gnuc_varargs=$g_have_gnuc_varargs
3416 g_have_iso_c_varargs=$g_have_iso_c_varargs
3417 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3418
3419 g_can_inline=$g_can_inline
3420 g_have_gnuc_visibility=$g_have_gnuc_visibility
3421 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3422
3423 if test x$ac_cv_c_bigendian = xyes; then
3424   g_byte_order=G_BIG_ENDIAN
3425   g_bs_native=BE
3426   g_bs_alien=LE
3427 else
3428   g_byte_order=G_LITTLE_ENDIAN
3429   g_bs_native=LE
3430   g_bs_alien=BE
3431 fi
3432
3433 g_pollin=$glib_cv_value_POLLIN
3434 g_pollout=$glib_cv_value_POLLOUT
3435 g_pollpri=$glib_cv_value_POLLPRI
3436 g_pollhup=$glib_cv_value_POLLHUP
3437 g_pollerr=$glib_cv_value_POLLERR
3438 g_pollnval=$glib_cv_value_POLLNVAL
3439
3440 # If a family is not found on the system, define that family to
3441 # a negative value, picking a different one for each undefined
3442 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3443 # This is needed because glib-mkenums doesn't handle optional
3444 # values in enums, and thus we have to have all existing values
3445 # defined in the enum.
3446 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3447   g_af_unix=$glib_cv_value_AF_UNIX
3448 else
3449   g_af_unix=-1
3450 fi
3451 g_af_inet=$glib_cv_value_AF_INET
3452 g_af_inet6=$glib_cv_value_AF_INET6
3453
3454 g_msg_peek=$glib_cv_value_MSG_PEEK
3455 g_msg_oob=$glib_cv_value_MSG_OOB
3456 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3457
3458 g_stack_grows=$glib_cv_stack_grows
3459
3460 g_have_eilseq=$have_eilseq
3461
3462 g_threads_impl_def=$g_threads_impl
3463
3464 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3465 g_memory_barrier_needed="$glib_memory_barrier_needed"
3466 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3467
3468 g_module_suffix="$glib_gmodule_suffix"
3469
3470 g_pid_type="$glib_pid_type"
3471 case $host in
3472   *-*-beos*)
3473     glib_os="#define G_OS_BEOS"
3474     ;;
3475   *-*-cygwin*)
3476     glib_os="#define G_OS_UNIX
3477 #define G_PLATFORM_WIN32
3478 #define G_WITH_CYGWIN"
3479     ;;
3480   *-*-mingw*)
3481     glib_os="#define G_OS_WIN32
3482 #define G_PLATFORM_WIN32"
3483     ;;
3484   *)
3485     glib_os="#define G_OS_UNIX"
3486     ;;
3487 esac
3488 glib_static_compilation=""
3489 if test x$glib_win32_static_compilation = xyes; then
3490   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3491 #define GOBJECT_STATIC_COMPILATION 1"
3492 fi
3493 ])
3494
3495 # Redo enough to get guint32 and guint64 for the alignment checks below
3496 case 4 in
3497 $ac_cv_sizeof_short)
3498   gint32=short
3499   ;;
3500 $ac_cv_sizeof_int)
3501   gint32=int
3502   ;;
3503 $ac_cv_sizeof_long)
3504   gint32=long
3505   ;;
3506 esac
3507 case 8 in
3508 $ac_cv_sizeof_int)
3509   gint64=int
3510   ;;
3511 $ac_cv_sizeof_long)
3512   gint64=long
3513   ;;
3514 $ac_cv_sizeof_long_long)
3515   gint64='long long'
3516   ;;
3517 $ac_cv_sizeof___int64)
3518   gint64='__int64'
3519   ;;
3520 esac
3521
3522 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3523 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3524 typedef unsigned $gint32 guint32;])
3525 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3526 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3527 typedef unsigned $gint64 guint64;])
3528 AC_CHECK_TYPE([unsigned long])
3529 AC_CHECK_ALIGNOF([unsigned long])
3530
3531 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3532 #
3533 # 1.2.14 required for dbus_message_set_serial
3534 AS_IF([ test x$enable_modular_tests = xyes], [
3535    PKG_CHECK_MODULES(DBUS1,
3536                      dbus-1 >= 1.2.14,
3537                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3538                      have_dbus1=no)
3539    AC_SUBST(DBUS1_CFLAGS)
3540    AC_SUBST(DBUS1_LIBS)
3541 ])
3542 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3543
3544 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3545 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3546
3547 dnl
3548 dnl Check for -Bsymbolic-functions linker flag used to avoid
3549 dnl intra-library PLT jumps, if available.
3550 dnl
3551
3552 AC_ARG_ENABLE(Bsymbolic,
3553               [AS_HELP_STRING([--disable-Bsymbolic],
3554                               [avoid linking with -Bsymbolic])],,
3555               [SAVED_LDFLAGS="${LDFLAGS}"
3556                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3557                LDFLAGS=-Wl,-Bsymbolic-functions
3558                AC_TRY_LINK([], [int main (void) { return 0; }],
3559                            AC_MSG_RESULT(yes)
3560                            enable_Bsymbolic=yes,
3561                            AC_MSG_RESULT(no)
3562                            enable_Bsymbolic=no)
3563                LDFLAGS="${SAVED_LDFLAGS}"])
3564
3565 if test "x${enable_Bsymbolic}" = "xyes"; then
3566   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3567 fi
3568
3569 AC_SUBST(GLIB_LINK_FLAGS)
3570
3571 dnl
3572 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3573 dnl visibility attributes for symbol export control
3574 dnl
3575 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3576 case "$host" in
3577   *-*-mingw*)
3578     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3579     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3580               [defines how to decorate public symbols while building])
3581     CFLAGS="${CFLAGS} -fvisibility=hidden"
3582     ;;
3583   *)
3584     dnl on other compilers, check if we can do -fvisibility=hidden
3585     SAVED_CFLAGS="${CFLAGS}"
3586     CFLAGS="-fvisibility=hidden"
3587     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3588     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3589                    AC_MSG_RESULT(yes)
3590                    enable_fvisibility_hidden=yes,
3591                    AC_MSG_RESULT(no)
3592                    enable_fvisibility_hidden=no)
3593     CFLAGS="${SAVED_CFLAGS}"
3594
3595     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3596       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3597                 [defines how to decorate public symbols while building])
3598       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3599     ])
3600     ;;
3601 esac
3602 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3603
3604 dnl Compiler flags; macro originates from systemd
3605 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3606 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3607    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3608    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3609    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3610    -Werror=format=2 -Werror=missing-include-dirs])
3611 CFLAGS="$with_cflags $CFLAGS"
3612
3613 #
3614 # Define variables corresponding to the correct include paths to use for
3615 # in-tree building.
3616 #
3617
3618 # for config.h:
3619 config_h_INCLUDES='-I$(top_builddir)'
3620 AC_SUBST(config_h_INCLUDES)
3621
3622 # glib:
3623 #   config.h
3624 #   $(top_builddir)/glib: for glibconfig.h
3625 #   $(top_srcdir)/glib:   for glib.h
3626 #   $(top_srcdir):        for everything
3627 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3628 AC_SUBST(glib_INCLUDES)
3629
3630 # gobject:
3631 #   same as glib
3632 gobject_INCLUDES='$(glib_INCLUDES)'
3633 AC_SUBST(gobject_INCLUDES)
3634
3635 # gmodule:
3636 #   glib includes
3637 #   $(top_srcdir)/gmodule: for gmodule.h
3638 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3639 AC_SUBST(gmodule_INCLUDES)
3640
3641 # gio:
3642 #   same as gmodule
3643 gio_INCLUDES='$(gmodule_INCLUDES)'
3644 AC_SUBST(gio_INCLUDES)
3645
3646
3647 AC_CONFIG_FILES([
3648 glib-2.0.pc
3649 gmodule-2.0.pc
3650 gmodule-export-2.0.pc
3651 gmodule-no-export-2.0.pc
3652 gthread-2.0.pc
3653 gobject-2.0.pc
3654 gio-2.0.pc
3655 gio-unix-2.0.pc
3656 gio-windows-2.0.pc
3657 glib-zip
3658 glib-gettextize
3659 Makefile
3660 build/Makefile
3661 build/win32/Makefile
3662 build/win32/dirent/Makefile
3663 build/win32/vs9/Makefile
3664 build/win32/vs10/Makefile
3665 build/win32/vs11/Makefile
3666 glib/Makefile
3667 glib/glib.stp
3668 glib/libcharset/Makefile
3669 glib/gnulib/Makefile
3670 glib/pcre/Makefile
3671 glib/update-pcre/Makefile
3672 glib/tests/Makefile
3673 gmodule/Makefile
3674 gmodule/gmoduleconf.h
3675 gobject/Makefile
3676 gobject/gobject.stp
3677 gobject/glib-mkenums
3678 gobject/tests/Makefile
3679 gthread/Makefile
3680 gio/Makefile
3681 gio/gdbus-2.0/codegen/Makefile
3682 gio/gdbus-2.0/codegen/config.py
3683 gio/gnetworking.h
3684 gio/xdgmime/Makefile
3685 gio/inotify/Makefile
3686 gio/kqueue/Makefile
3687 gio/fen/Makefile
3688 gio/fam/Makefile
3689 gio/win32/Makefile
3690 gio/tests/Makefile
3691 gio/tests/gdbus-object-manager-example/Makefile
3692 gio/tests/services/Makefile
3693 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3694 po/Makefile.in
3695 docs/Makefile
3696 docs/reference/Makefile
3697 docs/reference/glib/Makefile
3698 docs/reference/glib/version.xml
3699 docs/reference/gobject/Makefile
3700 docs/reference/gobject/version.xml
3701 docs/reference/gio/Makefile
3702 docs/reference/gio/gdbus-object-manager-example/Makefile
3703 docs/reference/gio/version.xml
3704 tests/Makefile
3705 tests/gobject/Makefile
3706 tests/refcount/Makefile
3707 m4macros/Makefile
3708 ])
3709
3710 AC_CONFIG_COMMANDS([chmod-scripts],
3711 [chmod 0755 glib-zip
3712 chmod 0755 glib-gettextize
3713 chmod 0755 gobject/glib-mkenums])
3714
3715 # we want to invoke this macro solely so that the config.status script
3716 # and automake generated makefiles know about these generated files.
3717 # They are only needed to distcheck the package
3718 if false; then
3719   AC_CONFIG_FILES([
3720     INSTALL
3721     README
3722     config.h.win32
3723     glib/glibconfig.h.win32
3724     glib/makefile.msc
3725     glib/glib.rc
3726     gmodule/makefile.msc
3727     gmodule/gmodule.rc
3728     gobject/makefile.msc
3729     gobject/gobject.rc
3730     gthread/makefile.msc
3731     gthread/gthread.rc
3732     gio/gio.rc
3733     tests/makefile.msc
3734   ])
3735 fi
3736
3737 AC_OUTPUT