configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.21.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.28.1
  56 GSTPB_REQ=0.10.28.1
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106
 107 dnl determine c++ compiler
 108 AC_PROG_CXX
 109 dnl determine if c++ is available on this system
 110 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 111
 112 dnl determine c++ preprocessor
 113 dnl FIXME: do we need this ?
 114 AC_PROG_CXXCPP
 115
 116 AS_PROG_OBJC
 117
 118 dnl check if the compiler supports '-c' and '-o' options
 119 AM_PROG_CC_C_O
 120
 121 dnl find an assembler
 122 AM_PROG_AS
 123
 124 dnl check if the compiler supports do while(0) macros
 125 AG_GST_CHECK_DOWHILE_MACROS
 126
 127 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 128 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 129
 130 dnl check for gconftool-2
 131 dnl this macro defines an am conditional, so it needs to be run always
 132 AM_GCONF_SOURCE_2
 133
 134 dnl check for documentation tools
 135 GTK_DOC_CHECK([1.3])
 136 AS_PATH_PYTHON([2.1])
 137 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 138
 139 dnl *** checks for libraries ***
 140
 141 dnl check for libm, for sin()
 142 AC_CHECK_LIBM
 143 AC_SUBST(LIBM)
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/rtp/gstasteriskh263.c
 154 AC_CHECK_HEADERS([netinet/in.h])
 155 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 156 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 157
 158 dnl used in gst/udp
 159 AC_CHECK_HEADERS([sys/time.h])
 160
 161 dnl *** checks for types/defines ***
 162
 163 dnl Check for FIONREAD ioctl declaration.  This check is needed
 164 dnl for the UDP plugin to build on Solaris
 165 GST_CHECK_FIONREAD
 166
 167 dnl *** checks for structures ***
 168
 169 dnl *** checks for compiler characteristics ***
 170
 171 dnl check if we have GCC inline-asm
 172 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 173 if test x$HAVE_GCC_ASM = xyes ; then
 174   AC_DEFINE(HAVE_GCC_ASM, 1,
 175     [Define if compiler supports gcc inline assembly])
 176 fi
 177 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 178
 179 dnl *** checks for library functions ***
 180
 181 LIBS_SAVE=$LIBS
 182 LIBS="$LIBS $LIBM"
 183 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 184 LIBS=$LIBS_SAVE
 185
 186 dnl Check whether isinf() is defined by math.h
 187 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 189 if test "$ac_cv_have_isinf" = "yes"
 190 then
 191     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 192 fi
 193
 194 dnl Check for mmap (needed by electricfence plugin)
 195 AC_FUNC_MMAP
 196 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" == "xyes")
 197
 198 dnl Check for mmap (needed by electricfence plugin)
 199
 200 AC_CHECK_TYPE([struct ip_mreqn], [
 201               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 202               [#include <netinet/in.h>])
 203
 204 dnl *** checks for dependency libraries ***
 205
 206 dnl GLib is required
 207 AG_GST_GLIB_CHECK([2.18])
 208
 209 dnl liboil is required
 210 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 211 if test "x$HAVE_LIBOIL" != "xyes"; then
 212   AC_ERROR([liboil-0.3.8 or later is required])
 213 fi
 214
 215 dnl checks for gstreamer
 216 dnl uninstalled is selected preferentially -- see pkg-config(1)
 217 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 221 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 222 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 223
 224 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 225 if test -z $GST_TOOLS_DIR; then
 226   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 227 fi
 228 AC_SUBST(GST_TOOLS_DIR)
 229
 230 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 231 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 232
 233 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 234
 235 dnl Check for documentation xrefs
 236 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 237 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 238 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 239 AC_SUBST(GLIB_PREFIX)
 240 AC_SUBST(GST_PREFIX)
 241 AC_SUBST(GSTPB_PREFIX)
 242
 243 dnl GTK is optional and used in examples
 244 if test "x$BUILD_EXAMPLES" = "xyes"; then
 245   PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.8.0, HAVE_GTK=yes, HAVE_GTK=no)
 246   AC_SUBST(GTK_LIBS)
 247   AC_SUBST(GTK_CFLAGS)
 248 fi
 249 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 250
 251 dnl should we install schemas ?
 252 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 253 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 254   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 255   if test x$GCONFTOOL = xno; then
 256     AC_MSG_WARN(Not installing GConf schemas)
 257     HAVE_GCONFTOOL="no"
 258   else
 259     HAVE_GCONFTOOL="yes"
 260   fi
 261   AC_SUBST(HAVE_GCONFTOOL)
 262 ])
 263
 264 dnl *** set variables based on configure arguments ***
 265
 266 dnl set license and copyright notice
 267 GST_LICENSE="LGPL"
 268 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 269 AC_SUBST(GST_LICENSE)
 270
 271 dnl set location of plugin directory
 272 AG_GST_SET_PLUGINDIR
 273
 274 dnl define an ERROR_CFLAGS Makefile variable
 275 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [-Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef])
 276
 277 dnl define an ERROR_CXXFLAGS Makefile variable
 278 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [-Wmissing-declarations -Wredundant-decls -Wundef])
 279
 280 dnl define correct level for debugging messages
 281 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 282
 283 dnl used in examples
 284 AG_GST_DEFAULT_ELEMENTS
 285
 286 dnl *** plug-ins to include ***
 287
 288 dnl these are all the gst plug-ins, compilable without additional libs
 289 dnl videofilter is at the top because others depend on it
 290 AG_GST_CHECK_PLUGIN(videofilter)
 291 AG_GST_CHECK_PLUGIN(alpha)
 292 AG_GST_CHECK_PLUGIN(apetag)
 293 AG_GST_CHECK_PLUGIN(audiofx)
 294 AG_GST_CHECK_PLUGIN(auparse)
 295 AG_GST_CHECK_PLUGIN(autodetect)
 296 AG_GST_CHECK_PLUGIN(avi)
 297 AG_GST_CHECK_PLUGIN(cutter)
 298 AG_GST_CHECK_PLUGIN(debugutils)
 299 AG_GST_CHECK_PLUGIN(deinterlace)
 300 AG_GST_CHECK_PLUGIN(effectv)
 301 AG_GST_CHECK_PLUGIN(equalizer)
 302 AG_GST_CHECK_PLUGIN(flv)
 303 AG_GST_CHECK_PLUGIN(id3demux)
 304 AG_GST_CHECK_PLUGIN(icydemux)
 305 AG_GST_CHECK_PLUGIN(interleave)
 306 AG_GST_CHECK_PLUGIN(flx)
 307 AG_GST_CHECK_PLUGIN(goom)
 308 AG_GST_CHECK_PLUGIN(goom2k1)
 309 AG_GST_CHECK_PLUGIN(law)
 310 AG_GST_CHECK_PLUGIN(level)
 311 AG_GST_CHECK_PLUGIN(matroska)
 312 AG_GST_CHECK_PLUGIN(monoscope)
 313 AG_GST_CHECK_PLUGIN(multifile)
 314 AG_GST_CHECK_PLUGIN(multipart)
 315 AG_GST_CHECK_PLUGIN(qtdemux)
 316 AG_GST_CHECK_PLUGIN(replaygain)
 317 AG_GST_CHECK_PLUGIN(rtp)
 318 AG_GST_CHECK_PLUGIN(rtpmanager)
 319 AG_GST_CHECK_PLUGIN(rtsp)
 320 AG_GST_CHECK_PLUGIN(shapewipe)
 321 AG_GST_CHECK_PLUGIN(smpte)
 322 AG_GST_CHECK_PLUGIN(spectrum)
 323 AG_GST_CHECK_PLUGIN(udp)
 324 AG_GST_CHECK_PLUGIN(videobox)
 325 AG_GST_CHECK_PLUGIN(videocrop)
 326 AG_GST_CHECK_PLUGIN(videomixer)
 327 AG_GST_CHECK_PLUGIN(wavenc)
 328 AG_GST_CHECK_PLUGIN(wavparse)
 329 AG_GST_CHECK_PLUGIN(y4m)
 330
 331 dnl *** checks for socket and nsl libraries ***
 332 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 333
 334 dnl disable gst plugins we might not be able to build on this
 335 dnl platform: udp and rtsp (ugly but minimally invasive)
 336 dnl FIXME: maybe move to sys
 337 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 338 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 339
 340 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 341   AG_GST_DISABLE_PLUGIN(udp)
 342   AG_GST_DISABLE_PLUGIN(rtsp)
 343 fi
 344
 345 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 346   WIN32_LIBS="-lws2_32"
 347   AC_SUBST(WIN32_LIBS)
 348 fi
 349
 350 dnl disable experimental plug-ins
 351 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 352   AG_GST_DISABLE_PLUGIN(monoscope)
 353 fi
 354
 355 dnl *** sys plug-ins ***
 356
 357 echo
 358 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 359 echo
 360
 361 dnl DirectSound
 362 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 363 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 364   HAVE_DIRECTSOUND="no"
 365   save_CFLAGS="$CFLAGS"
 366   save_LDFLAGS="$LDFLAGS"
 367   save_LIBS="$LIBS"
 368   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 369   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 370   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 371   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 372   AC_LINK_IFELSE([
 373 #include <windows.h>
 374 #include <dxerr9.h>
 375 #include <dsound.h>
 376
 377 int main ()
 378 {
 379   DXGetErrorString9 (0);
 380   DirectSoundCreate(NULL, NULL, NULL);
 381
 382   return 0;
 383 }
 384 ],
 385     [HAVE_DIRECTSOUND="yes"],
 386     [HAVE_DIRECTSOUND="no"])
 387   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 388   CFLAGS=$save_CFLAGS
 389   LDFLAGS=$save_LDFLAGS
 390   LIBS=$save_LIBS
 391
 392   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 393     dnl this is much more than we want
 394     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 395     AC_SUBST(DIRECTSOUND_CFLAGS)
 396     AC_SUBST(DIRECTSOUND_LDFLAGS)
 397     AC_SUBST(DIRECTSOUND_LIBS)
 398   fi
 399   AC_SUBST(HAVE_DIRECTSOUND)
 400 ])
 401
 402 dnl *** OSS audio *** (Linux, *BSD)
 403 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 404 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 405  HAVE_OSS="yes"
 406 dnl Linux and newer BSD versions :
 407  AC_CHECK_HEADER(sys/soundcard.h, [
 408    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 409    ] , [
 410 dnl Some old BSD versions and also newer OpenBSD versions :
 411    AC_CHECK_HEADER(soundcard.h, [
 412      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 413      ], [
 414   dnl Some old BSD versions :
 415      AC_CHECK_HEADER(machine/soundcard.h, [
 416        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 417          [Define if OSS includes are in /machine/])
 418        ], [
 419        HAVE_OSS="no"
 420      ])
 421    ])
 422  ])
 423 ])
 424
 425 dnl *** Sun Audio ***
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 427 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 428   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 429 ])
 430
 431 dnl *** OSX Audio ***
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 433 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 434   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 435 ])
 436
 437 dnl *** OS X video ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 439 HAVE_OSX_VIDEO="no"
 440 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 441   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 442 ])
 443 dnl in case header OpenGL/gl.h is found on other platforms
 444 case "$host" in
 445   *-*darwin*)
 446     dnl do nothing
 447     ;;
 448   *)
 449     HAVE_OSX_VIDEO="no"
 450     ;;
 451 esac
 452
 453
 454 dnl *** Video 4 Linux 2 ***
 455 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 456 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 458 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 459   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 460   AC_TRY_COMPILE([
 461 #include <sys/types.h>
 462 #ifdef __sun /* Solaris */
 463 #include <sys/types.h>
 464 #include <sys/videodev2.h>
 465 #else /* Linux */
 466 #include <linux/types.h>
 467 #define _LINUX_TIME_H
 468 #define __user
 469 #include <linux/videodev2.h>
 470 #endif
 471 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 472 #error too early v4l2 version or no v4l2 at all
 473 #endif
 474     ], [
 475 return 0;
 476     ], [
 477       HAVE_GST_V4L2="yes"
 478       AC_MSG_RESULT(yes)
 479     ], [
 480       HAVE_GST_V4L2="no"
 481       AC_MSG_RESULT(no)
 482
 483       HAVE_VIDEODEV=no
 484       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 485       [
 486         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 487       ])
 488
 489       if test "x$HAVE_VIDEODEV" = "xyes"; then
 490         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 491         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 492       else
 493         AC_MSG_WARN([video4linux2 was not found])
 494       fi
 495     ])
 496
 497   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 498     dnl check for missing v4l2_buffer declaration (see #135919)
 499     MISSING_DECL=0
 500     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 501     AC_TRY_COMPILE([
 502 #include <sys/types.h>
 503 #ifdef __sun /* Solaris */
 504 #include <sys/types.h>
 505 #include <sys/videodev2.h>
 506 #else /* Linux */
 507 #include <linux/types.h>
 508 #define _LINUX_TIME_H
 509 #define __user
 510 #include <linux/videodev2.h>
 511 #endif
 512     ],[
 513 struct v4l2_buffer buf;
 514 buf.index = 0;
 515 return 0;
 516     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 517     if [ test x$MISSING_DECL = x1 ]; then
 518       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 519     fi
 520
 521     dnl check for XOverlay libraries
 522     AG_GST_CHECK_XV
 523   fi
 524 ])
 525
 526 # Optional gudev for device probing
 527 AC_ARG_WITH([gudev],
 528   AC_HELP_STRING([--with-gudev],
 529     [device detection with gudev]),
 530   [],
 531   [with_gudev=check])
 532 if test x$HAVE_GST_V4L2 = xyes; then
 533   if test x$with_gudev != xno; then
 534       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 535           [ have_gudev=yes
 536             AC_DEFINE(HAVE_GUDEV, 1,
 537                [Whether gudev is available for device detection])
 538             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 539           ], [
 540           have_gudev=no
 541           ])
 542   else
 543     have_gudev=no
 544   fi
 545 fi
 546 AC_SUBST(GUDEV_CFLAGS)
 547 AC_SUBST(GUDEV_LIBS)
 548
 549 # Make libv4l2 non-automagic
 550 AC_ARG_WITH([libv4l2],
 551   AC_HELP_STRING([--with-libv4l2],
 552     [support video buffer conversion using libv4l2]),
 553   [],
 554   [with_libv4l2=check])
 555 if test x$HAVE_GST_V4L2 = xyes; then
 556   if test x$with_libv4l2 != xno; then
 557       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 558           [ have_libv4l2=yes
 559             AC_DEFINE(HAVE_LIBV4L2, 1,
 560                 [Whether libv4l2 is available for video buffer conversion])
 561           ], [
 562           have_libv4l2=no
 563           ])
 564   else
 565     have_libv4l2=no
 566   fi
 567 fi
 568
 569 dnl Check for X11
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 571 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 572                   [ximagesrc], [
 573   AC_PATH_XTRA
 574
 575   dnl now try to find the HEADER
 576   ac_cflags_save="$CFLAGS"
 577   ac_cppflags_save="$CPPFLAGS"
 578   CFLAGS="$CFLAGS $X_CFLAGS"
 579   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 580   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 581
 582   if test "x$HAVE_X" = "xno"
 583   then
 584     AC_MSG_NOTICE([cannot find X11 development files])
 585   else
 586     dnl this is much more than we want
 587     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 588     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 589     dnl it does not add the libs; therefore we add them here
 590     X_LIBS="$X_LIBS -lX11"
 591     AC_SUBST(X_CFLAGS)
 592     AC_SUBST(X_LIBS)
 593
 594     dnl check for Xfixes
 595     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 596     if test "x$HAVE_XFIXES" = "xyes"
 597     then
 598         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 599     fi
 600     AC_SUBST(XFIXES_LIBS)
 601     AC_SUBST(XFIXES_CFLAGS)
 602
 603     dnl check for Xdamage
 604     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 605     if test "x$HAVE_XDAMAGE" = "xyes"
 606     then
 607         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 608     fi
 609     AC_SUBST(XDAMAGE_LIBS)
 610     AC_SUBST(XDAMAGE_CFLAGS)
 611   fi
 612   AC_SUBST(HAVE_X)
 613   CFLAGS="$ac_cflags_save"
 614   CPPFLAGS="$ac_cppflags_save"
 615 ])
 616
 617 dnl FIXME: this should be rolled into the test above, it's just an additional
 618 dnl feature of the ximagesrc plug-in
 619 dnl This is the same as in gst-plugins-base
 620 dnl check for X Shm
 621 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 622 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 623   if test x$HAVE_X = xyes; then
 624     AC_CHECK_LIB(Xext, XShmAttach,
 625                  HAVE_XSHM="yes", HAVE_XSHM="no",
 626                  $X_LIBS)
 627     if test "x$HAVE_XSHM" = "xyes"; then
 628       XSHM_LIBS="-lXext"
 629     else
 630       dnl On AIX, it is in XextSam instead, but we still need -lXext
 631       AC_CHECK_LIB(XextSam, XShmAttach,
 632                    HAVE_XSHM="yes", HAVE_XSHM="no",
 633                    $X_LIBS)
 634       if test "x$HAVE_XSHM" = "xyes"; then
 635         XSHM_LIBS="-lXext -lXextSam"
 636       fi
 637     fi
 638   fi
 639 ], ,[
 640   AC_SUBST(HAVE_XSHM)
 641   AC_SUBST(XSHM_LIBS)
 642 ])
 643
 644 dnl for V4L2, we also need to know if we have XVIDEO
 645 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 646 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 647                   [], [
 648   AG_GST_CHECK_XV
 649 ])
 650
 651 dnl *** ext plug-ins ***
 652 dnl keep this list sorted alphabetically !
 653
 654 if test "x$BUILD_EXTERNAL" = "xyes"; then
 655
 656 echo
 657 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 658 echo
 659
 660 dnl *** aalib ***
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 662 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 663   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 664   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 665 ])
 666
 667 dnl *** annodex ***
 668 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 669 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 670   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 671 ])
 672
 673 dnl *** cairo ***
 674 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 675 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 676   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 677 ])
 678
 679 dnl **** ESound ****
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 681 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 682   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 683   if test $HAVE_ESD = no
 684   then
 685     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 686     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 687   fi
 688 ])
 689
 690 dnl *** FLAC ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 692 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 693   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 694 ])
 695
 696 dnl *** GConf ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 698 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 699   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 700 ])
 701
 702 dnl *** GDK pixbuf ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 704 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 705   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 706 ])
 707
 708 dnl *** HAL ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 710 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 711   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 712 ])
 713
 714 dnl *** jpeg ***
 715 dnl FIXME: we could use header checks here as well IMO
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 717 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 718   AC_ARG_WITH(jpeg-mmx,
 719     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 720   OLD_LIBS="$LIBS"
 721   if test x$with_jpeg_mmx != x; then
 722     LIBS="$LIBS -L$with_jpeg_mmx"
 723   fi
 724   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 725   JPEG_LIBS="$LIBS -ljpeg-mmx"
 726   LIBS="$OLD_LIBS"
 727   if test x$HAVE_JPEG != xyes; then
 728     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 729     JPEG_LIBS="-ljpeg"
 730   fi
 731   AC_SUBST(JPEG_LIBS)
 732 ])
 733
 734 dnl *** libcaca ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 736 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 737   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 738   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 739   if test "x$HAVE_LIBCACA" != "xyes"; then
 740     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 741     dnl see if it compilation works too, might not if we are cross-compiling
 742     if test "x$HAVE_LIBCACA" = "xyes"; then
 743       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 744                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 745     fi
 746   fi
 747 ])
 748
 749 dnl *** libdv ***
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 751 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 752   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 753 ])
 754
 755 dnl *** libpng ***
 756 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 757 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 758   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 759 ])
 760
 761 dnl *** pulseaudio ***
 762 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 763 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 764   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 765   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 766   if test x$HAVE_PULSE_0_9_11 = xyes; then
 767     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 768   fi
 769   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 770   if test x$HAVE_PULSE_0_9_12 = xyes; then
 771     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 772   fi
 773   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 774   if test x$HAVE_PULSE_0_9_13 = xyes; then
 775     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 776   fi
 777   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 778   if test x$HAVE_PULSE_0_9_15 = xyes; then
 779     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 780   fi
 781   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 782   if test x$HAVE_PULSE_0_9_20 = xyes; then
 783     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 784   fi
 785 ])
 786
 787 dnl *** dv1394 ***
 788 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 789 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 790   dnl first test for libraw1394 >= 1.2.1
 791   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.2.1)
 792   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 793   dnl now see how far we got
 794   if test x$HAVE_RAW1394 = xyes && \
 795      test x$HAVE_LIBIEC61883 = xyes; then
 796        AG_GST_CHECK_LIBHEADER(AVC1394,
 797         avc1394, avc1394_send_command, $RAW1394_LIBS,
 798         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 799        AG_GST_CHECK_LIBHEADER(ROM1394,
 800         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 801         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 802        if test x$HAVE_AVC1394 = xyes && \
 803           test x$HAVE_AVC1394 = xyes && \
 804           test x$HAVE_ROM1394 = xyes; then
 805           HAVE_DV1394=yes
 806           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 807           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 808           AC_SUBST(DV1394_CFLAGS)
 809           AC_SUBST(DV1394_LIBS)
 810         fi
 811   else
 812        if test x$HAVE_RAW1394 = xno; then
 813           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 814           AG_GST_CHECK_LIBHEADER(AVC1394,
 815            avc1394, avc1394_send_command, $RAW1394_LIBS,
 816            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 817           AG_GST_CHECK_LIBHEADER(ROM1394,
 818            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 819            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 820           if test x$HAVE_RAW1394 = xyes && \
 821              test x$HAVE_AVC1394 = xyes && \
 822              test x$HAVE_ROM1394 = xyes; then
 823              HAVE_DV1394=yes
 824              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 825              DV1394_CFLAGS="$RAW1394_CFLAGS"
 826              if test x$HAVE_LIBIEC61883 = xyes; then
 827                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 828                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 829              fi
 830              AC_SUBST(DV1394_CFLAGS)
 831              AC_SUBST(DV1394_LIBS)
 832            fi
 833          fi
 834   fi
 835 ])
 836
 837 dnl *** shout2 ***
 838 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 839 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 840   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 841   if test $HAVE_SHOUT2 = no
 842   then
 843     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 844     AC_SUBST(SHOUT2_CFLAGS)
 845     AC_SUBST(SHOUT2_LIBS)
 846   fi
 847 ])
 848
 849 dnl *** soup ***
 850 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 851 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 852   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 853     HAVE_SOUP="yes"
 854     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 855   ],[
 856     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 857       HAVE_SOUP="no"
 858       AC_MSG_RESULT(no)
 859     ])
 860   ])
 861   AC_SUBST(SOUP_CFLAGS)
 862   AC_SUBST(SOUP_LIBS)
 863 ])
 864
 865 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 866 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 867 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 868 dnl   speex_jitter.h is 1.1.x only
 869 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 870 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 871   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 872   if test $HAVE_SPEEX = no
 873   then
 874     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 875       AC_CHECK_HEADER(speex/speex_jitter.h, [
 876         dnl speex 1.1.x :
 877         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 878           dnl speex 1.1.5 or + :
 879           HAVE_SPEEX="yes"
 880           SPEEX_LIBS="-lspeex"
 881           AC_SUBST(SPEEX_CFLAGS)
 882           AC_SUBST(SPEEX_LIBS)
 883         ],[
 884           HAVE_SPEEX="no"
 885         ])
 886       ],[
 887         dnl speex 1.0.x :
 888           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 889             dnl speex 1.0.4
 890             HAVE_SPEEX="yes"
 891             SPEEX_LIBS="-lspeex"
 892             AC_SUBST(SPEEX_CFLAGS)
 893             AC_SUBST(SPEEX_LIBS)
 894
 895             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 896               [defined if speex 1.0.x API detected])
 897         ],[
 898             HAVE_SPEEX="no"
 899             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 900         ], [
 901 #include <speex/speex.h>
 902         ])
 903       ])
 904     ])
 905   fi
 906 ])
 907
 908 dnl *** taglib ***
 909 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 910 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 911   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 912   if test "x$HAVE_CXX" != "xyes"; then
 913     USE_TAGLIB=false
 914     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 915   else
 916     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 917     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 918         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 919       ], [
 920         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 921     ])
 922     AC_SUBST(TAGLIB_CXXFLAGS)
 923   fi
 924 ])
 925
 926 dnl *** wavpack ***
 927 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 928 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 929   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 930     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 931       HAVE_WAVPACK=yes
 932       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 933     ],[
 934       HAVE_WAVPACK=no
 935       AC_MSG_RESULT(no)
 936     ])
 937   ])
 938   AC_SUBST(WAVPACK_CFLAGS)
 939   AC_SUBST(WAVPACK_LIBS)
 940 ])
 941
 942 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 943 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 944 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 945   AG_GST_CHECK_LIBHEADER(ZLIB,
 946     z, uncompress,, zlib.h, [
 947     HAVE_ZLIB="yes"
 948     ZLIB_LIBS="-lz"
 949     AC_SUBST(ZLIB_LIBS)
 950   ])
 951 ])
 952
 953 dnl *** matroska prefers to have bz2 ***
 954 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 955 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 956   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 957   AC_SUBST(BZ2_LIBS)
 958 ])
 959
 960 else
 961
 962 dnl not building plugins with external dependencies,
 963 dnl but we still need to set the conditionals
 964 AM_CONDITIONAL(USE_AALIB, false)
 965 AM_CONDITIONAL(USE_ANNODEX, false)
 966 AM_CONDITIONAL(USE_BZ2, false)
 967 AM_CONDITIONAL(USE_CAIRO, false)
 968 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 969 AM_CONDITIONAL(USE_DV1394, false)
 970 AM_CONDITIONAL(USE_ESD, false)
 971 AM_CONDITIONAL(USE_FLAC, false)
 972 AM_CONDITIONAL(USE_GCONF, false)
 973 AM_CONDITIONAL(USE_GCONFTOOL, false)
 974 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 975 AM_CONDITIONAL(USE_GST_V4L2, false)
 976 AM_CONDITIONAL(USE_HAL, false)
 977 AM_CONDITIONAL(USE_JPEG, false)
 978 AM_CONDITIONAL(USE_LIBCACA, false)
 979 AM_CONDITIONAL(USE_LIBDV, false)
 980 AM_CONDITIONAL(USE_LIBPNG, false)
 981 AM_CONDITIONAL(USE_OSS, false)
 982 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 983 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 984 AM_CONDITIONAL(USE_PULSE, false)
 985 AM_CONDITIONAL(USE_SHOUT2, false)
 986 AM_CONDITIONAL(USE_SOUP, false)
 987 AM_CONDITIONAL(USE_SPEEX, false)
 988 AM_CONDITIONAL(USE_SUNAUDIO, false)
 989 AM_CONDITIONAL(USE_TAGLIB, false)
 990 AM_CONDITIONAL(USE_WAVPACK, false)
 991 AM_CONDITIONAL(USE_X, false)
 992 AM_CONDITIONAL(USE_XSHM, false)
 993 AM_CONDITIONAL(USE_XVIDEO, false)
 994 AM_CONDITIONAL(USE_ZLIB, false)
 995
 996 fi dnl of EXT plugins
 997
 998 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 999
1000 dnl Overview:
1001 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1002 dnl GST_*:              flags shared by all built objects
1003 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1004 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1005 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1006 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1007
1008 dnl GST_OPTION_CFLAGS
1009 if test "x$USE_DEBUG" = xyes; then
1010    PROFILE_CFLAGS="-g"
1011 fi
1012 AC_SUBST(PROFILE_CFLAGS)
1013
1014 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1015   dnl Define _only_ for git (not pre-releases or releases)
1016   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1017 else
1018   DEPRECATED_CFLAGS=""
1019 fi
1020 AC_SUBST(DEPRECATED_CFLAGS)
1021
1022 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1023 dnl at make time with e.g. make ERROR_CFLAGS=""
1024 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1025 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1026 AC_SUBST(GST_OPTION_CFLAGS)
1027 AC_SUBST(GST_OPTION_CXXFLAGS)
1028
1029 dnl our libraries need to be versioned correctly
1030 AC_SUBST(GST_LT_LDFLAGS)
1031
1032 dnl FIXME: do we want to rename to GST_ALL_* ?
1033 dnl prefer internal headers to already installed ones
1034 dnl also add builddir include for enumtypes and marshal
1035 dnl add ERROR_CFLAGS, but overridable
1036 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1037 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
1038 AC_SUBST(GST_CFLAGS)
1039 AC_SUBST(GST_CXXFLAGS)
1040 AC_SUBST(GST_LIBS)
1041
1042 dnl LDFLAGS really should only contain flags, not libs - they get added before
1043 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1044 GST_ALL_LDFLAGS="-no-undefined"
1045 AC_SUBST(GST_ALL_LDFLAGS)
1046
1047 dnl this really should only contain flags, not libs - they get added before
1048 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1049 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1050 AC_SUBST(GST_PLUGIN_LDFLAGS)
1051
1052 dnl *** output files ***
1053
1054 dnl keep this alphabetic per directory, please
1055 AC_CONFIG_FILES(
1056 Makefile
1057 gst/Makefile
1058 gst/alpha/Makefile
1059 gst/apetag/Makefile
1060 gst/audiofx/Makefile
1061 gst/auparse/Makefile
1062 gst/autodetect/Makefile
1063 gst/avi/Makefile
1064 gst/cutter/Makefile
1065 gst/deinterlace/Makefile
1066 gst/debugutils/Makefile
1067 gst/effectv/Makefile
1068 gst/equalizer/Makefile
1069 gst/flv/Makefile
1070 gst/id3demux/Makefile
1071 gst/icydemux/Makefile
1072 gst/interleave/Makefile
1073 gst/goom/Makefile
1074 gst/goom2k1/Makefile
1075 gst/law/Makefile
1076 gst/level/Makefile
1077 gst/matroska/Makefile
1078 gst/monoscope/Makefile
1079 gst/multifile/Makefile
1080 gst/multipart/Makefile
1081 gst/qtdemux/Makefile
1082 gst/replaygain/Makefile
1083 gst/rtp/Makefile
1084 gst/rtpmanager/Makefile
1085 gst/rtsp/Makefile
1086 gst/shapewipe/Makefile
1087 gst/smpte/Makefile
1088 gst/spectrum/Makefile
1089 gst/udp/Makefile
1090 gst/videobox/Makefile
1091 gst/videocrop/Makefile
1092 gst/videofilter/Makefile
1093 gst/videomixer/Makefile
1094 gst/wavenc/Makefile
1095 gst/wavparse/Makefile
1096 gst/flx/Makefile
1097 gst/y4m/Makefile
1098 ext/jpeg/Makefile
1099 ext/Makefile
1100 ext/aalib/Makefile
1101 ext/annodex/Makefile
1102 ext/cairo/Makefile
1103 ext/dv/Makefile
1104 ext/esd/Makefile
1105 ext/flac/Makefile
1106 ext/gconf/Makefile
1107 ext/gdk_pixbuf/Makefile
1108 ext/hal/Makefile
1109 ext/libcaca/Makefile
1110 ext/libpng/Makefile
1111 ext/pulse/Makefile
1112 ext/raw1394/Makefile
1113 ext/shout2/Makefile
1114 ext/soup/Makefile
1115 ext/speex/Makefile
1116 ext/taglib/Makefile
1117 ext/wavpack/Makefile
1118 sys/Makefile
1119 sys/directsound/Makefile
1120 sys/oss/Makefile
1121 sys/sunaudio/Makefile
1122 sys/osxaudio/Makefile
1123 sys/osxvideo/Makefile
1124 sys/v4l2/Makefile
1125 sys/waveform/Makefile
1126 sys/ximage/Makefile
1127 po/Makefile.in
1128 tests/Makefile
1129 tests/check/Makefile
1130 tests/examples/Makefile
1131 tests/examples/audiofx/Makefile
1132 tests/examples/equalizer/Makefile
1133 tests/examples/level/Makefile
1134 tests/examples/rtp/Makefile
1135 tests/examples/shapewipe/Makefile
1136 tests/examples/spectrum/Makefile
1137 tests/examples/v4l2/Makefile
1138 tests/files/Makefile
1139 tests/icles/Makefile
1140 gconf/Makefile
1141 gconf/gstreamer.schemas
1142 common/Makefile
1143 common/m4/Makefile
1144 m4/Makefile
1145 docs/Makefile
1146 docs/plugins/Makefile
1147 docs/version.entities
1148 pkgconfig/Makefile
1149 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1150 gst-plugins-good.spec
1151 )
1152
1153 dnl Create the config.h file for Visual Studio builds
1154 dnl Beware of spaces and /'s in some of the shell variable contents.
1155 sed \
1156     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1157     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1158     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1159     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1160     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1161     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1162     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1163     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1164     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1165     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1166     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1167     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1168     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1169     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1170     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1171     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1172     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1173     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1174     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1175     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1176     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1177     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1178     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1179     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1180     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1181     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1182     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1183     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1184     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1185     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1186     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1187     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1188     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1189     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1190     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1191     config.h.in >win32/common/config.h-new
1192
1193 AC_OUTPUT
1194
1195 AG_GST_OUTPUT_PLUGINS