configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 dnl *** checks for header files ***
 138
 139 dnl check if we have ANSI C header files
 140 AC_HEADER_STDC
 141
 142 dnl used by ext/wavpack
 143 AX_CREATE_STDINT_H
 144
 145 dnl used in gst/udp
 146 AC_CHECK_HEADERS([sys/time.h])
 147
 148 dnl used in gst/udp
 149 AC_CHECK_HEADERS([sys/socket.h])
 150
 151 dnl *** checks for types/defines ***
 152
 153 dnl Check for FIONREAD ioctl declaration.  This check is needed
 154 dnl for the UDP plugin to build on Solaris
 155 GST_CHECK_FIONREAD
 156
 157 dnl *** checks for structures ***
 158
 159 dnl *** checks for compiler characteristics ***
 160
 161 dnl check if we have GCC inline-asm
 162 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 163 if test x$HAVE_GCC_ASM = xyes ; then
 164   AC_DEFINE(HAVE_GCC_ASM, 1,
 165     [Define if compiler supports gcc inline assembly])
 166 fi
 167 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 168
 169 dnl *** checks for library functions ***
 170
 171 LIBS_SAVE=$LIBS
 172 LIBS="$LIBS $LIBM"
 173 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 174 LIBS=$LIBS_SAVE
 175
 176 dnl Check whether isinf() is defined by math.h
 177 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 178     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 179 if test "$ac_cv_have_isinf" = "yes"
 180 then
 181     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 182 fi
 183
 184 dnl Check for mmap (needed by electricfence plugin)
 185 AC_FUNC_MMAP
 186 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 187
 188 dnl Check for mmap (needed by electricfence plugin)
 189
 190 AC_CHECK_TYPE([struct ip_mreqn], [
 191               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 192               [#include <netinet/in.h>])
 193
 194 dnl *** checks for dependency libraries ***
 195
 196
 197 dnl GLib
 198 GLIB_REQ=2.32.0
 199 AG_GST_GLIB_CHECK([$GLIB_REQ])
 200
 201 dnl Orc
 202 ORC_CHECK([0.4.16])
 203
 204 dnl checks for gstreamer
 205 dnl uninstalled is selected preferentially -- see pkg-config(1)
 206 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 207 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 208 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 209 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 210 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 211 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 212
 213 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 214 if test -z $GST_TOOLS_DIR; then
 215   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 216 fi
 217 AC_SUBST(GST_TOOLS_DIR)
 218
 219 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 220 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 221
 222 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 223
 224 dnl Check for documentation xrefs
 225 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 226 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 227 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 228 AC_SUBST(GLIB_PREFIX)
 229 AC_SUBST(GST_PREFIX)
 230 AC_SUBST(GSTPB_PREFIX)
 231
 232 dnl GTK is optional and used in examples
 233 HAVE_GTK=no
 234 GTK_REQ=3.0.0
 235 if test "x$BUILD_EXAMPLES" = "xyes"; then
 236   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 237   dnl some examples need gtk+-x11
 238   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 239   AC_SUBST(GTK_LIBS)
 240   AC_SUBST(GTK_CFLAGS)
 241 fi
 242 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 243 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 244
 245 dnl *** set variables based on configure arguments ***
 246
 247 dnl set license and copyright notice
 248 GST_LICENSE="LGPL"
 249 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 250 AC_SUBST(GST_LICENSE)
 251
 252 dnl set location of plugin directory
 253 AG_GST_SET_PLUGINDIR
 254
 255 dnl set release date/time
 256 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 257   ["${srcdir}/gst-plugins-good.doap"],
 258   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 259
 260 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 261 dnl make sure it doesn't complain about unused variables if debugging is disabled
 262 NO_WARNINGS=""
 263 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 264
 265 dnl define an ERROR_CFLAGS Makefile variable
 266 dnl -Wundef: too many broken headers
 267 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 268       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 269       -Wwrite-strings -Wold-style-definition -Waggregate-return
 270       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 271       -Wnested-externs $NO_WARNINGS])
 272
 273 dnl define an ERROR_CXXFLAGS Makefile variable
 274 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 275         -Wmissing-declarations -Wredundant-decls
 276         -Wwrite-strings
 277         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 278         $NO_WARNINGS])
 279
 280 dnl define an ERROR_OBJCFLAGS Makefile variable
 281 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 282       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 283       -Wwrite-strings -Wold-style-definition
 284       -Winit-self -Wmissing-include-dirs -Wno-multichar
 285       -Wnested-externs $NO_WARNINGS])
 286
 287 dnl define correct level for debugging messages
 288 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 289
 290 dnl used in examples
 291 AG_GST_DEFAULT_ELEMENTS
 292
 293 dnl *** plug-ins to include ***
 294
 295 dnl Non ported plugins (non-dependant, then dependant)
 296 dnl Make sure you have a space before and after all plugins
 297 GST_PLUGINS_NONPORTED="cairo cairo_gobject osx_audio "
 298 AC_SUBST(GST_PLUGINS_NONPORTED)
 299
 300 dnl these are all the gst plug-ins, compilable without additional libs
 301 dnl videofilter is at the top because others depend on it
 302 AG_GST_CHECK_PLUGIN(alpha)
 303 AG_GST_CHECK_PLUGIN(apetag)
 304 AG_GST_CHECK_PLUGIN(audiofx)
 305 AG_GST_CHECK_PLUGIN(audioparsers)
 306 AG_GST_CHECK_PLUGIN(auparse)
 307 AG_GST_CHECK_PLUGIN(autodetect)
 308 AG_GST_CHECK_PLUGIN(avi)
 309 AG_GST_CHECK_PLUGIN(cutter)
 310 AG_GST_CHECK_PLUGIN(debugutils)
 311 AG_GST_CHECK_PLUGIN(deinterlace)
 312 AG_GST_CHECK_PLUGIN(effectv)
 313 AG_GST_CHECK_PLUGIN(equalizer)
 314 AG_GST_CHECK_PLUGIN(flv)
 315 AG_GST_CHECK_PLUGIN(flx)
 316 AG_GST_CHECK_PLUGIN(goom)
 317 AG_GST_CHECK_PLUGIN(goom2k1)
 318 AG_GST_CHECK_PLUGIN(icydemux)
 319 AG_GST_CHECK_PLUGIN(id3demux)
 320 AG_GST_CHECK_PLUGIN(imagefreeze)
 321 AG_GST_CHECK_PLUGIN(interleave)
 322 AG_GST_CHECK_PLUGIN(isomp4)
 323 AG_GST_CHECK_PLUGIN(law)
 324 AG_GST_CHECK_PLUGIN(level)
 325 AG_GST_CHECK_PLUGIN(matroska)
 326 AG_GST_CHECK_PLUGIN(monoscope)
 327 AG_GST_CHECK_PLUGIN(multifile)
 328 AG_GST_CHECK_PLUGIN(multipart)
 329 AG_GST_CHECK_PLUGIN(replaygain)
 330 AG_GST_CHECK_PLUGIN(rtp)
 331 AG_GST_CHECK_PLUGIN(rtpmanager)
 332 AG_GST_CHECK_PLUGIN(rtsp)
 333 AG_GST_CHECK_PLUGIN(shapewipe)
 334 AG_GST_CHECK_PLUGIN(smpte)
 335 AG_GST_CHECK_PLUGIN(spectrum)
 336 AG_GST_CHECK_PLUGIN(udp)
 337 AG_GST_CHECK_PLUGIN(videobox)
 338 AG_GST_CHECK_PLUGIN(videocrop)
 339 AG_GST_CHECK_PLUGIN(videofilter)
 340 AG_GST_CHECK_PLUGIN(videomixer)
 341 AG_GST_CHECK_PLUGIN(wavenc)
 342 AG_GST_CHECK_PLUGIN(wavparse)
 343 AG_GST_CHECK_PLUGIN(y4m)
 344
 345 dnl disable experimental plug-ins
 346 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 347   AG_GST_DISABLE_PLUGIN(monoscope)
 348 fi
 349
 350 dnl *** sys plug-ins ***
 351
 352 echo
 353 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 354 echo
 355
 356 dnl DirectSound
 357 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 358 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 359   HAVE_DIRECTSOUND="no"
 360   save_CFLAGS="$CFLAGS"
 361   save_LDFLAGS="$LDFLAGS"
 362   save_LIBS="$LIBS"
 363   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 364   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 365   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 366   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 367   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 368 #include <windows.h>
 369 #include <dxerr9.h>
 370 #include <dsound.h>
 371 ]], [[
 372   DXGetErrorString9 (0);
 373   DirectSoundCreate(NULL, NULL, NULL);
 374 ]])
 375 ],
 376     [HAVE_DIRECTSOUND="yes"],
 377     [HAVE_DIRECTSOUND="no"])
 378   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 379   CFLAGS=$save_CFLAGS
 380   LDFLAGS=$save_LDFLAGS
 381   LIBS=$save_LIBS
 382
 383   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 384     dnl this is much more than we want
 385     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 386     AC_SUBST(DIRECTSOUND_CFLAGS)
 387     AC_SUBST(DIRECTSOUND_LDFLAGS)
 388     AC_SUBST(DIRECTSOUND_LIBS)
 389   fi
 390   AC_SUBST(HAVE_DIRECTSOUND)
 391 ])
 392
 393 dnl *** Win32 WaveOut ***
 394 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 395 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 396   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 397 ])
 398
 399 dnl *** OSS audio *** (Linux, *BSD)
 400 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 401 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 402  HAVE_OSS="yes"
 403 dnl Linux and newer BSD versions :
 404  AC_CHECK_HEADER(sys/soundcard.h, [
 405    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 406    ] , [
 407 dnl Some old BSD versions and also newer OpenBSD versions :
 408    AC_CHECK_HEADER(soundcard.h, [
 409      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 410      ], [
 411   dnl Some old BSD versions :
 412      AC_CHECK_HEADER(machine/soundcard.h, [
 413        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 414          [Define if OSS includes are in /machine/])
 415        ], [
 416        HAVE_OSS="no"
 417      ])
 418    ])
 419  ])
 420 ])
 421
 422 dnl *** oss4 ***
 423 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 424 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 425   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 426   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 427       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 428       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 429 ])
 430
 431 dnl *** Sun Audio ***
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 433 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 434   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 435 ])
 436
 437 dnl *** OSX Audio ***
 438 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 439 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 440   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 441 ])
 442
 443 dnl *** OS X video ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 445 HAVE_OSX_VIDEO="no"
 446 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 447   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 448 ])
 449 dnl in case header OpenGL/gl.h is found on other platforms
 450 case "$host" in
 451   *-*darwin*)
 452     dnl do nothing
 453     ;;
 454   *)
 455     HAVE_OSX_VIDEO="no"
 456     ;;
 457 esac
 458
 459
 460 dnl *** Video 4 Linux 2 ***
 461 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 462 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 464 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 465   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 466   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 467 #include <sys/types.h>
 468 #ifdef __sun /* Solaris */
 469 #include <sys/types.h>
 470 #include <sys/videodev2.h>
 471 #else /* Linux */
 472 #include <linux/types.h>
 473 #define _LINUX_TIME_H
 474 #define __user
 475 #include <linux/videodev2.h>
 476 #endif
 477 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 478 #error too early v4l2 version or no v4l2 at all
 479 #endif
 480     ]], [[
 481 return 0;
 482     ]])],[
 483       HAVE_GST_V4L2="yes"
 484       AC_MSG_RESULT(yes)
 485     ],[
 486       HAVE_GST_V4L2="no"
 487       AC_MSG_RESULT(no)
 488
 489       HAVE_VIDEODEV=no
 490       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 491       [
 492         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 493       ])
 494
 495       if test "x$HAVE_VIDEODEV" = "xyes"; then
 496         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 497         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 498       else
 499         AC_MSG_WARN([video4linux2 was not found])
 500       fi
 501     ])
 502
 503   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 504     dnl check for missing v4l2_buffer declaration (see #135919)
 505     MISSING_DECL=0
 506     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 507     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 508 #include <sys/types.h>
 509 #ifdef __sun /* Solaris */
 510 #include <sys/types.h>
 511 #include <sys/videodev2.h>
 512 #else /* Linux */
 513 #include <linux/types.h>
 514 #define _LINUX_TIME_H
 515 #define __user
 516 #include <linux/videodev2.h>
 517 #endif
 518     ]], [[
 519 struct v4l2_buffer buf;
 520 buf.index = 0;
 521 return 0;
 522     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 523     if [ test x$MISSING_DECL = x1 ]; then
 524       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 525     fi
 526
 527     dnl check for XOverlay libraries
 528     AG_GST_CHECK_XV
 529   fi
 530 ])
 531
 532 # Optional gudev for device probing
 533 AC_ARG_WITH([gudev],
 534   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 535   [],
 536   [with_gudev=check])
 537 if test x$HAVE_GST_V4L2 = xyes; then
 538   if test x$with_gudev != xno; then
 539       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 540           [ have_gudev=yes
 541             AC_DEFINE(HAVE_GUDEV, 1,
 542                [Whether gudev is available for device detection])
 543             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 544           ], [
 545           have_gudev=no
 546           ])
 547   else
 548     have_gudev=no
 549   fi
 550 fi
 551 AC_SUBST(GUDEV_CFLAGS)
 552 AC_SUBST(GUDEV_LIBS)
 553
 554 # Make libv4l2 non-automagic
 555 AC_ARG_WITH([libv4l2],
 556   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 557   [],
 558   [with_libv4l2=check])
 559 if test x$HAVE_GST_V4L2 = xyes; then
 560   if test x$with_libv4l2 != xno; then
 561       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 562           [ have_libv4l2=yes
 563             AC_DEFINE(HAVE_LIBV4L2, 1,
 564                 [Whether libv4l2 is available for video buffer conversion])
 565           ], [
 566           have_libv4l2=no
 567           ])
 568   else
 569     have_libv4l2=no
 570   fi
 571 fi
 572
 573 dnl Check for X11
 574 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 575 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 576                   [ximagesrc], [
 577   AC_PATH_XTRA
 578
 579   dnl now try to find the HEADER
 580   ac_cflags_save="$CFLAGS"
 581   ac_cppflags_save="$CPPFLAGS"
 582   CFLAGS="$CFLAGS $X_CFLAGS"
 583   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 584   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 585
 586   if test "x$HAVE_X" = "xno"
 587   then
 588     AC_MSG_NOTICE([cannot find X11 development files])
 589   else
 590     dnl this is much more than we want
 591     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 592     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 593     dnl it does not add the libs; therefore we add them here
 594     X_LIBS="$X_LIBS -lX11"
 595     AC_SUBST(X_CFLAGS)
 596     AC_SUBST(X_LIBS)
 597
 598     dnl check for Xfixes
 599     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 600     if test "x$HAVE_XFIXES" = "xyes"
 601     then
 602         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 603     fi
 604     AC_SUBST(XFIXES_LIBS)
 605     AC_SUBST(XFIXES_CFLAGS)
 606
 607     dnl check for Xdamage
 608     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 609     if test "x$HAVE_XDAMAGE" = "xyes"
 610     then
 611         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 612     fi
 613     AC_SUBST(XDAMAGE_LIBS)
 614     AC_SUBST(XDAMAGE_CFLAGS)
 615   fi
 616   AC_SUBST(HAVE_X)
 617   CFLAGS="$ac_cflags_save"
 618   CPPFLAGS="$ac_cppflags_save"
 619 ])
 620
 621 dnl FIXME: this should be rolled into the test above, it's just an additional
 622 dnl feature of the ximagesrc plug-in
 623 dnl This is the same as in gst-plugins-base
 624 dnl check for X Shm
 625 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 626 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 627   if test x$HAVE_X = xyes; then
 628     AC_CHECK_LIB(Xext, XShmAttach,
 629                  HAVE_XSHM="yes", HAVE_XSHM="no",
 630                  $X_LIBS)
 631     if test "x$HAVE_XSHM" = "xyes"; then
 632       XSHM_LIBS="-lXext"
 633     else
 634       dnl On AIX, it is in XextSam instead, but we still need -lXext
 635       AC_CHECK_LIB(XextSam, XShmAttach,
 636                    HAVE_XSHM="yes", HAVE_XSHM="no",
 637                    $X_LIBS)
 638       if test "x$HAVE_XSHM" = "xyes"; then
 639         XSHM_LIBS="-lXext -lXextSam"
 640       fi
 641     fi
 642   fi
 643 ], ,[
 644   AC_SUBST(HAVE_XSHM)
 645   AC_SUBST(XSHM_LIBS)
 646 ])
 647
 648 dnl for V4L2, we also need to know if we have XVIDEO
 649 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 650 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 651                   [], [
 652   AG_GST_CHECK_XV
 653 ])
 654
 655 dnl *** ext plug-ins ***
 656 dnl keep this list sorted alphabetically !
 657
 658 if test "x$BUILD_EXTERNAL" = "xyes"; then
 659
 660 echo
 661 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 662 echo
 663
 664 dnl *** aalib ***
 665 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 666 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 667   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 668   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 669 ])
 670
 671 dnl *** cairo ***
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 673 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 674   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 675 ])
 676
 677 dnl *** cairo-gobject ***
 678 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO_GOBJECT, true)
 679 AG_GST_CHECK_FEATURE(CAIRO_GOBJECT,
 680   [Cairo graphics rendering gobject bindings], cairooverlay, [
 681   AG_GST_PKG_CHECK_MODULES(CAIRO_GOBJECT, cairo-gobject >= 1.10.0)
 682 ])
 683
 684 dnl *** FLAC ***
 685 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 686 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 687   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 688 ])
 689
 690 dnl *** GDK pixbuf ***
 691 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 692 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 693   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 694 ])
 695
 696 dnl *** Jack ***
 697 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 698 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 699   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 700   AC_SUBST(JACK_CFLAGS)
 701   AC_SUBST(JACK_LIBS)
 702
 703   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 704   if test x$HAVE_JACK_0_120_1 = xyes; then
 705     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 706   fi
 707   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 708   if test x$HAVE_JACK_1_9_7 = xyes; then
 709     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 710   fi
 711
 712 ])
 713
 714 dnl *** jpeg ***
 715 dnl FIXME: we could use header checks here as well IMO
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 717 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 718   AC_ARG_WITH(jpeg-mmx,
 719     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 720   OLD_LIBS="$LIBS"
 721   if test x$with_jpeg_mmx != x; then
 722     LIBS="$LIBS -L$with_jpeg_mmx"
 723   fi
 724   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 725   JPEG_LIBS="$LIBS -ljpeg-mmx"
 726   LIBS="$OLD_LIBS"
 727   if test x$HAVE_JPEG != xyes; then
 728     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 729     JPEG_LIBS="-ljpeg"
 730   fi
 731   AC_SUBST(JPEG_LIBS)
 732 ])
 733
 734 dnl *** libcaca ***
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 736 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 737   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 738 ])
 739
 740 dnl *** libdv ***
 741 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 742 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 743   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 744 ])
 745
 746 dnl *** libpng ***
 747 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 748 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 749   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 750 ])
 751
 752 dnl *** pulseaudio ***
 753 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 754 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 755
 756   dnl used in ext/pulse/pulseutil.c
 757   AC_CHECK_HEADERS([process.h])
 758
 759   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 760 ])
 761
 762 dnl *** dv1394 ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 764 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 765   dnl first test for libraw1394 >= 2.0.0
 766   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 767   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 768   dnl now see how far we got
 769   if test x$HAVE_RAW1394 = xyes && \
 770      test x$HAVE_LIBIEC61883 = xyes; then
 771        AG_GST_CHECK_LIBHEADER(AVC1394,
 772         avc1394, avc1394_send_command, $RAW1394_LIBS,
 773         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 774        AG_GST_CHECK_LIBHEADER(ROM1394,
 775         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 776         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 777        if test x$HAVE_AVC1394 = xyes && \
 778           test x$HAVE_AVC1394 = xyes && \
 779           test x$HAVE_ROM1394 = xyes; then
 780           HAVE_DV1394=yes
 781           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 782           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 783           AC_SUBST(DV1394_CFLAGS)
 784           AC_SUBST(DV1394_LIBS)
 785         fi
 786   else
 787        if test x$HAVE_RAW1394 = xno; then
 788           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 789           AG_GST_CHECK_LIBHEADER(AVC1394,
 790            avc1394, avc1394_send_command, $RAW1394_LIBS,
 791            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 792           AG_GST_CHECK_LIBHEADER(ROM1394,
 793            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 794            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 795           if test x$HAVE_RAW1394 = xyes && \
 796              test x$HAVE_AVC1394 = xyes && \
 797              test x$HAVE_ROM1394 = xyes; then
 798              HAVE_DV1394=yes
 799              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 800              DV1394_CFLAGS="$RAW1394_CFLAGS"
 801              if test x$HAVE_LIBIEC61883 = xyes; then
 802                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 803                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 804              fi
 805              AC_SUBST(DV1394_CFLAGS)
 806              AC_SUBST(DV1394_LIBS)
 807            fi
 808          fi
 809   fi
 810 ])
 811 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 812
 813 dnl *** shout2 ***
 814 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 815 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 816   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 817 ])
 818
 819 dnl *** soup ***
 820 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 821 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 822   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 823     HAVE_SOUP="yes"
 824     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 825   ],[
 826     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, HAVE_SOUP="yes", [
 827       HAVE_SOUP="no"
 828     ])
 829   ])
 830   AC_SUBST(SOUP_CFLAGS)
 831   AC_SUBST(SOUP_LIBS)
 832 ])
 833
 834 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 835 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 836 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 837 dnl   speex_jitter.h is 1.1.x only
 838 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 839 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 840   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 841   if test $HAVE_SPEEX = no
 842   then
 843     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 844       AC_CHECK_HEADER(speex/speex_jitter.h, [
 845         dnl speex 1.1.x :
 846         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 847           dnl speex 1.1.5 or + :
 848           HAVE_SPEEX="yes"
 849           SPEEX_LIBS="-lspeex"
 850           AC_SUBST(SPEEX_CFLAGS)
 851           AC_SUBST(SPEEX_LIBS)
 852         ],[
 853           HAVE_SPEEX="no"
 854         ])
 855       ],[
 856         dnl speex 1.0.x :
 857           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 858             dnl speex 1.0.4
 859             HAVE_SPEEX="yes"
 860             SPEEX_LIBS="-lspeex"
 861             AC_SUBST(SPEEX_CFLAGS)
 862             AC_SUBST(SPEEX_LIBS)
 863
 864             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 865               [defined if speex 1.0.x API detected])
 866         ],[
 867             HAVE_SPEEX="no"
 868             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 869         ], [
 870 #include <speex/speex.h>
 871         ])
 872       ])
 873     ])
 874   fi
 875 ])
 876
 877 dnl *** taglib ***
 878 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 879 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 880   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 881   if test "x$HAVE_CXX" != "xyes"; then
 882     USE_TAGLIB=false
 883     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 884   else
 885     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 886     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 887         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 888       ], [
 889         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 890     ])
 891     AC_SUBST(TAGLIB_CXXFLAGS)
 892   fi
 893 ])
 894
 895 dnl *** vpx ***
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 897 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 898   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 899
 900   if test $HAVE_VPX = "yes"; then
 901     OLD_LIBS="$LIBS"
 902     OLD_CFLAGS="$CFLAGS"
 903     CFLAGS="$CFLAGS $VPX_CFLAGS"
 904     LIBS="$LIBS $VPX_LIBS"
 905     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 906       HAVE_VP8=yes
 907       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 908     ])
 909     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 910       HAVE_VP8=yes
 911       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 912     ])
 913     LIBS="$OLD_LIBS"
 914     CFLAGS="$OLD_CFLAGS"
 915   fi
 916   AC_SUBST(VPX_LIBS)
 917   AC_SUBST(VPX_CFLAGS)
 918 ])
 919
 920 dnl *** wavpack ***
 921 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 922 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 923   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 924     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 925       HAVE_WAVPACK=yes
 926       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 927     ],[
 928       HAVE_WAVPACK=no
 929     ])
 930   ])
 931   AC_SUBST(WAVPACK_CFLAGS)
 932   AC_SUBST(WAVPACK_LIBS)
 933 ])
 934
 935 dnl *** qtdemux & matroska prefer to have zlib ***
 936 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 937 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 938   AG_GST_CHECK_LIBHEADER(ZLIB,
 939     z, uncompress,, zlib.h, [
 940     HAVE_ZLIB="yes"
 941     ZLIB_LIBS="-lz"
 942     AC_SUBST(ZLIB_LIBS)
 943   ])
 944 ])
 945
 946 dnl *** matroska prefers to have bz2 ***
 947 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 948 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 949   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 950   AC_SUBST(BZ2_LIBS)
 951 ])
 952
 953 else
 954
 955 dnl not building plugins with external dependencies,
 956 dnl but we still need to set the conditionals
 957 AM_CONDITIONAL(USE_AALIB, false)
 958 AM_CONDITIONAL(USE_BZ2, false)
 959 AM_CONDITIONAL(USE_CAIRO, false)
 960 AM_CONDITIONAL(USE_CAIRO_GOBJECT, false)
 961 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 962 AM_CONDITIONAL(USE_DV1394, false)
 963 AM_CONDITIONAL(USE_FLAC, false)
 964 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 965 AM_CONDITIONAL(USE_GST_V4L2, false)
 966 AM_CONDITIONAL(USE_JACK, false)
 967 AM_CONDITIONAL(USE_JPEG, false)
 968 AM_CONDITIONAL(USE_LIBCACA, false)
 969 AM_CONDITIONAL(USE_LIBDV, false)
 970 AM_CONDITIONAL(USE_LIBIEC61883, false)
 971 AM_CONDITIONAL(USE_LIBPNG, false)
 972 AM_CONDITIONAL(USE_OSS, false)
 973 AM_CONDITIONAL(USE_OSS4, false)
 974 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 975 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 976 AM_CONDITIONAL(USE_PULSE, false)
 977 AM_CONDITIONAL(USE_SHOUT2, false)
 978 AM_CONDITIONAL(USE_SOUP, false)
 979 AM_CONDITIONAL(USE_SPEEX, false)
 980 AM_CONDITIONAL(USE_SUNAUDIO, false)
 981 AM_CONDITIONAL(USE_TAGLIB, false)
 982 AM_CONDITIONAL(USE_VPX, false)
 983 AM_CONDITIONAL(USE_WAVEFORM, false)
 984 AM_CONDITIONAL(USE_WAVPACK, false)
 985 AM_CONDITIONAL(USE_X, false)
 986 AM_CONDITIONAL(USE_XSHM, false)
 987 AM_CONDITIONAL(USE_XVIDEO, false)
 988 AM_CONDITIONAL(USE_ZLIB, false)
 989
 990 fi dnl of EXT plugins
 991
 992 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 993
 994 dnl Overview:
 995 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 996 dnl GST_*:              flags shared by all built objects
 997 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 998 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 999 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1000 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1001
1002 dnl GST_OPTION_CFLAGS
1003 if test "x$USE_DEBUG" = xyes; then
1004    PROFILE_CFLAGS="-g"
1005 fi
1006 AC_SUBST(PROFILE_CFLAGS)
1007
1008 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1009   dnl Define _only_ for git (not pre-releases or releases)
1010   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1011 else
1012   DEPRECATED_CFLAGS=""
1013 fi
1014 AC_SUBST(DEPRECATED_CFLAGS)
1015
1016 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1017 dnl at make time with e.g. make ERROR_CFLAGS=""
1018 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1019 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1020 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1021 AC_SUBST(GST_OPTION_CFLAGS)
1022 AC_SUBST(GST_OPTION_CXXFLAGS)
1023 AC_SUBST(GST_OPTION_OBJCFLAGS)
1024
1025 dnl our libraries need to be versioned correctly
1026 AC_SUBST(GST_LT_LDFLAGS)
1027
1028 dnl FIXME: do we want to rename to GST_ALL_* ?
1029 dnl prefer internal headers to already installed ones
1030 dnl also add builddir include for enumtypes and marshal
1031 dnl add ERROR_CFLAGS, but overridable
1032 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1033 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1034 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1035 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1036 AC_SUBST(GST_CFLAGS)
1037 AC_SUBST(GST_CXXFLAGS)
1038 AC_SUBST(GST_OBJCFLAGS)
1039 AC_SUBST(GST_LIBS)
1040
1041 dnl LDFLAGS really should only contain flags, not libs - they get added before
1042 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1043 GST_ALL_LDFLAGS="-no-undefined"
1044 AC_SUBST(GST_ALL_LDFLAGS)
1045
1046 dnl this really should only contain flags, not libs - they get added before
1047 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1048 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1049 AC_SUBST(GST_PLUGIN_LDFLAGS)
1050
1051 dnl *** output files ***
1052
1053 dnl keep this alphabetic per directory, please
1054 AC_CONFIG_FILES(
1055 Makefile
1056 gst/Makefile
1057 gst/alpha/Makefile
1058 gst/apetag/Makefile
1059 gst/audiofx/Makefile
1060 gst/audioparsers/Makefile
1061 gst/auparse/Makefile
1062 gst/autodetect/Makefile
1063 gst/avi/Makefile
1064 gst/cutter/Makefile
1065 gst/deinterlace/Makefile
1066 gst/debugutils/Makefile
1067 gst/effectv/Makefile
1068 gst/equalizer/Makefile
1069 gst/flv/Makefile
1070 gst/goom/Makefile
1071 gst/goom2k1/Makefile
1072 gst/id3demux/Makefile
1073 gst/icydemux/Makefile
1074 gst/imagefreeze/Makefile
1075 gst/interleave/Makefile
1076 gst/isomp4/Makefile
1077 gst/law/Makefile
1078 gst/level/Makefile
1079 gst/matroska/Makefile
1080 gst/monoscope/Makefile
1081 gst/multifile/Makefile
1082 gst/multipart/Makefile
1083 gst/replaygain/Makefile
1084 gst/rtp/Makefile
1085 gst/rtpmanager/Makefile
1086 gst/rtsp/Makefile
1087 gst/shapewipe/Makefile
1088 gst/smpte/Makefile
1089 gst/spectrum/Makefile
1090 gst/udp/Makefile
1091 gst/videobox/Makefile
1092 gst/videocrop/Makefile
1093 gst/videofilter/Makefile
1094 gst/videomixer/Makefile
1095 gst/wavenc/Makefile
1096 gst/wavparse/Makefile
1097 gst/flx/Makefile
1098 gst/y4m/Makefile
1099 ext/Makefile
1100 ext/aalib/Makefile
1101 ext/cairo/Makefile
1102 ext/dv/Makefile
1103 ext/flac/Makefile
1104 ext/gdk_pixbuf/Makefile
1105 ext/jack/Makefile
1106 ext/jpeg/Makefile
1107 ext/libcaca/Makefile
1108 ext/libpng/Makefile
1109 ext/pulse/Makefile
1110 ext/raw1394/Makefile
1111 ext/shout2/Makefile
1112 ext/soup/Makefile
1113 ext/speex/Makefile
1114 ext/taglib/Makefile
1115 ext/vpx/Makefile
1116 ext/wavpack/Makefile
1117 sys/Makefile
1118 sys/directsound/Makefile
1119 sys/oss/Makefile
1120 sys/oss4/Makefile
1121 sys/osxaudio/Makefile
1122 sys/osxvideo/Makefile
1123 sys/sunaudio/Makefile
1124 sys/v4l2/Makefile
1125 sys/waveform/Makefile
1126 sys/ximage/Makefile
1127 po/Makefile.in
1128 tests/Makefile
1129 tests/check/Makefile
1130 tests/examples/Makefile
1131 tests/examples/audiofx/Makefile
1132 tests/examples/cairo/Makefile
1133 tests/examples/equalizer/Makefile
1134 tests/examples/jack/Makefile
1135 tests/examples/level/Makefile
1136 tests/examples/pulse/Makefile
1137 tests/examples/rtp/Makefile
1138 tests/examples/shapewipe/Makefile
1139 tests/examples/spectrum/Makefile
1140 tests/examples/v4l2/Makefile
1141 tests/files/Makefile
1142 tests/icles/Makefile
1143 common/Makefile
1144 common/m4/Makefile
1145 m4/Makefile
1146 docs/Makefile
1147 docs/plugins/Makefile
1148 docs/version.entities
1149 pkgconfig/Makefile
1150 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1151 gst-plugins-good.spec
1152 )
1153
1154 dnl Create the config.h file for Visual Studio builds
1155 dnl Beware of spaces and /'s in some of the shell variable contents.
1156 sed \
1157     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1158     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1159     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1160     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1161     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1162     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1163     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1164     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1165     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1166     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1167     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1168     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1169     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1170     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1171     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1172     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1173     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1174     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1175     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1176     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1177     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1178     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1179     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1180     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1181     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1182     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1183     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1184     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1185     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1186     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1187     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1188     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1189     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1190     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1191     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1192     config.h.in >win32/common/config.h-new
1193
1194 AC_OUTPUT
1195
1196 AG_GST_OUTPUT_PLUGINS
1197 ORC_OUTPUT
1198