configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libmpx \
 161                 target-libssp \
 162                 target-libquadmath \
 163                 target-libgfortran \
 164                 target-libffi \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Enable libmpx on supported systems by request.
 605 if test -d ${srcdir}/libmpx; then
 606     if test x$enable_libmpx = x; then
 607        AC_MSG_CHECKING([for libmpx support])
 608        if (srcdir=${srcdir}/libmpx; \
 609                . ${srcdir}/configure.tgt; \
 610                test "$LIBMPX_SUPPORTED" != "yes")
 611        then
 612            AC_MSG_RESULT([no])
 613            noconfigdirs="$noconfigdirs target-libmpx"
 614        else
 615            AC_MSG_RESULT([yes])
 616        fi
 617     fi
 618 fi
 619
 620 # Disable libhsail-rt on unsupported systems.
 621 if test -d ${srcdir}/libhsail-rt; then
 622     if test x$enable_libhsail_rt = x; then
 623         AC_MSG_CHECKING([for libhsail-rt support])
 624         if (srcdir=${srcdir}/libhsail-rt; \
 625                 . ${srcdir}/configure.tgt; \
 626                 test -n "$UNSUPPORTED")
 627         then
 628             AC_MSG_RESULT([no])
 629             unsupported_languages="$unsupported_languages brig"
 630             # This implicitly disables also target-libhsail-rt as it won't
 631             # get added to the build without BRIG FE.
 632         else
 633             AC_MSG_RESULT([yes])
 634         fi
 635     fi
 636 fi
 637
 638
 639 # Disable libquadmath for some systems.
 640 case "${target}" in
 641   avr-*-*)
 642     noconfigdirs="$noconfigdirs target-libquadmath"
 643     ;;
 644   # libquadmath is unused on AIX and libquadmath build process use of
 645   # LD_LIBRARY_PATH can break AIX bootstrap.
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libquadmath"
 648     ;;
 649 esac
 650
 651 # Disable libssp for some systems.
 652 case "${target}" in
 653   avr-*-*)
 654     # No hosted I/O support.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   powerpc-*-aix* | rs6000-*-aix*)
 658     noconfigdirs="$noconfigdirs target-libssp"
 659     ;;
 660   rl78-*-*)
 661     # libssp uses a misaligned load to trigger a fault, but the RL78
 662     # doesn't fault for those - instead, it gives a build-time error
 663     # for explicit misaligned loads.
 664     noconfigdirs="$noconfigdirs target-libssp"
 665     ;;
 666   visium-*-*)
 667     # No hosted I/O support.
 668     noconfigdirs="$noconfigdirs target-libssp"
 669     ;;
 670 esac
 671
 672 # Disable libstdc++-v3 for some systems.
 673 # Allow user to override this if they pass --enable-libstdc++-v3
 674 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 675   case "${target}" in
 676     *-*-vxworks*)
 677       # VxWorks uses the Dinkumware C++ library.
 678       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 679       ;;
 680     arm*-wince-pe*)
 681       # the C++ libraries don't build on top of CE's C libraries
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684     avr-*-*)
 685       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 686       ;;
 687     ft32-*-*)
 688       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 689       ;;
 690   esac
 691 fi
 692
 693 # Disable Fortran for some systems.
 694 case "${target}" in
 695   mmix-*-*)
 696     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 697     unsupported_languages="$unsupported_languages fortran"
 698     ;;
 699 esac
 700
 701 # Disable libffi for some systems.
 702 case "${target}" in
 703   powerpc-*-darwin*)
 704     ;;
 705   i[[3456789]]86-*-darwin*)
 706     ;;
 707   x86_64-*-darwin[[912]]*)
 708     ;;
 709   *-*-darwin*)
 710     noconfigdirs="$noconfigdirs target-libffi"
 711     ;;
 712   *-*-netware*)
 713     noconfigdirs="$noconfigdirs target-libffi"
 714     ;;
 715   *-*-phoenix*)
 716     noconfigdirs="$noconfigdirs target-libffi"
 717     ;;
 718   *-*-rtems*)
 719     noconfigdirs="$noconfigdirs target-libffi"
 720     ;;
 721   *-*-tpf*)
 722     noconfigdirs="$noconfigdirs target-libffi"
 723     ;;
 724   *-*-uclinux*)
 725     noconfigdirs="$noconfigdirs target-libffi"
 726     ;;
 727   *-*-vxworks*)
 728     noconfigdirs="$noconfigdirs target-libffi"
 729     ;;
 730   aarch64*-*-freebsd*)
 731     noconfigdirs="$noconfigdirs target-libffi"
 732     ;;
 733   alpha*-*-*vms*)
 734     noconfigdirs="$noconfigdirs target-libffi"
 735     ;;
 736   arm*-*-freebsd*)
 737     noconfigdirs="$noconfigdirs target-libffi"
 738     ;;
 739   arm-wince-pe)
 740     noconfigdirs="$noconfigdirs target-libffi"
 741     ;;
 742   arm*-*-symbianelf*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   cris-*-* | crisv32-*-*)
 746     case "${target}" in
 747       *-*-linux*)
 748         ;;
 749       *) # See PR46792 regarding target-libffi.
 750         noconfigdirs="$noconfigdirs target-libffi";;
 751     esac
 752     ;;
 753   hppa*64*-*-hpux*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   hppa*-hp-hpux11*)
 757     ;;
 758   hppa*-*-hpux*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   ia64*-*-*vms*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   i[[3456789]]86-w64-mingw*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   i[[3456789]]86-*-mingw*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   x86_64-*-mingw*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   mmix-*-*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   powerpc-*-aix*)
 777     ;;
 778   rs6000-*-aix*)
 779     ;;
 780   ft32-*-*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-lynxos*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786 esac
 787
 788 # Disable the go frontend on systems where it is known to not work. Please keep
 789 # this in sync with contrib/config-list.mk.
 790 case "${target}" in
 791 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 792     unsupported_languages="$unsupported_languages go"
 793     ;;
 794 esac
 795
 796 # Disable libgo for some systems where it is known to not work.
 797 # For testing, you can easily override this with --enable-libgo.
 798 if test x$enable_libgo = x; then
 799     case "${target}" in
 800     *-*-darwin*)
 801         # PR 46986
 802         noconfigdirs="$noconfigdirs target-libgo"
 803         ;;
 804     *-*-cygwin* | *-*-mingw*)
 805         noconfigdirs="$noconfigdirs target-libgo"
 806         ;;
 807     esac
 808 fi
 809
 810 # Default libgloss CPU subdirectory.
 811 libgloss_dir="$target_cpu"
 812
 813 case "${target}" in
 814   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 815     libgloss_dir=wince
 816     ;;
 817   aarch64*-*-* )
 818     libgloss_dir=aarch64
 819     ;;
 820   arm*-*-*)
 821     libgloss_dir=arm
 822     ;;
 823   cris-*-* | crisv32-*-*)
 824     libgloss_dir=cris
 825     ;;
 826   hppa*-*-*)
 827     libgloss_dir=pa
 828     ;;
 829   i[[3456789]]86-*-*)
 830     libgloss_dir=i386
 831     ;;
 832   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 833     libgloss_dir=m68hc11
 834     ;;
 835   m68*-*-* | fido-*-*)
 836     libgloss_dir=m68k
 837     ;;
 838   mips*-*-*)
 839     libgloss_dir=mips
 840     ;;
 841   powerpc*-*-*)
 842     libgloss_dir=rs6000
 843     ;;
 844   sparc*-*-*)
 845     libgloss_dir=sparc
 846     ;;
 847 esac
 848
 849 # Disable newlib and libgloss for various target OSes.
 850 case "${target}" in
 851   alpha*-dec-osf*)
 852     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 853     ;;
 854   i[[3456789]]86-*-linux*)
 855     # This section makes it possible to build newlib natively on linux.
 856     # If we are using a cross compiler then don't configure newlib.
 857     if test x${is_cross_compiler} != xno ; then
 858       noconfigdirs="$noconfigdirs target-newlib"
 859     fi
 860     noconfigdirs="$noconfigdirs target-libgloss"
 861     # If we are not using a cross compiler, do configure newlib.
 862     # Note however, that newlib will only be configured in this situation
 863     # if the --with-newlib option has been given, because otherwise
 864     # 'target-newlib' will appear in skipdirs.
 865     ;;
 866   i[[3456789]]86-*-rdos*)
 867     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 868     ;;
 869   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 870     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 871     ;;
 872   sparc-*-sunos4*)
 873     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 874     ;;
 875   *-*-aix*)
 876     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 877     ;;
 878   *-*-beos*)
 879     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 880     ;;
 881   *-*-chorusos)
 882     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 883     ;;
 884   *-*-dragonfly*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   *-*-freebsd*)
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 891     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 892     ;;
 893   *-*-lynxos*)
 894     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 895     ;;
 896   *-*-mingw*)
 897     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 898     ;;
 899   *-*-netbsd*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   *-*-netware*)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   *-*-tpf*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   *-*-uclinux*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-vxworks*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914 esac
 915
 916 case "${target}" in
 917   *-*-chorusos)
 918     ;;
 919   aarch64-*-darwin*)
 920     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 921     noconfigdirs="$noconfigdirs sim target-rda"
 922     ;;
 923   arm-*-darwin*)
 924     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 925     noconfigdirs="$noconfigdirs sim target-rda"
 926     ;;
 927   powerpc-*-darwin*)
 928     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 929     noconfigdirs="$noconfigdirs sim target-rda"
 930     ;;
 931   i[[3456789]]86-*-darwin*)
 932     noconfigdirs="$noconfigdirs ld gprof"
 933     noconfigdirs="$noconfigdirs sim target-rda"
 934     ;;
 935   x86_64-*-darwin[[912]]*)
 936     noconfigdirs="$noconfigdirs ld gas gprof"
 937     noconfigdirs="$noconfigdirs sim target-rda"
 938     ;;
 939   *-*-darwin*)
 940     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 941     noconfigdirs="$noconfigdirs sim target-rda"
 942     ;;
 943   *-*-dragonfly*)
 944     ;;
 945   *-*-freebsd*)
 946     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 947         && test -f /usr/local/include/gmp.h; then
 948       with_gmp=/usr/local
 949     fi
 950     ;;
 951   *-*-kaos*)
 952     # Remove unsupported stuff on all kaOS configurations.
 953     noconfigdirs="$noconfigdirs target-libgloss"
 954     ;;
 955   *-*-netbsd*)
 956     ;;
 957   *-*-netware*)
 958     ;;
 959   *-*-phoenix*)
 960     noconfigdirs="$noconfigdirs target-libgloss"
 961     ;;
 962   *-*-rtems*)
 963     noconfigdirs="$noconfigdirs target-libgloss"
 964     ;;
 965     # The tpf target doesn't support gdb yet.
 966   *-*-tpf*)
 967     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 968     ;;
 969   *-*-uclinux*)
 970     noconfigdirs="$noconfigdirs target-rda"
 971     ;;
 972   *-*-vxworks*)
 973     ;;
 974   alpha*-dec-osf*)
 975     # ld works, but does not support shared libraries.
 976     # gas doesn't generate exception information.
 977     noconfigdirs="$noconfigdirs gas ld"
 978     ;;
 979   alpha*-*-*vms*)
 980     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 981     ;;
 982   alpha*-*-*)
 983     # newlib is not 64 bit ready
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 987     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 988     ;;
 989   arc*-*-*)
 990     noconfigdirs="$noconfigdirs sim"
 991     ;;
 992   arm-*-pe*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995   arm-*-riscix*)
 996     noconfigdirs="$noconfigdirs ld target-libgloss"
 997     ;;
 998   avr-*-*)
 999     if test x${with_avrlibc} != xno; then
1000       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1001     fi
1002     ;;
1003   c4x-*-* | tic4x-*-*)
1004     noconfigdirs="$noconfigdirs target-libgloss"
1005     ;;
1006   tic54x-*-*)
1007     noconfigdirs="$noconfigdirs target-libgloss gdb"
1008     ;;
1009   d10v-*-*)
1010     noconfigdirs="$noconfigdirs target-libgloss"
1011     ;;
1012   d30v-*-*)
1013     noconfigdirs="$noconfigdirs gdb"
1014     ;;
1015   fr30-*-elf*)
1016     noconfigdirs="$noconfigdirs gdb"
1017     ;;
1018   ft32-*-*)
1019     noconfigdirs="$noconfigdirs target-rda gprof"
1020     ;;
1021   moxie-*-*)
1022     noconfigdirs="$noconfigdirs"
1023     ;;
1024   h8300*-*-*)
1025     noconfigdirs="$noconfigdirs target-libgloss"
1026     ;;
1027   h8500-*-*)
1028     noconfigdirs="$noconfigdirs target-libgloss"
1029     ;;
1030   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1031     ;;
1032   hppa*64*-*-hpux*)
1033     noconfigdirs="$noconfigdirs gdb"
1034     ;;
1035   hppa*-*-hpux11*)
1036     noconfigdirs="$noconfigdirs gdb ld"
1037     ;;
1038   hppa*64*-*-linux*)
1039     ;;
1040   hppa*-*-linux*)
1041     ;;
1042   hppa*-*-*elf* | \
1043   hppa*-*-lites* | \
1044   hppa*-*-openbsd* | \
1045   hppa*64*-*-*)
1046     ;;
1047   hppa*-*-pro*)
1048     ;;
1049   hppa*-*-*)
1050     noconfigdirs="$noconfigdirs ld"
1051     ;;
1052   i960-*-*)
1053     noconfigdirs="$noconfigdirs gdb"
1054     ;;
1055   ia64*-*-elf*)
1056     # No gdb support yet.
1057     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1058     ;;
1059   ia64*-**-hpux*)
1060     # No ld support yet.
1061     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1062     ;;
1063   ia64*-*-*vms*)
1064     # No ld support yet.
1065     noconfigdirs="$noconfigdirs libgui itcl ld"
1066     ;;
1067   i[[3456789]]86-w64-mingw*)
1068     ;;
1069   i[[3456789]]86-*-mingw*)
1070     target_configdirs="$target_configdirs target-winsup"
1071     ;;
1072   *-*-cygwin*)
1073     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1074     noconfigdirs="$noconfigdirs target-libgloss"
1075     # always build newlib if winsup directory is present.
1076     if test -d "$srcdir/winsup/cygwin"; then
1077       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1078     elif test -d "$srcdir/newlib"; then
1079       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1080     fi
1081     ;;
1082   i[[3456789]]86-*-pe)
1083     noconfigdirs="$noconfigdirs target-libgloss"
1084     ;;
1085   i[[3456789]]86-*-sco3.2v5*)
1086     # The linker does not yet know about weak symbols in COFF,
1087     # and is not configured to handle mixed ELF and COFF.
1088     noconfigdirs="$noconfigdirs ld target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco*)
1091     noconfigdirs="$noconfigdirs gprof target-libgloss"
1092     ;;
1093   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1094     noconfigdirs="$noconfigdirs target-libgloss"
1095     ;;
1096   i[[3456789]]86-*-sysv4*)
1097     noconfigdirs="$noconfigdirs target-libgloss"
1098     ;;
1099   i[[3456789]]86-*-beos*)
1100     noconfigdirs="$noconfigdirs gdb"
1101     ;;
1102   i[[3456789]]86-*-rdos*)
1103     noconfigdirs="$noconfigdirs gdb"
1104     ;;
1105   mmix-*-*)
1106     noconfigdirs="$noconfigdirs gdb"
1107     ;;
1108   mt-*-*)
1109     noconfigdirs="$noconfigdirs sim"
1110     ;;
1111   powerpc-*-aix*)
1112     # copied from rs6000-*-* entry
1113     noconfigdirs="$noconfigdirs gprof"
1114     ;;
1115   powerpc*-*-winnt* | powerpc*-*-pe*)
1116     target_configdirs="$target_configdirs target-winsup"
1117     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1118     # always build newlib.
1119     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1120     ;;
1121     # This is temporary until we can link against shared libraries
1122   powerpcle-*-solaris*)
1123     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1124     ;;
1125   powerpc-*-beos*)
1126     noconfigdirs="$noconfigdirs gdb"
1127     ;;
1128   rs6000-*-lynxos*)
1129     noconfigdirs="$noconfigdirs gprof"
1130     ;;
1131   rs6000-*-aix*)
1132     noconfigdirs="$noconfigdirs gprof"
1133     ;;
1134   rs6000-*-*)
1135     noconfigdirs="$noconfigdirs gprof"
1136     ;;
1137   m68k-apollo-*)
1138     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1139     ;;
1140   microblaze*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1144     if test x$with_newlib = xyes; then
1145       noconfigdirs="$noconfigdirs gprof"
1146     fi
1147     ;;
1148   mips*-*-irix5*)
1149     noconfigdirs="$noconfigdirs gprof target-libgloss"
1150     ;;
1151   mips*-*-irix6*)
1152     noconfigdirs="$noconfigdirs gprof target-libgloss"
1153     ;;
1154   mips*-*-bsd*)
1155     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1156     ;;
1157   mips*-*-linux*)
1158     ;;
1159   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1160   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1161     noconfigdirs="$noconfigdirs ld gas gprof"
1162     ;;
1163   mips*-*-*)
1164     noconfigdirs="$noconfigdirs gprof"
1165     ;;
1166   nvptx*-*-*)
1167     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1168     ;;
1169   sh-*-*)
1170     case "${target}" in
1171       sh*-*-elf)
1172          ;;
1173       *)
1174          noconfigdirs="$noconfigdirs target-libgloss" ;;
1175     esac
1176     ;;
1177   sparc-*-sunos4*)
1178     if test x${is_cross_compiler} = xno ; then
1179            use_gnu_ld=no
1180     fi
1181     ;;
1182   tic6x-*-*)
1183     noconfigdirs="$noconfigdirs sim"
1184     ;;
1185   tilepro*-*-* | tilegx*-*-*)
1186     noconfigdirs="$noconfigdirs sim"
1187     ;;
1188   v810-*-*)
1189     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1190     ;;
1191   vax-*-*)
1192     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1193     ;;
1194   wasm32-*-*)
1195     noconfigdirs="$noconfigdirs ld"
1196     ;;
1197 esac
1198
1199 # If we aren't building newlib, then don't build libgloss, since libgloss
1200 # depends upon some newlib header files.
1201 case "${noconfigdirs}" in
1202   *target-libgloss*) ;;
1203   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1204 esac
1205
1206 # Work in distributions that contain no compiler tools, like Autoconf.
1207 host_makefile_frag=/dev/null
1208 if test -d ${srcdir}/config ; then
1209 case "${host}" in
1210   i[[3456789]]86-*-msdosdjgpp*)
1211     host_makefile_frag="config/mh-djgpp"
1212     ;;
1213   *-cygwin*)
1214     ACX_CHECK_CYGWIN_CAT_WORKS
1215     host_makefile_frag="config/mh-cygwin"
1216     ;;
1217   *-mingw*)
1218     host_makefile_frag="config/mh-mingw"
1219     ;;
1220   alpha*-linux*)
1221     host_makefile_frag="config/mh-alpha-linux"
1222     ;;
1223   hppa*-hp-hpux10*)
1224     host_makefile_frag="config/mh-pa-hpux10"
1225     ;;
1226   hppa*-hp-hpux*)
1227     host_makefile_frag="config/mh-pa"
1228     ;;
1229   hppa*-*)
1230     host_makefile_frag="config/mh-pa"
1231     ;;
1232   *-*-darwin*)
1233     host_makefile_frag="config/mh-darwin"
1234     ;;
1235   powerpc-*-aix*)
1236     host_makefile_frag="config/mh-ppc-aix"
1237     ;;
1238   rs6000-*-aix*)
1239     host_makefile_frag="config/mh-ppc-aix"
1240     ;;
1241 esac
1242 fi
1243
1244 if test "${build}" != "${host}" ; then
1245   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1246   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1247   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1248   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1249   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1250   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1251   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1252   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1253   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1254   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1255   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1256   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1257 else
1258   AR_FOR_BUILD="\$(AR)"
1259   AS_FOR_BUILD="\$(AS)"
1260   CC_FOR_BUILD="\$(CC)"
1261   CXX_FOR_BUILD="\$(CXX)"
1262   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1263   GOC_FOR_BUILD="\$(GOC)"
1264   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1265   LD_FOR_BUILD="\$(LD)"
1266   NM_FOR_BUILD="\$(NM)"
1267   RANLIB_FOR_BUILD="\$(RANLIB)"
1268   WINDRES_FOR_BUILD="\$(WINDRES)"
1269   WINDMC_FOR_BUILD="\$(WINDMC)"
1270 fi
1271
1272 AC_PROG_CC
1273 AC_PROG_CXX
1274
1275 # We must set the default linker to the linker used by gcc for the correct
1276 # operation of libtool.  If LD is not defined and we are using gcc, try to
1277 # set the LD default to the ld used by gcc.
1278 if test -z "$LD"; then
1279   if test "$GCC" = yes; then
1280     case $build in
1281     *-*-mingw*)
1282       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1283     *)
1284       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1285     esac
1286     case $gcc_prog_ld in
1287     # Accept absolute paths.
1288     [[\\/]* | [A-Za-z]:[\\/]*)]
1289       LD="$gcc_prog_ld" ;;
1290     esac
1291   fi
1292 fi
1293
1294 # Check whether -static-libstdc++ -static-libgcc is supported.
1295 have_static_libs=no
1296 if test "$GCC" = yes; then
1297   saved_LDFLAGS="$LDFLAGS"
1298
1299   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1300   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1301   AC_LANG_PUSH(C++)
1302   AC_LINK_IFELSE([
1303 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1304 #error -static-libstdc++ not implemented
1305 #endif
1306 int main() {}],
1307     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1308     [AC_MSG_RESULT([no])])
1309   AC_LANG_POP(C++)
1310
1311   LDFLAGS="$saved_LDFLAGS"
1312 fi
1313
1314 ACX_PROG_GNAT
1315 ACX_PROG_CMP_IGNORE_INITIAL
1316
1317 AC_ARG_ENABLE([bootstrap],
1318 [AS_HELP_STRING([--enable-bootstrap],
1319                 [enable bootstrapping @<:@yes if native build@:>@])],,
1320 enable_bootstrap=default)
1321
1322 # Issue errors and warnings for invalid/strange bootstrap combinations.
1323 if test -r $srcdir/gcc/configure; then
1324   have_compiler=yes
1325 else
1326   have_compiler=no
1327 fi
1328
1329 case "$have_compiler:$host:$target:$enable_bootstrap" in
1330   *:*:*:no) ;;
1331
1332   # Default behavior.  Enable bootstrap if we have a compiler
1333   # and we are in a native configuration.
1334   yes:$build:$build:default)
1335     enable_bootstrap=yes ;;
1336
1337   *:*:*:default)
1338     enable_bootstrap=no ;;
1339
1340   # We have a compiler and we are in a native configuration, bootstrap is ok
1341   yes:$build:$build:yes)
1342     ;;
1343
1344   # Other configurations, but we have a compiler.  Assume the user knows
1345   # what he's doing.
1346   yes:*:*:yes)
1347     AC_MSG_WARN([trying to bootstrap a cross compiler])
1348     ;;
1349
1350   # No compiler: if they passed --enable-bootstrap explicitly, fail
1351   no:*:*:yes)
1352     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1353
1354   # Fail if wrong command line
1355   *)
1356     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1357     ;;
1358 esac
1359
1360 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1361 # C++98 compiler can still start the bootstrap.
1362 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1363   CXX="$CXX -std=gnu++98"
1364 fi
1365
1366 # Used for setting $lt_cv_objdir
1367 _LT_CHECK_OBJDIR
1368
1369 # Check for GMP, MPFR and MPC
1370 gmplibs="-lmpc -lmpfr -lgmp"
1371 gmpinc=
1372 have_gmp=no
1373
1374 # Specify a location for mpc
1375 # check for this first so it ends up on the link line before mpfr.
1376 AC_ARG_WITH(mpc,
1377 [AS_HELP_STRING([--with-mpc=PATH],
1378                 [specify prefix directory for installed MPC package.
1379                  Equivalent to --with-mpc-include=PATH/include
1380                  plus --with-mpc-lib=PATH/lib])])
1381 AC_ARG_WITH(mpc-include,
1382 [AS_HELP_STRING([--with-mpc-include=PATH],
1383                 [specify directory for installed MPC include files])])
1384 AC_ARG_WITH(mpc-lib,
1385 [AS_HELP_STRING([--with-mpc-lib=PATH],
1386                 [specify directory for the installed MPC library])])
1387
1388 if test "x$with_mpc" != x; then
1389   gmplibs="-L$with_mpc/lib $gmplibs"
1390   gmpinc="-I$with_mpc/include $gmpinc"
1391 fi
1392 if test "x$with_mpc_include" != x; then
1393   gmpinc="-I$with_mpc_include $gmpinc"
1394 fi
1395 if test "x$with_mpc_lib" != x; then
1396   gmplibs="-L$with_mpc_lib $gmplibs"
1397 fi
1398 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1399   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1400   gmpinc='-I$$s/mpc/src '"$gmpinc"
1401   # Do not test the mpc version.  Assume that it is sufficient, since
1402   # it is in the source tree, and the library has not been built yet
1403   # but it would be included on the link line in the version check below
1404   # hence making the test fail.
1405   have_gmp=yes
1406 fi
1407
1408 # Specify a location for mpfr
1409 # check for this first so it ends up on the link line before gmp.
1410 AC_ARG_WITH(mpfr-dir,
1411 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1412 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1413 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1414
1415 AC_ARG_WITH(mpfr,
1416 [AS_HELP_STRING([--with-mpfr=PATH],
1417                 [specify prefix directory for installed MPFR package.
1418                  Equivalent to --with-mpfr-include=PATH/include
1419                  plus --with-mpfr-lib=PATH/lib])])
1420 AC_ARG_WITH(mpfr-include,
1421 [AS_HELP_STRING([--with-mpfr-include=PATH],
1422                 [specify directory for installed MPFR include files])])
1423 AC_ARG_WITH(mpfr-lib,
1424 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1425                 [specify directory for the installed MPFR library])])
1426
1427 if test "x$with_mpfr" != x; then
1428   gmplibs="-L$with_mpfr/lib $gmplibs"
1429   gmpinc="-I$with_mpfr/include $gmpinc"
1430 fi
1431 if test "x$with_mpfr_include" != x; then
1432   gmpinc="-I$with_mpfr_include $gmpinc"
1433 fi
1434 if test "x$with_mpfr_lib" != x; then
1435   gmplibs="-L$with_mpfr_lib $gmplibs"
1436 fi
1437 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1438   # MPFR v3.1.0 moved the sources into a src sub-directory.
1439   if ! test -d ${srcdir}/mpfr/src; then
1440     AC_MSG_ERROR([dnl
1441 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1442   fi
1443   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1444   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1445   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1446   # Do not test the mpfr version.  Assume that it is sufficient, since
1447   # it is in the source tree, and the library has not been built yet
1448   # but it would be included on the link line in the version check below
1449   # hence making the test fail.
1450   have_gmp=yes
1451 fi
1452
1453 # Specify a location for gmp
1454 AC_ARG_WITH(gmp-dir,
1455 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1456 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1457 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1458
1459 AC_ARG_WITH(gmp,
1460 [AS_HELP_STRING([--with-gmp=PATH],
1461                 [specify prefix directory for the installed GMP package.
1462                  Equivalent to --with-gmp-include=PATH/include
1463                  plus --with-gmp-lib=PATH/lib])])
1464 AC_ARG_WITH(gmp-include,
1465 [AS_HELP_STRING([--with-gmp-include=PATH],
1466                 [specify directory for installed GMP include files])])
1467 AC_ARG_WITH(gmp-lib,
1468 [AS_HELP_STRING([--with-gmp-lib=PATH],
1469                 [specify directory for the installed GMP library])])
1470
1471
1472 if test "x$with_gmp" != x; then
1473   gmplibs="-L$with_gmp/lib $gmplibs"
1474   gmpinc="-I$with_gmp/include $gmpinc"
1475 fi
1476 if test "x$with_gmp_include" != x; then
1477   gmpinc="-I$with_gmp_include $gmpinc"
1478 fi
1479 if test "x$with_gmp_lib" != x; then
1480   gmplibs="-L$with_gmp_lib $gmplibs"
1481 fi
1482 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1483   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1484   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1485   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1486   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1487   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1488   # Do not test the gmp version.  Assume that it is sufficient, since
1489   # it is in the source tree, and the library has not been built yet
1490   # but it would be included on the link line in the version check below
1491   # hence making the test fail.
1492   have_gmp=yes
1493 fi
1494
1495 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1496   have_gmp=yes
1497   saved_CFLAGS="$CFLAGS"
1498   CFLAGS="$CFLAGS $gmpinc"
1499   # Check for the recommended and required versions of GMP.
1500   AC_MSG_CHECKING([for the correct version of gmp.h])
1501   AC_TRY_COMPILE([#include "gmp.h"],[
1502   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1503   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1504   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1505   choke me
1506   #endif
1507   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1508   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1509   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1510   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1511   choke me
1512   #endif
1513   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1514    [AC_MSG_RESULT([no]); have_gmp=no])
1515
1516   # If we have GMP, check the MPFR version.
1517   if test x"$have_gmp" = xyes; then
1518     # Check for the recommended and required versions of MPFR.
1519     AC_MSG_CHECKING([for the correct version of mpfr.h])
1520     AC_TRY_COMPILE([#include <gmp.h>
1521     #include <mpfr.h>],[
1522     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1523     choke me
1524     #endif
1525     ], [AC_TRY_COMPILE([#include <gmp.h>
1526     #include <mpfr.h>],[
1527     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1528     choke me
1529     #endif
1530     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1531      [AC_MSG_RESULT([no]); have_gmp=no])
1532   fi
1533
1534   # Check for the MPC header version.
1535   if test x"$have_gmp" = xyes ; then
1536     # Check for the recommended and required versions of MPC.
1537     AC_MSG_CHECKING([for the correct version of mpc.h])
1538     AC_TRY_COMPILE([#include <mpc.h>],[
1539     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1540     choke me
1541     #endif
1542     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1543     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1544     choke me
1545     #endif
1546     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1547      [AC_MSG_RESULT([no]); have_gmp=no])
1548   fi
1549
1550   # Now check the MPFR library.
1551   if test x"$have_gmp" = xyes; then
1552     saved_LIBS="$LIBS"
1553     LIBS="$LIBS $gmplibs"
1554     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1555     AC_TRY_LINK([#include <mpc.h>],[
1556     mpfr_t n;
1557     mpfr_t x;
1558     mpc_t c;
1559     int t;
1560     mpfr_init (n);
1561     mpfr_init (x);
1562     mpfr_atan2 (n, n, x, GMP_RNDN);
1563     mpfr_erfc (n, x, GMP_RNDN);
1564     mpfr_subnormalize (x, t, GMP_RNDN);
1565     mpfr_clear(n);
1566     mpfr_clear(x);
1567     mpc_init2 (c, 53);
1568     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1569     mpc_cosh (c, c, MPC_RNDNN);
1570     mpc_pow (c, c, c, MPC_RNDNN);
1571     mpc_acosh (c, c, MPC_RNDNN);
1572     mpc_clear (c);
1573     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1574     LIBS="$saved_LIBS"
1575   fi
1576
1577   CFLAGS="$saved_CFLAGS"
1578
1579 # The library versions listed in the error message below should match
1580 # the HARD-minimums enforced above.
1581   if test x$have_gmp != xyes; then
1582     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1583 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1584 their locations.  Source code for these libraries can be found at
1585 their respective hosting sites as well as at
1586 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1587 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1588 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1589 make sure that you have installed both the libraries and the header
1590 files.  They may be located in separate packages.])
1591   fi
1592 fi
1593
1594 # Flags needed for both GMP, MPFR and/or MPC.
1595 AC_SUBST(gmplibs)
1596 AC_SUBST(gmpinc)
1597 AC_SUBST(extra_mpfr_configure_flags)
1598 AC_SUBST(extra_mpc_gmp_configure_flags)
1599 AC_SUBST(extra_mpc_mpfr_configure_flags)
1600 AC_SUBST(extra_isl_gmp_configure_flags)
1601
1602 # Libraries to use for stage1 or when not bootstrapping.
1603 AC_ARG_WITH(stage1-libs,
1604 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1605 [if test "$withval" = "no" -o "$withval" = "yes"; then
1606    stage1_libs=
1607  else
1608    stage1_libs=$withval
1609  fi],
1610 [stage1_libs=])
1611 AC_SUBST(stage1_libs)
1612
1613 # Linker flags to use for stage1 or when not bootstrapping.
1614 AC_ARG_WITH(stage1-ldflags,
1615 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1616 [if test "$withval" = "no" -o "$withval" = "yes"; then
1617    stage1_ldflags=
1618  else
1619    stage1_ldflags=$withval
1620  fi],
1621 [stage1_ldflags=
1622  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1623  # if supported.  But if the user explicitly specified the libraries to use,
1624  # trust that they are doing what they want.
1625  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1626    stage1_ldflags="-static-libstdc++ -static-libgcc"
1627  fi])
1628 AC_SUBST(stage1_ldflags)
1629
1630 # Libraries to use for stage2 and later builds.
1631 AC_ARG_WITH(boot-libs,
1632 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1633 [if test "$withval" = "no" -o "$withval" = "yes"; then
1634    poststage1_libs=
1635  else
1636    poststage1_libs=$withval
1637  fi],
1638 [poststage1_libs=])
1639 AC_SUBST(poststage1_libs)
1640
1641 # Linker flags to use for stage2 and later builds.
1642 AC_ARG_WITH(boot-ldflags,
1643 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1644                 [linker flags for stage2 and later])],
1645 [if test "$withval" = "no" -o "$withval" = "yes"; then
1646    poststage1_ldflags=
1647  else
1648    poststage1_ldflags=$withval
1649  fi],
1650 [poststage1_ldflags=
1651  # In stages 2 and 3, default to linking libstdc++ and libgcc
1652  # statically.  But if the user explicitly specified the libraries to
1653  # use, trust that they are doing what they want.
1654  if test "$poststage1_libs" = ""; then
1655    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1656  fi])
1657 AC_SUBST(poststage1_ldflags)
1658
1659 # GCC GRAPHITE dependency isl.
1660 # Basic setup is inlined here, actual checks are in config/isl.m4
1661
1662 AC_ARG_WITH(isl,
1663   [AS_HELP_STRING(
1664    [--with-isl=PATH],
1665    [Specify prefix directory for the installed isl package.
1666     Equivalent to --with-isl-include=PATH/include
1667     plus --with-isl-lib=PATH/lib])])
1668
1669 # Treat --without-isl as a request to disable
1670 # GRAPHITE support and skip all following checks.
1671 if test "x$with_isl" != "xno"; then
1672   # Check for isl
1673   dnl Provide configure switches and initialize islinc & isllibs
1674   dnl with user input.
1675   ISL_INIT_FLAGS
1676   dnl The versions of isl that work for Graphite
1677   ISL_CHECK_VERSION()
1678   dnl Only execute fail-action, if isl has been requested.
1679   ISL_IF_FAILED([
1680     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1681 fi
1682
1683 # If the isl check failed, disable builds of in-tree variant of isl
1684 if test "x$with_isl" = xno ||
1685    test "x$gcc_cv_isl" = xno; then
1686   noconfigdirs="$noconfigdirs isl"
1687   islinc=
1688 fi
1689
1690 AC_SUBST(isllibs)
1691 AC_SUBST(islinc)
1692
1693 # Check for LTO support.
1694 AC_ARG_ENABLE(lto,
1695 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1696 enable_lto=$enableval,
1697 enable_lto=yes; default_enable_lto=yes)
1698
1699 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1700   build_lto_plugin=yes
1701 ],[if test x"$default_enable_lto" = x"yes" ; then
1702     case $target in
1703       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1704       # On other non-ELF platforms, LTO has yet to be validated.
1705       *) enable_lto=no ;;
1706     esac
1707   else
1708   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1709   # It would also be nice to check the binutils support, but we don't
1710   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1711   # warn during gcc/ subconfigure; unless you're bootstrapping with
1712   # -flto it won't be needed until after installation anyway.
1713     case $target in
1714       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1715       *) if test x"$enable_lto" = x"yes"; then
1716         AC_MSG_ERROR([LTO support is not enabled for this target.])
1717         fi
1718       ;;
1719     esac
1720   fi
1721   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1722   # Build it unless LTO was explicitly disabled.
1723   case $target in
1724     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1725     *) ;;
1726   esac
1727 ])
1728
1729 AC_ARG_ENABLE(linker-plugin-configure-flags,
1730   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1731     [additional flags for configuring linker plugins @<:@none@:>@])],
1732   extra_linker_plugin_configure_flags=$enableval,
1733   extra_linker_plugin_configure_flags=)
1734 AC_SUBST(extra_linker_plugin_configure_flags)
1735 AC_ARG_ENABLE(linker-plugin-flags,
1736   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1737     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1738   extra_linker_plugin_flags=$enableval,
1739   extra_linker_plugin_flags=)
1740 AC_SUBST(extra_linker_plugin_flags)
1741
1742 # Enable --enable-host-shared.
1743 # Checked early to determine whether jit is an 'all' language
1744 AC_ARG_ENABLE(host-shared,
1745 [AS_HELP_STRING([--enable-host-shared],
1746                 [build host code as shared libraries])],
1747 [host_shared=$enableval], [host_shared=no])
1748 AC_SUBST(host_shared)
1749
1750 # By default, C and C++ are the only stage 1 languages.
1751 stage1_languages=,c,
1752
1753 # Target libraries that we bootstrap.
1754 bootstrap_target_libs=,target-libgcc,
1755
1756 # Figure out what language subdirectories are present.
1757 # Look if the user specified --enable-languages="..."; if not, use
1758 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1759 # go away some day.
1760 # NB:  embedded tabs in this IF block -- do not untabify
1761 if test -d ${srcdir}/gcc; then
1762   if test x"${enable_languages+set}" != xset; then
1763     if test x"${LANGUAGES+set}" = xset; then
1764       enable_languages="${LANGUAGES}"
1765         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1766     else
1767       enable_languages=default
1768     fi
1769   else
1770     if test x"${enable_languages}" = x ||
1771        test x"${enable_languages}" = xyes;
1772        then
1773       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1774       exit 1
1775     fi
1776   fi
1777   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1778
1779   # 'f95' is the old name for the 'fortran' language. We issue a warning
1780   # and make the substitution.
1781   case ,${enable_languages}, in
1782     *,f95,*)
1783       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1784       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1785       ;;
1786   esac
1787
1788   # If bootstrapping, C++ must be enabled.
1789   case ",$enable_languages,:$enable_bootstrap" in
1790     *,c++,*:*) ;;
1791     *:yes)
1792       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1793         enable_languages="${enable_languages},c++"
1794       else
1795         AC_MSG_ERROR([bootstrapping requires c++ sources])
1796       fi
1797       ;;
1798   esac
1799
1800   # First scan to see if an enabled language requires some other language.
1801   # We assume that a given config-lang.in will list all the language
1802   # front ends it requires, even if some are required indirectly.
1803   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1804     case ${lang_frag} in
1805       ..) ;;
1806       # The odd quoting in the next line works around
1807       # an apparent bug in bash 1.12 on linux.
1808       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1809       *)
1810         # From the config-lang.in, get $language, $lang_requires, and
1811         # $lang_requires_boot_languages.
1812         language=
1813         lang_requires=
1814         lang_requires_boot_languages=
1815         # set srcdir during sourcing lang_frag to the gcc dir.
1816         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1817         # polutes this shell
1818         saved_srcdir=${srcdir}
1819         srcdir=${srcdir}/gcc . ${lang_frag}
1820         srcdir=${saved_srcdir}
1821         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1822           case ,${enable_languages}, in
1823             *,$other,*) ;;
1824             *,default,*) ;;
1825             *,all,*) ;;
1826             *,$language,*)
1827               echo " \`$other' language required by \`$language'; enabling" 1>&2
1828               enable_languages="${enable_languages},${other}"
1829               ;;
1830           esac
1831         done
1832         for other in ${lang_requires_boot_languages} ; do
1833           if test "$other" != "c"; then
1834             case ,${enable_stage1_languages}, in
1835               *,$other,*) ;;
1836               *,default,*) ;;
1837               *,all,*) ;;
1838               *)
1839                 case ,${enable_languages}, in
1840                   *,$language,*)
1841                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1842                     enable_stage1_languages="$enable_stage1_languages,${other}"
1843                     ;;
1844                 esac
1845                 ;;
1846             esac
1847           fi
1848         done
1849         ;;
1850     esac
1851   done
1852
1853   new_enable_languages=,c,
1854
1855   # If LTO is enabled, add the LTO front end.
1856   if test "$enable_lto" = "yes" ; then
1857     case ,${enable_languages}, in
1858       *,lto,*) ;;
1859       *) enable_languages="${enable_languages},lto" ;;
1860     esac
1861     if test "${build_lto_plugin}" = "yes" ; then
1862       configdirs="$configdirs lto-plugin"
1863     fi
1864   fi
1865
1866   # If we're building an offloading compiler, add the LTO front end.
1867   if test x"$enable_as_accelerator_for" != x ; then
1868     case ,${enable_languages}, in
1869       *,lto,*) ;;
1870       *) enable_languages="${enable_languages},lto" ;;
1871     esac
1872   fi
1873
1874   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1875   potential_languages=,c,
1876
1877   enabled_target_libs=
1878   disabled_target_libs=
1879
1880   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1881     case ${lang_frag} in
1882       ..) ;;
1883       # The odd quoting in the next line works around
1884       # an apparent bug in bash 1.12 on linux.
1885       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1886       *)
1887         # From the config-lang.in, get $language, $target_libs,
1888         # $lang_dirs, $boot_language, and $build_by_default
1889         language=
1890         target_libs=
1891         lang_dirs=
1892         subdir_requires=
1893         boot_language=no
1894         build_by_default=yes
1895         # set srcdir during sourcing.  See above about save & restore
1896         saved_srcdir=${srcdir}
1897         srcdir=${srcdir}/gcc . ${lang_frag}
1898         srcdir=${saved_srcdir}
1899         if test x${language} = x; then
1900           echo "${lang_frag} doesn't set \$language." 1>&2
1901           exit 1
1902         fi
1903
1904         if test "$language" = "c++"; then
1905           boot_language=yes
1906         fi
1907
1908         add_this_lang=no
1909         # C is always enabled, so no need to add it again
1910         if test "$language" != "c"; then
1911           case ,${enable_languages}, in
1912             *,${language},*)
1913               # Language was explicitly selected; include it
1914               add_this_lang=yes
1915               ;;
1916             *,all,*)
1917               # All languages are enabled
1918               add_this_lang=all
1919               ;;
1920             *,default,*)
1921               # 'default' was selected, select it if it is a default language
1922               add_this_lang=${build_by_default}
1923               ;;
1924           esac
1925         fi
1926
1927         # Disable languages that need other directories if these aren't available.
1928         for i in $subdir_requires; do
1929           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1930           case ${add_this_lang} in
1931             yes)
1932               # Specifically requested language; tell them.
1933               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1934               ;;
1935             all)
1936               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1937               add_this_lang=unsupported
1938               ;;
1939             *)
1940               # Silently disable.
1941               add_this_lang=unsupported
1942               ;;
1943           esac
1944         done
1945
1946         # Disable Ada if no preexisting GNAT is available.
1947         case ${add_this_lang}:${language}:${have_gnat} in
1948           yes:ada:no)
1949             # Specifically requested language; tell them.
1950             AC_MSG_ERROR([GNAT is required to build $language])
1951             ;;
1952           all:ada:no)
1953             AC_MSG_WARN([GNAT is required to build $language])
1954             add_this_lang=unsupported
1955             ;;
1956           *:ada:no)
1957             # Silently disable.
1958             add_this_lang=unsupported
1959             ;;
1960         esac
1961
1962         # Disable jit if -enable-host-shared not specified
1963         case ${add_this_lang}:${language}:${host_shared} in
1964           yes:jit:no)
1965             # PR jit/64780: explicitly specify --enable-host-shared
1966             AC_MSG_ERROR([
1967 Enabling language "jit" requires --enable-host-shared.
1968
1969 --enable-host-shared typically slows the rest of the compiler down by
1970 a few %, so you must explicitly enable it.
1971
1972 If you want to build both the jit and the regular compiler, it is often
1973 best to do this via two separate configure/builds, in separate
1974 directories, to avoid imposing the performance cost of
1975 --enable-host-shared on the regular compiler.])
1976             ;;
1977           all:jit:no)
1978             AC_MSG_WARN([--enable-host-shared required to build $language])
1979             add_this_lang=unsupported
1980             ;;
1981           *:jit:no)
1982             # Silently disable.
1983             add_this_lang=unsupported
1984             ;;
1985         esac
1986
1987         # Disable a language that is unsupported by the target.
1988         case "${add_this_lang}: $unsupported_languages " in
1989           no:*) ;;
1990           unsupported:*) ;;
1991           *:*" $language "*)
1992             AC_MSG_WARN([${language} not supported for this target])
1993             add_this_lang=unsupported
1994             ;;
1995         esac
1996
1997         case $add_this_lang in
1998           unsupported)
1999             # Remove language-dependent dirs.
2000             disabled_target_libs="$disabled_target_libs $target_libs"
2001             noconfigdirs="$noconfigdirs $lang_dirs"
2002             ;;
2003           no)
2004             # Remove language-dependent dirs; still show language as supported.
2005             disabled_target_libs="$disabled_target_libs $target_libs"
2006             noconfigdirs="$noconfigdirs $lang_dirs"
2007             potential_languages="${potential_languages}${language},"
2008             ;;
2009           all|yes)
2010             new_enable_languages="${new_enable_languages}${language},"
2011             potential_languages="${potential_languages}${language},"
2012             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2013             enabled_target_libs="$enabled_target_libs $target_libs"
2014             case "${boot_language}:,$enable_stage1_languages," in
2015               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2016                 # Add to (comma-separated) list of stage 1 languages.
2017                 case ",$stage1_languages," in
2018                   *,$language,* | ,yes, | ,all,) ;;
2019                   *) stage1_languages="${stage1_languages}${language}," ;;
2020                 esac
2021                 # We need to bootstrap any supporting libraries.
2022                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2023                 ;;
2024             esac
2025             ;;
2026         esac
2027         ;;
2028     esac
2029   done
2030
2031   # Add target libraries which are only needed for disabled languages
2032   # to noconfigdirs.
2033   if test -n "$disabled_target_libs"; then
2034     for dir in $disabled_target_libs; do
2035       case " $enabled_target_libs " in
2036       *" ${dir} "*) ;;
2037       *) noconfigdirs="$noconfigdirs $dir" ;;
2038       esac
2039     done
2040   fi
2041
2042   AC_ARG_ENABLE(stage1-languages,
2043   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2044                   [choose additional languages to build during
2045                   stage1.  Mostly useful for compiler development])],
2046   [case ,${enable_stage1_languages}, in
2047     ,no,|,,)
2048       # Set it to something that will have no effect in the loop below
2049       enable_stage1_languages=c ;;
2050     ,yes,)
2051       enable_stage1_languages=`echo $new_enable_languages | \
2052         sed -e "s/^,//" -e "s/,$//" ` ;;
2053     *,all,*)
2054       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2055         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2056   esac
2057
2058   # Add "good" languages from enable_stage1_languages to stage1_languages,
2059   # while "bad" languages go in missing_languages.  Leave no duplicates.
2060   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2061     case $potential_languages in
2062       *,$i,*)
2063         case $stage1_languages in
2064           *,$i,*) ;;
2065           *) stage1_languages="$stage1_languages$i," ;;
2066         esac ;;
2067       *)
2068         case $missing_languages in
2069           *,$i,*) ;;
2070           *) missing_languages="$missing_languages$i," ;;
2071         esac ;;
2072      esac
2073   done])
2074
2075   # Remove leading/trailing commas that were added for simplicity
2076   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2077   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2078   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2079   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2080
2081   if test "x$missing_languages" != x; then
2082     AC_MSG_ERROR([
2083 The following requested languages could not be built: ${missing_languages}
2084 Supported languages are: ${potential_languages}])
2085   fi
2086   if test "x$new_enable_languages" != "x$enable_languages"; then
2087     echo The following languages will be built: ${new_enable_languages}
2088     enable_languages="$new_enable_languages"
2089   fi
2090
2091   AC_SUBST(stage1_languages)
2092   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2093 fi
2094
2095 # Handle --disable-<component> generically.
2096 for dir in $configdirs $build_configdirs $target_configdirs ; do
2097   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2098   varname=`echo $dirname | sed -e s/+/_/g`
2099   if eval test x\${enable_${varname}} "=" xno ; then
2100     noconfigdirs="$noconfigdirs $dir"
2101   fi
2102 done
2103
2104 # Check for Boehm's garbage collector
2105 AC_ARG_ENABLE(objc-gc,
2106 [AS_HELP_STRING([--enable-objc-gc],
2107                 [enable use of Boehm's garbage collector with the
2108                  GNU Objective-C runtime])])
2109 AC_ARG_WITH([target-bdw-gc],
2110 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2111                 [specify prefix directory for installed bdw-gc package.
2112                  Equivalent to --with-target-bdw-gc-include=PATH/include
2113                  plus --with-target-bdw-gc-lib=PATH/lib])])
2114 AC_ARG_WITH([target-bdw-gc-include],
2115 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2116                 [specify directories for installed bdw-gc include files])])
2117 AC_ARG_WITH([target-bdw-gc-lib],
2118 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2119                 [specify directories for installed bdw-gc library])])
2120
2121 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2122   AC_MSG_CHECKING([for bdw garbage collector])
2123   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2124     dnl no bdw-gw options, assume default locations
2125     AC_MSG_RESULT([using bdw-gc in default locations])
2126   else
2127     dnl bdw-gw options, first error checking, complete checking in libobjc
2128     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2129       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2130     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2131       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2132     else
2133       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2134     fi
2135   fi
2136 esac
2137
2138 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2139 case ,${enable_languages}, in
2140   *,c++,*)
2141     # Disable libitm, libsanitizer if we're not building libstdc++
2142     case "${noconfigdirs}" in
2143       *target-libstdc++-v3*)
2144         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2145         ;;
2146       *) ;;
2147     esac
2148     ;;
2149   *)
2150     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2151     ;;
2152 esac
2153
2154 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2155 # $build_configdirs and $target_configdirs.
2156 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2157
2158 notsupp=""
2159 for dir in . $skipdirs $noconfigdirs ; do
2160   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2161   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2162     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2163     if test -r $srcdir/$dirname/configure ; then
2164       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2165         true
2166       else
2167         notsupp="$notsupp $dir"
2168       fi
2169     fi
2170   fi
2171   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2172     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2173     if test -r $srcdir/$dirname/configure ; then
2174       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2175         true
2176       else
2177         notsupp="$notsupp $dir"
2178       fi
2179     fi
2180   fi
2181   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2182     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2183     if test -r $srcdir/$dirname/configure ; then
2184       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2185         true
2186       else
2187         notsupp="$notsupp $dir"
2188       fi
2189     fi
2190   fi
2191 done
2192
2193 # Quietly strip out all directories which aren't configurable in this tree.
2194 # This relies on all configurable subdirectories being autoconfiscated, which
2195 # is now the case.
2196 build_configdirs_all="$build_configdirs"
2197 build_configdirs=
2198 for i in ${build_configdirs_all} ; do
2199   j=`echo $i | sed -e s/build-//g`
2200   if test -f ${srcdir}/$j/configure ; then
2201     build_configdirs="${build_configdirs} $i"
2202   fi
2203 done
2204
2205 configdirs_all="$configdirs"
2206 configdirs=
2207 for i in ${configdirs_all} ; do
2208   if test -f ${srcdir}/$i/configure ; then
2209     configdirs="${configdirs} $i"
2210   fi
2211 done
2212
2213 target_configdirs_all="$target_configdirs"
2214 target_configdirs=
2215 for i in ${target_configdirs_all} ; do
2216   j=`echo $i | sed -e s/target-//g`
2217   if test -f ${srcdir}/$j/configure ; then
2218     target_configdirs="${target_configdirs} $i"
2219   fi
2220 done
2221
2222 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2223 # so we have to add it after the preceding checks.
2224 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2225 then
2226   case " $configdirs " in
2227     *" libiberty "*)
2228       # If we can build libiberty, we can also build libiberty-linker-plugin.
2229       configdirs="$configdirs libiberty-linker-plugin"
2230       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2231         --with-libiberty=../libiberty-linker-plugin";;
2232     *)
2233       AC_MSG_ERROR([libiberty missing]);;
2234   esac
2235 fi
2236
2237 # Sometimes we have special requirements for the host libiberty.
2238 extra_host_libiberty_configure_flags=
2239 extra_host_zlib_configure_flags=
2240 case " $configdirs " in
2241   *" lto-plugin "* | *" libcc1 "*)
2242     # When these are to be built as shared libraries, the same applies to
2243     # libiberty.
2244     extra_host_libiberty_configure_flags=--enable-shared
2245     ;;
2246   *" bfd "*)
2247     # When bfd is to be built as a shared library, the same applies to
2248     # zlib.
2249     if test "$enable_shared" = "yes"; then
2250       extra_host_zlib_configure_flags=--enable-host-shared
2251     fi
2252     ;;
2253 esac
2254 AC_SUBST(extra_host_libiberty_configure_flags)
2255 AC_SUBST(extra_host_zlib_configure_flags)
2256
2257 # Produce a warning message for the subdirs we can't configure.
2258 # This isn't especially interesting in the Cygnus tree, but in the individual
2259 # FSF releases, it's important to let people know when their machine isn't
2260 # supported by the one or two programs in a package.
2261
2262 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2263   # If $appdirs is non-empty, at least one of those directories must still
2264   # be configured, or we error out.  (E.g., if the gas release supports a
2265   # specified target in some subdirs but not the gas subdir, we shouldn't
2266   # pretend that all is well.)
2267   if test -n "$appdirs" ; then
2268     for dir in $appdirs ; do
2269       if test -r $dir/Makefile.in ; then
2270         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2271           appdirs=""
2272           break
2273         fi
2274         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2275           appdirs=""
2276           break
2277         fi
2278       fi
2279     done
2280     if test -n "$appdirs" ; then
2281       echo "*** This configuration is not supported by this package." 1>&2
2282       exit 1
2283     fi
2284   fi
2285   # Okay, some application will build, or we don't care to check.  Still
2286   # notify of subdirs not getting built.
2287   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2288   echo "    ${notsupp}" 1>&2
2289   echo "    (Any other directories should still work fine.)" 1>&2
2290 fi
2291
2292 case "$host" in
2293   *msdosdjgpp*)
2294     enable_gdbtk=no ;;
2295 esac
2296
2297 # To find our prefix, in gcc_cv_tool_prefix.
2298 ACX_TOOL_DIRS
2299
2300 copy_dirs=
2301
2302 AC_ARG_WITH([build-sysroot],
2303   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2304                   [use sysroot as the system root during the build])],
2305   [if test x"$withval" != x ; then
2306      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2307    fi],
2308   [SYSROOT_CFLAGS_FOR_TARGET=])
2309 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2310
2311 AC_ARG_WITH([debug-prefix-map],
2312   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2313                   [map A to B, C to D ... in debug information])],
2314   [if test x"$withval" != x; then
2315      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2316      for debug_map in $withval; do
2317        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2318      done
2319    fi],
2320   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2321 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2322
2323 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2324 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2325 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2326 # We want to ensure that TARGET libraries (which we know are built with
2327 # gcc) are built with "-O2 -g", so include those options when setting
2328 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2329 if test "x$CFLAGS_FOR_TARGET" = x; then
2330   if test "x${is_cross_compiler}" = xyes; then
2331     CFLAGS_FOR_TARGET="-g -O2"
2332   else
2333     CFLAGS_FOR_TARGET=$CFLAGS
2334     case " $CFLAGS " in
2335       *" -O2 "*) ;;
2336       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2337     esac
2338     case " $CFLAGS " in
2339       *" -g "* | *" -g3 "*) ;;
2340       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2341     esac
2342   fi
2343 fi
2344 AC_SUBST(CFLAGS_FOR_TARGET)
2345
2346 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2347   if test "x${is_cross_compiler}" = xyes; then
2348     CXXFLAGS_FOR_TARGET="-g -O2"
2349   else
2350     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2351     case " $CXXFLAGS " in
2352       *" -O2 "*) ;;
2353       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2354     esac
2355     case " $CXXFLAGS " in
2356       *" -g "* | *" -g3 "*) ;;
2357       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2358     esac
2359   fi
2360 fi
2361 AC_SUBST(CXXFLAGS_FOR_TARGET)
2362
2363 AC_SUBST(LDFLAGS_FOR_TARGET)
2364
2365 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2366 # the named directory are copied to $(tooldir)/sys-include.
2367 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2368   if test x${is_cross_compiler} = xno ; then
2369     echo 1>&2 '***' --with-headers is only supported when cross compiling
2370     exit 1
2371   fi
2372   if test x"${with_headers}" != xyes ; then
2373     x=${gcc_cv_tool_prefix}
2374     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2375   fi
2376 fi
2377
2378 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2379 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2380 # are permitted.
2381 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2382   if test x${is_cross_compiler} = xno ; then
2383     echo 1>&2 '***' --with-libs is only supported when cross compiling
2384     exit 1
2385   fi
2386   if test x"${with_libs}" != xyes ; then
2387     # Copy the libraries in reverse order, so that files in the first named
2388     # library override files in subsequent libraries.
2389     x=${gcc_cv_tool_prefix}
2390     for l in ${with_libs}; do
2391       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2392     done
2393   fi
2394 fi
2395
2396 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2397 #
2398 # This is done by determining whether or not the appropriate directory
2399 # is available, and by checking whether or not specific configurations
2400 # have requested that this magic not happen.
2401 #
2402 # The command line options always override the explicit settings in
2403 # configure.ac, and the settings in configure.ac override this magic.
2404 #
2405 # If the default for a toolchain is to use GNU as and ld, and you don't
2406 # want to do that, then you should use the --without-gnu-as and
2407 # --without-gnu-ld options for the configure script.  Similarly, if
2408 # the default is to use the included zlib and you don't want to do that,
2409 # you should use the --with-system-zlib option for the configure script.
2410
2411 if test x${use_gnu_as} = x &&
2412    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2413   with_gnu_as=yes
2414   extra_host_args="$extra_host_args --with-gnu-as"
2415 fi
2416
2417 if test x${use_gnu_ld} = x &&
2418    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2419   with_gnu_ld=yes
2420   extra_host_args="$extra_host_args --with-gnu-ld"
2421 fi
2422
2423 if test x${use_included_zlib} = x &&
2424    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2425   :
2426 else
2427   with_system_zlib=yes
2428   extra_host_args="$extra_host_args --with-system-zlib"
2429 fi
2430
2431 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2432 # can detect this case.
2433
2434 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2435   with_newlib=yes
2436   extra_host_args="$extra_host_args --with-newlib"
2437 fi
2438
2439 # Handle ${copy_dirs}
2440 set fnord ${copy_dirs}
2441 shift
2442 while test $# != 0 ; do
2443   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2444     :
2445   else
2446     echo Copying $1 to $2
2447
2448     # Use the install script to create the directory and all required
2449     # parent directories.
2450     if test -d $2 ; then
2451       :
2452     else
2453       echo >config.temp
2454       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2455     fi
2456
2457     # Copy the directory, assuming we have tar.
2458     # FIXME: Should we use B in the second tar?  Not all systems support it.
2459     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2460
2461     # It is the responsibility of the user to correctly adjust all
2462     # symlinks.  If somebody can figure out how to handle them correctly
2463     # here, feel free to add the code.
2464
2465     echo $1 > $2/COPIED
2466   fi
2467   shift; shift
2468 done
2469
2470 # Determine a target-dependent exec_prefix that the installed
2471 # gcc will search in.  Keep this list sorted by triplet, with
2472 # the *-*-osname triplets last.
2473 md_exec_prefix=
2474 case "${target}" in
2475   i[[34567]]86-pc-msdosdjgpp*)
2476     md_exec_prefix=/dev/env/DJDIR/bin
2477     ;;
2478   *-*-hpux* | \
2479   *-*-nto-qnx* | \
2480   *-*-solaris2*)
2481     md_exec_prefix=/usr/ccs/bin
2482     ;;
2483 esac
2484
2485 extra_arflags_for_target=
2486 extra_nmflags_for_target=
2487 extra_ranlibflags_for_target=
2488 target_makefile_frag=/dev/null
2489 case "${target}" in
2490   spu-*-*)
2491     target_makefile_frag="config/mt-spu"
2492     ;;
2493   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2494     target_makefile_frag="config/mt-sde"
2495     ;;
2496   mipsisa*-*-elfoabi*)
2497     target_makefile_frag="config/mt-mips-elfoabi"
2498     ;;
2499   mips*-*-*linux* | mips*-*-gnu*)
2500     target_makefile_frag="config/mt-mips-gnu"
2501     ;;
2502   nios2-*-elf*)
2503     target_makefile_frag="config/mt-nios2-elf"
2504     ;;
2505   *-*-linux-android*)
2506     target_makefile_frag="config/mt-android"
2507     ;;
2508   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2509     target_makefile_frag="config/mt-gnu"
2510     ;;
2511   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2512     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2513     # commands to handle both 32-bit and 64-bit objects.  These flags are
2514     # harmless if we're using GNU nm or ar.
2515     extra_arflags_for_target=" -X32_64"
2516     extra_nmflags_for_target=" -B -X32_64"
2517     ;;
2518 esac
2519
2520 alphaieee_frag=/dev/null
2521 case $target in
2522   alpha*-*-*)
2523     # This just makes sure to use the -mieee option to build target libs.
2524     # This should probably be set individually by each library.
2525     alphaieee_frag="config/mt-alphaieee"
2526     ;;
2527 esac
2528
2529 # If --enable-target-optspace always use -Os instead of -O2 to build
2530 # the target libraries, similarly if it is not specified, use -Os
2531 # on selected platforms.
2532 ospace_frag=/dev/null
2533 case "${enable_target_optspace}:${target}" in
2534   yes:*)
2535     ospace_frag="config/mt-ospace"
2536     ;;
2537   :d30v-*)
2538     ospace_frag="config/mt-d30v"
2539     ;;
2540   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2541     ospace_frag="config/mt-ospace"
2542     ;;
2543   no:* | :*)
2544     ;;
2545   *)
2546     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2547     ;;
2548 esac
2549
2550 # Some systems (e.g., one of the i386-aix systems the gas testers are
2551 # using) don't handle "\$" correctly, so don't use it here.
2552 tooldir='${exec_prefix}'/${target_noncanonical}
2553 build_tooldir=${tooldir}
2554
2555 # Create a .gdbinit file which runs the one in srcdir
2556 # and tells GDB to look there for source files.
2557
2558 if test -r ${srcdir}/.gdbinit ; then
2559   case ${srcdir} in
2560     .) ;;
2561     *) cat > ./.gdbinit <<EOF
2562 # ${NO_EDIT}
2563 dir ${srcdir}
2564 dir .
2565 source ${srcdir}/.gdbinit
2566 EOF
2567     ;;
2568   esac
2569 fi
2570
2571 # Make sure that the compiler is able to generate an executable.  If it
2572 # can't, we are probably in trouble.  We don't care whether we can run the
2573 # executable--we might be using a cross compiler--we only care whether it
2574 # can be created.  At this point the main configure script has set CC.
2575 we_are_ok=no
2576 echo "int main () { return 0; }" > conftest.c
2577 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2578 if test $? = 0 ; then
2579   if test -s conftest || test -s conftest.exe ; then
2580     we_are_ok=yes
2581   fi
2582 fi
2583 case $we_are_ok in
2584   no)
2585     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2586     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2587     rm -f conftest*
2588     exit 1
2589     ;;
2590 esac
2591 rm -f conftest*
2592
2593 # Decide which environment variable is used to find dynamic libraries.
2594 case "${host}" in
2595   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2596   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2597   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2598   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2599 esac
2600
2601 # On systems where the dynamic library environment variable is PATH,
2602 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2603 # built executables to PATH.
2604 if test "$RPATH_ENVVAR" = PATH; then
2605   GCC_SHLIB_SUBDIR=/shlib
2606 else
2607   GCC_SHLIB_SUBDIR=
2608 fi
2609
2610 # Adjust the toplevel makefile according to whether bootstrap was selected.
2611 case $enable_bootstrap in
2612   yes)
2613     bootstrap_suffix=bootstrap
2614     BUILD_CONFIG=bootstrap-debug
2615     ;;
2616   no)
2617     bootstrap_suffix=no-bootstrap
2618     BUILD_CONFIG=
2619     ;;
2620 esac
2621
2622 AC_MSG_CHECKING(for default BUILD_CONFIG)
2623
2624 AC_ARG_WITH([build-config],
2625   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2626                   [use config/NAME.mk build configuration])],
2627   [case $with_build_config in
2628    yes) with_build_config= ;;
2629    no) with_build_config= BUILD_CONFIG= ;;
2630    esac])
2631
2632 if test "x${with_build_config}" != x; then
2633   BUILD_CONFIG=$with_build_config
2634 else
2635   case $BUILD_CONFIG in
2636   bootstrap-debug)
2637     if echo "int f (void) { return 0; }" > conftest.c &&
2638        ${CC} -c conftest.c &&
2639        mv conftest.o conftest.o.g0 &&
2640        ${CC} -c -g conftest.c &&
2641        mv conftest.o conftest.o.g &&
2642        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2643       :
2644     else
2645       BUILD_CONFIG=
2646     fi
2647     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2648     ;;
2649   esac
2650 fi
2651 AC_MSG_RESULT($BUILD_CONFIG)
2652 AC_SUBST(BUILD_CONFIG)
2653
2654 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2655 AC_MSG_CHECKING([for --enable-vtable-verify])
2656 AC_ARG_ENABLE(vtable-verify,
2657 [AS_HELP_STRING([--enable-vtable-verify],
2658                 [Enable vtable verification feature])],
2659 [case "$enableval" in
2660  yes) enable_vtable_verify=yes ;;
2661  no)  enable_vtable_verify=no ;;
2662  *)   enable_vtable_verify=no;;
2663  esac],
2664 [enable_vtable_verify=no])
2665 AC_MSG_RESULT($enable_vtable_verify)
2666
2667 # Record target_configdirs and the configure arguments for target and
2668 # build configuration in Makefile.
2669 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2670 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2671 bootstrap_fixincludes=no
2672
2673 # If we are building libgomp, bootstrap it.
2674 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2675   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2676 fi
2677
2678 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2679 # or bootstrap-ubsan, bootstrap it.
2680 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2681   case "$BUILD_CONFIG" in
2682     *bootstrap-asan* | *bootstrap-ubsan* )
2683       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2684       bootstrap_fixincludes=yes
2685       ;;
2686   esac
2687 fi
2688
2689 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2690 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2691    test "$enable_vtable_verify" != no; then
2692   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2693 fi
2694
2695 # If we are building libmpx and $BUILD_CONFIG contains bootstrap-mpx,
2696 # bootstrap it.
2697 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2698   case "$BUILD_CONFIG" in
2699     *bootstrap-mpx* )
2700       bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2701       ;;
2702   esac
2703 fi
2704
2705 # Determine whether gdb needs tk/tcl or not.
2706 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2707 # and in that case we want gdb to be built without tk.  Ugh!
2708 # In fact I believe gdb is the *only* package directly dependent on tk,
2709 # so we should be able to put the 'maybe's in unconditionally and
2710 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2711 # 100% sure that that's safe though.
2712
2713 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2714 case "$enable_gdbtk" in
2715   no)
2716     GDB_TK="" ;;
2717   yes)
2718     GDB_TK="${gdb_tk}" ;;
2719   *)
2720     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2721     # distro.  Eventually someone will fix this and move Insight, nee
2722     # gdbtk to a separate directory.
2723     if test -d ${srcdir}/gdb/gdbtk ; then
2724       GDB_TK="${gdb_tk}"
2725     else
2726       GDB_TK=""
2727     fi
2728     ;;
2729 esac
2730 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2731 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2732
2733 # Strip out unwanted targets.
2734
2735 # While at that, we remove Makefiles if we were started for recursive
2736 # configuration, so that the top-level Makefile reconfigures them,
2737 # like we used to do when configure itself was recursive.
2738
2739 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2740 # but now we're fixing up the Makefile ourselves with the additional
2741 # commands passed to AC_CONFIG_FILES.  Use separate variables
2742 # extrasub-{build,host,target} not because there is any reason to split
2743 # the substitutions up that way, but only to remain below the limit of
2744 # 99 commands in a script, for HP-UX sed.
2745 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2746
2747 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2748   yes:yes:*\ gold\ *:*,c++,*) ;;
2749   yes:yes:*\ gold\ *:*)
2750     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2751     ;;
2752 esac
2753
2754 extrasub_build=
2755 for module in ${build_configdirs} ; do
2756   if test -z "${no_recursion}" \
2757      && test -f ${build_subdir}/${module}/Makefile; then
2758     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2759     rm -f ${build_subdir}/${module}/Makefile
2760   fi
2761   extrasub_build="$extrasub_build
2762 /^@if build-$module\$/d
2763 /^@endif build-$module\$/d
2764 /^@if build-$module-$bootstrap_suffix\$/d
2765 /^@endif build-$module-$bootstrap_suffix\$/d"
2766 done
2767 extrasub_host=
2768 for module in ${configdirs} ; do
2769   if test -z "${no_recursion}"; then
2770     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2771       if test -f ${file}; then
2772         echo 1>&2 "*** removing ${file} to force reconfigure"
2773         rm -f ${file}
2774       fi
2775     done
2776   fi
2777   case ${module},${bootstrap_fixincludes} in
2778     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2779     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2780   esac
2781   extrasub_host="$extrasub_host
2782 /^@if $module\$/d
2783 /^@endif $module\$/d
2784 /^@if $module-$host_bootstrap_suffix\$/d
2785 /^@endif $module-$host_bootstrap_suffix\$/d"
2786 done
2787 extrasub_target=
2788 for module in ${target_configdirs} ; do
2789   if test -z "${no_recursion}" \
2790      && test -f ${target_subdir}/${module}/Makefile; then
2791     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2792     rm -f ${target_subdir}/${module}/Makefile
2793   fi
2794
2795   # We only bootstrap target libraries listed in bootstrap_target_libs.
2796   case $bootstrap_target_libs in
2797     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2798     *) target_bootstrap_suffix=no-bootstrap ;;
2799   esac
2800
2801   extrasub_target="$extrasub_target
2802 /^@if target-$module\$/d
2803 /^@endif target-$module\$/d
2804 /^@if target-$module-$target_bootstrap_suffix\$/d
2805 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2806 done
2807
2808 # Do the final fixup along with target modules.
2809 extrasub_target="$extrasub_target
2810 /^@if /,/^@endif /d"
2811
2812 # Create the serialization dependencies.  This uses a temporary file.
2813
2814 AC_ARG_ENABLE([serial-configure],
2815 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2816                 [force sequential configuration of
2817                  sub-packages for the host, target or build
2818                  machine, or all sub-packages])])
2819
2820 case ${enable_serial_configure} in
2821   yes)
2822     enable_serial_build_configure=yes
2823     enable_serial_host_configure=yes
2824     enable_serial_target_configure=yes
2825     ;;
2826 esac
2827
2828 # These force 'configure's to be done one at a time, to avoid problems
2829 # with contention over a shared config.cache.
2830 rm -f serdep.tmp
2831 echo '# serdep.tmp' > serdep.tmp
2832 olditem=
2833 test "x${enable_serial_build_configure}" = xyes &&
2834 for item in ${build_configdirs} ; do
2835   case ${olditem} in
2836     "") ;;
2837     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2838   esac
2839   olditem=${item}
2840 done
2841 olditem=
2842 test "x${enable_serial_host_configure}" = xyes &&
2843 for item in ${configdirs} ; do
2844   case ${olditem} in
2845     "") ;;
2846     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2847   esac
2848   olditem=${item}
2849 done
2850 olditem=
2851 test "x${enable_serial_target_configure}" = xyes &&
2852 for item in ${target_configdirs} ; do
2853   case ${olditem} in
2854     "") ;;
2855     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2856   esac
2857   olditem=${item}
2858 done
2859 serialization_dependencies=serdep.tmp
2860 AC_SUBST_FILE(serialization_dependencies)
2861
2862 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2863 # target, nonopt, and variable assignments.  These are the ones we
2864 # might not want to pass down to subconfigures.  The exception being
2865 # --cache-file=/dev/null, which is used to turn off the use of cache
2866 # files altogether, and which should be passed on to subconfigures.
2867 # Also strip program-prefix, program-suffix, and program-transform-name,
2868 # so that we can pass down a consistent program-transform-name.
2869 baseargs=
2870 tbaseargs=
2871 keep_next=no
2872 skip_next=no
2873 eval "set -- $ac_configure_args"
2874 for ac_arg
2875 do
2876   if test X"$skip_next" = X"yes"; then
2877     skip_next=no
2878     continue
2879   fi
2880   if test X"$keep_next" = X"yes"; then
2881     case $ac_arg in
2882       *\'*)
2883         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2884     esac
2885     baseargs="$baseargs '$ac_arg'"
2886     tbaseargs="$tbaseargs '$ac_arg'"
2887     keep_next=no
2888     continue
2889   fi
2890
2891   # Handle separated arguments.  Based on the logic generated by
2892   # autoconf 2.59.
2893   case $ac_arg in
2894     *=* | --config-cache | -C | -disable-* | --disable-* \
2895       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2896       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2897       | -with-* | --with-* | -without-* | --without-* | --x)
2898       separate_arg=no
2899       ;;
2900     -*)
2901       separate_arg=yes
2902       ;;
2903     *)
2904       separate_arg=no
2905       ;;
2906   esac
2907
2908   skip_targ=no
2909   case $ac_arg in
2910 changequote(,)
2911   --with-* | --without-*)
2912     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2913
2914     case $libopt in
2915     *[-_]include)
2916       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2917       ;;
2918     *[-_]lib)
2919       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2920       ;;
2921     *)
2922       lib=$libopt
2923       ;;
2924     esac
2925 changequote([,])
2926
2927     case $lib in
2928     mpc | mpfr | gmp | isl)
2929       # If we're processing --with-$lib, --with-$lib-include or
2930       # --with-$lib-lib, for one of the libs above, and target is
2931       # different from host, don't pass the current argument to any
2932       # target library's configure.
2933       if test x$is_cross_compiler = xyes; then
2934         skip_targ=yes
2935       fi
2936       ;;
2937     esac
2938     ;;
2939   esac
2940
2941   case "$ac_arg" in
2942     --cache-file=/dev/null | \
2943     -cache-file=/dev/null )
2944       # Handled here to avoid the test to skip args below.
2945       baseargs="$baseargs '$ac_arg'"
2946       tbaseargs="$tbaseargs '$ac_arg'"
2947       # Assert: $separate_arg should always be no.
2948       keep_next=$separate_arg
2949       ;;
2950     --no*)
2951       continue
2952       ;;
2953     --c* | \
2954     --sr* | \
2955     --ho* | \
2956     --bu* | \
2957     --t* | \
2958     --program-* | \
2959     -cache_file* | \
2960     -srcdir* | \
2961     -host* | \
2962     -build* | \
2963     -target* | \
2964     -program-prefix* | \
2965     -program-suffix* | \
2966     -program-transform-name* )
2967       skip_next=$separate_arg
2968       continue
2969       ;;
2970     -*)
2971       # An option.  Add it.
2972       case $ac_arg in
2973         *\'*)
2974           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2975       esac
2976       baseargs="$baseargs '$ac_arg'"
2977       if test X"$skip_targ" = Xno; then
2978         tbaseargs="$tbaseargs '$ac_arg'"
2979       fi
2980       keep_next=$separate_arg
2981       ;;
2982     *)
2983       # Either a variable assignment, or a nonopt (triplet).  Don't
2984       # pass it down; let the Makefile handle this.
2985       continue
2986       ;;
2987   esac
2988 done
2989 # Remove the initial space we just introduced and, as these will be
2990 # expanded by make, quote '$'.
2991 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2992
2993 # Add in --program-transform-name, after --program-prefix and
2994 # --program-suffix have been applied to it.  Autoconf has already
2995 # doubled dollar signs and backslashes in program_transform_name; we want
2996 # the backslashes un-doubled, and then the entire thing wrapped in single
2997 # quotes, because this will be expanded first by make and then by the shell.
2998 # Also, because we want to override the logic in subdir configure scripts to
2999 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3000 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3001 ${program_transform_name}
3002 EOF_SED
3003 gcc_transform_name=`cat conftestsed.out`
3004 rm -f conftestsed.out
3005 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3006 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3007 if test "$silent" = yes; then
3008   baseargs="$baseargs --silent"
3009   tbaseargs="$tbaseargs --silent"
3010 fi
3011 baseargs="$baseargs --disable-option-checking"
3012 tbaseargs="$tbaseargs --disable-option-checking"
3013
3014 # Record and document user additions to sub configure arguments.
3015 AC_ARG_VAR([build_configargs],
3016            [additional configure arguments for build directories])
3017 AC_ARG_VAR([host_configargs],
3018            [additional configure arguments for host directories])
3019 AC_ARG_VAR([target_configargs],
3020            [additional configure arguments for target directories])
3021
3022 # For the build-side libraries, we just need to pretend we're native,
3023 # and not use the same cache file.  Multilibs are neither needed nor
3024 # desired.  We can't even use the same cache file for all build-side
3025 # libraries, as they're compiled differently; some with C, some with
3026 # C++ or with different feature-enabling options.
3027 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3028
3029 # For host modules, accept cache file option, or specification as blank.
3030 case "${cache_file}" in
3031 "") # empty
3032   cache_file_option="" ;;
3033 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3034   cache_file_option="--cache-file=${cache_file}" ;;
3035 *) # relative path
3036   cache_file_option="--cache-file=../${cache_file}" ;;
3037 esac
3038
3039 # Host dirs don't like to share a cache file either, horribly enough.
3040 # This seems to be due to autoconf 2.5x stupidity.
3041 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3042
3043 target_configargs="$target_configargs ${tbaseargs}"
3044
3045 # Passing a --with-cross-host argument lets the target libraries know
3046 # whether they are being built with a cross-compiler or being built
3047 # native.  However, it would be better to use other mechanisms to make the
3048 # sorts of decisions they want to make on this basis.  Please consider
3049 # this option to be deprecated.  FIXME.
3050 if test x${is_cross_compiler} = xyes ; then
3051   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3052 fi
3053
3054 # Special user-friendly check for native x86_64-linux build, if
3055 # multilib is not explicitly enabled.
3056 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3057   x86_64-*linux*:yes:$build:$build:)
3058     # Make sure we have a development environment that handles 32-bit
3059     dev64=no
3060     echo "int main () { return 0; }" > conftest.c
3061     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3062     if test $? = 0 ; then
3063       if test -s conftest || test -s conftest.exe ; then
3064         dev64=yes
3065       fi
3066     fi
3067     rm -f conftest*
3068     if test x${dev64} != xyes ; then
3069       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3070     fi
3071     ;;
3072 esac
3073
3074 # Default to --enable-multilib.
3075 if test x${enable_multilib} = x ; then
3076   target_configargs="--enable-multilib ${target_configargs}"
3077 fi
3078
3079 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3080 # changed from the earlier setting of with_newlib.
3081 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3082   target_configargs="--with-newlib ${target_configargs}"
3083 fi
3084
3085 # Different target subdirs use different values of certain variables
3086 # (notably CXX).  Worse, multilibs use *lots* of different values.
3087 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3088 # it doesn't automatically accept command-line overrides of them.
3089 # This means it's not safe for target subdirs to share a cache file,
3090 # which is disgusting, but there you have it.  Hopefully this can be
3091 # fixed in future.  It's still worthwhile to use a cache file for each
3092 # directory.  I think.
3093
3094 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3095 # We need to pass --target, as newer autoconf's requires consistency
3096 # for target_alias and gcc doesn't manage it consistently.
3097 target_configargs="--cache-file=./config.cache ${target_configargs}"
3098
3099 FLAGS_FOR_TARGET=
3100 case " $target_configdirs " in
3101  *" newlib "*)
3102   case " $target_configargs " in
3103   *" --with-newlib "*)
3104    case "$target" in
3105     *-cygwin*)
3106       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3107       ;;
3108    esac
3109
3110    # If we're not building GCC, don't discard standard headers.
3111    if test -d ${srcdir}/gcc; then
3112      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3113
3114      if test "${build}" != "${host}"; then
3115        # On Canadian crosses, CC_FOR_TARGET will have already been set
3116        # by `configure', so we won't have an opportunity to add -Bgcc/
3117        # to it.  This is right: we don't want to search that directory
3118        # for binaries, but we want the header files in there, so add
3119        # them explicitly.
3120        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3121
3122        # Someone might think of using the pre-installed headers on
3123        # Canadian crosses, in case the installed compiler is not fully
3124        # compatible with the compiler being built.  In this case, it
3125        # would be better to flag an error than risking having
3126        # incompatible object files being constructed.  We can't
3127        # guarantee that an error will be flagged, but let's hope the
3128        # compiler will do it, when presented with incompatible header
3129        # files.
3130      fi
3131    fi
3132
3133    case "${target}-${is_cross_compiler}" in
3134    i[[3456789]]86-*-linux*-no)
3135       # Here host == target, so we don't need to build gcc,
3136       # so we don't want to discard standard headers.
3137       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3138       ;;
3139    *)
3140       # If we're building newlib, use its generic headers last, but search
3141       # for any libc-related directories first (so make it the last -B
3142       # switch).
3143       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3144
3145       # If we're building libgloss, find the startup file, simulator library
3146       # and linker script.
3147       case " $target_configdirs " in
3148         *" libgloss "*)
3149         # Look for startup file, simulator library and maybe linker script.
3150         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3151         # Look for libnosys.a in case the target needs it.
3152         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3153         # Most targets have the linker script in the source directory.
3154         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3155         ;;
3156       esac
3157       ;;
3158    esac
3159    ;;
3160   esac
3161   ;;
3162 esac
3163
3164 case "$target" in
3165   x86_64-*mingw* | *-w64-mingw*)
3166   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3167   # however, use a symlink named 'mingw' in ${prefix} .
3168     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3169     ;;
3170   *-mingw*)
3171   # MinGW can't be handled as Cygwin above since it does not use newlib.
3172     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3173     ;;
3174 esac
3175
3176 # Allow the user to override the flags for
3177 # our build compiler if desired.
3178 if test x"${build}" = x"${host}" ; then
3179   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3180   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3181   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3182 fi
3183
3184 # On Canadian crosses, we'll be searching the right directories for
3185 # the previously-installed cross compiler, so don't bother to add
3186 # flags for directories within the install tree of the compiler
3187 # being built; programs in there won't even run.
3188 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3189   # Search for pre-installed headers if nothing else fits.
3190   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3191 fi
3192
3193 if test "x${use_gnu_ld}" = x &&
3194    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3195   # Arrange for us to find uninstalled linker scripts.
3196   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3197 fi
3198
3199 # Search for other target-specific linker scripts and such.
3200 case "${target}" in
3201   mep*)
3202     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3203     ;;
3204 esac
3205
3206 # Makefile fragments.
3207 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3208 do
3209   eval fragval=\$$frag
3210   if test $fragval != /dev/null; then
3211     eval $frag=${srcdir}/$fragval
3212   fi
3213 done
3214 AC_SUBST_FILE(host_makefile_frag)
3215 AC_SUBST_FILE(target_makefile_frag)
3216 AC_SUBST_FILE(alphaieee_frag)
3217 AC_SUBST_FILE(ospace_frag)
3218
3219 # Miscellanea: directories, flags, etc.
3220 AC_SUBST(RPATH_ENVVAR)
3221 AC_SUBST(GCC_SHLIB_SUBDIR)
3222 AC_SUBST(tooldir)
3223 AC_SUBST(build_tooldir)
3224 AC_SUBST(CONFIGURE_GDB_TK)
3225 AC_SUBST(GDB_TK)
3226 AC_SUBST(INSTALL_GDB_TK)
3227
3228 # Build module lists & subconfigure args.
3229 AC_SUBST(build_configargs)
3230 AC_SUBST(build_configdirs)
3231
3232 # Host module lists & subconfigure args.
3233 AC_SUBST(host_configargs)
3234 AC_SUBST(configdirs)
3235 AC_SUBST(target_configdirs)
3236
3237 # Target module lists & subconfigure args.
3238 AC_SUBST(target_configargs)
3239
3240
3241 # Build tools.
3242 AC_SUBST(AR_FOR_BUILD)
3243 AC_SUBST(AS_FOR_BUILD)
3244 AC_SUBST(CC_FOR_BUILD)
3245 AC_SUBST(CFLAGS_FOR_BUILD)
3246 AC_SUBST(CXXFLAGS_FOR_BUILD)
3247 AC_SUBST(CXX_FOR_BUILD)
3248 AC_SUBST(DLLTOOL_FOR_BUILD)
3249 AC_SUBST(GFORTRAN_FOR_BUILD)
3250 AC_SUBST(GOC_FOR_BUILD)
3251 AC_SUBST(LDFLAGS_FOR_BUILD)
3252 AC_SUBST(LD_FOR_BUILD)
3253 AC_SUBST(NM_FOR_BUILD)
3254 AC_SUBST(RANLIB_FOR_BUILD)
3255 AC_SUBST(WINDMC_FOR_BUILD)
3256 AC_SUBST(WINDRES_FOR_BUILD)
3257
3258 # Generate default definitions for YACC, M4, LEX and other programs that run
3259 # on the build machine.  These are used if the Makefile can't locate these
3260 # programs in objdir.
3261 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3262
3263 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3264 case " $build_configdirs " in
3265   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3266 esac
3267
3268 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3269 case " $build_configdirs " in
3270   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3271 esac
3272
3273 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3274 case " $build_configdirs " in
3275   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3276 esac
3277
3278 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3279 case " $build_configdirs " in
3280   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3281   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3282 esac
3283
3284 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3285 case " $build_configdirs " in
3286   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3287 esac
3288
3289 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3290 case " $build_configdirs " in
3291   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3292   *)
3293 changequote(,)
3294     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3295     # higher, else we use the "missing" dummy.
3296     if ${MAKEINFO} --version \
3297        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3298       :
3299     else
3300       MAKEINFO="$MISSING makeinfo"
3301     fi
3302     ;;
3303 changequote([,])
3304 esac
3305
3306 # FIXME: expect and dejagnu may become build tools?
3307
3308 AC_CHECK_PROGS(EXPECT, expect, expect)
3309 case " $configdirs " in
3310   *" expect "*)
3311     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3312     ;;
3313 esac
3314
3315 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3316 case " $configdirs " in
3317   *" dejagnu "*)
3318     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3319     ;;
3320 esac
3321
3322
3323 # Host tools.
3324 NCN_STRICT_CHECK_TOOLS(AR, ar)
3325 NCN_STRICT_CHECK_TOOLS(AS, as)
3326 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3327 NCN_STRICT_CHECK_TOOLS(LD, ld)
3328 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3329 NCN_STRICT_CHECK_TOOLS(NM, nm)
3330 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3331 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3332 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3333 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3334 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3335 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3336 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3337 AC_SUBST(CC)
3338 AC_SUBST(CXX)
3339 AC_SUBST(CFLAGS)
3340 AC_SUBST(CXXFLAGS)
3341
3342 # Target tools.
3343 AC_ARG_WITH([build-time-tools],
3344   [AS_HELP_STRING([--with-build-time-tools=PATH],
3345                   [use given path to find target tools during the build])],
3346   [case x"$withval" in
3347      x/*) ;;
3348      *)
3349        with_build_time_tools=
3350        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3351        ;;
3352    esac],
3353   [with_build_time_tools=])
3354
3355 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3356 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3357 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3358 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3359 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3360
3361 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3362 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3363 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3364 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3366 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3367 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3368 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3369 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3370 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3371 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3372 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3373 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3374
3375 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3376
3377 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3378 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3379 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3380 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3381 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3382                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3383                 c++)
3384 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3385                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3386                 c++)
3387 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3388 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3389 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3390                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3391 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3392                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3393 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3394 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3395 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3396 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3397 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3398 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3399 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3400 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3401 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3402 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3403
3404 AC_SUBST(FLAGS_FOR_TARGET)
3405 AC_SUBST(RAW_CXX_FOR_TARGET)
3406
3407 # Certain tools may need extra flags.
3408 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3409 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3410 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3411
3412 # When building target libraries, except in a Canadian cross, we use
3413 # the same toolchain as the compiler we just built.
3414 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3415 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3416 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3417 if test $host = $build; then
3418   case " $configdirs " in
3419     *" gcc "*)
3420       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3421       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3422       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3423       ;;
3424   esac
3425 fi
3426
3427 AC_SUBST(COMPILER_AS_FOR_TARGET)
3428 AC_SUBST(COMPILER_LD_FOR_TARGET)
3429 AC_SUBST(COMPILER_NM_FOR_TARGET)
3430
3431 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3432 AC_ARG_ENABLE(maintainer-mode,
3433 [AS_HELP_STRING([--enable-maintainer-mode],
3434                 [enable make rules and dependencies not useful
3435                  (and sometimes confusing) to the casual installer])],
3436       USE_MAINTAINER_MODE=$enableval,
3437       USE_MAINTAINER_MODE=no)
3438 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3439 AC_SUBST(MAINTAINER_MODE_TRUE)
3440 AC_SUBST(MAINTAINER_MODE_FALSE)
3441 if test "$USE_MAINTAINER_MODE" = yes; then
3442   MAINTAINER_MODE_TRUE=
3443   MAINTAINER_MODE_FALSE='#'
3444 else
3445   MAINTAINER_MODE_TRUE='#'
3446   MAINTAINER_MODE_FALSE=
3447 fi
3448 MAINT=$MAINTAINER_MODE_TRUE
3449 AC_SUBST(MAINT)dnl
3450
3451 # ---------------------
3452 # GCC bootstrap support
3453 # ---------------------
3454
3455 # Stage specific cflags for build.
3456 stage1_cflags="-g"
3457 case $build in
3458   vax-*-*)
3459     case ${GCC} in
3460       yes) stage1_cflags="-g -Wa,-J" ;;
3461       *) stage1_cflags="-g -J" ;;
3462     esac ;;
3463 esac
3464
3465 AC_SUBST(stage1_cflags)
3466
3467 # Enable --enable-checking in stage1 of the compiler.
3468 AC_ARG_ENABLE(stage1-checking,
3469 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3470                 [choose additional checking for stage1 of the compiler])],
3471 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3472 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3473   # For --disable-checking or implicit --enable-checking=release, avoid
3474   # setting --enable-checking=gc in the default stage1 checking for LTO
3475   # bootstraps.  See PR62077.
3476   case $BUILD_CONFIG in
3477     *lto*)
3478       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3479     *)
3480       stage1_checking=--enable-checking=yes,types;;
3481   esac
3482   if test "x$enable_checking" = x && \
3483      test -d ${srcdir}/gcc && \
3484      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3485     stage1_checking=--enable-checking=yes,types,extra
3486   fi
3487 else
3488   stage1_checking=--enable-checking=$enable_checking,types
3489 fi])
3490 AC_SUBST(stage1_checking)
3491
3492 # Enable -Werror in bootstrap stage2 and later.
3493 AC_ARG_ENABLE(werror,
3494 [AS_HELP_STRING([--enable-werror],
3495                 [enable -Werror in bootstrap stage2 and later])],
3496 [
3497 case ${enable_werror} in
3498   yes) stage2_werror_flag="--enable-werror-always" ;;
3499   *) stage2_werror_flag="" ;;
3500 esac
3501 ],
3502 [
3503 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3504   case $BUILD_CONFIG in
3505   bootstrap-debug)
3506       stage2_werror_flag="--enable-werror-always" ;;
3507   "")
3508       stage2_werror_flag="--enable-werror-always" ;;
3509   esac
3510 fi
3511 ])
3512
3513 AC_SUBST(stage2_werror_flag)
3514
3515 # Specify what files to not compare during bootstrap.
3516
3517 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3518 case "$target" in
3519   hppa*64*-*-hpux*) ;;
3520   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3521   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3522 esac
3523 AC_SUBST(compare_exclusions)
3524
3525 AC_CONFIG_FILES([Makefile],
3526   [sed "$extrasub_build" Makefile |
3527    sed "$extrasub_host" |
3528    sed "$extrasub_target" > mf$$
3529    mv -f mf$$ Makefile],
3530   [extrasub_build="$extrasub_build"
3531    extrasub_host="$extrasub_host"
3532    extrasub_target="$extrasub_target"])
3533 AC_OUTPUT