configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 AC_PREREQ([2.60])
  24 AC_INIT([intel-gpu-tools],
  25         [1.6],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  27         [intel-gpu-tools])
  28
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_GNU_SOURCE
  36 AC_CANONICAL_HOST
  37
  38 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  39 AM_PATH_PYTHON([3],, [:])
  40
  41 AC_PROG_CC
  42 AM_PROG_LEX
  43 AC_PROG_YACC
  44
  45 # check for gtk-doc
  46 m4_ifdef([GTK_DOC_CHECK], [
  47 GTK_DOC_CHECK([1.14],[--flavour no-tmpl])
  48 ],[
  49 AM_CONDITIONAL([ENABLE_GTK_DOC], false)
  50 enable_gtk_doc=no
  51 ])
  52
  53
  54 # Checks for functions, headers, structures, etc.
  55 AC_HEADER_STDC
  56 AC_CHECK_HEADERS([termios.h])
  57 AC_CHECK_MEMBERS([struct sysinfo.totalram],[],[],[AC_INCLUDES_DEFAULT
  58                   #include <sys/sysinfo.h>
  59                   ])
  60 AC_CHECK_FUNCS([swapctl])
  61 AC_CHECK_FUNCS([asprintf])
  62
  63 # Initialize libtool
  64 AC_DISABLE_STATIC
  65 AC_PROG_LIBTOOL
  66
  67 # Require X.Org macros 1.16 or later for XORG_TESTSET_CFLAG
  68 m4_ifndef([XORG_MACROS_VERSION],
  69           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  70 XORG_MACROS_VERSION(1.16)
  71 XORG_DEFAULT_OPTIONS
  72
  73 # warning flags for the assembler. We can't quite use CWARNFLAGS for it yet as
  74 # it generates waaaay too many warnings.
  75 ASSEMBLER_WARN_CFLAGS=""
  76 if test "x$GCC" = "xyes"; then
  77         ASSEMBLER_WARN_CFLAGS="-Wall -Wstrict-prototypes \
  78         -Wmissing-prototypes -Wmissing-declarations \
  79         -Wnested-externs -fno-strict-aliasing"
  80 fi
  81 AC_SUBST(ASSEMBLER_WARN_CFLAGS)
  82
  83 PKG_CHECK_MODULES(DRM, [libdrm_intel >= 2.4.52 libdrm])
  84 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
  85 PKG_CHECK_MODULES(OVERLAY_XVLIB, [xv x11 xext], enable_overlay_xvlib=yes, enable_overlay_xvlib=no)
  86 PKG_CHECK_MODULES(OVERLAY_XLIB, [cairo-xlib], enable_overlay_xlib=yes, enable_overlay_xlib=no)
  87
  88 AM_CONDITIONAL(BUILD_OVERLAY_XVLIB, [test "x$enable_overlay_xvlib" = xyes])
  89 AM_CONDITIONAL(BUILD_OVERLAY_XLIB, [test "x$enable_overlay_xlib" = xyes])
  90 AM_CONDITIONAL(BUILD_OVERLAY, [test "x$enable_overlay_xlib" = xyes -o "x$enable_overlay_xvlib"])
  91 if test x$enable_overlay_xvlib = xyes; then
  92         AC_DEFINE(HAVE_OVERLAY_XVLIB, 1, [Enable XV backend])
  93         PKG_CHECK_MODULES(DRI2PROTO, [dri2proto >= 2.6])
  94 fi
  95 if test x$enable_overlay_xlib = xyes; then
  96         AC_DEFINE(HAVE_OVERLAY_XLIB, 1, [Enable X backend])
  97         PKG_CHECK_MODULES(DRI2PROTO, [dri2proto >= 2.6])
  98 fi
  99 PKG_CHECK_MODULES(XRANDR, xrandr >= 1.3, AC_DEFINE(HAVE_XRANDR, 1, [Have libXrandr]), [have_xrandr=no])
 100
 101 # for testdisplay
 102 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.12.0])
 103 PKG_CHECK_MODULES(LIBUDEV, [libudev], [udev=yes], [udev=no])
 104 if test x"$udev" = xyes; then
 105         AC_DEFINE(HAVE_UDEV,1,[Enable udev-based monitor hotplug detection])
 106 fi
 107 PKG_CHECK_MODULES(GLIB, glib-2.0)
 108
 109 # can we build the assembler?
 110 AS_IF([test x"$LEX" != "x:" -a x"$YACC" != xyacc],
 111       [enable_assembler=yes],
 112       [enable_assembler=no])
 113 AM_CONDITIONAL(BUILD_ASSEMBLER, [test "x$enable_assembler" = xyes])
 114
 115 # -----------------------------------------------------------------------------
 116 #                       Configuration options
 117 # -----------------------------------------------------------------------------
 118 # for dma-buf tests
 119 AC_ARG_ENABLE(nouveau, AS_HELP_STRING([--disable-nouveau],
 120               [Enable use of nouveau API for prime tests (default: auto)]),
 121               [NOUVEAU=$enableval], [NOUVEAU=auto])
 122 if test "x$NOUVEAU" = xauto; then
 123         PKG_CHECK_EXISTS([libdrm_nouveau >= 2.4.33], [NOUVEAU=yes], [NOUVEAU=no])
 124 fi
 125 if test "x$NOUVEAU" = xyes; then
 126         PKG_CHECK_MODULES(DRM_NOUVEAU, [libdrm_nouveau >= 2.4.33])
 127         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau support])
 128 fi
 129 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 130
 131 #Configure options for the python quick-dumper
 132 AC_ARG_ENABLE(dumper,
 133               AS_HELP_STRING([--disable-dumper],
 134                              [Disable the python based register dumper (default: enabled)]),
 135                              [DUMPER=$enableval], [DUMPER=auto])
 136 if test "x$DUMPER" = xauto; then
 137         # AX_PYTHON_DEVEL/AX_SWIG_PYTHON are not super friendly and don't
 138         # easily allow us to introspect the result of their checks. So if we
 139         # find SWING on the system, that's enough to try compiling the dumper.
 140         AX_PKG_SWIG(2.0.0, [DUMPER=yes], [DUMPER=no])
 141 fi
 142 if test "x$DUMPER" == xyes; then
 143         AC_DEFINE(HAVE_DUMPER, 1, [Have dumper support])
 144         # SWIG configuration
 145         AX_PKG_SWIG(2.0.0, [], [ AC_MSG_ERROR([SWIG 2.0.0 or higher is required to build..]) ])
 146         AX_PYTHON_DEVEL([>= '3.0'])
 147         AX_SWIG_PYTHON
 148 fi
 149 AM_CONDITIONAL(HAVE_DUMPER, [test "x$DUMPER" = xyes])
 150
 151 # Define a configure option for the shader debugger
 152 AC_ARG_ENABLE(shader-debugger, AS_HELP_STRING([--enable-shader-debugger],
 153               [Enable shader debugging support [autodetected]]),
 154               [BUILD_SHADER_DEBUGGER="$enableval"], [BUILD_SHADER_DEBUGGER=auto])
 155
 156 # Shader debugger depends on python3, intel-genasm and objcopy
 157 if test "x$BUILD_SHADER_DEBUGGER" != xno; then
 158         # Check that the assembler is built
 159         if test "x$enable_assembler" = xno; then
 160                 BUILD_SHADER_DEBUGGER=no
 161                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 162                         AC_MSG_ERROR([Shader debugger requested, but assembler not enabled.])
 163                 fi
 164         fi
 165
 166         # Check Python 3 is installed
 167         if test "$PYTHON" = ":" ; then
 168                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 169                         AC_MSG_ERROR([Shader debugger requested, python version 3 not found.])
 170                 else
 171                         BUILD_SHADER_DEBUGGER=no
 172                 fi
 173         fi
 174
 175         # Check for the objcopy GNU binary utiliy command
 176         AC_PATH_PROGS([OBJCOPY], objcopy)
 177         if test -z "$OBJCOPY" ; then
 178                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 179                         AC_MSG_ERROR([Shader debugger requested, but objcopy command not found.])
 180                 else
 181                         BUILD_SHADER_DEBUGGER=no
 182                 fi
 183         fi
 184 fi
 185
 186 AM_CONDITIONAL(BUILD_SHADER_DEBUGGER, [test "x$BUILD_SHADER_DEBUGGER" != xno])
 187 AS_IF([test "x$BUILD_SHADER_DEBUGGER" != xno],
 188       [enable_debugger=yes], [enable_debugger=no])
 189
 190 # -----------------------------------------------------------------------------
 191
 192 # To build multithread code, gcc uses -pthread, Solaris Studio cc uses -mt
 193 XORG_TESTSET_CFLAG([THREAD_CFLAGS], [-pthread], [-mt])
 194 AC_SUBST([THREAD_CFLAGS])
 195
 196 AC_ARG_ENABLE(tests,
 197               AS_HELP_STRING([--disable-tests],
 198               [Disable tests build (default: enabled)]),
 199               [BUILD_TESTS=$enableval], [BUILD_TESTS="yes"])
 200 if test "x$BUILD_TESTS" = xyes; then
 201         AC_DEFINE(BUILD_TESTS, 1, [Build tests])
 202 fi
 203 AM_CONDITIONAL(BUILD_TESTS, [test "x$BUILD_TESTS" = xyes])
 204 AC_DEFINE_UNQUOTED(TARGET_CPU_PLATFORM, ["$host_cpu"], [Target platform])
 205
 206 AC_CONFIG_FILES([
 207                  Makefile
 208                  benchmarks/Makefile
 209                  demos/Makefile
 210                  docs/Makefile
 211                  docs/reference/Makefile
 212                  docs/reference/intel-gpu-tools/Makefile
 213                  docs/reference/intel-gpu-tools/version.xml
 214                  lib/Makefile
 215                  man/Makefile
 216                  scripts/Makefile
 217                  tests/Makefile
 218                  tools/Makefile
 219                  tools/quick_dump/Makefile
 220                  tools/null_state_gen/Makefile
 221                  debugger/Makefile
 222                  debugger/system_routine/Makefile
 223                  assembler/Makefile
 224                  assembler/doc/Makefile
 225                  assembler/test/Makefile
 226                  assembler/intel-gen4asm.pc
 227                  overlay/Makefile
 228                  ])
 229 AC_OUTPUT
 230
 231 # Print a summary of the compilation
 232 echo ""
 233 echo "Intel GPU tools"
 234
 235 echo ""
 236 echo " • Tests:"
 237 echo "       Build tests        : ${BUILD_TESTS}"
 238 echo "       Compile prime tests: ${NOUVEAU}"
 239 echo ""
 240 echo " • Tools:"
 241 echo "       Assembler          : ${enable_assembler}"
 242 echo "       Debugger           : ${enable_debugger}"
 243 echo "       Python dumper      : ${DUMPER}"
 244 echo "       Overlay            : X: ${enable_overlay_xlib}, Xv: ${enable_overlay_xvlib}"
 245 echo ""
 246 echo " • API-Documentation      : ${enable_gtk_doc}"
 247 echo ""
 248
 249 # vim: set ft=config ts=8 sw=8 tw=0 noet :