configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([1.31.1])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE(
 177   AC_LANG_PROGRAM([
 178 #include <libxml/HTMLparser.h>
 179                      ],[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/rtsp
 193 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 194 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 195   WIN32_LIBS="-lws2_32"
 196   AC_SUBST(WIN32_LIBS)
 197 fi
 198
 199 dnl check for hstrerror, for gst-libs/gst/rtsp
 200 save_libs="$LIBS"
 201 AC_CHECK_FUNC(hstrerror, ,
 202     AC_CHECK_LIB(resolv, hstrerror, ,
 203         [AC_DEFINE(NO_HSTRERROR, 1,
 204              [Define if you have no native hstrerror() function.])]))
 205 HSTRERROR_LIBS=$LIBS
 206 AC_SUBST(HSTRERROR_LIBS)
 207 LIBS="$save_libs"
 208
 209 dnl used in gst-libs/gst/pbutils and associated unit test
 210 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 211
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(log2)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.26])
 258
 259 ORC_CHECK([0.4.11])
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 267 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 268
 269 dnl Check for documentation xrefs
 270 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 271 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 272 AC_SUBST(GLIB_PREFIX)
 273 AC_SUBST(GST_PREFIX)
 274
 275 dnl GTK is optional and only used in examples
 276 HAVE_GTK=no
 277 HAVE_GTK_X11=no
 278 GTK_REQ=3.0.0
 279 if test "x$BUILD_EXAMPLES" = "xyes"; then
 280   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 281   dnl some examples need gtk+-x11
 282   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 283   AC_SUBST(GTK_LIBS)
 284   AC_SUBST(GTK_CFLAGS)
 285 fi
 286 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 287 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 288
 289 dnl QT is optional and only used in examples
 290 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 291   HAVE_QT_GV=yes
 292   HAVE_QT=yes
 293 ], [
 294   HAVE_QT_GV=no
 295   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 296 ])
 297 if test "x$HAVE_QT" = "xyes"; then
 298   AC_MSG_CHECKING([Qt moc])
 299   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 300   AC_MSG_RESULT($QT4_MOC)
 301   AC_SUBST(QT4_MOC)
 302 fi
 303 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 304 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 305
 306 dnl chck for linux headers needed by the joystick seek example
 307 AC_COMPILE_IFELSE(
 308 [
 309   AC_LANG_PROGRAM([
 310     #include <linux/input.h>
 311     #include <linux/joystick.h>
 312   ],[
 313     struct js_event js;
 314     js.type = JS_EVENT_AXIS;
 315   ])
 316 ], [
 317   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 318 ], [
 319   HAVE_LINUX_JOYSTICK_HEADERS="no"
 320 ])
 321 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 322
 323 dnl Check for -Bsymbolic-functions linker flag used to avoid
 324 dnl intra-library PLT jumps, if available.
 325 AC_ARG_ENABLE(Bsymbolic,
 326               [AC_HELP_STRING([--disable-Bsymbolic],
 327                               [avoid linking with -Bsymbolic])],,
 328               [SAVED_LDFLAGS="${LDFLAGS}"
 329                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 330                LDFLAGS=-Wl,-Bsymbolic-functions
 331                AC_TRY_LINK([], [int main (void) { return 0; }],
 332                            AC_MSG_RESULT(yes)
 333                            enable_Bsymbolic=yes,
 334                            AC_MSG_RESULT(no)
 335                            enable_Bsymbolic=no)
 336                LDFLAGS="${SAVED_LDFLAGS}"])
 337
 338
 339 dnl *** set variables based on configure arguments ***
 340
 341 dnl set license and copyright notice
 342 GST_LICENSE="LGPL"
 343 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 344 AC_SUBST(GST_LICENSE)
 345
 346 dnl set location of plugin directory
 347 AG_GST_SET_PLUGINDIR
 348
 349 dnl set release date/time
 350 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 351   ["${srcdir}/gst-plugins-base.doap"],
 352   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 353
 354 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 355 dnl make sure it doesn't complain about unused variables if debugging is disabled
 356 NO_WARNINGS=""
 357 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 358
 359 dnl define an ERROR_CFLAGS Makefile variable
 360 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 361 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 362     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 363     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 364     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 365     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 366
 367 dnl define an ERROR_CXXFLAGS Makefile variable
 368 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 369     -Wmissing-declarations -Wredundant-decls -Wundef
 370     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 371     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 372     -Wno-multichar $NO_WARNINGS])
 373
 374 dnl define correct level for debugging messages
 375 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 376
 377 dnl used in examples
 378 AG_GST_DEFAULT_ELEMENTS
 379
 380 dnl needed for encoding-target
 381 GST_DATADIR="$GST_PREFIX/share"
 382 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 383 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 384
 385 dnl behaviour of speex based audio resampler
 386 AC_MSG_CHECKING(which audio resample format to use for integer)
 387 AC_ARG_WITH([audioresample_format],
 388         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 389         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 390 AC_MSG_RESULT($ac_cv_audioresample_format)
 391 case $ac_cv_audioresample_format in
 392   int)
 393     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 394     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 395   ;;
 396   float)
 397     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 398     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 399   ;;
 400   auto)
 401     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 402     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 403 esac
 404
 405 dnl *** plug-ins to include ***
 406
 407 dnl these are all the gst plug-ins, compilable without additional libs
 408 AG_GST_CHECK_PLUGIN(adder)
 409 AG_GST_CHECK_PLUGIN(app)
 410 AG_GST_CHECK_PLUGIN(audioconvert)
 411 AG_GST_CHECK_PLUGIN(audiorate)
 412 AG_GST_CHECK_PLUGIN(audiotestsrc)
 413 AG_GST_CHECK_PLUGIN(encoding)
 414 AG_GST_CHECK_PLUGIN(videoconvert)
 415 AG_GST_CHECK_PLUGIN(gdp)
 416 AG_GST_CHECK_PLUGIN(playback)
 417 AG_GST_CHECK_PLUGIN(audioresample)
 418 AG_GST_CHECK_PLUGIN(subparse)
 419 AG_GST_CHECK_PLUGIN(tcp)
 420 AG_GST_CHECK_PLUGIN(typefind)
 421 AG_GST_CHECK_PLUGIN(videotestsrc)
 422 AG_GST_CHECK_PLUGIN(videorate)
 423 AG_GST_CHECK_PLUGIN(videoscale)
 424 AG_GST_CHECK_PLUGIN(volume)
 425
 426 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 427 AM_CONDITIONAL(USE_XML, false)
 428 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 429
 430 dnl disable plug-ins that require libxml2's HTML support if it is not available
 431 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 432   AG_GST_DISABLE_PLUGIN(subparse)
 433 fi
 434
 435 dnl disable plug-ins that require sys/socket.h if it is not available
 436 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 437   AG_GST_DISABLE_PLUGIN(tcp)
 438 fi
 439
 440 dnl iso-codes is optional, used by libgsttag
 441 AC_ARG_ENABLE(iso-codes,
 442 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 443 [case "${enableval}" in
 444   yes) enable_iso_codes=yes ;;
 445   no)  enable_iso_codes=no ;;
 446   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 447 esac
 448 ],
 449 [enable_iso_codes=yes]) dnl Default value
 450
 451 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 452 if test "x$enable_iso_codes" = "xyes"; then
 453   AC_MSG_RESULT([yes])
 454   have_iso_codes=no
 455   AC_MSG_CHECKING([whether iso-codes are available on this system])
 456   if $PKG_CONFIG iso-codes; then
 457     AC_MSG_RESULT([yes])
 458     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 459     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 460       AC_MSG_RESULT([yes])
 461       AC_MSG_CHECKING([for iso-codes prefix])
 462       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 463       if test -d "$ISO_CODES_PREFIX"; then
 464         AC_MSG_RESULT([yes])
 465         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 466         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 467         ISO_639_DOMAIN="iso_639"
 468         AC_MSG_CHECKING([ISO_639_DOMAIN])
 469         AC_MSG_RESULT([$ISO_639_DOMAIN])
 470         have_iso_codes=yes
 471         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 472         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 473         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 474         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 475       else
 476         AC_MSG_RESULT([no])
 477       fi
 478     else
 479       AC_MSG_RESULT([no])
 480     fi
 481   else
 482     AC_MSG_RESULT([no])
 483   fi
 484   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 485 else
 486   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 487   AM_CONDITIONAL(USE_ISO_CODES, false)
 488 fi
 489
 490 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 491 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 492 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 493   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 494       HAVE_ZLIB="yes"
 495     ], [
 496       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 497         HAVE_ZLIB="yes"
 498         ZLIB_LIBS="-lz"
 499         AC_SUBST(ZLIB_LIBS)
 500       ])
 501     ])
 502 ])
 503
 504 dnl *** sys plug-ins ***
 505
 506 echo
 507 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 508 echo
 509
 510 dnl *** X11 ***
 511 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 512 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 513                   [ximagesink], [
 514   AC_PATH_XTRA
 515   ac_cflags_save="$CFLAGS"
 516   ac_cppflags_save="$CPPFLAGS"
 517   CFLAGS="$CFLAGS $X_CFLAGS"
 518   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 519
 520   dnl now try to find the HEADER
 521   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 522
 523   if test "x$HAVE_X" = "xno"
 524   then
 525     AC_MSG_NOTICE([cannot find X11 development files])
 526   else
 527     dnl this is much more than we want
 528     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 529     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 530     dnl it does not add the libs; therefore we add them here
 531     X_LIBS="$X_LIBS -lX11"
 532     AC_SUBST(X_CFLAGS)
 533     AC_SUBST(X_LIBS)
 534   fi
 535   AC_SUBST(HAVE_X)
 536   CFLAGS="$ac_cflags_save"
 537   CPPFLAGS="$ac_cppflags_save"
 538 ])
 539
 540 dnl Check for Xv extension
 541 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 542 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 543                   [xvimagesink], [
 544   AG_GST_CHECK_XV
 545 ])
 546
 547 dnl check for X Shm
 548 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 549 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 550   if test x$HAVE_X = xyes; then
 551     AC_CHECK_LIB(Xext, XShmAttach,
 552                  HAVE_XSHM="yes", HAVE_XSHM="no",
 553                  $X_LIBS)
 554     if test "x$HAVE_XSHM" = "xyes"; then
 555       XSHM_LIBS="-lXext"
 556     else
 557       dnl On AIX, it is in XextSam instead, but we still need -lXext
 558       AC_CHECK_LIB(XextSam, XShmAttach,
 559                    HAVE_XSHM="yes", HAVE_XSHM="no",
 560                    $X_LIBS)
 561       if test "x$HAVE_XSHM" = "xyes"; then
 562         XSHM_LIBS="-lXext -lXextSam"
 563       fi
 564     fi
 565   fi
 566 ], , [
 567   AC_SUBST(HAVE_XSHM)
 568   AC_SUBST(XSHM_LIBS)
 569 ])
 570
 571 dnl *** ext plug-ins ***
 572 dnl keep this list sorted alphabetically !
 573
 574 if test "x$BUILD_EXTERNAL" = "xyes"; then
 575
 576 echo
 577 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 578 echo
 579
 580 dnl *** alsa ***
 581 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 582 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 583   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 584     HAVE_ALSA="yes"
 585     AC_SUBST(ALSA_CFLAGS)
 586     AC_SUBST(ALSA_LIBS)
 587   ], [
 588     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 589   ])
 590 ])
 591
 592 dnl *** CDParanoia ***
 593 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 594 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 595 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 596   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 597     HAVE_CDPARANOIA="yes"
 598   ], [
 599     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 600                         cdda_open, -lm,
 601                         cdda_interface.h,
 602                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 603                         HEADER_DIR="no"
 604                         FOUND_CDPARANOIA="yes")
 605     if test "x$FOUND_CDPARANOIA" != "xyes";
 606     then
 607       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 608                           cdda_open, -lm,
 609                           cdda/cdda_interface.h,
 610                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 611                           HEADER_DIR="yes"
 612                           FOUND_CDPARANOIA="yes")
 613     fi
 614     if test "x$HEADER_DIR" = "xyes";
 615     then
 616       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 617                          defined if cdda headers are in a cdda/ directory)
 618     fi
 619     if test "x$FOUND_CDPARANOIA" = "xyes";
 620     then
 621       AC_CHECK_LIB(cdda_paranoia,
 622                    paranoia_cachemodel_size,
 623                    : ,
 624                    HAVE_CDPARANOIA=no,
 625                  [-lcdda_interface])
 626     fi
 627
 628     AC_SUBST(CDPARANOIA_LIBS)
 629   ])
 630 ])
 631 dnl FIXME : add second check somehow if that is necessary
 632 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 633 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 634
 635 dnl *** ivorbis ***
 636 dnl AM_PATH_IVORBIS only takes two options
 637 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 638 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 639   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 640   if test $HAVE_IVORBIS = no
 641   then
 642     IVORBIS_LIBS=
 643     IVORBIS_CFLAGS=
 644     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 645       [IVORBIS_LIBS=-lvorbisidec
 646       HAVE_IVORBIS=yes
 647       case $host in
 648       arm-*-*)
 649         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 650       esac
 651       ],
 652       HAVE_IVORBIS=no)
 653     AC_SUBST(IVORBIS_LIBS)
 654     AC_SUBST(IVORBIS_CFLAGS)
 655   else
 656     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 657       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 658       USE_TREMOLO=no)
 659   fi
 660 ])
 661
 662 dnl *** libgio ***
 663 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 664 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 665   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 666     HAVE_GIO="yes"
 667     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 668     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 669            [The GIO modules directory.])
 670     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 671     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 672            [The GIO library directory.])
 673   ], [
 674     HAVE_GIO="no"
 675   ])
 676   AC_SUBST(GIO_CFLAGS)
 677   AC_SUBST(GIO_LIBS)
 678   AC_SUBST(GIO_LDFLAGS)
 679 ])
 680
 681 dnl *** libvisual ***
 682 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 683 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 684   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 685   if test $HAVE_LIBVISUAL = no
 686   then
 687     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 688     if test x$HAVE_LIBVISUAL = xyes; then
 689       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 690     fi
 691   else
 692     if test x$HAVE_LIBVISUAL = xyes; then
 693       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 694     fi
 695   fi
 696   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 697   if test x$LIBVIS_PLUGINSDIR != x; then
 698     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 699         "$LIBVIS_PLUGINSDIR",
 700         [directory in which the detected libvisual's plugins are located])
 701   fi
 702 ])
 703
 704 dnl *** ogg ***
 705 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 706 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 707   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 708   if test $HAVE_OGG = no
 709   then
 710     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 711     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 712   fi
 713 ])
 714
 715 dnl *** pango ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 717 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 718   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 719 ])
 720
 721 dnl *** theora ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 723 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 724   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 725 ])
 726
 727 dnl *** vorbis ***
 728 dnl AM_PATH_VORBIS only takes two options
 729 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 730 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 731   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 732   if test $HAVE_VORBIS = no
 733   then
 734     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 735     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 736   fi
 737 ])
 738
 739 if test "x$HAVE_VORBIS" = "xyes"; then
 740   ac_cflags_save="$CFLAGS"
 741   AC_COMPILE_IFELSE(
 742     AC_LANG_PROGRAM([
 743 #include <vorbis/codec.h>
 744                      ],[
 745 vorbis_dsp_state *v;
 746
 747 vorbis_synthesis_restart (v);
 748                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 749   if test "x$HAVE_VSR" = "xyes"; then
 750     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 751                        [defined if vorbis_synthesis_restart is present])
 752   fi
 753   CFLAGS="$ac_cflags_save"
 754 fi
 755
 756 else
 757
 758 dnl not building plugins with external dependencies,
 759 dnl but we still need to set the conditionals
 760 AM_CONDITIONAL(USE_ALSA, false)
 761 AM_CONDITIONAL(USE_CDPARANOIA, false)
 762 AM_CONDITIONAL(USE_GIO, false)
 763 AM_CONDITIONAL(USE_IVORBIS, false)
 764 AM_CONDITIONAL(USE_LIBVISUAL, false)
 765 AM_CONDITIONAL(USE_OGG, false)
 766 AM_CONDITIONAL(USE_PANGO, false)
 767 AM_CONDITIONAL(USE_THEORA, false)
 768 AM_CONDITIONAL(USE_VORBIS, false)
 769
 770 fi dnl of EXT plugins
 771
 772 dnl seeking needs freetype, so check for it here
 773 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 774   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 775 ])
 776 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 777 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 778 AC_SUBST(FT2_CFLAGS)
 779 AC_SUBST(FT2_LIBS)
 780
 781 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 782
 783 dnl Overview:
 784 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 785 dnl GST_*:              flags shared by built objects to link against GStreamer
 786 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 787 dnl                          (compare to other modules) or for i18n
 788 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 789 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 790 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 791 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 792
 793 dnl GST_OPTION_CFLAGS
 794 if test "x$USE_DEBUG" = xyes; then
 795    PROFILE_CFLAGS="-g"
 796 fi
 797 AC_SUBST(PROFILE_CFLAGS)
 798
 799 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 800   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 801   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 802 else
 803   DEPRECATED_CFLAGS=""
 804 fi
 805 AC_SUBST(DEPRECATED_CFLAGS)
 806
 807 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 808 dnl at make time with e.g. make ERROR_CFLAGS=""
 809 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 810 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 811 AC_SUBST(GST_OPTION_CFLAGS)
 812 AC_SUBST(GST_OPTION_CXXFLAGS)
 813
 814 dnl our libraries need to be versioned correctly
 815 AC_SUBST(GST_LT_LDFLAGS)
 816
 817 dnl GST_PLUGINS_BASE_CFLAGS
 818 dnl prefer internal headers to already installed ones
 819 dnl also add builddir include for enumtypes and marshal
 820 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 821 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 822
 823 dnl FIXME: do we want to rename to GST_ALL_* ?
 824 dnl add GST_OPTION_CFLAGS, but overridable
 825 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 826 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 827 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 828 AC_SUBST(GST_CFLAGS)
 829 AC_SUBST(GST_CXXFLAGS)
 830 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 831 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 832 AC_SUBST(GST_LIBS)
 833
 834 dnl LDFLAGS really should only contain flags, not libs - they get added before
 835 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 836 GST_ALL_LDFLAGS="-no-undefined"
 837 if test "x${enable_Bsymbolic}" = "xyes"; then
 838   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 839 fi
 840 AC_SUBST(GST_ALL_LDFLAGS)
 841
 842 dnl GST_LIB_LDFLAGS
 843 dnl linker flags shared by all libraries
 844 dnl LDFLAGS modifier defining exported symbols from built libraries
 845 dnl (export _gst_foo but not __gst_foo)
 846 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 847 AC_SUBST(GST_LIB_LDFLAGS)
 848
 849 dnl this really should only contain flags, not libs - they get added before
 850 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 851 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 852 AC_SUBST(GST_PLUGIN_LDFLAGS)
 853
 854 dnl *** output files ***
 855
 856 AC_CONFIG_FILES(
 857 Makefile
 858 gst-plugins-base.spec
 859 gst/Makefile
 860 gst/adder/Makefile
 861 gst/app/Makefile
 862 gst/audioconvert/Makefile
 863 gst/audiorate/Makefile
 864 gst/audiotestsrc/Makefile
 865 gst/encoding/Makefile
 866 gst/videoconvert/Makefile
 867 gst/gdp/Makefile
 868 gst/playback/Makefile
 869 gst/audioresample/Makefile
 870 gst/subparse/Makefile
 871 gst/tcp/Makefile
 872 gst/typefind/Makefile
 873 gst/videotestsrc/Makefile
 874 gst/videorate/Makefile
 875 gst/videoscale/Makefile
 876 gst/volume/Makefile
 877 sys/Makefile
 878 sys/ximage/Makefile
 879 sys/xvimage/Makefile
 880 ext/Makefile
 881 ext/alsa/Makefile
 882 ext/cdparanoia/Makefile
 883 ext/gio/Makefile
 884 ext/libvisual/Makefile
 885 ext/ogg/Makefile
 886 ext/pango/Makefile
 887 ext/theora/Makefile
 888 ext/vorbis/Makefile
 889 gst-libs/Makefile
 890 gst-libs/gst/Makefile
 891 gst-libs/gst/audio/Makefile
 892 gst-libs/gst/app/Makefile
 893 gst-libs/gst/fft/Makefile
 894 gst-libs/gst/interfaces/Makefile
 895 gst-libs/gst/riff/Makefile
 896 gst-libs/gst/rtp/Makefile
 897 gst-libs/gst/rtsp/Makefile
 898 gst-libs/gst/sdp/Makefile
 899 gst-libs/gst/tag/Makefile
 900 gst-libs/gst/pbutils/Makefile
 901 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 902 gst-libs/gst/video/Makefile
 903 tools/Makefile
 904 pkgconfig/Makefile
 905 pkgconfig/gstreamer-audio.pc
 906 pkgconfig/gstreamer-audio-uninstalled.pc
 907 pkgconfig/gstreamer-app.pc
 908 pkgconfig/gstreamer-app-uninstalled.pc
 909 pkgconfig/gstreamer-fft.pc
 910 pkgconfig/gstreamer-fft-uninstalled.pc
 911 pkgconfig/gstreamer-interfaces.pc
 912 pkgconfig/gstreamer-interfaces-uninstalled.pc
 913 pkgconfig/gstreamer-pbutils.pc
 914 pkgconfig/gstreamer-pbutils-uninstalled.pc
 915 pkgconfig/gstreamer-riff.pc
 916 pkgconfig/gstreamer-riff-uninstalled.pc
 917 pkgconfig/gstreamer-rtp.pc
 918 pkgconfig/gstreamer-rtp-uninstalled.pc
 919 pkgconfig/gstreamer-rtsp.pc
 920 pkgconfig/gstreamer-rtsp-uninstalled.pc
 921 pkgconfig/gstreamer-sdp.pc
 922 pkgconfig/gstreamer-sdp-uninstalled.pc
 923 pkgconfig/gstreamer-tag.pc
 924 pkgconfig/gstreamer-tag-uninstalled.pc
 925 pkgconfig/gstreamer-video.pc
 926 pkgconfig/gstreamer-video-uninstalled.pc
 927 pkgconfig/gstreamer-plugins-base.pc
 928 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 929 tests/Makefile
 930 tests/check/Makefile
 931 tests/examples/Makefile
 932 tests/examples/app/Makefile
 933 tests/examples/audio/Makefile
 934 tests/examples/dynamic/Makefile
 935 tests/examples/encoding/Makefile
 936 tests/examples/fft/Makefile
 937 tests/examples/gio/Makefile
 938 tests/examples/overlay/Makefile
 939 tests/examples/seek/Makefile
 940 tests/examples/snapshot/Makefile
 941 tests/examples/playrec/Makefile
 942 tests/files/Makefile
 943 tests/icles/Makefile
 944 tests/icles/playback/Makefile
 945 docs/Makefile
 946 docs/design/Makefile
 947 docs/libs/Makefile
 948 docs/plugins/Makefile
 949 docs/version.entities
 950 po/Makefile.in
 951 common/Makefile
 952 common/m4/Makefile
 953 m4/Makefile
 954 )
 955
 956 dnl Create the config.h file for Visual Studio builds
 957 dnl Beware of spaces and /'s in some of the shell variable contents.
 958 sed \
 959     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 960     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 961     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 962     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 963     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 964     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 965     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 966     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 967     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 968     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 969     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 970     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 971     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 972     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 973     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 974     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 975     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 976     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 977     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 978     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 979     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 980     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 981     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 982     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 983     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 984     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 985     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 986     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 987     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 988     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 989     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 990     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 991     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 992     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 993     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 994     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 995     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 996     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 997     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 998     config.h.in >win32/common/config.h-new
 999
1000
1001
1002 AC_OUTPUT
1003
1004 AG_GST_OUTPUT_PLUGINS
1005 ORC_OUTPUT
1006