configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 AC_SYS_LARGEFILE
  31
  32 dnl Required versions of library packages
  33 dnl Not all of these are actually used, depending on the configure options.
  34 GLIB_REQUIRED=2.34.0
  35 LIBXML_REQUIRED=2.7
  36 VALA_REQUIRED=0.22.0
  37 VALADOC_REQUIRED=0.2
  38 GSSDP_REQUIRED=0.13.0
  39 GUPNP_REQUIRED=0.19.0
  40 GUPNP_AV_REQUIRED=0.12.4
  41 GUPNP_DLNA_REQUIRED=0.9.4
  42 GSTREAMER_REQUIRED=1.0
  43 GSTPBU_REQUIRED=1.0
  44 GIO_REQUIRED=2.26
  45 GEE_REQUIRED=0.8.0
  46 UUID_REQUIRED=1.41.3
  47 LIBSOUP_REQUIRED=2.42.0
  48 GTK_REQUIRED=3.0
  49
  50 dnl Additional requirements for media-export plugin
  51 GSTREAMER_TAG_REQUIRED=1.0
  52 GSTREAMER_APP_REQUIRED=1.0
  53 LIBSQLITE3_REQUIRED=3.5
  54
  55 dnl Additional requirements for tracker plugin
  56 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  57
  58 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  59
  60 RYGEL_BASE_MODULES="gupnp-1.0 >= $GUPNP_REQUIRED gee-0.8 >= $GEE_REQUIRED"
  61 PKG_CHECK_MODULES([LIBRYGEL_CORE_DEPS], [$RYGEL_BASE_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED])
  62 RYGEL_BASE_MODULES_VALAFLAGS='--pkg gupnp-1.0 --pkg gee-0.8'
  63 LIBRYGEL_CORE_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg gmodule-2.0 --pkg posix"
  64 AC_SUBST([LIBRYGEL_CORE_DEPS_VALAFLAGS])
  65
  66 RYGEL_COMMON_MODULES="$RYGEL_BASE_MODULES gupnp-av-1.0 >= $GUPNP_AV_REQUIRED"
  67 PKG_CHECK_MODULES([LIBRYGEL_SERVER_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gio-2.0 >= $GIO_REQUIRED gmodule-2.0 libxml-2.0 >= $LIBXML_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  68 RYGEL_COMMON_MODULES_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gupnp-av-1.0"
  69 LIBRYGEL_SERVER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gssdp-1.0 --pkg gio-2.0 --pkg libsoup-2.4 --pkg gmodule-2.0"
  70 AC_SUBST([LIBRYGEL_SERVER_DEPS_VALAFLAGS])
  71
  72 PKG_CHECK_MODULES([LIBRYGEL_RENDERER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED])
  73 LIBRYGEL_RENDERER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg libsoup-2.4"
  74 AC_SUBST([LIBRYGEL_RENDERER_DEPS_VALAFLAGS])
  75
  76 PKG_CHECK_MODULES([RYGEL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  77
  78 # Not all tests use all of these dependencies,
  79 # but having one set of dependencies keeps things simple.
  80 PKG_CHECK_MODULES([TEST_DEPS], [$RYGEL_COMMON_MODULES uuid >= $UUID_REQUIRED gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED libsoup-2.4 >= $LIBSOUP_REQUIRED libxml-2.0 >= $LIBXML_REQUIRED])
  81 TEST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gio-2.0 --pkg gssdp-1.0 --pkg libsoup-2.4 --pkg libxml-2.0 --pkg gmodule-2.0"
  82 AC_SUBST([TEST_DEPS_VALAFLAGS])
  83
  84 PKG_CHECK_MODULES([EXAMPLE_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED])
  85
  86
  87
  88 dnl Media engine to use
  89 BUILT_ENGINES="librygel-media-engine-simple"
  90
  91 dnl Disabling the gstreamer media_engine also disables
  92 dnl anything else that uses gstreamer.
  93 AC_ARG_WITH([media_engine],
  94             AS_HELP_STRING(
  95                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  96                 [Media Engine to use]),
  97             [with_media_engine="$withval"],
  98             [with_media_engine="gstreamer"])
  99
 100 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 101       [
 102         enable_gstreamer="yes"
 103         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
 104
 105         PKG_CHECK_MODULES([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS],
 106                           [$RYGEL_COMMON_MODULES
 107                            gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 108                            gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 109                            gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 110                            gio-2.0 >= $GIO_REQUIRED])
 111         RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-base-1.0 --pkg gstreamer-pbutils-1.0 --pkg gupnp-dlna-2.0"
 112         AC_SUBST([RYGEL_MEDIA_ENGINE_GSTREAMER_DEPS_VALAFLAGS])
 113
 114         PKG_CHECK_MODULES([LIBRYGEL_RENDERER_GST_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_REQUIRED gio-2.0 >= $GIO_REQUIRED])
 115         LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gstreamer-1.0"
 116         AC_SUBST([LIBRYGEL_RENDERER_GST_DEPS_VALAFLAGS])
 117       ],
 118       [enable_gstreamer="no"])
 119 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
 120 AC_SUBST([BUILT_ENGINES])
 121
 122 dnl Add plugins
 123 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
 124 AS_IF([test "x$enable_external_plugin" = "xyes"],
 125   [
 126     PKG_CHECK_MODULES([RYGEL_PLUGIN_EXTERNAL_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 127   ])
 128
 129 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
 130 AS_IF([test "x$enable_mpris_plugin" = "xyes"],
 131   [
 132     PKG_CHECK_MODULES([RYGEL_PLUGIN_MPRIS_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 133   ])
 134
 135 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
 136 AS_IF([test "x$enable_mediathek_plugin" = "xyes"],
 137   [
 138     PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIATHEK_DEPS],
 139                       [$RYGEL_COMMON_MODULES
 140                        gio-2.0 >= $GIO_REQUIRED
 141                        libsoup-2.4 >= $LIBSOUP_REQUIRED
 142                        libxml-2.0 >= $LIBXML_REQUIRED])
 143   ])
 144
 145 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 146       [
 147         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 148         AS_IF([test "x$enable_playbin_plugin" = "xyes"],
 149           [
 150             PKG_CHECK_MODULES([RYGEL_PLUGIN_PLAYBIN_DEPS], [$RYGEL_COMMON_MODULES gstreamer-1.0 >= $GSTREAMER_TAG_REQUIRED])
 151           ])
 152
 153         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 154         AS_IF([test "x$enable_media_export_plugin" = "xyes"],
 155           [
 156             PKG_CHECK_MODULES([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS],
 157                               [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 158                                gupnp-dlna-2.0 >= $GUPNP_DLNA_REQUIRED
 159                                gupnp-dlna-gst-2.0 >= $GUPNP_DLNA_REQUIRED
 160                                gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED
 161                                gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED
 162                                gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED
 163                                libsoup-2.4 >= $LIBSOUP_REQUIRED
 164                                sqlite3 >= $LIBSQLITE3_REQUIRED
 165                                uuid])
 166             RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS --pkg gupnp-dlna-2.0 --pkg gupnp-dlna-gst-2.0 --pkg gstreamer-tag-1.0 --pkg gstreamer-app-1.0 --pkg gstreamer-pbutils-1.0 --pkg sqlite3"
 167             AC_SUBST([RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_VALAFLAGS])
 168           ])
 169
 170         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 171         AS_IF([test "x$enable_gst_launch_plugin" = "xyes"],
 172           [
 173             PKG_CHECK_MODULES([RYGEL_PLUGIN_GST_LAUNCH_DEPS], [$RYGEL_COMMON_MODULES])
 174             RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS="$RYGEL_COMMON_MODULES_VALAFLAGS"
 175             AC_SUBST([RYGEL_PLUGIN_GST_LAUNCH_DEPS_VALAFLAGS])
 176           ])
 177
 178         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 179         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_2_la_vala.stamp])
 180       ],
 181       [
 182         RYGEL_DISABLE_PLUGIN([playbin])
 183         RYGEL_DISABLE_PLUGIN([media-export])
 184         RYGEL_DISABLE_PLUGIN([gst-launch])
 185       ])
 186
 187 dnl Example plugins:
 188 AC_ARG_ENABLE([example-plugins],
 189               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 190               enable_example_plugins=no)
 191 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 192
 193 dnl Explicitly add stamp files for targets that are not plugins
 194 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_2_la_vala.stamp])
 195 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_2_la_vala.stamp])
 196 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_2_la_vala.stamp])
 197 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 198 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 199 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 200
 201 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 202       [
 203         RYGEL_CHECK_PACKAGES([gupnp-dlna-2.0 gstreamer-1.0
 204                               gstreamer-pbutils-1.0])
 205       ])
 206
 207 dnl Debugging
 208 AC_ARG_ENABLE(debug,
 209         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 210         enable_debug=no)
 211 if test "x$enable_debug" = "xyes"; then
 212         CFLAGS="$CFLAGS -O0 -g"
 213         RYGEL_DEBUG_VALAFLAGS="-g"
 214 fi
 215
 216 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 217
 218 dnl Strict compiler
 219 AC_ARG_ENABLE(strict-cc,
 220         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 221         enable_strict_cc=no)
 222 if test "x$enable_strict_cc" = "xyes"; then
 223         CFLAGS="$CFLAGS -Wall -Werror"
 224 else
 225         CFLAGS="$CFLAGS -w"
 226 fi
 227
 228 dnl Run uninstalled
 229 AC_ARG_ENABLE(uninstalled,
 230     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 231         enable_uninstalled=no)
 232 if test "x$enable_uninstalled" = "xyes"; then
 233         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 234 fi
 235 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 236
 237 dnl Check wether user wants to build UIs
 238 AC_ARG_WITH( ui,
 239   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 240   try_ui=$withval, try_ui=yes )
 241
 242 HAVE_GTK=no
 243 if test x$try_ui = xyes ; then
 244     dnl check for gtk
 245     PKG_CHECK_MODULES([RYGEL_UI_DEPS], [$RYGEL_BASE_MODULES gtk+-3.0 >= $GTK_REQUIRED gssdp-1.0 >= $GSSDP_REQUIRED gee-0.8 >= $GEE_REQUIRED],
 246       [
 247         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 248         RYGEL_UI_DEPS_VALAFLAGS="$RYGEL_BASE_MODULES_VALAFLAGS --pkg gtk+-3.0 --pkg gssdp-1.0 --pkg gee-0.8"
 249         AC_SUBST([RYGEL_UI_DEPS_VALAFLAGS])
 250
 251         PKG_CHECK_MODULES([EXAMPLE_UI_DEPS],
 252                           [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED
 253                            gssdp-1.0 >= $GSSDP_REQUIRED
 254                            gstreamer-video-1.0 >= $GSTREAMER_REQUIRED
 255                            gtk+-3.0 >= $GTK_REQUIRED])
 256       ],
 257       [
 258         AC_MSG_WARN([UI dependencies not found.])
 259         AC_MSG_WARN([UI applications will not be built.])
 260       ])
 261
 262 else
 263     AC_MSG_NOTICE([UI applications disabled.])
 264 fi
 265
 266 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 267
 268 dnl Tests
 269 AC_ARG_ENABLE([tests],
 270               AS_HELP_STRING([--enable-tests],[always build tests]),,
 271               enable_tests=no)
 272 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 273
 274 dnl Generate coverage data
 275 AC_ARG_ENABLE([coverage],
 276   AS_HELP_STRING([--enable-coverage],
 277                  [Generate converage reports for unit tests]),
 278   [],
 279   [enable_coverage=no])
 280 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 281 AS_IF([test "x$enable_coverage" != "xno"],
 282   [
 283     AC_PATH_PROG([LCOV], [lcov])
 284     AC_PATH_PROG([GENHTML], [genhtml])
 285     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 286     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 287     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 288   ]
 289 )
 290
 291 dnl Check additional requirements for MediaExport plugins
 292 if test "x$enable_media_export_plugin" = "xyes";
 293 then
 294     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 295     AC_CHECK_HEADER([unistr.h],
 296                     AC_CHECK_LIB([unistring],
 297                                  [u8_strcoll],
 298                                  [have_unistring=yes],[have_unistring=no]))
 299     if test "x$have_unistring" = "xyes"; then
 300         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 301         RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS="$RYGEL_PLUGIN_MEDIA_EXPORT_DEPS_LIBS -lunistring"
 302     fi
 303 fi
 304
 305
 306 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
 307 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 308   [
 309     PKG_CHECK_MODULES([RYGEL_PLUGIN_TRACKER_DEPS], [$RYGEL_COMMON_MODULES gio-2.0 >= $GIO_REQUIRED])
 310
 311     tracker_api_version="0.14"
 312     PKG_CHECK_MODULES(TRACKER_SPARQL,
 313                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 314                       [tracker_api_version="0.14"],
 315                       [tracker_api_version=""])
 316     AS_IF([test "x$[]tracker_api_version" = "x"],
 317           [
 318             PKG_CHECK_MODULES(TRACKER_SPARQL,
 319                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 320                               [tracker_api_version="0.15"],
 321                               [tracker_api_version=""])
 322           ])
 323     AS_IF([test "x$[]tracker_api_version" = "x"],
 324           [
 325             PKG_CHECK_MODULES(TRACKER_SPARQL,
 326                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 327                               [tracker_api_version="0.16"],
 328                               [tracker_api_version=""])
 329           ])
 330     AS_IF([test "x$[]tracker_api_version" = "x"],
 331           [
 332             PKG_CHECK_MODULES(TRACKER_SPARQL,
 333                               tracker-sparql-0.18 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 334                               [tracker_api_version="0.18"],
 335                               [])
 336           ])
 337     AS_IF([test "x$enable_vala" = "xyes"],
 338           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 339
 340     RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS="--pkg tracker-sparql-$tracker_api_version"
 341     AC_SUBST([RYGEL_PLUGIN_TRACKER_DEPS_VALAFLAGS])
 342   ])
 343
 344 # This should be called only after all RYGEL_CHECK_VALA() and RYGEL_ADD_PLUGIN() calls:
 345 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 346                  [gupnp-1.0
 347                   gupnp-av-1.0
 348                   gio-2.0
 349                   gee-0.8
 350                   posix])
 351
 352 dnl Gettext
 353 GETTEXT_PACKAGE=rygel
 354 AC_SUBST(GETTEXT_PACKAGE)
 355 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 356   [Define the gettext package to be used])
 357
 358 AM_GLIB_GNU_GETTEXT
 359 IT_PROG_INTLTOOL([0.40.0])
 360
 361 dnl Shave the output
 362 AM_SILENT_RULES([yes])
 363
 364 dnl documenation
 365 AC_PATH_PROG([XSLTPROC], [xsltproc])
 366 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 367
 368 dnl Use valadoc and gtk-doc for API documentation:
 369 dnl This is on by default when using autogen.sh
 370 dnl (so it is not on by default when building from a tarball with configure.)
 371 AC_ARG_ENABLE(apidocs,
 372               AS_HELP_STRING([--enable-apidocs[=@<:@no/auto/yes@:>@]],
 373                              [Create API documentation using valadoc and GTK-Doc]),,
 374     [enable_apidocs=auto])
 375
 376 found_valadoc=no
 377 AS_IF([test "x$enable_apidocs" != "xno"], [
 378     AC_PATH_PROG(VALADOC, valadoc, :)
 379     AS_IF([test -x "$VALADOC"], [
 380       found_valadoc=yes
 381       AC_SUBST(VALADOC)
 382       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0],,
 383                         AS_IF([test "x$enable_apidocs" == "xyes"],
 384                               [AC_MSG_ERROR([Unable to find gtk-doc])],
 385                               [found_valadoc=no])
 386                         )
 387     ], [
 388       AS_IF([test "x$enable_apidocs" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 389     ])
 390   ])
 391
 392 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 393
 394 AC_SUBST([RYGEL_PLUGIN_LINKER_FLAGS],
 395          ["-module -avoid-version -Wl,-z,defs"])
 396 AC_SUBST([RYGEL_PLUGIN_DIR],
 397          [${libdir}/rygel-2.2/plugins])
 398 AC_SUBST([RYGEL_MEDIA_ENGINE_DIR],
 399          [${libdir}/rygel-2.2/engines])
 400
 401 AC_CONFIG_FILES([
 402 Makefile
 403 src/Makefile
 404 src/librygel-core/Makefile
 405 src/librygel-renderer/Makefile
 406 src/librygel-renderer-gst/Makefile
 407 src/librygel-server/Makefile
 408 src/rygel/Makefile
 409 src/ui/Makefile
 410 src/media-engines/Makefile
 411 src/media-engines/gstreamer/Makefile
 412 src/media-engines/gstreamer/media-engine-gst.plugin
 413 src/media-engines/simple/Makefile
 414 src/media-engines/simple/media-engine-simple.plugin
 415 src/plugins/Makefile
 416 data/Makefile
 417 data/xml/Makefile
 418 data/xml/MediaServer3.xml.in
 419 data/xml/MediaRenderer2.xml.in
 420 data/icons/Makefile
 421 data/icons/32x32/Makefile
 422 data/icons/48x48/Makefile
 423 data/icons/120x120/Makefile
 424 data/icons/128x128/Makefile
 425 data/icons/scalable/Makefile
 426 data/rygel.desktop.in
 427 data/rygel-preferences.desktop.in
 428 doc/Makefile
 429 doc/reference/Makefile
 430 doc/reference/librygel-core/Makefile
 431 doc/reference/librygel-renderer/Makefile
 432 doc/reference/librygel-server/Makefile
 433 doc/reference/librygel-renderer-gst/Makefile
 434 po/Makefile.in
 435 rygel-core-2.2.pc
 436 rygel-renderer-2.2.pc
 437 rygel-server-2.2.pc
 438 rygel-renderer-gst-2.2.pc
 439 tests/Makefile
 440 examples/Makefile
 441 examples/renderer-plugins/Makefile
 442 examples/renderer-plugins/vala/Makefile
 443 examples/renderer-plugins/vala/example-renderer-vala.plugin
 444 examples/renderer-plugins/C/Makefile
 445 examples/renderer-plugins/C/example-renderer-c.plugin
 446 examples/server-plugins/Makefile
 447 examples/server-plugins/vala/Makefile
 448 examples/server-plugins/vala/example-server-vala.plugin
 449 examples/server-plugins/C/Makefile
 450 examples/server-plugins/C/example-server-c.plugin
 451 ])
 452 AC_OUTPUT
 453
 454 echo "
 455
 456                     ${PACKAGE} ${VERSION}
 457                     ============
 458
 459
 460         Prefix:                 ${prefix}
 461         Source code location:   ${srcdir}
 462         Compiler:               ${CC}
 463         CFLAGS:                 ${CFLAGS}
 464         VALAFLAGS:              ${VALAFLAGS}
 465         uninstalled:            ${enable_uninstalled}
 466         preferences ui:         ${HAVE_GTK}
 467         Media Engine:           ${with_media_engine}
 468         API documentation:      ${found_valadoc}
 469     Plugins:
 470         examples:               ${enable_example_plugins}
 471         tracker:                ${enable_tracker_plugin}
 472             version:            ${tracker_api_version}
 473         mediathek:              ${enable_mediathek_plugin}
 474         media-export            ${enable_media_export_plugin}
 475         external:               ${enable_external_plugin}
 476         MPRIS2:                 ${enable_mpris_plugin}
 477         gst-launch:             ${enable_gst_launch_plugin}
 478         playbin:                ${enable_playbin_plugin}
 479 "