configure.ac

   1 AC_PREREQ([2.69])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT([GStreamer Base Plug-ins],[1.6.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-base])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.14 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 dnl CURRENT, REVISION, AGE
  46 dnl - library source changed -> increment REVISION
  47 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  48 dnl - interfaces added -> increment AGE
  49 dnl - interfaces removed -> AGE = 0
  50 dnl
  51 dnl Keep CURRENT as MINOR * 100 + MICRO
  52 dnl Ex : 1.0.0 => 0
  53 dnl      1.0.3 => 3
  54 dnl      1.1.0 => 100
  55 dnl      1.2.5 => 205
  56 dnl      1.10.9 (who knows) => 1009
  57 dnl
  58 dnl sets GST_LT_LDFLAGS
  59 AS_LIBTOOL(GST, 601, 0, 601)
  60
  61 dnl *** required versions of GStreamer stuff ***
  62 GST_REQ=1.6.1
  63
  64 dnl *** autotools stuff ****
  65
  66 dnl allow for different autotools
  67 AS_AUTOTOOLS_ALTERNATE
  68
  69 dnl Add parameters for aclocal
  70 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  71
  72 dnl set up gettext
  73 dnl the version check needs to stay here because autopoint greps for it
  74 AM_GNU_GETTEXT_VERSION([0.17])
  75 AM_GNU_GETTEXT([external])
  76 AG_GST_GETTEXT([gst-plugins-base-$GST_API_VERSION])
  77
  78 dnl *** check for arguments to configure ***
  79
  80 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  81
  82 AG_GST_ARG_DEBUG
  83 AG_GST_ARG_PROFILING
  84 AG_GST_ARG_VALGRIND
  85 AG_GST_ARG_GCOV
  86
  87 AG_GST_ARG_EXAMPLES
  88
  89 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  90 AG_GST_ARG_WITH_PACKAGE_NAME
  91 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  92
  93 AG_GST_PKG_CONFIG_PATH
  94
  95 dnl let distro override plugin install helper path
  96 AC_ARG_WITH(install-plugins-helper,
  97   AS_HELP_STRING([--with-install-plugins-helper],[specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122 AG_GST_PLATFORM
 123
 124 dnl * hardware/architecture *
 125
 126 dnl common/m4/gst-arch.m4
 127 dnl check CPU type
 128 AG_GST_ARCH
 129
 130 dnl check for large file support
 131 dnl affected plugins must include config.h
 132 AC_SYS_LARGEFILE
 133
 134 dnl *** checks for programs ***
 135
 136 dnl find a compiler
 137 AC_PROG_CC
 138 AC_PROG_CC_STDC
 139
 140 dnl check if the compiler supports '-c' and '-o' options
 141 AM_PROG_CC_C_O
 142
 143 dnl determine if c++ is available on this system
 144 AC_PROG_CXX
 145 dnl CXX may be set to some default even if no c++ compiler is available
 146 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 147 AC_LANG_PUSH([C++])
 148 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ class Foo { int bar; };]], [[]])],[working_cxx=yes],[working_cxx=no])
 149 AC_LANG_POP([C++])
 150 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 151 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 152
 153 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 154 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 155
 156
 157 dnl check for tbm buffer
 158
 159 AC_ARG_ENABLE(tbmbuf, AC_HELP_STRING([--enable-use-tbmbuf], [use tbm buf]),
 160         [
 161           case "${enableval}" in
 162            yes) BOARD_USE_TBM_BUF=yes ;;
 163            no)  BOARD_USE_TBM_BUF=no ;;
 164            *)   AC_MSG_ERROR(bad value ${enableval} for --enable-use-tbmbuf) ;;
 165           esac
 166         ],
 167         [BOARD_USE_TBM_BUF=yes])
 168 AM_CONDITIONAL([BOARD_USE_TBM_BUF], [test "x$BOARD_USE_TBM_BUF" = "xyes"])
 169
 170 dnl check for gobject-introspection
 171 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 172
 173 dnl check for documentation tools
 174 GTK_DOC_CHECK([1.12])
 175 AG_GST_PLUGIN_DOCS([1.12])
 176
 177 dnl *** checks for libraries ***
 178
 179 dnl libm, for sin() etc.
 180 LT_LIB_M
 181 AC_SUBST(LIBM)
 182
 183 dnl *** checks for header files ***
 184
 185 dnl check if we have ANSI C header files
 186 AC_HEADER_STDC
 187
 188 dnl check for GCC specific SSE headers
 189 dnl these are used by the speex resampler code
 190 AC_CHECK_HEADERS([xmmintrin.h emmintrin.h])
 191
 192 dnl used in gst/tcp
 193 AC_CHECK_HEADERS([sys/socket.h],
 194   [HAVE_SYS_SOCKET_H="yes"], [HAVE_SYS_SOCKET_H="no"], [AC_INCLUDES_DEFAULT])
 195 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 196
 197 dnl used in gst-libs/gst/rtsp
 198 AC_CHECK_HEADERS([winsock2.h], [HAVE_WINSOCK2_H=yes], [HAVE_WINSOCK2_H=no], [AC_INCLUDES_DEFAULT])
 199 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 200 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 201   WIN32_LIBS="-lws2_32"
 202   AC_SUBST(WIN32_LIBS)
 203 fi
 204
 205 dnl used in gst-libs/gst/pbutils and associated unit test
 206 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h], [], [], [AC_INCLUDES_DEFAULT])
 207
 208 dnl checks for ARM NEON support
 209 dnl this instruction set is used by the speex resampler code
 210 AC_MSG_CHECKING(for ARM NEON support in current arch/CFLAGS)
 211 AC_LINK_IFELSE([
 212 AC_LANG_PROGRAM([[
 213   #include <arm_neon.h>
 214   int32x4_t testfunc(int16_t *a, int16_t *b) {
 215       asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 216       return vmull_s16(vld1_s16(a), vld1_s16(b));
 217   }
 218 ]])],
 219 [
 220   AC_DEFINE(HAVE_ARM_NEON,[],[ARM NEON support is enabled])
 221   AC_MSG_RESULT(yes)
 222 ],
 223 [
 224   AC_MSG_RESULT(no)
 225 ])
 226
 227 dnl also, Windows does not have long long
 228 AX_CREATE_STDINT_H
 229
 230 dnl *** checks for functions ***
 231 AC_CHECK_FUNCS([localtime_r gmtime_r])
 232
 233 dnl *** checks for math functions ***
 234 LIBS_SAVE=$LIBS
 235 LIBS="$LIBS $LIBM"
 236 AC_CHECK_FUNCS(log2)
 237 LIBS=$LIBS_SAVE
 238
 239 dnl *** checks for types/defines ***
 240
 241 dnl *** checks for structures ***
 242
 243 dnl *** checks for compiler characteristics ***
 244
 245 dnl *** checks for library functions ***
 246
 247 dnl check for fseeko()
 248 AC_FUNC_FSEEKO
 249
 250 dnl Check for fast float to int casting as defined in C99
 251 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 252 save_libs=$LIBS
 253 LIBS="$LIBS $LIBM"
 254 #AC_C99_FUNC_LRINT
 255 #AC_C99_FUNC_LRINTF
 256 LIBS=$save_libs
 257
 258 dnl Check for a way to display the function name in debug output
 259 AG_GST_CHECK_FUNCTION
 260
 261 dnl *** checks for dependency libraries ***
 262
 263 dnl GLib
 264 GLIB_REQ=2.32
 265 AG_GST_GLIB_CHECK([$GLIB_REQ])
 266
 267 ORC_CHECK([0.4.23])
 268
 269 dnl checks for gstreamer
 270 dnl uninstalled is selected preferentially -- see pkg-config(1)
 271 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 273 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 274 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 275 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 276 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 277
 278 dnl Check for documentation xrefs
 279 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 280 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 281 AC_SUBST(GLIB_PREFIX)
 282 AC_SUBST(GST_PREFIX)
 283
 284 dnl GTK is optional and only used in examples
 285 HAVE_GTK=no
 286 HAVE_GTK_X11=no
 287 GTK_REQ=3.10
 288 if test "x$BUILD_EXAMPLES" = "xyes"; then
 289   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 290   dnl some examples need gtk+-x11
 291   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 292   PKG_CHECK_MODULES(GTK_QUARTZ, gtk+-quartz-3.0 >= $GTK_REQ, HAVE_GTK_QUARTZ=yes, HAVE_GTK_QUARTZ=no)
 293   AC_SUBST(GTK_LIBS)
 294   AC_SUBST(GTK_CFLAGS)
 295 fi
 296 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 297 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 298 AM_CONDITIONAL(HAVE_GTK_QUARTZ, test "x$HAVE_GTK_QUARTZ" = "xyes")
 299
 300 HAVE_QT=no
 301 HAVE_QT_MOC=no
 302 dnl QT is optional and only used in examples
 303 PKG_CHECK_MODULES(QT, Qt5Gui Qt5Widgets, [
 304   HAVE_QT=yes
 305 ], [
 306   HAVE_QT=no
 307 ])
 308 if test "x$HAVE_QT" = "xyes"; then
 309   AC_CHECK_TOOL(QT_MOC, moc)
 310   AC_MSG_CHECKING([for Qt5 moc])
 311   mocversion=`$QT_MOC -v 2>&1`
 312   mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 313   if test x"$mocversiongrep" != x"$mocversion"; then
 314     AC_MSG_RESULT([no])
 315     # moc was not the qt5 one, try with moc-qt5
 316     AC_CHECK_TOOL(QT_MOC, moc-qt5)
 317     AC_MSG_CHECKING([for Qt5 moc-qt5])
 318     mocversion=`$QT_MOC -v 2>&1`
 319     mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 320     if test x"$mocversiongrep" != x"$mocversion"; then
 321       AC_CHECK_TOOL(QTCHOOSER, qtchooser)
 322       AC_MSG_CHECKING([for qtchooser])
 323       qt5tooldir=`QT_SELECT=qt5 qtchooser -print-env | grep QTTOOLDIR | cut -d '=' -f 2 | cut -d \" -f 2`
 324       mocversion=`$qt5tooldir/moc -v 2>&1`
 325       mocversiongrep=`echo $mocversion | grep "Qt 5\|moc 5"`
 326       if test x"$mocversiongrep" != x"$mocversion"; then
 327         # no valid moc found
 328         QT_MOC="no"
 329       else
 330         QT_MOC=$qt5tooldir/moc
 331       fi
 332     else
 333       QT_MOC=$QT_MOC
 334     fi
 335   fi
 336   AC_SUBST(QT_MOC)
 337   AC_MSG_RESULT([$QT_MOC])
 338 fi
 339 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 340 AM_CONDITIONAL(HAVE_QT_MOC, test "x$HAVE_QT_MOC" != "xno")
 341
 342 dnl chck for linux headers needed by the joystick seek example
 343 AC_COMPILE_IFELSE(
 344 [
 345   AC_LANG_PROGRAM([
 346     #include <linux/input.h>
 347     #include <linux/joystick.h>
 348   ],[
 349     struct js_event js;
 350     js.type = JS_EVENT_AXIS;
 351   ])
 352 ], [
 353   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 354 ], [
 355   HAVE_LINUX_JOYSTICK_HEADERS="no"
 356 ])
 357 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 358
 359 dnl Check for -Bsymbolic-functions linker flag used to avoid
 360 dnl intra-library PLT jumps, if available.
 361 AC_ARG_ENABLE(Bsymbolic,
 362               [AS_HELP_STRING([--disable-Bsymbolic],[avoid linking with -Bsymbolic])],,
 363               [SAVED_LDFLAGS="${LDFLAGS}"
 364                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 365                LDFLAGS=-Wl,-Bsymbolic-functions
 366                AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int main (void) { return 0; }]])],[
 367                            AC_MSG_RESULT(yes)
 368                            enable_Bsymbolic=yes],[
 369                            AC_MSG_RESULT(no)
 370                            enable_Bsymbolic=no])
 371                LDFLAGS="${SAVED_LDFLAGS}"])
 372
 373
 374 dnl *** set variables based on configure arguments ***
 375
 376 dnl set license and copyright notice
 377 GST_LICENSE="LGPL"
 378 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 379 AC_SUBST(GST_LICENSE)
 380
 381 dnl set location of plugin directory
 382 AG_GST_SET_PLUGINDIR
 383
 384 dnl set release date/time
 385 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 386   ["${srcdir}/gst-plugins-base.doap"],
 387   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 388
 389 dnl build static plugins or not
 390 AC_MSG_CHECKING([whether to build static plugins or not])
 391 AC_ARG_ENABLE(
 392   static-plugins,
 393   AC_HELP_STRING(
 394     [--enable-static-plugins],
 395     [build static plugins @<:@default=no@:>@]),
 396   [AS_CASE(
 397     [$enableval], [no], [], [yes], [],
 398     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 399   [enable_static_plugins=no])
 400 AC_MSG_RESULT([$enable_static_plugins])
 401 if test "x$enable_static_plugins" = xyes; then
 402   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 403     [Define if static plugins should be built])
 404   GST_PLUGIN_LIBTOOLFLAGS=""
 405 else
 406   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 407 fi
 408 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 409 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 410
 411 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 412 dnl make sure it doesn't complain about unused variables if debugging is disabled
 413 NO_WARNINGS=""
 414 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 415
 416 dnl define an ERROR_CFLAGS Makefile variable
 417 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 418 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 419     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 420     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 421     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 422     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 423
 424 dnl define an ERROR_CXXFLAGS Makefile variable
 425 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 426     -Wmissing-declarations -Wredundant-decls -Wundef
 427     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 428     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 429     -Wno-multichar $NO_WARNINGS])
 430
 431 dnl define correct level for debugging messages
 432 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 433
 434 dnl used in examples
 435 AG_GST_DEFAULT_ELEMENTS
 436
 437 dnl needed for encoding-target
 438 GST_DATADIR="$GST_PREFIX/share"
 439 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 440 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION", [major/minor version])
 441
 442 dnl behaviour of speex based audio resampler
 443 AC_MSG_CHECKING(which audio resample format to use for integer)
 444 AC_ARG_WITH([audioresample_format],
 445         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 446         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 447 AC_MSG_RESULT($ac_cv_audioresample_format)
 448 case $ac_cv_audioresample_format in
 449   int)
 450     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 451     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 452   ;;
 453   float)
 454     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 455     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 456   ;;
 457   auto)
 458     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 459     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 460 esac
 461
 462 dnl Check for mmap (needed by allocators library)
 463 AC_CHECK_FUNC([mmap], [AC_DEFINE(HAVE_MMAP, 1, [Defined if mmap is supported])])
 464
 465 dnl *** plug-ins to include ***
 466
 467 dnl these are all the gst plug-ins, compilable without additional libs
 468 AG_GST_CHECK_PLUGIN(adder)
 469 AG_GST_CHECK_PLUGIN(app)
 470 AG_GST_CHECK_PLUGIN(audioconvert)
 471 AG_GST_CHECK_PLUGIN(audiorate)
 472 AG_GST_CHECK_PLUGIN(audiotestsrc)
 473 AG_GST_CHECK_PLUGIN(encoding)
 474 AG_GST_CHECK_PLUGIN(videoconvert)
 475 AG_GST_CHECK_PLUGIN(gio)
 476 AG_GST_CHECK_PLUGIN(playback)
 477 AG_GST_CHECK_PLUGIN(audioresample)
 478 AG_GST_CHECK_PLUGIN(subparse)
 479 AG_GST_CHECK_PLUGIN(tcp)
 480 AG_GST_CHECK_PLUGIN(typefind)
 481 AG_GST_CHECK_PLUGIN(videotestsrc)
 482 AG_GST_CHECK_PLUGIN(videorate)
 483 AG_GST_CHECK_PLUGIN(videoscale)
 484 AG_GST_CHECK_PLUGIN(volume)
 485
 486 dnl iso-codes is optional, used by libgsttag
 487 AC_ARG_ENABLE(iso-codes,
 488 AS_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 489 [case "${enableval}" in
 490   yes) enable_iso_codes=yes ;;
 491   no)  enable_iso_codes=no ;;
 492   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 493 esac
 494 ],
 495 [enable_iso_codes=yes]) dnl Default value
 496
 497 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 498 if test "x$enable_iso_codes" = "xyes"; then
 499   AC_MSG_RESULT([yes])
 500   have_iso_codes=no
 501   AC_MSG_CHECKING([whether iso-codes are available on this system])
 502   if $PKG_CONFIG iso-codes; then
 503     AC_MSG_RESULT([yes])
 504     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 505     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 506       AC_MSG_RESULT([yes])
 507       AC_MSG_CHECKING([for iso-codes prefix])
 508       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 509       if test -d "$ISO_CODES_PREFIX"; then
 510         AC_MSG_RESULT([yes])
 511         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 512         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 513         ISO_639_DOMAIN="iso_639"
 514         AC_MSG_CHECKING([ISO_639_DOMAIN])
 515         AC_MSG_RESULT([$ISO_639_DOMAIN])
 516         have_iso_codes=yes
 517         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 518         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 519         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 520         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 521       else
 522         AC_MSG_RESULT([no])
 523       fi
 524     else
 525       AC_MSG_RESULT([no])
 526     fi
 527   else
 528     AC_MSG_RESULT([no])
 529   fi
 530   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 531 else
 532   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 533   AM_CONDITIONAL(USE_ISO_CODES, false)
 534 fi
 535
 536 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 537 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 538 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 539   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 540       HAVE_ZLIB="yes"
 541     ], [
 542       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 543         HAVE_ZLIB="yes"
 544         ZLIB_LIBS="-lz"
 545         AC_SUBST(ZLIB_LIBS)
 546       ])
 547     ])
 548 ])
 549
 550 dnl *** sys plug-ins ***
 551
 552 echo
 553 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 554 echo
 555
 556 dnl *** X11 ***
 557 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 558 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 559                   [ximagesink], [
 560   AG_GST_PKG_CHECK_MODULES(X, x11)
 561 ])
 562
 563 dnl Check for Xv extension
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 565 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 566                   [xvimagesink], [
 567   AG_GST_PKG_CHECK_MODULES(XVIDEO, x11 xv)
 568 ])
 569
 570 dnl check for X Shm
 571 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 572 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], [ ], [
 573   if test x$HAVE_X = xyes; then
 574     PKG_CHECK_MODULES(XSHM, xext, [
 575       AC_CHECK_LIB(Xext, XShmAttach, [
 576         HAVE_XSHM="yes"
 577       ], [
 578         HAVE_XSHM="no"
 579         XSHM_LIBS=""
 580       ], [ $X_LIBS ])
 581     ], [
 582       HAVE_XSHM="no"
 583     ])
 584   fi
 585 ], , [
 586   AC_SUBST(HAVE_XSHM)
 587   AC_SUBST(XSHM_LIBS)
 588 ])
 589
 590 dnl *** ext plug-ins ***
 591 dnl keep this list sorted alphabetically !
 592
 593 if test "x$BUILD_EXTERNAL" = "xyes"; then
 594
 595 echo
 596 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 597 echo
 598
 599 dnl *** alsa ***
 600 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 601 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 602   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 603     HAVE_ALSA="yes"
 604     AC_SUBST(ALSA_CFLAGS)
 605     AC_SUBST(ALSA_LIBS)
 606   ], [
 607     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 608   ])
 609 ])
 610
 611 dnl *** CDParanoia ***
 612 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 613 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 614 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 615   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 616     HAVE_CDPARANOIA="yes"
 617   ], [
 618     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 619                         cdda_open, -lm,
 620                         cdda_interface.h,
 621                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 622                         HEADER_DIR="no"
 623                         FOUND_CDPARANOIA="yes")
 624     if test "x$FOUND_CDPARANOIA" != "xyes";
 625     then
 626       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 627                           cdda_open, -lm,
 628                           cdda/cdda_interface.h,
 629                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 630                           HEADER_DIR="yes"
 631                           FOUND_CDPARANOIA="yes")
 632     fi
 633     if test "x$HEADER_DIR" = "xyes";
 634     then
 635       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 636                          defined if cdda headers are in a cdda/ directory)
 637     fi
 638     if test "x$FOUND_CDPARANOIA" = "xyes";
 639     then
 640       AC_CHECK_LIB(cdda_paranoia,
 641                    paranoia_cachemodel_size,
 642                    : ,
 643                    HAVE_CDPARANOIA=no,
 644                  [-lcdda_interface])
 645     fi
 646
 647     AC_SUBST(CDPARANOIA_LIBS)
 648   ])
 649 ])
 650 dnl FIXME : add second check somehow if that is necessary
 651 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 652 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 653
 654 dnl *** ivorbis ***
 655 dnl AM_PATH_IVORBIS only takes two options
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 657 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 658   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 659   if test $HAVE_IVORBIS = no
 660   then
 661     IVORBIS_LIBS=
 662     IVORBIS_CFLAGS=
 663     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 664       [IVORBIS_LIBS=-lvorbisidec
 665       HAVE_IVORBIS=yes
 666       case $host in
 667       arm-*-*)
 668         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 669       esac
 670       ],
 671       HAVE_IVORBIS=no)
 672     AC_SUBST(IVORBIS_LIBS)
 673     AC_SUBST(IVORBIS_CFLAGS)
 674   else
 675     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 676       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 677       USE_TREMOLO=no)
 678   fi
 679 ])
 680
 681 dnl *** libvisual ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 683 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 684   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 685   if test x$HAVE_LIBVISUAL = xyes; then
 686     LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 687   fi
 688   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 689   if test x$LIBVIS_PLUGINSDIR != x; then
 690     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 691         "$LIBVIS_PLUGINSDIR",
 692         [directory in which the detected libvisual's plugins are located])
 693   fi
 694 ])
 695
 696 dnl *** ogg ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 698 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 699   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 700 ])
 701
 702 dnl *** pango ***
 703 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 704 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 705   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.22.0  pangocairo >= 1.22.0)
 706 ])
 707
 708 dnl *** theora ***
 709 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 710 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 711   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 712 ])
 713
 714 dnl *** vorbis ***
 715 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 716 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 717   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 718 ])
 719
 720 dnl *** gio-unix-2.0 for tests/check/pipelines/tcp.c ***
 721 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO_UNIX_2_0, true)
 722 AG_GST_CHECK_FEATURE(GIO_UNIX_2_0, [glib GIO unix], gio-unix-2.0, [
 723   AG_GST_PKG_CHECK_MODULES(GIO_UNIX_2_0, gio-unix-2.0 >= 2.24)
 724 ])
 725
 726 if test "x$HAVE_VORBIS" = "xyes"; then
 727   ac_cflags_save="$CFLAGS"
 728   AC_COMPILE_IFELSE([
 729     AC_LANG_PROGRAM([[
 730 #include <vorbis/codec.h>
 731                      ]],[[
 732 vorbis_dsp_state *v;
 733
 734 vorbis_synthesis_restart (v);
 735                      ]])], HAVE_VSR=yes, HAVE_VSR=no)
 736   if test "x$HAVE_VSR" = "xyes"; then
 737     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 738                        [defined if vorbis_synthesis_restart is present])
 739   fi
 740   CFLAGS="$ac_cflags_save"
 741 fi
 742
 743 else
 744
 745 dnl not building plugins with external dependencies,
 746 dnl but we still need to set the conditionals
 747 AM_CONDITIONAL(USE_ALSA, false)
 748 AM_CONDITIONAL(USE_CDPARANOIA, false)
 749 AM_CONDITIONAL(USE_IVORBIS, false)
 750 AM_CONDITIONAL(USE_LIBVISUAL, false)
 751 AM_CONDITIONAL(USE_OGG, false)
 752 AM_CONDITIONAL(USE_PANGO, false)
 753 AM_CONDITIONAL(USE_THEORA, false)
 754 AM_CONDITIONAL(USE_VORBIS, false)
 755
 756 fi dnl of EXT plugins
 757
 758 dnl seeking needs freetype, so check for it here
 759 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 760   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 761 ])
 762 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 763 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 764 AC_SUBST(FT2_CFLAGS)
 765 AC_SUBST(FT2_LIBS)
 766
 767 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 768
 769 dnl Overview:
 770 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 771 dnl GST_*:              flags shared by built objects to link against GStreamer
 772 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 773 dnl                          (compare to other modules) or for i18n
 774 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 775 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 776 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 777 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 778
 779 dnl GST_OPTION_CFLAGS
 780 if test "x$USE_DEBUG" = xyes; then
 781    PROFILE_CFLAGS="-g"
 782 fi
 783 AC_SUBST(PROFILE_CFLAGS)
 784
 785 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 786   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 787   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 788 else
 789   DEPRECATED_CFLAGS=""
 790 fi
 791 AC_SUBST(DEPRECATED_CFLAGS)
 792
 793 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 794 dnl at make time with e.g. make ERROR_CFLAGS=""
 795 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 796 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 797 AC_SUBST(GST_OPTION_CFLAGS)
 798 AC_SUBST(GST_OPTION_CXXFLAGS)
 799
 800 dnl our libraries need to be versioned correctly
 801 AC_SUBST(GST_LT_LDFLAGS)
 802
 803 dnl GST_PLUGINS_BASE_CFLAGS
 804 dnl prefer internal headers to already installed ones
 805 dnl also add builddir include for enumtypes and marshal
 806 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 807 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 808
 809 dnl FIXME: do we want to rename to GST_ALL_* ?
 810 dnl add GST_OPTION_CFLAGS, but overridable
 811 GST_CFLAGS="$GST_CFLAGS"
 812 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 813 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 814 AC_SUBST(GST_CFLAGS)
 815 AC_SUBST(GST_CXXFLAGS)
 816 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 817 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 818 AC_SUBST(GST_LIBS)
 819
 820 dnl LDFLAGS really should only contain flags, not libs - they get added before
 821 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 822 GST_ALL_LDFLAGS="-no-undefined"
 823 if test "x${enable_Bsymbolic}" = "xyes"; then
 824   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 825 fi
 826 AC_SUBST(GST_ALL_LDFLAGS)
 827
 828 dnl GST_LIB_LDFLAGS
 829 dnl linker flags shared by all libraries
 830 dnl LDFLAGS modifier defining exported symbols from built libraries
 831 dnl (export _gst_foo but not __gst_foo)
 832 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 833 AC_SUBST(GST_LIB_LDFLAGS)
 834
 835 dnl this really should only contain flags, not libs - they get added before
 836 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 837 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
 838 AC_SUBST(GST_PLUGIN_LDFLAGS)
 839
 840 dnl use tbm
 841 PKG_CHECK_MODULES(TBM, libdrm libtbm)
 842 AC_SUBST(TBM_CFLAGS)
 843 AC_SUBST(TBM_LIBS)
 844
 845 dnl use  mm-common
 846 PKG_CHECK_MODULES(MMCOMMON,mm-common)
 847 AC_SUBST(MMCOMMON_CFLAGS)
 848
 849 dnl *** output files ***
 850
 851 $MKDIR_P tests/check/orc
 852
 853 AC_CONFIG_FILES(
 854 Makefile
 855 gst-plugins-base.spec
 856 gst/Makefile
 857 gst/adder/Makefile
 858 gst/app/Makefile
 859 gst/audioconvert/Makefile
 860 gst/audiorate/Makefile
 861 gst/audiotestsrc/Makefile
 862 gst/encoding/Makefile
 863 gst/videoconvert/Makefile
 864 gst/gio/Makefile
 865 gst/playback/Makefile
 866 gst/audioresample/Makefile
 867 gst/subparse/Makefile
 868 gst/tcp/Makefile
 869 gst/typefind/Makefile
 870 gst/videotestsrc/Makefile
 871 gst/videorate/Makefile
 872 gst/videoscale/Makefile
 873 gst/volume/Makefile
 874 sys/Makefile
 875 sys/ximage/Makefile
 876 sys/xvimage/Makefile
 877 ext/Makefile
 878 ext/alsa/Makefile
 879 ext/cdparanoia/Makefile
 880 ext/libvisual/Makefile
 881 ext/ogg/Makefile
 882 ext/pango/Makefile
 883 ext/theora/Makefile
 884 ext/vorbis/Makefile
 885 gst-libs/Makefile
 886 gst-libs/gst/Makefile
 887 gst-libs/gst/allocators/Makefile
 888 gst-libs/gst/audio/Makefile
 889 gst-libs/gst/app/Makefile
 890 gst-libs/gst/fft/Makefile
 891 gst-libs/gst/riff/Makefile
 892 gst-libs/gst/rtp/Makefile
 893 gst-libs/gst/rtsp/Makefile
 894 gst-libs/gst/sdp/Makefile
 895 gst-libs/gst/tag/Makefile
 896 gst-libs/gst/pbutils/Makefile
 897 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 898 gst-libs/gst/video/Makefile
 899 tools/Makefile
 900 pkgconfig/Makefile
 901 pkgconfig/gstreamer-allocators.pc
 902 pkgconfig/gstreamer-allocators-uninstalled.pc
 903 pkgconfig/gstreamer-audio.pc
 904 pkgconfig/gstreamer-audio-uninstalled.pc
 905 pkgconfig/gstreamer-app.pc
 906 pkgconfig/gstreamer-app-uninstalled.pc
 907 pkgconfig/gstreamer-fft.pc
 908 pkgconfig/gstreamer-fft-uninstalled.pc
 909 pkgconfig/gstreamer-pbutils.pc
 910 pkgconfig/gstreamer-pbutils-uninstalled.pc
 911 pkgconfig/gstreamer-riff.pc
 912 pkgconfig/gstreamer-riff-uninstalled.pc
 913 pkgconfig/gstreamer-rtp.pc
 914 pkgconfig/gstreamer-rtp-uninstalled.pc
 915 pkgconfig/gstreamer-rtsp.pc
 916 pkgconfig/gstreamer-rtsp-uninstalled.pc
 917 pkgconfig/gstreamer-sdp.pc
 918 pkgconfig/gstreamer-sdp-uninstalled.pc
 919 pkgconfig/gstreamer-tag.pc
 920 pkgconfig/gstreamer-tag-uninstalled.pc
 921 pkgconfig/gstreamer-video.pc
 922 pkgconfig/gstreamer-video-uninstalled.pc
 923 pkgconfig/gstreamer-plugins-base.pc
 924 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 925 tests/Makefile
 926 tests/check/Makefile
 927 tests/examples/Makefile
 928 tests/examples/app/Makefile
 929 tests/examples/audio/Makefile
 930 tests/examples/dynamic/Makefile
 931 tests/examples/encoding/Makefile
 932 tests/examples/fft/Makefile
 933 tests/examples/gio/Makefile
 934 tests/examples/overlay/Makefile
 935 tests/examples/seek/Makefile
 936 tests/examples/snapshot/Makefile
 937 tests/examples/playback/Makefile
 938 tests/examples/playrec/Makefile
 939 tests/files/Makefile
 940 tests/icles/Makefile
 941 tests/icles/playback/Makefile
 942 docs/Makefile
 943 docs/design/Makefile
 944 docs/libs/Makefile
 945 docs/plugins/Makefile
 946 docs/version.entities
 947 po/Makefile.in
 948 common/Makefile
 949 common/m4/Makefile
 950 m4/Makefile
 951 )
 952
 953 dnl Create the config.h file for Visual Studio builds
 954 dnl Beware of spaces and /'s in some of the shell variable contents.
 955 sed \
 956     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 957     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 958     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 959     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 960     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 961     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 962     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 963     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 964     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 965     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 966     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 967     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 968     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 969     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 970     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 971     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 972     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 973     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 974     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 975     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 976     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 977     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 978     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 979     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 980     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 981     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 982     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 983     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 984     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 985     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 986     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 987     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 988     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 989     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 990     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 991     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 992     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 993     config.h.in >win32/common/config.h-new
 994
 995
 996
 997 AC_OUTPUT
 998
 999 AG_GST_OUTPUT_PLUGINS
1000 ORC_OUTPUT
1001