configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins-good, GST_PLUGINS_GOOD_VERSION, 0, 9, 0, 1,
  16   GST_CVS="no", GST_CVS="yes")
  17
  18 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  19
  20 dnl our libraries and install dirs use major.minor as a version
  21 GST_MAJORMINOR=$GST_PLUGINS_GOOD_VERSION_MAJOR.$GST_PLUGINS_GOOD_VERSION_MINOR
  22 dnl we override it here if we need to for the release candidate of new series
  23 GST_MAJORMINOR=0.9
  24 AC_SUBST(GST_MAJORMINOR)
  25
  26 dnl CURRENT, REVISION, AGE
  27 dnl - library source changed -> increment REVISION
  28 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  29 dnl - interfaces added -> increment AGE
  30 dnl - interfaces removed -> AGE = 0
  31 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  32 AS_LIBTOOL(GST_PLUGINS_GOOD, 0, 0, 0)
  33 AS_LIBTOOL_TAGS([CXX])
  34 AM_PROG_LIBTOOL
  35
  36 dnl FIXME take something else ?
  37 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  38 AM_CONFIG_HEADER(config.h)
  39
  40 dnl Add parameters for aclocal
  41 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  42 ACLOCAL_FLAGS="-I m4 -I common/m4"
  43 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  44
  45 AC_PROG_CC
  46 AM_PROG_CC_STDC
  47 AM_PROG_AS
  48 AS="${CC}"
  49 AS_PROG_OBJC
  50
  51 dnl the gettext stuff needed
  52 AM_GNU_GETTEXT_VERSION(0.11.5)
  53 AM_GNU_GETTEXT([external])
  54
  55 GETTEXT_PACKAGE=gst-plugins-good-$GST_MAJORMINOR
  56 AC_SUBST(GETTEXT_PACKAGE)
  57 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  58                   [gettext package name])
  59
  60 dnl define LOCALEDIR in config.h
  61 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  62 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  63                    [gettext locale dir])
  64
  65 dnl decide on error flags
  66 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  67
  68 if test "x$GST_WALL" = "xyes"; then
  69    GST_ERROR="$GST_ERROR -Wall"
  70
  71    if test "x$GST_CVS" = "xyes"; then
  72      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  73    fi
  74 fi
  75
  76 dnl determine c++ compiler
  77 AC_PROG_CXX
  78 dnl determine if c++ is available on this system
  79 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  80 dnl determine c++ preprocessor
  81 AC_PROG_CXXCPP
  82 AC_ISC_POSIX
  83
  84 AC_HEADER_STDC([])
  85 AC_C_INLINE
  86 AX_CREATE_STDINT_H
  87
  88 dnl Check for malloc.h
  89 AC_CHECK_HEADER(malloc.h,[
  90   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  91 ])
  92
  93 dnl Check for a way to display the function name in debug output
  94 GST_CHECK_FUNCTION()
  95
  96 dnl Check for FIONREAD ioctl declaration :
  97 GST_CHECK_FIONREAD()
  98
  99 DEFAULT_AUDIOSINK="autoaudiosink"
 100 DEFAULT_VIDEOSINK="autovideosink"
 101 DEFAULT_AUDIOSRC="alsasrc"
 102 DEFAULT_VIDEOSRC="v4lsrc"
 103 DEFAULT_VISUALIZER="goom"
 104 case "$host" in
 105   *-sun-* | *pc-solaris* )
 106     DEFAULT_AUDIOSRC="sunaudiosrc"
 107     ;;
 108   *-darwin* )
 109     DEFAULT_AUDIOSRC="osxaudiosrc"
 110     ;;
 111 esac
 112
 113 AC_SUBST(DEFAULT_AUDIOSINK)
 114 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK,"$DEFAULT_AUDIOSINK",[Default audio sink])
 115 AC_SUBST(DEFAULT_AUDIOSRC)
 116 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC,"$DEFAULT_AUDIOSRC",[Default audio source])
 117 AC_SUBST(DEFAULT_VIDEOSINK)
 118 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK,"$DEFAULT_VIDEOSINK",[Default video sink])
 119 AC_SUBST(DEFAULT_VIDEOSRC)
 120 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC,"$DEFAULT_VIDEOSRC",[Default video source])
 121 AC_SUBST(DEFAULT_VISUALIZER)
 122 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER,"$DEFAULT_VISUALIZER",[Default visualizer])
 123
 124 dnl ############################################
 125 dnl # Super Duper options for plug-in building #
 126 dnl ############################################
 127
 128 dnl ext plug-ins; plug-ins that have external dependencies
 129 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 130 [HAVE_EXTERNAL=yes],enabled,
 131 [
 132   AC_MSG_WARN(building external plug-ins)
 133   BUILD_EXTERNAL="yes"
 134 ],[
 135   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 136   BUILD_EXTERNAL="no"
 137 ])
 138 # make BUILD_EXTERNAL available to Makefile.am
 139 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 140
 141 dnl ##############################
 142 dnl # Do automated configuration #
 143 dnl ##############################
 144
 145 dnl Check for tools:
 146 dnl ================
 147
 148 dnl allow for different autotools
 149 AS_AUTOTOOLS_ALTERNATE()
 150
 151 dnl modify pkg-config path
 152 AC_ARG_WITH(pkg-config-path,
 153    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 154    [export PKG_CONFIG_PATH=${withval}])
 155
 156 GST_DOC()
 157 dnl check architecture
 158 GST_ARCH()
 159
 160 dnl check for gconftool-2
 161
 162 dnl this macro defines an am conditional, so it needs to be run always
 163 AM_GCONF_SOURCE_2
 164
 165 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 166 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 167   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 168   if test x$GCONFTOOL = xno; then
 169     AC_MSG_WARN(Not installing GConf schemas)
 170     HAVE_GCONFTOOL="no"
 171   else
 172     HAVE_GCONFTOOL="yes"
 173   fi
 174   AC_SUBST(HAVE_GCONFTOOL)
 175 ])
 176
 177 dnl check for GConf libraries
 178 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 179 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 180   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 181   AC_SUBST(GCONF_CFLAGS)
 182   AC_SUBST(GCONF_LIBS)
 183 ])
 184
 185 dnl check for gstreamer
 186 dnl uninstalled is selected preferentially -- see pkg-config(1)
 187 GST_REQ=0.9.0.1
 188 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 189   HAVE_GST="yes", HAVE_GST="no")
 190
 191 if test "x$HAVE_GST" = "xno"; then
 192   AC_MSG_ERROR(no GStreamer found)
 193 fi
 194
 195 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 196 if test -z $GST_TOOLS_DIR; then
 197   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 198 fi
 199 AC_SUBST(GST_TOOLS_DIR)
 200
 201 dnl check for gstreamer-base; uninstalled is selected preferentially
 202 PKG_CHECK_MODULES(GST_BASE, gstreamer-base-$GST_MAJORMINOR >= $GST_REQ,
 203   HAVE_GST_BASE="yes", HAVE_GST_BASE="no")
 204
 205 if test "x$HAVE_GST_BASE" = "xno"; then
 206   AC_MSG_ERROR(no GStreamer Base Libs found)
 207 fi
 208
 209 AC_SUBST(GST_BASE_LIBS)
 210 AC_SUBST(GST_BASE_CFLAGS)
 211
 212 dnl check for gstreamer-plugins-base; uinstalled is selected preferentially
 213 PKG_CHECK_MODULES(GST_PLUGINS_BASE,
 214   gstreamer-plugins-base-$GST_MAJORMINOR >= $GST_REQ,
 215   HAVE_GST_PLUGINS_BASE="yes", HAVE_GST_PLUGINS_BASE="no")
 216
 217 if test "x$HAVE_GST_PLUGINS_BASE" = "xno"; then
 218   AC_MSG_ERROR(no GStreamer Base Plugins development files found)
 219 fi
 220
 221 AC_SUBST(GST_PLUGINS_BASE_LIBS)
 222 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 223
 224 dnl Determine endianness
 225 AC_C_BIGENDIAN
 226
 227 dnl Check for fast float to int casting as defined in C99
 228 AC_C99_FUNC_LRINT()
 229 AC_C99_FUNC_LRINTF()
 230
 231 dnl Check for essential libraries first:
 232 dnl ====================================
 233
 234 GST_GLIB2_CHECK()
 235
 236 dnl Check for additional libraries that we might use:
 237 dnl =================================================
 238
 239 # we set the defaults always to make sure we have non-empty variables
 240 # for the Makefile
 241
 242 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.0, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 243 AC_SUBST(LIBOIL_CFLAGS)
 244 AC_SUBST(LIBOIL_LIBS)
 245 if test "x${HAVE_LIBOIL}" = xyes ; then
 246   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 247   true
 248 fi
 249
 250 dnl ===========================================================================
 251 dnl ============================= gst plug-ins ================================
 252 dnl ===========================================================================
 253
 254 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 255 AC_SUBST(plugindir)
 256
 257 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 258 AC_SUBST(GST_PLUGIN_LDFLAGS)
 259
 260 dnl these are all the gst plug-ins, compilable without additional libs
 261 dnl videofilter is at the top because others depend on it
 262 GST_PLUGINS_ALL="\
 263                 videofilter \
 264                 alpha \
 265                 autodetect \
 266                 avi \
 267                 effectv \
 268                 fdsrc \
 269                 goom \
 270                 law \
 271                 level \
 272                 rtp     \
 273                 rtsp    \
 274                 smpte   \
 275                 udp     \
 276                 videobox \
 277                 wavenc \
 278                 wavparse \
 279                 "
 280
 281 AC_SUBST(GST_PLUGINS_ALL)
 282
 283 GST_PLUGINS_SELECTED=""
 284
 285 AC_ARG_WITH(plugins,
 286     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 287     [for i in `echo $withval | tr , ' '`; do
 288         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 289         then
 290             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 291         else
 292             echo "plug-in $i not recognized, ignoring..."
 293         fi
 294     done],
 295     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 296
 297 AC_SUBST(GST_PLUGINS_SELECTED)
 298
 299 dnl ==========================================================================
 300 dnl ============================= sys plug-ins ================================
 301 dnl ==========================================================================
 302
 303 dnl *** OSS audio *** (Linux, *BSD)
 304 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 305 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 306  HAVE_OSS="yes"
 307 dnl Linux and newer BSD versions :
 308  AC_CHECK_HEADER(sys/soundcard.h, [
 309    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 310    ] , [
 311 dnl Some old BSD versions :
 312    AC_CHECK_HEADER(soundcard.h, [
 313      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 314      ], [
 315   dnl Some old BSD versions :
 316      AC_CHECK_HEADER(machine/soundcard.h, [
 317        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,, [Define if OSS includes are in /machine/])
 318        ], [
 319        HAVE_OSS="no"
 320      ])
 321    ])
 322  ])
 323 ])
 324
 325 dnl ###########################
 326 dnl # Configure external libs #
 327 dnl ###########################
 328
 329 dnl *** aalib ***
 330 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 331 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 332   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 333   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 334 ])
 335
 336 dnl **** ESound ****
 337 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 338 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink, [
 339   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 340     HAVE_ESD="yes"
 341     AC_SUBST(ESD_CFLAGS)
 342     AC_SUBST(ESD_LIBS)
 343   ], [
 344     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 345     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 346   ])
 347 ])
 348
 349 dnl *** FLAC ***
 350 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 351 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 352   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC -lm")
 353   dnl API change in FLAC 1.1.1, so require that...
 354   if test x$HAVE_FLAC = xyes; then
 355     AC_CHECK_DECL(FLAC__SEEKABLE_STREAM_ENCODER_TELL_ERROR,
 356                   HAVE_FLAC="yes", HAVE_FLAC="no", [
 357 #include <FLAC/seekable_stream_encoder.h>
 358                   ])
 359   fi
 360   AC_SUBST(FLAC_LIBS)
 361 ])
 362
 363 dnl *** jpeg ***
 364 dnl FIXME: we could use header checks here as well IMO
 365 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 366 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
 367   AC_ARG_WITH(jpeg-mmx,
 368     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 369   OLD_LIBS="$LIBS"
 370   if test x$with_jpeg_mmx != x; then
 371     LIBS="$LIBS -L$with_jpeg_mmx"
 372   fi
 373   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 374   JPEG_LIBS="$LIBS -ljpeg-mmx"
 375   LIBS="$OLD_LIBS"
 376   if test x$HAVE_JPEG != xyes; then
 377     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 378     JPEG_LIBS="-ljpeg"
 379   fi
 380   AC_SUBST(JPEG_LIBS)
 381 ])
 382
 383
 384 dnl *** ladspa ***
 385 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
 386 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
 387   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
 388 ])
 389
 390 dnl *** libcaca ***
 391 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 392 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
 393   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 394   AC_SUBST(LIBCACA_CFLAGS)
 395   AC_SUBST(LIBCACA_LIBS)
 396 ])
 397
 398 dnl *** libdv ***
 399 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 400 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
 401   PKG_CHECK_MODULES(LIBDV, libdv >= 0.100, HAVE_LIBDV="yes", HAVE_LIBDV="no")
 402   AC_SUBST(LIBDV_CFLAGS)
 403   AC_SUBST(LIBDV_LIBS)
 404 ])
 405
 406 dnl *** libpng ***
 407 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 408 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
 409   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
 410   AC_SUBST(LIBPNG_CFLAGS)
 411   AC_SUBST(LIBPNG_LIBS)
 412 ])
 413
 414 dnl *** dv1394 ***
 415 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 416 GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], dv1394src, [
 417   dnl we need to test three headers and three libs
 418   GST_CHECK_LIBHEADER(RAW1394,
 419     raw1394, raw1394_new_handle,,
 420     libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
 421   GST_CHECK_LIBHEADER(AVC1394,
 422     avc1394, avc1394_send_command, $RAW1394_LIBS,
 423     libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 424   GST_CHECK_LIBHEADER(ROM1394,
 425     rom1394, rom1394_free_directory, $RAW1394_LIBS,
 426     libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 427
 428   dnl now see how far we got
 429   if test x$HAVE_RAW1394 = xyes && \
 430      test x$HAVE_AVC1394 = xyes && \
 431      test x$HAVE_ROM1394 = xyes; then
 432        HAVE_DV1394=yes
 433        DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 434        AC_SUBST(DV1394_LIBS)
 435   else
 436        HAVE_DV1394=no
 437   fi
 438 ])
 439
 440 dnl *** shout2 ***
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 442 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
 443   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
 444     HAVE_SHOUT2="yes"
 445     AC_SUBST(SHOUT2_CFLAGS)
 446     AC_SUBST(SHOUT2_LIBS)
 447   ], [
 448     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
 449     AC_SUBST(SHOUT2_CFLAGS)
 450     AC_SUBST(SHOUT2_LIBS)
 451   ])
 452 ])
 453
 454 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 455 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 456 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 457 dnl   speex_jitter.h is 1.1.x only
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 459 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
 460   PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, [
 461     HAVE_SPEEX="yes"
 462     AC_SUBST(SPEEX_CFLAGS)
 463     AC_SUBST(SPEEX_LIBS)
 464   ], [
 465     GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 466       AC_CHECK_HEADER(speex/speex_jitter.h, [
 467         dnl speex 1.1.x :
 468         GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 469           dnl speex 1.1.5 or + :
 470           HAVE_SPEEX="yes"
 471           SPEEX_LIBS="-lspeex"
 472           AC_SUBST(SPEEX_CFLAGS)
 473           AC_SUBST(SPEEX_LIBS)
 474         ],[
 475           HAVE_SPEEX="no"
 476         ])
 477       ],[
 478         dnl speex 1.0.x :
 479           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 480             dnl speex 1.0.4
 481             HAVE_SPEEX="yes"
 482             SPEEX_LIBS="-lspeex"
 483             AC_SUBST(SPEEX_CFLAGS)
 484             AC_SUBST(SPEEX_LIBS)
 485
 486             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 487               [defined if speex 1.0.x API detected])
 488         ],[
 489             HAVE_SPEEX="no"
 490             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 491         ], [
 492 #include <speex/speex.h>
 493         ])
 494       ])
 495     ])
 496   ])
 497 ])
 498
 499 dnl also add builddir include for enumtypes and marshal
 500 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
 501
 502 AC_SUBST(GST_LIBS)
 503 AC_SUBST(GST_CFLAGS)
 504
 505 dnl ######################
 506 dnl # Checks for gtk-doc #
 507 dnl ######################
 508
 509 GTK_DOC_CHECK([1.3])
 510
 511 dnl ############################
 512 dnl # Set up some more defines #
 513 dnl ############################
 514
 515 dnl set license and copyright notice
 516 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
 517
 518 dnl package name in plugins
 519 AC_ARG_WITH(package-name,
 520 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
 521 [case "${withval}" in
 522   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 523   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
 524   *) GST_PACKAGE="${withval}" ;;
 525 esac],
 526 [
 527 dnl default value
 528 if test "x$GST_CVS" = "xyes"
 529 then
 530   dnl nano >= 1
 531   GST_PACKAGE="GStreamer CVS/prerelease"
 532 else
 533   GST_PACKAGE="GStreamer source release"
 534 fi
 535 ]
 536 )
 537 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
 538 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
 539
 540 dnl package origin URL
 541 AC_ARG_WITH(package-origin,
 542 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
 543 [case "${withval}" in
 544   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 545   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
 546   *) GST_ORIGIN="${withval}" ;;
 547 esac],
 548 [GST_ORIGIN="http://gstreamer.freedesktop.org/"]) dnl Default value
 549 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
 550 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
 551
 552 dnl #########################
 553 dnl # Make the output files #
 554 dnl #########################
 555
 556 dnl keep this alphabetic per directory, please
 557 AC_CONFIG_FILES(
 558 Makefile
 559 gst/Makefile
 560 gst/alpha/Makefile
 561 gst/autodetect/Makefile
 562 gst/avi/Makefile
 563 gst/effectv/Makefile
 564 gst/fdsrc/Makefile
 565 gst/goom/Makefile
 566 gst/law/Makefile
 567 gst/level/Makefile
 568 gst/rtp/Makefile
 569 gst/rtsp/Makefile
 570 gst/smpte/Makefile
 571 gst/udp/Makefile
 572 gst/videobox/Makefile
 573 gst/videofilter/Makefile
 574 gst/wavenc/Makefile
 575 gst/wavparse/Makefile
 576 ext/jpeg/Makefile
 577 ext/Makefile
 578 ext/aalib/Makefile
 579 ext/dv/Makefile
 580 ext/esd/Makefile
 581 ext/flac/Makefile
 582 ext/gconf/Makefile
 583 ext/ladspa/Makefile
 584 ext/libcaca/Makefile
 585 ext/libpng/Makefile
 586 ext/raw1394/Makefile
 587 ext/shout2/Makefile
 588 ext/speex/Makefile
 589 sys/Makefile
 590 sys/oss/Makefile
 591 po/Makefile.in
 592 common/Makefile
 593 common/m4/Makefile
 594 gconf/Makefile
 595 gconf/gstreamer.schemas
 596 docs/Makefile
 597 docs/plugins/Makefile
 598 docs/version.entities
 599 m4/Makefile
 600 gst-plugins-good.spec
 601 )
 602 AC_OUTPUT
 603
 604 echo -n "configure: *** Plug-ins that will be built :"
 605 echo -e "$GST_PLUGINS_YES" | sort
 606 echo
 607 echo -n "configure: *** Plug-ins that will not be built :"
 608 echo -e "$GST_PLUGINS_NO" | sort
 609 echo
 610 if test "x$BUILD_EXTERNAL" = "xno"; then
 611   echo "configure: *** No external plug-ins will be built"
 612 fi