configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.68)
   4
   5 AC_INIT([libffi], [3.0.12-rc3], [http://github.com/atgreen/libffi/issues])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AC_CANONICAL_SYSTEM
   9 target_alias=${target_alias-$host_alias}
  10
  11 . ${srcdir}/configure.host
  12
  13 AX_ENABLE_BUILDDIR
  14
  15 AM_INIT_AUTOMAKE
  16
  17 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  18 # We must force CC to /not/ be precious variables; otherwise
  19 # the wrong, non-multilib-adjusted value will be used in multilibs.
  20 # As a side effect, we have to subst CFLAGS ourselves.
  21 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
  22 # defaults of its own if none are provided.
  23
  24 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  25 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  26 save_CFLAGS=$CFLAGS
  27 AC_PROG_CC
  28 CFLAGS=$save_CFLAGS
  29 m4_undefine([_AC_ARG_VAR_PRECIOUS])
  30 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_PROG_AS
  35 AM_PROG_CC_C_O
  36 AC_PROG_LIBTOOL
  37 AC_CONFIG_MACRO_DIR([m4])
  38
  39 # Test for 64-bit build.
  40 AC_CHECK_SIZEOF([size_t])
  41
  42 AX_COMPILER_VENDOR
  43 AX_CC_MAXOPT
  44 # The AX_CFLAGS_WARN_ALL macro doesn't currently work for sunpro
  45 # compiler.
  46 if test "$ax_cv_c_compiler_vendor" != "sun"; then
  47   AX_CFLAGS_WARN_ALL
  48 fi
  49
  50 if test "x$GCC" = "xyes"; then
  51   CFLAGS="$CFLAGS -fexceptions"
  52   touch local.exp
  53 else
  54   cat > local.exp <<EOF
  55 set CC_FOR_TARGET "$CC"
  56 EOF
  57 fi
  58
  59 AM_MAINTAINER_MODE
  60
  61 AC_CHECK_HEADERS(sys/mman.h)
  62 AC_CHECK_FUNCS(mmap)
  63 AC_FUNC_MMAP_BLACKLIST
  64
  65 dnl The -no-testsuite modules omit the test subdir.
  66 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  67
  68 TARGETDIR="unknown"
  69 case "$host" in
  70   aarch64*-*-*)
  71         TARGET=AARCH64; TARGETDIR=aarch64
  72         ;;
  73
  74   alpha*-*-*)
  75         TARGET=ALPHA; TARGETDIR=alpha;
  76         # Support 128-bit long double, changeable via command-line switch.
  77         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  78         ;;
  79
  80   arm*-*-*)
  81         TARGET=ARM; TARGETDIR=arm
  82         ;;
  83
  84   amd64-*-freebsd* | amd64-*-openbsd*)
  85         TARGET=X86_64; TARGETDIR=x86
  86         ;;
  87
  88   amd64-*-freebsd*)
  89         TARGET=X86_64; TARGETDIR=x86
  90         ;;
  91
  92   amd64-*-freebsd*)
  93         TARGET=X86_64; TARGETDIR=x86
  94         ;;
  95
  96   avr32*-*-*)
  97         TARGET=AVR32; TARGETDIR=avr32
  98         ;;
  99
 100   bfin*)
 101         TARGET=BFIN; TARGETDIR=bfin
 102         ;;
 103
 104   cris-*-*)
 105         TARGET=LIBFFI_CRIS; TARGETDIR=cris
 106         ;;
 107
 108   frv-*-*)
 109         TARGET=FRV; TARGETDIR=frv
 110         ;;
 111
 112   hppa*-*-linux* | parisc*-*-linux* | hppa*-*-openbsd*)
 113         TARGET=PA_LINUX; TARGETDIR=pa
 114         ;;
 115   hppa*64-*-hpux*)
 116         TARGET=PA64_HPUX; TARGETDIR=pa
 117         ;;
 118   hppa*-*-hpux*)
 119         TARGET=PA_HPUX; TARGETDIR=pa
 120         ;;
 121
 122   i?86-*-freebsd* | i?86-*-openbsd*)
 123         TARGET=X86_FREEBSD; TARGETDIR=x86
 124         ;;
 125   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2* | i?86-*-interix*)
 126         TARGET=X86_WIN32; TARGETDIR=x86
 127         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
 128         # We must also check with_cross_host to decide if this is a native
 129         # or cross-build and select where to install dlls appropriately.
 130         if test -n "$with_cross_host" &&
 131            test x"$with_cross_host" != x"no"; then
 132           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
 133         else
 134           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
 135         fi
 136         ;;
 137   i?86-*-darwin*)
 138         TARGET=X86_DARWIN; TARGETDIR=x86
 139         ;;
 140   i?86-*-solaris2.1[[0-9]]*)
 141         TARGETDIR=x86
 142         if test $ac_cv_sizeof_size_t = 4; then
 143           TARGET=X86;
 144         else
 145           TARGET=X86_64;
 146         fi
 147         ;;
 148
 149   x86_64-*-darwin*)
 150         TARGET=X86_DARWIN; TARGETDIR=x86
 151         ;;
 152
 153   x86_64-*-cygwin* | x86_64-*-mingw*)
 154         TARGET=X86_WIN64; TARGETDIR=x86
 155         # All mingw/cygwin/win32 builds require -no-undefined for sharedlib.
 156         # We must also check with_cross_host to decide if this is a native
 157         # or cross-build and select where to install dlls appropriately.
 158         if test -n "$with_cross_host" &&
 159            test x"$with_cross_host" != x"no"; then
 160           AM_LTLDFLAGS='-no-undefined -bindir "$(toolexeclibdir)"';
 161         else
 162           AM_LTLDFLAGS='-no-undefined -bindir "$(bindir)"';
 163         fi
 164         ;;
 165
 166   i?86-*-* | x86_64-*-*)
 167         TARGETDIR=x86
 168         if test $ac_cv_sizeof_size_t = 4; then
 169           case "$host" in
 170             *-gnux32)
 171               TARGET=X86_64
 172               ;;
 173             *)
 174               TARGET=X86
 175               ;;
 176           esac
 177         else
 178           TARGET=X86_64;
 179         fi
 180         ;;
 181
 182   ia64*-*-*)
 183         TARGET=IA64; TARGETDIR=ia64
 184         ;;
 185
 186   m32r*-*-*)
 187         TARGET=M32R; TARGETDIR=m32r
 188         ;;
 189
 190   m68k-*-*)
 191         TARGET=M68K; TARGETDIR=m68k
 192         ;;
 193
 194   microblaze*-*-*)
 195         TARGET=MICROBLAZE; TARGETDIR=microblaze
 196         ;;
 197
 198   mips-sgi-irix5.* | mips-sgi-irix6.* | mips*-*-rtems*)
 199         TARGET=MIPS; TARGETDIR=mips
 200         ;;
 201   mips*-*-linux* | mips*-*-openbsd*)
 202         # Support 128-bit long double for NewABI.
 203         HAVE_LONG_DOUBLE='defined(__mips64)'
 204         TARGET=MIPS; TARGETDIR=mips
 205         ;;
 206
 207   powerpc*-*-linux* | powerpc-*-sysv*)
 208         TARGET=POWERPC; TARGETDIR=powerpc
 209         ;;
 210   powerpc-*-amigaos*)
 211         TARGET=POWERPC; TARGETDIR=powerpc
 212         ;;
 213   powerpc-*-beos*)
 214         TARGET=POWERPC; TARGETDIR=powerpc
 215         ;;
 216   powerpc-*-darwin* | powerpc64-*-darwin*)
 217         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 218         ;;
 219   powerpc-*-aix* | rs6000-*-aix*)
 220         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 221         ;;
 222   powerpc-*-freebsd* | powerpc-*-openbsd*)
 223         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 224         ;;
 225   powerpc64-*-freebsd*)
 226         TARGET=POWERPC; TARGETDIR=powerpc
 227         ;;
 228   powerpc*-*-rtems*)
 229         TARGET=POWERPC; TARGETDIR=powerpc
 230         ;;
 231
 232   s390-*-* | s390x-*-*)
 233         TARGET=S390; TARGETDIR=s390
 234         ;;
 235
 236   sh-*-* | sh[[34]]*-*-*)
 237         TARGET=SH; TARGETDIR=sh
 238         ;;
 239   sh64-*-* | sh5*-*-*)
 240         TARGET=SH64; TARGETDIR=sh64
 241         ;;
 242
 243   sparc*-*-*)
 244         TARGET=SPARC; TARGETDIR=sparc
 245         ;;
 246
 247   tile*-*)
 248         TARGET=TILE; TARGETDIR=tile
 249         ;;
 250
 251   xtensa*-*)
 252         TARGET=XTENSA; TARGETDIR=xtensa
 253         ;;
 254
 255 esac
 256
 257 AC_SUBST(AM_RUNTESTFLAGS)
 258 AC_SUBST(AM_LTLDFLAGS)
 259
 260 if test $TARGETDIR = unknown; then
 261   AC_MSG_ERROR(["libffi has not been ported to $host."])
 262 fi
 263
 264 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 265 AM_CONDITIONAL(BFIN, test x$TARGET = xBFIN)
 266 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 267 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 268 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 269 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 270 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 271 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 272 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 273 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 274 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 275 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 276 AM_CONDITIONAL(MICROBLAZE, test x$TARGET = xMICROBLAZE)
 277 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
 278 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 279 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 280 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 281 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 282 AM_CONDITIONAL(AARCH64, test x$TARGET = xAARCH64)
 283 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 284 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 285 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 286 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 287 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 288 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 289 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 290 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 291 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 292 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 293 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 294 AM_CONDITIONAL(TILE, test x$TARGET = xTILE)
 295 AM_CONDITIONAL(XTENSA, test x$TARGET = xXTENSA)
 296
 297 AC_HEADER_STDC
 298 AC_CHECK_FUNCS(memcpy)
 299 AC_FUNC_ALLOCA
 300
 301 AC_CHECK_SIZEOF(double)
 302 AC_CHECK_SIZEOF(long double)
 303
 304 # Also AC_SUBST this variable for ffi.h.
 305 if test -z "$HAVE_LONG_DOUBLE"; then
 306   HAVE_LONG_DOUBLE=0
 307   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 308     if test $ac_cv_sizeof_long_double != 0; then
 309       HAVE_LONG_DOUBLE=1
 310       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 311     fi
 312   fi
 313 fi
 314 AC_SUBST(HAVE_LONG_DOUBLE)
 315
 316 AC_C_BIGENDIAN
 317
 318 GCC_AS_CFI_PSEUDO_OP
 319
 320 if test x$TARGET = xSPARC; then
 321     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 322         libffi_cv_as_sparc_ua_pcrel, [
 323         save_CFLAGS="$CFLAGS"
 324         save_LDFLAGS="$LDFLAGS"
 325         CFLAGS="$CFLAGS -fpic"
 326         LDFLAGS="$LDFLAGS -shared"
 327         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 328                     [libffi_cv_as_sparc_ua_pcrel=yes],
 329                     [libffi_cv_as_sparc_ua_pcrel=no])
 330         CFLAGS="$save_CFLAGS"
 331         LDFLAGS="$save_LDFLAGS"])
 332     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 333         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 334                   [Define if your assembler and linker support unaligned PC relative relocs.])
 335     fi
 336
 337     AC_CACHE_CHECK([assembler .register pseudo-op support],
 338        libffi_cv_as_register_pseudo_op, [
 339        libffi_cv_as_register_pseudo_op=unknown
 340        # Check if we have .register
 341        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
 342                        [libffi_cv_as_register_pseudo_op=yes],
 343                        [libffi_cv_as_register_pseudo_op=no])
 344     ])
 345     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 346        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 347                [Define if your assembler supports .register.])
 348     fi
 349 fi
 350
 351 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 352     AC_CACHE_CHECK([assembler supports pc related relocs],
 353         libffi_cv_as_x86_pcrel, [
 354         libffi_cv_as_x86_pcrel=no
 355         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 356         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 357             libffi_cv_as_x86_pcrel=yes
 358         fi
 359         ])
 360     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 361         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 362                   [Define if your assembler supports PC relative relocs.])
 363     fi
 364
 365     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 366        libffi_cv_as_ascii_pseudo_op, [
 367        libffi_cv_as_ascii_pseudo_op=unknown
 368        # Check if we have .ascii
 369        AC_TRY_COMPILE(,[asm (".ascii \\"string\\"");],
 370                        [libffi_cv_as_ascii_pseudo_op=yes],
 371                        [libffi_cv_as_ascii_pseudo_op=no])
 372     ])
 373     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 374        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 375                [Define if your assembler supports .ascii.])
 376     fi
 377
 378     AC_CACHE_CHECK([assembler .string pseudo-op support],
 379        libffi_cv_as_string_pseudo_op, [
 380        libffi_cv_as_string_pseudo_op=unknown
 381        # Check if we have .string
 382        AC_TRY_COMPILE(,[asm (".string \\"string\\"");],
 383                        [libffi_cv_as_string_pseudo_op=yes],
 384                        [libffi_cv_as_string_pseudo_op=no])
 385     ])
 386     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 387        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 388                [Define if your assembler supports .string.])
 389     fi
 390 fi
 391
 392 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
 393 AC_ARG_ENABLE(pax_emutramp,
 394   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
 395   if test "$enable_pax_emutramp" = "yes"; then
 396     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
 397       [Define this if you want to enable pax emulated trampolines])
 398   fi)
 399
 400 if test x$TARGET = xX86_WIN64; then
 401     LT_SYS_SYMBOL_USCORE
 402     if test "x$sys_symbol_underscore" = xyes; then
 403         AC_DEFINE(SYMBOL_UNDERSCORE, 1, [Define if symbols are underscored.])
 404     fi
 405 fi
 406
 407 FFI_EXEC_TRAMPOLINE_TABLE=0
 408 case "$target" in
 409      *arm*-apple-darwin*)
 410        FFI_EXEC_TRAMPOLINE_TABLE=1
 411        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
 412                  [Cannot use PROT_EXEC on this target, so, we revert to
 413                    alternative means])
 414      ;;
 415      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
 416        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 417                  [Cannot use malloc on this target, so, we revert to
 418                    alternative means])
 419      ;;
 420 esac
 421 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
 422 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
 423
 424 if test x$TARGET = xX86_64; then
 425     AC_CACHE_CHECK([assembler supports unwind section type],
 426         libffi_cv_as_x86_64_unwind_section_type, [
 427         libffi_cv_as_x86_64_unwind_section_type=yes
 428         echo '.section .eh_frame,"a",@unwind' > conftest.s
 429         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 430             libffi_cv_as_x86_64_unwind_section_type=no
 431         fi
 432         ])
 433     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 434         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 435                   [Define if your assembler supports unwind section type.])
 436     fi
 437 fi
 438
 439 if test "x$GCC" = "xyes"; then
 440   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 441       libffi_cv_ro_eh_frame, [
 442         libffi_cv_ro_eh_frame=no
 443         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 444         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
 445             objdump -h conftest.o > conftest.dump 2>&1
 446             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
 447             libffi_test_line=`expr $libffi_eh_frame_line + 1`p
 448             sed -n $libffi_test_line conftest.dump > conftest.line
 449             if grep READONLY conftest.line > /dev/null; then
 450                 libffi_cv_ro_eh_frame=yes
 451             fi
 452         fi
 453         rm -f conftest.*
 454       ])
 455   if test "x$libffi_cv_ro_eh_frame" = xyes; then
 456       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 457               [Define if .eh_frame sections should be read-only.])
 458       AC_DEFINE(EH_FRAME_FLAGS, "a",
 459               [Define to the flags needed for the .section .eh_frame directive.  ])
 460   else
 461       AC_DEFINE(EH_FRAME_FLAGS, "aw",
 462               [Define to the flags needed for the .section .eh_frame directive.  ])
 463   fi
 464
 465   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 466       libffi_cv_hidden_visibility_attribute, [
 467         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
 468         libffi_cv_hidden_visibility_attribute=no
 469         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 470             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 471                 libffi_cv_hidden_visibility_attribute=yes
 472             fi
 473         fi
 474         rm -f conftest.*
 475       ])
 476   if test $libffi_cv_hidden_visibility_attribute = yes; then
 477       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 478               [Define if __attribute__((visibility("hidden"))) is supported.])
 479   fi
 480 fi
 481
 482 AH_BOTTOM([
 483 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 484 #ifdef LIBFFI_ASM
 485 #define FFI_HIDDEN(name) .hidden name
 486 #else
 487 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 488 #endif
 489 #else
 490 #ifdef LIBFFI_ASM
 491 #define FFI_HIDDEN(name)
 492 #else
 493 #define FFI_HIDDEN
 494 #endif
 495 #endif
 496 ])
 497
 498 AC_SUBST(TARGET)
 499 AC_SUBST(TARGETDIR)
 500
 501 AC_SUBST(SHELL)
 502
 503 AC_ARG_ENABLE(debug,
 504 [  --enable-debug          debugging mode],
 505   if test "$enable_debug" = "yes"; then
 506     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 507   fi)
 508 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 509
 510 AC_ARG_ENABLE(structs,
 511 [  --disable-structs       omit code for struct support],
 512   if test "$enable_structs" = "no"; then
 513     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 514   fi)
 515 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 516
 517 AC_ARG_ENABLE(raw-api,
 518 [  --disable-raw-api       make the raw api unavailable],
 519   if test "$enable_raw_api" = "no"; then
 520     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 521   fi)
 522
 523 AC_ARG_ENABLE(purify-safety,
 524 [  --enable-purify-safety  purify-safe mode],
 525   if test "$enable_purify_safety" = "yes"; then
 526     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 527   fi)
 528
 529 # These variables are only ever used when we cross-build to X86_WIN32.
 530 # And we only support this with GCC, so...
 531 if test "x$GCC" = "xyes"; then
 532   if test -n "$with_cross_host" &&
 533      test x"$with_cross_host" != x"no"; then
 534     toolexecdir='$(exec_prefix)/$(target_alias)'
 535     toolexeclibdir='$(toolexecdir)/lib'
 536   else
 537     toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 538     toolexeclibdir='$(libdir)'
 539   fi
 540   multi_os_directory=`$CC -print-multi-os-directory`
 541   case $multi_os_directory in
 542     .) ;; # Avoid trailing /.
 543     *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 544   esac
 545   AC_SUBST(toolexecdir)
 546 else
 547   toolexeclibdir='$(libdir)'
 548 fi
 549 AC_SUBST(toolexeclibdir)
 550
 551 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 552 AC_CONFIG_COMMANDS(src, [
 553 test -d src || mkdir src
 554 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 555 ], [TARGETDIR="$TARGETDIR"])
 556
 557 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 558
 559 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
 560
 561 AC_OUTPUT