configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # Copyright 2004-2006 Lennart Poettering
   9 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
  10 #
  11 # PulseAudio is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU Lesser General Public License as published by
  13 # the Free Software Foundation; either version 2 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # PulseAudio is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  19 # General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public License
  22 # along with PulseAudio; if not, write to the Free Software Foundation,
  23 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  24
  25 AC_PREREQ(2.57)
  26
  27 m4_define(PA_MAJOR, [0])
  28 m4_define(PA_MINOR, [9])
  29 m4_define(PA_MICRO, [7])
  30
  31 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  32 AC_CONFIG_SRCDIR([src/daemon/main.c])
  33 AC_CONFIG_HEADERS([config.h])
  34 AM_INIT_AUTOMAKE([foreign -Wall])
  35
  36 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  37 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  38
  39 AC_SUBST(PA_API_VERSION, 10)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 11)
  41
  42 AC_SUBST(LIBPULSE_VERSION_INFO, [3:0:3])
  43 AC_SUBST(LIBPULSECORE_VERSION_INFO, [4:0:0])
  44 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  45 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  46 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:2:0])
  47
  48 AC_CANONICAL_HOST
  49
  50 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  51    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  52    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  53 fi
  54
  55 #### Platform hacks ####
  56
  57 case $host in
  58    *-*-solaris* )
  59       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  60       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  61       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  62       ;;
  63 esac
  64
  65 #### Checks for programs. ####
  66
  67 # CC
  68
  69 AC_PROG_CC
  70 AM_PROG_CC_C_O
  71 AC_PROG_GCC_TRADITIONAL
  72 AC_GNU_SOURCE
  73
  74 # M4
  75
  76 AC_PATH_PROG([M4], [m4 gm4], [no])
  77 if test "x$M4" = xno ; then
  78    AC_MSG_ERROR([m4 missing])
  79 fi
  80
  81 # GCC flags
  82
  83 test_gcc_flag() {
  84     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
  85     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
  86     ret=$?
  87     rm -f conftest.o
  88     return $ret
  89 }
  90
  91 # If using GCC specify some additional parameters
  92 if test "x$GCC" = "xyes" ; then
  93
  94     # We use gnu99 instead of c99 because many have interpreted the standard
  95     # in a way that int64_t isn't defined on non-64 bit platforms.
  96     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
  97
  98     for flag in $DESIRED_FLAGS ; do
  99         AC_MSG_CHECKING([whether $CC accepts $flag])
 100         if test_gcc_flag $flag ; then
 101            CFLAGS="$CFLAGS $flag"
 102            AC_MSG_RESULT([yes])
 103         else
 104            AC_MSG_RESULT([no])
 105         fi
 106     done
 107 fi
 108
 109 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 110 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 111 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 112 ret=$?
 113 rm -f conftest.o conftest
 114 if test $ret -eq 0 ; then
 115     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 116     AC_MSG_RESULT([yes])
 117 else
 118     AC_MSG_RESULT([no])
 119 fi
 120
 121 #### libtool stuff ####
 122
 123 AC_LTDL_ENABLE_INSTALL
 124 AC_LIBLTDL_INSTALLABLE
 125 AC_LIBTOOL_DLOPEN
 126 AC_LIBTOOL_WIN32_DLL
 127 AC_PROG_LIBTOOL
 128 AC_SUBST(LTDLINCL)
 129 AC_SUBST(LIBLTDL)
 130 AC_CONFIG_SUBDIRS(libltdl)
 131
 132 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 133     AC_MSG_ERROR([[
 134
 135         *** Cannot find the libltdl development files.
 136         *** Maybe you need to install the libltdl-dev package.
 137         ]])
 138 fi
 139
 140 #### Determine build environment ####
 141
 142 os_is_win32=0
 143
 144 case "$host_os" in
 145         mingw*)
 146         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 147         os_is_win32=1
 148                 ;;
 149         esac
 150
 151 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 152
 153 ###################################
 154 #   Basic environment checks      #
 155 ###################################
 156
 157 #### Checks for header files. ####
 158
 159 # ISO
 160 AC_HEADER_STDC
 161
 162 # POSIX
 163 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 164     netinet/in_systm.h netinet/tcp.h pwd.h sched.h \
 165     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 166     syslog.h])
 167 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 168                  [#include <sys/types.h>
 169                   #if HAVE_NETINET_IN_H
 170                   # include <netinet/in.h>
 171                   #endif
 172                   #if HAVE_NETINET_IN_SYSTM_H
 173                   # include <netinet/in_systm.h>
 174                   #endif
 175                  ])
 176 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 177 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 178
 179 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 180 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 181
 182 # XPG4-UNIX
 183 AC_CHECK_HEADERS([sys/poll.h])
 184
 185 # Linux
 186 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 187
 188 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 189
 190 AC_CHECK_HEADERS([sys/prctl.h])
 191
 192 # Solaris
 193 AC_CHECK_HEADERS([sys/filio.h])
 194
 195 # Windows
 196 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 197
 198 # Other
 199 AC_CHECK_HEADERS([sys/ioctl.h])
 200
 201 #### Typdefs, structures, etc. ####
 202
 203 AC_C_CONST
 204 AC_C_BIGENDIAN
 205 AC_TYPE_PID_T
 206 AC_TYPE_SIZE_T
 207 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 208     [Define ssize_t if it is not done by the standard libs.])])
 209 AC_TYPE_OFF_T
 210 AC_TYPE_SIGNAL
 211 AC_TYPE_UID_T
 212
 213 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 214 HAVE_SIGXCPU=1
 215 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 216 ], [HAVE_SIGXCPU=0])
 217 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 218
 219 # Solaris lacks this
 220 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 221     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 222         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 223
 224 #### Check for libs ####
 225
 226 # ISO
 227 AC_SEARCH_LIBS([pow], [m])
 228
 229 # POSIX
 230 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 231 AC_SEARCH_LIBS([dlopen], [dl])
 232 AC_SEARCH_LIBS([shm_open], [rt])
 233
 234 # BSD
 235 AC_SEARCH_LIBS([connect], [socket])
 236
 237 # Non-standard
 238
 239 # This magic is needed so we do not needlessly add static libs to the win32
 240 # build, disabling its ability to make dlls.
 241 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 242
 243 #### Check for functions ####
 244
 245 # POSIX
 246 AC_FUNC_FORK
 247 AC_FUNC_GETGROUPS
 248 AC_FUNC_SELECT_ARGTYPES
 249 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 250     getuid inet_ntop inet_pton nanosleep pipe posix_fadvise posix_madvise \
 251     posix_memalign setpgid setsid shm_open sigaction sleep sysconf])
 252 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 253
 254 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 255
 256 # X/OPEN
 257 AC_CHECK_FUNCS([readlink])
 258
 259 # SUSv2
 260 AC_CHECK_FUNCS([ctime_r usleep])
 261
 262 # SUSv3
 263 AC_CHECK_FUNCS([strerror_r])
 264
 265 # BSD
 266 AC_CHECK_FUNCS([lstat])
 267
 268 # Non-standard
 269
 270 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll])
 271
 272 #### POSIX threads ####
 273
 274 ACX_PTHREAD
 275
 276 #### Large File-Support (LFS) ####
 277
 278 AC_SYS_LARGEFILE
 279
 280 # Check for open64 to know if the current system does have open64() and similar functions
 281 AC_CHECK_FUNCS([open64])
 282
 283 #### [lib]iconv ####
 284
 285 AM_ICONV
 286
 287 ###################################
 288 #      External libraries         #
 289 ###################################
 290
 291 #### X11 (optional) ####
 292
 293 HAVE_X11=0
 294
 295 # The macro tests the host, not the build target
 296 if test "x$os_is_win32" != "x1" ; then
 297     AC_PATH_XTRA
 298     test "x$no_x" != "xyes" && HAVE_X11=1
 299 fi
 300
 301 AC_SUBST(HAVE_X11)
 302 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 303 if test "x$HAVE_X11" = "x1" ; then
 304     AC_DEFINE([HAVE_X11], 1, [Have X11])
 305 fi
 306
 307 #### Capabilities (optional) ####
 308
 309 CAP_LIBS=''
 310
 311 AC_ARG_WITH(
 312         [caps],
 313         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 314
 315 if test "x${with_caps}" != "xno"; then
 316     AC_SEARCH_LIBS([cap_init], [cap], [], [
 317                     if test "x${with_caps}" = "xyes" ; then
 318                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 319                     fi])
 320     AC_CHECK_HEADERS([sys/capability.h], [], [
 321                     if test "x${with_caps}" = "xyes" ; then
 322                         AC_MSG_ERROR([*** POSIX caps headers not found])
 323                     fi])
 324 fi
 325
 326 #### pkg-config ####
 327
 328 # Check for pkg-config manually first, as if its not installed the
 329 # PKG_PROG_PKG_CONFIG macro won't be defined.
 330 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 331
 332 if test x"$have_pkg_config" = "xno"; then
 333     AC_MSG_ERROR(pkg-config is required to install this program)
 334 fi
 335
 336 PKG_PROG_PKG_CONFIG
 337
 338 #### Sound file ####
 339
 340 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 341 AC_SUBST(LIBSNDFILE_CFLAGS)
 342 AC_SUBST(LIBSNDFILE_LIBS)
 343
 344 #### atomic-ops ###
 345
 346 AC_CHECK_HEADERS([atomic_ops.h], [], [
 347 AC_MSG_ERROR([*** libatomic-ops headers not found])
 348 ])
 349
 350 # Win32 does not need the lib and breaks horribly if we try to include it
 351 if test "x$os_is_win32" != "x1" ; then
 352     LIBS="$LIBS -latomic_ops"
 353 fi
 354
 355 #### Libsamplerate support (optional) ####
 356
 357 AC_ARG_ENABLE([samplerate],
 358     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 359         [
 360             case "${enableval}" in
 361                 yes) samplerate=yes ;;
 362                 no) samplerate=no ;;
 363                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 364             esac
 365         ],
 366         [samplerate=auto])
 367
 368 if test "x${samplerate}" != xno ; then
 369     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 370         HAVE_LIBSAMPLERATE=1,
 371         [
 372             HAVE_LIBSAMPLERATE=0
 373             if test "x$samplerate" = xyes ; then
 374                 AC_MSG_ERROR([*** Libsamplerate not found])
 375             fi
 376         ])
 377 else
 378     HAVE_LIBSAMPLERATE=0
 379 fi
 380
 381 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 382    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 383 fi
 384
 385 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 386 AC_SUBST(LIBSAMPLERATE_LIBS)
 387 AC_SUBST(HAVE_LIBSAMPLERATE)
 388 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 389
 390 #### OSS support (optional) ####
 391
 392 AC_ARG_ENABLE([oss],
 393     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 394         [
 395             case "${enableval}" in
 396                 yes) oss=yes ;;
 397                 no) oss=no ;;
 398                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 399             esac
 400         ],
 401         [oss=auto])
 402
 403 if test "x${oss}" != xno ; then
 404     AC_CHECK_HEADERS([sys/soundcard.h],
 405         [
 406             HAVE_OSS=1
 407             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 408         ],
 409         [
 410             HAVE_OSS=0
 411             if test "x$oss" = xyes ; then
 412                 AC_MSG_ERROR([*** OSS support not found])
 413             fi
 414         ])
 415 else
 416     HAVE_OSS=0
 417 fi
 418
 419 AC_SUBST(HAVE_OSS)
 420 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 421
 422
 423 #### ALSA support (optional) ####
 424
 425 AC_ARG_ENABLE([alsa],
 426     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 427         [
 428             case "${enableval}" in
 429                 yes) alsa=yes ;;
 430                 no) alsa=no ;;
 431                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 432             esac
 433         ],
 434         [alsa=auto])
 435
 436 if test "x${alsa}" != xno ; then
 437     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 438         [
 439             HAVE_ALSA=1
 440             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 441         ],
 442         [
 443             HAVE_ALSA=0
 444             if test "x$alsa" = xyes ; then
 445                 AC_MSG_ERROR([*** ALSA support not found])
 446             fi
 447         ])
 448 else
 449     HAVE_ALSA=0
 450 fi
 451
 452 AC_SUBST(ASOUNDLIB_CFLAGS)
 453 AC_SUBST(ASOUNDLIB_LIBS)
 454 AC_SUBST(HAVE_ALSA)
 455 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 456
 457 #### Solaris audio support (optional) ####
 458
 459 AC_ARG_ENABLE([solaris],
 460     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 461         [
 462             case "${enableval}" in
 463                 yes) solaris=yes ;;
 464                 no) solaris=no ;;
 465                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 466             esac
 467         ],
 468         [solaris=auto])
 469
 470 if test "x${solaris}" != xno ; then
 471     AC_CHECK_HEADERS([sys/audio.h],
 472         [
 473             HAVE_SOLARIS=1
 474             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 475         ],
 476         [
 477             HAVE_SOLARIS=0
 478             if test "x$solaris" = xyes ; then
 479                 AC_MSG_ERROR([*** Solaris audio support not found])
 480             fi
 481         ])
 482 else
 483     HAVE_SOLARIS=0
 484 fi
 485
 486 AC_SUBST(HAVE_SOLARIS)
 487 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 488
 489 #### GLib 2 support (optional) ####
 490
 491 AC_ARG_ENABLE([glib2],
 492     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 493         [
 494             case "${enableval}" in
 495                 yes) glib2=yes ;;
 496                 no) glib2=no ;;
 497                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 498             esac
 499         ],
 500         [glib2=auto])
 501
 502 if test "x${glib2}" != xno ; then
 503     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 504         HAVE_GLIB20=1,
 505         [
 506             HAVE_GLIB20=0
 507             if test "x$glib2" = xyes ; then
 508                 AC_MSG_ERROR([*** GLib 2 support not found])
 509             fi
 510         ])
 511 else
 512     HAVE_GLIB20=0
 513 fi
 514
 515 AC_SUBST(GLIB20_CFLAGS)
 516 AC_SUBST(GLIB20_LIBS)
 517 AC_SUBST(HAVE_GLIB20)
 518 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 519
 520 #### GConf support (optional) ####
 521
 522 AC_ARG_ENABLE([gconf],
 523     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 524         [
 525             case "${enableval}" in
 526                 yes) gconf=yes ;;
 527                 no) gconf=no ;;
 528                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 529             esac
 530         ],
 531         [glib=auto])
 532
 533 if test "x${gconf}" != xno ; then
 534     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 535         HAVE_GCONF=1,
 536         [
 537             HAVE_GCONF=0
 538             if test "x$gconf" = xyes ; then
 539                 AC_MSG_ERROR([*** GConf support not found])
 540             fi
 541         ])
 542 else
 543     HAVE_GCONF=0
 544 fi
 545
 546 AC_SUBST(GCONF_CFLAGS)
 547 AC_SUBST(GCONF_LIBS)
 548 AC_SUBST(HAVE_GCONF)
 549 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 550
 551 #### Avahi support (optional) ####
 552
 553 AC_ARG_ENABLE([avahi],
 554     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 555         [
 556             case "${enableval}" in
 557                 yes) avahi=yes ;;
 558                 no) avahi=no ;;
 559                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 560             esac
 561         ],
 562         [avahi=auto])
 563
 564 if test "x${avahi}" != xno ; then
 565     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 566         HAVE_AVAHI=1,
 567         [
 568                 HAVE_AVAHI=0
 569                 if test "x$avahi" = xyes ; then
 570                         AC_MSG_ERROR([*** Avahi support not found])
 571                 fi
 572         ])
 573 else
 574     HAVE_AVAHI=0
 575 fi
 576
 577 AC_SUBST(AVAHI_CFLAGS)
 578 AC_SUBST(AVAHI_LIBS)
 579 AC_SUBST(HAVE_AVAHI)
 580 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 581
 582 ### LIBOIL ####
 583
 584 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 585 AC_SUBST(LIBOIL_CFLAGS)
 586 AC_SUBST(LIBOIL_LIBS)
 587
 588 ### JACK (optional) ####
 589
 590 AC_ARG_ENABLE([jack],
 591     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 592         [
 593             case "${enableval}" in
 594                 yes) jack=yes ;;
 595                 no) jack=no ;;
 596                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 597             esac
 598         ],
 599         [jack=auto])
 600
 601 if test "x${jack}" != xno ; then
 602     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 603         HAVE_JACK=1,
 604         [
 605             HAVE_JACK=0
 606             if test "x$jack" = xyes ; then
 607                 AC_MSG_ERROR([*** JACK support not found])
 608             fi
 609         ])
 610 else
 611     HAVE_JACK=0
 612 fi
 613
 614 AC_SUBST(JACK_CFLAGS)
 615 AC_SUBST(JACK_LIBS)
 616 AC_SUBST(HAVE_JACK)
 617 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 618
 619 #### Async DNS support (optional) ####
 620
 621 AC_ARG_ENABLE([asyncns],
 622     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 623         [
 624             case "${enableval}" in
 625                 yes) asyncns=yes ;;
 626                 no) asyncns=no ;;
 627                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 628             esac
 629         ],
 630         [asyncns=auto])
 631
 632 if test "x${asyncns}" != xno ; then
 633     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 634         HAVE_LIBASYNCNS=1,
 635         [
 636             HAVE_LIBASYNCNS=0
 637             if test "x$asyncns" = xyes ; then
 638                 AC_MSG_ERROR([*** Async DNS support not found])
 639             fi
 640         ])
 641 else
 642     HAVE_LIBASYNCNS=0
 643 fi
 644
 645 AC_SUBST(LIBASYNCNS_CFLAGS)
 646 AC_SUBST(LIBASYNCNS_LIBS)
 647 AC_SUBST(HAVE_LIBASYNCNS)
 648 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 649
 650 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 651    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 652 fi
 653
 654 #### TCP wrappers (optional) ####
 655
 656 AC_ARG_ENABLE([tcpwrap],
 657     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 658         [
 659             case "${enableval}" in
 660                 yes) tcpwrap=yes ;;
 661                 no) tcpwrap=no ;;
 662                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 663             esac
 664         ],
 665         [tcpwrap=auto])
 666
 667 if test "x${tcpwrap}" != xno ; then
 668     ACX_LIBWRAP
 669     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 670         AC_MSG_ERROR([*** TCP wrappers support not found])
 671     fi
 672 else
 673     LIBWRAP_LIBS=
 674 fi
 675
 676 AC_SUBST(LIBWRAP_LIBS)
 677
 678 #### LIRC support (optional) ####
 679
 680 AC_ARG_ENABLE([lirc],
 681     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 682         [
 683             case "${enableval}" in
 684                 yes) lirc=yes ;;
 685                 no) lirc=no ;;
 686                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 687             esac
 688         ],
 689         [lirc=auto])
 690
 691 if test "x${lirc}" != xno ; then
 692     ACX_LIRC
 693     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 694         AC_MSG_ERROR([*** LIRC support not found])
 695     fi
 696 else
 697     HAVE_LIRC=0
 698 fi
 699
 700 AC_SUBST(LIRC_CFLAGS)
 701 AC_SUBST(LIRC_LIBS)
 702 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 703
 704 #### HAL support (optional) ####
 705
 706 AC_ARG_ENABLE([hal],
 707     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 708         [
 709             case "${enableval}" in
 710                 yes) hal=yes ;;
 711                 no) hal=no ;;
 712                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 713             esac
 714         ],
 715         [hal=auto])
 716 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 717     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 718         HAVE_HAL=1,
 719         [
 720             HAVE_HAL=0
 721             if test "x$hal" = xyes ; then
 722                 AC_MSG_ERROR([*** HAL support not found])
 723             fi
 724         ])
 725 else
 726     HAVE_HAL=0
 727 fi
 728
 729 AC_SUBST(HAL_CFLAGS)
 730 AC_SUBST(HAL_LIBS)
 731 AC_SUBST(HAVE_HAL)
 732 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 733
 734 #### D-Bus support (optional) ####
 735
 736 AC_ARG_ENABLE([dbus],
 737     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 738         [
 739             case "${enableval}" in
 740                 yes) dbus=yes ;;
 741                 no) dbus=no ;;
 742                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 743             esac
 744         ],
 745         [dbus=auto])
 746
 747 if test "x$HAVE_HAL" = x1 ; then
 748    dbus=yes
 749 fi
 750
 751 if test "x${dbus}" != xno ; then
 752
 753     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 754         [
 755             HAVE_DBUS=1
 756             saved_LIBS="$LIBS"
 757             LIBS="$LIBS $DBUS_LIBS"
 758             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 759             LIBS="$saved_LIBS"
 760
 761         ],
 762         [
 763             HAVE_DBUS=0
 764             if test "x$dbus" = xyes ; then
 765                 AC_MSG_ERROR([*** D-Bus support not found])
 766             fi
 767         ])
 768 else
 769     HAVE_DBUS=0
 770 fi
 771
 772 AC_SUBST(DBUS_CFLAGS)
 773 AC_SUBST(DBUS_LIBS)
 774 AC_SUBST(HAVE_DBUS)
 775 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 776
 777 #### PulseAudio system group & user  #####
 778
 779 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 780 if test -z "$with_system_user" ; then
 781     PA_SYSTEM_USER=pulse
 782 else
 783     PA_SYSTEM_USER=$with_system_user
 784 fi
 785 AC_SUBST(PA_SYSTEM_USER)
 786 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 787
 788 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 789 if test -z "$with_system_group" ; then
 790     PA_SYSTEM_GROUP=pulse
 791 else
 792     PA_SYSTEM_GROUP=$with_system_group
 793 fi
 794 AC_SUBST(PA_SYSTEM_GROUP)
 795 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 796
 797 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 798 if test -z "$with_realtime_group" ; then
 799     PA_REALTIME_GROUP=pulse-rt
 800 else
 801     PA_REALTIME_GROUP=$with_realtime_group
 802 fi
 803 AC_SUBST(PA_REALTIME_GROUP)
 804 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 805
 806 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 807 if test -z "$with_access_group" ; then
 808     PA_ACCESS_GROUP=pulse-access
 809 else
 810     PA_ACCESS_GROUP=$with_access_group
 811 fi
 812 AC_SUBST(PA_ACCESS_GROUP)
 813 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 814
 815 #### PulseAudio system runtime dir ####
 816 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 817 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 818
 819 ###################################
 820 #            Output               #
 821 ###################################
 822
 823 AC_ARG_ENABLE(
 824         [static-bins],
 825         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 826         [STATIC_BINS=1], [STATIC_BINS=0])
 827 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 828
 829 AC_ARG_WITH(
 830         [preopen-mods],
 831         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 832         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 833 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 834 if test "x$PREOPEN_MODS" != "xall" ; then
 835     tmpLIBS=""
 836     for mod in $PREOPEN_MODS; do
 837         tmpLIBS="$tmpLIBS module-$mod.la"
 838     done
 839     PREOPEN_MODS="$tmpLIBS"
 840     AC_SUBST(PREOPEN_MODS)
 841 fi
 842
 843 AC_ARG_WITH(
 844         [module-dir],
 845         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 846         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 847
 848 AC_SUBST(modlibexecdir)
 849
 850 AC_ARG_ENABLE(
 851         [force-preopen],
 852         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 853         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 854 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 855
 856 AC_CONFIG_FILES([
 857 Makefile
 858 src/Makefile
 859 libpulse.pc
 860 libpulse-simple.pc
 861 libpulse-browse.pc
 862 libpulse-mainloop-glib.pc
 863 doxygen/Makefile
 864 doxygen/doxygen.conf
 865 src/pulse/version.h
 866 ])
 867 AC_OUTPUT
 868
 869 # ==========================================================================
 870 ENABLE_X11=no
 871 if test "x$HAVE_X11" = "x1" ; then
 872    ENABLE_X11=yes
 873 fi
 874
 875 ENABLE_OSS=no
 876 if test "x$HAVE_OSS" = "x1" ; then
 877    ENABLE_OSS=yes
 878 fi
 879
 880 ENABLE_ALSA=no
 881 if test "x$HAVE_ALSA" = "x1" ; then
 882    ENABLE_ALSA=yes
 883 fi
 884
 885 ENABLE_SOLARIS=no
 886 if test "x$HAVE_SOLARIS" = "x1" ; then
 887    ENABLE_SOLARIS=yes
 888 fi
 889
 890 ENABLE_GLIB20=no
 891 if test "x$HAVE_GLIB20" = "x1" ; then
 892    ENABLE_GLIB20=yes
 893 fi
 894
 895 ENABLE_GCONF=no
 896 if test "x$HAVE_GCONF" = "x1" ; then
 897    ENABLE_GCONF=yes
 898 fi
 899
 900 ENABLE_AVAHI=no
 901 if test "x$HAVE_AVAHI" = "x1" ; then
 902    ENABLE_AVAHI=yes
 903 fi
 904
 905 ENABLE_JACK=no
 906 if test "x$HAVE_JACK" = "x1" ; then
 907    ENABLE_JACK=yes
 908 fi
 909
 910 ENABLE_LIBASYNCNS=no
 911 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 912    ENABLE_LIBASYNCNS=yes
 913 fi
 914
 915 ENABLE_LIRC=no
 916 if test "x$HAVE_LIRC" = "x1" ; then
 917    ENABLE_LIRC=yes
 918 fi
 919
 920 ENABLE_HAL=no
 921 if test "x$HAVE_HAL" = "x1" ; then
 922    ENABLE_HAL=yes
 923 fi
 924
 925 ENABLE_TCPWRAP=no
 926 if test "x${LIBWRAP_LIBS}" != x ; then
 927    ENABLE_TCPWRAP=yes
 928 fi
 929
 930 ENABLE_LIBSAMPLERATE=no
 931 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
 932    ENABLE_LIBSAMPLERATE=yes
 933 fi
 934
 935 echo "
 936  ---{ $PACKAGE_NAME $VERSION }---
 937
 938     prefix:                 ${prefix}
 939     sysconfdir:             ${sysconfdir}
 940     localstatedir:          ${localstatedir}
 941     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 942     Compiler:               ${CC}
 943     CFLAGS:                 ${CFLAGS}
 944     Have X11:               ${ENABLE_X11}
 945     Enable OSS:             ${ENABLE_OSS}
 946     Enable Alsa:            ${ENABLE_ALSA}
 947     Enable Solaris:         ${ENABLE_SOLARIS}
 948     Enable GLib 2.0:        ${ENABLE_GLIB20}
 949     Enable GConf:           ${ENABLE_GCONF}
 950     Enable Avahi:           ${ENABLE_AVAHI}
 951     Enable Jack:            ${ENABLE_JACK}
 952     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 953     Enable LIRC:            ${ENABLE_LIRC}
 954     Enable HAL:             ${ENABLE_HAL}
 955     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 956     Enable libsamplerate:   ${ENABLE_LIBSAMPLERATE}
 957     System User:            ${PA_SYSTEM_USER}
 958     System Group:           ${PA_SYSTEM_GROUP}
 959     Realtime Group:         ${PA_REALTIME_GROUP}
 960     Access Group:           ${PA_ACCESS_GROUP}
 961 "