configure.ac

   1 ## Copyright (c) 2009  Openismus GmbH  <http://www.openismus.com/>
   2 ##
   3 ## This file is part of libsigc++.
   4 ##
   5 ## libsigc++ is free software: you can redistribute it and/or modify it
   6 ## under the terms of the GNU Lesser General Public License as published
   7 ## by the Free Software Foundation, either version 2.1 of the License,
   8 ## or (at your option) any later version.
   9 ##
  10 ## libsigc++ is distributed in the hope that it will be useful, but
  11 ## WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  13 ## See the GNU Lesser General Public License for more details.
  14 ##
  15 ## You should have received a copy of the GNU Lesser General Public License
  16 ## along with this library.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_INIT([libsigc++], [2.99.9],
  19         [http://bugzilla.gnome.org/enter_bug.cgi?product=libsigc%2B%2B],
  20         [libsigc++], [http://libsigc.sourceforge.net/])
  21 AC_PREREQ([2.59])
  22
  23 AC_CONFIG_SRCDIR([sigc++/sigc++.h])
  24 AC_CONFIG_AUX_DIR([build])
  25 AC_CONFIG_MACRO_DIR([build])
  26 AC_CONFIG_HEADERS([config.h sigc++config.h])
  27
  28 AM_INIT_AUTOMAKE([1.9 -Wno-portability check-news dist-bzip2 no-define nostdinc tar-ustar])
  29 # Support silent build rules.
  30 # Disable by either passing --disable-silent-rules to configure or passing V=1 to make.
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32 AM_MAINTAINER_MODE
  33 AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
  34
  35 MM_PREREQ([0.9.10])
  36 MM_INIT_MODULE([sigc++-3.0])
  37 MM_CONFIG_DOCTOOL_DIR([docs])
  38
  39 AC_PROG_CXX
  40 MM_AX_CXX_COMPILE_STDCXX([14],[noext],[mandatory])
  41
  42 AC_DISABLE_STATIC
  43 LT_INIT([win32-dll])
  44
  45 MM_ARG_ENABLE_DOCUMENTATION
  46 MM_ARG_WITH_TAGFILE_DOC([libstdc++.tag], [mm-common-libstdc++])
  47
  48 AC_LANG([C++])
  49
  50 AS_IF([test "x$config_error" = xyes],
  51       [AC_MSG_FAILURE([[One or more of the required C++ compiler features is missing.]])])
  52
  53 # Evaluate the --enable-warnings=level option.
  54 MM_ARG_ENABLE_WARNINGS([SIGC_WXXFLAGS],
  55                        [-Wall],
  56                        [-pedantic -Wall -Wextra -Wsuggest-override -Wshadow -Wzero-as-null-pointer-constant -Wformat-security])
  57
  58 # Offer the ability to omit some API from the library.
  59 MM_ARG_DISABLE_DEPRECATED_API([SIGCXX])
  60
  61 AC_ARG_ENABLE(benchmark,
  62   AS_HELP_STRING([--enable-benchmark=yes|no])
  63 )
  64
  65 AM_CONDITIONAL([SIGC_BUILD_BENCHMARK], [test "x$enable_benchmark" = xyes])
  66
  67 AS_IF([test "x$enable_benchmark" = xyes],[
  68   #Use boost::timer for our benchmark, if it's available.
  69   # See http://www.gnu.org/software/autoconf-archive/ax_boost_base.html
  70   # Boost System is needed by Boost Timer
  71   AX_BOOST_BASE
  72   AX_BOOST_SYSTEM
  73   AX_BOOST_TIMER
  74 ])
  75
  76 AC_CONFIG_FILES([Makefile
  77                  ${SIGCXX_MODULE_NAME}.pc:sigc++.pc.in
  78                  ${SIGCXX_MODULE_NAME}-uninstalled.pc:sigc++-uninstalled.pc.in
  79                  cmake/Makefile
  80                  sigc++/Makefile
  81                  examples/Makefile
  82                  tests/Makefile
  83                  docs/Makefile
  84                  docs/reference/Doxyfile
  85                  MSVC_Net2017/sigc.rc])
  86
  87 # Copy the generated configuration headers into the MSVC project directories.
  88 AC_CONFIG_COMMANDS([MSVC_Net2017/sigc++config.h],
  89                    [cp -f sigc++config.h MSVC_Net2017/sigc++config.h])
  90 AC_OUTPUT