configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20 #
  21 # Process this file with autoconf to produce a configure script
  22
  23 AC_PREREQ([2.60])
  24 AC_INIT([intel-gpu-tools],
  25         [1.3],
  26         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
  27         [intel-gpu-tools])
  28
  29 AC_CONFIG_SRCDIR([Makefile.am])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_GNU_SOURCE
  36
  37 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  38 AM_PATH_PYTHON([3],, [:])
  39
  40 AC_PROG_CC
  41 AM_PROG_LEX
  42 AC_PROG_YACC
  43
  44 # Checks for functions, headers, structures, etc.
  45 AC_HEADER_STDC
  46 AC_CHECK_HEADERS([termios.h])
  47 AC_CHECK_MEMBERS([struct sysinfo.totalram],[],[],[AC_INCLUDES_DEFAULT
  48                   #include <sys/sysinfo.h>
  49                   ])
  50 AC_CHECK_FUNCS([swapctl])
  51 AC_CHECK_FUNCS([asprintf])
  52
  53 # Initialize libtool
  54 AC_DISABLE_STATIC
  55 AC_PROG_LIBTOOL
  56
  57 # Require X.Org macros 1.16 or later for XORG_TESTSET_CFLAG
  58 m4_ifndef([XORG_MACROS_VERSION],
  59           [m4_fatal([must install xorg-macros 1.16 or later before running autoconf/autogen])])
  60 XORG_MACROS_VERSION(1.16)
  61 XORG_DEFAULT_OPTIONS
  62
  63 # warning flags for the assembler. We can't quite use CWARNFLAGS for it yet as
  64 # it generates waaaay too many warnings.
  65 ASSEMBLER_WARN_CFLAGS=""
  66 if test "x$GCC" = "xyes"; then
  67         ASSEMBLER_WARN_CFLAGS="-Wall -Wstrict-prototypes \
  68         -Wmissing-prototypes -Wmissing-declarations \
  69         -Wnested-externs -fno-strict-aliasing"
  70 fi
  71 AC_SUBST(ASSEMBLER_WARN_CFLAGS)
  72
  73 PKG_CHECK_MODULES(DRM, [libdrm_intel >= 2.4.40 libdrm])
  74 PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
  75 PKG_CHECK_MODULES(OVERLAY_XVLIB, [xv x11 xext], enable_overlay_xvlib=yes, enable_overlay_xvlib=no)
  76 PKG_CHECK_MODULES(OVERLAY_XLIB, [cairo-xlib], enable_overlay_xlib=yes, enable_overlay_xlib=no)
  77
  78 AM_CONDITIONAL(BUILD_OVERLAY_XVLIB, [test "x$enable_overlay_xvlib" = xyes])
  79 AM_CONDITIONAL(BUILD_OVERLAY_XLIB, [test "x$enable_overlay_xlib" = xyes])
  80 AM_CONDITIONAL(BUILD_OVERLAY, [test "x$enable_overlay_xlib" = xyes -o "x$enable_overlay_xvlib"])
  81 if test x$enable_overlay_xvlib = xyes; then
  82         AC_DEFINE(HAVE_OVERLAY_XVLIB, 1, [Enable XV backend])
  83 fi
  84 if test x$enable_overlay_xlib = xyes; then
  85         AC_DEFINE(HAVE_OVERLAY_XLIB, 1, [Enable X backend])
  86 fi
  87
  88 # for testdisplay
  89 PKG_CHECK_MODULES(CAIRO, [cairo >= 1.12.0])
  90 PKG_CHECK_MODULES(LIBUDEV, [libudev], [udev=yes], [udev=no])
  91 if test x"$udev" = xyes; then
  92         AC_DEFINE(HAVE_UDEV,1,[Enable udev-based monitor hotplug detection])
  93 fi
  94 PKG_CHECK_MODULES(GLIB, glib-2.0)
  95
  96 # can we build the assembler?
  97 AS_IF([test x"$LEX" != "x:" -a x"$YACC" != xyacc],
  98       [enable_assembler=yes],
  99       [enable_assembler=no])
 100 AM_CONDITIONAL(BUILD_ASSEMBLER, [test "x$enable_assembler" = xyes])
 101
 102 # -----------------------------------------------------------------------------
 103 #                       Configuration options
 104 # -----------------------------------------------------------------------------
 105 # for dma-buf tests
 106 AC_ARG_ENABLE(nouveau, AS_HELP_STRING([--disable-nouveau],
 107               [Enable use of nouveau API for prime tests (default: enabled)]),
 108               [NOUVEAU=$enableval], [NOUVEAU=yes])
 109 if test "x$NOUVEAU" = xyes; then
 110         PKG_CHECK_MODULES(DRM_NOUVEAU, [libdrm_nouveau >= 2.4.33])
 111         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau support])
 112 fi
 113 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 114
 115 #Configure options for the python quick-dumper
 116 AC_ARG_ENABLE(dumper,
 117               AS_HELP_STRING([--disable-dumper],
 118                              [Disable the python based register dumper (default: enabled)]),
 119                              [DUMPER=$enableval], [DUMPER=yes])
 120 if test "x$DUMPER" == xyes; then
 121         AC_DEFINE(HAVE_DUMPER, 1, [Have dumper support])
 122         # SWIG configuration
 123         AX_PKG_SWIG(2.0.0, [], [ AC_MSG_ERROR([SWIG 2.0.0 or higher is required to build..]) ])
 124         AX_PYTHON_DEVEL([>= '3.0'])
 125         AX_SWIG_PYTHON
 126 fi
 127 AM_CONDITIONAL(HAVE_DUMPER, [test "x$DUMPER" = xyes])
 128
 129 # Define a configure option for the shadder debugger
 130 AC_ARG_ENABLE(shader-debugger, AS_HELP_STRING([--enable-shader-debugger],
 131               [Enable shader debugging support [autodetected]]),
 132               [BUILD_SHADER_DEBUGGER="$enableval"], [BUILD_SHADER_DEBUGGER=auto])
 133
 134 # Shadder debugger depends on python3, intel-genasm and objcopy
 135 if test "x$BUILD_SHADER_DEBUGGER" != xno; then
 136         # Check Python 3 is installed
 137         if test "$PYTHON" = ":" ; then
 138                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 139                         AC_MSG_ERROR([Shader debugger requested, python version 3 not found.])
 140                 else
 141                         BUILD_SHADER_DEBUGGER=no
 142                 fi
 143         fi
 144         # Check for the Intel Chipset assembler compiler
 145         AC_PATH_PROGS([GEN4ASM], intel-gen4asm)
 146         if test -z "$GEN4ASM" ; then
 147                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 148                         AC_MSG_ERROR([Shader debugger requested, but intel-gen4asm not found.])
 149                 else
 150                         BUILD_SHADER_DEBUGGER=no
 151                 fi
 152         fi
 153         # Check for the objcopy GNU binary utiliy command
 154         AC_PATH_PROGS([OBJCOPY], objcopy)
 155         if test -z "$OBJCOPY" ; then
 156                 if test "x$BUILD_SHADER_DEBUGGER" = xyes; then
 157                         AC_MSG_ERROR([Shader debugger requested, but objcopy command not found.])
 158                 else
 159                         BUILD_SHADER_DEBUGGER=no
 160                 fi
 161         fi
 162 fi
 163
 164 AM_CONDITIONAL(BUILD_SHADER_DEBUGGER, [test "x$BUILD_SHADER_DEBUGGER" != xno])
 165 AS_IF([test "x$BUILD_SHADER_DEBUGGER" != xno],
 166       [enable_debugger=yes], [enable_debugger=no])
 167
 168 # -----------------------------------------------------------------------------
 169
 170 # To build multithread code, gcc uses -pthread, Solaris Studio cc uses -mt
 171 XORG_TESTSET_CFLAG([THREAD_CFLAGS], [-pthread], [-mt])
 172 AC_SUBST([THREAD_CFLAGS])
 173
 174 AC_ARG_ENABLE(tests,
 175               AS_HELP_STRING([--disable-tests],
 176               [Disable tests build (default: enabled)]),
 177               [BUILD_TESTS=$enableval], [BUILD_TESTS="yes"])
 178 if test "x$BUILD_TESTS" = xyes; then
 179         AC_DEFINE(BUILD_TESTS, 1, [Build tests])
 180 fi
 181 AM_CONDITIONAL(BUILD_TESTS, [test "x$BUILD_TESTS" = xyes])
 182
 183 AC_CONFIG_FILES([
 184                  Makefile
 185                  benchmarks/Makefile
 186                  demos/Makefile
 187                  lib/Makefile
 188                  man/Makefile
 189                  scripts/Makefile
 190                  tests/Makefile
 191                  tools/Makefile
 192                  tools/quick_dump/Makefile
 193                  debugger/Makefile
 194                  debugger/system_routine/Makefile
 195                  assembler/Makefile
 196                  assembler/doc/Makefile
 197                  assembler/test/Makefile
 198                  assembler/intel-gen4asm.pc
 199                  overlay/Makefile
 200                  ])
 201 AC_OUTPUT
 202
 203 # Print a summary of the compilation
 204 echo ""
 205 echo "Intel GPU tools"
 206
 207 echo ""
 208 echo " • Tests:"
 209 echo "       Build tests        : ${BUILD_TESTS}"
 210 echo "       Compile prime tests: ${NOUVEAU}"
 211 echo ""
 212 echo " • Tools:"
 213 echo "       Assembler          : ${enable_assembler}"
 214 echo "       Debugger           : ${enable_debugger}"
 215 echo "       Python dumper      : ${DUMPER}"
 216 echo "       Overlay            : X: ${enable_overlay_xlib}, Xv: ${enable_overlay_xvlib}"
 217 echo ""
 218
 219 # vim: set ft=config ts=8 sw=8 tw=0 noet :