configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.0.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 LT_PREREQ([2.2])
  28 LT_INIT([disable-static])
  29
  30 dnl Set internal versions
  31 OSMESA_VERSION=8
  32 AC_SUBST([OSMESA_VERSION])
  33
  34 dnl Versions for external dependencies
  35 LIBDRM_REQUIRED=2.4.24
  36 LIBDRM_RADEON_REQUIRED=2.4.39
  37 LIBDRM_INTEL_REQUIRED=2.4.38
  38 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  39 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  75 fi
  76
  77 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  78 dnl configuration in that case.
  79 AC_PROG_INSTALL
  80 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  81
  82 dnl We need a POSIX shell for parts of the build. Assume we have one
  83 dnl in most cases.
  84 case "$host_os" in
  85 solaris*)
  86     # Solaris /bin/sh is too old/non-POSIX compliant
  87     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  88     SHELL="$POSIX_SHELL"
  89     ;;
  90 esac
  91
  92 dnl clang is mostly GCC-compatible, but its version is much lower,
  93 dnl so we have to check for it.
  94 AC_MSG_CHECKING([if compiling with clang])
  95
  96 AC_COMPILE_IFELSE(
  97 [AC_LANG_PROGRAM([], [[
  98 #ifndef __clang__
  99        not clang
 100 #endif
 101 ]])],
 102 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 103
 104 AC_MSG_RESULT([$acv_mesa_CLANG])
 105
 106 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 107 dnl versions are explictly not supported.
 108 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 109     AC_MSG_CHECKING([whether gcc version is sufficient])
 110     major=0
 111     minor=0
 112
 113     GCC_VERSION=`$CC -dumpversion`
 114     if test $? -eq 0; then
 115         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 116         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 117     fi
 118
 119     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 122     else
 123         AC_MSG_RESULT([yes])
 124     fi
 125 fi
 126
 127
 128 MKDEP_OPTIONS=-fdepend
 129 dnl Ask gcc where it's keeping its secret headers
 130 if test "x$GCC" = xyes; then
 131     for dir in include include-fixed; do
 132         GCC_INCLUDES=`$CC -print-file-name=$dir`
 133         if test "x$GCC_INCLUDES" != x && \
 134            test "$GCC_INCLUDES" != "$dir" && \
 135            test -d "$GCC_INCLUDES"; then
 136             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 137         fi
 138     done
 139 fi
 140 AC_SUBST([MKDEP_OPTIONS])
 141
 142 dnl Make sure the pkg-config macros are defined
 143 m4_ifndef([PKG_PROG_PKG_CONFIG],
 144     [m4_fatal([Could not locate the pkg-config autoconf macros.
 145   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 146   are in a different location, try setting the environment variable
 147   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 148 PKG_PROG_PKG_CONFIG()
 149
 150 dnl LIB_DIR - library basename
 151 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 152 AC_SUBST([LIB_DIR])
 153
 154 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 155 _SAVE_LDFLAGS="$LDFLAGS"
 156 _SAVE_CPPFLAGS="$CPPFLAGS"
 157
 158 dnl Compiler macros
 159 DEFINES=""
 160 AC_SUBST([DEFINES])
 161 case "$host_os" in
 162 linux*|*-gnu*|gnu*)
 163     DEFINES="$DEFINES -D_GNU_SOURCE"
 164     ;;
 165 solaris*)
 166     DEFINES="$DEFINES -DSVR4"
 167     ;;
 168 cygwin*)
 169     DEFINES="$DEFINES"
 170     ;;
 171 esac
 172
 173 dnl Add flags for gcc and g++
 174 if test "x$GCC" = xyes; then
 175     CFLAGS="$CFLAGS -Wall -std=c99"
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl mklib options
 295 dnl
 296 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 297 if test "$enable_static" = yes; then
 298     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 299 fi
 300 AC_SUBST([MKLIB_OPTIONS])
 301
 302 dnl
 303 dnl other compiler options
 304 dnl
 305 AC_ARG_ENABLE([debug],
 306     [AS_HELP_STRING([--enable-debug],
 307         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 308     [enable_debug="$enableval"],
 309     [enable_debug=no]
 310 )
 311 if test "x$enable_debug" = xyes; then
 312     DEFINES="$DEFINES -DDEBUG"
 313     if test "x$GCC" = xyes; then
 314         CFLAGS="$CFLAGS -g"
 315     fi
 316     if test "x$GXX" = xyes; then
 317         CXXFLAGS="$CXXFLAGS -g"
 318     fi
 319 fi
 320
 321 dnl
 322 dnl library names
 323 dnl
 324 LIB_PREFIX_GLOB='lib'
 325 LIB_VERSION_SEPARATOR='.'
 326 if test "$enable_static" = yes; then
 327     LIB_EXTENSION='a'
 328 else
 329     case "$host_os" in
 330     darwin* )
 331         LIB_EXTENSION='dylib' ;;
 332     cygwin* )
 333         dnl prefix can be 'cyg' or 'lib'
 334         LIB_PREFIX_GLOB='???'
 335         LIB_VERSION_SEPARATOR='-'
 336         LIB_EXTENSION='dll' ;;
 337     aix* )
 338         LIB_EXTENSION='a' ;;
 339     * )
 340         LIB_EXTENSION='so' ;;
 341     esac
 342 fi
 343 AC_ARG_WITH([gl-lib-name],
 344   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 345     [specify GL library name @<:@default=GL@:>@])],
 346   [GL_LIB=$withval],
 347   [GL_LIB=GL])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 355
 356 dnl
 357 dnl Mangled Mesa support
 358 dnl
 359 AC_ARG_ENABLE([mangling],
 360   [AS_HELP_STRING([--enable-mangling],
 361     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 362   [enable_mangling="${enableval}"],
 363   [enable_mangling=no]
 364 )
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="Mangled${GL_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([OSMESA_LIB])
 372
 373 dnl
 374 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 375 dnl
 376 AC_ARG_ENABLE([texture-float],
 377     [AS_HELP_STRING([--enable-texture-float],
 378         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 379     [enable_texture_float="$enableval"],
 380     [enable_texture_float=no]
 381 )
 382 if test "x$enable_texture_float" = xyes; then
 383     AC_MSG_WARN([Floating-point textures enabled.])
 384     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 385     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 386 fi
 387
 388 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 389 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 390 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 391 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 392 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 393 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 394 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 395
 396 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403
 404 AC_SUBST([GL_LIB_NAME])
 405 AC_SUBST([OSMESA_LIB_NAME])
 406 AC_SUBST([EGL_LIB_NAME])
 407 AC_SUBST([GLESv1_CM_LIB_NAME])
 408 AC_SUBST([GLESv2_LIB_NAME])
 409 AC_SUBST([VG_LIB_NAME])
 410 AC_SUBST([GLAPI_LIB_NAME])
 411
 412 AC_SUBST([GL_LIB_GLOB])
 413 AC_SUBST([EGL_LIB_GLOB])
 414 AC_SUBST([GLESv1_CM_LIB_GLOB])
 415 AC_SUBST([GLESv2_LIB_GLOB])
 416 AC_SUBST([VG_LIB_GLOB])
 417 AC_SUBST([GLAPI_LIB_GLOB])
 418
 419 dnl
 420 dnl Arch/platform-specific settings
 421 dnl
 422 AC_ARG_ENABLE([asm],
 423     [AS_HELP_STRING([--disable-asm],
 424         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 425     [enable_asm="$enableval"],
 426     [enable_asm=yes]
 427 )
 428 asm_arch=""
 429 MESA_ASM_FILES=""
 430 AC_MSG_CHECKING([whether to enable assembly])
 431 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 432 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 433 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 434     case "$host_cpu" in
 435     i?86 | x86_64)
 436         enable_asm=no
 437         AC_MSG_RESULT([no, cross compiling])
 438         ;;
 439     esac
 440 fi
 441 # check for supported arches
 442 if test "x$enable_asm" = xyes; then
 443     case "$host_cpu" in
 444     i?86)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd*)
 447             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         MESA_ASM_FILES='$(X86_FILES)'
 471         AC_MSG_RESULT([yes, x86])
 472         ;;
 473     x86_64)
 474         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 475         MESA_ASM_FILES='$(X86_64_FILES)'
 476         AC_MSG_RESULT([yes, x86_64])
 477         ;;
 478     sparc)
 479         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 480         MESA_ASM_FILES='$(SPARC_FILES)'
 481         AC_MSG_RESULT([yes, sparc])
 482         ;;
 483     *)
 484         AC_MSG_RESULT([no, platform not supported])
 485         ;;
 486     esac
 487 fi
 488 AC_SUBST([MESA_ASM_FILES])
 489
 490 dnl PIC code macro
 491 MESA_PIC_FLAGS
 492
 493 dnl Check to see if dlopen is in default libraries (like Solaris, which
 494 dnl has it in libc), or if libdl is needed to get it.
 495 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 496     [AC_CHECK_LIB([dl], [dlopen],
 497        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 498 AC_SUBST([DLOPEN_LIBS])
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl Check for pthreads
 504 AX_PTHREAD
 505 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 506 dnl to -pthread, which causes problems if we need -lpthread to appear in
 507 dnl pkgconfig files.
 508 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     AC_CHECK_HEADER([selinux/selinux.h],[],
 518                     [AC_MSG_ERROR([SELinux headers not found])])
 519     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 520                  [AC_MSG_ERROR([SELinux library not found])])
 521     SELINUX_LIBS="-lselinux"
 522     DEFINES="$DEFINES -DMESA_SELINUX"
 523 fi
 524 AC_SUBST([SELINUX_LIBS])
 525
 526 dnl Options for APIs
 527 AC_ARG_ENABLE([opengl],
 528     [AS_HELP_STRING([--disable-opengl],
 529         [disable support for standard OpenGL API @<:@default=no@:>@])],
 530     [enable_opengl="$enableval"],
 531     [enable_opengl=yes])
 532 AC_ARG_ENABLE([gles1],
 533     [AS_HELP_STRING([--enable-gles1],
 534         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 535     [enable_gles1="$enableval"],
 536     [enable_gles1=no])
 537 AC_ARG_ENABLE([gles2],
 538     [AS_HELP_STRING([--enable-gles2],
 539         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 540     [enable_gles2="$enableval"],
 541     [enable_gles2=no])
 542 AC_ARG_ENABLE([openvg],
 543     [AS_HELP_STRING([--enable-openvg],
 544         [enable support for OpenVG API @<:@default=no@:>@])],
 545     [enable_openvg="$enableval"],
 546     [enable_openvg=no])
 547
 548 AC_ARG_ENABLE([dri],
 549     [AS_HELP_STRING([--enable-dri],
 550         [enable DRI modules @<:@default=enabled@:>@])],
 551     [enable_dri="$enableval"],
 552     [enable_dri=yes])
 553 AC_ARG_ENABLE([glx],
 554     [AS_HELP_STRING([--enable-glx],
 555         [enable GLX library @<:@default=enabled@:>@])],
 556     [enable_glx="$enableval"],
 557     [enable_glx=yes])
 558 AC_ARG_ENABLE([osmesa],
 559     [AS_HELP_STRING([--enable-osmesa],
 560         [enable OSMesa library @<:@default=disabled@:>@])],
 561     [enable_osmesa="$enableval"],
 562     [enable_osmesa=no])
 563 AC_ARG_ENABLE([egl],
 564     [AS_HELP_STRING([--disable-egl],
 565         [disable EGL library @<:@default=enabled@:>@])],
 566     [enable_egl="$enableval"],
 567     [enable_egl=yes])
 568
 569 AC_ARG_ENABLE([xorg],
 570     [AS_HELP_STRING([--enable-xorg],
 571         [enable support for X.Org DDX API @<:@default=no@:>@])],
 572     [enable_xorg="$enableval"],
 573     [enable_xorg=no])
 574 AC_ARG_ENABLE([xa],
 575     [AS_HELP_STRING([--enable-xa],
 576         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 577     [enable_xa="$enableval"],
 578     [enable_xa=no])
 579 AC_ARG_ENABLE([d3d1x],
 580     [AS_HELP_STRING([--enable-d3d1x],
 581         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 582     [enable_d3d1x="$enableval"],
 583     [enable_d3d1x=no])
 584 AC_ARG_ENABLE([gbm],
 585    [AS_HELP_STRING([--enable-gbm],
 586          [enable gbm library @<:@default=auto@:>@])],
 587    [enable_gbm="$enableval"],
 588    [enable_gbm=auto])
 589
 590 AC_ARG_ENABLE([xvmc],
 591    [AS_HELP_STRING([--enable-xvmc],
 592          [enable xvmc library @<:@default=auto@:>@])],
 593    [enable_xvmc="$enableval"],
 594    [enable_xvmc=auto])
 595 AC_ARG_ENABLE([vdpau],
 596    [AS_HELP_STRING([--enable-vdpau],
 597          [enable vdpau library @<:@default=auto@:>@])],
 598    [enable_vdpau="$enableval"],
 599    [enable_vdpau=auto])
 600 AC_ARG_ENABLE([va],
 601    [AS_HELP_STRING([--enable-va],
 602          [enable va library @<:@default=auto@:>@])],
 603    [enable_va="$enableval"],
 604    [enable_va=auto])
 605 AC_ARG_ENABLE([opencl],
 606    [AS_HELP_STRING([--enable-opencl],
 607          [enable OpenCL library @<:@default=no@:>@])],
 608    [enable_opencl="$enableval"],
 609    [enable_opencl=no])
 610 AC_ARG_ENABLE([xlib_glx],
 611     [AS_HELP_STRING([--enable-xlib-glx],
 612         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 613     [enable_xlib_glx="$enableval"],
 614     [enable_xlib_glx=no])
 615 AC_ARG_ENABLE([gallium_egl],
 616     [AS_HELP_STRING([--enable-gallium-egl],
 617         [enable optional EGL state tracker (not required
 618          for EGL support in Gallium with OpenGL and OpenGL ES)
 619          @<:@default=disable@:>@])],
 620     [enable_gallium_egl="$enableval"],
 621     [enable_gallium_egl=no])
 622 AC_ARG_ENABLE([gallium_gbm],
 623     [AS_HELP_STRING([--enable-gallium-gbm],
 624         [enable optional gbm state tracker (not required for
 625          gbm support in Gallium)
 626          @<:@default=auto@:>@])],
 627     [enable_gallium_gbm="$enableval"],
 628     [enable_gallium_gbm=auto])
 629
 630 AC_ARG_ENABLE([r600-llvm-compiler],
 631     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 632         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 633     [enable_r600_llvm="$enableval"],
 634     [enable_r600_llvm=no])
 635
 636 AC_ARG_ENABLE([gallium_tests],
 637     [AS_HELP_STRING([--enable-gallium-tests],
 638         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 639     [enable_gallium_tests="$enableval"],
 640     [enable_gallium_tests=no])
 641
 642 # Option for Gallium drivers
 643 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 644
 645 AC_ARG_WITH([gallium-drivers],
 646     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 647         [comma delimited Gallium drivers list, e.g.
 648         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 649         @<:@default=r300,r600,swrast@:>@])],
 650     [with_gallium_drivers="$withval"],
 651     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 652
 653 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 654 # here so that the script doesn't choke on an unknown driver name later.
 655 case "$with_gallium_drivers" in
 656     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 657     no) with_gallium_drivers='' ;;
 658 esac
 659
 660 if test "x$enable_opengl" = xno -a \
 661         "x$enable_gles1" = xno -a \
 662         "x$enable_gles2" = xno -a \
 663         "x$enable_openvg" = xno -a \
 664         "x$enable_xorg" = xno -a \
 665         "x$enable_xa" = xno -a \
 666         "x$enable_d3d1x" = xno -a \
 667         "x$enable_xvmc" = xno -a \
 668         "x$enable_vdpau" = xno -a \
 669         "x$enable_va" = xno -a \
 670         "x$enable_opencl" = xno; then
 671     AC_MSG_ERROR([at least one API should be enabled])
 672 fi
 673
 674 API_DEFINES=""
 675 if test "x$enable_opengl" = xno; then
 676     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 677 else
 678     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 679 fi
 680 if test "x$enable_gles1" = xyes; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 682 fi
 683 if test "x$enable_gles2" = xyes; then
 684     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 685 fi
 686 AC_SUBST([API_DEFINES])
 687
 688 if test "x$enable_glx" = xno; then
 689     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 690     enable_xlib_glx=no
 691 fi
 692
 693 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 694     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 695 fi
 696
 697 # Disable GLX if DRI and Xlib-GLX are not enabled
 698 if test "x$enable_glx" = xyes -a \
 699         "x$enable_dri" = xno -a \
 700         "x$enable_xlib_glx" = xno; then
 701     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 702     enable_glx=no
 703 fi
 704
 705 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 706 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 707                                   "x$enable_osmesa" = xyes)
 708
 709 AC_ARG_ENABLE([shared-glapi],
 710     [AS_HELP_STRING([--enable-shared-glapi],
 711         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 712     [enable_shared_glapi="$enableval"],
 713     [enable_shared_glapi="$enable_dri"])
 714
 715 # Shared GLAPI is only useful for DRI
 716 if test "x$enable_dri" = xno; then
 717     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 718     enable_shared_glapi=no
 719 fi
 720
 721 # TODO: Get rid of SHARED_GLAPI variable
 722 SHARED_GLAPI="0"
 723 if test "x$enable_shared_glapi" = xyes; then
 724     SHARED_GLAPI="1"
 725     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 726     # the remap table)
 727     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 728     CORE_DIRS="mapi/shared-glapi"
 729 fi
 730 AC_SUBST([SHARED_GLAPI])
 731 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 732
 733 dnl
 734 dnl Driver specific build directories
 735 dnl
 736 SRC_DIRS="gtest"
 737 GALLIUM_DIRS="auxiliary drivers state_trackers"
 738 GALLIUM_TARGET_DIRS=""
 739 GALLIUM_WINSYS_DIRS="sw"
 740 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 741 GALLIUM_STATE_TRACKERS_DIRS=""
 742
 743 # build glapi if OpenGL is enabled
 744 if test "x$enable_opengl" = xyes; then
 745     CORE_DIRS="$CORE_DIRS mapi/glapi"
 746 fi
 747
 748 # build es1api if OpenGL ES 1.x is enabled
 749 if test "x$enable_gles1" = xyes; then
 750     CORE_DIRS="$CORE_DIRS mapi/es1api"
 751 fi
 752
 753 # build es2api if OpenGL ES 2.x is enabled
 754 if test "x$enable_gles2" = xyes; then
 755     CORE_DIRS="$CORE_DIRS mapi/es2api"
 756 fi
 757
 758 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 759 case "x$enable_opengl$enable_gles1$enable_gles2" in
 760 x*yes*)
 761     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 762     ;;
 763 esac
 764
 765 case "x$enable_glx$enable_xlib_glx" in
 766 xyesyes)
 767     DRIVER_DIRS="$DRIVER_DIRS x11"
 768     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 769     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 770     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 771     HAVE_WINSYS_XLIB="yes"
 772     ;;
 773 xyesno)
 774     # DRI-based GLX
 775     SRC_DIRS="$SRC_DIRS glx"
 776     ;;
 777 esac
 778
 779 if test "x$enable_dri" = xyes; then
 780     DRIVER_DIRS="$DRIVER_DIRS dri"
 781
 782     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 783     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 784     HAVE_ST_DRI="yes"
 785 fi
 786
 787 if test "x$enable_osmesa" = xyes; then
 788     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 789 fi
 790
 791 AC_SUBST([SRC_DIRS])
 792 AC_SUBST([DRIVER_DIRS])
 793 AC_SUBST([GALLIUM_DIRS])
 794 AC_SUBST([GALLIUM_TARGET_DIRS])
 795 AC_SUBST([GALLIUM_WINSYS_DIRS])
 796 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 797 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 798 AC_SUBST([MESA_LLVM])
 799
 800 # Check for libdrm
 801 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 802                   [have_libdrm=yes], [have_libdrm=no])
 803
 804 if test "x$enable_dri" = xyes; then
 805     # DRI must be shared, I think
 806     if test "$enable_static" = yes; then
 807         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 808     fi
 809
 810     # not a hard requirement as swrast does not depend on it
 811     if test "x$have_libdrm" = xyes; then
 812         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 813     fi
 814 fi
 815
 816 dnl Find out if X is available.
 817 PKG_CHECK_MODULES([X11], [x11])
 818
 819 dnl Try to tell the user that the --x-* options are only used when
 820 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 821 m4_divert_once([HELP_BEGIN],
 822 [These options are only used when the X libraries cannot be found by the
 823 pkg-config utility.])
 824
 825 dnl We need X for xlib and dri, so bomb now if it's not found
 826 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 827     AC_MSG_ERROR([X11 development libraries needed for GLX])
 828 fi
 829
 830 if test "x$enable_glx" = xyes; then
 831     DEFINES="$DEFINES -DUSE_XCB"
 832 fi
 833
 834 dnl Direct rendering or just indirect rendering
 835 case "$host_os" in
 836 gnu*)
 837     dnl Disable by default on GNU/Hurd
 838     driglx_direct_default="no"
 839     ;;
 840 cygwin*)
 841     dnl Disable by default on cygwin
 842     driglx_direct_default="no"
 843     ;;
 844 *)
 845     driglx_direct_default="yes"
 846     ;;
 847 esac
 848 AC_ARG_ENABLE([driglx-direct],
 849     [AS_HELP_STRING([--disable-driglx-direct],
 850         [enable direct rendering in GLX and EGL for DRI \
 851             @<:@default=auto@:>@])],
 852     [driglx_direct="$enableval"],
 853     [driglx_direct="$driglx_direct_default"])
 854
 855 dnl
 856 dnl libGL configuration per driver
 857 dnl
 858 case "x$enable_glx$enable_xlib_glx" in
 859 xyesyes)
 860     # Xlib-based GLX
 861     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 862     GL_PC_REQ_PRIV="x11 xext"
 863     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 864     GL_LIB_DEPS="$XLIBGL_LIBS"
 865     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 866     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 867     ;;
 868 xyesno)
 869     # DRI-based GLX
 870     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 871     if test x"$driglx_direct" = xyes; then
 872         if test "x$have_libdrm" != xyes; then
 873             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 874         fi
 875         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 876         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 877     fi
 878
 879     # find the DRI deps for libGL
 880     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 881
 882     # add xf86vidmode if available
 883     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 884     if test "$HAVE_XF86VIDMODE" = yes ; then
 885         dri_modules="$dri_modules xxf86vm"
 886     fi
 887
 888     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 889     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 890     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 891     GL_LIB_DEPS="$DRIGL_LIBS"
 892
 893     # need DRM libs, $PTHREAD_LIBS, etc.
 894     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 895     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896     ;;
 897 esac
 898
 899 # This is outside the case (above) so that it is invoked even for non-GLX
 900 # builds.
 901 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 902
 903 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 904 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 906 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 907
 908 AC_SUBST([GL_LIB_DEPS])
 909 AC_SUBST([GL_PC_REQ_PRIV])
 910 AC_SUBST([GL_PC_LIB_PRIV])
 911 AC_SUBST([GL_PC_CFLAGS])
 912 AC_SUBST([DRI_PC_REQ_PRIV])
 913 AC_SUBST([GLESv1_CM_LIB_DEPS])
 914 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 915 AC_SUBST([GLESv2_LIB_DEPS])
 916 AC_SUBST([GLESv2_PC_LIB_PRIV])
 917
 918 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 919 GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 920
 921 AC_SUBST([HAVE_XF86VIDMODE])
 922
 923 dnl
 924 dnl More GLX setup
 925 dnl
 926 case "x$enable_glx$enable_xlib_glx" in
 927 xyesyes)
 928     DEFINES="$DEFINES -DUSE_XSHM"
 929     ;;
 930 xyesno)
 931     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 932     if test "x$driglx_direct" = xyes; then
 933         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 934     fi
 935     ;;
 936 esac
 937
 938 dnl
 939 dnl TLS detection
 940 dnl
 941
 942 AC_ARG_ENABLE([glx-tls],
 943     [AS_HELP_STRING([--enable-glx-tls],
 944         [enable TLS support in GLX @<:@default=disabled@:>@])],
 945     [GLX_USE_TLS="$enableval"],
 946     [GLX_USE_TLS=no])
 947 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 948
 949 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 950       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
 951
 952 dnl
 953 dnl More DRI setup
 954 dnl
 955 dnl Directory for DRI drivers
 956 AC_ARG_WITH([dri-driverdir],
 957     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 958         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 959     [DRI_DRIVER_INSTALL_DIR="$withval"],
 960     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 961 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 962 dnl Extra search path for DRI drivers
 963 AC_ARG_WITH([dri-searchpath],
 964     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 965         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 966     [DRI_DRIVER_SEARCH_DIR="$withval"],
 967     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 968 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 969 dnl Which drivers to build - default is chosen by platform
 970 AC_ARG_WITH([dri-drivers],
 971     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 972         [comma delimited DRI drivers list, e.g.
 973         "swrast,i965,radeon" @<:@default=auto@:>@])],
 974     [with_dri_drivers="$withval"],
 975     [with_dri_drivers=yes])
 976 if test "x$with_dri_drivers" = x; then
 977     with_dri_drivers=no
 978 fi
 979
 980 dnl If $with_dri_drivers is yes, directories will be added through
 981 dnl platform checks
 982 DRI_DIRS=""
 983 case "$with_dri_drivers" in
 984 no) ;;
 985 yes)
 986     # classic DRI drivers require FEATURE_GL to build
 987     if test "x$enable_opengl" = xyes; then
 988         DRI_DIRS="yes"
 989     fi
 990     ;;
 991 *)
 992     # verify the requested driver directories exist
 993     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 994     for driver in $dri_drivers; do
 995         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 996             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 997     done
 998     DRI_DIRS="$dri_drivers"
 999     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1000         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1001     fi
1002     ;;
1003 esac
1004
1005 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1006 if test "x$enable_dri" = xyes; then
1007     # Platform specific settings and drivers to build
1008     case "$host_os" in
1009     linux*)
1010         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1011         DEFINES="$DEFINES -DHAVE_ALIAS"
1012
1013         case "$host_cpu" in
1014         x86_64)
1015             if test "x$DRI_DIRS" = "xyes"; then
1016                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1017             fi
1018             ;;
1019         powerpc*)
1020             # Build only the drivers for cards that exist on PowerPC.
1021             if test "x$DRI_DIRS" = "xyes"; then
1022                 DRI_DIRS="r200 radeon swrast"
1023             fi
1024             ;;
1025         sparc*)
1026             # Build only the drivers for cards that exist on sparc
1027             if test "x$DRI_DIRS" = "xyes"; then
1028                 DRI_DIRS="r200 radeon swrast"
1029             fi
1030             ;;
1031         esac
1032         ;;
1033     freebsd* | dragonfly* | *netbsd*)
1034         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1035         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1036
1037         if test "x$DRI_DIRS" = "xyes"; then
1038             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1039         fi
1040         ;;
1041     gnu*)
1042         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1043         DEFINES="$DEFINES -DHAVE_ALIAS"
1044         ;;
1045     solaris*)
1046         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1047         ;;
1048     cygwin*)
1049         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1050         if test "x$DRI_DIRS" = "xyes"; then
1051             DRI_DIRS="swrast"
1052         fi
1053         ;;
1054     esac
1055
1056     # default drivers
1057     if test "x$DRI_DIRS" = "xyes"; then
1058         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1059     fi
1060
1061     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1062
1063     # Check for expat
1064     if test "x$enable_dri" = xyes; then
1065         EXPAT_INCLUDES=""
1066         EXPAT_LIB=-lexpat
1067         AC_ARG_WITH([expat],
1068             [AS_HELP_STRING([--with-expat=DIR],
1069                 [expat install directory])],[
1070             EXPAT_INCLUDES="-I$withval/include"
1071             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1072             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1073             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1074             ])
1075         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1076         save_LIBS="$LIBS"
1077         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1078             [AC_MSG_ERROR([Expat required for DRI.])])
1079         LIBS="$save_LIBS"
1080     fi
1081
1082     # if we are building any dri driver other than swrast ...
1083     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1084         # ... libdrm is required
1085         if test "x$have_libdrm" != xyes; then
1086             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1087         fi
1088         # ... and build dricommon
1089         HAVE_COMMON_DRI=yes
1090     fi
1091
1092     # put all the necessary libs together
1093     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1094     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1095 fi
1096 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1097 AC_SUBST([DRI_DIRS])
1098 AC_SUBST([EXPAT_INCLUDES])
1099 AC_SUBST([DRI_LIB_DEPS])
1100 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1101
1102 case $DRI_DIRS in
1103 *i915*|*i965*)
1104     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1105
1106     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1107         case $d in
1108         i915)
1109             HAVE_I915_DRI=yes;
1110             ;;
1111         i965)
1112             HAVE_I965_DRI=yes;
1113             ;;
1114         esac
1115     done
1116
1117     ;;
1118 esac
1119
1120 case $DRI_DIRS in
1121 *nouveau*)
1122     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1123     HAVE_NOUVEAU_DRI=yes;
1124     ;;
1125 esac
1126
1127 case $DRI_DIRS in
1128 *radeon*|*r200*)
1129     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1130
1131     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1132         case $d in
1133         radeon)
1134             HAVE_RADEON_DRI=yes;
1135             ;;
1136         r200)
1137             HAVE_R200_DRI=yes;
1138             ;;
1139         esac
1140     done
1141
1142     ;;
1143 esac
1144
1145 case $DRI_DIRS in
1146 *swrast*)
1147     HAVE_SWRAST_DRI=yes;
1148     ;;
1149 esac
1150
1151 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1152 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1153 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1158
1159 dnl
1160 dnl OSMesa configuration
1161 dnl
1162
1163 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1164 AC_ARG_WITH([osmesa-bits],
1165     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1166         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1167     [osmesa_bits="$withval"],
1168     [osmesa_bits=8])
1169 if test "x$osmesa_bits" != x8; then
1170     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1171         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1172         osmesa_bits=8
1173     fi
1174 fi
1175 case "x$osmesa_bits" in
1176 x8)
1177     OSMESA_LIB="${OSMESA_LIB}"
1178     ;;
1179 x16|x32)
1180     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1181     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1182     ;;
1183 *)
1184     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1185     ;;
1186 esac
1187
1188 if test "x$enable_osmesa" = xyes; then
1189     # only link libraries with osmesa if shared
1190     if test "$enable_static" = no; then
1191         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1192     else
1193         OSMESA_LIB_DEPS=""
1194     fi
1195     OSMESA_MESA_DEPS=""
1196     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1197 fi
1198
1199 AC_SUBST([OSMESA_LIB_DEPS])
1200 AC_SUBST([OSMESA_MESA_DEPS])
1201 AC_SUBST([OSMESA_PC_REQ])
1202 AC_SUBST([OSMESA_PC_LIB_PRIV])
1203
1204 dnl
1205 dnl gbm configuration
1206 dnl
1207 if test "x$enable_gbm" = xauto; then
1208     case "$with_egl_platforms" in
1209         *drm*)
1210             enable_gbm=yes ;;
1211          *)
1212             enable_gbm=no ;;
1213     esac
1214 fi
1215 if test "x$enable_gbm" = xyes; then
1216     SRC_DIRS="$SRC_DIRS gbm"
1217
1218     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1219                       AC_MSG_ERROR([gbm needs udev]))
1220
1221     if test "x$enable_dri" = xyes; then
1222         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1223         if test "x$enable_shared_glapi" = xno; then
1224             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1225         fi
1226         PKG_CHECK_MODULES([LIBKMS], [libkms], [],
1227                           AC_MSG_ERROR([gbm needs libkms]))
1228     fi
1229 fi
1230 GBM_PC_REQ_PRIV="libudev"
1231 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1232 AC_SUBST([GBM_PC_REQ_PRIV])
1233 AC_SUBST([GBM_PC_LIB_PRIV])
1234
1235 dnl
1236 dnl EGL configuration
1237 dnl
1238 EGL_CLIENT_APIS=""
1239
1240 if test "x$enable_egl" = xyes; then
1241     SRC_DIRS="$SRC_DIRS egl"
1242     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1243
1244     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1245
1246     if test "$enable_static" != yes; then
1247         # build egl_glx when libGL is built
1248         if test "x$enable_glx" = xyes; then
1249             HAVE_EGL_DRIVER_GLX=1
1250         fi
1251
1252         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1253                           [have_libudev=yes],[have_libudev=no])
1254         if test "$have_libudev" = yes; then
1255             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1256         fi
1257
1258         if test "x$enable_dri" = xyes; then
1259             HAVE_EGL_DRIVER_DRI2=1
1260         fi
1261
1262     fi
1263 fi
1264 AC_SUBST([EGL_LIB_DEPS])
1265
1266 dnl
1267 dnl EGL Gallium configuration
1268 dnl
1269 if test "x$enable_gallium_egl" = xyes; then
1270     if test "x$with_gallium_drivers" = x; then
1271         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1272     fi
1273     if test "x$enable_egl" = xno; then
1274         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1275     fi
1276     if test "x$have_libdrm" != xyes; then
1277         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1278     fi
1279
1280     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1281     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1282     HAVE_ST_EGL="yes"
1283 fi
1284
1285 dnl
1286 dnl gbm Gallium configuration
1287 dnl
1288 if test "x$enable_gallium_gbm" = xauto; then
1289     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1290         yesyesyes*drm*)
1291             enable_gallium_gbm=yes ;;
1292          *)
1293             enable_gallium_gbm=no ;;
1294     esac
1295 fi
1296 if test "x$enable_gallium_gbm" = xyes; then
1297     if test "x$with_gallium_drivers" = x; then
1298         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1299     fi
1300     if test "x$enable_gbm" = xno; then
1301         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1302     fi
1303     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1304     if test "x$enable_dri" = xno; then
1305         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1306     fi
1307
1308     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1309     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1310     HAVE_ST_GBM="yes"
1311     enable_gallium_loader=yes
1312 fi
1313
1314 dnl
1315 dnl X.Org DDX configuration
1316 dnl
1317 if test "x$enable_xorg" = xyes; then
1318     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1319     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1320     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1321     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1322         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1323         HAVE_XEXTPROTO_71="no")
1324     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1325     HAVE_ST_XORG=yes
1326 fi
1327
1328 dnl
1329 dnl XA configuration
1330 dnl
1331 if test "x$enable_xa" = xyes; then
1332 AC_PROG_AWK
1333 AC_PROG_GREP
1334 AC_CHECK_PROG(NM, nm, "nm")
1335 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1336 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1337 enable_xa=no
1338 fi
1339 fi
1340 if test "x$enable_xa" = xyes; then
1341     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1342     HAVE_ST_XA=yes
1343     AC_SUBST(AWK)
1344     AC_SUBST(GREP)
1345     AC_SUBST(NM)
1346 fi
1347
1348 dnl
1349 dnl OpenVG configuration
1350 dnl
1351 VG_LIB_DEPS=""
1352
1353 if test "x$enable_openvg" = xyes; then
1354     if test "x$enable_egl" = xno; then
1355         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1356     fi
1357     if test "x$with_gallium_drivers" = x; then
1358         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1359     fi
1360     if test "x$enable_gallium_egl" = xno; then
1361         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1362     fi
1363
1364     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1365     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1366     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1367     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1368     HAVE_ST_VEGA=yes
1369     VG_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1370     AC_SUBST([VG_PC_LIB_PRIV])
1371 fi
1372
1373 dnl
1374 dnl D3D1X configuration
1375 dnl
1376
1377 if test "x$enable_d3d1x" = xyes; then
1378     if test "x$with_gallium_drivers" = x; then
1379         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1380     fi
1381
1382     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1383     HAVE_ST_D3D1X=yes
1384 fi
1385
1386 dnl
1387 dnl Gallium G3DVL configuration
1388 dnl
1389 AC_ARG_ENABLE([gallium-g3dvl],
1390     [AS_HELP_STRING([--enable-gallium-g3dvl],
1391         [build gallium g3dvl @<:@default=disabled@:>@])],
1392     [enable_gallium_g3dvl="$enableval"],
1393     [enable_gallium_g3dvl=no])
1394 if test "x$enable_gallium_g3dvl" = xyes; then
1395     if test "x$with_gallium_drivers" = x; then
1396         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1397     fi
1398
1399     if test "x$enable_xvmc" = xauto; then
1400         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1401     fi
1402
1403     if test "x$enable_vdpau" = xauto; then
1404         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1405     fi
1406
1407     if test "x$enable_va" = xauto; then
1408         #don't enable vaapi state tracker even if package exists
1409         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1410         enable_va=no
1411     fi
1412 fi
1413
1414 if test "x$enable_xvmc" = xyes; then
1415     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1416     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1417     HAVE_ST_XVMC="yes"
1418 fi
1419
1420 if test "x$enable_vdpau" = xyes; then
1421     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1422     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1423     HAVE_ST_VDPAU="yes"
1424 fi
1425
1426 if test "x$enable_va" = xyes; then
1427     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1428     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1429     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1430     HAVE_ST_VA="yes"
1431 fi
1432
1433 dnl
1434 dnl OpenCL configuration
1435 dnl
1436
1437 AC_ARG_WITH([libclc-path],
1438    [AS_HELP_STRING([--with-libclc-path],
1439          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1440    [LIBCLC_PATH="$withval"],
1441    [LIBCLC_PATH=""])
1442
1443 AC_ARG_WITH([clang-libdir],
1444    [AS_HELP_STRING([--with-clang-libdir],
1445          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1446    [CLANG_LIBDIR="$withval"],
1447    [CLANG_LIBDIR=""])
1448
1449 AC_SUBST([LIBCLC_PATH])
1450
1451 if test "x$enable_opencl" = xyes; then
1452     if test "x$with_gallium_drivers" = x; then
1453         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1454     fi
1455
1456     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1457         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1458     fi
1459
1460     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1461     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1462     enable_gallium_loader=yes
1463 fi
1464
1465 dnl
1466 dnl Gallium configuration
1467 dnl
1468 if test "x$with_gallium_drivers" != x; then
1469     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1470 fi
1471 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1472
1473 AC_SUBST([LLVM_BINDIR])
1474 AC_SUBST([LLVM_CFLAGS])
1475 AC_SUBST([LLVM_CPPFLAGS])
1476 AC_SUBST([LLVM_CXXFLAGS])
1477 AC_SUBST([LLVM_LIBDIR])
1478 AC_SUBST([LLVM_LIBS])
1479 AC_SUBST([LLVM_LDFLAGS])
1480 AC_SUBST([LLVM_INCLUDEDIR])
1481 AC_SUBST([LLVM_VERSION])
1482 AC_SUBST([CLANG_RESOURCE_DIR])
1483
1484 case "x$enable_opengl$enable_gles1$enable_gles2" in
1485 x*yes*)
1486     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1487     ;;
1488 esac
1489
1490 AC_SUBST([VG_LIB_DEPS])
1491 AC_SUBST([EGL_CLIENT_APIS])
1492
1493 dnl
1494 dnl EGL Platforms configuration
1495 dnl
1496 AC_ARG_WITH([egl-platforms],
1497     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1498         [comma delimited native platforms libEGL supports, e.g.
1499         "x11,drm" @<:@default=auto@:>@])],
1500     [with_egl_platforms="$withval"],
1501     [if test "x$enable_egl" = xyes; then
1502         with_egl_platforms="x11"
1503     else
1504         with_egl_platforms=""
1505     fi])
1506
1507 EGL_PLATFORMS=""
1508
1509 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1510     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1511 fi
1512
1513 # Do per-EGL platform setups and checks
1514 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1515 for plat in $egl_platforms; do
1516         case "$plat" in
1517         fbdev|null)
1518                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1519                 ;;
1520
1521         wayland)
1522                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1523                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1524                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1525
1526                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1527                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1528                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1529                 ;;
1530
1531         x11)
1532                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1533                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1534                 save_LIBS="$LIBS"
1535                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1536                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1537                 LIBS="$save_LIBS"
1538                 ;;
1539
1540         drm)
1541                 test "x$enable_gbm" = "xno" &&
1542                         AC_MSG_ERROR([EGL platform drm needs gbm])
1543                 ;;
1544
1545         android|gdi)
1546                 ;;
1547
1548         *)
1549                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1550                 ;;
1551         esac
1552
1553         case "$plat$have_libudev" in
1554                 waylandno|drmno)
1555                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1556         esac
1557 done
1558
1559 # libEGL wants to default to the first platform specified in
1560 # ./configure.  parse that here.
1561 if test "x$egl_platforms" != "x"; then
1562     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1563     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1564 else
1565     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1566 fi
1567
1568 EGL_PLATFORMS="$egl_platforms"
1569
1570 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1571 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1572 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1573 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1574 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1575
1576 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1577 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1578
1579 AC_SUBST([EGL_NATIVE_PLATFORM])
1580 AC_SUBST([EGL_PLATFORMS])
1581 AC_SUBST([EGL_CFLAGS])
1582
1583 AC_ARG_WITH([egl-driver-dir],
1584     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1585                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1586     [EGL_DRIVER_INSTALL_DIR="$withval"],
1587     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1588 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1589
1590 AC_ARG_WITH([xorg-driver-dir],
1591     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1592                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1593     [XORG_DRIVER_INSTALL_DIR="$withval"],
1594     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1595 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1596
1597 AC_ARG_WITH([max-width],
1598     [AS_HELP_STRING([--with-max-width=N],
1599                     [Maximum framebuffer width (4096)])],
1600     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1601      AS_IF([test "${withval}" -gt "4096"],
1602            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1603 )
1604 AC_ARG_WITH([max-height],
1605     [AS_HELP_STRING([--with-max-height=N],
1606                     [Maximum framebuffer height (4096)])],
1607     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1608      AS_IF([test "${withval}" -gt "4096"],
1609            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1610 )
1611
1612 dnl
1613 dnl Gallium LLVM
1614 dnl
1615 AC_ARG_ENABLE([gallium-llvm],
1616     [AS_HELP_STRING([--enable-gallium-llvm],
1617         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1618     [enable_gallium_llvm="$enableval"],
1619     [enable_gallium_llvm=auto])
1620
1621 AC_ARG_WITH([llvm-shared-libs],
1622     [AS_HELP_STRING([--with-llvm-shared-libs],
1623         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1624     [with_llvm_shared_libs=yes],
1625     [with_llvm_shared_libs=no])
1626
1627 AC_ARG_WITH([llvm-prefix],
1628     [AS_HELP_STRING([--with-llvm-prefix],
1629         [Prefix for LLVM installations in non-standard locations])],
1630     [llvm_prefix="$withval"],
1631     [llvm_prefix=""])
1632
1633
1634 if test "x$with_gallium_drivers" = x; then
1635     enable_gallium_llvm=no
1636 fi
1637 if test "x$enable_gallium_llvm" = xauto; then
1638     case "$host_cpu" in
1639     i*86|x86_64) enable_gallium_llvm=yes;;
1640     esac
1641 fi
1642 if test "x$enable_gallium_llvm" = xyes; then
1643     if test "x$llvm_prefix" != x; then
1644         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1645     else
1646         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1647     fi
1648
1649     if test "x$LLVM_CONFIG" != xno; then
1650         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1651         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1652         if test "x$with_llvm_shared_libs" = xyes; then
1653             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1654             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1655         else
1656             LLVM_COMPONENTS="engine bitwriter"
1657             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1658                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1659             fi
1660             if test "x$enable_opencl" = xyes; then
1661                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1662             fi
1663             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1664         fi
1665         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1666         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1667         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1668         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1669         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1670         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1671         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1672         MESA_LLVM=1
1673
1674         dnl Check for Clang interanl headers
1675         if test "x$enable_opencl" = xyes; then
1676             if test "x$CLANG_LIBDIR" = x; then
1677                 CLANG_LIBDIR=${LLVM_LIBDIR}
1678             fi
1679             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1680             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1681                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1682         fi
1683     else
1684         MESA_LLVM=0
1685     fi
1686 else
1687     MESA_LLVM=0
1688 fi
1689
1690 dnl Directory for XVMC libs
1691 AC_ARG_WITH([xvmc-libdir],
1692     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1693         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1694     [XVMC_LIB_INSTALL_DIR="$withval"],
1695     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1696 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1697
1698 dnl
1699 dnl Gallium Tests
1700 dnl
1701 if test "x$enable_gallium_tests" = xyes; then
1702     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1703     enable_gallium_loader=yes
1704 fi
1705
1706 dnl Directory for VDPAU libs
1707 AC_ARG_WITH([vdpau-libdir],
1708     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1709         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1710     [VDPAU_LIB_INSTALL_DIR="$withval"],
1711     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1712 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1713
1714 dnl Directory for VA libs
1715 AC_ARG_WITH([va-libdir],
1716     [AS_HELP_STRING([--with-va-libdir=DIR],
1717         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1718     [VA_LIB_INSTALL_DIR="$withval"],
1719     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1720 AC_SUBST([VA_LIB_INSTALL_DIR])
1721
1722 dnl Directory for OpenCL libs
1723 AC_ARG_WITH([opencl-libdir],
1724     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1725         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1726     [OPENCL_LIB_INSTALL_DIR="$withval"],
1727     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1728 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1729
1730 dnl
1731 dnl Gallium helper functions
1732 dnl
1733 gallium_check_st() {
1734     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1735          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1736          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1737          if test "x$have_libdrm" != xyes; then
1738             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1739          fi
1740          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1741     fi
1742     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1743          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1744     fi
1745     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1746          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1747     fi
1748     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1749          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1750     fi
1751     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1752          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1753     fi
1754     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1755          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1756     fi
1757     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1758          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1759     fi
1760 }
1761
1762 gallium_require_llvm() {
1763     if test "x$MESA_LLVM" = x0; then
1764         case "$host_cpu" in
1765         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1766         esac
1767     fi
1768 }
1769
1770 gallium_require_drm_loader() {
1771     if test "x$enable_gallium_loader" = xyes; then
1772         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1773                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1774         if test "x$have_libdrm" != xyes; then
1775             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1776         fi
1777         enable_gallium_drm_loader=yes
1778     fi
1779 }
1780
1781 dnl Gallium drivers
1782 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1783 if test "x$with_gallium_drivers" != x; then
1784     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1785     for driver in $gallium_drivers; do
1786         case "x$driver" in
1787         xsvga)
1788             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1789             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1790             ;;
1791         xi915)
1792             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1793             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1794             if test "x$MESA_LLVM" = x1; then
1795                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1796             fi
1797             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1798             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1799             ;;
1800         xr300)
1801             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1802             gallium_require_llvm "Gallium R300"
1803             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1804             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1805             ;;
1806         xr600)
1807             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1808             gallium_require_drm_loader
1809             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1810             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1811                 if test "x$LLVM_VERSION" != "x3.1"; then
1812                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1813                 fi
1814                 NEED_RADEON_GALLIUM=yes;
1815             fi
1816             if test "x$enable_r600_llvm" = xyes; then
1817                 USE_R600_LLVM_COMPILER=yes;
1818             fi
1819             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1820                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1821             fi
1822             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1823             ;;
1824         xradeonsi)
1825             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1826             gallium_require_drm_loader
1827             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1828             if test "x$LLVM_VERSION" != "x3.1"; then
1829                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1830             fi
1831             NEED_RADEON_GALLIUM=yes;
1832             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1833             ;;
1834         xnouveau)
1835             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1836             gallium_require_drm_loader
1837             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1838             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1839             ;;
1840         xswrast)
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1842             if test "x$MESA_LLVM" = x1; then
1843                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1844             fi
1845
1846             if test "x$HAVE_ST_DRI" = xyes; then
1847                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1848             fi
1849             if test "x$HAVE_ST_VDPAU" = xyes; then
1850                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1851             fi
1852             if test "x$HAVE_ST_XVMC" = xyes; then
1853                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1854             fi
1855             if test "x$HAVE_ST_VA" = xyes; then
1856                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1857             fi
1858             if test "x$HAVE_ST_VDPAU" = xyes ||
1859                test "x$HAVE_ST_XVMC" = xyes ||
1860                test "x$HAVE_ST_VA" = xyes; then
1861                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1862                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1863                fi
1864             fi
1865             ;;
1866         *)
1867             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1868             ;;
1869         esac
1870     done
1871 fi
1872
1873 if test "x$enable_gallium_loader" = xyes; then
1874     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1875     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1876     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1877     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1878
1879     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1880         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1881         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1882     fi
1883
1884     if test "x$enable_gallium_drm_loader" = xyes; then
1885         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1886         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1887                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1888         if test "x$pipe_loader_have_xcb" = xyes; then
1889             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1890             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1891         fi
1892     fi
1893
1894     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1895     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1896 fi
1897
1898 dnl Tell Automake which drivers to build
1899 for driver in $GALLIUM_DRIVERS_DIRS; do
1900     case "x$driver" in
1901         xgalahad)
1902             HAVE_GALAHAD_GALLIUM=yes;
1903             ;;
1904         xidentity)
1905             HAVE_IDENTITY_GALLIUM=yes;
1906             ;;
1907         xnoop)
1908             HAVE_NOOP_GALLIUM=yes;
1909             ;;
1910         *)
1911             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1912             ;;
1913     esac
1914 done
1915
1916 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1917 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1918 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1919 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1920 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1921 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1922 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1923 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1924 AC_SUBST([GALLIUM_MAKE_DIRS])
1925
1926 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1927
1928 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1929 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1930 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1931
1932 dnl prepend CORE_DIRS to SRC_DIRS
1933 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1934
1935 dnl Restore LDFLAGS and CPPFLAGS
1936 LDFLAGS="$_SAVE_LDFLAGS"
1937 CPPFLAGS="$_SAVE_CPPFLAGS"
1938
1939 dnl Add user CFLAGS and CXXFLAGS
1940 CFLAGS="$CFLAGS $USER_CFLAGS"
1941 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1942
1943 dnl Substitute the config
1944 AC_CONFIG_FILES([configs/current
1945                 Makefile
1946                 src/egl/Makefile
1947                 src/egl/drivers/Makefile
1948                 src/egl/drivers/dri2/Makefile
1949                 src/egl/drivers/glx/Makefile
1950                 src/egl/main/Makefile
1951                 src/egl/main/egl.pc
1952                 src/egl/wayland/Makefile
1953                 src/egl/wayland/wayland-drm/Makefile
1954                 src/egl/wayland/wayland-egl/Makefile
1955                 src/egl/wayland/wayland-egl/wayland-egl.pc
1956                 src/gallium/Makefile
1957                 src/gallium/auxiliary/pipe-loader/Makefile
1958                 src/gallium/drivers/Makefile
1959                 src/gallium/drivers/r300/Makefile
1960                 src/gallium/drivers/r600/Makefile
1961                 src/gallium/state_trackers/clover/Makefile
1962                 src/gallium/targets/opencl/Makefile
1963                 src/gbm/Makefile
1964                 src/gbm/main/gbm.pc
1965                 src/glsl/Makefile
1966                 src/glsl/glcpp/Makefile
1967                 src/glsl/tests/Makefile
1968                 src/glx/Makefile
1969                 src/glx/tests/Makefile
1970                 src/gtest/Makefile
1971                 src/Makefile
1972                 src/mapi/es1api/Makefile
1973                 src/mapi/es1api/glesv1_cm.pc
1974                 src/mapi/es2api/Makefile
1975                 src/mapi/es2api/glesv2.pc
1976                 src/mapi/glapi/Makefile
1977                 src/mapi/glapi/gen/Makefile
1978                 src/mapi/glapi/tests/Makefile
1979                 src/mapi/shared-glapi/Makefile
1980                 src/mapi/shared-glapi/tests/Makefile
1981                 src/mapi/vgapi/Makefile
1982                 src/mapi/vgapi/vg.pc
1983                 src/mesa/Makefile
1984                 src/mesa/gl.pc
1985                 src/mesa/drivers/Makefile
1986                 src/mesa/drivers/dri/dri.pc
1987                 src/mesa/drivers/dri/common/Makefile
1988                 src/mesa/drivers/dri/i915/Makefile
1989                 src/mesa/drivers/dri/i965/Makefile
1990                 src/mesa/drivers/dri/Makefile
1991                 src/mesa/drivers/dri/nouveau/Makefile
1992                 src/mesa/drivers/dri/r200/Makefile
1993                 src/mesa/drivers/dri/radeon/Makefile
1994                 src/mesa/drivers/dri/swrast/Makefile
1995                 src/mesa/drivers/osmesa/Makefile
1996                 src/mesa/drivers/osmesa/osmesa.pc
1997                 src/mesa/drivers/x11/Makefile
1998                 src/mesa/libdricore/Makefile
1999                 src/mesa/main/tests/Makefile
2000                 src/mesa/x86-64/Makefile
2001                 src/mesa/x86/Makefile])
2002
2003 dnl Sort the dirs alphabetically
2004 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2005 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2006 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2007 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2008 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2009
2010 AC_OUTPUT
2011
2012 dnl
2013 dnl Output some configuration info for the user
2014 dnl
2015 echo ""
2016 echo "        prefix:          $prefix"
2017 echo "        exec_prefix:     $exec_prefix"
2018 echo "        libdir:          $libdir"
2019 echo "        includedir:      $includedir"
2020
2021 dnl API info
2022 echo ""
2023 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2024 echo "        OpenVG:          $enable_openvg"
2025
2026 dnl Driver info
2027 echo ""
2028 if test "x$enable_osmesa" != xno; then
2029         echo "        OSMesa:          lib$OSMESA_LIB"
2030 else
2031         echo "        OSMesa:          no"
2032 fi
2033
2034 if test "x$enable_dri" != xno; then
2035         # cleanup the drivers var
2036         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2037         if test "x$DRI_DIRS" = x; then
2038             echo "        DRI drivers:     no"
2039         else
2040             echo "        DRI drivers:     $dri_dirs"
2041         fi
2042         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2043 fi
2044
2045 case "x$enable_glx$enable_xlib_glx" in
2046 xyesyes)
2047     echo "        GLX:             Xlib-based"
2048     ;;
2049 xyesno)
2050     echo "        GLX:             DRI-based"
2051     ;;
2052 *)
2053     echo "        GLX:             $enable_glx"
2054     ;;
2055 esac
2056
2057 dnl EGL
2058 echo ""
2059 echo "        EGL:             $enable_egl"
2060 if test "$enable_egl" = yes; then
2061     echo "        EGL platforms:   $EGL_PLATFORMS"
2062
2063     egl_drivers=""
2064     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2065         egl_drivers="$egl_drivers builtin:egl_glx"
2066     fi
2067     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2068         egl_drivers="$egl_drivers builtin:egl_dri2"
2069     fi
2070
2071     if test "x$HAVE_ST_EGL" = xyes; then
2072         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2073         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2074     else
2075         echo "        EGL drivers:    $egl_drivers"
2076     fi
2077 fi
2078
2079 echo ""
2080 if test "x$MESA_LLVM" = x1; then
2081     echo "        llvm:            yes"
2082     echo "        llvm-config:     $LLVM_CONFIG"
2083     echo "        llvm-version:    $LLVM_VERSION"
2084 else
2085     echo "        llvm:            no"
2086 fi
2087
2088 echo ""
2089 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2090     echo "        Gallium:         yes"
2091     echo "        Gallium dirs:    $GALLIUM_DIRS"
2092     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2093     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2094     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2095     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2096 else
2097     echo "        Gallium:         no"
2098 fi
2099
2100
2101 dnl Libraries
2102 echo ""
2103 echo "        Shared libs:     $enable_shared"
2104 echo "        Static libs:     $enable_static"
2105 echo "        Shared-glapi:    $enable_shared_glapi"
2106
2107 dnl Compiler options
2108 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2109 cflags=`echo $CFLAGS $PIC_FLAGS | \
2110     $SED 's/^ *//;s/  */ /;s/ *$//'`
2111 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2112     $SED 's/^ *//;s/  */ /;s/ *$//'`
2113 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2114 echo ""
2115 echo "        CFLAGS:          $cflags"
2116 echo "        CXXFLAGS:        $cxxflags"
2117 echo "        Macros:          $defines"
2118 echo ""
2119 echo "        PYTHON2:         $PYTHON2"
2120
2121 echo ""
2122 echo "        Run '${MAKE-make}' to build Mesa"
2123 echo ""