configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [12])
   6 m4_define([dbus_micro_version], [6])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 m4_pattern_forbid([^AX_],
  14   [Unexpanded AX_ macro found. Please install GNU autoconf-archive])
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 AM_INIT_AUTOMAKE([1.13 tar-ustar -Wno-portability subdir-objects])
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27 # By default, rebuild autotools files on demand; only use ./missing if the
  28 # user says --disable-maintainer-mode (some distributions like to do this)
  29 AM_MAINTAINER_MODE([enable])
  30
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32
  33 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  34
  35 # libtool versioning - this applies to libdbus
  36 #
  37 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  38 #
  39
  40 ## increment if the interface has additions, changes, removals.
  41 LT_CURRENT=22
  42
  43 ## increment any time the source changes; set to
  44 ##  0 if you increment CURRENT
  45 LT_REVISION=6
  46
  47 ## increment if any interfaces have been added; set to 0
  48 ## if any interfaces have been changed or removed. removal has
  49 ## precedence over adding, so set to 0 if both happened.
  50 LT_AGE=19
  51
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  56 AC_SUBST([SOVERSION])
  57
  58 DBUS_MAJOR_VERSION=dbus_major_version
  59 DBUS_MINOR_VERSION=dbus_minor_version
  60 DBUS_MICRO_VERSION=dbus_micro_version
  61 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  62
  63 AC_SUBST(DBUS_MAJOR_VERSION)
  64 AC_SUBST(DBUS_MINOR_VERSION)
  65 AC_SUBST(DBUS_MICRO_VERSION)
  66 AC_SUBST(DBUS_VERSION)
  67
  68 dnl
  69 dnl Build configuration
  70 dnl
  71
  72 dnl This must come first: other options use this to set their defaults. Don't
  73 dnl enable developer mode on production builds.
  74 AC_ARG_ENABLE([developer],
  75   [AS_HELP_STRING([--enable-developer],
  76     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  77   [enable_developer=$enableval],
  78   [enable_developer=no])
  79
  80 dnl 'disable_developer' is the negation of 'enable_developer'. If
  81 dnl 'enable-developer' is set to 'no' (the default), the value of
  82 dnl 'disable_developer' is set to 'yes', and vice versa. It's used
  83 dnl for macros that require the opposite of 'enable_developer', such
  84 dnl as several AX_ macros.
  85 dnl See https://bugs.freedesktop.org/show_bug.cgi?id=97357
  86 AS_IF([test "x$enable_developer" = "xyes"],[
  87     disable_developer=no
  88   ],[
  89     disable_developer=yes
  90   ])
  91
  92 # The debugging check must run before the compiler tests. Other command-line
  93 # options also use it to set their defaults. We disable debugging by default,
  94 # except for developer builds.
  95 AX_CHECK_ENABLE_DEBUG([$enable_developer])
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_CXX
 100 AC_USE_SYSTEM_EXTENSIONS
 101 AC_SYS_LARGEFILE
 102 AC_ISC_POSIX
 103 AC_HEADER_STDC
 104 AC_C_INLINE
 105 AM_PROG_LIBTOOL
 106 AC_PROG_MKDIR_P
 107 PKG_PROG_PKG_CONFIG
 108
 109 # TAP test driver support
 110 AC_PROG_AWK
 111 AC_REQUIRE_AUX_FILE([tap-driver.sh])
 112
 113 # This must come before we set up compiler warnings because it assumes
 114 # non-use of -Werror=missing-prototypes
 115 gl_VISIBILITY
 116 AM_CONDITIONAL([HAVE_VISIBILITY], [test "x$HAVE_VISIBILITY" = x1])
 117
 118 # Initialize libtool
 119 LT_INIT([win32-dll])
 120 LT_LANG([Windows Resource])
 121
 122 # Set some internal variables depending on the platform for later use.
 123 dbus_win=no
 124 dbus_cygwin=no
 125 dbus_unix=no
 126 case "${host}" in
 127     *-mingw32ce*)
 128         dbus_win=yes
 129         dbus_wince=yes
 130         ;;
 131     *-mingw32*)
 132         dbus_win=yes
 133         ;;
 134     *-cygwin*)
 135         dbus_cygwin=yes
 136         dbus_unix=yes
 137         ;;
 138     *)
 139         dbus_unix=yes
 140        ;;
 141 esac
 142
 143 # Special defines for certain platforms
 144 if test "$dbus_win" = yes; then
 145     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 146     # Yes, on Windows it really does work like this.
 147     # http://support.microsoft.com/kb/111855
 148     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 149     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 150     AC_SUBST(BUILD_TIMESTAMP)
 151     # Assume DBUS_VERSION is always three numbers
 152     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 153     AC_SUBST(BUILD_FILEVERSION)
 154     AS_IF([test -z "$RC"],
 155         [AC_MSG_ERROR([An implementation of windres is required])])
 156     if test "$dbus_wince" = yes; then
 157       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 158       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 159     fi
 160 else
 161     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 162 fi
 163 if test "$dbus_cygwin" = yes; then
 164     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 165 fi
 166
 167 # For best security, assume that all non-Windows platforms can do
 168 # credentials-passing.
 169 AS_IF([test "$dbus_win" = yes],
 170     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<!--<auth>EXTERNAL</auth>-->"],
 171     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<auth>EXTERNAL</auth>"])
 172 AC_SUBST([DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL])
 173
 174 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 175 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 176 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 177 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 178
 179 DBUS_STATIC_BUILD_CPPFLAGS=
 180 if test "x$enable_shared" = xno; then
 181     # On Windows, linking against the static library requires special effort
 182     # to turn off DLL import/export processing. We normally link some things
 183     # against the dynamic library, but if we're not building that, we'll
 184     # have to link everything statically.
 185     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 186 fi
 187 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 188
 189 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 190 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 191 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 192 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 193 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 194 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 195 AC_ARG_ENABLE([ducktype-docs],
 196               AS_HELP_STRING([--enable-ducktype-docs],
 197                              [build Ducktype documentation (requires Ducktype)]),
 198               [enable_ducktype_docs=$enableval], [enable_ducktype_docs=auto])
 199 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 200 AC_ARG_ENABLE([apparmor],
 201   [AS_HELP_STRING([--enable-apparmor], [build with AppArmor support])],
 202   [enable_apparmor=$enableval],
 203   [enable_apparmor=auto])
 204 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 205 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 206 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 207 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 208 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 209 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 210
 211 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 212 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 213 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 214 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 215 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 216 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 217 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 218 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 219 AC_ARG_WITH([test_user],
 220   [AS_HELP_STRING([--with-test-user=<user>],
 221     [Unprivileged user for regression tests, other than root and the dbus_user (default: nobody)])])
 222 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 223
 224 AC_ARG_ENABLE([embedded-tests],
 225   AS_HELP_STRING([--enable-embedded-tests],
 226     [enable unit test code in the library and binaries]),
 227   [], [enable_embedded_tests=$enable_developer])
 228 AC_ARG_ENABLE([modular-tests],
 229   AS_HELP_STRING([--enable-modular-tests],
 230     [enable modular regression tests (requires GLib)]),
 231   [], [enable_modular_tests=auto])
 232 # --enable-tests overrides both --enable-embedded-tests and
 233 # --enable-modular-tests
 234 AC_ARG_ENABLE([tests],
 235   AS_HELP_STRING([--enable-tests],
 236     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 237   [
 238   if test "x$enableval" = xyes; then
 239     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 240     AC_MSG_NOTICE([This has many dependencies (GLib, Python etc.)])
 241   fi
 242   enable_embedded_tests=$enableval
 243   enable_modular_tests=$enableval
 244   ],
 245   [])
 246
 247 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 248 # and also some stuff in the test/ subdir.
 249 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 250   [test "x$enable_embedded_tests" = xyes])
 251 if test "x$enable_embedded_tests" = xyes; then
 252     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 253       [Define to build test code into the library and binaries])
 254 fi
 255
 256 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 257 # These use GTest, from GLib, because life's too short. They're enabled by
 258 # default (unless you don't have GLib), because they don't bloat the library
 259 # or binaries.
 260
 261 dnl Don't do anything too subtle here, because the CMake build system
 262 dnl parses these lines with regular expressions. If necessary, adjust
 263 dnl cmake/modules/MacrosAutotools.cmake to compensate.
 264 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_40], [Ignore post-2.40 deprecations])
 265 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [G_ENCODE_VERSION(2,44)], [Prevent post-2.44 APIs])
 266
 267 with_glib=yes
 268
 269 AS_IF([test "x$enable_modular_tests" != xno],
 270   [
 271   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.40, gio-2.0 >= 2.40],
 272     [
 273       AS_IF([test "x$dbus_unix" = xyes],
 274         [PKG_CHECK_MODULES([GIO_UNIX], [gio-unix-2.0],
 275            [AC_DEFINE([HAVE_GIO_UNIX], [1], [Define if you have gio-unix-2.0])], [])])
 276     ],
 277     [if test "x$enable_modular_tests" = xyes; then
 278       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 279       AC_MSG_ERROR([$GLIB_ERRORS])
 280     else # assumed to be "auto"
 281       with_glib=no
 282     fi])
 283   ],
 284   [with_glib=no])
 285
 286 if test "x$enable_modular_tests" != xno; then
 287   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 288     [Define to build independent test binaries])
 289 fi
 290 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 291   [test "x$enable_modular_tests" != xno])
 292
 293 if test "x$with_glib" != xno; then
 294   AC_DEFINE([DBUS_WITH_GLIB], [1],
 295     [Define if GLib, GObject, GIO are available])
 296 fi
 297 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 298
 299 AC_ARG_ENABLE([installed-tests],
 300   AS_HELP_STRING([--enable-installed-tests],
 301     [enable unit test code in the library and binaries]),
 302   [], [enable_installed_tests=no])
 303 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 304   [test "x$enable_installed_tests" = xyes])
 305
 306 if test "x$enable_tests" = xyes; then
 307   # full test coverage is required, Python is a hard dependency
 308   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 309   AM_PATH_PYTHON([2.6])
 310   AC_MSG_CHECKING([for Python modules for full test coverage])
 311   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 312     AC_MSG_RESULT([yes])
 313   else
 314     AC_MSG_RESULT([no])
 315     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 316   fi
 317 else
 318   # --enable-tests not given: do not abort if Python is missing
 319   AM_PATH_PYTHON([2.6], [], [:])
 320 fi
 321
 322 if test x$enable_verbose_mode = xyes; then
 323     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 324 fi
 325
 326 dnl Intentional:
 327 dnl - $DISABLE_WARNINGS disables unused-label warnings if not
 328 dnl   checking or not asserting (tested further below)
 329 dnl - we are not going to stop using deprecated functions on a stable
 330 dnl   branch
 331 dnl - missing field initializers being 0 is a C feature, not a bug
 332 dnl - unused-parameter is to make writing callbacks less annoying
 333 DISABLE_WARNINGS="$DISABLE_WARNINGS
 334                   -Wno-deprecated-declarations
 335                   -Wno-missing-field-initializers
 336                   -Wno-unused-parameter"
 337
 338 if test x$enable_asserts = xno; then
 339     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 340     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 341     R_DYNAMIC_LDFLAG=""
 342     if test x$enable_embedded_tests = xyes; then
 343         DISABLE_WARNINGS="$DISABLE_WARNINGS
 344                           -Wno-unused-but-set-variable
 345                           -Wno-unused-variable
 346                           -Wno-unused-function"
 347     fi
 348 else
 349     # -rdynamic is needed for glibc's backtrace_symbols to work.
 350     # No clue how much overhead this adds, but it's useful
 351     # to do this on any assertion failure,
 352     # so for now it's enabled anytime asserts are (currently not
 353     # in production builds).
 354
 355     # To get -rdynamic you pass -export-dynamic to libtool.
 356     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 357     R_DYNAMIC_LDFLAG=-export-dynamic
 358 fi
 359 AC_SUBST(R_DYNAMIC_LDFLAG)
 360
 361 if test x$enable_checks = xno; then
 362     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 363     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 364     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 365 fi
 366
 367 AH_BOTTOM([
 368 /* explicitly define these macros to get less confusing conditions */
 369 #ifndef DBUS_DISABLE_ASSERT
 370 #  define DBUS_ENABLE_ASSERT 1
 371 #endif
 372 #ifndef DBUS_DISABLE_CHECKS
 373 #  define DBUS_ENABLE_CHECKS 1
 374 #endif])
 375
 376 # Test for code-coverage tools if --enable-code-coverage
 377 AX_CODE_COVERAGE
 378
 379 AS_IF([test x$enable_code_coverage = xyes],[
 380     AC_DEFINE_UNQUOTED(
 381       [DBUS_GCOV_ENABLED], [1],
 382       [Defined if gcov is enabled to force a rebuild due to config.h changing])
 383   ])
 384
 385 #### Integer sizes
 386
 387 AC_CHECK_SIZEOF(char)
 388 AC_CHECK_SIZEOF(short)
 389 AC_CHECK_SIZEOF(long)
 390 AC_CHECK_SIZEOF(int)
 391 AC_CHECK_SIZEOF(void *)
 392 AC_CHECK_SIZEOF(long long)
 393 AC_CHECK_SIZEOF(__int64)
 394
 395 ### See what our 64 bit type is called
 396 AC_MSG_CHECKING([64-bit integer type])
 397
 398 case 8 in
 399 $ac_cv_sizeof_int)
 400   dbusint64=int
 401   dbusint64_constant='(val)'
 402   dbusuint64_constant='(val)'
 403   ;;
 404 $ac_cv_sizeof_long)
 405   dbusint64=long
 406   dbusint64_constant='(val##L)'
 407   dbusuint64_constant='(val##UL)'
 408   ;;
 409 $ac_cv_sizeof_long_long)
 410   dbusint64='long long'
 411   dbusint64_constant='(val##LL)'
 412   dbusuint64_constant='(val##ULL)'
 413   ;;
 414 $ac_cv_sizeof___int64)
 415   dbusint64=__int64
 416   dbusint64_constant='(val##i64)'
 417   dbusuint64_constant='(val##ui64)'
 418   ;;
 419 esac
 420
 421 AS_IF(
 422   [test -z "$dbusint64"],
 423   [AC_MSG_RESULT([not found])
 424   AC_MSG_ERROR([Could not find a 64-bit integer type.
 425
 426 Please report a bug here with details of your platform and compiler:
 427
 428     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 429   ],
 430   dnl else
 431   [
 432         DBUS_INT64_TYPE="$dbusint64"
 433         DBUS_INT64_CONSTANT="$dbusint64_constant"
 434         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 435         AC_MSG_RESULT($DBUS_INT64_TYPE)
 436   ])
 437
 438 AC_SUBST(DBUS_INT64_TYPE)
 439 AC_SUBST(DBUS_INT64_CONSTANT)
 440 AC_SUBST(DBUS_UINT64_CONSTANT)
 441
 442 ### see what 32-bit int is called
 443 AC_MSG_CHECKING([32-bit integer type])
 444
 445 case 4 in
 446 $ac_cv_sizeof_short)
 447   dbusint32=short
 448   ;;
 449 $ac_cv_sizeof_int)
 450   dbusint32=int
 451   ;;
 452 $ac_cv_sizeof_long)
 453   dbusint32=long
 454   ;;
 455 esac
 456
 457 if test -z "$dbusint32" ; then
 458         DBUS_INT32_TYPE="no_int32_type_detected"
 459         AC_MSG_ERROR([No 32-bit integer type found])
 460 else
 461         DBUS_INT32_TYPE="$dbusint32"
 462         AC_MSG_RESULT($DBUS_INT32_TYPE)
 463 fi
 464
 465 AC_SUBST(DBUS_INT32_TYPE)
 466
 467 ### see what 16-bit int is called
 468 AC_MSG_CHECKING([16-bit integer type])
 469
 470 case 2 in
 471 $ac_cv_sizeof_short)
 472   dbusint16=short
 473   ;;
 474 $ac_cv_sizeof_int)
 475   dbusint16=int
 476   ;;
 477 esac
 478
 479 if test -z "$dbusint16" ; then
 480         DBUS_INT16_TYPE="no_int16_type_detected"
 481         AC_MSG_ERROR([No 16-bit integer type found])
 482 else
 483         DBUS_INT16_TYPE="$dbusint16"
 484         AC_MSG_RESULT($DBUS_INT16_TYPE)
 485 fi
 486
 487 AC_SUBST(DBUS_INT16_TYPE)
 488
 489 ## byte order
 490 case $host_os in
 491         darwin*)
 492                 # check at compile-time, so that it is possible to build universal
 493                 # (with multiple architectures at once on the compile line)
 494                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 495                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 496                         #if defined(__BIG_ENDIAN__)
 497                         #define WORDS_BIGENDIAN 1
 498                         #endif
 499                 ])
 500                 ;;
 501         *)
 502                 AC_C_BIGENDIAN
 503                 ;;
 504 esac
 505
 506 # As a GNU extension, glibc declares environ in unistd.h, which is one of
 507 # the AC_INCLUDES_DEFAULT.
 508 AC_CHECK_DECLS([environ])
 509
 510 dnl **********************************
 511 dnl *** va_copy checks (from GLib) ***
 512 dnl **********************************
 513 dnl we currently check for all three va_copy possibilities, so we get
 514 dnl all results in config.log for bug reports.
 515 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 516         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 517 #include <stdlib.h>
 518         static void f (int i, ...) {
 519         va_list args1, args2;
 520         va_start (args1, i);
 521         va_copy (args2, args1);
 522         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 523           exit (1);
 524         va_end (args1); va_end (args2);
 525         }
 526         int main() {
 527           f (0, 42);
 528           return 0;
 529         }])],
 530         [dbus_cv_va_copy=yes],
 531         [dbus_cv_va_copy=no])
 532 ])
 533 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 534         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 535 #include <stdlib.h>
 536         static void f (int i, ...) {
 537         va_list args1, args2;
 538         va_start (args1, i);
 539         __va_copy (args2, args1);
 540         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 541           exit (1);
 542         va_end (args1); va_end (args2);
 543         }
 544         int main() {
 545           f (0, 42);
 546           return 0;
 547         }])],
 548         [dbus_cv___va_copy=yes],
 549         [dbus_cv___va_copy=no])
 550 ])
 551
 552 if test "x$dbus_cv_va_copy" = "xyes"; then
 553   dbus_va_copy_func=va_copy
 554 else if test "x$dbus_cv___va_copy" = "xyes"; then
 555   dbus_va_copy_func=__va_copy
 556 fi
 557 fi
 558
 559 if test -n "$dbus_va_copy_func"; then
 560   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 561 fi
 562
 563 AC_LANG_PUSH(C)
 564 AC_CACHE_CHECK([whether va_lists can be copied by value],
 565         dbus_cv_va_val_copy,
 566         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 567 [[
 568         #include <stdarg.h>
 569         #include <stdlib.h>
 570 ]],
 571 [[
 572         static void f (int i, ...) {
 573         va_list args1, args2;
 574         va_start (args1, i);
 575         args2 = args1;
 576         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 577           exit (1);
 578         va_end (args1); va_end (args2);
 579         }
 580         int main() {
 581           f (0, 42);
 582           return 0;
 583         }
 584 ]])],
 585         [dbus_cv_va_val_copy=yes],
 586         [dbus_cv_va_val_copy=no],
 587         [dbus_cv_va_val_copy=yes])
 588 ])
 589 AC_LANG_POP(C)
 590
 591 if test "x$dbus_cv_va_val_copy" = "xno"; then
 592   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 593 fi
 594
 595
 596 #### Atomic integers
 597
 598 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 599   dbus_cv_sync_sub_and_fetch,
 600   [AC_LINK_IFELSE([
 601      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 602      [dbus_cv_sync_sub_and_fetch=yes],
 603      [dbus_cv_sync_sub_and_fetch=no])
 604   ])
 605
 606 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 607    have_sync=1
 608 else
 609    have_sync=0
 610 fi
 611
 612 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 613
 614 #### Various functions
 615 AC_SEARCH_LIBS(socket,[socket network])
 616 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 617
 618 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid setresuid getrlimit prlimit])
 619
 620 AC_CHECK_HEADERS([syslog.h])
 621 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 622   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 623 fi
 624
 625 # For test-segfault.c
 626 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 627 AC_CHECK_FUNCS_ONCE([prctl raise])
 628
 629 #### Check for broken poll; taken from Glib's configure
 630
 631 AC_MSG_CHECKING([for broken poll])
 632 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 633     #include <stdlib.h>
 634     #include <fcntl.h>
 635     #include <poll.h>
 636     #ifdef HAVE_SYS_POLL_H
 637     #include <sys/poll.h>
 638     #endif
 639     int main(void) {
 640       struct pollfd fds[1];
 641       int fd;
 642       fd = open("/dev/null", 1);
 643       fds[0].fd = fd;
 644       fds[0].events = POLLIN;
 645       fds[0].revents = 0;
 646       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 647             exit(1);  /* Does not work for devices -- fail */
 648       }
 649       exit(0);
 650     }]])],
 651   [broken_poll=no],
 652   [broken_poll=yes
 653    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 654   [broken_poll="no (cross compiling)"])
 655 AC_MSG_RESULT($broken_poll)
 656
 657 AC_MSG_CHECKING(for dirfd)
 658 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 659 #include <sys/types.h>
 660 #include <dirent.h>
 661 ]], [[
 662 DIR *dirp;
 663 dirp = opendir(".");
 664 dirfd(dirp);
 665 closedir(dirp);
 666 ]])],
 667 [dbus_have_dirfd=yes],
 668 [dbus_have_dirfd=no])
 669 AC_MSG_RESULT($dbus_have_dirfd)
 670 if test "$dbus_have_dirfd" = yes; then
 671         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 672 else
 673         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 674         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 675 #include <sys/types.h>
 676 #include <dirent.h>
 677         ]], [[
 678 DIR *dirp;
 679 int fd;
 680 dirp = opendir(".");
 681 fd = dirp->dd_fd;
 682 closedir(dirp);
 683         ]])],
 684         [dbus_have_ddfd=yes],
 685         [dbus_have_ddfd=no])
 686         AC_MSG_RESULT($dbus_have_ddfd)
 687         if test "$dbus_have_ddfd" = yes; then
 688                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 689         fi
 690 fi
 691
 692 AC_CHECK_HEADERS(sys/resource.h)
 693 AC_CHECK_HEADERS([sys/time.h])
 694
 695 AC_CHECK_HEADERS(dirent.h)
 696
 697 AC_CHECK_HEADERS([execinfo.h],
 698         [AC_SEARCH_LIBS([backtrace], [execinfo],
 699                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 700                         [Define to 1 if you have backtrace().])])])
 701
 702 AC_CHECK_HEADERS(errno.h)
 703
 704 AC_CHECK_HEADERS(signal.h)
 705
 706 AC_CHECK_HEADERS(locale.h)
 707
 708 AC_CHECK_HEADERS(byteswap.h)
 709
 710 AC_CHECK_HEADERS(unistd.h)
 711
 712 AC_CHECK_HEADERS([stdint.h])
 713
 714 AC_CHECK_HEADERS(ws2tcpip.h)
 715
 716 AC_CHECK_HEADERS(alloca.h)
 717
 718 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 719 #
 720 case $host_os in
 721     solaris*)
 722        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 723 esac
 724
 725 # checking for a posix version of getpwnam_r
 726 # if we are cross compiling and can not run the test
 727 # assume getpwnam_r is the posix version
 728 # it is up to the person cross compiling to change
 729 # this behavior if desired
 730 AC_LANG_PUSH(C)
 731 AC_CACHE_CHECK([for posix getpwnam_r],
 732                 ac_cv_func_posix_getpwnam_r,
 733                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 734 [[
 735 #include <errno.h>
 736 #include <pwd.h>
 737 ]],
 738 [[
 739     char buffer[10000];
 740     struct passwd pwd, *pwptr = &pwd;
 741     int error;
 742     errno = 0;
 743     error = getpwnam_r ("", &pwd, buffer,
 744                         sizeof (buffer), &pwptr);
 745    return (error < 0 && errno == ENOSYS)
 746            || error == ENOSYS;
 747 ]])],
 748         [ac_cv_func_posix_getpwnam_r=yes],
 749         [ac_cv_func_posix_getpwnam_r=no],
 750         [ac_cv_func_posix_getpwnam_r=yes]
 751 )])
 752 AC_LANG_POP(C)
 753
 754 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 755         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 756                 [Have POSIX function getpwnam_r])
 757 else
 758         AC_CACHE_CHECK([for nonposix getpwnam_r],
 759                 ac_cv_func_nonposix_getpwnam_r,
 760                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 761                         struct passwd pwd;
 762                         getpwnam_r ("", &pwd, buffer,
 763                                         sizeof (buffer));]])],
 764                         [ac_cv_func_nonposix_getpwnam_r=yes],
 765                         [ac_cv_func_nonposix_getpwnam_r=no])])
 766                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 767                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 768                         [Have non-POSIX function getpwnam_r])
 769         fi
 770 fi
 771
 772 dnl check for socklen_t
 773 AC_MSG_CHECKING(whether socklen_t is defined)
 774 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 775 #include <sys/types.h>
 776 #include <sys/socket.h>
 777 #include <netdb.h>
 778 ]], [[
 779 socklen_t foo;
 780 foo = 1;
 781 ]])],
 782 [dbus_have_socklen_t=yes],
 783 [dbus_have_socklen_t=no])
 784 AC_MSG_RESULT($dbus_have_socklen_t)
 785
 786 if test "x$dbus_have_socklen_t" = "xyes"; then
 787     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 788 fi
 789
 790 dnl check for writev header and writev function so we're
 791 dnl good to go if HAVE_WRITEV gets defined.
 792 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 793
 794 dnl needed on darwin for NAME_MAX
 795 AC_CHECK_HEADERS(sys/syslimits.h)
 796
 797 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 798 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 799 #include <sys/socket.h> ]])
 800
 801 dnl check for flavours of varargs macros (test from GLib)
 802 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 803 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 804 int a(int p1, int p2, int p3);
 805 #define call_a(...) a(1,__VA_ARGS__)
 806 call_a(2,3);
 807 ]])],
 808 [dbus_have_iso_c_varargs=yes],
 809 [dbus_have_iso_c_varargs=no])
 810 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 811
 812 AC_MSG_CHECKING(for GNUC varargs macros)
 813 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 814 int a(int p1, int p2, int p3);
 815 #define call_a(params...) a(1,params)
 816 call_a(2,3);
 817 ]])],
 818 [dbus_have_gnuc_varargs=yes],
 819 [dbus_have_gnuc_varargs=no])
 820 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 821
 822 dnl Output varargs tests
 823 if test x$dbus_have_iso_c_varargs = xyes; then
 824     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 825 fi
 826 if test x$dbus_have_gnuc_varargs = xyes; then
 827     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 828 fi
 829
 830 dnl Check for various credentials.
 831 AC_MSG_CHECKING(for struct cmsgcred)
 832 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 833 #include <sys/types.h>
 834 #include <sys/socket.h>
 835 ]], [[
 836 struct cmsgcred cred;
 837
 838 cred.cmcred_pid = 0;
 839 ]])],
 840 [dbus_have_struct_cmsgcred=yes],
 841 [dbus_have_struct_cmsgcred=no])
 842 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 843
 844 if test x$dbus_have_struct_cmsgcred = xyes; then
 845     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 846 fi
 847
 848 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 849                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 850                 [],
 851                 [[#include <sys/un.h>]])
 852
 853 AC_CHECK_FUNCS(getpeerucred getpeereid)
 854
 855 AC_CHECK_FUNCS(pipe2 accept4)
 856
 857 PKG_CHECK_MODULES([EXPAT], [expat])
 858
 859 save_cflags="$CFLAGS"
 860 save_libs="$LIBS"
 861 CFLAGS="$CFLAGS $EXPAT_CFLAGS"
 862 LIBS="$LIBS $EXPAT_LIBS"
 863 AC_CHECK_FUNCS([XML_SetHashSalt])
 864 CFLAGS="$save_cflags"
 865 LIBS="$save_libs"
 866
 867 # Thread lib detection
 868 AC_ARG_VAR([THREAD_LIBS])
 869 save_libs="$LIBS"
 870 LIBS="$LIBS $THREAD_LIBS"
 871
 872 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 873
 874 # Don't do these automatic checks if the user set THREAD_LIBS on the
 875 # configure command-line. If they did, we assume they're right.
 876 #
 877 # We also don't do these checks on Windows, because you don't need magical
 878 # linker flags to have threading support there.
 879 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 880   [
 881     # Mandatory pthread functions. In principle, some of these could be made
 882     # optional if there are platforms that don't have them.
 883     #
 884     # Currently, we only look in -lpthread.
 885     # In principle we might need to look in -lpthreads, -lthreads, ...
 886     # as well - please file a bug if your platform needs this.
 887     AC_SEARCH_LIBS([pthread_cond_timedwait],
 888         [pthread],
 889         [THREAD_LIBS="$LIBS"],
 890         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 891         [])
 892     AC_SEARCH_LIBS([pthread_mutexattr_init],
 893         [pthread],
 894         [THREAD_LIBS="$LIBS"],
 895         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 896         [])
 897     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 898         [pthread],
 899         [THREAD_LIBS="$LIBS"],
 900         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 901         [])
 902
 903     # Optional, for monotonic clocks. Because it's optional, this check
 904     # is non-fatal if we don't find it.
 905     AC_SEARCH_LIBS([pthread_condattr_setclock],
 906         [pthread],
 907         [THREAD_LIBS="$LIBS"])
 908
 909     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 910       [
 911         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 912         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 913         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 914 [[#include <time.h>
 915 #include <pthread.h>
 916 ]], [[
 917 struct timespec monotonic_timer;
 918 pthread_condattr_t attr;
 919 pthread_condattr_init (&attr);
 920 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 921 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 922 ]])],
 923             [have_clock_monotonic=true],
 924             [have_clock_monotonic=false])
 925         AS_IF([test x$have_clock_monotonic = xtrue],
 926           [
 927             AC_MSG_RESULT([found])
 928             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 929           ],
 930           [AC_MSG_RESULT([not found])])
 931       ]) dnl have pthread_condattr_setclock
 932   ]) dnl on Unix
 933
 934 LIBS="$save_libs"
 935
 936 AC_SUBST([THREAD_LIBS])
 937
 938 # SELinux detection
 939 if test x$enable_selinux = xno ; then
 940     have_selinux=no;
 941 else
 942     # See if we have SELinux library
 943     PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0.86],
 944                  [have_selinux=yes], [have_selinux=no])
 945
 946     if test x$enable_selinux = xauto ; then
 947         if test x$have_selinux = xno ; then
 948                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 949         fi
 950     else
 951         if test x$have_selinux = xno ; then
 952                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 953         fi
 954     fi
 955 fi
 956
 957 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 958
 959 if test x$have_selinux = xyes ; then
 960     # the selinux code creates threads
 961     # which requires libpthread even on linux
 962     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 963                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 964
 965     SELINUX_LIBS="$SELINUX_LIBS $SELINUX_THREAD_LIBS"
 966     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 967 else
 968     SELINUX_LIBS=
 969 fi
 970
 971 # AppArmor detection
 972 AS_IF([test x$enable_apparmor = xno],
 973   [have_apparmor=no],
 974   [
 975   PKG_CHECK_MODULES([APPARMOR], [libapparmor >= 2.8.95],
 976                     [have_apparmor=yes], [have_apparmor=no])
 977   PKG_CHECK_MODULES([APPARMOR_2_10], [libapparmor >= 2.10],
 978                     [have_apparmor_2_10=yes], [have_apparmor_2_10=no])
 979
 980   AS_IF([test x$enable_apparmor = xauto && test x$have_apparmor = xno],
 981         [AC_MSG_WARN([Sufficiently new AppArmor library not found])])
 982   AS_IF([test x$enable_apparmor != xauto && test x$have_apparmor = xno],
 983         [AC_MSG_ERROR([AppArmor explicitly required, and AppArmor library not found])])
 984   ])
 985
 986 AS_IF([test x$have_apparmor = xyes],
 987       [AC_DEFINE([HAVE_APPARMOR], [1], [AppArmor Support])])
 988 AS_IF([test x$have_apparmor_2_10 = xyes],
 989       [AC_DEFINE([HAVE_APPARMOR_2_10], [1],
 990                  [Define if libapparmor is version 2.10 or later])])
 991
 992 # inotify checks
 993 if test x$enable_inotify = xno ; then
 994     have_inotify=no;
 995 else
 996     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 997 fi
 998
 999 dnl check if inotify backend is enabled
1000 if test x$have_inotify = xyes; then
1001    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1002    AC_CHECK_FUNCS(inotify_init1)
1003 fi
1004
1005 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1006
1007 # For simplicity, we require the userland API for epoll_create1 at
1008 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1009 # not to have it at runtime.
1010 AC_ARG_ENABLE([epoll],
1011               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1012               [enable_epoll=$enableval], [enable_epoll=auto])
1013 if test x$enable_epoll = xno; then
1014     have_linux_epoll=no
1015 else
1016     AC_MSG_CHECKING([for Linux epoll(4)])
1017     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1018         [
1019         #ifndef __linux__
1020         #error This is not Linux
1021         #endif
1022         #include <sys/epoll.h>
1023         ],
1024         [epoll_create1 (EPOLL_CLOEXEC);])],
1025         [have_linux_epoll=yes],
1026         [have_linux_epoll=no])
1027     AC_MSG_RESULT([$have_linux_epoll])
1028 fi
1029 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1030     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1031 fi
1032 if test x$have_linux_epoll = xyes; then
1033   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1034 fi
1035 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1036
1037 # kqueue checks
1038 if test x$enable_kqueue = xno ; then
1039     have_kqueue=no
1040 else
1041     have_kqueue=yes
1042     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1043     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1044
1045     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1046         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1047     fi
1048 fi
1049
1050 dnl check if kqueue backend is enabled
1051 if test x$have_kqueue = xyes; then
1052    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1053 fi
1054
1055 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1056
1057 # launchd checks
1058 if test x$enable_launchd = xno ; then
1059     have_launchd=no
1060 else
1061     have_launchd=yes
1062     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1063     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1064     if test "x$LAUNCHCTL" = "x"; then
1065         have_launchd=no
1066     fi
1067
1068     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1069         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1070     fi
1071 fi
1072
1073 dnl check if launchd is enabled
1074 if test x$have_launchd = xyes; then
1075     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1076 fi
1077
1078 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1079
1080 #### Directory to place launchd agent file
1081 if test "x$with_launchd_agent_dir" = "x"; then
1082    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1083 else
1084    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1085 fi
1086
1087 AC_SUBST(LAUNCHD_AGENT_DIR)
1088
1089 dnl console owner file
1090 if test x$enable_console_owner_file = xno ; then
1091     have_console_owner_file=no;
1092 else
1093     case $host_os in
1094     solaris*)
1095         have_console_owner_file=yes;
1096         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1097         ;;
1098     *)
1099         have_console_owner_file=no;;
1100     esac
1101 fi
1102
1103 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1104
1105 dnl systemd detection
1106 if test x$enable_systemd = xno ; then
1107     have_systemd=no;
1108 else
1109     PKG_CHECK_MODULES([SYSTEMD],
1110         [libsystemd >= 209],
1111         [have_systemd=yes],
1112         [PKG_CHECK_MODULES([SYSTEMD],
1113             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1114             [have_systemd=yes],
1115             [have_systemd=no])])
1116 fi
1117
1118 if test x$have_systemd = xyes; then
1119     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1120 fi
1121
1122 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1123     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1124 fi
1125
1126 # If not found in $PATH, we might still have systemd and systemctl at runtime
1127 # (perhaps dbus is being compiled in a minimal chroot with no systemd).
1128 # Assume the upstream-recommended location. Distributors with split /usr
1129 # can override this with ./configure SYSTEMCTL=/bin/systemctl
1130 AC_PATH_PROG([SYSTEMCTL], [systemctl], [/usr/bin/systemctl])
1131
1132 # libaudit detection
1133 if test x$enable_libaudit = xno ; then
1134     have_libaudit=no;
1135 else
1136     # See if we have audit daemon & capabilities library
1137     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1138                  have_libaudit=yes, have_libaudit=no)
1139     if test x$have_libaudit = xyes ; then
1140         AC_CHECK_LIB(cap-ng, capng_clear,
1141                  have_libaudit=yes, have_libaudit=no)
1142     fi
1143 fi
1144
1145 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1146
1147 if test x$have_libaudit = xyes ; then
1148     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1149     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1150 fi
1151
1152 AC_SUBST([SELINUX_LIBS])
1153
1154 # Check for ADT API (Solaris Basic Security Mode auditing)
1155 AC_MSG_CHECKING(for ADT API)
1156 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1157 #include <bsm/adt.h>
1158 adt_user_context = ADT_USER;
1159 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1160
1161 if test ${check_adt_audit} = yes
1162 then
1163    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1164    ADT_LIBS="-lbsm"
1165    LIBS="-lbsm $LIBS"
1166    AC_MSG_RESULT(yes)
1167 else
1168    AC_MSG_RESULT(no)
1169 fi
1170 AC_SUBST([ADT_LIBS])
1171
1172 # Check for SCM_RIGHTS
1173 AC_MSG_CHECKING([for SCM_RIGHTS])
1174 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1175 #include <sys/types.h>
1176 #include <sys/socket.h>
1177 #include <sys/un.h>
1178 static int x = SCM_RIGHTS;
1179 ]], [[]])],
1180 [ AC_MSG_RESULT([supported])
1181   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1182 [ AC_MSG_RESULT([not supported]) ])
1183
1184 NETWORK_libs=
1185 if test x$dbus_win = xyes ; then
1186   if test x$dbus_wince = xyes ; then
1187     NETWORK_libs="-lws2"
1188   else
1189     NETWORK_libs="-lws2_32 -liphlpapi -ldbghelp"
1190   fi
1191 fi
1192
1193 AC_SUBST([NETWORK_libs])
1194
1195 AC_ARG_WITH([valgrind],
1196   [AS_HELP_STRING([--with-valgrind],
1197      [Add instrumentation to help valgrind to understand our allocator])],
1198   [],
1199   [with_valgrind=no])
1200
1201 AS_IF([test "x$with_valgrind" = xauto],
1202   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1203     [with_valgrind=yes], [with_valgrind=no])])
1204
1205 if test x$with_valgrind != xno; then
1206   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1207   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1208 fi
1209
1210 #### Set up final flags
1211 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1212 AC_SUBST([LIBDBUS_LIBS])
1213
1214 ### X11 detection
1215 DBUS_X_LIBS=
1216 DBUS_X_CFLAGS=
1217
1218 AC_ARG_ENABLE([x11-autolaunch],
1219   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1220   [], [enable_x11_autolaunch=auto])
1221
1222 if test "x$dbus_win" = xyes; then
1223     if test "x$enable_x11_autolaunch" = xyes; then
1224         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1225     fi
1226
1227     enable_x11_autolaunch=no
1228     have_x11=no
1229 else
1230     AC_PATH_XTRA
1231
1232     if test "x$no_x" = xyes; then
1233         have_x11=no
1234     else
1235         have_x11=yes
1236         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1237         DBUS_X_CFLAGS="$X_CFLAGS"
1238     fi
1239 fi
1240
1241 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1242     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1243 else
1244     # move from "auto" to "yes" or "no" if necessary
1245     if test "x$enable_x11_autolaunch" != xno; then
1246         enable_x11_autolaunch="$have_x11"
1247     fi
1248 fi
1249
1250 if test "x$have_x11" = xyes ; then
1251    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1252 fi
1253
1254 if test "x$enable_x11_autolaunch" = xyes ; then
1255    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1256 fi
1257 AM_CONDITIONAL([DBUS_ENABLE_X11_AUTOLAUNCH],
1258   [test "x$enable_x11_autolaunch" = xyes])
1259
1260 AC_SUBST([DBUS_X_CFLAGS])
1261 AC_SUBST([DBUS_X_LIBS])
1262
1263 # We're treating -fno-common like a warning: it makes the linker more
1264 # strict, because on some systems the linker is *always* this strict
1265 TEST_CFLAGS="$TEST_CFLAGS -fno-common"
1266
1267 AS_IF([test "x$enable_ansi" = "xyes"],[
1268     TEST_CFLAGS="$TEST_CFLAGS -ansi -pedantic"
1269     AC_DEFINE([_POSIX_C_SOURCE],[199309L],[Define to enable POSIX features])
1270     AC_DEFINE([_BSD_SOURCE],[1],[Define to enable BSD features])
1271   ])
1272
1273 dnl We are only calling this for its side-effect of setting up
1274 dnl --enable-compile-warnings; the WARN_CFLAGS, etc. are ignored,
1275 dnl to work around https://github.com/peti/autoconf-archive/pull/96
1276 AX_COMPILER_FLAGS([], [], [$disable_developer])
1277
1278 dnl Work around https://github.com/peti/autoconf-archive/pull/96 by using
1279 dnl a non-default variable name here (in particular there is no way to tell
1280 dnl AX_COMPILER_FLAGS to not use WARN_CXXFLAGS)
1281 AX_COMPILER_FLAGS_CFLAGS([EXTRA_CFLAGS],
1282                          [$disable_developer],
1283                          [$TEST_CFLAGS],
1284                          [-Wchar-subscripts \
1285                           -Wfloat-equal \
1286                           -Wpointer-sign \
1287                           $DISABLE_WARNINGS])
1288 dnl cc1plus: warning: command line option ‘-Wpointer-sign’ is valid for
1289 dnl C/ObjC but not for C++
1290 AX_COMPILER_FLAGS_CXXFLAGS([EXTRA_CXXFLAGS],
1291                            [$disable_developer],
1292                            [],
1293                            [-Wchar-subscripts \
1294                             -Wfloat-equal \
1295                             $DISABLE_WARNINGS])
1296 AX_COMPILER_FLAGS_LDFLAGS([EXTRA_LDFLAGS],
1297                           [$disable_developer])
1298
1299 dnl TODO: In principle we should put EXTRA_CFLAGS in each Makefile.am like
1300 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1301 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1302 dnl is the next best thing.
1303 CFLAGS="$EXTRA_CFLAGS $CFLAGS"
1304 CXXFLAGS="$EXTRA_CXXFLAGS $CXXFLAGS"
1305 LDFLAGS="$EXTRA_LDFLAGS $LDFLAGS"
1306
1307 case $host_os in
1308     solaris*)
1309         # Solaris' C library apparently needs these runes to be threadsafe...
1310         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1311         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1312         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1313         # ... and this opt-in to get file descriptor passing support
1314         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1315         ;;
1316 esac
1317
1318 ### Detect if ld supports --version-script
1319
1320 gl_LD_VERSION_SCRIPT
1321 AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
1322                [test "x$have_ld_version_script" = xyes])
1323 ### Doxygen Documentation
1324
1325 AC_PATH_PROG(DOXYGEN, doxygen, no)
1326
1327 AC_MSG_CHECKING([whether to build Doxygen documentation])
1328
1329 if test x$DOXYGEN = xno ; then
1330     have_doxygen=no
1331 else
1332     have_doxygen=yes
1333 fi
1334
1335 if test x$enable_doxygen_docs = xauto ; then
1336     if test x$have_doxygen = xno ; then
1337         enable_doxygen_docs=no
1338     else
1339         enable_doxygen_docs=yes
1340     fi
1341 fi
1342
1343 if test x$enable_doxygen_docs = xyes; then
1344     if test x$have_doxygen = xno; then
1345         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1346     fi
1347 fi
1348
1349 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1350 AC_MSG_RESULT($enable_doxygen_docs)
1351
1352 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1353 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1354
1355 ### Ducktype/Yelp documentation
1356
1357 AC_PATH_PROG([DUCKTYPE],[ducktype],[no])
1358 AC_PATH_PROG([YELP_BUILD],[yelp-build],[no])
1359
1360 AC_MSG_CHECKING([whether to build Ducktype documentation])
1361
1362 AS_IF([test "$DUCKTYPE" = "no"],[have_ducktype=no],[have_ducktype=yes])
1363 AS_IF([test "$YELP_BUILD" = "no"],[have_yelp_build=no],[have_yelp_build=yes])
1364
1365 AS_IF([test "$enable_ducktype_docs" = "auto"],[
1366     AS_IF([test "$have_ducktype" = "no" || test "$have_yelp_build" = "no"],[
1367         enable_ducktype_docs=no
1368     ],[
1369         enable_ducktype_docs=yes
1370     ])
1371 ])
1372
1373 AS_IF([test "$enable_ducktype_docs" = "yes"],[
1374     AS_IF([test "$have_ducktype" = "no"],[
1375         AC_MSG_ERROR([Building Ducktype docs explicitly required, but ducktype not found])
1376     ])
1377     AS_IF([test "$have_yelp_build" = "no"],[
1378         AC_MSG_ERROR([Building Ducktype docs explicitly required, but yelp-build not found])
1379     ])
1380 ])
1381
1382 AM_CONDITIONAL([DBUS_DUCKTYPE_DOCS_ENABLED],[test "$enable_ducktype_docs" = "yes"])
1383 AC_MSG_RESULT([$enable_ducktype_docs])
1384
1385 ### XML Documentation
1386
1387 AC_PATH_PROG(XMLTO, xmlto, no)
1388
1389 AC_MSG_CHECKING([whether to build XML documentation])
1390
1391 if test x$XMLTO = xno ; then
1392     have_xmlto=no
1393 else
1394     have_xmlto=yes
1395 fi
1396
1397 if test x$enable_xml_docs = xauto ; then
1398     if test x$have_xmlto = xno ; then
1399         enable_xml_docs=no
1400     else
1401         enable_xml_docs=yes
1402     fi
1403 fi
1404
1405 if test x$enable_xml_docs = xyes; then
1406     if test x$have_xmlto = xno; then
1407         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1408     fi
1409 fi
1410
1411 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1412 AC_MSG_RESULT($enable_xml_docs)
1413
1414 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1415     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes &&
1416      test x$enable_ducktype_docs = xyes])
1417
1418 # Autoconf 2.70 will support this, and many distros patch this option in,
1419 # but Autoconf 2.70 hasn't actually been released yet.
1420 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
1421 AC_SUBST([runstatedir])
1422
1423 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1424
1425 #### find the actual value for $prefix that we'll end up with
1426 ##   (I know this is broken and should be done in the Makefile, but
1427 ##    that's a major pain and almost nobody actually seems to care)
1428 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1429 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1430 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1431 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1432 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1433 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1434 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1435 AS_AC_EXPAND(EXPANDED_RUNSTATEDIR, "$runstatedir")
1436
1437 ##### systemd unit files
1438 AC_ARG_WITH([systemdsystemunitdir],
1439 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1440     [],
1441     [
1442     PKG_CHECK_EXISTS([systemd],
1443       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1444       [with_systemdsystemunitdir=no])
1445     ])
1446 if test "x$with_systemdsystemunitdir" != xno; then
1447    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1448 fi
1449 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1450
1451 AC_ARG_WITH([systemduserunitdir],
1452 AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1453     [],
1454     [
1455     PKG_CHECK_EXISTS([systemd],
1456       [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)],
1457       [with_systemduserunitdir='${libdir}/systemd/user'])
1458     ])
1459 AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1460
1461 ##### Set up location for system bus socket
1462 if ! test -z "$with_system_socket"; then
1463    DBUS_SYSTEM_SOCKET=$with_system_socket
1464 else
1465    # We don't use runstatedir for this (yet?), because /var/run has been the
1466    # interoperable system bus socket for 10+ years.
1467    # See https://bugs.freedesktop.org/show_bug.cgi?id=101628
1468    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1469 fi
1470
1471 AC_SUBST(DBUS_SYSTEM_SOCKET)
1472 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1473
1474 ## System bus only listens on local domain sockets, and never
1475 ## on an abstract socket (so only root can create the socket).
1476 ##
1477 ## This won't work on Windows. It's not meant to - the system bus is
1478 ## meaningless on Windows anyway.
1479 ##
1480 ## This has to be suitable for hard-coding in client libraries as well as
1481 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1482 ## and also to connect to. If this ever changes, it'll need to be split into
1483 ## two variables, one for the listening address and one for the connecting
1484 ## address.
1485 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1486 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1487 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1488
1489 #### Set up the pid file
1490 if ! test -z "$with_system_pid_file"; then
1491    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1492 else
1493    DBUS_SYSTEM_PID_FILE="${EXPANDED_RUNSTATEDIR}/dbus/pid"
1494 fi
1495
1496 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1497
1498 #### Directory to check for console ownership
1499 AS_IF([test -n "$with_console_auth_dir" && test "x$with_console_auth_dir" != xno],
1500     [AC_DEFINE_UNQUOTED([DBUS_CONSOLE_AUTH_DIR], ["$with_console_auth_dir"],
1501         [Directory to check for pam_console/pam_foreground flag files, or undefined])],
1502     [with_console_auth_dir=])
1503
1504 #### File to check for console ownership
1505 if test x$have_console_owner_file = xyes; then
1506    if ! test -z "$with_console_owner_file"; then
1507       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1508    else
1509       DBUS_CONSOLE_OWNER_FILE=/dev/console
1510    fi
1511 else
1512   DBUS_CONSOLE_OWNER_FILE=
1513 fi
1514
1515 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1516 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1517
1518 #### User to start the system bus as
1519 if test -z "$with_dbus_user" ; then
1520     DBUS_USER=messagebus
1521 else
1522     DBUS_USER=$with_dbus_user
1523 fi
1524 AC_SUBST(DBUS_USER)
1525 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1526
1527 #### User for regression tests
1528 AS_IF([test -z "$with_test_user"], [with_test_user=nobody])
1529 DBUS_TEST_USER="$with_test_user"
1530 AC_SUBST([DBUS_TEST_USER])
1531 AC_DEFINE_UNQUOTED([DBUS_TEST_USER], ["$DBUS_TEST_USER"],
1532   [Unprivileged user used in some regression tests])
1533
1534 #### Prefix to install into
1535 DBUS_PREFIX=$EXPANDED_PREFIX
1536 AC_SUBST(DBUS_PREFIX)
1537 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1538
1539 #### Direcotry to install data files into
1540 DBUS_DATADIR=$EXPANDED_DATADIR
1541 AC_SUBST(DBUS_DATADIR)
1542 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1543
1544 #### Directory to install dbus-daemon
1545 if test -z "$with_dbus_daemondir" ; then
1546     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1547     dbus_daemondir='${bindir}'
1548 else
1549     DBUS_DAEMONDIR=$with_dbus_daemondir
1550     dbus_daemondir=$with_dbus_daemondir
1551 fi
1552 AC_SUBST(DBUS_DAEMONDIR)
1553 AC_SUBST(dbus_daemondir)
1554 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1555
1556 #### Directory to install the other binaries
1557 DBUS_BINDIR="$EXPANDED_BINDIR"
1558 AC_SUBST(DBUS_BINDIR)
1559 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1560
1561 #### Directory to install the libexec binaries
1562 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1563 AC_SUBST(DBUS_LIBEXECDIR)
1564 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1565
1566 AC_ARG_ENABLE([relocation],
1567   [AS_HELP_STRING([--enable-relocation[=yes/no/auto]],
1568     [Make pkg-config metadata relocatable [default=auto]])],
1569   [], [enable_relocation=auto])
1570
1571 can_relocate=yes
1572
1573 AS_CASE(["${exec_prefix}"],
1574   ['NONE'|'${prefix}'],
1575     [:],
1576   [*],
1577     [can_relocate=no])
1578
1579 AS_CASE(["${libdir}"],
1580   ['${prefix}/lib'|'${prefix}/lib64'|'${exec_prefix}/lib'|'${exec_prefix}/lib64'],
1581     [:],
1582   [*],
1583     [can_relocate=no])
1584
1585 # If the user said --enable-relocation but we can't do it, error out
1586 AS_IF([test "x$can_relocate" = xno && test "x$enable_relocation" = xyes],
1587   [AC_MSG_ERROR([Relocatable pkg-config metadata requires --exec-prefix='\${prefix}' and the default libdir])])
1588
1589 # By default, on Windows we are relocatable if possible
1590 AS_IF([test "x$enable_relocation" = xauto && test "x$dbus_win" = xyes],
1591   [enable_relocation="$can_relocate"])
1592
1593 # By default, on non-Windows we are not relocatable because it can interfere
1594 # with pkg-config's ability to filter out system include directories,
1595 # resulting in linking an outdated system-wide library in preference to a
1596 # newer version installed elsewhere
1597 AS_IF([test "x$enable_relocation" = xauto],
1598   [enable_relocation="no"])
1599
1600
1601 AS_IF([test "x$enable_relocation" = xyes],
1602   [AC_SUBST([pkgconfig_prefix], ['${pcfiledir}/../../'])],
1603   [AC_SUBST([pkgconfig_prefix], ['${original_prefix}'])])
1604
1605 #### Directory to source sysconfdir configuration from
1606
1607 # On Windows this is relative to where we put the bus setup, in
1608 # ${datadir}/dbus-1. For simplicity, we only do this if
1609 # ${sysconfdir} = ${prefix}/etc and ${datadir} = ${prefix}/share.
1610 #
1611 # On Unix, or on Windows with weird install layouts, it's the absolute path.
1612 AS_IF([test "${dbus_win}" = yes && \
1613        test "$EXPANDED_SYSCONFDIR" = "$EXPANDED_PREFIX/etc" && \
1614        test "$EXPANDED_DATADIR" = "$EXPANDED_PREFIX/share"],
1615       [SYSCONFDIR_FROM_PKGDATADIR="../../etc"
1616        DATADIR_FROM_PKGSYSCONFDIR="../../share"],
1617       [SYSCONFDIR_FROM_PKGDATADIR="$EXPANDED_SYSCONFDIR"
1618        DATADIR_FROM_PKGSYSCONFDIR="$EXPANDED_DATADIR"])
1619 AC_SUBST([SYSCONFDIR_FROM_PKGDATADIR])
1620 AC_SUBST([DATADIR_FROM_PKGSYSCONFDIR])
1621
1622 #### Tell tests where to find certain stuff in builddir
1623
1624 DBUS_PWD=`pwd`
1625 # Useful in a cross-compilation environment, where the tests are run on the host system.
1626 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1627                            DBUS_PWD=$withval)
1628
1629 DBUS_TEST_EXEC="$DBUS_PWD/test"
1630 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1631
1632 AC_SUBST([DBUS_TEST_DATA])
1633 AC_SUBST([DBUS_TEST_EXEC])
1634
1635 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1636                    [Extension for executables, typically empty or .exe])
1637
1638 ## Export the non-setuid external helper
1639 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1640 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1641 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1642                    [Full path to the launch helper test program in the builddir])
1643
1644 #### Find socket directories
1645 if ! test -z "$TMPDIR" ; then
1646    DEFAULT_SOCKET_DIR=$TMPDIR
1647 elif ! test -z "$TEMP" ; then
1648    DEFAULT_SOCKET_DIR=$TEMP
1649 elif ! test -z "$TMP" ; then
1650    DEFAULT_SOCKET_DIR=$TMP
1651 else
1652    DEFAULT_SOCKET_DIR=/tmp
1653 fi
1654
1655 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1656
1657 if ! test -z "$with_test_socket_dir" ; then
1658    TEST_SOCKET_DIR="$with_test_socket_dir"
1659 else
1660    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1661 fi
1662 AC_SUBST(TEST_SOCKET_DIR)
1663 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1664
1665 if test "x$dbus_unix" = xyes; then
1666   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1667 else
1668   TEST_LISTEN="tcp:host=localhost"
1669 fi
1670 AC_SUBST([TEST_LISTEN])
1671 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1672   [Listening address for regression tests])
1673
1674 if ! test -z "$with_session_socket_dir" ; then
1675    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1676 else
1677    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1678 fi
1679 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1680 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1681
1682 # This must be a listening address. It doesn't necessarily need to be an
1683 # address you can connect to - it can be something vague like
1684 # "nonce-tcp:".
1685 #
1686 # The default varies by platform.
1687 AC_ARG_WITH([dbus_session_bus_listen_address],
1688             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1689                            [default address for a session bus to listen on (see configure.ac)]),
1690             [with_dbus_session_bus_listen_address=$withval],
1691             [with_dbus_session_bus_listen_address=])
1692
1693 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1694         # the user specified something, trust them
1695         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1696 elif test x$dbus_win = xyes; then
1697         # On Windows, you can (and should) listen on autolaunch addresses,
1698         # because autolaunching is different.
1699         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1700         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1701 elif test x$have_launchd = xyes; then
1702         # Mac OS X default is to use launchd
1703         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1704 else
1705         # The default on all other Unix platforms (notably Linux)
1706         # is to create a randomly named socket in /tmp or similar
1707         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1708 fi
1709 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1710
1711 # This must be an address you can connect to. It doesn't necessarily
1712 # need to be an address you can listen on - it can be "autolaunch:",
1713 # even on Unix.
1714 #
1715 # The default varies by platform.
1716 AC_ARG_WITH([dbus_session_bus_connect_address],
1717             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1718                            [fallback address for a session bus client to connect to (see configure.ac)]),
1719             [with_dbus_session_bus_connect_address=$withval],
1720             [with_dbus_session_bus_connect_address=])
1721
1722 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1723         # the user specified something, trust them
1724         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1725 elif test x$dbus_win = xyes; then
1726         # Windows autolaunching is a bit different; leaving it in its own
1727         # branch of the conditional because the default might conceivably
1728         # change (see #38201)
1729         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1730 else
1731         # The default on all other Unix platforms (notably Linux)
1732         # is to use auto-launching - this works a bit differently on Mac OS X
1733         # but comes out basically the same in the end
1734         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1735 fi
1736 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1737 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1738   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1739   [Fallback address for session bus clients])
1740
1741 # darwin needs this to initialize the environment
1742 AC_CHECK_HEADERS(crt_externs.h)
1743 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1744 AH_VERBATIM(_DARWIN_ENVIRON,
1745 [
1746 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1747 # include <sys/time.h>
1748 # include <crt_externs.h>
1749 # define environ (*_NSGetEnviron())
1750 #endif
1751 ])
1752
1753 AC_ARG_ENABLE([stats],
1754   [AS_HELP_STRING([--disable-stats],
1755     [disable bus daemon usage statistics])],
1756   [], [enable_stats=yes])
1757 if test "x$enable_stats" = xyes; then
1758   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1759     [Define to enable bus daemon usage statistics])
1760 fi
1761
1762 AC_ARG_ENABLE([user-session],
1763   [AS_HELP_STRING([--enable-user-session],
1764     [enable user-session semantics for session bus under systemd])],
1765   [], [enable_user_session=no])
1766 AM_CONDITIONAL([DBUS_ENABLE_USER_SESSION],
1767   [test "x$enable_user_session" = xyes])
1768
1769 AC_CONFIG_FILES([
1770 Doxyfile
1771 dbus/Version
1772 dbus/versioninfo.rc
1773 dbus/dbus-arch-deps.h
1774 bus/system.conf
1775 bus/session.conf
1776 bus/legacy-config/system.conf
1777 bus/legacy-config/session.conf
1778 bus/example-system-enable-stats.conf
1779 bus/example-session-disable-stats.conf
1780 bus/org.freedesktop.dbus-session.plist
1781 bus/dbus.service
1782 bus/dbus.socket
1783 bus/systemd-user/dbus.service
1784 bus/systemd-user/dbus.socket
1785 bus/sysusers.d/dbus.conf
1786 bus/tmpfiles.d/dbus.conf
1787 Makefile
1788 dbus/Makefile
1789 bus/Makefile
1790 tools/Makefile
1791 test/Makefile
1792 test/name-test/Makefile
1793 doc/Makefile
1794 doc/dbus-cleanup-sockets.1.xml
1795 doc/dbus-daemon.1.xml
1796 doc/dbus-launch.1.xml
1797 doc/dbus-monitor.1.xml
1798 doc/dbus-run-session.1.xml
1799 doc/dbus-send.1.xml
1800 doc/dbus-test-tool.1.xml
1801 doc/dbus-update-activation-environment.1.xml
1802 doc/dbus-uuidgen.1.xml
1803 dbus-1.pc
1804 dbus-1-uninstalled.pc
1805 cmake/DBus1Config.cmake:cmake/DBus1Config.pkgconfig.in
1806 cmake/DBus1ConfigVersion.cmake
1807 ])
1808 AC_OUTPUT
1809
1810 dnl ==========================================================================
1811 echo "
1812                     D-Bus $VERSION
1813                   ==============
1814
1815         prefix:                   ${EXPANDED_PREFIX}
1816         exec_prefix:              ${exec_prefix}
1817         libdir:                   ${EXPANDED_LIBDIR}
1818         libexecdir:               ${EXPANDED_LIBEXECDIR}
1819         bindir:                   ${EXPANDED_BINDIR}
1820         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1821         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1822         runstatedir:              ${EXPANDED_RUNSTATEDIR}
1823         datadir:                  ${EXPANDED_DATADIR}
1824         source code location:     ${srcdir}
1825         compiler:                 ${CC}
1826         cflags:                   ${CFLAGS}
1827         cppflags:                 ${CPPFLAGS}
1828         cxxflags:                 ${CXXFLAGS}
1829         ldflags:                  ${LDFLAGS}
1830         64-bit int:               ${DBUS_INT64_TYPE}
1831         32-bit int:               ${DBUS_INT32_TYPE}
1832         16-bit int:               ${DBUS_INT16_TYPE}
1833         Doxygen:                  ${DOXYGEN:-not found}
1834         xmlto:                    ${XMLTO:-not found}
1835         ducktype:                 ${DUCKTYPE:-not found}
1836         yelp-build:               ${YELP_BUILD:-not found}"
1837
1838 echo "
1839         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1840         gcc coverage profiling:   ${enable_code_coverage}
1841         Building embedded tests:  ${enable_embedded_tests}
1842         Building modular tests:   ${enable_modular_tests}
1843             - with GLib:          ${with_glib}
1844         Installing tests:         ${enable_installed_tests}
1845         Building verbose mode:    ${enable_verbose_mode}
1846         Building assertions:      ${enable_asserts}
1847         Building checks:          ${enable_checks}
1848         Building bus stats API:   ${enable_stats}
1849         Building SELinux support: ${have_selinux}
1850         Building AppArmor support: ${have_apparmor}
1851         Building inotify support: ${have_inotify}
1852         Building kqueue support:  ${have_kqueue}
1853         Building systemd support: ${have_systemd}
1854         Building X11 code:        ${have_x11}
1855         Building Doxygen docs:    ${enable_doxygen_docs}
1856         Building Ducktype docs:   ${enable_ducktype_docs}
1857         Building XML docs:        ${enable_xml_docs}
1858         Building launchd support: ${have_launchd}
1859         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1860         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1861         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1862         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1863         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1864         pam_console auth dir:     ${with_console_auth_dir:-(none)}
1865         Console owner file:       ${have_console_owner_file}
1866         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1867         System bus user:          ${DBUS_USER}
1868         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1869         'make check' socket dir:  ${TEST_SOCKET_DIR}
1870 "
1871 if test x$have_launchd = xyes; then
1872         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1873 fi
1874 echo
1875
1876 if test x$enable_embedded_tests = xyes; then
1877         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1878 fi
1879 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1880         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1881 fi
1882 AS_IF([test x$enable_code_coverage = xyes],[
1883     AC_MSG_WARN([Building with coverage profiling is definitely for developers only.])
1884   ])
1885 if test x$enable_verbose_mode = xyes; then
1886         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1887 fi
1888 if test x$enable_asserts = xyes; then
1889         echo "NOTE: building with assertions increases library size and decreases performance."
1890 fi
1891 if test x$enable_checks = xno; then
1892         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1893 fi