configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [0])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 AC_MSG_CHECKING([for the BeOS])
 121 case $host in
 122   *-*-beos*)
 123     glib_native_beos="yes"
 124     ;;
 125   *)
 126     glib_native_beos="no"
 127     ;;
 128 esac
 129 AC_MSG_RESULT([$glib_native_beos])
 130
 131 dnl
 132
 133 AC_MSG_CHECKING([for Win32])
 134 LIB_EXE_MACHINE_FLAG=X86
 135 case "$host" in
 136   *-*-mingw*)
 137     glib_native_win32=yes
 138     glib_pid_type='void *'
 139     glib_cv_stack_grows=no
 140     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 141     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 142     # (Sorry, I don't know exactly what is the problem, but it is related to
 143     # floating point formatting and decimal point vs. comma.)
 144     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 145     # rigorous enough to notice, though.
 146     # So preset the autoconf cache variables.
 147     ac_cv_func_vsnprintf_c99=no
 148     ac_cv_func_snprintf_c99=no
 149     case "$host" in
 150     x86_64-*-*)
 151       LIB_EXE_MACHINE_FLAG=X64
 152       ;;
 153     esac
 154
 155     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 156     ;;
 157   *)
 158     glib_native_win32=no
 159     glib_pid_type=int
 160     ;;
 161 esac
 162 case $host in
 163   *-*-linux*)
 164     glib_os_linux=yes
 165     ;;
 166 esac
 167
 168 AC_MSG_RESULT([$glib_native_win32])
 169
 170 AC_MSG_CHECKING([for the Android])
 171 case $host in
 172   *android*)
 173     glib_native_android="yes"
 174     ;;
 175   *)
 176     glib_native_android="no"
 177     ;;
 178 esac
 179 AC_MSG_RESULT([$glib_native_android])
 180
 181 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 182
 183 glib_have_carbon=no
 184 AC_MSG_CHECKING([for Mac OS X Carbon support])
 185 AC_TRY_CPP([
 186 #include <Carbon/Carbon.h>
 187 #include <CoreServices/CoreServices.h>
 188 ], glib_have_carbon=yes)
 189
 190 AC_MSG_RESULT([$glib_have_carbon])
 191
 192 glib_have_cocoa=no
 193 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 194 AC_TRY_CPP([
 195 #include <Cocoa/Cocoa.h>
 196 #ifdef GNUSTEP_BASE_VERSION
 197 #error "Detected GNUstep, not Cocoa"
 198 #endif
 199 ], glib_have_cocoa=yes)
 200
 201 AC_MSG_RESULT([$glib_have_cocoa])
 202
 203 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 204 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 205 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 206 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 207 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 208 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 209
 210 AS_IF([test "$glib_native_win32" = "yes"], [
 211   AC_CHECK_TOOL(WINDRES, windres, no)
 212   if test "$WINDRES" = no; then
 213     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 214   fi
 215   AC_CHECK_TOOL(NM, nm, no)
 216   if test "$NM" = no; then
 217     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 218   fi
 219   AC_CHECK_TOOL(RANLIB, ranlib, :)
 220   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 221   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 222 ])
 223 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 224
 225 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 226   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 228 ])
 229
 230 if test "x$glib_have_cocoa" = "xyes"; then
 231   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 232   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 233 fi
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253
 254 GLIB_TESTS
 255
 256 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 257 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 258   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 259   AC_MSG_RESULT([yes])
 260 ], [ AC_MSG_RESULT([no]) ])
 261
 262 AC_MSG_CHECKING([whether to disable memory pools])
 263 AS_IF([test "x$disable_mem_pools" = "xno"], [
 264   AC_MSG_RESULT([no])
 265 ], [
 266   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 267   AC_MSG_RESULT([yes])
 268 ])
 269
 270 dnl location to install runtime libraries, e.g. ../../lib to install
 271 dnl to /lib if libdir is /usr/lib
 272 AC_ARG_WITH(runtime-libdir,
 273            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 274                            [install runtime libraries relative to libdir])],
 275            [],
 276            [with_runtime_libdir=""])
 277 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 278 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 279 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 280 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 281 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 282
 283 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 284 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 285 AC_LANG_SAVE
 286 AC_LANG_CPLUSPLUS
 287 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 288 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 289 AC_LANG_RESTORE
 290
 291 AM_PROG_CC_C_O
 292 AC_PROG_INSTALL
 293
 294 AC_SYS_LARGEFILE
 295
 296 PKG_PROG_PKG_CONFIG(0.16)
 297
 298 if test "x$enable_debug" = "xyes"; then
 299   if test x$cflags_set != xset ; then
 300       case " $CFLAGS " in
 301       *[[\ \    ]]-g[[\ \       ]]*) ;;
 302       *) CFLAGS="$CFLAGS -g" ;;
 303       esac
 304   fi
 305   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 306 else
 307   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 308
 309   if test "x$enable_debug" = "xno"; then
 310     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 311   fi
 312 fi
 313
 314 # Ensure MSVC-compatible struct packing convention is used when
 315 # compiling for Win32 with gcc.
 316 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 317 # gcc2 uses "-fnative-struct".
 318 if test x"$glib_native_win32" = xyes; then
 319   if test x"$GCC" = xyes; then
 320     msnative_struct=''
 321     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 322     if test -z "$ac_cv_prog_CC"; then
 323       our_gcc="$CC"
 324     else
 325       our_gcc="$ac_cv_prog_CC"
 326     fi
 327     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 328       2.)
 329         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 330           msnative_struct='-fnative-struct'
 331         fi
 332         ;;
 333       *)
 334         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 335           msnative_struct='-mms-bitfields'
 336         fi
 337         ;;
 338     esac
 339     if test x"$msnative_struct" = x ; then
 340       AC_MSG_RESULT([no way])
 341       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 342     else
 343       CFLAGS="$CFLAGS $msnative_struct"
 344       AC_MSG_RESULT([${msnative_struct}])
 345     fi
 346   fi
 347 fi
 348 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 349 AC_SUBST(GLIB_EXTRA_CFLAGS)
 350
 351 AC_EXEEXT
 352
 353 # define a MAINT-like variable REBUILD which is set if Perl
 354 # and awk are found, so autogenerated sources can be rebuilt
 355 AC_PROG_AWK
 356 AC_CHECK_PROGS(PERL, [perl5 perl])
 357 # We would like indent, but don't require it.
 358 AC_CHECK_PROG(INDENT, indent, indent)
 359 REBUILD=\#
 360 if test "x$enable_rebuilds" = "xyes" && \
 361      test -n "$PERL" && \
 362      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 363      test -n "$AWK" ; then
 364   REBUILD=
 365 fi
 366 AC_SUBST(REBUILD)
 367
 368 # Need full path to Perl for glib-mkenums
 369 #
 370 if test "x$PERL" != x ; then
 371   AC_PATH_PROG(PERL_PATH, [$PERL])
 372 fi
 373 if test "x$PERL_PATH" = x ; then
 374   PERL_PATH="/usr/bin/env perl"
 375 fi
 376 AC_SUBST(PERL_PATH)
 377
 378 # option to specify python interpreter to use; this just sets $PYTHON, so that
 379 # we will fallback to reading $PYTHON if --with-python is not given, and
 380 # python.m4 will get the expected input
 381 AC_ARG_WITH(python,
 382             AS_HELP_STRING([--with-python=PATH],
 383                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 384             [PYTHON="$withval"], [])
 385 if test x"$PYTHON" = xyes; then
 386   AC_MSG_ERROR([--with-python option requires a path or program argument])
 387 fi
 388 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 389
 390
 391 dnl ***********************
 392 dnl *** Tests for iconv ***
 393 dnl ***********************
 394 dnl
 395 dnl We do this before the gettext checks, to avoid distortion
 396
 397 dnl On Windows we use a native implementation
 398
 399 AS_IF([ test x"$glib_native_win32" = xyes], [
 400   with_libiconv=native
 401 ], [
 402   AC_ARG_WITH(libiconv,
 403               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 404                               [use the libiconv library])],,
 405               [with_libiconv=maybe])
 406
 407   found_iconv=no
 408   case $with_libiconv in
 409     maybe)
 410       # Check in the C library first
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       # Check if we have GNU libiconv
 413       if test $found_iconv = "no"; then
 414         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       fi
 416       # Check if we have a iconv in -liconv, possibly from vendor
 417       if test $found_iconv = "no"; then
 418         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 419       fi
 420       ;;
 421     no)
 422       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 423       ;;
 424     gnu|yes)
 425       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 426       ;;
 427     native)
 428       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 429       ;;
 430   esac
 431
 432   if test "x$found_iconv" = "xno" ; then
 433      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 434   fi
 435 ])
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 AS_IF([test "x$found_zlib" = "xno"], [
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 ])
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 AS_IF([test x"$glib_native_win32" != xyes], [
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 ])
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 AS_IF([test "$glib_native_win32" = "yes"], [
 509   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 510     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 511   fi
 512   if test x$enable_static = xyes; then
 513     glib_win32_static_compilation=yes
 514     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 515 #define GOBJECT_STATIC_COMPILATION 1"
 516     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 517   fi
 518 ])
 519 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 520
 521 dnl
 522 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 523 dnl
 524 AS_IF([test $cross_compiling != yes], [
 525     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 526     glib_save_LIBS=$LIBS
 527     LIBS="$LIBS -lm"
 528     AC_TRY_RUN([#include <math.h>
 529                  int main (void) { return (log(1) != log(1.)); }],
 530          AC_MSG_RESULT(none needed),
 531          glib_save_CFLAGS=$CFLAGS
 532          CFLAGS="$CFLAGS -std1"
 533          AC_TRY_RUN([#include <math.h>
 534                      int main (void) { return (log(1) != log(1.)); }],
 535              AC_MSG_RESULT(-std1),
 536              AC_MSG_RESULT()
 537              CFLAGS=$glib_save_CFLAGS
 538              AC_MSG_WARN(
 539                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 540          )
 541     )
 542     LIBS=$glib_save_LIBS
 543 ])
 544
 545 dnl NeXTStep cc seems to need this
 546 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 547 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 548   AC_MSG_RESULT(none needed),
 549   glib_save_CFLAGS=$CFLAGS
 550   CFLAGS="$CFLAGS -posix"
 551   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 552     AC_MSG_RESULT(-posix),
 553     AC_MSG_RESULT()
 554     CFLAGS=$glib_save_CFLAGS
 555     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 556
 557 # Checks for library functions.
 558 AC_FUNC_VPRINTF
 559 AC_FUNC_ALLOCA
 560 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 561 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 562
 563 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 564   [AC_TRY_LINK([#include <unistd.h>
 565     extern int __libc_enable_secure;],
 566     [return __libc_enable_secure;],
 567    glib_cv_have_libc_enable_secure=yes,
 568    glib_cv_have_libc_enable_secure=no)])
 569 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 570    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 571      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 572 ])
 573
 574 AC_CHECK_SIZEOF(char)
 575 AC_CHECK_SIZEOF(short)
 576 AC_CHECK_SIZEOF(long)
 577 AC_CHECK_SIZEOF(int)
 578 AC_CHECK_SIZEOF(void *)
 579 AC_CHECK_SIZEOF(long long)
 580 AC_CHECK_SIZEOF(__int64)
 581
 582 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 583   [AC_TRY_LINK([#include <signal.h>
 584      #include <sys/types.h>
 585      sig_atomic_t val = 42;],
 586     [return val == 42 ? 0 : 1],
 587    ac_cv_type_sig_atomic_t=yes,
 588    ac_cv_type_sig_atomic_t=no)])
 589 if test x$ac_cv_type_sig_atomic_t = xyes; then
 590    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 591      [Define if you have the 'sig_atomic_t' type.])
 592 fi
 593
 594 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 595   :
 596 else
 597   AC_MSG_ERROR([
 598 *** GLib requires a 64 bit type. You might want to consider
 599 *** using the GNU C compiler.
 600 ])
 601 fi
 602
 603 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 604         # long long is a 64 bit integer.
 605         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 606         AC_CACHE_VAL(glib_cv_long_long_format,[
 607                 for format in ll q I64; do
 608                   AC_TRY_RUN([#include <stdio.h>
 609                         int main()
 610                         {
 611                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 612                           char buffer[1000];
 613                           sprintf (buffer, "%${format}u", a);
 614                           sscanf (buffer, "%${format}u", &b);
 615                           exit (b!=a);
 616                         }
 617                         ],
 618                         [glib_cv_long_long_format=${format}
 619                         break],
 620                         [],[:])
 621                 done])
 622         AS_IF([ test -n "$glib_cv_long_long_format"], [
 623           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 624           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 625           if test x"$glib_cv_long_long_format" = xI64; then
 626             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 627           fi
 628         ], [AC_MSG_RESULT(none)])
 629 ],[ test x$ac_cv_sizeof___int64 = x8], [
 630         # __int64 is a 64 bit integer.
 631         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 632         # We know this is MSVCRT.DLL, and what the formats are
 633         glib_cv_long_long_format=I64
 634         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 635         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 636         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 637 ])
 638
 639 AC_C_CONST
 640
 641 dnl
 642 dnl check in which direction the stack grows
 643 dnl
 644 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 645         AC_TRY_RUN([
 646         volatile int *a = 0, *b = 0;
 647         void foo (void);
 648         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 649         void foo (void) { volatile int x = 5; b = &x; }
 650         ],
 651         glib_cv_stack_grows=no
 652         ,
 653         glib_cv_stack_grows=yes
 654         ,)
 655 ])
 656
 657 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 658 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 659 dnl actually supported.
 660 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 661         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 662         __inline int foo () { return 0; }
 663         int main () { return foo (); }
 664         ]])],
 665         glib_cv_has__inline=yes
 666         ,
 667         glib_cv_has__inline=no
 668         ,)
 669 ])
 670 case x$glib_cv_has__inline in
 671 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 672 esac
 673 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 674         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 675         __inline__ int foo () { return 0; }
 676         int main () { return foo (); }
 677         ]])],
 678         glib_cv_has__inline__=yes
 679         ,
 680         glib_cv_has__inline__=no
 681         ,)
 682 ])
 683 case x$glib_cv_has__inline__ in
 684 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 685 esac
 686 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 687         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 688         #undef inline
 689         inline int foo () { return 0; }
 690         int main () { return foo (); }
 691         ]])],
 692         glib_cv_hasinline=yes
 693         ,
 694         glib_cv_hasinline=no
 695         ,)
 696 ])
 697 case x$glib_cv_hasinline in
 698 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 699 esac
 700
 701 # if we can use inline functions in headers
 702 AC_MSG_CHECKING(if inline functions in headers work)
 703 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 704 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 705 #  undef inline
 706 #  define inline __inline__
 707 #elif !defined (G_HAVE_INLINE)
 708 #  undef inline
 709 #  if defined (G_HAVE___INLINE__)
 710 #    define inline __inline__
 711 #  elif defined (G_HAVE___INLINE)
 712 #    define inline __inline
 713 #  endif
 714 #endif
 715
 716 int glib_test_func2 (int);
 717
 718 static inline int
 719 glib_test_func1 (void) {
 720   return glib_test_func2 (1);
 721 }
 722
 723 int
 724 main (void) {
 725   int i = 1;
 726 }]])],[g_can_inline=yes],[g_can_inline=no])
 727 AC_MSG_RESULT($g_can_inline)
 728
 729 dnl *** check for working do while(0) macros ***
 730 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 731         AC_TRY_COMPILE([],[
 732         #define STMT_START do
 733         #define STMT_END while(0)
 734         #define STMT_TEST STMT_START { i = 0; } STMT_END
 735         int main(void) { int i = 1; STMT_TEST; return i; }],
 736         [g_cv_support_dowhile_macros=yes],
 737         [g_cv_support_dowhile_macros=no],
 738         [g_cv_support_dowhile_macros=yes])
 739 ])
 740 if test x$g_cv_support_dowhile_macros = xyes; then
 741   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 742 fi
 743
 744 # check for flavours of varargs macros
 745 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 746 AC_TRY_COMPILE([],[
 747 int a(int p1, int p2, int p3);
 748 #define call_a(...) a(1,__VA_ARGS__)
 749 call_a(2,3);
 750 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 751 AC_MSG_RESULT($g_have_iso_c_varargs)
 752
 753 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 754 AS_IF([test "$CXX" = ""], [
 755 dnl No C++ compiler
 756   g_have_iso_cxx_varargs=no
 757 else
 758   AC_LANG_CPLUSPLUS
 759   AC_TRY_COMPILE([],[
 760 int a(int p1, int p2, int p3);
 761 #define call_a(...) a(1,__VA_ARGS__)
 762 call_a(2,3);
 763 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 764   AC_LANG_C
 765 ])
 766 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 767
 768 AC_MSG_CHECKING(for GNUC varargs macros)
 769 AC_TRY_COMPILE([],[
 770 int a(int p1, int p2, int p3);
 771 #define call_a(params...) a(1,params)
 772 call_a(2,3);
 773 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 774 AC_MSG_RESULT($g_have_gnuc_varargs)
 775
 776 # check for GNUC visibility support
 777 AC_MSG_CHECKING(for GNUC visibility attribute)
 778 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 779 void
 780 __attribute__ ((visibility ("hidden")))
 781      f_hidden (void)
 782 {
 783 }
 784 void
 785 __attribute__ ((visibility ("internal")))
 786      f_internal (void)
 787 {
 788 }
 789 void
 790 __attribute__ ((visibility ("protected")))
 791      f_protected (void)
 792 {
 793 }
 794 void
 795 __attribute__ ((visibility ("default")))
 796      f_default (void)
 797 {
 798 }
 799 int main (void)
 800 {
 801         f_hidden();
 802         f_internal();
 803         f_protected();
 804         f_default();
 805         return 0;
 806 }
 807 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 808 AC_MSG_RESULT($g_have_gnuc_visibility)
 809 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 810
 811 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 812 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 813 #else
 814 # include "error: this is not Sun Studio."
 815 #endif
 816 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 817 AC_MSG_RESULT($g_have_sunstudio_visibility)
 818 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 819
 820 # check for bytesex stuff
 821 AC_C_BIGENDIAN
 822 if test x$ac_cv_c_bigendian = xuniversal ; then
 823 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 824 #else
 825 #error Not a big endian.
 826 #endif],
 827     ac_cv_c_bigendian=yes
 828     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 829 #else
 830 #error Not a little endian.
 831 #endif],
 832     ac_cv_c_bigendian=no
 833     ,AC_MSG_WARN([Could not determine endianness.])))
 834 fi
 835
 836
 837 # check for header files
 838 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 839 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 840 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 841 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 842 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 843 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 844 AC_CHECK_HEADERS([linux/magic.h])
 845 AC_CHECK_HEADERS([sys/prctl.h])
 846
 847 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 848 [#if HAVE_SYS_PARAM_H
 849  #include <sys/param.h>
 850  #endif
 851 ])
 852 AC_CHECK_FUNCS(sysctlbyname)
 853
 854 AC_CHECK_HEADERS([xlocale.h])
 855
 856 # check for structure fields
 857 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 858 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 859 #include <sys/stat.h>
 860 #include <unistd.h>
 861 #ifdef HAVE_SYS_STATFS_H
 862 #include <sys/statfs.h>
 863 #endif
 864 #ifdef HAVE_SYS_PARAM_H
 865 #include <sys/param.h>
 866 #endif
 867 #ifdef HAVE_SYS_MOUNT_H
 868 #include <sys/mount.h>
 869 #endif])
 870 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 871 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 872 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 873 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 874
 875 AC_STRUCT_DIRENT_D_TYPE
 876
 877 # Checks for libcharset
 878 AM_LANGINFO_CODESET
 879 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 880 AC_CHECK_FUNCS(setlocale)
 881 gl_GLIBC21
 882
 883 # check additional type sizes
 884 AC_CHECK_SIZEOF(size_t)
 885
 886 dnl Try to figure out whether gsize should be long or int
 887 AC_MSG_CHECKING([for the appropriate definition for size_t])
 888
 889 case $ac_cv_sizeof_size_t in
 890   $ac_cv_sizeof_short)
 891       glib_size_type=short
 892       ;;
 893   $ac_cv_sizeof_int)
 894       glib_size_type=int
 895       ;;
 896   $ac_cv_sizeof_long)
 897       glib_size_type=long
 898       ;;
 899   $ac_cv_sizeof_long_long)
 900       glib_size_type='long long'
 901       ;;
 902   $ac_cv_sizeof__int64)
 903       glib_size_type='__int64'
 904       ;;
 905   *)  AC_MSG_ERROR([No type matching size_t in size])
 906       ;;
 907 esac
 908
 909 dnl If int/long are the same size, we see which one produces
 910 dnl warnings when used in the location as size_t. (This matters
 911 dnl on AIX with xlc)
 912 dnl
 913 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 914        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 915   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 916 #if defined(_AIX) && !defined(__GNUC__)
 917 #pragma options langlvl=stdc89
 918 #endif
 919 #include <stddef.h>
 920 int main ()
 921 {
 922   size_t s = 1;
 923   unsigned int *size_int = &s;
 924   return (int)*size_int;
 925 }
 926     ]])],glib_size_type=int,
 927       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 928 #if defined(_AIX) && !defined(__GNUC__)
 929 #pragma options langlvl=stdc89
 930 #endif
 931 #include <stddef.h>
 932 int main ()
 933 {
 934    size_t s = 1;
 935    unsigned long *size_long = &s;
 936    return (int)*size_long;
 937 }
 938         ]])],glib_size_type=long)])
 939 ])
 940
 941 AC_MSG_RESULT(unsigned $glib_size_type)
 942
 943 AC_CHECK_SIZEOF(ssize_t)
 944
 945 dnl Try to figure out whether gssize should be long or int
 946 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 947
 948 case $ac_cv_sizeof_ssize_t in
 949   $ac_cv_sizeof_short)
 950       glib_ssize_type=short
 951       ;;
 952   $ac_cv_sizeof_int)
 953       glib_ssize_type=int
 954       ;;
 955   $ac_cv_sizeof_long)
 956       glib_ssize_type=long
 957       ;;
 958   $ac_cv_sizeof_long_long)
 959       glib_ssize_type='long long'
 960       ;;
 961   $ac_cv_sizeof__int64)
 962       glib_ssize_type='__int64'
 963       ;;
 964   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 965       ;;
 966 esac
 967
 968 dnl If int/long are the same size, we see which one produces
 969 dnl warnings when used in the location as ssize_t. (This matters
 970 dnl on Android where ssize_t is long and size_t is unsigned int)
 971 dnl
 972 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 973        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 974   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 #ifdef HAVE_INTTYPES_H
 980 # include <inttypes.h>
 981 #endif
 982 #ifdef HAVE_STDINT_H
 983 # include <stdint.h>
 984 #endif
 985 #ifdef HAVE_UNISTD_H
 986 # include <unistd.h>
 987 #endif
 988 #ifdef HAVE_SYS_TYPES_H
 989 # include <sys/types.h>
 990 #endif
 991 int main ()
 992 {
 993   ssize_t s = 1;
 994   int *size_int = &s;
 995   return (int)*size_int;
 996 }
 997     ]])],glib_ssize_type=int,
 998       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 999 #if defined(_AIX) && !defined(__GNUC__)
1000 #pragma options langlvl=stdc89
1001 #endif
1002 #include <stddef.h>
1003 #ifdef HAVE_INTTYPES_H
1004 # include <inttypes.h>
1005 #endif
1006 #ifdef HAVE_STDINT_H
1007 # include <stdint.h>
1008 #endif
1009 #ifdef HAVE_UNISTD_H
1010 # include <unistd.h>
1011 #endif
1012 #ifdef HAVE_SYS_TYPES_H
1013 # include <sys/types.h>
1014 #endif
1015 int main ()
1016 {
1017    ssize_t s = 1;
1018    long *size_long = &s;
1019    return (int)*size_long;
1020 }
1021         ]])],glib_ssize_type=long)])
1022 ])
1023
1024 AC_MSG_RESULT($glib_ssize_type)
1025
1026 # Check for some functions
1027 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1028 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
1029 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
1030 # Check for high-resolution sleep functions
1031 AC_CHECK_FUNCS(splice)
1032 AC_CHECK_FUNCS(prlimit)
1033
1034 # To avoid finding a compatibility unusable statfs, which typically
1035 # successfully compiles, but warns to use the newer statvfs interface:
1036 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1037 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1038
1039 AC_MSG_CHECKING([whether to use statfs or statvfs])
1040 # Some systems have both statfs and statvfs, pick the most "native" for these
1041 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1042    [
1043    # on solaris and irix, statfs doesn't even have the f_bavail field
1044    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1045       [ac_cv_func_statfs=no],
1046    # else, at least on linux, statfs is the actual syscall
1047       [ac_cv_func_statvfs=no])
1048    ])
1049
1050 AS_IF([test x$ac_cv_func_statfs = xyes],
1051       [
1052          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1053          AC_MSG_RESULT([statfs])
1054       ],
1055       [test x$ac_cv_func_statvfs = xyes],
1056       [
1057          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1058          AC_MSG_RESULT([statvfs])
1059       ],
1060       [  AC_MSG_RESULT([neither])])
1061
1062 AC_CHECK_HEADERS(crt_externs.h)
1063 AC_CHECK_FUNCS(_NSGetEnviron)
1064
1065 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1066
1067 AC_FUNC_VSNPRINTF_C99
1068 AC_FUNC_PRINTF_UNIX98
1069
1070 # Internet address families
1071 if test $glib_native_win32 = yes; then
1072   glib_inet_includes=["
1073 #include <winsock2.h>
1074   "]
1075 else
1076   glib_inet_includes=["
1077 #include <sys/types.h>
1078 #include <sys/socket.h>
1079   "]
1080 fi
1081
1082 glib_failed=false
1083 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1084 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1085 # winsock defines this even though it doesn't support it
1086 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1087 if $glib_failed ; then
1088   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1089 fi
1090
1091 glib_failed=false
1092 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1093 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1094 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1095 if $glib_failed ; then
1096   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1097 fi
1098
1099 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1100
1101 AS_IF([test $glib_native_win32 = yes], [
1102   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1103   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1104   # they aren't present at run-time (on Windows 2000).
1105   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1106   AC_SUBST(WSPIAPI_INCLUDE)
1107 ], [
1108   # Android does not have C_IN in public headers, we define it wherever necessary
1109   AS_IF([test $glib_native_android != yes], [
1110     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1111     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1112                                         #include <arpa/nameser.h>],
1113                                        [int qclass = C_IN;])],
1114                       [AC_MSG_RESULT([no])],
1115                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1116                                                            #include <arpa/nameser.h>
1117                                                            #include <arpa/nameser_compat.h>],
1118                                                           [int qclass = C_IN;])],
1119                                          [AC_MSG_RESULT([yes])
1120                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1121                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1122   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1123
1124   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1125   NETWORK_LIBS=""
1126   AC_MSG_CHECKING([for res_query])
1127   AC_TRY_LINK([#include <sys/types.h>
1128                #include <netinet/in.h>
1129                #include <arpa/nameser.h>
1130                #include <resolv.h>
1131               ],[
1132                res_query("test", 0, 0, (void *)0, 0);
1133               ],[AC_MSG_RESULT([yes])],
1134               [save_libs="$LIBS"
1135                LIBS="-lresolv $LIBS"
1136                AC_TRY_LINK([#include <sys/types.h>
1137                             #include <netinet/in.h>
1138                             #include <arpa/nameser.h>
1139                             #include <resolv.h>
1140                            ],[
1141                             res_query("test", 0, 0, (void *)0, 0);
1142                            ],[AC_MSG_RESULT([in -lresolv])
1143                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1144                            [LIBS="-lbind $save_libs"
1145                             AC_TRY_LINK([#include <resolv.h>],
1146                                         [res_query("test", 0, 0, (void *)0, 0);],
1147                                         [AC_MSG_RESULT([in -lbind])
1148                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1149                                         [AC_MSG_ERROR(not found)])])
1150                LIBS="$save_libs"])
1151   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1152                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1153                                         [AC_MSG_ERROR(Could not find socket())]))
1154   save_libs="$LIBS"
1155   LIBS="$LIBS $NETWORK_LIBS"
1156   AC_MSG_CHECKING([for res_init])
1157   AC_TRY_LINK([#include <sys/types.h>
1158                #include <netinet/in.h>
1159                #include <arpa/nameser.h>
1160                #include <resolv.h>
1161               ],[
1162                res_init();
1163               ],[AC_MSG_RESULT([yes])
1164                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1165               ],[AC_MSG_RESULT([no])])
1166   LIBS="$save_libs"
1167 ])
1168 AC_SUBST(NETWORK_LIBS)
1169
1170 AC_CHECK_HEADER([linux/netlink.h],
1171                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1172                 [#include <sys/socket.h>])
1173 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1174
1175 AC_CHECK_TYPE([struct ip_mreqn], [
1176               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1177               [#include <netinet/in.h>])
1178
1179 case $host in
1180   *-*-solaris* )
1181      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1182      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1183      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1184      ;;
1185 esac
1186
1187 dnl
1188 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1189 dnl
1190 AS_IF([test "$ac_cv_func_statfs" = yes], [
1191   AC_MSG_CHECKING([number of arguments to statfs()])
1192   AC_TRY_COMPILE([#include <unistd.h>
1193   #ifdef HAVE_SYS_PARAM_H
1194   #include <sys/param.h>
1195   #endif
1196   #ifdef HAVE_SYS_VFS_H
1197   #include <sys/vfs.h>
1198   #endif
1199   #ifdef HAVE_SYS_MOUNT_H
1200   #include <sys/mount.h>
1201   #endif
1202   #ifdef HAVE_SYS_STATFS_H
1203   #include <sys/statfs.h>
1204   #endif], [struct statfs st;
1205   statfs(NULL, &st);],[
1206     AC_MSG_RESULT([2])
1207     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1208     AC_TRY_COMPILE([#include <unistd.h>
1209   #ifdef HAVE_SYS_PARAM_H
1210   #include <sys/param.h>
1211   #endif
1212   #ifdef HAVE_SYS_VFS_H
1213   #include <sys/vfs.h>
1214   #endif
1215   #ifdef HAVE_SYS_MOUNT_H
1216   #include <sys/mount.h>
1217   #endif
1218   #ifdef HAVE_SYS_STATFS_H
1219   #include <sys/statfs.h>
1220   #endif], [struct statfs st;
1221   statfs(NULL, &st, sizeof (st), 0);],[
1222       AC_MSG_RESULT([4])
1223       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1224       AC_MSG_RESULT(unknown)
1225       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1226 ])
1227
1228 dnl
1229 dnl open takes O_DIRECTORY as an option
1230 dnl
1231 AC_MSG_CHECKING([open() option O_DIRECTORY])
1232 AC_TRY_COMPILE([#include <fcntl.h>
1233 #include <sys/types.h>
1234 #include <sys/stat.h>],
1235 [open(0, O_DIRECTORY, 0);],[
1236         AC_MSG_RESULT([yes])
1237         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1238         AC_MSG_RESULT([no])])
1239
1240 #
1241 # Check whether to use an included printf
1242 #
1243
1244 AC_ARG_ENABLE(included-printf,
1245               [AS_HELP_STRING([--enable-included-printf],
1246                               [use included printf [default=auto]])],
1247               enable_included_printf="$enableval")
1248
1249 need_included_printf=no
1250 if test "x$enable_included_printf" = "xyes" ; then
1251   need_included_printf=yes
1252 fi
1253 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1254   need_included_printf=yes
1255 fi
1256 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1257   need_included_printf=yes
1258 fi
1259 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1260    test -z "$glib_cv_long_long_format" ; then
1261   need_included_printf=yes
1262 fi
1263
1264 if test "x$enable_included_printf" = "xno" &&
1265    test "x$need_included_printf" = "xyes" ; then
1266   AC_MSG_ERROR([
1267 *** Your C library's printf doesn't appear to have the features that
1268 *** GLib needs, but you specified --enable-included-printf=no.])
1269 fi
1270
1271 enable_included_printf=$need_included_printf
1272
1273 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1274 AS_IF([test "$enable_included_printf" != "yes"], [
1275   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1276 ], [
1277   if test -z "$glib_cv_long_long_format" ; then
1278     glib_cv_long_long_format="ll"
1279   fi
1280   AC_DEFINE(HAVE_VASPRINTF,1)
1281 ])
1282
1283 # Checks needed for gnulib vasnprintf
1284 bh_C_SIGNED
1285 jm_AC_TYPE_LONG_LONG
1286 gt_TYPE_LONGDOUBLE
1287 gt_TYPE_WCHAR_T
1288 gt_TYPE_WINT_T
1289 AC_TYPE_SIZE_T
1290 AC_CHECK_TYPES(ptrdiff_t)
1291 jm_AC_TYPE_INTMAX_T
1292 AC_CHECK_FUNCS([snprintf wcslen])
1293 AC_FUNC_SNPRINTF_C99
1294
1295 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1296 # The check is borrowed from the PERL Configure script.
1297 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1298   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1299     glib_cv_working_bcopy,[AC_TRY_RUN([
1300       int main() {
1301         char buf[128], abc[128], *b;
1302         int len, off, align;
1303         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1304         for (align = 7; align >= 0; align--) {
1305           for (len = 36; len; len--) {
1306             b = buf+align; bcopy(abc, b, len);
1307             for (off = 1; off <= len; off++) {
1308               bcopy(b, b+off, len); bcopy(b+off, b, len);
1309                 if (bcmp(b, abc, len)) return(1);
1310             }
1311           }
1312         }
1313         return(0);
1314       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1315
1316   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1317   if test "$glib_cv_working_bcopy" = "yes"; then
1318     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1319   fi
1320 ])
1321
1322 # Check if <sys/select.h> needs to be included for fd_set
1323 AC_MSG_CHECKING([for fd_set])
1324 AC_TRY_COMPILE([#include <sys/types.h>],
1325         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1326 AS_IF([test "$gtk_ok" = "yes"], [
1327     AC_MSG_RESULT([yes, found in sys/types.h])
1328 ], [
1329     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1330     if test "$gtk_ok" = "yes"; then
1331         # *** FIXME: give it a different name
1332         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1333         AC_MSG_RESULT([yes, found in sys/select.h])
1334     else
1335         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1336         AC_MSG_RESULT(no)
1337     fi
1338 ])
1339
1340 dnl Check for nl_langinfo and CODESET
1341 AC_LANG_SAVE
1342 AC_LANG_C
1343 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1344         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1345                        [char *codeset = nl_langinfo (CODESET);])],
1346                 [glib_cv_langinfo_codeset=yes],
1347                 [glib_cv_langinfo_codeset=no])])
1348 if test x$glib_cv_langinfo_codeset = xyes; then
1349   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1350 fi
1351
1352 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1353 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1354         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1355                  [char *str;
1356                  str = nl_langinfo (PM_STR);
1357                  str = nl_langinfo (D_T_FMT);
1358                  str = nl_langinfo (D_FMT);
1359                  str = nl_langinfo (T_FMT);
1360                  str = nl_langinfo (T_FMT_AMPM);
1361                  str = nl_langinfo (MON_1);
1362                  str = nl_langinfo (ABMON_12);
1363                  str = nl_langinfo (DAY_1);
1364                  str = nl_langinfo (ABDAY_7);])],
1365                 [glib_cv_langinfo_time=yes],
1366                 [glib_cv_langinfo_time=no])])
1367 if test x$glib_cv_langinfo_time = xyes; then
1368   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1369 fi
1370
1371 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1372 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1373         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1374                 [char *str;
1375                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1376                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1377                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1378                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1379                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1380                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1381                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1382                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1383                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1384                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1385                 [glib_cv_langinfo_outdigit=yes],
1386                 [glib_cv_langinfo_outdigit=no])])
1387 if test x$glib_cv_langinfo_outdigit = xyes; then
1388   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1389 fi
1390 AC_LANG_RESTORE
1391
1392 dnl ****************************************
1393 dnl *** posix_memalign                   ***
1394 dnl ****************************************
1395 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1396 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1397     glib_cv_compliant_posix_memalign=0
1398     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1399         AC_TRY_RUN([
1400                 #define _XOPEN_SOURCE 600
1401                 #include <stdlib.h> /* posix_memalign() should be defined here */
1402                 /* some systems break if #include <malloc.h> used */
1403                 static void test_memalign (size_t boundary, size_t size) {
1404                     void *mem = 0;
1405                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1406                         exit (1);
1407                     else
1408                       free (mem);
1409                 }
1410                 int main() {
1411                     test_memalign (  128,   128 - 2 * sizeof (void*));
1412                     test_memalign (  256,   256 - 2 * sizeof (void*));
1413                     test_memalign (  512,   512 - 2 * sizeof (void*));
1414                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1415                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1416                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1417                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1418                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1419                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1420                     exit (0); /* success */
1421                 }
1422                 ],
1423             [glib_cv_compliant_posix_memalign=1], [], [:])
1424       :
1425     fi
1426     ])
1427 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1428     AC_MSG_RESULT(yes)
1429     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1430 ], [
1431     AC_MSG_RESULT(no)
1432 ])
1433
1434
1435 dnl ****************************************
1436 dnl *** strlcpy/strlcat                  ***
1437 dnl ****************************************
1438 # Check for strlcpy
1439 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1440 AC_TRY_RUN([#include <stdlib.h>
1441 #include <string.h>
1442 int main() {
1443   char p[10];
1444   (void) strlcpy (p, "hi", 10);
1445   if (strlcat (p, "bye", 0) != 3)
1446     return 1;
1447   return 0;
1448 }], glib_cv_have_strlcpy=yes,
1449     glib_cv_have_strlcpy=no,
1450     glib_cv_have_strlcpy=no)])
1451 if test "$glib_cv_have_strlcpy" = "yes"; then
1452     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1453 fi
1454
1455
1456 dnl **********************
1457 dnl *** va_copy checks ***
1458 dnl **********************
1459 dnl we currently check for all three va_copy possibilities, so we get
1460 dnl all results in config.log for bug reports.
1461 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1462         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1463 #include <stdlib.h>
1464         void f (int i, ...) {
1465         va_list args1, args2;
1466         va_start (args1, i);
1467         va_copy (args2, args1);
1468         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1469           exit (1);
1470         va_end (args1); va_end (args2);
1471         }
1472         int main() {
1473           f (0, 42);
1474           return 0;
1475         }]])],
1476         [glib_cv_va_copy=yes],
1477         [glib_cv_va_copy=no])
1478 ])
1479 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1480         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1481 #include <stdlib.h>
1482         void f (int i, ...) {
1483         va_list args1, args2;
1484         va_start (args1, i);
1485         __va_copy (args2, args1);
1486         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1487           exit (1);
1488         va_end (args1); va_end (args2);
1489         }
1490         int main() {
1491           f (0, 42);
1492           return 0;
1493         }]])],
1494         [glib_cv___va_copy=yes],
1495         [glib_cv___va_copy=no])
1496 ])
1497
1498 if test "x$glib_cv_va_copy" = "xyes"; then
1499   g_va_copy_func=va_copy
1500 else if test "x$glib_cv___va_copy" = "xyes"; then
1501   g_va_copy_func=__va_copy
1502 fi
1503 fi
1504
1505 if test -n "$g_va_copy_func"; then
1506   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1507 fi
1508
1509 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1510         AC_TRY_RUN([#include <stdarg.h>
1511 #include <stdlib.h>
1512         void f (int i, ...) {
1513         va_list args1, args2;
1514         va_start (args1, i);
1515         args2 = args1;
1516         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1517           exit (1);
1518         va_end (args1); va_end (args2);
1519         }
1520         int main() {
1521           f (0, 42);
1522           return 0;
1523         }],
1524         [glib_cv_va_val_copy=yes],
1525         [glib_cv_va_val_copy=no],
1526         [glib_cv_va_val_copy=yes])
1527 ])
1528
1529 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1530   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1531 ])
1532
1533 dnl ***********************
1534 dnl *** g_module checks ***
1535 dnl ***********************
1536 G_MODULE_LIBS=
1537 G_MODULE_LIBS_EXTRA=
1538 G_MODULE_PLUGIN_LIBS=
1539 if test x"$glib_native_win32" = xyes; then
1540   dnl No use for this on Win32
1541   G_MODULE_LDFLAGS=
1542 else
1543   export SED
1544   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1545 fi
1546 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1547 G_MODULE_NEED_USCORE=0
1548 G_MODULE_BROKEN_RTLD_GLOBAL=0
1549 G_MODULE_HAVE_DLERROR=0
1550 dnl *** force native WIN32 shared lib loader
1551 if test -z "$G_MODULE_IMPL"; then
1552   case "$host" in
1553   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1554   esac
1555 fi
1556 dnl *** force native AIX library loader
1557 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1558 if test -z "$G_MODULE_IMPL"; then
1559   case "$host" in
1560   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1561   esac
1562 fi
1563 dnl *** dlopen() and dlsym() in system libraries
1564 AS_IF([ test -z "$G_MODULE_IMPL"], [
1565         AC_CHECK_FUNC(dlopen,
1566                       [AC_CHECK_FUNC(dlsym,
1567                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1568                       [])
1569 ])
1570 dnl *** load_image (BeOS)
1571 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1572   AC_CHECK_LIB(root, load_image,
1573       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1574       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1575       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1576       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1577       [])
1578 ])
1579 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1580 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1581         AC_CHECK_FUNC(NSLinkModule,
1582                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1583                        G_MODULE_NEED_USCORE=1],
1584                       [])
1585 ])
1586 dnl *** dlopen() and dlsym() in libdl
1587 AS_IF([ test -z "$G_MODULE_IMPL"], [
1588         AC_CHECK_LIB(dl, dlopen,
1589                      [AC_CHECK_LIB(dl, dlsym,
1590                                    [G_MODULE_LIBS=-ldl
1591                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1592                      [])
1593 ])
1594 dnl *** shl_load() in libdld (HP-UX)
1595 AS_IF([ test -z "$G_MODULE_IMPL"], [
1596         AC_CHECK_LIB(dld, shl_load,
1597                 [G_MODULE_LIBS=-ldld
1598                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1599                 [])
1600 ])
1601 dnl *** additional checks for G_MODULE_IMPL_DL
1602 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1603         LIBS_orig="$LIBS"
1604         LDFLAGS_orig="$LDFLAGS"
1605         LIBS="$G_MODULE_LIBS $LIBS"
1606         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1607 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1608         echo "void glib_plugin_test(void) { }" > plugin.c
1609         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1610                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1611         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1612                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1613                 -shrext ".o" -avoid-version plugin.lo \
1614                 -rpath /dont/care >/dev/null 2>&1
1615         eval `./libtool --config | grep ^objdir`
1616         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1617                 glib_cv_rtldglobal_broken,[
1618                 AC_TRY_RUN([
1619 #include <dlfcn.h>
1620 #ifndef RTLD_GLOBAL
1621 #  define RTLD_GLOBAL 0
1622 #endif
1623 #ifndef RTLD_LAZY
1624 #  define RTLD_LAZY 0
1625 #endif
1626 int glib_plugin_test;
1627 int main () {
1628     void *handle, *global, *local;
1629     global = &glib_plugin_test;
1630     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1631     if (!handle) return 0;
1632     local = dlsym (handle, "glib_plugin_test");
1633     return global == local;
1634 }                       ],
1635                         [glib_cv_rtldglobal_broken=no],
1636                         [glib_cv_rtldglobal_broken=yes],
1637                         [glib_cv_rtldglobal_broken=no])
1638                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1639                 rmdir ${objdir} 2>/dev/null
1640         ])
1641         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1642                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1643         else
1644                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1645         fi
1646 dnl *** check whether we need preceeding underscores
1647         AC_CACHE_CHECK([for preceeding underscore in symbols],
1648                 glib_cv_uscore,[
1649                 AC_TRY_RUN([#include <dlfcn.h>
1650                 int glib_underscore_test (void) { return 42; }
1651                 int main() {
1652                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1653                   handle = dlopen ((void*)0, 0);
1654                   if (handle) {
1655                     f1 = dlsym (handle, "glib_underscore_test");
1656                     f2 = dlsym (handle, "_glib_underscore_test");
1657                   } return (!f2 || f1);
1658                 }],
1659                         [glib_cv_uscore=yes],
1660                         [glib_cv_uscore=no],
1661                         [])
1662                 rm -f plugin.c plugin.$ac_objext plugin.lo
1663         ])
1664         GLIB_ASSERT_SET(glib_cv_uscore)
1665         if test "x$glib_cv_uscore" = "xyes"; then
1666                 G_MODULE_NEED_USCORE=1
1667         else
1668                 G_MODULE_NEED_USCORE=0
1669         fi
1670
1671         LDFLAGS="$LDFLAGS_orig"
1672 dnl *** check for having dlerror()
1673         AC_CHECK_FUNC(dlerror,
1674                 [G_MODULE_HAVE_DLERROR=1],
1675                 [G_MODULE_HAVE_DLERROR=0])
1676         LIBS="$LIBS_orig"
1677 ])
1678 dnl *** done, have we got an implementation?
1679 if test -z "$G_MODULE_IMPL"; then
1680         G_MODULE_IMPL=0
1681         G_MODULE_SUPPORTED=false
1682 else
1683         G_MODULE_SUPPORTED=true
1684 fi
1685
1686 AC_MSG_CHECKING(for the suffix of module shared libraries)
1687 export SED
1688 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1689 eval $shrext_cmds
1690 module=yes eval std_shrext=$shrext_cmds
1691 # chop the initial dot
1692 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1693 AC_MSG_RESULT(.$glib_gmodule_suffix)
1694 # any reason it may fail?
1695 if test "x$glib_gmodule_suffix" = x; then
1696         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1697 fi
1698
1699 AC_SUBST(G_MODULE_SUPPORTED)
1700 AC_SUBST(G_MODULE_IMPL)
1701 AC_SUBST(G_MODULE_LIBS)
1702 AC_SUBST(G_MODULE_LIBS_EXTRA)
1703 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1704 AC_SUBST(G_MODULE_LDFLAGS)
1705 AC_SUBST(G_MODULE_HAVE_DLERROR)
1706 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1707 AC_SUBST(G_MODULE_NEED_USCORE)
1708 AC_SUBST(GLIB_DEBUG_FLAGS)
1709
1710 dnl **********************
1711 dnl *** g_spawn checks ***
1712 dnl **********************
1713
1714 AC_MSG_CHECKING(for gspawn implementation)
1715 case "$host" in
1716   *-*-mingw*)
1717     GSPAWN=gspawn-win32.lo
1718     ;;
1719   *)
1720     GSPAWN=gspawn.lo
1721     ;;
1722 esac
1723 AC_MSG_RESULT($GSPAWN)
1724 AC_SUBST(GSPAWN)
1725
1726 dnl *************************
1727 dnl *** GIOChannel checks ***
1728 dnl *************************
1729
1730 AC_MSG_CHECKING(for GIOChannel implementation)
1731 case "$host" in
1732   *-*-mingw*)
1733     GIO=giowin32.lo
1734     ;;
1735   *)
1736     GIO=giounix.lo
1737     ;;
1738 esac
1739 AC_MSG_RESULT($GIO)
1740 AC_SUBST(GIO)
1741
1742 dnl *********************************
1743 dnl *** Directory for GIO modules ***
1744 dnl *********************************
1745
1746 AC_ARG_WITH(gio-module-dir,
1747            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1748                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1749            [],
1750            [with_gio_module_dir='${libdir}/gio/modules'])
1751 GIO_MODULE_DIR=$with_gio_module_dir
1752 AC_SUBST(GIO_MODULE_DIR)
1753
1754 dnl **********************************
1755 dnl *** Check for libselinux (GIO) ***
1756 dnl **********************************
1757 AC_ARG_ENABLE(selinux,
1758               AS_HELP_STRING([--disable-selinux],
1759                              [build without selinux support]))
1760 msg_selinux=no
1761 SELINUX_LIBS=
1762 AS_IF([ test "x$enable_selinux" != "xno"], [
1763
1764  AC_CHECK_LIB(selinux, is_selinux_enabled,
1765    [AC_CHECK_HEADERS(selinux/selinux.h,
1766      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1767        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1768         SELINUX_LIBS="-lselinux"
1769         msg_selinux=yes])
1770      ])
1771    ])
1772 ])
1773 AC_SUBST(SELINUX_LIBS)
1774
1775 dnl *****************************
1776 dnl ** Check for inotify (GIO) **
1777 dnl *****************************
1778 inotify_support=no
1779 AC_CHECK_HEADERS([sys/inotify.h],
1780 [
1781         inotify_support=yes
1782         AC_CHECK_FUNCS(inotify_init1)
1783 ])
1784
1785 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1786
1787 dnl ****************************
1788 dnl ** Check for kqueue (GIO) **
1789 dnl ****************************
1790 kqueue_support=no
1791 AC_CHECK_HEADERS([sys/event.h],
1792 [
1793         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1794 ])
1795
1796 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1797
1798 dnl *********************************
1799 dnl ** Check for Solaris FEN (GIO) **
1800 dnl *********************************
1801 fen_support=no
1802 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1803 #include <port.h>
1804 #ifndef PORT_SOURCE_FILE
1805 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1806 #endif
1807 int main() { return 0; } ]])],
1808 [
1809         fen_support=yes
1810 ],)
1811
1812 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1813
1814 dnl ****************************
1815 dnl *** Checks for FAM (GIO) ***
1816 dnl ****************************
1817
1818 should_disable_fam=no
1819
1820 AC_ARG_ENABLE(fam,
1821               AS_HELP_STRING([--disable-fam],
1822                              [don't use fam for file system monitoring]),
1823                          [
1824                                 if test "x$enable_fam" = "xno"; then
1825                                         should_disable_fam=yes
1826                                 fi
1827                          ]
1828                          )
1829 fam_support=no
1830 FAM_LIBS=
1831 if test "x$should_disable_fam" = "xno"; then
1832 AC_CHECK_LIB(fam, FAMOpen,
1833   [AC_CHECK_HEADERS(fam.h,
1834     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1835      AC_CHECK_LIB(fam, FAMNoExists,
1836                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1837      FAM_LIBS="-lfam"]
1838      fam_support=yes,
1839     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1840   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1841 AC_SUBST(FAM_LIBS)
1842 fi
1843 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1844
1845
1846 dnl *****************************
1847 dnl *** Check for xattr (GIO) ***
1848 dnl *****************************
1849 AC_ARG_ENABLE(xattr,
1850               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1851 msg_xattr=no
1852 XATTR_LIBS=
1853 AS_IF([ test "x$enable_xattr" != "xno"], [
1854
1855 dnl either glibc or libattr can provide xattr support
1856
1857 dnl for both of them, we check for getxattr being in
1858 dnl the library and a valid xattr header.
1859
1860 dnl try glibc
1861  AC_CHECK_LIB(c, getxattr,
1862    [AC_CHECK_HEADERS(sys/xattr.h,
1863      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1864       msg_xattr=yes])
1865    ])
1866
1867   AS_IF([ test "x$msg_xattr" != "xyes"], [
1868 dnl   failure. try libattr
1869    AC_CHECK_LIB(attr, getxattr,
1870       [AC_CHECK_HEADERS(attr/xattr.h,
1871        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1872         XATTR_LIBS="-lattr"
1873         msg_xattr=yes])
1874       ])
1875   ])
1876
1877   AS_IF([ test "x$msg_xattr" = "xyes"], [
1878     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1879     AC_TRY_COMPILE([
1880       #include <stdio.h>
1881       #ifdef HAVE_SYS_TYPES_H
1882       #include <sys/types.h>
1883       #endif
1884       #ifdef HAVE_SYS_XATTR_H
1885       #include <sys/xattr.h>
1886       #elif HAVE_ATTR_XATTR_H
1887       #include <attr/xattr.h>
1888       #endif
1889     ],
1890     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1891     [
1892       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1893       AC_MSG_RESULT([yes])
1894     ],
1895     [AC_MSG_RESULT([no])]
1896     )
1897   ])
1898 ])
1899 AC_SUBST(XATTR_LIBS)
1900
1901 dnl ************************
1902 dnl *** check for libelf ***
1903 dnl ************************
1904 AC_ARG_ENABLE(libelf,
1905               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1906 AS_IF([ test "x$enable_libelf" != "xno"],[
1907 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1908 AS_IF([ test $have_libelf = maybe ], [
1909   glib_save_LIBS=$LIBS
1910   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1911   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1912   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1913   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1914   LIBS=$glib_save_LIBS
1915
1916   if test $have_libelf != no; then
1917     LIBELF_LIBS=-lelf
1918     have_libelf=yes
1919   fi
1920 ])
1921 ])
1922
1923 if test x$have_libelf = xyes; then
1924   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1925 fi
1926
1927 dnl ****************************************
1928 dnl *** platform dependent source checks ***
1929 dnl ****************************************
1930
1931 AC_MSG_CHECKING(for platform-dependent source)
1932 case "$host" in
1933   *-*-cygwin*|*-*-mingw*)
1934     PLATFORMDEP=gwin32.lo
1935     ;;
1936   *)
1937     PLATFORMDEP=
1938     ;;
1939 esac
1940 AC_MSG_RESULT($PLATFORMDEP)
1941 AC_SUBST(PLATFORMDEP)
1942
1943 AC_MSG_CHECKING([whether to compile timeloop])
1944 case "$host" in
1945   *-*-cygwin*|*-*-mingw*|*-*-minix)
1946     enable_timeloop=no
1947     ;;
1948   *)
1949     enable_timeloop=yes
1950     ;;
1951 esac
1952 AC_MSG_RESULT($enable_timeloop)
1953 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1954
1955 AC_MSG_CHECKING([if building for some Win32 platform])
1956 case "$host" in
1957   *-*-mingw*|*-*-cygwin*)
1958     platform_win32=yes
1959     ;;
1960   *)
1961     platform_win32=no
1962     ;;
1963 esac
1964 AC_MSG_RESULT($platform_win32)
1965 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1966
1967 dnl ***********************
1968 dnl *** g_thread checks ***
1969 dnl ***********************
1970
1971 AC_ARG_WITH(threads,
1972            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1973                            [specify a thread implementation to use])],
1974            [],
1975            [with_threads=yes])
1976
1977 dnl error and warning message
1978 dnl *************************
1979
1980 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1981
1982 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1983                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1984                 compilation now, but then your programs might not work.
1985                 Please provide information on how it is done on your system."
1986
1987 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1988                  "
1989
1990 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1991                   provide information on your thread implementation."
1992
1993 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1994                 functions will not be MT-safe during their first call because
1995                 there is no working 'getpwuid_r' on your system."
1996
1997 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1998                 because there is no 'localtime_r' on your system."
1999
2000 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
2001                 linking threaded applications. As GLib cannot do that
2002                 automatically, you will get an linkg error everytime you are
2003                 not using the right compiler. In that case you have to relink
2004                 with the right compiler. Ususally just '_r' is appended
2005                 to the compiler name."
2006
2007 dnl determination of thread implementation
2008 dnl ***************************************
2009
2010 AC_MSG_CHECKING(for thread implementation)
2011
2012 have_threads=no
2013 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
2014         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
2015         # -U_OSF_SOURCE is for Digital UNIX 4.0d
2016         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
2017         glib_save_CPPFLAGS="$CPPFLAGS"
2018         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2019         AS_IF([ test "x$have_threads" = xno], [
2020                 AC_TRY_COMPILE([#include <pthread.h>],
2021                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2022                         have_threads=posix)
2023         ])
2024         # Tru64Unix requires -pthread to find pthread.h. See #103020
2025         CPPFLAGS="$CPPFLAGS -pthread"
2026         if test "x$have_threads" = xno; then
2027         AC_TRY_COMPILE([#include <pthread.h>],
2028                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
2029                        have_threads=posix)
2030         fi
2031         CPPFLAGS="$glib_save_CPPFLAGS"
2032 ])
2033 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
2034         case $host in
2035                 *-*-mingw*)
2036                 have_threads=win32
2037                 ;;
2038         esac
2039 fi
2040
2041 if test "x$have_threads" = xno; then
2042         AC_MSG_RESULT(none available)
2043         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
2044 else
2045         AC_MSG_RESULT($have_threads)
2046 fi
2047
2048
2049 dnl determination of G_THREAD_CFLAGS
2050 dnl ********************************
2051
2052 G_THREAD_LIBS=
2053 G_THREAD_LIBS_EXTRA=
2054 G_THREAD_CFLAGS=
2055
2056 dnl
2057 dnl Test program for basic POSIX threads functionality
2058 dnl
2059 m4_define([glib_thread_test],[
2060 #include <pthread.h>
2061 int check_me = 0;
2062 void* func(void* data) {check_me = 42; return &check_me;}
2063 int main()
2064  { pthread_t t;
2065    void *ret;
2066    pthread_create (&t, $1, func, 0);
2067    pthread_join (t, &ret);
2068    return (check_me != 42 || ret != &check_me);
2069 }])
2070
2071 AS_IF([ test x"$have_threads" = xposix], [
2072   # First we test for posix, whether -pthread or -pthreads do the trick as
2073   # both CPPFLAG and LIBS.
2074   # One of them does for most gcc versions and some other platforms/compilers
2075   # too and could be considered as the canonical way to go.
2076   case $host in
2077     *-*-cygwin*|*-*-darwin*)
2078        # skip cygwin and darwin -pthread or -pthreads test
2079        ;;
2080     *-solaris*)
2081       # These compiler/linker flags work with both Sun Studio and gcc
2082       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2083       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2084       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2085       G_THREAD_LIBS="-lpthread -lthread"
2086       ;;
2087     *)
2088       for flag in pthread pthreads mt; do
2089         glib_save_CFLAGS="$CFLAGS"
2090         CFLAGS="$CFLAGS -$flag"
2091         AC_TRY_RUN(glib_thread_test(0),
2092                    glib_flag_works=yes,
2093                    glib_flag_works=no,
2094                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2095                                    glib_flag_works=yes,
2096                                    glib_flag_works=no)])
2097         CFLAGS="$glib_save_CFLAGS"
2098         if test $glib_flag_works = yes ; then
2099            G_THREAD_CFLAGS=-$flag
2100         G_THREAD_LIBS=-$flag
2101         break;
2102         fi
2103       done
2104        ;;
2105   esac
2106 ])
2107
2108 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2109
2110   # The canonical -pthread[s] does not work. Try something different.
2111
2112   case $host in
2113         *-aix*)
2114                 if test x"$GCC" = xyes; then
2115                         # GCC 3.0 and above needs -pthread.
2116                         # Should be coverd by the case above.
2117                         # GCC 2.x and below needs -mthreads
2118                         G_THREAD_CFLAGS="-mthreads"
2119                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2120                 else
2121                         # We are probably using the aix compiler. Normaly a
2122                         # program would have to be compiled with the _r variant
2123                         # of the corresponding compiler, but we as GLib cannot
2124                         # do that: but the good news is that for compiling the
2125                         # only difference is the added -D_THREAD_SAFE compile
2126                         # option. This is according to the "C for AIX User's
2127                         # Guide".
2128                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2129                 fi
2130                 ;;
2131         *-dg-dgux*)  # DG/UX
2132                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2133                 ;;
2134         *-sysv5uw7*) # UnixWare 7
2135                 # We are not using gcc with -pthread. Catched above.
2136                 G_THREAD_CFLAGS="-Kthread"
2137                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2138                 ;;
2139         *-mingw*)
2140                 # No flag needed when using MSVCRT.DLL
2141                 G_THREAD_CFLAGS=""
2142                 ;;
2143         *)
2144                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2145                 ;;
2146   esac
2147 ])
2148
2149 # if we are not finding the localtime_r function, then we probably are
2150 # not using the proper multithread flag
2151
2152 glib_save_CPPFLAGS="$CPPFLAGS"
2153 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2154
2155 # First we test, whether localtime_r is declared in time.h
2156 # directly. Then we test whether a macro localtime_r exists, in
2157 # which case localtime_r in the test program is replaced and thus
2158 # if we still find localtime_r in the output, it is not defined as
2159 # a macro.
2160
2161 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2162   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2163                                                            localtime_r(a,b)],
2164                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2165
2166 CPPFLAGS="$glib_save_CPPFLAGS"
2167
2168 AC_MSG_CHECKING(thread related cflags)
2169 AC_MSG_RESULT($G_THREAD_CFLAGS)
2170 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2171
2172 dnl determination of G_THREAD_LIBS
2173 dnl ******************************
2174
2175 AS_IF([test x$have_threads = xposix], [
2176           glib_save_CPPFLAGS="$CPPFLAGS"
2177           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2178           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2179             case $host in
2180               *-aix*)
2181                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2182                 # probably using the aix compiler.
2183                 AC_MSG_WARN($AIX_COMPILE_INFO)
2184                 ;;
2185               *)
2186                 G_THREAD_LIBS=error
2187                 glib_save_LIBS="$LIBS"
2188                 for thread_lib in "" pthread pthread32 pthreads thread; do
2189                         if test x"$thread_lib" = x; then
2190                                 add_thread_lib=""
2191                                 IN=""
2192                         else
2193                                 add_thread_lib="-l$thread_lib"
2194                                 IN=" in -l$thread_lib"
2195                         fi
2196                         if test x"$have_threads" = xposix; then
2197                                 defattr=0
2198                         else
2199                                 defattr=pthread_attr_default
2200                         fi
2201
2202                         LIBS="$add_thread_lib $glib_save_LIBS"
2203
2204                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2205                         AC_TRY_RUN(glib_thread_test($defattr),
2206                                    glib_result=yes,
2207                                    glib_result=no,
2208                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2209                                                    glib_result=yes,
2210                                                    glib_result=no)])
2211                         AC_MSG_RESULT($glib_result)
2212
2213                         if test "$glib_result" = "yes" ; then
2214                           G_THREAD_LIBS="$add_thread_lib"
2215                           break
2216                         fi
2217                 done
2218                 if test "x$G_THREAD_LIBS" = xerror; then
2219                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2220                 fi
2221                 LIBS="$glib_save_LIBS"
2222                 ;;
2223             esac
2224           ])
2225
2226           g_threads_impl="POSIX"
2227           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2228           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2229           CPPFLAGS="$glib_save_CPPFLAGS"
2230 ], [test x$have_threads = xwin32], [
2231            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2232            g_threads_impl="WIN32"
2233 ], [
2234            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2235            g_threads_impl="NONE"
2236            G_THREAD_LIBS=error
2237 ])
2238 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2239 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2240 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2241
2242 if test "x$G_THREAD_LIBS" = xerror; then
2243         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2244 fi
2245
2246 case $host in
2247   *-*-beos*)
2248     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2249     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2250     ;;
2251   *)
2252     ;;
2253 esac
2254
2255 AC_MSG_CHECKING(thread related libraries)
2256 AC_MSG_RESULT($G_THREAD_LIBS)
2257
2258 dnl check for mt safe function variants and some posix functions
2259 dnl ************************************************************
2260
2261 glib_save_LIBS="$LIBS"
2262 # we are not doing the following for now, as this might require glib
2263 # to always be linked with the thread libs on some platforms.
2264 # LIBS="$LIBS $G_THREAD_LIBS"
2265 AC_CHECK_FUNCS(localtime_r gmtime_r)
2266 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2267         AC_CACHE_CHECK([for posix getpwuid_r],
2268                 ac_cv_func_posix_getpwuid_r,
2269                 [AC_TRY_RUN([
2270 #include <errno.h>
2271 #include <pwd.h>
2272 int main () {
2273     char buffer[10000];
2274     struct passwd pwd, *pwptr = &pwd;
2275     int error;
2276     errno = 0;
2277     error = getpwuid_r (0, &pwd, buffer,
2278                         sizeof (buffer), &pwptr);
2279    return (error < 0 && errno == ENOSYS)
2280            || error == ENOSYS;
2281 }                               ],
2282                         [ac_cv_func_posix_getpwuid_r=yes],
2283                         [ac_cv_func_posix_getpwuid_r=no])])
2284         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2285         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2286                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2287                         [Have POSIX function getpwuid_r])
2288         else
2289                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2290                         ac_cv_func_nonposix_getpwuid_r,
2291                         [AC_TRY_LINK([#include <pwd.h>],
2292                                 [char buffer[10000];
2293                                 struct passwd pwd;
2294                                 getpwuid_r (0, &pwd, buffer,
2295                                                 sizeof (buffer));],
2296                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2297                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2298                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2299                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2300                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2301                                 [Have non-POSIX function getpwuid_r])
2302                 fi
2303         fi
2304 ])
2305 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2306         AC_CACHE_CHECK([for posix getgrgid_r],
2307                 ac_cv_func_posix_getgrgid_r,
2308                 [AC_TRY_RUN([
2309 #include <errno.h>
2310 #include <grp.h>
2311 int main () {
2312     char buffer[10000];
2313     struct group grp, *grpptr = &grp;
2314     int error;
2315     errno = 0;
2316     error = getgrgid_r (0, &grp, buffer,
2317                         sizeof (buffer), &grpptr);
2318    return (error < 0 && errno == ENOSYS)
2319            || error == ENOSYS;
2320 }                              ],
2321                        [ac_cv_func_posix_getgrgid_r=yes],
2322                        [ac_cv_func_posix_getgrgid_r=no])])
2323         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2324         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2325                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2326                         [Have POSIX function getgrgid_r])
2327         ], [
2328                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2329                         ac_cv_func_nonposix_getgrgid_r,
2330                         [AC_TRY_LINK([#include <grp.h>],
2331                                 [char buffer[10000];
2332                                 struct group grp;
2333                                 getgrgid_r (0, &grp, buffer,
2334                                 sizeof (buffer));],
2335                         [ac_cv_func_nonposix_getgrgid_r=yes],
2336                         [ac_cv_func_nonposix_getgrgid_r=no])])
2337                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2338                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2339                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2340                                 [Have non-POSIX function getgrgid_r])
2341                 fi
2342         ])
2343 ])
2344 LIBS="$G_THREAD_LIBS $LIBS"
2345 AS_IF([ test x"$have_threads" = xposix], [
2346         glib_save_CPPFLAGS="$CPPFLAGS"
2347         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2348         # This is not AC_CHECK_FUNC to also work with function
2349         # name mangling in header files.
2350         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2351         AC_LINK_IFELSE(
2352             [AC_LANG_PROGRAM(
2353                 [#include <pthread.h>],
2354                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2355             [AC_MSG_RESULT(yes)
2356              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2357                 [Have function pthread_attr_setstacksize])],
2358             [AC_MSG_RESULT(no)])
2359         AC_MSG_CHECKING(for pthread_condattr_setclock)
2360         AC_LINK_IFELSE(
2361             [AC_LANG_PROGRAM(
2362                 [#include <pthread.h>],
2363                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2364             [AC_MSG_RESULT(yes)
2365              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2366                 [Have function pthread_condattr_setclock])],
2367             [AC_MSG_RESULT(no)])
2368         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2369         AC_LINK_IFELSE(
2370             [AC_LANG_PROGRAM(
2371                 [#include <pthread.h>],
2372                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2373             [AC_MSG_RESULT(yes)
2374              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2375                 [Have function pthread_cond_timedwait_monotonic])],
2376             [AC_MSG_RESULT(no)])
2377         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2378         AC_LINK_IFELSE(
2379             [AC_LANG_PROGRAM(
2380                 [#include <pthread.h>],
2381                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2382             [AC_MSG_RESULT(yes)
2383              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2384                 [Have function pthread_cond_timedwait_monotonic_np])],
2385             [AC_MSG_RESULT(no)])
2386         CPPFLAGS="$glib_save_CPPFLAGS"
2387 ])
2388
2389 LIBS="$glib_save_LIBS"
2390
2391 # now spit out all the warnings.
2392 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2393    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2394         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2395 fi
2396 if test "$ac_cv_func_localtime_r" != "yes"; then
2397         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2398 fi
2399
2400 #
2401 # Hack to deal with:
2402 #
2403 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2404 #     building shared libraries with linux.
2405 #  b) FreeBSD doesn't do this either.
2406 #
2407 case $host in
2408   *android*)
2409     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2410     ;;
2411   *-*-freebsd*|*-*-linux*)
2412     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2413     ;;
2414   *-*-openbsd*)
2415     LDFLAGS="$LDFLAGS -pthread"
2416     ;;
2417   *)
2418     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2419     ;;
2420 esac
2421
2422 AC_SUBST(G_THREAD_CFLAGS)
2423 AC_SUBST(G_THREAD_LIBS)
2424 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2425 AC_SUBST(G_THREAD_LIBS_EXTRA)
2426
2427 AC_CHECK_FUNCS(clock_gettime, [], [
2428   AC_CHECK_LIB(rt, clock_gettime, [
2429     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2430     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2431     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2432   ])
2433 ])
2434
2435
2436 dnl ************************
2437 dnl *** g_atomic_* tests ***
2438 dnl ************************
2439
2440 dnl We need to decide at configure time if GLib will use real atomic
2441 dnl operations ("lock free") or emulated ones with a mutex.  This is
2442 dnl because we must put this information in glibconfig.h so we know if
2443 dnl it is safe or not to inline using compiler intrinsics directly from
2444 dnl the header.
2445 dnl
2446 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2447 dnl user is interested in knowing if they can use the atomic ops across
2448 dnl processes.
2449 dnl
2450 dnl We can currently support the atomic ops natively when building GLib
2451 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2452 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2453 dnl we are using GCC (and not mingw*).
2454 dnl
2455 dnl Note that the atomic ops are only available with GCC on x86 when
2456 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2457 dnl not available but would be available given the right flags, we want
2458 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2459 dnl that then to silently fall back on emulated atomic ops just because
2460 dnl the user had the wrong build environment.
2461
2462 dnl We may add other compilers here in the future...
2463
2464 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2465   case $host in
2466     *-*-mingw*)
2467       glib_cv_g_atomic_lock_free=yes
2468       ;;
2469     *)
2470       AC_TRY_LINK([],
2471                      [volatile int atomic = 2;\
2472                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2473                      [glib_cv_g_atomic_lock_free=yes],
2474                      [glib_cv_g_atomic_lock_free=no])
2475       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2476         SAVE_CFLAGS="${CFLAGS}"
2477         CFLAGS="-march=i486"
2478         AC_TRY_LINK([],
2479                        [volatile int atomic = 2;\
2480                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2481                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2482                        [])
2483         CFLAGS="${SAVE_CFLAGS}"
2484       fi
2485       ;;
2486   esac])
2487
2488
2489 case $host in
2490   *-*-mingw*)
2491     ;;
2492   *)
2493     # Some compilers support atomic operations but do not define
2494     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2495     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2496       AC_TRY_LINK([],
2497                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2498                      [],
2499                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2500     fi
2501     ;;
2502  esac
2503
2504 dnl We need a more robust approach here...
2505 case $host_cpu in
2506   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2507     glib_memory_barrier_needed=no
2508     ;;
2509   sparc*|alpha*|powerpc*|ia64)
2510     glib_memory_barrier_needed=yes
2511     ;;
2512   *)
2513     glib_memory_barrier_needed=yes
2514     ;;
2515 esac
2516
2517 dnl ************************
2518 dnl ** Check for futex(2) **
2519 dnl ************************
2520 AC_CACHE_CHECK(for futex(2) system call,
2521     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2522 #include <linux/futex.h>
2523 #include <sys/syscall.h>
2524 #include <unistd.h>
2525 ],[
2526 int
2527 main (void)
2528 {
2529   /* it is not like this actually runs or anything... */
2530   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2531   return 0;
2532 }
2533 ])],glib_cv_futex=yes,glib_cv_futex=no))
2534 if test x"$glib_cv_futex" = xyes; then
2535   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2536 fi
2537
2538 AC_CACHE_CHECK(for eventfd(2) system call,
2539     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2540 #include <sys/eventfd.h>
2541 #include <unistd.h>
2542 ],[
2543 int
2544 main (void)
2545 {
2546   eventfd (0, EFD_CLOEXEC);
2547   return 0;
2548 }
2549 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2550 if test x"$glib_cv_eventfd" = x"yes"; then
2551   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2552 fi
2553 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2554
2555 dnl ****************************************
2556 dnl *** GLib POLL* compatibility defines ***
2557 dnl ****************************************
2558
2559 glib_poll_includes=["
2560 #include <sys/types.h>
2561 #include <sys/poll.h>
2562 "]
2563
2564 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2565    test $ac_cv_header_sys_poll_h = yes ], [
2566   glib_failed=false
2567   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2568   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2569   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2570   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2571   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2572   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2573   if $glib_failed ; then
2574     AC_MSG_ERROR([Could not determine values for POLL* constants])
2575   fi
2576 ], [
2577   glib_cv_value_POLLIN=1
2578   glib_cv_value_POLLOUT=4
2579   glib_cv_value_POLLPRI=2
2580   glib_cv_value_POLLERR=8
2581   glib_cv_value_POLLHUP=16
2582   glib_cv_value_POLLNVAL=32
2583 ])
2584
2585 AC_MSG_CHECKING([for broken poll])
2586 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2587         #include <stdlib.h>
2588         #include <fcntl.h>
2589         #include <poll.h>
2590         #ifdef HAVE_SYS_POLL_H
2591         #include <sys/poll.h>
2592         #endif
2593         int main(void) {
2594           struct pollfd fds[1];
2595           int fd;
2596           fd = open("/dev/null", 1);
2597           fds[0].fd = fd;
2598           fds[0].events = POLLIN;
2599           fds[0].revents = 0;
2600           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2601                 exit(1);  /* Does not work for devices -- fail */
2602           }
2603           exit(0);
2604         }]])],
2605   [broken_poll=no],
2606   [broken_poll=yes
2607    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2608   [broken_poll="no (cross compiling)"])
2609 AC_MSG_RESULT($broken_poll)
2610
2611 dnl *********************
2612 dnl *** GRegex checks ***
2613 dnl *********************
2614
2615 PCRE_REQUIRED_VERSION=8.13
2616
2617 # Check if we should use the internal or the system-supplied pcre
2618 AC_ARG_WITH(pcre,
2619             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2620                             [whether to use system PCRE [default=internal]])])
2621
2622 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2623
2624 AS_IF([ test "x$with_pcre" = xsystem], [
2625   PKG_CHECK_MODULES(PCRE,
2626                     libpcre >= $PCRE_REQUIRED_VERSION)
2627   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2628                   glib_save_CFLAGS="$CFLAGS"
2629                   glib_save_LIBS="$LIBS"
2630                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2631                   AC_TRY_RUN([#include <pcre.h>
2632                               int main () {
2633                                 int support;
2634                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2635                                 if (!support)
2636                                   return 1;
2637                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2638                                 if (!support)
2639                                   return 1;
2640                                 return 0;
2641                               }],
2642                   glib_cv_pcre_has_unicode=yes,
2643                   glib_cv_pcre_has_unicode=no,
2644                   glib_cv_pcre_has_unicode=yes)
2645                   CFLAGS="$glib_save_CFLAGS"
2646                   LIBS="$glib_save_LIBS"
2647       ])
2648   if test "$glib_cv_pcre_has_unicode" = "no"; then
2649     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2650   fi
2651   AC_SUBST(PCRE_CFLAGS)
2652   AC_SUBST(PCRE_LIBS)
2653   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2654   PCRE_REQUIRES=libpcre
2655   AC_SUBST(PCRE_REQUIRES)
2656 ], [
2657   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2658   AS_IF([ test x"$GCC" = xyes], [
2659     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2660     save_CFLAGS="$CFLAGS"
2661     CFLAGS="$CFLAGS -Wno-pointer-sign"
2662     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2663                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2664     CFLAGS="$save_CFLAGS"
2665   ])
2666 ])
2667 AC_SUBST(PCRE_WARN_CFLAGS)
2668
2669 dnl **********************
2670 dnl *** Win32 API libs ***
2671 dnl **********************
2672
2673 case $host in
2674   *-*-cygwin*)
2675         G_LIBS_EXTRA="-luser32 -lkernel32"
2676     ;;
2677   *-*-mingw*)
2678         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2679     ;;
2680   *)
2681         G_LIBS_EXTRA=""
2682     ;;
2683 esac
2684 AC_SUBST(G_LIBS_EXTRA)
2685
2686 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2687 dnl since we need it for g_iconv()
2688
2689 AC_MSG_CHECKING([for EILSEQ])
2690 AC_TRY_COMPILE([
2691 #include <errno.h>
2692 ],
2693 [
2694 int error = EILSEQ;
2695 ], have_eilseq=yes, have_eilseq=no);
2696 AC_MSG_RESULT($have_eilseq)
2697
2698 dnl ******************************************************************
2699 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2700 dnl *** glib-compile-schemas in PATH                               ***
2701 dnl ******************************************************************
2702
2703 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2704
2705 AS_IF([ test $cross_compiling = yes ], [
2706   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2707   if test x$GLIB_GENMARSHAL = xno; then
2708     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2709   fi
2710
2711   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2712   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2713     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2714   fi
2715
2716   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2717   if test x$GLIB_COMPILE_RESOURCES = xno; then
2718     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2719   fi
2720 ])
2721
2722 dnl **************************
2723 dnl *** Checks for gtk-doc ***
2724 dnl **************************
2725 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2726 # it on it's own line.
2727 m4_ifdef([GTK_DOC_CHECK], [
2728 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2729 ],[
2730 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2731 ])
2732
2733 AC_ARG_ENABLE(man,
2734               [AS_HELP_STRING([--enable-man],
2735                               [generate man pages [default=auto]])],,
2736               enable_man=maybe)
2737
2738 AS_IF([test "$enable_man" != no], [
2739   AC_PATH_PROG([XSLTPROC], [xsltproc])
2740   AS_IF([test -z "$XSLTPROC"], [
2741     AS_IF([test "$enable_man" = yes], [
2742       AC_MSG_ERROR([xsltproc is required for --enable-man])
2743     ])
2744     enable_man=no
2745   ])
2746 ])
2747
2748 AS_IF([ test "$enable_man" != no ], [
2749   dnl check for DocBook DTD in the local catalog
2750   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2751      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2752   AS_IF([test "$have_docbook_dtd" != yes], [
2753     AS_IF([test "$enable_man" = yes ], [
2754       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2755     ])
2756     enable_man=no
2757   ])
2758 ])
2759
2760 AS_IF([test "$enable_man" != no], [
2761   dnl check for DocBook XSL stylesheets in the local catalog
2762   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2763      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2764   AS_IF([ test "$have_docbook_dtd" != yes ], [
2765     AS_IF([ test "$enable_man" = yes ], [
2766       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2767     ])
2768     enable_man=no
2769   ])
2770 ])
2771
2772 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2773
2774 AC_MSG_CHECKING([whether to generate man pages])
2775 AS_IF([ test "$enable_man" != no ], [
2776   AC_MSG_RESULT([yes])
2777 ], [
2778   AC_MSG_RESULT([no])
2779 ])
2780
2781 dnl
2782 dnl Tracing
2783 dnl
2784
2785 AC_ARG_ENABLE([dtrace],
2786              [AS_HELP_STRING([--enable-dtrace],
2787                               [include tracing support for dtrace])])
2788 have_dtrace=no
2789 AC_MSG_CHECKING([whether to include dtrace tracing support])
2790 AS_IF([ test "x$enable_dtrace" != xno], [
2791   if test x$glib_have_carbon = xyes; then
2792     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2793   else
2794     AC_MSG_RESULT([yes])
2795     AC_CHECK_PROGS(DTRACE, dtrace)
2796     if test -z "$DTRACE"; then
2797       if test "x$enable_dtrace" = xyes; then
2798         AC_MSG_ERROR([dtrace not found])
2799       fi
2800     else
2801       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2802                       [if test "x$enable_dtrace" = xyes; then
2803                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2804                        fi])
2805     fi
2806   fi
2807 ], [
2808   AC_MSG_RESULT([no])
2809 ])
2810 if test "x$have_dtrace" = xyes; then
2811   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2812 fi
2813 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2814
2815 AC_MSG_CHECKING([whether to include systemtap tracing support])
2816 AC_ARG_ENABLE([systemtap],
2817              [AS_HELP_STRING([--enable-systemtap],
2818                               [include tracing support for systemtap])])
2819 have_systemtap=no
2820 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2821   have_systemtap=yes
2822 fi
2823 AC_MSG_RESULT(${have_systemtap})
2824
2825 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2826
2827 AC_ARG_WITH([tapset-install-dir],
2828             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2829                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2830             [if test "x${withval}" = x; then
2831                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2832              else
2833                ABS_TAPSET_DIR="${withval}"
2834               fi],
2835             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2836 AC_SUBST(ABS_TAPSET_DIR)
2837
2838 dnl ************************************
2839 dnl *** Enable lcov coverage reports ***
2840 dnl ************************************
2841
2842 AC_ARG_ENABLE(gcov,
2843   AS_HELP_STRING([--enable-gcov],
2844                  [enable coverage testing with gcov]),
2845   [use_gcov=$enableval], [use_gcov=no])
2846
2847 AS_IF([ test "x$use_gcov" = "xyes"], [
2848   dnl we need gcc:
2849   if test "$GCC" != "yes"; then
2850     AC_MSG_ERROR([GCC is required for --enable-gcov])
2851   fi
2852
2853   dnl Check if ccache is being used
2854   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2855   case `$SHTOOL path $CC` in
2856     *ccache*[)] gcc_ccache=yes;;
2857     *[)] gcc_ccache=no;;
2858   esac
2859
2860   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2861     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2862   fi
2863
2864   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2865   AC_CHECK_PROG(LTP, lcov, lcov)
2866   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2867
2868   AS_IF([ test "$LTP" ], [
2869     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2870       glib_cv_ltp_version=invalid
2871       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2872       for ltp_check_version in $ltp_version_list; do
2873         if test "$ltp_version" = "$ltp_check_version"; then
2874           glib_cv_ltp_version="$ltp_check_version (ok)"
2875         fi
2876       done
2877     ])
2878   ], [
2879     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2880     AC_MSG_ERROR([$ltp_msg])
2881   ])
2882
2883   case $glib_cv_ltp_version in
2884     ""|invalid[)]
2885       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2886       AC_MSG_ERROR([$ltp_msg])
2887       LTP="exit 0;"
2888       ;;
2889   esac
2890
2891   if test -z "$LTP_GENHTML"; then
2892     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2893   fi
2894
2895   dnl Remove all optimization flags from CFLAGS
2896   changequote({,})
2897   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2898   changequote([,])
2899
2900   dnl Add the special gcc flags
2901   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2902   LDFLAGS="$LDFLAGS -lgcov"
2903 ])
2904
2905 dnl ******************************
2906 dnl *** output the whole stuff ***
2907 dnl ******************************
2908
2909 dnl this section will only be run if config.status is invoked with no
2910 dnl arguments, or with "glib/glibconfig.h" as an argument.
2911 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2912 [
2913         outfile=glib/glibconfig.h-tmp
2914         cat > $outfile <<\_______EOF
2915 /* glibconfig.h
2916  *
2917  * This is a generated file.  Please modify 'configure.ac'
2918  */
2919
2920 #ifndef __GLIBCONFIG_H__
2921 #define __GLIBCONFIG_H__
2922
2923 #include <glib/gmacros.h>
2924
2925 _______EOF
2926
2927         if test x$glib_limits_h = xyes; then
2928           echo '#include <limits.h>' >> $outfile
2929         fi
2930         if test x$glib_float_h = xyes; then
2931           echo '#include <float.h>' >> $outfile
2932         fi
2933         if test x$glib_values_h = xyes; then
2934           echo '#include <values.h>' >> $outfile
2935         fi
2936         if test "$glib_header_alloca_h" = "yes"; then
2937           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2938         fi
2939         if test x$glib_sys_poll_h = xyes; then
2940           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2941         fi
2942         if test x$glib_included_printf != xyes; then
2943           echo "
2944 /* Specifies that GLib's g_print*() functions wrap the
2945  * system printf functions.  This is useful to know, for example,
2946  * when using glibc's register_printf_function().
2947  */" >> $outfile
2948           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2949         fi
2950
2951         cat >> $outfile <<_______EOF
2952
2953 G_BEGIN_DECLS
2954
2955 #define G_MINFLOAT      $glib_mf
2956 #define G_MAXFLOAT      $glib_Mf
2957 #define G_MINDOUBLE     $glib_md
2958 #define G_MAXDOUBLE     $glib_Md
2959 #define G_MINSHORT      $glib_ms
2960 #define G_MAXSHORT      $glib_Ms
2961 #define G_MAXUSHORT     $glib_Mus
2962 #define G_MININT        $glib_mi
2963 #define G_MAXINT        $glib_Mi
2964 #define G_MAXUINT       $glib_Mui
2965 #define G_MINLONG       $glib_ml
2966 #define G_MAXLONG       $glib_Ml
2967 #define G_MAXULONG      $glib_Mul
2968
2969 _______EOF
2970
2971
2972         ### this should always be true in a modern C/C++ compiler
2973         cat >>$outfile <<_______EOF
2974 typedef signed char gint8;
2975 typedef unsigned char guint8;
2976 _______EOF
2977
2978
2979         if test -n "$gint16"; then
2980           cat >>$outfile <<_______EOF
2981 typedef signed $gint16 gint16;
2982 typedef unsigned $gint16 guint16;
2983 #define G_GINT16_MODIFIER $gint16_modifier
2984 #define G_GINT16_FORMAT $gint16_format
2985 #define G_GUINT16_FORMAT $guint16_format
2986 _______EOF
2987         fi
2988
2989
2990         if test -n "$gint32"; then
2991           cat >>$outfile <<_______EOF
2992 typedef signed $gint32 gint32;
2993 typedef unsigned $gint32 guint32;
2994 #define G_GINT32_MODIFIER $gint32_modifier
2995 #define G_GINT32_FORMAT $gint32_format
2996 #define G_GUINT32_FORMAT $guint32_format
2997 _______EOF
2998         fi
2999
3000         cat >>$outfile <<_______EOF
3001 #define G_HAVE_GINT64 1          /* deprecated, always true */
3002
3003 ${glib_extension}typedef signed $gint64 gint64;
3004 ${glib_extension}typedef unsigned $gint64 guint64;
3005
3006 #define G_GINT64_CONSTANT(val)  $gint64_constant
3007 #define G_GUINT64_CONSTANT(val) $guint64_constant
3008 _______EOF
3009
3010         if test x$gint64_format != x ; then
3011           cat >>$outfile <<_______EOF
3012 #define G_GINT64_MODIFIER $gint64_modifier
3013 #define G_GINT64_FORMAT $gint64_format
3014 #define G_GUINT64_FORMAT $guint64_format
3015 _______EOF
3016         else
3017           cat >>$outfile <<_______EOF
3018 #undef G_GINT64_MODIFIER
3019 #undef G_GINT64_FORMAT
3020 #undef G_GUINT64_FORMAT
3021 _______EOF
3022         fi
3023
3024         cat >>$outfile <<_______EOF
3025
3026 #define GLIB_SIZEOF_VOID_P $glib_void_p
3027 #define GLIB_SIZEOF_LONG   $glib_long
3028 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3029 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
3030
3031 _______EOF
3032
3033         cat >>$outfile <<_______EOF
3034 typedef signed $glib_ssize_type_define gssize;
3035 typedef unsigned $glib_size_type_define gsize;
3036 #define G_GSIZE_MODIFIER $gsize_modifier
3037 #define G_GSSIZE_MODIFIER $gssize_modifier
3038 #define G_GSIZE_FORMAT $gsize_format
3039 #define G_GSSIZE_FORMAT $gssize_format
3040
3041 #define G_MAXSIZE       G_MAXU$glib_msize_type
3042 #define G_MINSSIZE      G_MIN$glib_mssize_type
3043 #define G_MAXSSIZE      G_MAX$glib_mssize_type
3044
3045 typedef gint64 goffset;
3046 #define G_MINOFFSET     G_MININT64
3047 #define G_MAXOFFSET     G_MAXINT64
3048
3049 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3050 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3051 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3052
3053 _______EOF
3054
3055         if test -z "$glib_unknown_void_p"; then
3056           cat >>$outfile <<_______EOF
3057
3058 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3059 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3060
3061 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3062 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3063
3064 typedef signed $glib_intptr_type_define gintptr;
3065 typedef unsigned $glib_intptr_type_define guintptr;
3066
3067 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3068 #define G_GINTPTR_FORMAT        $gintptr_format
3069 #define G_GUINTPTR_FORMAT       $guintptr_format
3070 _______EOF
3071         else
3072           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3073         fi
3074
3075
3076
3077         cat >>$outfile <<_______EOF
3078 $glib_atexit
3079 $glib_memmove
3080 $glib_defines
3081 $glib_os
3082 $glib_static_compilation
3083
3084 $glib_vacopy
3085
3086 #ifdef  __cplusplus
3087 #define G_HAVE_INLINE   1
3088 #else   /* !__cplusplus */
3089 $glib_inline
3090 #endif  /* !__cplusplus */
3091
3092 #ifdef  __cplusplus
3093 #define G_CAN_INLINE    1
3094 _______EOF
3095
3096         if test x$g_can_inline = xyes ; then
3097                 cat >>$outfile <<_______EOF
3098 #else   /* !__cplusplus */
3099 #define G_CAN_INLINE    1
3100 _______EOF
3101         fi
3102
3103         cat >>$outfile <<_______EOF
3104 #endif
3105
3106 _______EOF
3107
3108         if test x$g_have_iso_c_varargs = xyes ; then
3109                 cat >>$outfile <<_______EOF
3110 #ifndef __cplusplus
3111 # define G_HAVE_ISO_VARARGS 1
3112 #endif
3113 _______EOF
3114         fi
3115         if test x$g_have_iso_cxx_varargs = xyes ; then
3116                 cat >>$outfile <<_______EOF
3117 #ifdef __cplusplus
3118 # define G_HAVE_ISO_VARARGS 1
3119 #endif
3120 _______EOF
3121         fi
3122         if test x$g_have_gnuc_varargs = xyes ; then
3123                 cat >>$outfile <<_______EOF
3124
3125 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3126  * is passed ISO vararg support is turned off, and there is no work
3127  * around to turn it on, so we unconditionally turn it off.
3128  */
3129 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3130 #  undef G_HAVE_ISO_VARARGS
3131 #endif
3132
3133 #define G_HAVE_GNUC_VARARGS 1
3134 _______EOF
3135         fi
3136
3137         case x$g_stack_grows in
3138         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3139         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3140         esac
3141
3142
3143         echo >>$outfile
3144         if test x$g_have_eilseq = xno; then
3145                 cat >>$outfile <<_______EOF
3146 #ifndef EILSEQ
3147 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3148  * The correspondence between this and the corresponding definition
3149  * in libiconv is essential.
3150  */
3151 #  define EILSEQ ENOENT
3152 #endif
3153 _______EOF
3154
3155         fi
3156
3157         if test x$g_have_gnuc_visibility = xyes; then
3158                 cat >>$outfile <<_______EOF
3159 #define G_HAVE_GNUC_VISIBILITY 1
3160 _______EOF
3161         fi
3162                 cat >>$outfile <<_______EOF
3163 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3164 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3165 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3166 #define G_GNUC_INTERNAL __hidden
3167 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3168 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3169 #else
3170 #define G_GNUC_INTERNAL
3171 #endif
3172 _______EOF
3173
3174         echo >>$outfile
3175         cat >>$outfile <<_______EOF
3176 #define G_THREADS_ENABLED
3177 #define G_THREADS_IMPL_$g_threads_impl_def
3178 _______EOF
3179
3180         if test x"$g_memory_barrier_needed" != xno; then
3181           echo >>$outfile
3182           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3183         fi
3184         if test x"$g_atomic_lock_free" = xyes; then
3185           echo >>$outfile
3186           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3187         fi
3188         echo >>$outfile
3189         g_bit_sizes="16 32 64"
3190         for bits in $g_bit_sizes; do
3191           cat >>$outfile <<_______EOF
3192 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3193 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3194 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3195 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3196 _______EOF
3197         done
3198
3199         cat >>$outfile <<_______EOF
3200 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3201 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3202 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3203 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3204 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3205 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3206 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3207 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3208 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3209 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3210 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3211 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3212 #define G_BYTE_ORDER $g_byte_order
3213
3214 #define GLIB_SYSDEF_POLLIN =$g_pollin
3215 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3216 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3217 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3218 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3219 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3220
3221 #define G_MODULE_SUFFIX "$g_module_suffix"
3222
3223 typedef $g_pid_type GPid;
3224
3225 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3226 #define GLIB_SYSDEF_AF_INET $g_af_inet
3227 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3228
3229 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3230 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3231 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3232
3233 G_END_DECLS
3234
3235 #endif /* __GLIBCONFIG_H__ */
3236 _______EOF
3237
3238
3239         if cmp -s $outfile glib/glibconfig.h; then
3240           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3241           rm -f $outfile
3242         else
3243           mv $outfile glib/glibconfig.h
3244         fi
3245 ],[
3246
3247 # Note that if two cases are the same, case goes with the first one.
3248 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3249 # on variable expansion in case labels.  Look at the generated config.status
3250 # for a hint.
3251
3252 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3253   glib_header_alloca_h="$ac_cv_working_alloca_h"
3254 else
3255   glib_header_alloca_h="$ac_cv_header_alloca_h"
3256 fi
3257
3258 case xyes in
3259 x$ac_cv_header_float_h)
3260   glib_float_h=yes
3261   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3262   glib_md=DBL_MIN glib_Md=DBL_MAX
3263   ;;
3264 x$ac_cv_header_values_h)
3265   glib_values_h=yes
3266   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3267   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3268   ;;
3269 esac
3270
3271 case xyes in
3272 x$ac_cv_header_limits_h)
3273   glib_limits_h=yes
3274   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3275   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3276   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3277   ;;
3278 x$ac_cv_header_values_h)
3279   glib_values_h=yes
3280   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3281   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3282   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3283   ;;
3284 esac
3285
3286 if test x$ac_cv_header_sys_poll_h = xyes ; then
3287   glib_sys_poll_h=yes
3288 fi
3289
3290 if test x$enable_included_printf = xyes ; then
3291   glib_included_printf=yes
3292 fi
3293
3294 case 2 in
3295 $ac_cv_sizeof_short)
3296   gint16=short
3297   gint16_modifier='"h"'
3298   gint16_format='"hi"'
3299   guint16_format='"hu"'
3300   ;;
3301 $ac_cv_sizeof_int)
3302   gint16=int
3303   gint16_modifier='""'
3304   gint16_format='"i"'
3305   guint16_format='"u"'
3306   ;;
3307 esac
3308 case 4 in
3309 $ac_cv_sizeof_short)
3310   gint32=short
3311   gint32_modifier='"h"'
3312   gint32_format='"hi"'
3313   guint32_format='"hu"'
3314   ;;
3315 $ac_cv_sizeof_int)
3316   gint32=int
3317   gint32_modifier='""'
3318   gint32_format='"i"'
3319   guint32_format='"u"'
3320   ;;
3321 $ac_cv_sizeof_long)
3322   gint32=long
3323   gint32_modifier='"l"'
3324   gint32_format='"li"'
3325   guint32_format='"lu"'
3326   ;;
3327 esac
3328 case 8 in
3329 $ac_cv_sizeof_int)
3330   gint64=int
3331   gint64_modifier='""'
3332   gint64_format='"i"'
3333   guint64_format='"u"'
3334   glib_extension=
3335   gint64_constant='(val)'
3336   guint64_constant='(val)'
3337   ;;
3338 $ac_cv_sizeof_long)
3339   gint64=long
3340   gint64_modifier='"l"'
3341   gint64_format='"li"'
3342   guint64_format='"lu"'
3343   glib_extension=
3344   gint64_constant='(val##L)'
3345   guint64_constant='(val##UL)'
3346   ;;
3347 $ac_cv_sizeof_long_long)
3348   gint64='long long'
3349   if test -n "$glib_cv_long_long_format"; then
3350     gint64_modifier='"'$glib_cv_long_long_format'"'
3351     gint64_format='"'$glib_cv_long_long_format'i"'
3352     guint64_format='"'$glib_cv_long_long_format'u"'
3353   fi
3354   glib_extension='G_GNUC_EXTENSION '
3355   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3356   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3357   ;;
3358 $ac_cv_sizeof___int64)
3359   gint64='__int64'
3360   if test -n "$glib_cv_long_long_format"; then
3361     gint64_modifier='"'$glib_cv_long_long_format'"'
3362     gint64_format='"'$glib_cv_long_long_format'i"'
3363     guint64_format='"'$glib_cv_long_long_format'u"'
3364   fi
3365   glib_extension=
3366   gint64_constant='(val##i64)'
3367   guint64_constant='(val##ui64)'
3368   ;;
3369 esac
3370 glib_size_t=$ac_cv_sizeof_size_t
3371 glib_ssize_t=$ac_cv_sizeof_ssize_t
3372 glib_size_type_define="$glib_size_type"
3373 glib_ssize_type_define="$glib_ssize_type"
3374 glib_void_p=$ac_cv_sizeof_void_p
3375 glib_long=$ac_cv_sizeof_long
3376
3377 case "$glib_size_type" in
3378 short)
3379   gsize_modifier='"h"'
3380   gsize_format='"hu"'
3381   glib_msize_type='SHRT'
3382   ;;
3383 int)
3384   gsize_modifier='""'
3385   gsize_format='"u"'
3386   glib_msize_type='INT'
3387   ;;
3388 long)
3389   gsize_modifier='"l"'
3390   gsize_format='"lu"'
3391   glib_msize_type='LONG'
3392   ;;
3393 "long long"|__int64)
3394   gsize_modifier='"I64"'
3395   gsize_format='"I64u"'
3396   glib_msize_type='INT64'
3397   ;;
3398 esac
3399
3400 case "$glib_ssize_type" in
3401 short)
3402   gssize_modifier='"h"'
3403   gssize_format='"hi"'
3404   glib_mssize_type='SHRT'
3405   ;;
3406 int)
3407   gssize_modifier='""'
3408   gssize_format='"i"'
3409   glib_mssize_type='INT'
3410   ;;
3411 long)
3412   gssize_modifier='"l"'
3413   gssize_format='"li"'
3414   glib_mssize_type='LONG'
3415   ;;
3416 "long long"|__int64)
3417   gssize_modifier='"I64"'
3418   gssize_format='"I64i"'
3419   glib_mssize_type='INT64'
3420   ;;
3421 esac
3422
3423 gintbits=`expr $ac_cv_sizeof_int \* 8`
3424 glongbits=`expr $ac_cv_sizeof_long \* 8`
3425 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3426 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3427
3428 case $ac_cv_sizeof_void_p in
3429 $ac_cv_sizeof_int)
3430   glib_intptr_type_define=int
3431   gintptr_modifier='""'
3432   gintptr_format='"i"'
3433   guintptr_format='"u"'
3434   glib_gpi_cast='(gint)'
3435   glib_gpui_cast='(guint)'
3436   ;;
3437 $ac_cv_sizeof_long)
3438   glib_intptr_type_define=long
3439   gintptr_modifier='"l"'
3440   gintptr_format='"li"'
3441   guintptr_format='"lu"'
3442   glib_gpi_cast='(glong)'
3443   glib_gpui_cast='(gulong)'
3444   ;;
3445 $ac_cv_sizeof_long_long)
3446   glib_intptr_type_define='long long'
3447   gintptr_modifier='"I64"'
3448   gintptr_format='"I64i"'
3449   guintptr_format='"I64u"'
3450   glib_gpi_cast='(gint64)'
3451   glib_gpui_cast='(guint64)'
3452   ;;
3453 $ac_cv_sizeof___int64)
3454   glib_intptr_type_define=__int64
3455   gintptr_modifier='"I64"'
3456   gintptr_format='"I64i"'
3457   guintptr_format='"I64u"'
3458   glib_gpi_cast='(gint64)'
3459   glib_gpui_cast='(guint64)'
3460   ;;
3461 *)
3462   glib_unknown_void_p=yes
3463   ;;
3464 esac
3465
3466
3467 case xyes in
3468 x$ac_cv_func_atexit)
3469   glib_atexit="
3470 #ifdef NeXT /* @#%@! NeXTStep */
3471 # define g_ATEXIT(proc) (!atexit (proc))
3472 #else
3473 # define g_ATEXIT(proc) (atexit (proc))
3474 #endif"
3475   ;;
3476 x$ac_cv_func_on_exit)
3477   glib_atexit="
3478 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3479   ;;
3480 esac
3481
3482 case xyes in
3483 x$ac_cv_func_memmove)
3484   glib_memmove='
3485 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3486   ;;
3487 x$glib_cv_working_bcopy)
3488   glib_memmove="
3489 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3490 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3491   ;;
3492 *)
3493   glib_memmove="
3494 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3495  * so we have to roll our own copy routine. */
3496 void g_memmove (void* dest, const void * src, unsigned long len);"
3497   ;;
3498 esac
3499
3500 glib_defines="
3501 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3502 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3503 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3504 "
3505
3506 case xyes in
3507 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3508 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3509 *)                      glib_vacopy=''
3510 esac
3511
3512 if test x$glib_cv_va_val_copy = xno; then
3513   glib_vacopy="\$glib_vacopy
3514 #define G_VA_COPY_AS_ARRAY 1"
3515 fi
3516
3517 if test x$glib_cv_hasinline = xyes; then
3518     glib_inline='#define G_HAVE_INLINE 1'
3519 fi
3520 if test x$glib_cv_has__inline = xyes; then
3521     glib_inline="\$glib_inline
3522 #define G_HAVE___INLINE 1"
3523 fi
3524 if test x$glib_cv_has__inline__ = xyes; then
3525     glib_inline="\$glib_inline
3526 #define G_HAVE___INLINE__ 1"
3527 fi
3528
3529 g_have_gnuc_varargs=$g_have_gnuc_varargs
3530 g_have_iso_c_varargs=$g_have_iso_c_varargs
3531 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3532
3533 g_can_inline=$g_can_inline
3534 g_have_gnuc_visibility=$g_have_gnuc_visibility
3535 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3536
3537 if test x$ac_cv_c_bigendian = xyes; then
3538   g_byte_order=G_BIG_ENDIAN
3539   g_bs_native=BE
3540   g_bs_alien=LE
3541 else
3542   g_byte_order=G_LITTLE_ENDIAN
3543   g_bs_native=LE
3544   g_bs_alien=BE
3545 fi
3546
3547 g_pollin=$glib_cv_value_POLLIN
3548 g_pollout=$glib_cv_value_POLLOUT
3549 g_pollpri=$glib_cv_value_POLLPRI
3550 g_pollhup=$glib_cv_value_POLLHUP
3551 g_pollerr=$glib_cv_value_POLLERR
3552 g_pollnval=$glib_cv_value_POLLNVAL
3553
3554 # If a family is not found on the system, define that family to
3555 # a negative value, picking a different one for each undefined
3556 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3557 # This is needed because glib-mkenums doesn't handle optional
3558 # values in enums, and thus we have to have all existing values
3559 # defined in the enum.
3560 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3561   g_af_unix=$glib_cv_value_AF_UNIX
3562 else
3563   g_af_unix=-1
3564 fi
3565 g_af_inet=$glib_cv_value_AF_INET
3566 g_af_inet6=$glib_cv_value_AF_INET6
3567
3568 g_msg_peek=$glib_cv_value_MSG_PEEK
3569 g_msg_oob=$glib_cv_value_MSG_OOB
3570 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3571
3572 g_stack_grows=$glib_cv_stack_grows
3573
3574 g_have_eilseq=$have_eilseq
3575
3576 g_threads_impl_def=$g_threads_impl
3577
3578 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3579 g_memory_barrier_needed="$glib_memory_barrier_needed"
3580 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3581
3582 g_module_suffix="$glib_gmodule_suffix"
3583
3584 g_pid_type="$glib_pid_type"
3585 case $host in
3586   *-*-beos*)
3587     glib_os="#define G_OS_BEOS"
3588     ;;
3589   *-*-cygwin*)
3590     glib_os="#define G_OS_UNIX
3591 #define G_PLATFORM_WIN32
3592 #define G_WITH_CYGWIN"
3593     ;;
3594   *-*-mingw*)
3595     glib_os="#define G_OS_WIN32
3596 #define G_PLATFORM_WIN32"
3597     ;;
3598   *)
3599     glib_os="#define G_OS_UNIX"
3600     ;;
3601 esac
3602 glib_static_compilation=""
3603 if test x$glib_win32_static_compilation = xyes; then
3604   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3605 #define GOBJECT_STATIC_COMPILATION 1"
3606 fi
3607 ])
3608
3609 # Redo enough to get guint32 and guint64 for the alignment checks below
3610 case 4 in
3611 $ac_cv_sizeof_short)
3612   gint32=short
3613   ;;
3614 $ac_cv_sizeof_int)
3615   gint32=int
3616   ;;
3617 $ac_cv_sizeof_long)
3618   gint32=long
3619   ;;
3620 esac
3621 case 8 in
3622 $ac_cv_sizeof_int)
3623   gint64=int
3624   ;;
3625 $ac_cv_sizeof_long)
3626   gint64=long
3627   ;;
3628 $ac_cv_sizeof_long_long)
3629   gint64='long long'
3630   ;;
3631 $ac_cv_sizeof___int64)
3632   gint64='__int64'
3633   ;;
3634 esac
3635
3636 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3637 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3638 typedef unsigned $gint32 guint32;])
3639 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3640 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3641 typedef unsigned $gint64 guint64;])
3642 AC_CHECK_TYPE([unsigned long])
3643 AC_CHECK_ALIGNOF([unsigned long])
3644
3645 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3646 #
3647 # 1.2.14 required for dbus_message_set_serial
3648 PKG_CHECK_MODULES(DBUS1,
3649      dbus-1 >= 1.2.14,
3650      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3651      have_dbus1=no)
3652 AC_SUBST(DBUS1_CFLAGS)
3653 AC_SUBST(DBUS1_LIBS)
3654 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3655
3656 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3657 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3658
3659 dnl
3660 dnl Check for -Bsymbolic-functions linker flag used to avoid
3661 dnl intra-library PLT jumps, if available.
3662 dnl
3663
3664 AC_ARG_ENABLE(Bsymbolic,
3665               [AS_HELP_STRING([--disable-Bsymbolic],
3666                               [avoid linking with -Bsymbolic])],,
3667               [SAVED_LDFLAGS="${LDFLAGS}"
3668                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3669                LDFLAGS=-Wl,-Bsymbolic-functions
3670                AC_TRY_LINK([], [int main (void) { return 0; }],
3671                            AC_MSG_RESULT(yes)
3672                            enable_Bsymbolic=yes,
3673                            AC_MSG_RESULT(no)
3674                            enable_Bsymbolic=no)
3675                LDFLAGS="${SAVED_LDFLAGS}"])
3676
3677 if test "x${enable_Bsymbolic}" = "xyes"; then
3678   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3679 fi
3680
3681 AC_SUBST(GLIB_LINK_FLAGS)
3682
3683 dnl
3684 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3685 dnl visibility attributes for symbol export control
3686 dnl
3687 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3688 case "$host" in
3689   *-*-mingw*)
3690     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3691     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3692               [defines how to decorate public symbols while building])
3693     CFLAGS="${CFLAGS} -fvisibility=hidden"
3694     ;;
3695   *)
3696     dnl on other compilers, check if we can do -fvisibility=hidden
3697     SAVED_CFLAGS="${CFLAGS}"
3698     CFLAGS="-fvisibility=hidden"
3699     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3700     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3701                    AC_MSG_RESULT(yes)
3702                    enable_fvisibility_hidden=yes,
3703                    AC_MSG_RESULT(no)
3704                    enable_fvisibility_hidden=no)
3705     CFLAGS="${SAVED_CFLAGS}"
3706
3707     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3708       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3709                 [defines how to decorate public symbols while building])
3710       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3711     ])
3712     ;;
3713 esac
3714 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3715
3716 dnl Compiler flags; macro originates from systemd
3717 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3718 AC_ARG_ENABLE(compile-warnings,
3719               [AS_HELP_STRING([--disable-compile-warnings],
3720                               [Don't use builtin compiler warnings])],,
3721                               enable_compile_warnings=yes)
3722 AS_IF([test "x$enable_compile_warnings" = xyes], [
3723   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3724    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3725    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3726    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3727    -Werror=format=2 -Werror=missing-include-dirs])
3728 ])
3729 AC_SUBST(GLIB_WARN_CFLAGS)
3730
3731 #
3732 # Define variables corresponding to the correct include paths to use for
3733 # in-tree building.
3734 #
3735
3736 # for config.h:
3737 config_h_INCLUDES='-I$(top_builddir)'
3738 AC_SUBST(config_h_INCLUDES)
3739
3740 # glib:
3741 #   config.h
3742 #   $(top_builddir)/glib: for glibconfig.h
3743 #   $(top_srcdir)/glib:   for glib.h
3744 #   $(top_srcdir):        for everything
3745 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3746 AC_SUBST(glib_INCLUDES)
3747
3748 # gobject:
3749 #   same as glib
3750 gobject_INCLUDES='$(glib_INCLUDES)'
3751 AC_SUBST(gobject_INCLUDES)
3752
3753 # gmodule:
3754 #   glib includes
3755 #   $(top_srcdir)/gmodule: for gmodule.h
3756 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3757 AC_SUBST(gmodule_INCLUDES)
3758
3759 # gio:
3760 #   same as gmodule
3761 gio_INCLUDES='$(gmodule_INCLUDES)'
3762 AC_SUBST(gio_INCLUDES)
3763
3764
3765 AC_CONFIG_FILES([
3766 glib-2.0.pc
3767 gmodule-2.0.pc
3768 gmodule-export-2.0.pc
3769 gmodule-no-export-2.0.pc
3770 gthread-2.0.pc
3771 gobject-2.0.pc
3772 gio-2.0.pc
3773 gio-unix-2.0.pc
3774 gio-windows-2.0.pc
3775 glib-zip
3776 glib-gettextize
3777 Makefile
3778 build/Makefile
3779 build/win32/Makefile
3780 build/win32/dirent/Makefile
3781 build/win32/vs9/Makefile
3782 build/win32/vs10/Makefile
3783 build/win32/vs11/Makefile
3784 glib/Makefile
3785 glib/glib.stp
3786 glib/libcharset/Makefile
3787 glib/gnulib/Makefile
3788 glib/pcre/Makefile
3789 glib/update-pcre/Makefile
3790 glib/tests/Makefile
3791 gmodule/Makefile
3792 gmodule/gmoduleconf.h
3793 gobject/Makefile
3794 gobject/gobject.stp
3795 gobject/glib-mkenums
3796 gobject/tests/Makefile
3797 gthread/Makefile
3798 gio/Makefile
3799 gio/gdbus-2.0/codegen/Makefile
3800 gio/gdbus-2.0/codegen/config.py
3801 gio/gnetworking.h
3802 gio/xdgmime/Makefile
3803 gio/inotify/Makefile
3804 gio/kqueue/Makefile
3805 gio/fen/Makefile
3806 gio/fam/Makefile
3807 gio/win32/Makefile
3808 gio/tests/Makefile
3809 gio/tests/gdbus-object-manager-example/Makefile
3810 gio/tests/services/Makefile
3811 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3812 po/Makefile.in
3813 docs/Makefile
3814 docs/reference/Makefile
3815 docs/reference/glib/Makefile
3816 docs/reference/glib/version.xml
3817 docs/reference/gobject/Makefile
3818 docs/reference/gobject/version.xml
3819 docs/reference/gio/Makefile
3820 docs/reference/gio/gdbus-object-manager-example/Makefile
3821 docs/reference/gio/version.xml
3822 tests/Makefile
3823 tests/gobject/Makefile
3824 tests/refcount/Makefile
3825 m4macros/Makefile
3826 ])
3827
3828 AC_CONFIG_COMMANDS([chmod-scripts],
3829 [chmod 0755 glib-zip
3830 chmod 0755 glib-gettextize
3831 chmod 0755 gobject/glib-mkenums])
3832
3833 # we want to invoke this macro solely so that the config.status script
3834 # and automake generated makefiles know about these generated files.
3835 # They are only needed to distcheck the package
3836 if false; then
3837   AC_CONFIG_FILES([
3838     INSTALL
3839     README
3840     config.h.win32
3841     glib/glibconfig.h.win32
3842     glib/makefile.msc
3843     glib/glib.rc
3844     gmodule/makefile.msc
3845     gmodule/gmodule.rc
3846     gobject/makefile.msc
3847     gobject/gobject.rc
3848     gthread/makefile.msc
3849     gthread/gthread.rc
3850     gio/gio.rc
3851     tests/makefile.msc
3852   ])
3853 fi
3854
3855 AC_OUTPUT