configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libatomic \
 154                 target-libitm \
 155                 target-libstdc++-v3 \
 156                 target-libsanitizer \
 157                 target-libvtv \
 158                 target-libssp \
 159                 target-libquadmath \
 160                 target-libgfortran \
 161                 target-libffi \
 162                 target-libobjc \
 163                 target-libada \
 164                 target-libgm2 \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 251 # is provided.
 252 if test x$with_system_readline = xyes ; then
 253   noconfigdirs="$noconfigdirs readline"
 254 fi
 255
 256 # some tools are so dependent upon X11 that if we're not building with X,
 257 # it's not even worth trying to configure, much less build, that tool.
 258
 259 case ${with_x} in
 260   yes | "") ;; # the default value for this tree is that X11 is available
 261   no)
 262     skipdirs="${skipdirs} tk itcl libgui"
 263     # We won't be able to build gdbtk without X.
 264     enable_gdbtk=no
 265     ;;
 266   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 267 esac
 268
 269 # Some are only suitable for cross toolchains.
 270 # Remove these if host=target.
 271 cross_only="target-libgloss target-newlib target-opcodes"
 272
 273 case $is_cross_compiler in
 274   no) skipdirs="${skipdirs} ${cross_only}" ;;
 275 esac
 276
 277 # If both --with-headers and --with-libs are specified, default to
 278 # --without-newlib.
 279 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 280    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 281   if test x"${with_newlib}" = x ; then
 282     with_newlib=no
 283   fi
 284 fi
 285
 286 # Recognize --with-newlib/--without-newlib.
 287 case ${with_newlib} in
 288   no) skipdirs="${skipdirs} target-newlib" ;;
 289   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 290 esac
 291
 292 AC_ARG_ENABLE(as-accelerator-for,
 293 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 294                 [build as offload target compiler.
 295                 Specify offload host triple by ARG])])
 296
 297 AC_ARG_ENABLE(offload-targets,
 298 [AS_HELP_STRING([--enable-offload-targets=LIST],
 299                 [enable offloading to devices from comma-separated LIST of
 300                 TARGET[=DIR]. Use optional path to find offload target compiler
 301                 during the build])],
 302 [
 303   if test x"$enable_offload_targets" = x; then
 304     AC_MSG_ERROR([no offload targets specified])
 305   fi
 306 ], [enable_offload_targets=])
 307
 308 AC_ARG_ENABLE(offload-defaulted,
 309 [AS_HELP_STRING([--enable-offload-defaulted]
 310                 [If enabled, configured but not installed offload compilers and
 311                 libgomp plugins are silently ignored.  Useful for distribution
 312                 compilers where those are in separate optional packages.])],
 313 [enable_offload_defaulted=$enableval],
 314 [enable_offload_defaulted=])
 315
 316 # Handle --enable-gold, --enable-ld.
 317 # --disable-gold [--enable-ld]
 318 #     Build only ld.  Default option.
 319 # --enable-gold [--enable-ld]
 320 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 321 #     as "ld.bfd" and "ld".
 322 # --enable-gold=default [--enable-ld]
 323 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 324 #     install ld as "ld.bfd".
 325 # --enable-gold[=default] --disable-ld
 326 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 327 # --enable-gold --enable-ld=default
 328 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 329 #     and ld.bfd).
 330 #     In other words, ld is default
 331 # --enable-gold=default --enable-ld=default
 332 #     Error.
 333
 334 default_ld=
 335 AC_ARG_ENABLE(gold,
 336 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 337                 [build gold @<:@ARG={default,yes,no}@:>@])],
 338 ENABLE_GOLD=$enableval,
 339 ENABLE_GOLD=no)
 340 case "${ENABLE_GOLD}" in
 341   yes|default)
 342     # Check for ELF target.
 343     is_elf=no
 344     case "${target}" in
 345       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 346       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 347       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 348       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 349         case "${target}" in
 350           *-*-linux*aout* | *-*-linux*oldld*)
 351             ;;
 352           *)
 353             is_elf=yes
 354             ;;
 355         esac
 356     esac
 357
 358     if test "$is_elf" = "yes"; then
 359       # Check for target supported by gold.
 360       case "${target}" in
 361         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 362         | aarch64*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 363           configdirs="$configdirs gold"
 364           if test x${ENABLE_GOLD} = xdefault; then
 365             default_ld=gold
 366           fi
 367           ENABLE_GOLD=yes
 368           ;;
 369       esac
 370     fi
 371     ;;
 372   no)
 373     ;;
 374   *)
 375     AC_MSG_ERROR([invalid --enable-gold argument])
 376     ;;
 377 esac
 378
 379 AC_ARG_ENABLE(ld,
 380 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 381                 [build ld @<:@ARG={default,yes,no}@:>@])],
 382 ENABLE_LD=$enableval,
 383 ENABLE_LD=yes)
 384
 385 case "${ENABLE_LD}" in
 386   default)
 387     if test x${default_ld} != x; then
 388       AC_MSG_ERROR([either gold or ld can be the default ld])
 389     fi
 390     ;;
 391   yes)
 392     ;;
 393   no)
 394     if test x${ENABLE_GOLD} != xyes; then
 395       AC_MSG_WARN([neither ld nor gold are enabled])
 396     fi
 397     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 398     ;;
 399   *)
 400     AC_MSG_ERROR([invalid --enable-ld argument])
 401     ;;
 402 esac
 403
 404 # PR gas/19109
 405 # Decide the default method for compressing debug sections.
 406 # Provide a configure time option to override our default.
 407 AC_ARG_ENABLE(compressed_debug_sections,
 408 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 409                 [Enable compressed debug sections for gas, gold or ld by
 410                  default])],
 411 [
 412   if test x"$enable_compressed_debug_sections" = xyes; then
 413     AC_MSG_ERROR([no program with compressed debug sections specified])
 414   fi
 415 ], [enable_compressed_debug_sections=])
 416
 417 # Configure extra directories which are host specific
 418
 419 case "${host}" in
 420   *-cygwin*)
 421     configdirs="$configdirs libtermcap" ;;
 422 esac
 423
 424 # A target can indicate whether a language isn't supported for some reason.
 425 # Only spaces may be used in this macro; not newlines or tabs.
 426 unsupported_languages=
 427
 428 # Remove more programs from consideration, based on the host or
 429 # target this usually means that a port of the program doesn't
 430 # exist yet.
 431
 432 case "${host}" in
 433   i[[3456789]]86-*-msdosdjgpp*)
 434     noconfigdirs="$noconfigdirs tcl tk itcl"
 435     ;;
 436 esac
 437
 438
 439 AC_ARG_ENABLE(libquadmath,
 440 AS_HELP_STRING([--disable-libquadmath],
 441   [do not build libquadmath directory]),
 442 ENABLE_LIBQUADMATH=$enableval,
 443 ENABLE_LIBQUADMATH=yes)
 444 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 445   noconfigdirs="$noconfigdirs target-libquadmath"
 446 fi
 447
 448
 449 AC_ARG_ENABLE(libquadmath-support,
 450 AS_HELP_STRING([--disable-libquadmath-support],
 451   [disable libquadmath support for Fortran]),
 452 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 453 ENABLE_LIBQUADMATH_SUPPORT=yes)
 454 enable_libquadmath_support=
 455 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 456   enable_libquadmath_support=no
 457 fi
 458
 459
 460 AC_ARG_ENABLE(libada,
 461 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 462 ENABLE_LIBADA=$enableval,
 463 ENABLE_LIBADA=yes)
 464 if test "${ENABLE_LIBADA}" != "yes" ; then
 465   noconfigdirs="$noconfigdirs gnattools"
 466 fi
 467
 468 AC_ARG_ENABLE(libgm2,
 469 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 470 ENABLE_LIBGM2=$enableval,
 471 ENABLE_LIBGM2=no)
 472 if test "${ENABLE_LIBGM2}" != "yes" ; then
 473   noconfigdirs="$noconfigdirs gm2tools"
 474 fi
 475
 476 AC_ARG_ENABLE(libssp,
 477 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 478 ENABLE_LIBSSP=$enableval,
 479 ENABLE_LIBSSP=yes)
 480
 481 AC_ARG_ENABLE(libstdcxx,
 482 AS_HELP_STRING([--disable-libstdcxx],
 483   [do not build libstdc++-v3 directory]),
 484 ENABLE_LIBSTDCXX=$enableval,
 485 ENABLE_LIBSTDCXX=default)
 486 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 487   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 488 fi]
 489
 490 # Enable libgomp by default on hosted POSIX systems, and a few others.
 491 if test x$enable_libgomp = x ; then
 492     case "${target}" in
 493     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 494         ;;
 495     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 496         ;;
 497     *-*-solaris2* | *-*-hpux11*)
 498         ;;
 499     *-*-darwin* | *-*-aix*)
 500         ;;
 501     nvptx*-*-* | amdgcn*-*-*)
 502         ;;
 503     *)
 504         noconfigdirs="$noconfigdirs target-libgomp"
 505         ;;
 506     esac
 507 fi
 508
 509 # Disable libatomic on unsupported systems.
 510 if test -d ${srcdir}/libatomic; then
 511     if test x$enable_libatomic = x; then
 512         AC_MSG_CHECKING([for libatomic support])
 513         if (srcdir=${srcdir}/libatomic; \
 514                 . ${srcdir}/configure.tgt; \
 515                 test -n "$UNSUPPORTED")
 516         then
 517             AC_MSG_RESULT([no])
 518             noconfigdirs="$noconfigdirs target-libatomic"
 519         else
 520             AC_MSG_RESULT([yes])
 521         fi
 522     fi
 523 fi
 524
 525 # Disable libitm on unsupported systems.
 526 if test -d ${srcdir}/libitm; then
 527     if test x$enable_libitm = x; then
 528         AC_MSG_CHECKING([for libitm support])
 529         if (srcdir=${srcdir}/libitm; \
 530                 . ${srcdir}/configure.tgt; \
 531                 test -n "$UNSUPPORTED")
 532         then
 533             AC_MSG_RESULT([no])
 534             noconfigdirs="$noconfigdirs target-libitm"
 535         else
 536             AC_MSG_RESULT([yes])
 537         fi
 538     fi
 539 fi
 540
 541 # Disable libsanitizer on unsupported systems.
 542 if test -d ${srcdir}/libsanitizer; then
 543     if test x$enable_libsanitizer = x; then
 544         AC_MSG_CHECKING([for libsanitizer support])
 545         if (srcdir=${srcdir}/libsanitizer; \
 546                 . ${srcdir}/configure.tgt; \
 547                 test -n "$UNSUPPORTED")
 548         then
 549             AC_MSG_RESULT([no])
 550             noconfigdirs="$noconfigdirs target-libsanitizer"
 551         else
 552             AC_MSG_RESULT([yes])
 553         fi
 554     fi
 555 fi
 556
 557 # Disable libvtv on unsupported systems.
 558 if test -d ${srcdir}/libvtv; then
 559     if test x$enable_libvtv = x; then
 560         AC_MSG_CHECKING([for libvtv support])
 561         if (srcdir=${srcdir}/libvtv; \
 562                 . ${srcdir}/configure.tgt; \
 563                 test "$VTV_SUPPORTED" != "yes")
 564         then
 565             AC_MSG_RESULT([no])
 566             noconfigdirs="$noconfigdirs target-libvtv"
 567         else
 568             AC_MSG_RESULT([yes])
 569         fi
 570     fi
 571 fi
 572
 573 # Disable libquadmath for some systems.
 574 case "${target}" in
 575   avr-*-*)
 576     noconfigdirs="$noconfigdirs target-libquadmath"
 577     ;;
 578   # libquadmath is unused on AIX and libquadmath build process use of
 579   # LD_LIBRARY_PATH can break AIX bootstrap.
 580   powerpc-*-aix* | rs6000-*-aix*)
 581     noconfigdirs="$noconfigdirs target-libquadmath"
 582     ;;
 583 esac
 584
 585 # Disable libssp for some systems.
 586 case "${target}" in
 587   avr-*-*)
 588     # No hosted I/O support.
 589     noconfigdirs="$noconfigdirs target-libssp"
 590     ;;
 591   bpf-*-*)
 592     noconfigdirs="$noconfigdirs target-libssp"
 593     ;;
 594   powerpc-*-aix* | rs6000-*-aix*)
 595     noconfigdirs="$noconfigdirs target-libssp"
 596     ;;
 597   pru-*-*)
 598     # No hosted I/O support.
 599     noconfigdirs="$noconfigdirs target-libssp"
 600     ;;
 601   rl78-*-*)
 602     # libssp uses a misaligned load to trigger a fault, but the RL78
 603     # doesn't fault for those - instead, it gives a build-time error
 604     # for explicit misaligned loads.
 605     noconfigdirs="$noconfigdirs target-libssp"
 606     ;;
 607   visium-*-*)
 608     # No hosted I/O support.
 609     noconfigdirs="$noconfigdirs target-libssp"
 610     ;;
 611 esac
 612
 613 # Disable libstdc++-v3 for some systems.
 614 # Allow user to override this if they pass --enable-libstdcxx
 615 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 616   case "${target}" in
 617     *-*-vxworks*)
 618       # VxWorks uses the Dinkumware C++ library.
 619       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 620       ;;
 621     amdgcn*-*-*)
 622       # Not ported/fails to build when using newlib.
 623       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 624       ;;
 625     arm*-wince-pe*)
 626       # the C++ libraries don't build on top of CE's C libraries
 627       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 628       ;;
 629     avr-*-*)
 630       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 631       ;;
 632     bpf-*-*)
 633       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 634       ;;
 635     ft32-*-*)
 636       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 637       ;;
 638   esac
 639 fi
 640
 641 # Disable C++ on systems where it is known to not work.
 642 # For testing, you can override this with --enable-languages=c++.
 643 case ,${enable_languages}, in
 644   *,c++,*)
 645     ;;
 646   *)
 647       case "${target}" in
 648         bpf-*-*)
 649           unsupported_languages="$unsupported_languages c++"
 650           ;;
 651       esac
 652       ;;
 653 esac
 654
 655 # Disable Objc on systems where it is known to not work.
 656 # For testing, you can override this with --enable-languages=objc.
 657 case ,${enable_languages}, in
 658   *,objc,*)
 659     ;;
 660   *)
 661       case "${target}" in
 662         bpf-*-*)
 663           unsupported_languages="$unsupported_languages objc"
 664           ;;
 665       esac
 666       ;;
 667 esac
 668
 669 # Disable D on systems where it is known to not work.
 670 # For testing, you can override this with --enable-languages=d.
 671 case ,${enable_languages}, in
 672   *,d,*)
 673     ;;
 674   *)
 675     case "${target}" in
 676       bpf-*-*)
 677         unsupported_languages="$unsupported_languages d"
 678         ;;
 679     esac
 680     ;;
 681 esac
 682
 683 # Disable libphobos on unsupported systems.
 684 # For testing, you can override this with --enable-libphobos.
 685 if test -d ${srcdir}/libphobos; then
 686     if test x$enable_libphobos = x; then
 687         AC_MSG_CHECKING([for libphobos support])
 688         if (srcdir=${srcdir}/libphobos; \
 689                 . ${srcdir}/configure.tgt; \
 690                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 691         then
 692             AC_MSG_RESULT([no])
 693             noconfigdirs="$noconfigdirs target-libphobos"
 694         else
 695             AC_MSG_RESULT([yes])
 696         fi
 697     fi
 698 fi
 699
 700 # Disable Fortran for some systems.
 701 case "${target}" in
 702   mmix-*-*)
 703     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 704     unsupported_languages="$unsupported_languages fortran"
 705     ;;
 706   bpf-*-*)
 707     unsupported_languages="$unsupported_languages fortran"
 708     ;;
 709 esac
 710
 711 # Disable libffi for some systems.
 712 case "${target}" in
 713   powerpc-*-darwin*)
 714     ;;
 715   i[[3456789]]86-*-darwin*)
 716     ;;
 717   x86_64-*-darwin[[912]]*)
 718     ;;
 719   *-*-darwin*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   *-*-netware*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   *-*-phoenix*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   *-*-rtems*)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   *-*-tpf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   *-*-uclinux*)
 735     noconfigdirs="$noconfigdirs target-libffi"
 736     ;;
 737   *-*-vxworks*)
 738     noconfigdirs="$noconfigdirs target-libffi"
 739     ;;
 740   aarch64*-*-freebsd*)
 741     noconfigdirs="$noconfigdirs target-libffi"
 742     ;;
 743   alpha*-*-*vms*)
 744     noconfigdirs="$noconfigdirs target-libffi"
 745     ;;
 746   arm*-*-freebsd*)
 747     noconfigdirs="$noconfigdirs target-libffi"
 748     ;;
 749   arm-wince-pe)
 750     noconfigdirs="$noconfigdirs target-libffi"
 751     ;;
 752   arm*-*-symbianelf*)
 753     noconfigdirs="$noconfigdirs target-libffi"
 754     ;;
 755   bpf-*-*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   cris-*-* | crisv32-*-*)
 759     case "${target}" in
 760       *-*-linux*)
 761         ;;
 762       *) # See PR46792 regarding target-libffi.
 763         noconfigdirs="$noconfigdirs target-libffi";;
 764     esac
 765     ;;
 766   hppa*64*-*-hpux*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   ia64*-*-*vms*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   i[[3456789]]86-w64-mingw*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   i[[3456789]]86-*-mingw*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   x86_64-*-mingw*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   mmix-*-*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   powerpc-*-aix*)
 785     ;;
 786   rs6000-*-aix*)
 787     ;;
 788   ft32-*-*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   *-*-lynxos*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794 esac
 795
 796 # Disable the go frontend on systems where it is known to not work. Please keep
 797 # this in sync with contrib/config-list.mk.
 798 case "${target}" in
 799 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 800     unsupported_languages="$unsupported_languages go"
 801     ;;
 802 esac
 803
 804 # Only allow gdbserver on some systems.
 805 if test -d ${srcdir}/gdbserver; then
 806     if test x$enable_gdbserver = x; then
 807         AC_MSG_CHECKING([for gdbserver support])
 808         if (srcdir=${srcdir}/gdbserver; \
 809                 . ${srcdir}/configure.srv; \
 810                 test -n "$UNSUPPORTED")
 811         then
 812             AC_MSG_RESULT([no])
 813             noconfigdirs="$noconfigdirs gdbserver"
 814         else
 815             AC_MSG_RESULT([yes])
 816         fi
 817     fi
 818 fi
 819
 820 # Disable libgo for some systems where it is known to not work.
 821 # For testing, you can easily override this with --enable-libgo.
 822 if test x$enable_libgo = x; then
 823     case "${target}" in
 824     *-*-darwin*)
 825         # PR 46986
 826         noconfigdirs="$noconfigdirs target-libgo"
 827         ;;
 828     *-*-cygwin* | *-*-mingw*)
 829         noconfigdirs="$noconfigdirs target-libgo"
 830         ;;
 831     bpf-*-*)
 832         noconfigdirs="$noconfigdirs target-libgo"
 833         ;;
 834     esac
 835 fi
 836
 837 # Default libgloss CPU subdirectory.
 838 libgloss_dir="$target_cpu"
 839
 840 case "${target}" in
 841   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 842     libgloss_dir=wince
 843     ;;
 844   aarch64*-*-* )
 845     libgloss_dir=aarch64
 846     ;;
 847   arm*-*-*)
 848     libgloss_dir=arm
 849     ;;
 850   cris-*-* | crisv32-*-*)
 851     libgloss_dir=cris
 852     ;;
 853   hppa*-*-*)
 854     libgloss_dir=pa
 855     ;;
 856   i[[3456789]]86-*-*)
 857     libgloss_dir=i386
 858     ;;
 859   loongarch*-*-*)
 860     libgloss_dir=loongarch
 861     ;;
 862   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 863     libgloss_dir=m68hc11
 864     ;;
 865   m68*-*-* | fido-*-*)
 866     libgloss_dir=m68k
 867     ;;
 868   mips*-*-*)
 869     libgloss_dir=mips
 870     ;;
 871   powerpc*-*-*)
 872     libgloss_dir=rs6000
 873     ;;
 874   pru-*-*)
 875     libgloss_dir=pru
 876     ;;
 877   sparc*-*-*)
 878     libgloss_dir=sparc
 879     ;;
 880 esac
 881
 882 # Disable newlib and libgloss for various target OSes.
 883 case "${target}" in
 884   alpha*-dec-osf*)
 885     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 886     ;;
 887   i[[3456789]]86-*-linux*)
 888     # This section makes it possible to build newlib natively on linux.
 889     # If we are using a cross compiler then don't configure newlib.
 890     if test x${is_cross_compiler} != xno ; then
 891       noconfigdirs="$noconfigdirs target-newlib"
 892     fi
 893     noconfigdirs="$noconfigdirs target-libgloss"
 894     # If we are not using a cross compiler, do configure newlib.
 895     # Note however, that newlib will only be configured in this situation
 896     # if the --with-newlib option has been given, because otherwise
 897     # 'target-newlib' will appear in skipdirs.
 898     ;;
 899   i[[3456789]]86-*-rdos*)
 900     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 901     ;;
 902   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 903     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 904     ;;
 905   sparc-*-sunos4*)
 906     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 907     ;;
 908   bpf-*-*)
 909     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 910     ;;
 911   *-*-aix*)
 912     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 913     ;;
 914   *-*-beos*)
 915     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 916     ;;
 917   *-*-chorusos)
 918     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 919     ;;
 920   *-*-dragonfly*)
 921     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 922     ;;
 923   *-*-freebsd*)
 924     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 925     ;;
 926   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 927     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 928     ;;
 929   *-*-lynxos*)
 930     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 931     ;;
 932   *-*-mingw*)
 933     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 934     ;;
 935   *-*-netbsd*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   *-*-netware*)
 939     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 940     ;;
 941   *-*-tpf*)
 942     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 943     ;;
 944   *-*-uclinux*)
 945     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 946     ;;
 947   *-*-vxworks*)
 948     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 949     ;;
 950 esac
 951
 952 case "${target}" in
 953   *-*-chorusos)
 954     ;;
 955   aarch64-*-darwin*)
 956     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 957     noconfigdirs="$noconfigdirs sim target-rda"
 958     ;;
 959   amdgcn*-*-*)
 960     ;;
 961   arm-*-darwin*)
 962     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 963     noconfigdirs="$noconfigdirs sim target-rda"
 964     ;;
 965   powerpc-*-darwin*)
 966     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 967     noconfigdirs="$noconfigdirs sim target-rda"
 968     ;;
 969   i[[3456789]]86-*-darwin*)
 970     noconfigdirs="$noconfigdirs ld gprof"
 971     noconfigdirs="$noconfigdirs sim target-rda"
 972     ;;
 973   x86_64-*-darwin[[912]]*)
 974     noconfigdirs="$noconfigdirs ld gas gprof"
 975     noconfigdirs="$noconfigdirs sim target-rda"
 976     ;;
 977   *-*-darwin*)
 978     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 979     noconfigdirs="$noconfigdirs sim target-rda"
 980     ;;
 981   *-*-dragonfly*)
 982     ;;
 983   *-*-freebsd*)
 984     if test "x$with_gmp" = x \
 985         && ! test -d ${srcdir}/gmp \
 986         && test -f /usr/local/include/gmp.h; then
 987       with_gmp=/usr/local
 988     fi
 989     ;;
 990   *-*-kaos*)
 991     # Remove unsupported stuff on all kaOS configurations.
 992     noconfigdirs="$noconfigdirs target-libgloss"
 993     ;;
 994   *-*-netbsd*)
 995     ;;
 996   *-*-netware*)
 997     ;;
 998   *-*-phoenix*)
 999     noconfigdirs="$noconfigdirs target-libgloss"
1000     ;;
1001   *-*-rtems*)
1002     noconfigdirs="$noconfigdirs target-libgloss"
1003     ;;
1004     # The tpf target doesn't support gdb yet.
1005   *-*-tpf*)
1006     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1007     ;;
1008   *-*-uclinux*)
1009     noconfigdirs="$noconfigdirs target-rda"
1010     ;;
1011   *-*-vxworks*)
1012     ;;
1013   alpha*-dec-osf*)
1014     # ld works, but does not support shared libraries.
1015     # gas doesn't generate exception information.
1016     noconfigdirs="$noconfigdirs gas ld"
1017     ;;
1018   alpha*-*-*vms*)
1019     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1020     ;;
1021   alpha*-*-*)
1022     # newlib is not 64 bit ready
1023     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1024     ;;
1025   bpf-*-*)
1026     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1027     ;;
1028   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1029     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1030     ;;
1031   arc*-*-*)
1032     noconfigdirs="$noconfigdirs sim"
1033     ;;
1034   arm-*-pe*)
1035     noconfigdirs="$noconfigdirs target-libgloss"
1036     ;;
1037   arm-*-riscix*)
1038     noconfigdirs="$noconfigdirs ld target-libgloss"
1039     ;;
1040   avr-*-*)
1041     if test x${with_avrlibc} != xno; then
1042       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1043     fi
1044     ;;
1045   c4x-*-* | tic4x-*-*)
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   tic54x-*-*)
1049     noconfigdirs="$noconfigdirs target-libgloss gdb"
1050     ;;
1051   d10v-*-*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054   d30v-*-*)
1055     noconfigdirs="$noconfigdirs gdb"
1056     ;;
1057   fr30-*-elf*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ft32-*-*)
1061     noconfigdirs="$noconfigdirs target-rda gprof"
1062     ;;
1063   moxie-*-*)
1064     noconfigdirs="$noconfigdirs"
1065     ;;
1066   h8300*-*-*)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   h8500-*-*)
1070     noconfigdirs="$noconfigdirs target-libgloss"
1071     ;;
1072   hppa*64*-*-hpux*)
1073     noconfigdirs="$noconfigdirs gdb"
1074     ;;
1075   hppa*64*-*-linux*)
1076     ;;
1077   hppa*-*-linux*)
1078     ;;
1079   hppa*-*-*elf* | \
1080   hppa*-*-lites* | \
1081   hppa*-*-openbsd* | \
1082   hppa*64*-*-*)
1083     ;;
1084   hppa*-*-pro*)
1085     ;;
1086   hppa*-*-*)
1087     noconfigdirs="$noconfigdirs ld"
1088     ;;
1089   i960-*-*)
1090     noconfigdirs="$noconfigdirs gdb"
1091     ;;
1092   ia64*-*-elf*)
1093     # No gdb support yet.
1094     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1095     ;;
1096   ia64*-**-hpux*)
1097     # No ld support yet.
1098     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1099     ;;
1100   ia64*-*-*vms*)
1101     # No ld support yet.
1102     noconfigdirs="$noconfigdirs libgui itcl ld"
1103     ;;
1104   i[[3456789]]86-w64-mingw*)
1105     ;;
1106   i[[3456789]]86-*-mingw*)
1107     target_configdirs="$target_configdirs target-winsup"
1108     ;;
1109   *-*-cygwin*)
1110     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1111     noconfigdirs="$noconfigdirs target-libgloss"
1112     # always build newlib if winsup directory is present.
1113     if test -d "$srcdir/winsup/cygwin"; then
1114       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1115     elif test -d "$srcdir/newlib"; then
1116       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1117     fi
1118     ;;
1119   i[[3456789]]86-*-pe)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   i[[3456789]]86-*-sco3.2v5*)
1123     # The linker does not yet know about weak symbols in COFF,
1124     # and is not configured to handle mixed ELF and COFF.
1125     noconfigdirs="$noconfigdirs ld target-libgloss"
1126     ;;
1127   i[[3456789]]86-*-sco*)
1128     noconfigdirs="$noconfigdirs gprof target-libgloss"
1129     ;;
1130   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1131     noconfigdirs="$noconfigdirs target-libgloss"
1132     ;;
1133   i[[3456789]]86-*-sysv4*)
1134     noconfigdirs="$noconfigdirs target-libgloss"
1135     ;;
1136   i[[3456789]]86-*-beos*)
1137     noconfigdirs="$noconfigdirs gdb"
1138     ;;
1139   i[[3456789]]86-*-rdos*)
1140     noconfigdirs="$noconfigdirs gdb"
1141     ;;
1142   mmix-*-*)
1143     noconfigdirs="$noconfigdirs gdb"
1144     ;;
1145   mt-*-*)
1146     noconfigdirs="$noconfigdirs sim"
1147     ;;
1148   nfp-*-*)
1149     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1150     noconfigdirs="$noconfigdirs $target_libraries"
1151     ;;
1152   pdp11-*-*)
1153     noconfigdirs="$noconfigdirs gdb gprof"
1154     ;;
1155   powerpc-*-aix*)
1156     # copied from rs6000-*-* entry
1157     noconfigdirs="$noconfigdirs gprof"
1158     ;;
1159   powerpc*-*-winnt* | powerpc*-*-pe*)
1160     target_configdirs="$target_configdirs target-winsup"
1161     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1162     # always build newlib.
1163     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1164     ;;
1165     # This is temporary until we can link against shared libraries
1166   powerpcle-*-solaris*)
1167     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1168     ;;
1169   powerpc-*-beos*)
1170     noconfigdirs="$noconfigdirs gdb"
1171     ;;
1172   rs6000-*-lynxos*)
1173     noconfigdirs="$noconfigdirs gprof"
1174     ;;
1175   rs6000-*-aix*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   rs6000-*-*)
1179     noconfigdirs="$noconfigdirs gprof"
1180     ;;
1181   m68k-apollo-*)
1182     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1183     ;;
1184   microblaze*)
1185     noconfigdirs="$noconfigdirs gprof"
1186     ;;
1187   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1188     if test x$with_newlib = xyes; then
1189       noconfigdirs="$noconfigdirs gprof"
1190     fi
1191     ;;
1192   mips*-*-irix5*)
1193     noconfigdirs="$noconfigdirs gprof target-libgloss"
1194     ;;
1195   mips*-*-irix6*)
1196     noconfigdirs="$noconfigdirs gprof target-libgloss"
1197     ;;
1198   mips*-*-bsd*)
1199     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1200     ;;
1201   mips*-*-linux*)
1202     ;;
1203   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1204   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1205     noconfigdirs="$noconfigdirs ld gas gprof"
1206     ;;
1207   mips*-*-*)
1208     noconfigdirs="$noconfigdirs gprof"
1209     ;;
1210   nvptx*-*-*)
1211     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1212     ;;
1213   sh-*-*)
1214     case "${target}" in
1215       sh*-*-elf)
1216          ;;
1217       *)
1218          noconfigdirs="$noconfigdirs target-libgloss" ;;
1219     esac
1220     ;;
1221   sparc-*-sunos4*)
1222     if test x${is_cross_compiler} = xno ; then
1223            use_gnu_ld=no
1224     fi
1225     ;;
1226   tic6x-*-*)
1227     noconfigdirs="$noconfigdirs sim"
1228     ;;
1229   v810-*-*)
1230     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1231     ;;
1232   vax-*-*)
1233     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1234     ;;
1235   wasm32-*-*)
1236     noconfigdirs="$noconfigdirs ld"
1237     ;;
1238   loongarch*-*-linux*)
1239     ;;
1240   loongarch*-*-*)
1241     noconfigdirs="$noconfigdirs gprof"
1242     ;;
1243 esac
1244
1245 # If we aren't building newlib, then don't build libgloss, since libgloss
1246 # depends upon some newlib header files.
1247 case "${noconfigdirs}" in
1248   *target-libgloss*) ;;
1249   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1250 esac
1251
1252 # Work in distributions that contain no compiler tools, like Autoconf.
1253 host_makefile_frag=/dev/null
1254 if test -d ${srcdir}/config ; then
1255 case "${host}" in
1256   i[[3456789]]86-*-msdosdjgpp*)
1257     host_makefile_frag="config/mh-djgpp"
1258     ;;
1259   *-cygwin*)
1260     ACX_CHECK_CYGWIN_CAT_WORKS
1261     host_makefile_frag="config/mh-cygwin"
1262     ;;
1263   *-mingw*)
1264     host_makefile_frag="config/mh-mingw"
1265     ;;
1266   alpha*-linux*)
1267     host_makefile_frag="config/mh-alpha-linux"
1268     ;;
1269   hppa*-hp-hpux*)
1270     host_makefile_frag="config/mh-pa"
1271     ;;
1272   hppa*-*)
1273     host_makefile_frag="config/mh-pa"
1274     ;;
1275   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1276     host_makefile_frag="config/mh-darwin"
1277     ;;
1278   powerpc-*-aix*)
1279     host_makefile_frag="config/mh-ppc-aix"
1280     ;;
1281   rs6000-*-aix*)
1282     host_makefile_frag="config/mh-ppc-aix"
1283     ;;
1284 esac
1285 fi
1286
1287 if test "${build}" != "${host}" ; then
1288   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1289   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1290   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1291   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1292   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1293   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1294   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1295   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1296   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1297   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1298   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1299   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1300   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1301   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1302   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1303 else
1304   AR_FOR_BUILD="\$(AR)"
1305   AS_FOR_BUILD="\$(AS)"
1306   CC_FOR_BUILD="\$(CC)"
1307   CXX_FOR_BUILD="\$(CXX)"
1308   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1309   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1310   GOC_FOR_BUILD="\$(GOC)"
1311   GDC_FOR_BUILD="\$(GDC)"
1312   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1313   LD_FOR_BUILD="\$(LD)"
1314   NM_FOR_BUILD="\$(NM)"
1315   RANLIB_FOR_BUILD="\$(RANLIB)"
1316   WINDRES_FOR_BUILD="\$(WINDRES)"
1317   WINDMC_FOR_BUILD="\$(WINDMC)"
1318 fi
1319
1320 AC_PROG_CC_C99
1321 AC_PROG_CXX
1322
1323 # We must set the default linker to the linker used by gcc for the correct
1324 # operation of libtool.  If LD is not defined and we are using gcc, try to
1325 # set the LD default to the ld used by gcc.
1326 if test -z "$LD"; then
1327   if test "$GCC" = yes; then
1328     case $build in
1329     *-*-mingw*)
1330       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1331     *)
1332       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1333     esac
1334     case $gcc_prog_ld in
1335     # Accept absolute paths.
1336     [[\\/]* | [A-Za-z]:[\\/]*)]
1337       LD="$gcc_prog_ld" ;;
1338     esac
1339   fi
1340 fi
1341
1342 # Check whether -static-libstdc++ -static-libgcc is supported.
1343 have_static_libs=no
1344 if test "$GCC" = yes; then
1345   saved_LDFLAGS="$LDFLAGS"
1346
1347   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1348   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1349   AC_LANG_PUSH(C++)
1350   AC_LINK_IFELSE([AC_LANG_SOURCE([
1351 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1352 #error -static-libstdc++ not implemented
1353 #endif
1354 int main() {}])],
1355     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1356     [AC_MSG_RESULT([no])])
1357   AC_LANG_POP(C++)
1358
1359   LDFLAGS="$saved_LDFLAGS"
1360 fi
1361
1362 ACX_PROG_GNAT
1363 ACX_PROG_GDC
1364 ACX_PROG_CMP_IGNORE_INITIAL
1365
1366 AC_ARG_ENABLE([bootstrap],
1367 [AS_HELP_STRING([--enable-bootstrap],
1368                 [enable bootstrapping @<:@yes if native build@:>@])],,
1369 enable_bootstrap=default)
1370
1371 # Issue errors and warnings for invalid/strange bootstrap combinations.
1372 if test -r $srcdir/gcc/configure; then
1373   have_compiler=yes
1374 else
1375   have_compiler=no
1376 fi
1377
1378 case "$have_compiler:$host:$target:$enable_bootstrap" in
1379   *:*:*:no) ;;
1380
1381   # Default behavior.  Enable bootstrap if we have a compiler
1382   # and we are in a native configuration.
1383   yes:$build:$build:default)
1384     enable_bootstrap=yes ;;
1385
1386   *:*:*:default)
1387     enable_bootstrap=no ;;
1388
1389   # We have a compiler and we are in a native configuration, bootstrap is ok
1390   yes:$build:$build:yes)
1391     ;;
1392
1393   # Other configurations, but we have a compiler.  Assume the user knows
1394   # what he's doing.
1395   yes:*:*:yes)
1396     AC_MSG_WARN([trying to bootstrap a cross compiler])
1397     ;;
1398
1399   # No compiler: if they passed --enable-bootstrap explicitly, fail
1400   no:*:*:yes)
1401     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1402
1403   # Fail if wrong command line
1404   *)
1405     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1406     ;;
1407 esac
1408
1409 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1410 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1411 # require C++11 (or higher).
1412 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1413   CXX="$CXX -std=c++11"
1414 elif test "$have_compiler" = yes; then
1415   AX_CXX_COMPILE_STDCXX(11)
1416
1417   if test "${build}" != "${host}"; then
1418     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1419   fi
1420 fi
1421
1422 AC_ARG_ENABLE([pgo-build],
1423 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1424                 [enable the PGO build])],
1425 [enable_pgo_build=$enableval],
1426 [enable_pgo_build=no])
1427
1428 # Issue errors and warnings for invalid/strange PGO build combinations.
1429 case "$have_compiler:$host:$target:$enable_pgo_build" in
1430   *:*:*:no) ;;
1431
1432   # Allow the PGO build only if we aren't building a compiler and
1433   # we are in a native configuration.
1434   no:$build:$build:yes | no:$build:$build:lto) ;;
1435
1436   # Disallow the PGO bootstrap if we are building a compiler.
1437   yes:*:*:yes | yes:*:*:lto)
1438     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1439
1440   *)
1441     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1442     ;;
1443 esac
1444
1445 if test "$enable_pgo_build" != "no"; then
1446   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1447   old_CFLAGS="$CFLAGS"
1448   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1449   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1450   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1451                     [PGO_BUILD_GEN_CFLAGS=])
1452   CFLAGS="$old_CFLAGS"
1453   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1454     AC_MSG_RESULT([yes])
1455     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1456   else
1457     AC_MSG_RESULT([no])
1458     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1459   fi
1460
1461   if test "$enable_pgo_build" = "lto"; then
1462     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1463     old_CFLAGS="$CFLAGS"
1464     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1465     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1466     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1467                       [PGO_BUILD_LTO_CFLAGS=])
1468     CFLAGS="$old_CFLAGS"
1469     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1470       AC_MSG_RESULT([yes])
1471     else
1472       AC_MSG_RESULT([no])
1473       AC_MSG_WARN([LTO is disabled for the PGO build])
1474     fi
1475   fi
1476 fi
1477 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1478 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1479 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1480
1481 # Used for setting $lt_cv_objdir
1482 _LT_CHECK_OBJDIR
1483
1484 # Check for GMP, MPFR and MPC
1485 require_gmp=no
1486 require_mpc=no
1487 if test -d ${srcdir}/gcc ; then
1488   require_gmp=yes
1489   require_mpc=yes
1490 fi
1491 if test -d ${srcdir}/gdb ; then
1492   if test "x$enable_gdb" != xno; then
1493    require_gmp=yes
1494   fi
1495 fi
1496
1497 gmplibs="-lmpfr -lgmp"
1498 if test x"$require_mpc" = "xyes" ; then
1499   gmplibs="-lmpc $gmplibs"
1500 fi
1501 gmpinc=
1502 have_gmp=no
1503
1504 # Specify a location for mpc
1505 # check for this first so it ends up on the link line before mpfr.
1506 AC_ARG_WITH(mpc,
1507 [AS_HELP_STRING([--with-mpc=PATH],
1508                 [specify prefix directory for installed MPC package.
1509                  Equivalent to --with-mpc-include=PATH/include
1510                  plus --with-mpc-lib=PATH/lib])])
1511 AC_ARG_WITH(mpc-include,
1512 [AS_HELP_STRING([--with-mpc-include=PATH],
1513                 [specify directory for installed MPC include files])])
1514 AC_ARG_WITH(mpc-lib,
1515 [AS_HELP_STRING([--with-mpc-lib=PATH],
1516                 [specify directory for the installed MPC library])])
1517
1518 if test "x$with_mpc" != x; then
1519   gmplibs="-L$with_mpc/lib $gmplibs"
1520   gmpinc="-I$with_mpc/include $gmpinc"
1521 fi
1522 if test "x$with_mpc_include" != x; then
1523   gmpinc="-I$with_mpc_include $gmpinc"
1524 fi
1525 if test "x$with_mpc_lib" != x; then
1526   gmplibs="-L$with_mpc_lib $gmplibs"
1527 fi
1528 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1529   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1530   gmpinc='-I$$s/mpc/src '"$gmpinc"
1531   # Do not test the mpc version.  Assume that it is sufficient, since
1532   # it is in the source tree, and the library has not been built yet
1533   # but it would be included on the link line in the version check below
1534   # hence making the test fail.
1535   have_gmp=yes
1536 fi
1537
1538 # Specify a location for mpfr
1539 # check for this first so it ends up on the link line before gmp.
1540 AC_ARG_WITH(mpfr,
1541 [AS_HELP_STRING([--with-mpfr=PATH],
1542                 [specify prefix directory for installed MPFR package.
1543                  Equivalent to --with-mpfr-include=PATH/include
1544                  plus --with-mpfr-lib=PATH/lib])])
1545 AC_ARG_WITH(mpfr-include,
1546 [AS_HELP_STRING([--with-mpfr-include=PATH],
1547                 [specify directory for installed MPFR include files])])
1548 AC_ARG_WITH(mpfr-lib,
1549 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1550                 [specify directory for the installed MPFR library])])
1551
1552 if test "x$with_mpfr" != x; then
1553   gmplibs="-L$with_mpfr/lib $gmplibs"
1554   gmpinc="-I$with_mpfr/include $gmpinc"
1555 fi
1556 if test "x$with_mpfr_include" != x; then
1557   gmpinc="-I$with_mpfr_include $gmpinc"
1558 fi
1559 if test "x$with_mpfr_lib" != x; then
1560   gmplibs="-L$with_mpfr_lib $gmplibs"
1561 fi
1562 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1563   # MPFR v3.1.0 moved the sources into a src sub-directory.
1564   if ! test -d ${srcdir}/mpfr/src; then
1565     AC_MSG_ERROR([dnl
1566 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1567   fi
1568   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1569   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1570   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1571   # Do not test the mpfr version.  Assume that it is sufficient, since
1572   # it is in the source tree, and the library has not been built yet
1573   # but it would be included on the link line in the version check below
1574   # hence making the test fail.
1575   have_gmp=yes
1576 fi
1577
1578 # Specify a location for gmp
1579 AC_ARG_WITH(gmp,
1580 [AS_HELP_STRING([--with-gmp=PATH],
1581                 [specify prefix directory for the installed GMP package.
1582                  Equivalent to --with-gmp-include=PATH/include
1583                  plus --with-gmp-lib=PATH/lib])])
1584 AC_ARG_WITH(gmp-include,
1585 [AS_HELP_STRING([--with-gmp-include=PATH],
1586                 [specify directory for installed GMP include files])])
1587 AC_ARG_WITH(gmp-lib,
1588 [AS_HELP_STRING([--with-gmp-lib=PATH],
1589                 [specify directory for the installed GMP library])])
1590
1591
1592 if test "x$with_gmp" != x; then
1593   gmplibs="-L$with_gmp/lib $gmplibs"
1594   gmpinc="-I$with_gmp/include $gmpinc"
1595 fi
1596 if test "x$with_gmp_include" != x; then
1597   gmpinc="-I$with_gmp_include $gmpinc"
1598 fi
1599 if test "x$with_gmp_lib" != x; then
1600   gmplibs="-L$with_gmp_lib $gmplibs"
1601 fi
1602 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1603   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1604   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1605   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1606   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1607   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1608   # Do not test the gmp version.  Assume that it is sufficient, since
1609   # it is in the source tree, and the library has not been built yet
1610   # but it would be included on the link line in the version check below
1611   # hence making the test fail.
1612   have_gmp=yes
1613 fi
1614
1615 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1616   have_gmp=yes
1617   saved_CFLAGS="$CFLAGS"
1618   CFLAGS="$CFLAGS $gmpinc"
1619   # Check for the recommended and required versions of GMP.
1620   AC_MSG_CHECKING([for the correct version of gmp.h])
1621   AC_TRY_COMPILE([#include "gmp.h"],[
1622   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1623   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1624   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1625   choke me
1626   #endif
1627   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1628   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1629   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1630   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1631   choke me
1632   #endif
1633   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1634    [AC_MSG_RESULT([no]); have_gmp=no])
1635
1636   # If we have GMP, check the MPFR version.
1637   if test x"$have_gmp" = xyes; then
1638     # Check for the recommended and required versions of MPFR.
1639     AC_MSG_CHECKING([for the correct version of mpfr.h])
1640     AC_TRY_COMPILE([#include <gmp.h>
1641     #include <mpfr.h>],[
1642     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1643     choke me
1644     #endif
1645     ], [AC_TRY_COMPILE([#include <gmp.h>
1646     #include <mpfr.h>],[
1647     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1648     choke me
1649     #endif
1650     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1651      [AC_MSG_RESULT([no]); have_gmp=no])
1652   fi
1653
1654   # Check for the MPC header version.
1655   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1656     # Check for the recommended and required versions of MPC.
1657     AC_MSG_CHECKING([for the correct version of mpc.h])
1658     AC_TRY_COMPILE([#include <mpc.h>],[
1659     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1660     choke me
1661     #endif
1662     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1663     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1664     choke me
1665     #endif
1666     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1667      [AC_MSG_RESULT([no]); have_gmp=no])
1668   fi
1669
1670   # Now check the MPFR library.
1671   if test x"$have_gmp" = xyes; then
1672     saved_LIBS="$LIBS"
1673     LIBS="$LIBS $gmplibs"
1674     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1675     AC_TRY_LINK([#include <mpfr.h>],[
1676     mpfr_t n;
1677     mpfr_t x;
1678     int t;
1679     mpfr_init (n);
1680     mpfr_init (x);
1681     mpfr_atan2 (n, n, x, MPFR_RNDN);
1682     mpfr_erfc (n, x, MPFR_RNDN);
1683     mpfr_subnormalize (x, t, MPFR_RNDN);
1684     mpfr_clear(n);
1685     mpfr_clear(x);
1686     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1687     LIBS="$saved_LIBS"
1688   fi
1689
1690   # Now check the MPC library
1691   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1692     saved_LIBS="$LIBS"
1693     LIBS="$LIBS $gmplibs"
1694     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1695     AC_TRY_LINK([#include <mpc.h>],[
1696     mpc_t c;
1697     mpc_init2 (c, 53);
1698     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1699     mpc_cosh (c, c, MPC_RNDNN);
1700     mpc_pow (c, c, c, MPC_RNDNN);
1701     mpc_acosh (c, c, MPC_RNDNN);
1702     mpc_clear (c);
1703     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1704     LIBS="$saved_LIBS"
1705   fi
1706
1707   CFLAGS="$saved_CFLAGS"
1708
1709 # The library versions listed in the error message below should match
1710 # the HARD-minimums enforced above.
1711   if test x$have_gmp != xyes; then
1712     if test -d ${srcdir}/gcc ; then
1713       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1714 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1715 their locations.  Source code for these libraries can be found at
1716 their respective hosting sites as well as at
1717 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1718 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1719 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1720 make sure that you have installed both the libraries and the header
1721 files.  They may be located in separate packages.])
1722     else
1723       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1724 Try the --with-gmp and/or --with-mpfr options to specify
1725 their locations.  If you obtained GMP and/or MPFR from a vendor
1726 distribution package, make sure that you have installed both the libraries
1727 and the header files.  They may be located in separate packages.])
1728     fi
1729   fi
1730 fi
1731
1732 # Flags needed for both GMP, MPFR and/or MPC.
1733 AC_SUBST(gmplibs)
1734 AC_SUBST(gmpinc)
1735 AC_SUBST(extra_mpfr_configure_flags)
1736 AC_SUBST(extra_mpc_gmp_configure_flags)
1737 AC_SUBST(extra_mpc_mpfr_configure_flags)
1738 AC_SUBST(extra_isl_gmp_configure_flags)
1739
1740 # Libraries to use for stage1 or when not bootstrapping.
1741 AC_ARG_WITH(stage1-libs,
1742 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1743 [if test "$withval" = "no" -o "$withval" = "yes"; then
1744    stage1_libs=
1745  else
1746    stage1_libs=$withval
1747  fi],
1748 [stage1_libs=])
1749 AC_SUBST(stage1_libs)
1750
1751 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1752 # default is yes if gcc is being built; no otherwise.  The reason for
1753 # this default is that gdb is sometimes linked against GNU Source
1754 # Highlight, which is a shared library that uses C++ exceptions.  In
1755 # this case, -static-libstdc++ will cause crashes.
1756 AC_ARG_WITH(static-standard-libraries,
1757 [AS_HELP_STRING([--with-static-standard-libraries],
1758                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1759 [], [with_static_standard_libraries=auto])
1760 if test "$with_static_standard_libraries" = auto; then
1761   with_static_standard_libraries=$have_compiler
1762 fi
1763
1764 # Linker flags to use for stage1 or when not bootstrapping.
1765 AC_ARG_WITH(stage1-ldflags,
1766 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1767 [if test "$withval" = "no" -o "$withval" = "yes"; then
1768    stage1_ldflags=
1769  else
1770    stage1_ldflags=$withval
1771  fi],
1772 [stage1_ldflags=
1773  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1774  # if supported.  But if the user explicitly specified the libraries to use,
1775  # trust that they are doing what they want.
1776  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1777      -a "$have_static_libs" = yes; then
1778    stage1_ldflags="-static-libstdc++ -static-libgcc"
1779  fi])
1780 AC_SUBST(stage1_ldflags)
1781
1782 # Libraries to use for stage2 and later builds.
1783 AC_ARG_WITH(boot-libs,
1784 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1785 [if test "$withval" = "no" -o "$withval" = "yes"; then
1786    poststage1_libs=
1787  else
1788    poststage1_libs=$withval
1789  fi],
1790 [poststage1_libs=])
1791 AC_SUBST(poststage1_libs)
1792
1793 # Linker flags to use for stage2 and later builds.
1794 AC_ARG_WITH(boot-ldflags,
1795 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1796                 [linker flags for stage2 and later])],
1797 [if test "$withval" = "no" -o "$withval" = "yes"; then
1798    poststage1_ldflags=
1799  else
1800    poststage1_ldflags=$withval
1801  fi],
1802 [poststage1_ldflags=
1803  # In stages 2 and 3, default to linking libstdc++ and libgcc
1804  # statically.  But if the user explicitly specified the libraries to
1805  # use, trust that they are doing what they want.
1806  if test "$poststage1_libs" = ""; then
1807    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1808  fi])
1809 AC_SUBST(poststage1_ldflags)
1810
1811 # GCC GRAPHITE dependency isl.
1812 # Basic setup is inlined here, actual checks are in config/isl.m4
1813
1814 AC_ARG_WITH(isl,
1815   [AS_HELP_STRING(
1816    [--with-isl=PATH],
1817    [Specify prefix directory for the installed isl package.
1818     Equivalent to --with-isl-include=PATH/include
1819     plus --with-isl-lib=PATH/lib])])
1820
1821 # Treat --without-isl as a request to disable
1822 # GRAPHITE support and skip all following checks.
1823 if test "x$with_isl" != "xno"; then
1824   # Check for isl
1825   dnl Provide configure switches and initialize islinc & isllibs
1826   dnl with user input.
1827   ISL_INIT_FLAGS
1828   dnl The versions of isl that work for Graphite
1829   ISL_CHECK_VERSION()
1830   dnl Only execute fail-action, if isl has been requested.
1831   ISL_IF_FAILED([
1832     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1833 fi
1834
1835 # If the isl check failed, disable builds of in-tree variant of isl
1836 if test "x$with_isl" = xno ||
1837    test "x$gcc_cv_isl" = xno; then
1838   noconfigdirs="$noconfigdirs isl"
1839   islinc=
1840 fi
1841
1842 AC_SUBST(isllibs)
1843 AC_SUBST(islinc)
1844
1845 # Check for LTO support.
1846 AC_ARG_ENABLE(lto,
1847 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1848 enable_lto=$enableval,
1849 enable_lto=yes; default_enable_lto=yes)
1850
1851 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1852   build_lto_plugin=yes
1853 ],[if test x"$default_enable_lto" = x"yes" ; then
1854     case $target in
1855       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1856       # On other non-ELF platforms, LTO has yet to be validated.
1857       *) enable_lto=no ;;
1858     esac
1859   else
1860   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1861   # It would also be nice to check the binutils support, but we don't
1862   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1863   # warn during gcc/ subconfigure; unless you're bootstrapping with
1864   # -flto it won't be needed until after installation anyway.
1865     case $target in
1866       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1867       *) if test x"$enable_lto" = x"yes"; then
1868         AC_MSG_ERROR([LTO support is not enabled for this target.])
1869         fi
1870       ;;
1871     esac
1872   fi
1873   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1874   # Build it unless LTO was explicitly disabled.
1875   case $target in
1876     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1877     *) ;;
1878   esac
1879 ])
1880
1881 AC_ARG_ENABLE(linker-plugin-configure-flags,
1882   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1883     [additional flags for configuring linker plugins @<:@none@:>@])],
1884   extra_linker_plugin_configure_flags=$enableval,
1885   extra_linker_plugin_configure_flags=)
1886 AC_SUBST(extra_linker_plugin_configure_flags)
1887 AC_ARG_ENABLE(linker-plugin-flags,
1888   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1889     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1890   extra_linker_plugin_flags=$enableval,
1891   extra_linker_plugin_flags=)
1892 AC_SUBST(extra_linker_plugin_flags)
1893
1894 # Enable --enable-host-shared.
1895 # Checked early to determine whether jit is an 'all' language
1896 AC_ARG_ENABLE(host-shared,
1897 [AS_HELP_STRING([--enable-host-shared],
1898                 [build host code as shared libraries])],
1899 [host_shared=$enableval
1900  case $host in
1901    x86_64-*-darwin* | aarch64-*-darwin*)
1902      if test x$host_shared != xyes ; then
1903        # PIC is the default, and actually cannot be switched off.
1904        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1905        host_shared=yes
1906      fi ;;
1907   *) ;;
1908  esac],
1909 [case $host in
1910   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1911   *) host_shared=no ;;
1912  esac])
1913
1914 AC_SUBST(host_shared)
1915
1916 # If we are building PIC/PIE host executables, and we are building dependent
1917 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
1918 # code.
1919 host_libs_picflag=
1920 if test "$host_shared" = "yes";then
1921 host_libs_picflag='--with-pic'
1922 fi
1923 AC_SUBST(host_libs_picflag)
1924
1925 # By default, C and C++ are the only stage 1 languages.
1926 stage1_languages=,c,
1927
1928 # Target libraries that we bootstrap.
1929 bootstrap_target_libs=,target-libgcc,
1930
1931 # Figure out what language subdirectories are present.
1932 # Look if the user specified --enable-languages="..."; if not, use
1933 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1934 # go away some day.
1935 # NB:  embedded tabs in this IF block -- do not untabify
1936 if test -d ${srcdir}/gcc; then
1937   if test x"${enable_languages+set}" != xset; then
1938     if test x"${LANGUAGES+set}" = xset; then
1939       enable_languages="${LANGUAGES}"
1940         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1941     else
1942       enable_languages=default
1943     fi
1944   else
1945     if test x"${enable_languages}" = x ||
1946        test x"${enable_languages}" = xyes;
1947        then
1948       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1949       exit 1
1950     fi
1951   fi
1952   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1953
1954   # 'f95' is the old name for the 'fortran' language. We issue a warning
1955   # and make the substitution.
1956   case ,${enable_languages}, in
1957     *,f95,*)
1958       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1959       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1960       ;;
1961   esac
1962
1963   # If bootstrapping, C++ must be enabled.
1964   case ",$enable_languages,:$enable_bootstrap" in
1965     *,c++,*:*) ;;
1966     *:yes)
1967       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1968         enable_languages="${enable_languages},c++"
1969       else
1970         AC_MSG_ERROR([bootstrapping requires c++ sources])
1971       fi
1972       ;;
1973   esac
1974
1975   # First scan to see if an enabled language requires some other language.
1976   # We assume that a given config-lang.in will list all the language
1977   # front ends it requires, even if some are required indirectly.
1978   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1979     case ${lang_frag} in
1980       ..) ;;
1981       # The odd quoting in the next line works around
1982       # an apparent bug in bash 1.12 on linux.
1983       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1984       *)
1985         # From the config-lang.in, get $language, $lang_requires, and
1986         # $lang_requires_boot_languages.
1987         language=
1988         lang_requires=
1989         lang_requires_boot_languages=
1990         # set srcdir during sourcing lang_frag to the gcc dir.
1991         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1992         # polutes this shell
1993         saved_srcdir=${srcdir}
1994         srcdir=${srcdir}/gcc . ${lang_frag}
1995         srcdir=${saved_srcdir}
1996         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1997           case ,${enable_languages}, in
1998             *,$other,*) ;;
1999             *,default,*) ;;
2000             *,all,*) ;;
2001             *,$language,*)
2002               echo " \`$other' language required by \`$language'; enabling" 1>&2
2003               enable_languages="${enable_languages},${other}"
2004               ;;
2005           esac
2006         done
2007         for other in ${lang_requires_boot_languages} ; do
2008           if test "$other" != "c"; then
2009             case ,${enable_stage1_languages}, in
2010               *,$other,*) ;;
2011               *,default,*) ;;
2012               *,all,*) ;;
2013               *)
2014                 case ,${enable_languages}, in
2015                   *,$language,*)
2016                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2017                     enable_stage1_languages="$enable_stage1_languages,${other}"
2018                     ;;
2019                 esac
2020                 ;;
2021             esac
2022           fi
2023         done
2024         ;;
2025     esac
2026   done
2027
2028   new_enable_languages=,c,
2029
2030   # If LTO is enabled, add the LTO front end.
2031   if test "$enable_lto" = "yes" ; then
2032     case ,${enable_languages}, in
2033       *,lto,*) ;;
2034       *) enable_languages="${enable_languages},lto" ;;
2035     esac
2036     if test "${build_lto_plugin}" = "yes" ; then
2037       configdirs="$configdirs lto-plugin"
2038     fi
2039   fi
2040
2041   # If we're building an offloading compiler, add the LTO front end.
2042   if test x"$enable_as_accelerator_for" != x ; then
2043     case ,${enable_languages}, in
2044       *,lto,*) ;;
2045       *) enable_languages="${enable_languages},lto" ;;
2046     esac
2047   fi
2048
2049   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2050   potential_languages=,c,
2051
2052   enabled_target_libs=
2053   disabled_target_libs=
2054
2055   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2056     case ${lang_frag} in
2057       ..) ;;
2058       # The odd quoting in the next line works around
2059       # an apparent bug in bash 1.12 on linux.
2060       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2061       *)
2062         # From the config-lang.in, get $language, $target_libs,
2063         # $lang_dirs, $boot_language, and $build_by_default
2064         language=
2065         target_libs=
2066         lang_dirs=
2067         subdir_requires=
2068         boot_language=no
2069         build_by_default=yes
2070         # set srcdir during sourcing.  See above about save & restore
2071         saved_srcdir=${srcdir}
2072         srcdir=${srcdir}/gcc . ${lang_frag}
2073         srcdir=${saved_srcdir}
2074         if test x${language} = x; then
2075           echo "${lang_frag} doesn't set \$language." 1>&2
2076           exit 1
2077         fi
2078
2079         if test "$language" = "c++"; then
2080           boot_language=yes
2081         fi
2082
2083         add_this_lang=no
2084         # C is always enabled, so no need to add it again
2085         if test "$language" != "c"; then
2086           case ,${enable_languages}, in
2087             *,${language},*)
2088               # Language was explicitly selected; include it
2089               add_this_lang=yes
2090               ;;
2091             *,all,*)
2092               # All languages are enabled
2093               add_this_lang=all
2094               ;;
2095             *,default,*)
2096               # 'default' was selected, select it if it is a default language
2097               add_this_lang=${build_by_default}
2098               ;;
2099           esac
2100         fi
2101
2102         # Disable languages that need other directories if these aren't available.
2103         for i in $subdir_requires; do
2104           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2105           case ${add_this_lang} in
2106             yes)
2107               # Specifically requested language; tell them.
2108               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2109               ;;
2110             all)
2111               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2112               add_this_lang=unsupported
2113               ;;
2114             *)
2115               # Silently disable.
2116               add_this_lang=unsupported
2117               ;;
2118           esac
2119         done
2120
2121         # Disable Ada if no preexisting GNAT is available.
2122         case ${add_this_lang}:${language}:${have_gnat} in
2123           yes:ada:no)
2124             # Specifically requested language; tell them.
2125             AC_MSG_ERROR([GNAT is required to build $language])
2126             ;;
2127           all:ada:no)
2128             AC_MSG_WARN([GNAT is required to build $language])
2129             add_this_lang=unsupported
2130             ;;
2131           *:ada:no)
2132             # Silently disable.
2133             add_this_lang=unsupported
2134             ;;
2135         esac
2136
2137         # Disable D if no preexisting GDC is available.
2138         case ${add_this_lang}:${language}:${have_gdc} in
2139           yes:d:no)
2140             # Specifically requested language; tell them.
2141             AC_MSG_ERROR([GDC is required to build $language])
2142            ;;
2143           all:d:no)
2144             AC_MSG_WARN([GDC is required to build $language])
2145             add_this_lang=unsupported
2146             ;;
2147           *:d:no)
2148             # Silently disable.
2149             add_this_lang=unsupported
2150             ;;
2151         esac
2152
2153         # Disable Rust for GCC 13 release.
2154         case ${add_this_lang}:${language} in
2155           yes:rust)
2156             # Specifically requested language; tell them.
2157             AC_MSG_ERROR([Rust is not supported in GCC 13 release])
2158            ;;
2159           *:rust)
2160             # Silently disable.
2161             add_this_lang=unsupported
2162             ;;
2163         esac
2164
2165         # Disable jit if -enable-host-shared not specified
2166         # but not if building for Mingw. All code in Windows
2167         # is position independent code (PIC).
2168         case $target in
2169           *mingw*) ;;
2170           *)
2171           case ${add_this_lang}:${language}:${host_shared} in
2172             yes:jit:no)
2173                    # PR jit/64780: explicitly specify --enable-host-shared
2174             AC_MSG_ERROR([
2175 Enabling language "jit" requires --enable-host-shared.
2176
2177 --enable-host-shared typically slows the rest of the compiler down by
2178 a few %, so you must explicitly enable it.
2179
2180 If you want to build both the jit and the regular compiler, it is often
2181 best to do this via two separate configure/builds, in separate
2182 directories, to avoid imposing the performance cost of
2183 --enable-host-shared on the regular compiler.])
2184                     ;;
2185             all:jit:no)
2186               AC_MSG_WARN([--enable-host-shared required to build $language])
2187               add_this_lang=unsupported
2188               ;;
2189             *:jit:no)
2190               # Silently disable.
2191               add_this_lang=unsupported
2192               ;;
2193                 esac
2194           ;;
2195         esac
2196
2197         # Disable a language that is unsupported by the target.
2198         case "${add_this_lang}: $unsupported_languages " in
2199           no:*) ;;
2200           unsupported:*) ;;
2201           *:*" $language "*)
2202             AC_MSG_WARN([${language} not supported for this target])
2203             add_this_lang=unsupported
2204             ;;
2205         esac
2206
2207         case $add_this_lang in
2208           unsupported)
2209             # Remove language-dependent dirs.
2210             disabled_target_libs="$disabled_target_libs $target_libs"
2211             noconfigdirs="$noconfigdirs $lang_dirs"
2212             ;;
2213           no)
2214             # Remove language-dependent dirs; still show language as supported.
2215             disabled_target_libs="$disabled_target_libs $target_libs"
2216             noconfigdirs="$noconfigdirs $lang_dirs"
2217             potential_languages="${potential_languages}${language},"
2218             ;;
2219           all|yes)
2220             new_enable_languages="${new_enable_languages}${language},"
2221             potential_languages="${potential_languages}${language},"
2222             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2223             enabled_target_libs="$enabled_target_libs $target_libs"
2224             case "${boot_language}:,$enable_stage1_languages," in
2225               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2226                 # Add to (comma-separated) list of stage 1 languages.
2227                 case ",$stage1_languages," in
2228                   *,$language,* | ,yes, | ,all,) ;;
2229                   *) stage1_languages="${stage1_languages}${language}," ;;
2230                 esac
2231                 # We need to bootstrap any supporting libraries.
2232                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2233                 ;;
2234             esac
2235             ;;
2236         esac
2237         ;;
2238     esac
2239   done
2240
2241   # Add target libraries which are only needed for disabled languages
2242   # to noconfigdirs.
2243   if test -n "$disabled_target_libs"; then
2244     for dir in $disabled_target_libs; do
2245       case " $enabled_target_libs " in
2246       *" ${dir} "*) ;;
2247       *) noconfigdirs="$noconfigdirs $dir" ;;
2248       esac
2249     done
2250   fi
2251
2252   AC_ARG_ENABLE(stage1-languages,
2253   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2254                   [choose additional languages to build during
2255                   stage1.  Mostly useful for compiler development])],
2256   [case ,${enable_stage1_languages}, in
2257     ,no,|,,)
2258       # Set it to something that will have no effect in the loop below
2259       enable_stage1_languages=c ;;
2260     ,yes,)
2261       enable_stage1_languages=`echo $new_enable_languages | \
2262         sed -e "s/^,//" -e "s/,$//" ` ;;
2263     *,all,*)
2264       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2265         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2266   esac
2267
2268   # Add "good" languages from enable_stage1_languages to stage1_languages,
2269   # while "bad" languages go in missing_languages.  Leave no duplicates.
2270   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2271     case $potential_languages in
2272       *,$i,*)
2273         case $stage1_languages in
2274           *,$i,*) ;;
2275           *) stage1_languages="$stage1_languages$i," ;;
2276         esac ;;
2277       *)
2278         case $missing_languages in
2279           *,$i,*) ;;
2280           *) missing_languages="$missing_languages$i," ;;
2281         esac ;;
2282      esac
2283   done])
2284
2285   # Remove leading/trailing commas that were added for simplicity
2286   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2287   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2288   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2289   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2290
2291   if test "x$missing_languages" != x; then
2292     AC_MSG_ERROR([
2293 The following requested languages could not be built: ${missing_languages}
2294 Supported languages are: ${potential_languages}])
2295   fi
2296   if test "x$new_enable_languages" != "x$enable_languages"; then
2297     echo The following languages will be built: ${new_enable_languages}
2298     enable_languages="$new_enable_languages"
2299   fi
2300
2301   AC_SUBST(stage1_languages)
2302   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2303 fi
2304
2305 # Handle --disable-<component> generically.
2306 for dir in $configdirs $build_configdirs $target_configdirs ; do
2307   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2308   varname=`echo $dirname | sed -e s/+/_/g`
2309   if eval test x\${enable_${varname}} "=" xno ; then
2310     noconfigdirs="$noconfigdirs $dir"
2311   fi
2312 done
2313
2314 # Check for Boehm's garbage collector
2315 AC_ARG_ENABLE(objc-gc,
2316 [AS_HELP_STRING([--enable-objc-gc],
2317                 [enable use of Boehm's garbage collector with the
2318                  GNU Objective-C runtime])])
2319 AC_ARG_WITH([target-bdw-gc],
2320 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2321                 [specify prefix directory for installed bdw-gc package.
2322                  Equivalent to --with-target-bdw-gc-include=PATH/include
2323                  plus --with-target-bdw-gc-lib=PATH/lib])])
2324 AC_ARG_WITH([target-bdw-gc-include],
2325 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2326                 [specify directories for installed bdw-gc include files])])
2327 AC_ARG_WITH([target-bdw-gc-lib],
2328 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2329                 [specify directories for installed bdw-gc library])])
2330
2331 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2332   AC_MSG_CHECKING([for bdw garbage collector])
2333   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2334     dnl no bdw-gw options, assume default locations
2335     AC_MSG_RESULT([using bdw-gc in default locations])
2336   else
2337     dnl bdw-gw options, first error checking, complete checking in libobjc
2338     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2339       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2340     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2341       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2342     else
2343       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2344     fi
2345   fi
2346 esac
2347
2348 # Disable libitm, libsanitizer, libvtv if we're not building C++
2349 case ,${enable_languages}, in
2350   *,c++,*)
2351     # Disable libitm, libsanitizer if we're not building libstdc++
2352     case "${noconfigdirs}" in
2353       *target-libstdc++-v3*)
2354         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2355         ;;
2356       *) ;;
2357     esac
2358     ;;
2359   *)
2360     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2361     ;;
2362 esac
2363
2364 # If gcc/ is not in the source tree then we'll not be building a
2365 # target compiler, assume in that case we don't want to build any
2366 # target libraries or tools.
2367 #
2368 # This was added primarily for the benefit for binutils-gdb who reuse
2369 # this configure script, but don't always have target tools available.
2370 if test ! -d ${srcdir}/gcc; then
2371    skipdirs="${skipdirs} ${target_configdirs}"
2372 fi
2373
2374 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2375 # $build_configdirs and $target_configdirs.
2376 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2377
2378 notsupp=""
2379 for dir in . $skipdirs $noconfigdirs ; do
2380   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2381   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2382     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2383     if test -r $srcdir/$dirname/configure ; then
2384       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2385         true
2386       else
2387         notsupp="$notsupp $dir"
2388       fi
2389     fi
2390   fi
2391   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2392     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2393     if test -r $srcdir/$dirname/configure ; then
2394       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2395         true
2396       else
2397         notsupp="$notsupp $dir"
2398       fi
2399     fi
2400   fi
2401   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2402     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2403     if test -r $srcdir/$dirname/configure ; then
2404       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2405         true
2406       else
2407         notsupp="$notsupp $dir"
2408       fi
2409     fi
2410   fi
2411 done
2412
2413 # Quietly strip out all directories which aren't configurable in this tree.
2414 # This relies on all configurable subdirectories being autoconfiscated, which
2415 # is now the case.
2416 build_configdirs_all="$build_configdirs"
2417 build_configdirs=
2418 for i in ${build_configdirs_all} ; do
2419   j=`echo $i | sed -e s/build-//g`
2420   if test -f ${srcdir}/$j/configure ; then
2421     build_configdirs="${build_configdirs} $i"
2422   fi
2423 done
2424
2425 configdirs_all="$configdirs"
2426 configdirs=
2427 for i in ${configdirs_all} ; do
2428   if test -f ${srcdir}/$i/configure ; then
2429     configdirs="${configdirs} $i"
2430   fi
2431 done
2432
2433 target_configdirs_all="$target_configdirs"
2434 target_configdirs=
2435 for i in ${target_configdirs_all} ; do
2436   j=`echo $i | sed -e s/target-//g`
2437   if test -f ${srcdir}/$j/configure ; then
2438     target_configdirs="${target_configdirs} $i"
2439   fi
2440 done
2441
2442 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2443 # so we have to add it after the preceding checks.
2444 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2445 then
2446   case " $configdirs " in
2447     *" libiberty "*)
2448       # If we can build libiberty, we can also build libiberty-linker-plugin.
2449       configdirs="$configdirs libiberty-linker-plugin"
2450       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2451         --with-libiberty=../libiberty-linker-plugin";;
2452     *)
2453       AC_MSG_ERROR([libiberty missing]);;
2454   esac
2455 fi
2456
2457 # Sometimes we have special requirements for the host libiberty.
2458 extra_host_libiberty_configure_flags=
2459 case " $configdirs " in
2460   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2461     # When these are to be built as shared libraries, the same applies to
2462     # libiberty.
2463     extra_host_libiberty_configure_flags=--enable-shared
2464     ;;
2465 esac
2466 AC_SUBST(extra_host_libiberty_configure_flags)
2467
2468 # Sometimes we have special requirements for the host zlib.
2469 extra_host_zlib_configure_flags=
2470 case " $configdirs " in
2471   *" bfd "*)
2472     # When bfd is to be built as a shared library, the same applies to
2473     # zlib.
2474     if test "$enable_shared" = "yes"; then
2475       extra_host_zlib_configure_flags=--enable-host-shared
2476     fi
2477     ;;
2478 esac
2479 AC_SUBST(extra_host_zlib_configure_flags)
2480
2481 # Produce a warning message for the subdirs we can't configure.
2482 # This isn't especially interesting in the Cygnus tree, but in the individual
2483 # FSF releases, it's important to let people know when their machine isn't
2484 # supported by the one or two programs in a package.
2485
2486 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2487   # If $appdirs is non-empty, at least one of those directories must still
2488   # be configured, or we error out.  (E.g., if the gas release supports a
2489   # specified target in some subdirs but not the gas subdir, we shouldn't
2490   # pretend that all is well.)
2491   if test -n "$appdirs" ; then
2492     for dir in $appdirs ; do
2493       if test -r $dir/Makefile.in ; then
2494         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2495           appdirs=""
2496           break
2497         fi
2498         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2499           appdirs=""
2500           break
2501         fi
2502       fi
2503     done
2504     if test -n "$appdirs" ; then
2505       echo "*** This configuration is not supported by this package." 1>&2
2506       exit 1
2507     fi
2508   fi
2509   # Okay, some application will build, or we don't care to check.  Still
2510   # notify of subdirs not getting built.
2511   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2512   echo "    ${notsupp}" 1>&2
2513   echo "    (Any other directories should still work fine.)" 1>&2
2514 fi
2515
2516 case "$host" in
2517   *msdosdjgpp*)
2518     enable_gdbtk=no ;;
2519 esac
2520
2521 # To find our prefix, in gcc_cv_tool_prefix.
2522 ACX_TOOL_DIRS
2523
2524 copy_dirs=
2525
2526 AC_ARG_WITH([build-sysroot],
2527   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2528                   [use sysroot as the system root during the build])],
2529   [if test x"$withval" != x ; then
2530      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2531    fi],
2532   [SYSROOT_CFLAGS_FOR_TARGET=])
2533 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2534
2535 AC_ARG_WITH([debug-prefix-map],
2536   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2537                   [map A to B, C to D ... in debug information])],
2538   [if test x"$withval" != x; then
2539      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2540      for debug_map in $withval; do
2541        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2542      done
2543    fi],
2544   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2545 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2546
2547 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2548 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2549 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2550 # We want to ensure that TARGET libraries (which we know are built with
2551 # gcc) are built with "-O2 -g", so include those options when setting
2552 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2553 if test "x$CFLAGS_FOR_TARGET" = x; then
2554   if test "x${is_cross_compiler}" = xyes; then
2555     CFLAGS_FOR_TARGET="-g -O2"
2556   else
2557     CFLAGS_FOR_TARGET=$CFLAGS
2558     case " $CFLAGS " in
2559       *" -O2 "*) ;;
2560       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2561     esac
2562     case " $CFLAGS " in
2563       *" -g "* | *" -g3 "*) ;;
2564       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2565     esac
2566   fi
2567 fi
2568 AC_SUBST(CFLAGS_FOR_TARGET)
2569
2570 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2571   if test "x${is_cross_compiler}" = xyes; then
2572     CXXFLAGS_FOR_TARGET="-g -O2"
2573   else
2574     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2575     case " $CXXFLAGS " in
2576       *" -O2 "*) ;;
2577       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2578     esac
2579     case " $CXXFLAGS " in
2580       *" -g "* | *" -g3 "*) ;;
2581       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2582     esac
2583   fi
2584 fi
2585 AC_SUBST(CXXFLAGS_FOR_TARGET)
2586
2587 AC_SUBST(LDFLAGS_FOR_TARGET)
2588
2589 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2590 # the named directory are copied to $(tooldir)/sys-include.
2591 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2592   if test x${is_cross_compiler} = xno ; then
2593     echo 1>&2 '***' --with-headers is only supported when cross compiling
2594     exit 1
2595   fi
2596   if test x"${with_headers}" != xyes ; then
2597     x=${gcc_cv_tool_prefix}
2598     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2599   fi
2600 fi
2601
2602 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2603 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2604 # are permitted.
2605 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2606   if test x${is_cross_compiler} = xno ; then
2607     echo 1>&2 '***' --with-libs is only supported when cross compiling
2608     exit 1
2609   fi
2610   if test x"${with_libs}" != xyes ; then
2611     # Copy the libraries in reverse order, so that files in the first named
2612     # library override files in subsequent libraries.
2613     x=${gcc_cv_tool_prefix}
2614     for l in ${with_libs}; do
2615       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2616     done
2617   fi
2618 fi
2619
2620 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2621 #
2622 # This is done by determining whether or not the appropriate directory
2623 # is available, and by checking whether or not specific configurations
2624 # have requested that this magic not happen.
2625 #
2626 # The command line options always override the explicit settings in
2627 # configure.ac, and the settings in configure.ac override this magic.
2628 #
2629 # If the default for a toolchain is to use GNU as and ld, and you don't
2630 # want to do that, then you should use the --without-gnu-as and
2631 # --without-gnu-ld options for the configure script.  Similarly, if
2632 # the default is to use the included zlib and you don't want to do that,
2633 # you should use the --with-system-zlib option for the configure script.
2634
2635 if test x${use_gnu_as} = x &&
2636    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2637   with_gnu_as=yes
2638   extra_host_args="$extra_host_args --with-gnu-as"
2639 fi
2640
2641 if test x${use_gnu_ld} = x &&
2642    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2643   with_gnu_ld=yes
2644   extra_host_args="$extra_host_args --with-gnu-ld"
2645 fi
2646
2647 if test x${use_included_zlib} = x &&
2648    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2649   :
2650 else
2651   with_system_zlib=yes
2652   extra_host_args="$extra_host_args --with-system-zlib"
2653 fi
2654
2655 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2656 # can detect this case.
2657
2658 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2659   with_newlib=yes
2660   extra_host_args="$extra_host_args --with-newlib"
2661 fi
2662
2663 # Handle ${copy_dirs}
2664 set fnord ${copy_dirs}
2665 shift
2666 while test $# != 0 ; do
2667   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2668     :
2669   else
2670     echo Copying $1 to $2
2671
2672     # Use the install script to create the directory and all required
2673     # parent directories.
2674     if test -d $2 ; then
2675       :
2676     else
2677       echo >config.temp
2678       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2679     fi
2680
2681     # Copy the directory, assuming we have tar.
2682     # FIXME: Should we use B in the second tar?  Not all systems support it.
2683     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2684
2685     # It is the responsibility of the user to correctly adjust all
2686     # symlinks.  If somebody can figure out how to handle them correctly
2687     # here, feel free to add the code.
2688
2689     echo $1 > $2/COPIED
2690   fi
2691   shift; shift
2692 done
2693
2694 # Determine a target-dependent exec_prefix that the installed
2695 # gcc will search in.  Keep this list sorted by triplet, with
2696 # the *-*-osname triplets last.
2697 md_exec_prefix=
2698 case "${target}" in
2699   i[[34567]]86-pc-msdosdjgpp*)
2700     md_exec_prefix=/dev/env/DJDIR/bin
2701     ;;
2702   *-*-hpux* | \
2703   *-*-nto-qnx* | \
2704   *-*-solaris2*)
2705     md_exec_prefix=/usr/ccs/bin
2706     ;;
2707 esac
2708
2709 extra_arflags_for_target=
2710 extra_nmflags_for_target=
2711 extra_ranlibflags_for_target=
2712 target_makefile_frag=/dev/null
2713 case "${target}" in
2714   spu-*-*)
2715     target_makefile_frag="config/mt-spu"
2716     ;;
2717   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2718     target_makefile_frag="config/mt-sde"
2719     ;;
2720   mipsisa*-*-elfoabi*)
2721     target_makefile_frag="config/mt-mips-elfoabi"
2722     ;;
2723   mips*-*-*linux* | mips*-*-gnu*)
2724     target_makefile_frag="config/mt-mips-gnu"
2725     ;;
2726   nios2-*-elf*)
2727     target_makefile_frag="config/mt-nios2-elf"
2728     ;;
2729   *-*-linux-android*)
2730     target_makefile_frag="config/mt-android"
2731     ;;
2732   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2733     target_makefile_frag="config/mt-gnu"
2734     ;;
2735   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2736     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2737     # commands to handle both 32-bit and 64-bit objects.  These flags are
2738     # harmless if we're using GNU nm or ar.
2739     extra_arflags_for_target=" -X32_64"
2740     extra_nmflags_for_target=" -B -X32_64"
2741     ;;
2742 esac
2743
2744 alphaieee_frag=/dev/null
2745 case $target in
2746   alpha*-*-*)
2747     # This just makes sure to use the -mieee option to build target libs.
2748     # This should probably be set individually by each library.
2749     alphaieee_frag="config/mt-alphaieee"
2750     ;;
2751 esac
2752
2753 # If --enable-target-optspace always use -Os instead of -O2 to build
2754 # the target libraries, similarly if it is not specified, use -Os
2755 # on selected platforms.
2756 ospace_frag=/dev/null
2757 case "${enable_target_optspace}:${target}" in
2758   yes:*)
2759     ospace_frag="config/mt-ospace"
2760     ;;
2761   :d30v-*)
2762     ospace_frag="config/mt-d30v"
2763     ;;
2764   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2765     ospace_frag="config/mt-ospace"
2766     ;;
2767   no:* | :*)
2768     ;;
2769   *)
2770     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2771     ;;
2772 esac
2773
2774 # Some systems (e.g., one of the i386-aix systems the gas testers are
2775 # using) don't handle "\$" correctly, so don't use it here.
2776 tooldir='${exec_prefix}'/${target_noncanonical}
2777 build_tooldir=${tooldir}
2778
2779 # Create a .gdbinit file which runs the one in srcdir
2780 # and tells GDB to look there for source files.
2781
2782 if test -r ${srcdir}/.gdbinit ; then
2783   case ${srcdir} in
2784     .) ;;
2785     *) cat > ./.gdbinit <<EOF
2786 # ${NO_EDIT}
2787 dir ${srcdir}
2788 dir .
2789 source ${srcdir}/.gdbinit
2790 EOF
2791     ;;
2792   esac
2793 fi
2794
2795 # Make sure that the compiler is able to generate an executable.  If it
2796 # can't, we are probably in trouble.  We don't care whether we can run the
2797 # executable--we might be using a cross compiler--we only care whether it
2798 # can be created.  At this point the main configure script has set CC.
2799 we_are_ok=no
2800 echo "int main () { return 0; }" > conftest.c
2801 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2802 if test $? = 0 ; then
2803   if test -s conftest || test -s conftest.exe ; then
2804     we_are_ok=yes
2805   fi
2806 fi
2807 case $we_are_ok in
2808   no)
2809     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2810     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2811     rm -f conftest*
2812     exit 1
2813     ;;
2814 esac
2815 rm -f conftest*
2816
2817 # Decide which environment variable is used to find dynamic libraries.
2818 case "${host}" in
2819   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2820   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2821   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2822   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2823 esac
2824
2825 # On systems where the dynamic library environment variable is PATH,
2826 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2827 # built executables to PATH.
2828 if test "$RPATH_ENVVAR" = PATH; then
2829   GCC_SHLIB_SUBDIR=/shlib
2830 else
2831   GCC_SHLIB_SUBDIR=
2832 fi
2833
2834 # Adjust the toplevel makefile according to whether bootstrap was selected.
2835 case $enable_bootstrap in
2836   yes)
2837     bootstrap_suffix=bootstrap
2838     BUILD_CONFIG=bootstrap-debug
2839     ;;
2840   no)
2841     bootstrap_suffix=no-bootstrap
2842     BUILD_CONFIG=
2843     ;;
2844 esac
2845
2846 AC_MSG_CHECKING(for default BUILD_CONFIG)
2847
2848 AC_ARG_WITH([build-config],
2849   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2850                   [use config/NAME.mk build configuration])],
2851   [case $with_build_config in
2852    yes) with_build_config= ;;
2853    no) with_build_config= BUILD_CONFIG= ;;
2854    esac])
2855
2856 if test "x${with_build_config}" != x; then
2857   BUILD_CONFIG=$with_build_config
2858 else
2859   case $BUILD_CONFIG in
2860   bootstrap-debug)
2861     if echo "int f (void) { return 0; }" > conftest.c &&
2862        ${CC} -c conftest.c &&
2863        mv conftest.o conftest.o.g0 &&
2864        ${CC} -c -g conftest.c &&
2865        mv conftest.o conftest.o.g &&
2866        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2867       :
2868     else
2869       BUILD_CONFIG=
2870     fi
2871     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2872     ;;
2873   esac
2874 fi
2875 AC_MSG_RESULT($BUILD_CONFIG)
2876 AC_SUBST(BUILD_CONFIG)
2877
2878 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2879 AC_MSG_CHECKING([for --enable-vtable-verify])
2880 AC_ARG_ENABLE(vtable-verify,
2881 [AS_HELP_STRING([--enable-vtable-verify],
2882                 [Enable vtable verification feature])],
2883 [case "$enableval" in
2884  yes) enable_vtable_verify=yes ;;
2885  no)  enable_vtable_verify=no ;;
2886  *)   enable_vtable_verify=no;;
2887  esac],
2888 [enable_vtable_verify=no])
2889 AC_MSG_RESULT($enable_vtable_verify)
2890
2891 # Record target_configdirs and the configure arguments for target and
2892 # build configuration in Makefile.
2893 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2894 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2895 bootstrap_fixincludes=no
2896
2897 # If we are building libgomp, bootstrap it.
2898 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2899   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2900 fi
2901
2902 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2903 # or bootstrap-ubsan, bootstrap it.
2904 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2905   case "$BUILD_CONFIG" in
2906     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2907       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2908       bootstrap_fixincludes=yes
2909       ;;
2910   esac
2911 fi
2912
2913 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2914 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2915    test "$enable_vtable_verify" != no; then
2916   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2917 fi
2918
2919 # If we are building libatomic and the list of enabled languages includes the
2920 # D frontend, bootstrap it.
2921 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2922   case ,${enable_languages}, in
2923     *,d,*)
2924       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2925       ;;
2926   esac
2927 fi
2928
2929 # Determine whether gdb needs tk/tcl or not.
2930 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2931 # and in that case we want gdb to be built without tk.  Ugh!
2932 # In fact I believe gdb is the *only* package directly dependent on tk,
2933 # so we should be able to put the 'maybe's in unconditionally and
2934 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2935 # 100% sure that that's safe though.
2936
2937 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2938 case "$enable_gdbtk" in
2939   no)
2940     GDB_TK="" ;;
2941   yes)
2942     GDB_TK="${gdb_tk}" ;;
2943   *)
2944     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2945     # distro.  Eventually someone will fix this and move Insight, nee
2946     # gdbtk to a separate directory.
2947     if test -d ${srcdir}/gdb/gdbtk ; then
2948       GDB_TK="${gdb_tk}"
2949     else
2950       GDB_TK=""
2951     fi
2952     ;;
2953 esac
2954 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2955 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2956
2957 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2958 # else does, only include them if one of these is built.  The Makefile
2959 # provides the ordering, so it's enough here to add to the list.
2960 case " ${configdirs} " in
2961   *\ gdb\ *)
2962     configdirs="${configdirs} gnulib gdbsupport"
2963     ;;
2964   *\ gdbserver\ *)
2965     configdirs="${configdirs} gnulib gdbsupport"
2966     ;;
2967   *\ sim\ *)
2968     configdirs="${configdirs} gnulib"
2969     ;;
2970 esac
2971
2972 # Strip out unwanted targets.
2973
2974 # While at that, we remove Makefiles if we were started for recursive
2975 # configuration, so that the top-level Makefile reconfigures them,
2976 # like we used to do when configure itself was recursive.
2977
2978 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2979 # but now we're fixing up the Makefile ourselves with the additional
2980 # commands passed to AC_CONFIG_FILES.  Use separate variables
2981 # extrasub-{build,host,target} not because there is any reason to split
2982 # the substitutions up that way, but only to remain below the limit of
2983 # 99 commands in a script, for HP-UX sed.
2984
2985 # Do not nest @if/@endif or @unless/@endunless pairs, because
2986 # configure will not warn you at all.
2987
2988 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2989   yes:yes:*\ gold\ *:*,c++,*) ;;
2990   yes:yes:*\ gold\ *:*)
2991     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2992     ;;
2993 esac
2994
2995 extrasub_build=
2996 for module in ${build_configdirs} ; do
2997   if test -z "${no_recursion}" \
2998      && test -f ${build_subdir}/${module}/Makefile; then
2999     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3000     rm -f ${build_subdir}/${module}/Makefile
3001   fi
3002   extrasub_build="$extrasub_build
3003 /^@if build-$module\$/d
3004 /^@endif build-$module\$/d
3005 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3006 /^@if build-$module-$bootstrap_suffix\$/d
3007 /^@endif build-$module-$bootstrap_suffix\$/d
3008 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3009 done
3010 extrasub_host=
3011 for module in ${configdirs} ; do
3012   if test -z "${no_recursion}"; then
3013     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3014       if test -f ${file}; then
3015         echo 1>&2 "*** removing ${file} to force reconfigure"
3016         rm -f ${file}
3017       fi
3018     done
3019   fi
3020   case ${module},${bootstrap_fixincludes} in
3021     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3022     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3023   esac
3024   extrasub_host="$extrasub_host
3025 /^@if $module\$/d
3026 /^@endif $module\$/d
3027 /^@unless $module\$/,/^@endunless $module\$/d
3028 /^@if $module-$host_bootstrap_suffix\$/d
3029 /^@endif $module-$host_bootstrap_suffix\$/d
3030 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3031 done
3032 extrasub_target=
3033 for module in ${target_configdirs} ; do
3034   if test -z "${no_recursion}" \
3035      && test -f ${target_subdir}/${module}/Makefile; then
3036     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3037     rm -f ${target_subdir}/${module}/Makefile
3038   fi
3039
3040   # We only bootstrap target libraries listed in bootstrap_target_libs.
3041   case $bootstrap_target_libs in
3042     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3043     *) target_bootstrap_suffix=no-bootstrap ;;
3044   esac
3045
3046   extrasub_target="$extrasub_target
3047 /^@if target-$module\$/d
3048 /^@endif target-$module\$/d
3049 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3050 /^@if target-$module-$target_bootstrap_suffix\$/d
3051 /^@endif target-$module-$target_bootstrap_suffix\$/d
3052 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3053 done
3054
3055 # Do the final fixup along with target modules.
3056 extrasub_target="$extrasub_target
3057 /^@if /,/^@endif /d
3058 /^@unless /d
3059 /^@endunless /d"
3060
3061 if test "$enable_pgo_build" != "no"; then
3062   extrasub_build="$extrasub_build
3063 /^@if pgo-build\$/d
3064 /^@endif pgo-build\$/d"
3065 fi
3066
3067 # Create the serialization dependencies.  This uses a temporary file.
3068
3069 AC_ARG_ENABLE([serial-configure],
3070 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3071                 [force sequential configuration of
3072                  sub-packages for the host, target or build
3073                  machine, or all sub-packages])])
3074
3075 case ${enable_serial_configure} in
3076   yes)
3077     enable_serial_build_configure=yes
3078     enable_serial_host_configure=yes
3079     enable_serial_target_configure=yes
3080     ;;
3081 esac
3082
3083 # These force 'configure's to be done one at a time, to avoid problems
3084 # with contention over a shared config.cache.
3085 rm -f serdep.tmp
3086 echo '# serdep.tmp' > serdep.tmp
3087 olditem=
3088 test "x${enable_serial_build_configure}" = xyes &&
3089 for item in ${build_configdirs} ; do
3090   case ${olditem} in
3091     "") ;;
3092     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3093   esac
3094   olditem=${item}
3095 done
3096 olditem=
3097 test "x${enable_serial_host_configure}" = xyes &&
3098 for item in ${configdirs} ; do
3099   case ${olditem} in
3100     "") ;;
3101     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3102   esac
3103   olditem=${item}
3104 done
3105 olditem=
3106 test "x${enable_serial_target_configure}" = xyes &&
3107 for item in ${target_configdirs} ; do
3108   case ${olditem} in
3109     "") ;;
3110     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3111   esac
3112   olditem=${item}
3113 done
3114 serialization_dependencies=serdep.tmp
3115 AC_SUBST_FILE(serialization_dependencies)
3116
3117 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3118 # target, nonopt, and variable assignments.  These are the ones we
3119 # might not want to pass down to subconfigures.  The exception being
3120 # --cache-file=/dev/null, which is used to turn off the use of cache
3121 # files altogether, and which should be passed on to subconfigures.
3122 # Also strip program-prefix, program-suffix, and program-transform-name,
3123 # so that we can pass down a consistent program-transform-name.
3124 baseargs=
3125 tbaseargs=
3126 keep_next=no
3127 skip_next=no
3128 eval "set -- $ac_configure_args"
3129 for ac_arg
3130 do
3131   if test X"$skip_next" = X"yes"; then
3132     skip_next=no
3133     continue
3134   fi
3135   if test X"$keep_next" = X"yes"; then
3136     case $ac_arg in
3137       *\'*)
3138         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3139     esac
3140     baseargs="$baseargs '$ac_arg'"
3141     tbaseargs="$tbaseargs '$ac_arg'"
3142     keep_next=no
3143     continue
3144   fi
3145
3146   # Handle separated arguments.  Based on the logic generated by
3147   # autoconf 2.59.
3148   case $ac_arg in
3149     *=* | --config-cache | -C | -disable-* | --disable-* \
3150       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3151       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3152       | -with-* | --with-* | -without-* | --without-* | --x)
3153       separate_arg=no
3154       ;;
3155     -*)
3156       separate_arg=yes
3157       ;;
3158     *)
3159       separate_arg=no
3160       ;;
3161   esac
3162
3163   skip_targ=no
3164   case $ac_arg in
3165 changequote(,)
3166   --with-* | --without-*)
3167     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3168
3169     case $libopt in
3170     *[-_]include)
3171       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3172       ;;
3173     *[-_]lib)
3174       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3175       ;;
3176     *)
3177       lib=$libopt
3178       ;;
3179     esac
3180 changequote([,])
3181
3182     case $lib in
3183     mpc | mpfr | gmp | isl)
3184       # If we're processing --with-$lib, --with-$lib-include or
3185       # --with-$lib-lib, for one of the libs above, and target is
3186       # different from host, don't pass the current argument to any
3187       # target library's configure.
3188       if test x$is_cross_compiler = xyes; then
3189         skip_targ=yes
3190       fi
3191       ;;
3192     esac
3193     ;;
3194   esac
3195
3196   case "$ac_arg" in
3197     --cache-file=/dev/null | \
3198     -cache-file=/dev/null )
3199       # Handled here to avoid the test to skip args below.
3200       baseargs="$baseargs '$ac_arg'"
3201       tbaseargs="$tbaseargs '$ac_arg'"
3202       # Assert: $separate_arg should always be no.
3203       keep_next=$separate_arg
3204       ;;
3205     --no*)
3206       continue
3207       ;;
3208     --c* | \
3209     --sr* | \
3210     --ho* | \
3211     --bu* | \
3212     --t* | \
3213     --program-* | \
3214     -cache_file* | \
3215     -srcdir* | \
3216     -host* | \
3217     -build* | \
3218     -target* | \
3219     -program-prefix* | \
3220     -program-suffix* | \
3221     -program-transform-name* )
3222       skip_next=$separate_arg
3223       continue
3224       ;;
3225     -*)
3226       # An option.  Add it.
3227       case $ac_arg in
3228         *\'*)
3229           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3230       esac
3231       baseargs="$baseargs '$ac_arg'"
3232       if test X"$skip_targ" = Xno; then
3233         tbaseargs="$tbaseargs '$ac_arg'"
3234       fi
3235       keep_next=$separate_arg
3236       ;;
3237     *)
3238       # Either a variable assignment, or a nonopt (triplet).  Don't
3239       # pass it down; let the Makefile handle this.
3240       continue
3241       ;;
3242   esac
3243 done
3244 # Remove the initial space we just introduced and, as these will be
3245 # expanded by make, quote '$'.
3246 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3247
3248 # Add in --program-transform-name, after --program-prefix and
3249 # --program-suffix have been applied to it.  Autoconf has already
3250 # doubled dollar signs and backslashes in program_transform_name; we want
3251 # the backslashes un-doubled, and then the entire thing wrapped in single
3252 # quotes, because this will be expanded first by make and then by the shell.
3253 # Also, because we want to override the logic in subdir configure scripts to
3254 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3255 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3256 ${program_transform_name}
3257 EOF_SED
3258 gcc_transform_name=`cat conftestsed.out`
3259 rm -f conftestsed.out
3260 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3261 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3262 if test "$silent" = yes; then
3263   baseargs="$baseargs --silent"
3264   tbaseargs="$tbaseargs --silent"
3265 fi
3266 baseargs="$baseargs --disable-option-checking"
3267 tbaseargs="$tbaseargs --disable-option-checking"
3268
3269 # Record and document user additions to sub configure arguments.
3270 AC_ARG_VAR([build_configargs],
3271            [additional configure arguments for build directories])
3272 AC_ARG_VAR([host_configargs],
3273            [additional configure arguments for host directories])
3274 AC_ARG_VAR([target_configargs],
3275            [additional configure arguments for target directories])
3276
3277 # For the build-side libraries, we just need to pretend we're native,
3278 # and not use the same cache file.  Multilibs are neither needed nor
3279 # desired.  We can't even use the same cache file for all build-side
3280 # libraries, as they're compiled differently; some with C, some with
3281 # C++ or with different feature-enabling options.
3282 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3283
3284 # For host modules, accept cache file option, or specification as blank.
3285 case "${cache_file}" in
3286 "") # empty
3287   cache_file_option="" ;;
3288 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3289   cache_file_option="--cache-file=${cache_file}" ;;
3290 *) # relative path
3291   cache_file_option="--cache-file=../${cache_file}" ;;
3292 esac
3293
3294 # Host dirs don't like to share a cache file either, horribly enough.
3295 # This seems to be due to autoconf 2.5x stupidity.
3296 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3297
3298 target_configargs="$target_configargs ${tbaseargs}"
3299
3300 # Passing a --with-cross-host argument lets the target libraries know
3301 # whether they are being built with a cross-compiler or being built
3302 # native.  However, it would be better to use other mechanisms to make the
3303 # sorts of decisions they want to make on this basis.  Please consider
3304 # this option to be deprecated.  FIXME.
3305 if test x${is_cross_compiler} = xyes ; then
3306   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3307 fi
3308
3309 # Special user-friendly check for native x86_64-linux build, if
3310 # multilib is not explicitly enabled.
3311 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3312   x86_64-*linux*:yes:$build:$build:)
3313     # Make sure we have a development environment that handles 32-bit
3314     dev64=no
3315     echo "int main () { return 0; }" > conftest.c
3316     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3317     if test $? = 0 ; then
3318       if test -s conftest || test -s conftest.exe ; then
3319         dev64=yes
3320       fi
3321     fi
3322     rm -f conftest*
3323     if test x${dev64} != xyes ; then
3324       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3325     fi
3326     ;;
3327 esac
3328
3329 # Default to --enable-multilib.
3330 if test x${enable_multilib} = x ; then
3331   target_configargs="--enable-multilib ${target_configargs}"
3332 fi
3333
3334 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3335 # changed from the earlier setting of with_newlib.
3336 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3337   target_configargs="--with-newlib ${target_configargs}"
3338 fi
3339
3340 # Different target subdirs use different values of certain variables
3341 # (notably CXX).  Worse, multilibs use *lots* of different values.
3342 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3343 # it doesn't automatically accept command-line overrides of them.
3344 # This means it's not safe for target subdirs to share a cache file,
3345 # which is disgusting, but there you have it.  Hopefully this can be
3346 # fixed in future.  It's still worthwhile to use a cache file for each
3347 # directory.  I think.
3348
3349 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3350 # We need to pass --target, as newer autoconf's requires consistency
3351 # for target_alias and gcc doesn't manage it consistently.
3352 target_configargs="--cache-file=./config.cache ${target_configargs}"
3353
3354 FLAGS_FOR_TARGET=
3355 case " $target_configdirs " in
3356  *" newlib "*)
3357   case " $target_configargs " in
3358   *" --with-newlib "*)
3359    case "$target" in
3360     *-cygwin*)
3361       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3362       ;;
3363    esac
3364
3365    # If we're not building GCC, don't discard standard headers.
3366    if test -d ${srcdir}/gcc; then
3367      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3368
3369      if test "${build}" != "${host}"; then
3370        # On Canadian crosses, CC_FOR_TARGET will have already been set
3371        # by `configure', so we won't have an opportunity to add -Bgcc/
3372        # to it.  This is right: we don't want to search that directory
3373        # for binaries, but we want the header files in there, so add
3374        # them explicitly.
3375        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3376
3377        # Someone might think of using the pre-installed headers on
3378        # Canadian crosses, in case the installed compiler is not fully
3379        # compatible with the compiler being built.  In this case, it
3380        # would be better to flag an error than risking having
3381        # incompatible object files being constructed.  We can't
3382        # guarantee that an error will be flagged, but let's hope the
3383        # compiler will do it, when presented with incompatible header
3384        # files.
3385      fi
3386    fi
3387
3388    case "${target}-${is_cross_compiler}" in
3389    i[[3456789]]86-*-linux*-no)
3390       # Here host == target, so we don't need to build gcc,
3391       # so we don't want to discard standard headers.
3392       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3393       ;;
3394    *)
3395       # If we're building newlib, use its generic headers last, but search
3396       # for any libc-related directories first (so make it the last -B
3397       # switch).
3398       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3399
3400       # If we're building libgloss, find the startup file, simulator library
3401       # and linker script.
3402       case " $target_configdirs " in
3403         *" libgloss "*)
3404         # Look for startup file, simulator library and maybe linker script.
3405         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3406         # Look for libnosys.a in case the target needs it.
3407         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3408         # Most targets have the linker script in the source directory.
3409         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3410         ;;
3411       esac
3412       ;;
3413    esac
3414    ;;
3415   esac
3416   ;;
3417 esac
3418
3419 case "$target" in
3420   x86_64-*mingw* | *-w64-mingw*)
3421   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3422   # however, use a symlink named 'mingw' in ${prefix} .
3423     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3424     ;;
3425   *-mingw*)
3426   # MinGW can't be handled as Cygwin above since it does not use newlib.
3427     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3428     ;;
3429 esac
3430
3431 # Allow the user to override the flags for
3432 # our build compiler if desired.
3433 if test x"${build}" = x"${host}" ; then
3434   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3435   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3436   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3437   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3438 fi
3439
3440 # On Canadian crosses, we'll be searching the right directories for
3441 # the previously-installed cross compiler, so don't bother to add
3442 # flags for directories within the install tree of the compiler
3443 # being built; programs in there won't even run.
3444 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3445   # Search for pre-installed headers if nothing else fits.
3446   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3447 fi
3448
3449 if test "x${use_gnu_ld}" = x &&
3450    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3451   # Arrange for us to find uninstalled linker scripts.
3452   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3453 fi
3454
3455 # Search for other target-specific linker scripts and such.
3456 case "${target}" in
3457   mep*)
3458     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3459     ;;
3460   # The VxWorks support for shared libraries is getting in
3461   # incrementally.  Make sure it doesn't get activated implicitly:
3462   *vxworks*)
3463     if test "${enable_shared-unset}" = unset ; then
3464       enable_shared=no
3465       # So the build of libraries knows ...
3466       target_configargs="${target_configargs} --disable-shared"
3467       # So gcc knows ...
3468       host_configargs="${host_configargs} --disable-shared"
3469     fi
3470     ;;
3471 esac
3472
3473 # Makefile fragments.
3474 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3475 do
3476   eval fragval=\$$frag
3477   if test $fragval != /dev/null; then
3478     eval $frag=${srcdir}/$fragval
3479   fi
3480 done
3481 AC_SUBST_FILE(host_makefile_frag)
3482 AC_SUBST_FILE(target_makefile_frag)
3483 AC_SUBST_FILE(alphaieee_frag)
3484 AC_SUBST_FILE(ospace_frag)
3485
3486 # Miscellanea: directories, flags, etc.
3487 AC_SUBST(RPATH_ENVVAR)
3488 AC_SUBST(GCC_SHLIB_SUBDIR)
3489 AC_SUBST(tooldir)
3490 AC_SUBST(build_tooldir)
3491 AC_SUBST(CONFIGURE_GDB_TK)
3492 AC_SUBST(GDB_TK)
3493 AC_SUBST(INSTALL_GDB_TK)
3494
3495 # Build module lists & subconfigure args.
3496 AC_SUBST(build_configargs)
3497 AC_SUBST(build_configdirs)
3498
3499 # Host module lists & subconfigure args.
3500 AC_SUBST(host_configargs)
3501 AC_SUBST(configdirs)
3502 AC_SUBST(target_configdirs)
3503
3504 # Target module lists & subconfigure args.
3505 AC_SUBST(target_configargs)
3506
3507
3508 # Build tools.
3509 AC_SUBST(AR_FOR_BUILD)
3510 AC_SUBST(AS_FOR_BUILD)
3511 AC_SUBST(CC_FOR_BUILD)
3512 AC_SUBST(CFLAGS_FOR_BUILD)
3513 AC_SUBST(CPP_FOR_BUILD)
3514 AC_SUBST(CPPFLAGS_FOR_BUILD)
3515 AC_SUBST(CXXFLAGS_FOR_BUILD)
3516 AC_SUBST(CXX_FOR_BUILD)
3517 AC_SUBST(DLLTOOL_FOR_BUILD)
3518 AC_SUBST(DSYMUTIL_FOR_BUILD)
3519 AC_SUBST(GFORTRAN_FOR_BUILD)
3520 AC_SUBST(GOC_FOR_BUILD)
3521 AC_SUBST(GDC_FOR_BUILD)
3522 AC_SUBST(LDFLAGS_FOR_BUILD)
3523 AC_SUBST(LD_FOR_BUILD)
3524 AC_SUBST(NM_FOR_BUILD)
3525 AC_SUBST(RANLIB_FOR_BUILD)
3526 AC_SUBST(WINDMC_FOR_BUILD)
3527 AC_SUBST(WINDRES_FOR_BUILD)
3528
3529 # Generate default definitions for YACC, M4, LEX and other programs that run
3530 # on the build machine.  These are used if the Makefile can't locate these
3531 # programs in objdir.
3532 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3533
3534 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3535 case " $build_configdirs " in
3536   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3537 esac
3538
3539 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3540 case " $build_configdirs " in
3541   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3542 esac
3543
3544 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3545 case " $build_configdirs " in
3546   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3547 esac
3548
3549 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3550 case " $build_configdirs " in
3551   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3552   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3553 esac
3554
3555 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3556 case " $build_configdirs " in
3557   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3558 esac
3559
3560 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3561 case " $build_configdirs " in
3562   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3563   *)
3564 changequote(,)
3565     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3566     # higher, else we use the "missing" dummy.
3567     if ${MAKEINFO} --version \
3568        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3569       :
3570     else
3571       MAKEINFO="$MISSING makeinfo"
3572     fi
3573     ;;
3574 changequote([,])
3575 esac
3576
3577 # FIXME: expect and dejagnu may become build tools?
3578
3579 AC_CHECK_PROGS(EXPECT, expect, expect)
3580 case " $configdirs " in
3581   *" expect "*)
3582     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3583     ;;
3584 esac
3585
3586 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3587 case " $configdirs " in
3588   *" dejagnu "*)
3589     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3590     ;;
3591 esac
3592
3593
3594 # Host tools.
3595 NCN_STRICT_CHECK_TOOLS(AR, ar)
3596 NCN_STRICT_CHECK_TOOLS(AS, as)
3597 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3598 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3599 NCN_STRICT_CHECK_TOOLS(LD, ld)
3600 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3601 NCN_STRICT_CHECK_TOOLS(NM, nm)
3602 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3603 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3604 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3605 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3606 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3607 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3608 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3609 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3610 AC_SUBST(CC)
3611 AC_SUBST(CXX)
3612 AC_SUBST(CFLAGS)
3613 AC_SUBST(CXXFLAGS)
3614 AC_SUBST(GDC)
3615 AC_SUBST(GDCFLAGS)
3616
3617 # Target tools.
3618 AC_ARG_WITH([build-time-tools],
3619   [AS_HELP_STRING([--with-build-time-tools=PATH],
3620                   [use given path to find target tools during the build])],
3621   [case x"$withval" in
3622      x/*) ;;
3623      *)
3624        with_build_time_tools=
3625        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3626        ;;
3627    esac],
3628   [with_build_time_tools=])
3629
3630 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3631 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3632 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3633 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3634 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3635 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3636 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3637
3638 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3639 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3640 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3641 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3642 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3643 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3644 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3645 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3646 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3647 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3648 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3649 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3650 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3651 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3652 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3653
3654 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3655
3656 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3657 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3658 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3659 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3660 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3661                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3662                 c++)
3663 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3664                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3665                 c++)
3666 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3667 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3668 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3669 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3670                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3671 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3672                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3673 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3674                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3675 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3676                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3677 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3678 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3679 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3680 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3681 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3682 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3683 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3684 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3685 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3686 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3687 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3688
3689 AC_SUBST(FLAGS_FOR_TARGET)
3690 AC_SUBST(RAW_CXX_FOR_TARGET)
3691
3692 # Certain tools may need extra flags.
3693 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3694 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3695 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3696
3697 # When building target libraries, except in a Canadian cross, we use
3698 # the same toolchain as the compiler we just built.
3699 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3700 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3701 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3702 if test $host = $build; then
3703   case " $configdirs " in
3704     *" gcc "*)
3705       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3706       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3707       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3708       ;;
3709   esac
3710 fi
3711
3712 AC_SUBST(COMPILER_AS_FOR_TARGET)
3713 AC_SUBST(COMPILER_LD_FOR_TARGET)
3714 AC_SUBST(COMPILER_NM_FOR_TARGET)
3715
3716 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3717 AC_ARG_ENABLE(maintainer-mode,
3718 [AS_HELP_STRING([--enable-maintainer-mode],
3719                 [enable make rules and dependencies not useful
3720                  (and sometimes confusing) to the casual installer])],
3721       USE_MAINTAINER_MODE=$enableval,
3722       USE_MAINTAINER_MODE=no)
3723 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3724 AC_SUBST(MAINTAINER_MODE_TRUE)
3725 AC_SUBST(MAINTAINER_MODE_FALSE)
3726 if test "$USE_MAINTAINER_MODE" = yes; then
3727   MAINTAINER_MODE_TRUE=
3728   MAINTAINER_MODE_FALSE='#'
3729 else
3730   MAINTAINER_MODE_TRUE='#'
3731   MAINTAINER_MODE_FALSE=
3732 fi
3733 MAINT=$MAINTAINER_MODE_TRUE
3734 AC_SUBST(MAINT)dnl
3735
3736 # ---------------------
3737 # GCC bootstrap support
3738 # ---------------------
3739
3740 # Stage specific cflags for build.
3741 stage1_cflags="-g"
3742 case $build in
3743   vax-*-*)
3744     case ${GCC} in
3745       yes) stage1_cflags="-g -Wa,-J" ;;
3746       *) stage1_cflags="-g -J" ;;
3747     esac ;;
3748 esac
3749
3750 AC_SUBST(stage1_cflags)
3751
3752 # Enable --enable-checking in stage1 of the compiler.
3753 AC_ARG_ENABLE(stage1-checking,
3754 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3755                 [choose additional checking for stage1 of the compiler])],
3756 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3757 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3758   # For --disable-checking or implicit --enable-checking=release, avoid
3759   # setting --enable-checking=gc in the default stage1 checking for LTO
3760   # bootstraps.  See PR62077.
3761   case $BUILD_CONFIG in
3762     *lto*)
3763       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3764     *)
3765       stage1_checking=--enable-checking=yes,types;;
3766   esac
3767   if test "x$enable_checking" = x && \
3768      test -d ${srcdir}/gcc && \
3769      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3770     stage1_checking=--enable-checking=yes,types,extra
3771   fi
3772 else
3773   stage1_checking=--enable-checking=$enable_checking,types
3774 fi])
3775 AC_SUBST(stage1_checking)
3776
3777 # Enable -Werror in bootstrap stage2 and later.
3778 AC_ARG_ENABLE(werror,
3779 [AS_HELP_STRING([--enable-werror],
3780                 [enable -Werror in bootstrap stage2 and later])],
3781 [
3782 case ${enable_werror} in
3783   yes) stage2_werror_flag="--enable-werror-always" ;;
3784   *) stage2_werror_flag="" ;;
3785 esac
3786 ],
3787 [
3788 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3789   case $BUILD_CONFIG in
3790   bootstrap-debug)
3791       stage2_werror_flag="--enable-werror-always" ;;
3792   "")
3793       stage2_werror_flag="--enable-werror-always" ;;
3794   esac
3795 fi
3796 ])
3797
3798 AC_SUBST(stage2_werror_flag)
3799
3800 # Specify what files to not compare during bootstrap.
3801
3802 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3803 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3804 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3805 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3806 case "$target" in
3807   hppa*64*-*-hpux*) ;;
3808   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3809 esac
3810 AC_SUBST(compare_exclusions)
3811
3812 AC_CONFIG_FILES([Makefile],
3813   [sed "$extrasub_build" Makefile |
3814    sed "$extrasub_host" |
3815    sed "$extrasub_target" > mf$$
3816    mv -f mf$$ Makefile],
3817   [extrasub_build="$extrasub_build"
3818    extrasub_host="$extrasub_host"
3819    extrasub_target="$extrasub_target"])
3820 AC_OUTPUT