configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [8])
   6 m4_define([dbus_micro_version], [2])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22 # By default, rebuild autotools files on demand; only use ./missing if the
  23 # user says --disable-maintainer-mode (some distributions like to do this)
  24 AM_MAINTAINER_MODE([enable])
  25
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  29
  30 # libtool versioning - this applies to libdbus
  31 #
  32 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  33 #
  34
  35 ## increment if the interface has additions, changes, removals.
  36 LT_CURRENT=11
  37
  38 ## increment any time the source changes; set to
  39 ##  0 if you increment CURRENT
  40 LT_REVISION=4
  41
  42 ## increment if any interfaces have been added; set to 0
  43 ## if any interfaces have been changed or removed. removal has
  44 ## precedence over adding, so set to 0 if both happened.
  45 LT_AGE=8
  46
  47 AC_SUBST(LT_CURRENT)
  48 AC_SUBST(LT_REVISION)
  49 AC_SUBST(LT_AGE)
  50
  51 DBUS_MAJOR_VERSION=dbus_major_version
  52 DBUS_MINOR_VERSION=dbus_minor_version
  53 DBUS_MICRO_VERSION=dbus_micro_version
  54 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  55
  56 AC_SUBST(DBUS_MAJOR_VERSION)
  57 AC_SUBST(DBUS_MINOR_VERSION)
  58 AC_SUBST(DBUS_MICRO_VERSION)
  59 AC_SUBST(DBUS_VERSION)
  60
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_CXX
  64 AC_USE_SYSTEM_EXTENSIONS
  65 AC_ISC_POSIX
  66 AC_HEADER_STDC
  67 AC_C_INLINE
  68 AM_PROG_LIBTOOL
  69 AC_PROG_MKDIR_P
  70 COMPILER_COVERAGE
  71 COMPILER_OPTIMISATIONS
  72 PKG_PROG_PKG_CONFIG
  73
  74 # Initialize libtool
  75 LT_INIT([win32-dll])
  76 LT_LANG([Windows Resource])
  77
  78 # Set some internal variables depending on the platform for later use.
  79 dbus_win=no
  80 dbus_cygwin=no
  81 dbus_unix=no
  82 case "${host}" in
  83     *-mingw32ce*)
  84         dbus_win=yes
  85         dbus_wince=yes
  86         ;;
  87     *-mingw32*)
  88         dbus_win=yes
  89         ;;
  90     *-cygwin*)
  91         dbus_cygwin=yes
  92         dbus_unix=yes
  93         ;;
  94     *)
  95         dbus_unix=yes
  96        ;;
  97 esac
  98
  99 # Special defines for certain platforms
 100 if test "$dbus_win" = yes; then
 101     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 102     # Yes, on Windows it really does work like this.
 103     # http://support.microsoft.com/kb/111855
 104     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 105     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 106     AC_SUBST(BUILD_TIMESTAMP)
 107     # Assume DBUS_VERSION is always three numbers
 108     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 109     AC_SUBST(BUILD_FILEVERSION)
 110     AC_CHECK_TOOL(WINDRES, windres, no)
 111     if test "$WINDRES" = no; then
 112       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 113     fi
 114     if test "$dbus_wince" = yes; then
 115       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 116       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 117     fi
 118 else
 119     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 120 fi
 121 if test "$dbus_cygwin" = yes; then
 122     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 123 fi
 124
 125 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 126 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 127 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 128 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 129
 130 # this must come first: other options use this to set their defaults
 131 AC_ARG_ENABLE([developer],
 132   [AS_HELP_STRING([--enable-developer],
 133     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
 134   [],
 135   [enable_developer=no])
 136
 137 DBUS_STATIC_BUILD_CPPFLAGS=
 138 if test "x$enable_shared" = xno; then
 139     # On Windows, linking against the static library requires special effort
 140     # to turn off DLL import/export processing. We normally link some things
 141     # against the dynamic library, but if we're not building that, we'll
 142     # have to link everything statically.
 143     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 144 fi
 145 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 146
 147 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 148 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 149 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 150 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 151 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 152 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 153 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 154 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 155 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 156 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 157 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 158 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 159 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 160 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 161
 162 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 163 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 164 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 165 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 166 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 167 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 168 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 169 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 170 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 171 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 172
 173 AC_ARG_ENABLE([embedded-tests],
 174   AS_HELP_STRING([--enable-embedded-tests],
 175     [enable unit test code in the library and binaries]),
 176   [], [enable_embedded_tests=$enable_developer])
 177 AC_ARG_ENABLE([modular-tests],
 178   AS_HELP_STRING([--enable-modular-tests],
 179     [enable modular regression tests (requires GLib)]),
 180   [], [enable_modular_tests=auto])
 181 # --enable-tests overrides both --enable-embedded-tests and
 182 # --enable-modular-tests
 183 AC_ARG_ENABLE([tests],
 184   AS_HELP_STRING([--enable-tests],
 185     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 186   [
 187   if test "x$enableval" = xyes; then
 188     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 189     AC_MSG_NOTICE([This has many dependencies (GLib, dbus-glib, Python)])
 190   fi
 191   enable_embedded_tests=$enableval
 192   enable_modular_tests=$enableval
 193   ],
 194   [])
 195
 196 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 197 # and also some stuff in the test/ subdir.
 198 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 199   [test "x$enable_embedded_tests" = xyes])
 200 if test "x$enable_embedded_tests" = xyes; then
 201     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 202       [Define to build test code into the library and binaries])
 203 fi
 204
 205 # call early to ensure availability
 206 PKG_PROG_PKG_CONFIG
 207
 208 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 209 # These use GTest, from GLib, because life's too short. They're enabled by
 210 # default (unless you don't have GLib), because they don't bloat the library
 211 # or binaries.
 212
 213 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_26], [Ignore post-2.26 deprecations])
 214 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_32], [Prevent post-2.32 APIs])
 215
 216 with_glib=yes
 217
 218 AS_IF([test "x$enable_modular_tests" != xno],
 219   [
 220   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.24, gio-2.0 >= 2.24],
 221     [],
 222     [if test "x$enable_modular_tests" = xyes; then
 223       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 224       AC_MSG_ERROR([$GLIB_ERRORS])
 225     else # assumed to be "auto"
 226       with_glib=no
 227     fi])
 228   ],
 229   [with_glib=no])
 230
 231 # Not required, because we can use internal APIs (but that makes the
 232 # "installable tests" less useful as integration tests)
 233 AC_ARG_WITH([dbus_glib],
 234   [AS_HELP_STRING([--with-dbus-glib], [Use dbus-glib for regression tests])],
 235   [],
 236   [with_dbus_glib=auto])
 237 AS_IF([test "x$with_dbus_glib" != xno],
 238   [PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 239     [],
 240     [AS_IF([test "x$with_dbus_glib" = xyes],
 241       dnl specifically requested, but not found
 242       [AC_MSG_ERROR([$DBUS_GLIB_ERRORS])],
 243       dnl else: assumed to be "auto"
 244       [with_dbus_glib=no])])])
 245 AM_CONDITIONAL([DBUS_WITH_DBUS_GLIB], [test "x$with_dbus_glib" != xno])
 246
 247 if test "x$enable_modular_tests" != xno; then
 248   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 249     [Define to build independent test binaries])
 250 fi
 251 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 252   [test "x$enable_modular_tests" != xno])
 253
 254 if test "x$with_glib" != xno; then
 255   AC_DEFINE([DBUS_WITH_GLIB], [1],
 256     [Define if GLib, GObject, GIO are available])
 257 fi
 258 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 259
 260 AC_ARG_ENABLE([installed-tests],
 261   AS_HELP_STRING([--enable-installed-tests],
 262     [enable unit test code in the library and binaries]),
 263   [], [enable_installed_tests=no])
 264 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 265   [test "x$enable_installed_tests" = xyes])
 266
 267 if test "x$enable_tests" = xyes; then
 268   # full test coverage is required, Python is a hard dependency
 269   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygobject])
 270   AM_PATH_PYTHON([2.6])
 271   AC_MSG_CHECKING([for Python modules for full test coverage])
 272   if "$PYTHON" -c "import dbus, gobject, dbus.mainloop.glib"; then
 273     AC_MSG_RESULT([yes])
 274   else
 275     AC_MSG_RESULT([no])
 276     AC_MSG_ERROR([cannot import dbus, gobject, dbus.mainloop.glib Python modules])
 277   fi
 278 else
 279   # --enable-tests not given: do not abort if Python is missing
 280   AM_PATH_PYTHON([2.6], [], [:])
 281 fi
 282
 283 if test x$enable_verbose_mode = xyes; then
 284     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 285 fi
 286
 287 if test x$enable_asserts = xno; then
 288     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 289     DISABLE_UNUSED_WARNINGS="unused-label"
 290     R_DYNAMIC_LDFLAG=""
 291     if test x$enable_embedded_tests = xyes; then
 292         DISABLE_UNUSED_WARNINGS="$DISABLE_UNUSED_WARNINGS \
 293                 unused-but-set-variable unused-variable \
 294                 unused-function"
 295     fi
 296 else
 297     # -rdynamic is needed for glibc's backtrace_symbols to work.
 298     # No clue how much overhead this adds, but it's useful
 299     # to do this on any assertion failure,
 300     # so for now it's enabled anytime asserts are (currently not
 301     # in production builds).
 302
 303     # To get -rdynamic you pass -export-dynamic to libtool.
 304     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 305     R_DYNAMIC_LDFLAG=-export-dynamic
 306 fi
 307 AC_SUBST(R_DYNAMIC_LDFLAG)
 308
 309 if test x$enable_checks = xno; then
 310     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 311     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 312     DISABLE_UNUSED_WARNINGS="unused-label"
 313 fi
 314
 315 AH_BOTTOM([
 316 /* explicitly define these macros to get less confusing conditions */
 317 #ifndef DBUS_DISABLE_ASSERT
 318 #  define DBUS_ENABLE_ASSERT 1
 319 #endif
 320 #ifndef DBUS_DISABLE_CHECKS
 321 #  define DBUS_ENABLE_CHECKS 1
 322 #endif])
 323
 324 if test x$enable_compiler_coverage = xyes; then
 325      ## so that config.h changes when you toggle gcov support
 326      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 327 fi
 328
 329 # glibc21.m4 serial 3
 330 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 331 dnl This file is free software; the Free Software Foundation
 332 dnl gives unlimited permission to copy and/or distribute it,
 333 dnl with or without modifications, as long as this notice is preserved.
 334
 335 # Test for the GNU C Library, version 2.1 or newer.
 336 # From Bruno Haible.
 337
 338 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 339   ac_cv_gnu_library_2_1,
 340   [AC_EGREP_CPP([Lucky GNU user],
 341     [
 342 #include <features.h>
 343 #ifdef __GNU_LIBRARY__
 344  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 345   Lucky GNU user
 346  #endif
 347 #endif
 348     ],
 349     ac_cv_gnu_library_2_1=yes,
 350     ac_cv_gnu_library_2_1=no)
 351   ]
 352 )
 353
 354 #### Integer sizes
 355
 356 AC_CHECK_SIZEOF(char)
 357 AC_CHECK_SIZEOF(short)
 358 AC_CHECK_SIZEOF(long)
 359 AC_CHECK_SIZEOF(int)
 360 AC_CHECK_SIZEOF(void *)
 361 AC_CHECK_SIZEOF(long long)
 362 AC_CHECK_SIZEOF(__int64)
 363
 364 ### See what our 64 bit type is called
 365 AC_MSG_CHECKING([64-bit integer type])
 366
 367 case 8 in
 368 $ac_cv_sizeof_int)
 369   dbusint64=int
 370   dbusint64_constant='(val)'
 371   dbusuint64_constant='(val)'
 372   dbusint64_printf_modifier='""'
 373   ;;
 374 $ac_cv_sizeof_long)
 375   dbusint64=long
 376   dbusint64_constant='(val##L)'
 377   dbusuint64_constant='(val##UL)'
 378   dbusint64_printf_modifier='"l"'
 379   ;;
 380 $ac_cv_sizeof_long_long)
 381   dbusint64='long long'
 382   dbusint64_constant='(val##LL)'
 383   dbusuint64_constant='(val##ULL)'
 384   # Ideally we discover what the format is, but this is
 385   # only used in verbose mode, so eh...
 386   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 387     dbusint64_printf_modifier='"ll"'
 388   fi
 389   ;;
 390 $ac_cv_sizeof___int64)
 391   dbusint64=__int64
 392   dbusint64_constant='(val##i64)'
 393   dbusuint64_constant='(val##ui64)'
 394   # See above case
 395   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 396     dbusint64_printf_modifier='"ll"'
 397   fi
 398   ;;
 399 esac
 400
 401 AS_IF(
 402   [test -z "$dbusint64"],
 403   [AC_MSG_RESULT([not found])
 404   AC_MSG_ERROR([Could not find a 64-bit integer type.
 405
 406 Please report a bug here with details of your platform and compiler:
 407
 408     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 409   ],
 410   dnl else
 411   [
 412         DBUS_INT64_TYPE="$dbusint64"
 413         DBUS_INT64_CONSTANT="$dbusint64_constant"
 414         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 415         if test x"$dbusint64_printf_modifier" != x; then
 416                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 417         fi
 418         AC_MSG_RESULT($DBUS_INT64_TYPE)
 419   ])
 420
 421 AC_SUBST(DBUS_INT64_TYPE)
 422 AC_SUBST(DBUS_INT64_CONSTANT)
 423 AC_SUBST(DBUS_UINT64_CONSTANT)
 424
 425 ### see what 32-bit int is called
 426 AC_MSG_CHECKING([32-bit integer type])
 427
 428 case 4 in
 429 $ac_cv_sizeof_short)
 430   dbusint32=short
 431   ;;
 432 $ac_cv_sizeof_int)
 433   dbusint32=int
 434   ;;
 435 $ac_cv_sizeof_long)
 436   dbusint32=long
 437   ;;
 438 esac
 439
 440 if test -z "$dbusint32" ; then
 441         DBUS_INT32_TYPE="no_int32_type_detected"
 442         AC_MSG_ERROR([No 32-bit integer type found])
 443 else
 444         DBUS_INT32_TYPE="$dbusint32"
 445         AC_MSG_RESULT($DBUS_INT32_TYPE)
 446 fi
 447
 448 AC_SUBST(DBUS_INT32_TYPE)
 449
 450 ### see what 16-bit int is called
 451 AC_MSG_CHECKING([16-bit integer type])
 452
 453 case 2 in
 454 $ac_cv_sizeof_short)
 455   dbusint16=short
 456   ;;
 457 $ac_cv_sizeof_int)
 458   dbusint16=int
 459   ;;
 460 esac
 461
 462 if test -z "$dbusint16" ; then
 463         DBUS_INT16_TYPE="no_int16_type_detected"
 464         AC_MSG_ERROR([No 16-bit integer type found])
 465 else
 466         DBUS_INT16_TYPE="$dbusint16"
 467         AC_MSG_RESULT($DBUS_INT16_TYPE)
 468 fi
 469
 470 AC_SUBST(DBUS_INT16_TYPE)
 471
 472 ## byte order
 473 case $host_os in
 474         darwin*)
 475                 # check at compile-time, so that it is possible to build universal
 476                 # (with multiple architectures at once on the compile line)
 477                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 478                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 479                         #if defined(__BIG_ENDIAN__)
 480                         #define WORDS_BIGENDIAN 1
 481                         #endif
 482                 ])
 483                 ;;
 484         *)
 485                 AC_C_BIGENDIAN
 486                 ;;
 487 esac
 488
 489 dnl **********************************
 490 dnl *** va_copy checks (from GLib) ***
 491 dnl **********************************
 492 dnl we currently check for all three va_copy possibilities, so we get
 493 dnl all results in config.log for bug reports.
 494 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 495         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 496 #include <stdlib.h>
 497         static void f (int i, ...) {
 498         va_list args1, args2;
 499         va_start (args1, i);
 500         va_copy (args2, args1);
 501         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 502           exit (1);
 503         va_end (args1); va_end (args2);
 504         }
 505         int main() {
 506           f (0, 42);
 507           return 0;
 508         }])],
 509         [dbus_cv_va_copy=yes],
 510         [dbus_cv_va_copy=no])
 511 ])
 512 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 513         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 514 #include <stdlib.h>
 515         static void f (int i, ...) {
 516         va_list args1, args2;
 517         va_start (args1, i);
 518         __va_copy (args2, args1);
 519         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 520           exit (1);
 521         va_end (args1); va_end (args2);
 522         }
 523         int main() {
 524           f (0, 42);
 525           return 0;
 526         }])],
 527         [dbus_cv___va_copy=yes],
 528         [dbus_cv___va_copy=no])
 529 ])
 530
 531 if test "x$dbus_cv_va_copy" = "xyes"; then
 532   dbus_va_copy_func=va_copy
 533 else if test "x$dbus_cv___va_copy" = "xyes"; then
 534   dbus_va_copy_func=__va_copy
 535 fi
 536 fi
 537
 538 if test -n "$dbus_va_copy_func"; then
 539   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 540 fi
 541
 542 AC_LANG_PUSH(C)
 543 AC_CACHE_CHECK([whether va_lists can be copied by value],
 544         dbus_cv_va_val_copy,
 545         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 546 [[
 547         #include <stdarg.h>
 548         #include <stdlib.h>
 549 ]],
 550 [[
 551         static void f (int i, ...) {
 552         va_list args1, args2;
 553         va_start (args1, i);
 554         args2 = args1;
 555         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 556           exit (1);
 557         va_end (args1); va_end (args2);
 558         }
 559         int main() {
 560           f (0, 42);
 561           return 0;
 562         }
 563 ]])],
 564         [dbus_cv_va_val_copy=yes],
 565         [dbus_cv_va_val_copy=no],
 566         [dbus_cv_va_val_copy=yes])
 567 ])
 568 AC_LANG_POP(C)
 569
 570 if test "x$dbus_cv_va_val_copy" = "xno"; then
 571   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 572 fi
 573
 574
 575 #### Atomic integers
 576
 577 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 578   dbus_cv_sync_sub_and_fetch,
 579   [AC_LINK_IFELSE([
 580      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 581      [dbus_cv_sync_sub_and_fetch=yes],
 582      [dbus_cv_sync_sub_and_fetch=no])
 583   ])
 584
 585 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 586    have_sync=1
 587 else
 588    have_sync=0
 589 fi
 590
 591 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 592
 593 #### Various functions
 594 AC_SEARCH_LIBS(socket,[socket network])
 595 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 596
 597 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid)
 598
 599 AC_CHECK_HEADERS([syslog.h])
 600 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 601   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 602 fi
 603
 604 #### Check for broken poll; taken from Glib's configure
 605
 606 AC_MSG_CHECKING([for broken poll])
 607 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 608     #include <stdlib.h>
 609     #include <fcntl.h>
 610     #include <poll.h>
 611     #ifdef HAVE_SYS_POLL_H
 612     #include <sys/poll.h>
 613     #endif
 614     int main(void) {
 615       struct pollfd fds[1];
 616       int fd;
 617       fd = open("/dev/null", 1);
 618       fds[0].fd = fd;
 619       fds[0].events = POLLIN;
 620       fds[0].revents = 0;
 621       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 622             exit(1);  /* Does not work for devices -- fail */
 623       }
 624       exit(0);
 625     }]])],
 626   [broken_poll=no],
 627   [broken_poll=yes
 628    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 629   [broken_poll="no (cross compiling)"])
 630 AC_MSG_RESULT($broken_poll)
 631
 632 AC_MSG_CHECKING(for dirfd)
 633 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 634 #include <sys/types.h>
 635 #include <dirent.h>
 636 ]], [[
 637 DIR *dirp;
 638 dirp = opendir(".");
 639 dirfd(dirp);
 640 closedir(dirp);
 641 ]])],
 642 [dbus_have_dirfd=yes],
 643 [dbus_have_dirfd=no])
 644 AC_MSG_RESULT($dbus_have_dirfd)
 645 if test "$dbus_have_dirfd" = yes; then
 646         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 647 else
 648         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 649         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 650 #include <sys/types.h>
 651 #include <dirent.h>
 652         ]], [[
 653 DIR *dirp;
 654 int fd;
 655 dirp = opendir(".");
 656 fd = dirp->dd_fd;
 657 closedir(dirp);
 658         ]])],
 659         [dbus_have_ddfd=yes],
 660         [dbus_have_ddfd=no])
 661         AC_MSG_RESULT($dbus_have_ddfd)
 662         if test "$dbus_have_ddfd" = yes; then
 663                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 664         fi
 665 fi
 666
 667 AC_CHECK_HEADERS(sys/resource.h)
 668
 669 AC_CHECK_HEADERS(dirent.h)
 670
 671 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 672
 673 AC_CHECK_HEADERS(errno.h)
 674
 675 AC_CHECK_HEADERS(signal.h)
 676
 677 AC_CHECK_HEADERS(locale.h)
 678
 679 AC_CHECK_HEADERS(byteswap.h)
 680
 681 AC_CHECK_HEADERS(unistd.h)
 682
 683 AC_CHECK_HEADERS(ws2tcpip.h)
 684
 685 AC_CHECK_HEADERS(alloca.h)
 686
 687 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 688 #
 689 case $host_os in
 690     solaris*)
 691        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 692 esac
 693
 694 # checking for a posix version of getpwnam_r
 695 # if we are cross compiling and can not run the test
 696 # assume getpwnam_r is the posix version
 697 # it is up to the person cross compiling to change
 698 # this behavior if desired
 699 AC_LANG_PUSH(C)
 700 AC_CACHE_CHECK([for posix getpwnam_r],
 701                 ac_cv_func_posix_getpwnam_r,
 702                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 703 [[
 704 #include <errno.h>
 705 #include <pwd.h>
 706 ]],
 707 [[
 708     char buffer[10000];
 709     struct passwd pwd, *pwptr = &pwd;
 710     int error;
 711     errno = 0;
 712     error = getpwnam_r ("", &pwd, buffer,
 713                         sizeof (buffer), &pwptr);
 714    return (error < 0 && errno == ENOSYS)
 715            || error == ENOSYS;
 716 ]])],
 717         [ac_cv_func_posix_getpwnam_r=yes],
 718         [ac_cv_func_posix_getpwnam_r=no],
 719         [ac_cv_func_posix_getpwnam_r=yes]
 720 )])
 721 AC_LANG_POP(C)
 722
 723 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 724         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 725                 [Have POSIX function getpwnam_r])
 726 else
 727         AC_CACHE_CHECK([for nonposix getpwnam_r],
 728                 ac_cv_func_nonposix_getpwnam_r,
 729                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 730                         struct passwd pwd;
 731                         getpwnam_r ("", &pwd, buffer,
 732                                         sizeof (buffer));]])],
 733                         [ac_cv_func_nonposix_getpwnam_r=yes],
 734                         [ac_cv_func_nonposix_getpwnam_r=no])])
 735                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 736                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 737                         [Have non-POSIX function getpwnam_r])
 738         fi
 739 fi
 740
 741 dnl check for socklen_t
 742 AC_MSG_CHECKING(whether socklen_t is defined)
 743 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 744 #include <sys/types.h>
 745 #include <sys/socket.h>
 746 #include <netdb.h>
 747 ]], [[
 748 socklen_t foo;
 749 foo = 1;
 750 ]])],
 751 [dbus_have_socklen_t=yes],
 752 [dbus_have_socklen_t=no])
 753 AC_MSG_RESULT($dbus_have_socklen_t)
 754
 755 if test "x$dbus_have_socklen_t" = "xyes"; then
 756     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 757 fi
 758
 759 dnl check for writev header and writev function so we're
 760 dnl good to go if HAVE_WRITEV gets defined.
 761 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 762
 763 dnl needed on darwin for NAME_MAX
 764 AC_CHECK_HEADERS(sys/syslimits.h)
 765
 766 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 767 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 768 #include <sys/socket.h> ]])
 769
 770 dnl check for flavours of varargs macros (test from GLib)
 771 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 772 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 773 int a(int p1, int p2, int p3);
 774 #define call_a(...) a(1,__VA_ARGS__)
 775 call_a(2,3);
 776 ]])],
 777 [dbus_have_iso_c_varargs=yes],
 778 [dbus_have_iso_c_varargs=no])
 779 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 780
 781 AC_MSG_CHECKING(for GNUC varargs macros)
 782 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 783 int a(int p1, int p2, int p3);
 784 #define call_a(params...) a(1,params)
 785 call_a(2,3);
 786 ]])],
 787 [dbus_have_gnuc_varargs=yes],
 788 [dbus_have_gnuc_varargs=no])
 789 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 790
 791 dnl Output varargs tests
 792 if test x$dbus_have_iso_c_varargs = xyes; then
 793     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 794 fi
 795 if test x$dbus_have_gnuc_varargs = xyes; then
 796     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 797 fi
 798
 799 dnl Check for various credentials.
 800 AC_MSG_CHECKING(for struct cmsgcred)
 801 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 802 #include <sys/types.h>
 803 #include <sys/socket.h>
 804 ]], [[
 805 struct cmsgcred cred;
 806
 807 cred.cmcred_pid = 0;
 808 ]])],
 809 [dbus_have_struct_cmsgcred=yes],
 810 [dbus_have_struct_cmsgcred=no])
 811 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 812
 813 if test x$dbus_have_struct_cmsgcred = xyes; then
 814     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 815 fi
 816
 817 AC_CHECK_FUNCS(getpeerucred getpeereid)
 818
 819 AC_CHECK_FUNCS(pipe2 accept4)
 820
 821 #### Abstract sockets
 822
 823 if test x$enable_abstract_sockets = xauto; then
 824 AC_LANG_PUSH(C)
 825 warn_on_xcompile=no
 826 AC_CACHE_CHECK([abstract socket namespace],
 827                 ac_cv_have_abstract_sockets,
 828                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 829 [[
 830 #include <sys/types.h>
 831 #include <stdlib.h>
 832 #include <string.h>
 833 #include <stdio.h>
 834 #include <sys/socket.h>
 835 #include <sys/un.h>
 836 #include <errno.h>
 837 ]],
 838 [[
 839   size_t slen;
 840   int listen_fd;
 841   struct sockaddr_un addr;
 842
 843   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 844
 845   if (listen_fd < 0)
 846     {
 847       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 848       exit (1);
 849     }
 850
 851   memset (&addr, '\0', sizeof (addr));
 852   addr.sun_family = AF_UNIX;
 853   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 854   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 855    * beginning.
 856    */
 857   slen = SUN_LEN(&addr);
 858   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 859
 860   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 861     {
 862        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 863                 strerror (errno));
 864        exit (1);
 865     }
 866   else
 867     exit (0);
 868 ]])],
 869               [ac_cv_have_abstract_sockets=yes],
 870               [ac_cv_have_abstract_sockets=no],
 871               [
 872                 ac_cv_have_abstract_sockets=no
 873                 warn_on_xcompile=yes
 874               ]
 875 )])
 876 if test x$warn_on_xcompile = xyes ; then
 877   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 878 fi
 879 AC_LANG_POP(C)
 880 fi
 881
 882 if test x$enable_abstract_sockets = xyes; then
 883     if test x$ac_cv_have_abstract_sockets = xno; then
 884         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 885     fi
 886 fi
 887
 888 if test x$enable_abstract_sockets = xno; then
 889    ac_cv_have_abstract_sockets=no;
 890 fi
 891
 892 if test x$ac_cv_have_abstract_sockets = xyes ; then
 893    DBUS_PATH_OR_ABSTRACT=abstract
 894    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 895 else
 896    DBUS_PATH_OR_ABSTRACT=path
 897 fi
 898
 899 # this is used in addresses to prefer abstract, e.g.
 900 # unix:path=/foo or unix:abstract=/foo
 901 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 902
 903 #### Sort out XML library
 904
 905 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 906              [ AC_CHECK_HEADERS(expat.h, [],
 907                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 908              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 909
 910 XML_LIBS=-lexpat
 911 XML_CFLAGS=
 912 AC_SUBST([XML_CFLAGS])
 913 AC_SUBST([XML_LIBS])
 914
 915 # Thread lib detection
 916 AC_ARG_VAR([THREAD_LIBS])
 917 save_libs="$LIBS"
 918 LIBS="$LIBS $THREAD_LIBS"
 919
 920 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 921
 922 # Don't do these automatic checks if the user set THREAD_LIBS on the
 923 # configure command-line. If they did, we assume they're right.
 924 #
 925 # We also don't do these checks on Windows, because you don't need magical
 926 # linker flags to have threading support there.
 927 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 928   [
 929     # Mandatory pthread functions. In principle, some of these could be made
 930     # optional if there are platforms that don't have them.
 931     #
 932     # Currently, we only look in -lpthread.
 933     # In principle we might need to look in -lpthreads, -lthreads, ...
 934     # as well - please file a bug if your platform needs this.
 935     AC_SEARCH_LIBS([pthread_cond_timedwait],
 936         [pthread],
 937         [THREAD_LIBS="$LIBS"],
 938         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 939         [])
 940     AC_SEARCH_LIBS([pthread_mutexattr_init],
 941         [pthread],
 942         [THREAD_LIBS="$LIBS"],
 943         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 944         [])
 945     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 946         [pthread],
 947         [THREAD_LIBS="$LIBS"],
 948         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 949         [])
 950
 951     # Optional, for monotonic clocks. Because it's optional, this check
 952     # is non-fatal if we don't find it.
 953     AC_SEARCH_LIBS([pthread_condattr_setclock],
 954         [pthread],
 955         [THREAD_LIBS="$LIBS"])
 956
 957     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 958       [
 959         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 960         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 961         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 962 [[#include <time.h>
 963 #include <pthread.h>
 964 ]], [[
 965 struct timespec monotonic_timer;
 966 pthread_condattr_t attr;
 967 pthread_condattr_init (&attr);
 968 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 969 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 970 ]])],
 971             [have_clock_monotonic=true],
 972             [have_clock_monotonic=false])
 973         AS_IF([test x$have_clock_monotonic = xtrue],
 974           [
 975             AC_MSG_RESULT([found])
 976             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 977           ],
 978           [AC_MSG_RESULT([not found])])
 979       ]) dnl have pthread_condattr_setclock
 980   ]) dnl on Unix
 981
 982 LIBS="$save_libs"
 983
 984 AC_SUBST([THREAD_LIBS])
 985
 986 # SELinux detection
 987 if test x$enable_selinux = xno ; then
 988     have_selinux=no;
 989 else
 990     # See if we have SELinux library
 991     AC_CHECK_LIB(selinux, is_selinux_enabled,
 992                  have_selinux=yes, have_selinux=no)
 993
 994     # see if we have the SELinux header with the new D-Bus stuff in it
 995     if test x$have_selinux = xyes ; then
 996         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 997         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 998                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 999                             #else
1000                             #error DBUS__ACQUIRE_SVC not defined
1001                             #endif]])],
1002                           [have_selinux=yes],
1003                           [have_selinux=no])
1004         AC_MSG_RESULT($have_selinux)
1005     fi
1006
1007     if test x$enable_selinux = xauto ; then
1008         if test x$have_selinux = xno ; then
1009                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1010         fi
1011     else
1012         if test x$have_selinux = xno ; then
1013                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1014         fi
1015     fi
1016 fi
1017
1018 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1019
1020 if test x$have_selinux = xyes ; then
1021     # the selinux code creates threads
1022     # which requires libpthread even on linux
1023     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1024                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1025
1026     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1027     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1028 else
1029     SELINUX_LIBS=
1030 fi
1031
1032 # inotify checks
1033 if test x$enable_inotify = xno ; then
1034     have_inotify=no;
1035 else
1036     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1037 fi
1038
1039 dnl check if inotify backend is enabled
1040 if test x$have_inotify = xyes; then
1041    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1042    AC_CHECK_FUNCS(inotify_init1)
1043 fi
1044
1045 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1046
1047 # For simplicity, we require the userland API for epoll_create1 at
1048 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1049 # not to have it at runtime.
1050 AC_ARG_ENABLE([epoll],
1051               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1052               [enable_epoll=$enableval], [enable_epoll=auto])
1053 if test x$enable_epoll = xno; then
1054     have_linux_epoll=no
1055 else
1056     AC_MSG_CHECKING([for Linux epoll(4)])
1057     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1058         [
1059         #ifndef __linux__
1060         #error This is not Linux
1061         #endif
1062         #include <sys/epoll.h>
1063         ],
1064         [epoll_create1 (EPOLL_CLOEXEC);])],
1065         [have_linux_epoll=yes],
1066         [have_linux_epoll=no])
1067     AC_MSG_RESULT([$have_linux_epoll])
1068 fi
1069 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1070     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1071 fi
1072 if test x$have_linux_epoll = xyes; then
1073   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1074 fi
1075 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1076
1077 # kqueue checks
1078 if test x$enable_kqueue = xno ; then
1079     have_kqueue=no
1080 else
1081     have_kqueue=yes
1082     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1083     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1084
1085     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1086         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1087     fi
1088 fi
1089
1090 dnl check if kqueue backend is enabled
1091 if test x$have_kqueue = xyes; then
1092    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1093 fi
1094
1095 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1096
1097 # launchd checks
1098 if test x$enable_launchd = xno ; then
1099     have_launchd=no
1100 else
1101     have_launchd=yes
1102     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1103     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1104     if test "x$LAUNCHCTL" = "x"; then
1105         have_launchd=no
1106     fi
1107
1108     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1109         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1110     fi
1111 fi
1112
1113 dnl check if launchd is enabled
1114 if test x$have_launchd = xyes; then
1115     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1116 fi
1117
1118 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1119
1120 #### Directory to place launchd agent file
1121 if test "x$with_launchd_agent_dir" = "x"; then
1122    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1123 else
1124    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1125 fi
1126
1127 AC_SUBST(LAUNCHD_AGENT_DIR)
1128
1129 dnl console owner file
1130 if test x$enable_console_owner_file = xno ; then
1131     have_console_owner_file=no;
1132 else
1133     case $host_os in
1134     solaris*)
1135         have_console_owner_file=yes;
1136         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1137         ;;
1138     *)
1139         have_console_owner_file=no;;
1140     esac
1141 fi
1142
1143 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1144
1145 dnl systemd detection
1146 if test x$enable_systemd = xno ; then
1147     have_systemd=no;
1148 else
1149     PKG_CHECK_MODULES(SYSTEMD,
1150         [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1151         have_systemd=yes,
1152         have_systemd=no)
1153 fi
1154
1155 if test x$have_systemd = xyes; then
1156     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1157 fi
1158
1159 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1160     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1161 fi
1162
1163 # libaudit detection
1164 if test x$enable_libaudit = xno ; then
1165     have_libaudit=no;
1166 else
1167     # See if we have audit daemon & capabilities library
1168     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1169                  have_libaudit=yes, have_libaudit=no)
1170     if test x$have_libaudit = xyes ; then
1171         AC_CHECK_LIB(cap-ng, capng_clear,
1172                  have_libaudit=yes, have_libaudit=no)
1173     fi
1174 fi
1175
1176 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1177
1178 if test x$have_libaudit = xyes ; then
1179     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1180     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1181 fi
1182
1183 AC_SUBST([SELINUX_LIBS])
1184
1185 # Check for ADT API (Solaris Basic Security Mode auditing)
1186 AC_MSG_CHECKING(for ADT API)
1187 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1188 #include <bsm/adt.h>
1189 adt_user_context = ADT_USER;
1190 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1191
1192 if test ${check_adt_audit} = yes
1193 then
1194    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1195    ADT_LIBS="-lbsm"
1196    LIBS="-lbsm $LIBS"
1197    AC_MSG_RESULT(yes)
1198 else
1199    AC_MSG_RESULT(no)
1200 fi
1201 AC_SUBST([ADT_LIBS])
1202
1203 # Check for SCM_RIGHTS
1204 AC_MSG_CHECKING([for SCM_RIGHTS])
1205 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1206 #include <sys/types.h>
1207 #include <sys/socket.h>
1208 #include <sys/un.h>
1209 static int x = SCM_RIGHTS;
1210 ]], [[]])],
1211 [ AC_MSG_RESULT([supported])
1212   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1213 [ AC_MSG_RESULT([not supported]) ])
1214
1215 NETWORK_libs=
1216 if test x$dbus_win = xyes ; then
1217   if test x$dbus_wince = xyes ; then
1218     NETWORK_libs="-lws2"
1219   else
1220     NETWORK_libs="-lws2_32 -liphlpapi"
1221   fi
1222 fi
1223
1224 AC_SUBST([NETWORK_libs])
1225
1226 AC_ARG_WITH([valgrind],
1227   [AS_HELP_STRING([--with-valgrind],
1228      [Add instrumentation to help valgrind to understand our allocator])],
1229   [],
1230   [with_valgrind=no])
1231
1232 AS_IF([test "x$with_valgrind" = xauto],
1233   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1234     [with_valgrind=yes], [with_valgrind=no])])
1235
1236 if test x$with_valgrind != xno; then
1237   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1238   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1239 fi
1240
1241 # Determine maximum number of Unix fds which may be passed
1242 AS_CASE([$host_os],
1243   [*qnx*],
1244     [DEFAULT_MESSAGE_UNIX_FDS=256],
1245   [*],
1246     [DEFAULT_MESSAGE_UNIX_FDS=1024])
1247 AC_DEFINE_UNQUOTED([DBUS_DEFAULT_MESSAGE_UNIX_FDS],
1248   [$DEFAULT_MESSAGE_UNIX_FDS],
1249   [Default for dbus_connection_get_max_message_unix_fds()])
1250 AC_SUBST([DEFAULT_MESSAGE_UNIX_FDS])
1251
1252 #### Set up final flags
1253 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs"
1254 AC_SUBST([LIBDBUS_LIBS])
1255
1256 ### X11 detection
1257 DBUS_X_LIBS=
1258 DBUS_X_CFLAGS=
1259
1260 AC_ARG_ENABLE([x11-autolaunch],
1261   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1262   [], [enable_x11_autolaunch=auto])
1263
1264 if test "x$dbus_win" = xyes; then
1265     if test "x$enable_x11_autolaunch" = xyes; then
1266         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1267     fi
1268
1269     enable_x11_autolaunch=no
1270     have_x11=no
1271 else
1272     AC_PATH_XTRA
1273
1274     if test "x$no_x" = xyes; then
1275         have_x11=no
1276     else
1277         have_x11=yes
1278         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1279         DBUS_X_CFLAGS="$X_CFLAGS"
1280     fi
1281 fi
1282
1283 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1284     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1285 else
1286     # move from "auto" to "yes" or "no" if necessary
1287     if test "x$enable_x11_autolaunch" != xno; then
1288         enable_x11_autolaunch="$have_x11"
1289     fi
1290 fi
1291
1292 if test "x$have_x11" = xyes ; then
1293    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1294 fi
1295
1296 if test "x$enable_x11_autolaunch" = xyes ; then
1297    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1298 fi
1299
1300 AC_SUBST([DBUS_X_CFLAGS])
1301 AC_SUBST([DBUS_X_LIBS])
1302
1303 #### gcc warning flags
1304
1305 cc_supports_flag() {
1306   AC_MSG_CHECKING(whether $CC supports "$*")
1307   save_CFLAGS="$CFLAGS"
1308   CFLAGS="$*"
1309   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1310   CFLAGS="$save_CFLAGS"
1311   AC_MSG_RESULT([$rc])
1312   test "x$rc" = xyes
1313 }
1314
1315 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1316   dnl Use -Werror by default if:
1317   dnl - we're not on Windows (too many warnings), and
1318   dnl - we're in developer mode (a D-Bus developer, not a distro or end-user)
1319   dnl Override with --enable-Werror or --disable-Werror
1320   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$enable_developer = xyes],
1321
1322   dnl Enable these warnings if possible:
1323   [all \
1324    extra \
1325    char-subscripts \
1326    missing-declarations \
1327    missing-prototypes \
1328    nested-externs \
1329    pointer-arith \
1330    cast-align \
1331    no-address \
1332    float-equal \
1333    declaration-after-statement \
1334   ],
1335
1336   dnl Disable these warnings if possible, make them non-fatal if possible,
1337   dnl and don't enable -Werror unless we succeeded.
1338   dnl
1339   dnl Intentional:
1340   dnl - $DISABLE_UNUSED_WARNINGS disables unused-label warnings if not
1341   dnl   checking or not asserting
1342   dnl - missing field initializers being 0 is a C feature, not a bug
1343   dnl - unused-parameter is to make writing callbacks less annoying
1344   dnl
1345   dnl To be fixed one day:
1346   dnl - sign-compare and pointer-sign are workarounds for fd.o #17433
1347   dnl - type-limits is probably a bug too, but having the rest of -Wextra
1348   dnl   is better than nothing
1349   [$DISABLE_UNUSED_WARNINGS \
1350    missing-field-initializers \
1351    unused-parameter \
1352    sign-compare \
1353    pointer-sign \
1354    type-limits \
1355   ])
1356
1357 if test "x$GCC" = "xyes"; then
1358   # We're treating -fno-common like a warning: it makes the linker more
1359   # strict, because on some systems the linker is *always* this strict
1360   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1361
1362   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1363   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1364
1365   if test "x$enable_ansi" = "xyes"; then
1366     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1367       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1368   fi
1369 fi
1370
1371 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1372 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1373 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1374 dnl is the next best thing
1375 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1376
1377 case $host_os in
1378     solaris*)
1379         # Solaris' C library apparently needs these runes to be threadsafe...
1380         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1381         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1382         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1383         # ... and this opt-in to get file descriptor passing support
1384         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1385         ;;
1386 esac
1387
1388 ### Doxygen Documentation
1389
1390 AC_PATH_PROG(DOXYGEN, doxygen, no)
1391
1392 AC_MSG_CHECKING([whether to build Doxygen documentation])
1393
1394 if test x$DOXYGEN = xno ; then
1395     have_doxygen=no
1396 else
1397     have_doxygen=yes
1398 fi
1399
1400 if test x$enable_doxygen_docs = xauto ; then
1401     if test x$have_doxygen = xno ; then
1402         enable_doxygen_docs=no
1403     else
1404         enable_doxygen_docs=yes
1405     fi
1406 fi
1407
1408 if test x$enable_doxygen_docs = xyes; then
1409     if test x$have_doxygen = xno; then
1410         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1411     fi
1412 fi
1413
1414 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1415 AC_MSG_RESULT($enable_doxygen_docs)
1416
1417 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1418 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1419
1420 ### XML Documentation
1421
1422 AC_PATH_PROG(XMLTO, xmlto, no)
1423
1424 AC_MSG_CHECKING([whether to build XML documentation])
1425
1426 if test x$XMLTO = xno ; then
1427     have_xmlto=no
1428 else
1429     have_xmlto=yes
1430 fi
1431
1432 if test x$enable_xml_docs = xauto ; then
1433     if test x$have_xmlto = xno ; then
1434         enable_xml_docs=no
1435     else
1436         enable_xml_docs=yes
1437     fi
1438 fi
1439
1440 if test x$enable_xml_docs = xyes; then
1441     if test x$have_xmlto = xno; then
1442         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1443     fi
1444 fi
1445
1446 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1447 AC_MSG_RESULT($enable_xml_docs)
1448
1449 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1450     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes])
1451
1452 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1453
1454 #### find the actual value for $prefix that we'll end up with
1455 ##   (I know this is broken and should be done in the Makefile, but
1456 ##    that's a major pain and almost nobody actually seems to care)
1457 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1458 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1459 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1460 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1461 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1462 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1463 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1464
1465 #### Check our operating system
1466 operating_system=unknown
1467 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1468    operating_system=redhat
1469 fi
1470
1471 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1472    operating_system=slackware
1473 fi
1474
1475 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1476    operating_system=cygwin
1477 fi
1478
1479 #### Sort out init scripts
1480
1481 if test x$with_init_scripts = x; then
1482     case x$operating_system in
1483         xredhat)        with_init_scripts=redhat ;;
1484         xslackware)     with_init_scripts=slackware ;;
1485         xcygwin)        with_init_scripts=cygwin ;;
1486         *)                      with_init_scripts=none ;;
1487     esac
1488 fi
1489
1490 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1491 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1492 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1493
1494 ##### systemd unit files
1495 AC_ARG_WITH([systemdsystemunitdir],
1496 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1497     [],
1498     [
1499     PKG_CHECK_EXISTS([systemd],
1500       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1501       [with_systemdsystemunitdir=no])
1502     ])
1503 if test "x$with_systemdsystemunitdir" != xno; then
1504    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1505 fi
1506 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1507
1508 ##### Set up location for system bus socket
1509 if ! test -z "$with_system_socket"; then
1510    DBUS_SYSTEM_SOCKET=$with_system_socket
1511 else
1512    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1513 fi
1514
1515 AC_SUBST(DBUS_SYSTEM_SOCKET)
1516 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1517
1518 ## System bus only listens on local domain sockets, and never
1519 ## on an abstract socket (so only root can create the socket).
1520 ##
1521 ## This won't work on Windows. It's not meant to - the system bus is
1522 ## meaningless on Windows anyway.
1523 ##
1524 ## This has to be suitable for hard-coding in client libraries as well as
1525 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1526 ## and also to connect to. If this ever changes, it'll need to be split into
1527 ## two variables, one for the listening address and one for the connecting
1528 ## address.
1529 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1530 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1531 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1532
1533 #### Set up the pid file
1534 if ! test -z "$with_system_pid_file"; then
1535    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1536 elif test x$with_init_scripts = xredhat ; then
1537    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1538 else
1539    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1540 fi
1541
1542 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1543
1544 #### Directory to check for console ownership
1545 if ! test -z "$with_console_auth_dir"; then
1546    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1547 else
1548    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1549 fi
1550
1551 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1552 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1553
1554 #### File to check for console ownership
1555 if test x$have_console_owner_file = xyes; then
1556    if ! test -z "$with_console_owner_file"; then
1557       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1558    else
1559       DBUS_CONSOLE_OWNER_FILE=/dev/console
1560    fi
1561 else
1562   DBUS_CONSOLE_OWNER_FILE=
1563 fi
1564
1565 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1566 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1567
1568 #### User to start the system bus as
1569 if test -z "$with_dbus_user" ; then
1570     DBUS_USER=messagebus
1571 else
1572     DBUS_USER=$with_dbus_user
1573 fi
1574 AC_SUBST(DBUS_USER)
1575 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1576
1577 #### Prefix to install into
1578 DBUS_PREFIX=$EXPANDED_PREFIX
1579 AC_SUBST(DBUS_PREFIX)
1580 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1581
1582 #### Direcotry to install data files into
1583 DBUS_DATADIR=$EXPANDED_DATADIR
1584 AC_SUBST(DBUS_DATADIR)
1585 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1586
1587 #### Directory to install dbus-daemon
1588 if test -z "$with_dbus_daemondir" ; then
1589     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1590 else
1591     DBUS_DAEMONDIR=$with_dbus_daemondir
1592 fi
1593 AC_SUBST(DBUS_DAEMONDIR)
1594 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1595
1596 #### Directory to install the other binaries
1597 DBUS_BINDIR="$EXPANDED_BINDIR"
1598 AC_SUBST(DBUS_BINDIR)
1599 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1600
1601 #### Directory to install the libexec binaries
1602 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1603 AC_SUBST(DBUS_LIBEXECDIR)
1604 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1605
1606 #### Tell tests where to find certain stuff in builddir
1607
1608 DBUS_PWD=`pwd`
1609 # Useful in a cross-compilation environment, where the tests are run on the host system.
1610 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1611                            DBUS_PWD=$withval)
1612
1613 DBUS_TEST_EXEC="$DBUS_PWD/test"
1614 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1615
1616 AC_SUBST([DBUS_TEST_DATA])
1617 AC_SUBST([DBUS_TEST_EXEC])
1618
1619 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1620                    [Full path to the daemon in the builddir])
1621 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1622                    [Extension for executables, typically empty or .exe])
1623
1624 AC_DEFINE_UNQUOTED(TEST_BUS_LAUNCH_BINARY, ["$DBUS_PWD/tools/dbus-launch$EXEEXT"],
1625                    [Full path to the dbus-launch in the builddir])
1626
1627 ## Export the non-setuid external helper
1628 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1629 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1630 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1631                    [Full path to the launch helper test program in the builddir])
1632
1633 #### Find socket directories
1634 if ! test -z "$TMPDIR" ; then
1635    DEFAULT_SOCKET_DIR=$TMPDIR
1636 elif ! test -z "$TEMP" ; then
1637    DEFAULT_SOCKET_DIR=$TEMP
1638 elif ! test -z "$TMP" ; then
1639    DEFAULT_SOCKET_DIR=$TMP
1640 else
1641    DEFAULT_SOCKET_DIR=/tmp
1642 fi
1643
1644 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1645
1646 if ! test -z "$with_test_socket_dir" ; then
1647    TEST_SOCKET_DIR="$with_test_socket_dir"
1648 else
1649    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1650 fi
1651 AC_SUBST(TEST_SOCKET_DIR)
1652 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1653
1654 if test "x$dbus_unix" = xyes; then
1655   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1656 else
1657   TEST_LISTEN="tcp:host=localhost"
1658 fi
1659 AC_SUBST([TEST_LISTEN])
1660 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1661   [Listening address for regression tests])
1662
1663 if ! test -z "$with_session_socket_dir" ; then
1664    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1665 else
1666    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1667 fi
1668 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1669 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1670
1671 # This must be a listening address. It doesn't necessarily need to be an
1672 # address you can connect to - it can be something vague like
1673 # "nonce-tcp:".
1674 #
1675 # The default varies by platform.
1676 AC_ARG_WITH([dbus_session_bus_listen_address],
1677             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1678                            [default address for a session bus to listen on (see configure.ac)]),
1679             [with_dbus_session_bus_listen_address=$withval],
1680             [with_dbus_session_bus_listen_address=])
1681
1682 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1683         # the user specified something, trust them
1684         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1685 elif test x$dbus_win = xyes; then
1686         # On Windows, you can (and should) listen on autolaunch addresses,
1687         # because autolaunching is different.
1688         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1689         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1690 elif test x$have_launchd = xyes; then
1691         # Mac OS X default is to use launchd
1692         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1693 else
1694         # The default on all other Unix platforms (notably Linux)
1695         # is to create a randomly named socket in /tmp or similar
1696         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1697 fi
1698 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1699
1700 # This must be an address you can connect to. It doesn't necessarily
1701 # need to be an address you can listen on - it can be "autolaunch:",
1702 # even on Unix.
1703 #
1704 # The default varies by platform.
1705 AC_ARG_WITH([dbus_session_bus_connect_address],
1706             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1707                            [fallback address for a session bus client to connect to (see configure.ac)]),
1708             [with_dbus_session_bus_connect_address=$withval],
1709             [with_dbus_session_bus_connect_address=])
1710
1711 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1712         # the user specified something, trust them
1713         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1714 elif test x$dbus_win = xyes; then
1715         # Windows autolaunching is a bit different; leaving it in its own
1716         # branch of the conditional because the default might conceivably
1717         # change (see #38201)
1718         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1719 else
1720         # The default on all other Unix platforms (notably Linux)
1721         # is to use auto-launching - this works a bit differently on Mac OS X
1722         # but comes out basically the same in the end
1723         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1724 fi
1725 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1726 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1727   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1728   [Fallback address for session bus clients])
1729
1730 # darwin needs this to initialize the environment
1731 AC_CHECK_HEADERS(crt_externs.h)
1732 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1733 AH_VERBATIM(_DARWIN_ENVIRON,
1734 [
1735 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1736 # include <sys/time.h>
1737 # include <crt_externs.h>
1738 # define environ (*_NSGetEnviron())
1739 #endif
1740 ])
1741
1742 AC_ARG_ENABLE([stats],
1743   [AS_HELP_STRING([--enable-stats],
1744     [enable bus daemon usage statistics])],
1745   [], [enable_stats=no])
1746 if test "x$enable_stats" = xyes; then
1747   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1748     [Define to enable bus daemon usage statistics])
1749 fi
1750
1751 #enable smack label support
1752 AC_ARG_ENABLE([smack], [AS_HELP_STRING([--enable-smack], [enable SMACK security checks])], [], [enable_smack=no])
1753 if test "x$enable_smack" = xyes; then
1754   PKG_CHECK_MODULES([LIBSMACK], [libsmack >= 1.0],
1755      [AC_DEFINE([DBUS_ENABLE_SMACK], [1], [Define to enable SMACK security features])],
1756      [AC_MSG_ERROR([libsmack is required to enable smack support])])
1757 fi
1758
1759 AC_SUBST([LIBSMACK_CFLAGS])
1760 AC_SUBST([LIBSMACK_LIBS])
1761
1762 #enable cynara integration
1763 AC_ARG_ENABLE([cynara], [AS_HELP_STRING([--enable-cynara], [enable Cynara integration])], [], [enable_cynara=no])
1764 if test "x$enable_cynara" = xyes; then
1765   PKG_CHECK_MODULES([CYNARA], [cynara-client-async >= 0.4.2 cynara-session >= 0.4.2],
1766      [AC_DEFINE([DBUS_ENABLE_CYNARA], [1], [Define to enable Cynara privilege checks in dbus-daemon])],
1767      [AC_MSG_ERROR([libcynara-client-async and cynara-session are required to enable Cynara integration])])
1768 fi
1769
1770 AC_SUBST([CYNARA_CFLAGS])
1771 AC_SUBST([CYNARA_LIBS])
1772
1773
1774 AC_CONFIG_FILES([
1775 Doxyfile
1776 dbus/versioninfo.rc
1777 dbus/dbus-arch-deps.h
1778 bus/system.conf
1779 bus/session.conf
1780 bus/messagebus
1781 bus/messagebus-config
1782 bus/org.freedesktop.dbus-session.plist
1783 bus/rc.messagebus
1784 bus/dbus.service
1785 bus/dbus.socket
1786 Makefile
1787 dbus/Makefile
1788 bus/Makefile
1789 tools/Makefile
1790 test/Makefile
1791 test/name-test/Makefile
1792 doc/Makefile
1793 doc/dbus-cleanup-sockets.1.xml
1794 doc/dbus-daemon.1.xml
1795 doc/dbus-launch.1.xml
1796 doc/dbus-monitor.1.xml
1797 doc/dbus-run-session.1.xml
1798 doc/dbus-send.1.xml
1799 doc/dbus-uuidgen.1.xml
1800 dbus-1.pc
1801 dbus-1-uninstalled.pc
1802 test/data/valid-config-files/debug-allow-all.conf
1803 test/data/valid-config-files/debug-allow-all-sha1.conf
1804 test/data/valid-config-files/debug-check-some.conf
1805 test/data/valid-config-files/incoming-limit.conf
1806 test/data/valid-config-files-system/debug-allow-all-pass.conf
1807 test/data/valid-config-files-system/debug-allow-all-fail.conf
1808 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1809 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1810 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1811 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1812 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1813 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1814 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1815 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1816 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1817 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1818 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1819 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1820 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1821 ])
1822 AC_OUTPUT
1823
1824 dnl ==========================================================================
1825 echo "
1826                     D-Bus $VERSION
1827                   ==============
1828
1829         prefix:                   ${EXPANDED_PREFIX}
1830         exec_prefix:              ${exec_prefix}
1831         libdir:                   ${EXPANDED_LIBDIR}
1832         libexecdir:               ${EXPANDED_LIBEXECDIR}
1833         bindir:                   ${EXPANDED_BINDIR}
1834         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1835         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1836         datadir:                  ${EXPANDED_DATADIR}
1837         source code location:     ${srcdir}
1838         compiler:                 ${CC}
1839         cflags:                   ${CFLAGS}
1840         cppflags:                 ${CPPFLAGS}
1841         cxxflags:                 ${CXXFLAGS}
1842         64-bit int:               ${DBUS_INT64_TYPE}
1843         32-bit int:               ${DBUS_INT32_TYPE}
1844         16-bit int:               ${DBUS_INT16_TYPE}
1845         Doxygen:                  ${DOXYGEN:-not found}
1846         xmlto:                    ${XMLTO:-not found}"
1847
1848 echo "
1849         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1850         gcc coverage profiling:   ${enable_compiler_coverage}
1851         Building embedded tests:  ${enable_embedded_tests}
1852         Building modular tests:   ${enable_modular_tests}
1853             - with GLib:          ${with_glib}
1854             - with dbus-glib:     ${with_dbus_glib}
1855         Building verbose mode:    ${enable_verbose_mode}
1856         Building assertions:      ${enable_asserts}
1857         Building checks:          ${enable_checks}
1858         Building bus stats API:   ${enable_stats}
1859         Building SELinux support: ${have_selinux}
1860         Building SMACK support:   ${enable_smack}
1861         Building inotify support: ${have_inotify}
1862         Building kqueue support:  ${have_kqueue}
1863         Building systemd support: ${have_systemd}
1864         Building X11 code:        ${have_x11}
1865         Building Doxygen docs:    ${enable_doxygen_docs}
1866         Building XML docs:        ${enable_xml_docs}
1867         Building launchd support: ${have_launchd}
1868         Init scripts style:       ${with_init_scripts}
1869         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1870         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1871         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1872         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1873         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1874         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1875         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1876         Console owner file:       ${have_console_owner_file}
1877         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1878         System bus user:          ${DBUS_USER}
1879         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1880         'make check' socket dir:  ${TEST_SOCKET_DIR}
1881 "
1882 if test x$have_launchd = xyes; then
1883         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1884 fi
1885 echo
1886
1887 if test x$enable_embedded_tests = xyes; then
1888         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1889 fi
1890 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1891         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1892 fi
1893 if test x$enable_compiler_coverage = xyes; then
1894         echo "NOTE: building with coverage profiling is definitely for developers only."
1895 fi
1896 if test x$enable_verbose_mode = xyes; then
1897         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1898 fi
1899 if test x$enable_asserts = xyes; then
1900         echo "NOTE: building with assertions increases library size and decreases performance."
1901 fi
1902 if test x$enable_checks = xno; then
1903         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1904 fi