configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT(GStreamer Good Plug-ins, 0.10.25.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-good)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl FIXME: this macro doesn't actually work;
  47 dnl the generated libtool script has no support for the listed tags.
  48 dnl So this needs to be fixed first if we want to use this
  49 dnl AS_LIBTOOL_TAGS
  50
  51 AC_LIBTOOL_WIN32_DLL
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.30
  56 GSTPB_REQ=0.10.30
  57
  58 dnl *** autotools stuff ****
  59
  60 dnl allow for different autotools
  61 AS_AUTOTOOLS_ALTERNATE
  62
  63 dnl Add parameters for aclocal
  64 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  65
  66 dnl set up gettext
  67 dnl the version check needs to stay here because autopoint greps for it
  68 AM_GNU_GETTEXT_VERSION([0.17])
  69 AM_GNU_GETTEXT([external])
  70 AG_GST_GETTEXT([gst-plugins-good-$GST_MAJORMINOR])
  71
  72 dnl *** check for arguments to configure ***
  73
  74 AG_GST_ARG_DEBUG
  75 AG_GST_ARG_PROFILING
  76 AG_GST_ARG_VALGRIND
  77 AG_GST_ARG_GCOV
  78
  79 AG_GST_ARG_EXAMPLES
  80
  81 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  82 AG_GST_ARG_WITH_PACKAGE_NAME
  83 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  84
  85 AG_GST_ARG_WITH_PLUGINS
  86
  87 AG_GST_ARG_ENABLE_EXTERNAL
  88
  89 AG_GST_ARG_ENABLE_EXPERIMENTAL
  90
  91 dnl *** checks for platform ***
  92
  93 dnl * hardware/architecture *
  94
  95 dnl common/m4/gst-arch.m4
  96 dnl check CPU type
  97 AG_GST_ARCH
  98
  99 dnl Determine endianness
 100 AC_C_BIGENDIAN
 101
 102 dnl *** checks for programs ***
 103
 104 dnl find a compiler
 105 AC_PROG_CC
 106 AC_PROG_CC_STDC
 107
 108 dnl determine c++ compiler
 109 AC_PROG_CXX
 110 dnl determine if c++ is available on this system
 111 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 112
 113 dnl determine c++ preprocessor
 114 dnl FIXME: do we need this ?
 115 AC_PROG_CXXCPP
 116
 117 AS_PROG_OBJC
 118
 119 dnl check if the compiler supports '-c' and '-o' options
 120 AM_PROG_CC_C_O
 121
 122 dnl find an assembler
 123 AM_PROG_AS
 124
 125 dnl check if the compiler supports do while(0) macros
 126 AG_GST_CHECK_DOWHILE_MACROS
 127
 128 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 129 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 130
 131 dnl check for gconftool-2
 132 dnl this macro defines an am conditional, so it needs to be run always
 133 AM_GCONF_SOURCE_2
 134
 135 dnl check for documentation tools
 136 GTK_DOC_CHECK([1.3])
 137 AS_PATH_PYTHON([2.1])
 138 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 139
 140 dnl *** checks for libraries ***
 141
 142 dnl check for libm, for sin()
 143 AC_CHECK_LIBM
 144 AC_SUBST(LIBM)
 145
 146 dnl *** checks for header files ***
 147
 148 dnl check if we have ANSI C header files
 149 AC_HEADER_STDC
 150
 151 dnl used by ext/wavpack
 152 AX_CREATE_STDINT_H
 153
 154 dnl used in gst/rtp/gstasteriskh263.c
 155 AC_CHECK_HEADERS([netinet/in.h])
 156 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 157 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 158
 159 dnl used in gst/udp
 160 AC_CHECK_HEADERS([sys/time.h])
 161
 162 dnl *** checks for types/defines ***
 163
 164 dnl Check for FIONREAD ioctl declaration.  This check is needed
 165 dnl for the UDP plugin to build on Solaris
 166 GST_CHECK_FIONREAD
 167
 168 dnl *** checks for structures ***
 169
 170 dnl *** checks for compiler characteristics ***
 171
 172 dnl check if we have GCC inline-asm
 173 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 174 if test x$HAVE_GCC_ASM = xyes ; then
 175   AC_DEFINE(HAVE_GCC_ASM, 1,
 176     [Define if compiler supports gcc inline assembly])
 177 fi
 178 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 179
 180 dnl *** checks for library functions ***
 181
 182 LIBS_SAVE=$LIBS
 183 LIBS="$LIBS $LIBM"
 184 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 185 LIBS=$LIBS_SAVE
 186
 187 dnl Check whether isinf() is defined by math.h
 188 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 189     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 190 if test "$ac_cv_have_isinf" = "yes"
 191 then
 192     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 193 fi
 194
 195 dnl Check for mmap (needed by electricfence plugin)
 196 AC_FUNC_MMAP
 197 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 198
 199 dnl Check for mmap (needed by electricfence plugin)
 200
 201 AC_CHECK_TYPE([struct ip_mreqn], [
 202               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 203               [#include <netinet/in.h>])
 204
 205 dnl *** checks for dependency libraries ***
 206
 207 dnl GLib is required
 208 AG_GST_GLIB_CHECK([2.18])
 209
 210 dnl Orc
 211 ORC_CHECK([0.4.7])
 212
 213
 214 dnl checks for gstreamer
 215 dnl uninstalled is selected preferentially -- see pkg-config(1)
 216 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 219 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 220 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 221 AG_GST_CHECK_GST_PLUGINS_BASE($GST_MAJORMINOR, [$GSTPB_REQ], yes)
 222
 223 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 224 if test -z $GST_TOOLS_DIR; then
 225   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 226 fi
 227 AC_SUBST(GST_TOOLS_DIR)
 228
 229 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 230 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 231
 232 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 233
 234 dnl Check for documentation xrefs
 235 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 236 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 237 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_MAJORMINOR`"
 238 AC_SUBST(GLIB_PREFIX)
 239 AC_SUBST(GST_PREFIX)
 240 AC_SUBST(GSTPB_PREFIX)
 241
 242 dnl GTK is optional and used in examples
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0, HAVE_GTK=yes,
 245   [PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.14.0, HAVE_GTK=yes, HAVE_GTK=no)])
 246   AC_SUBST(GTK_LIBS)
 247   AC_SUBST(GTK_CFLAGS)
 248 fi
 249 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 250
 251 dnl should we install schemas ?
 252 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 253 AG_GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 254   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 255   if test x$GCONFTOOL = xno; then
 256     AC_MSG_WARN(Not installing GConf schemas)
 257     HAVE_GCONFTOOL="no"
 258   else
 259     HAVE_GCONFTOOL="yes"
 260   fi
 261   AC_SUBST(HAVE_GCONFTOOL)
 262 ])
 263
 264 dnl *** set variables based on configure arguments ***
 265
 266 dnl set license and copyright notice
 267 GST_LICENSE="LGPL"
 268 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 269 AC_SUBST(GST_LICENSE)
 270
 271 dnl set location of plugin directory
 272 AG_GST_SET_PLUGINDIR
 273
 274 dnl define an ERROR_CFLAGS Makefile variable
 275 dnl -Wundef: too many broken headers
 276 dnl -Waggregate-return: causes problems with ObjC code like in osxvideosink
 277 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 278         -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 279         -Wwrite-strings -Wold-style-definition
 280         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 281         -Wnested-externs ])
 282
 283 dnl define an ERROR_CXXFLAGS Makefile variable
 284 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 285         -Wmissing-declarations -Wredundant-decls
 286         -Wwrite-strings
 287         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar ])
 288
 289 dnl define correct level for debugging messages
 290 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 291
 292 dnl used in examples
 293 AG_GST_DEFAULT_ELEMENTS
 294
 295 dnl *** plug-ins to include ***
 296
 297 dnl these are all the gst plug-ins, compilable without additional libs
 298 dnl videofilter is at the top because others depend on it
 299 AG_GST_CHECK_PLUGIN(videofilter)
 300 AG_GST_CHECK_PLUGIN(alpha)
 301 AG_GST_CHECK_PLUGIN(apetag)
 302 AG_GST_CHECK_PLUGIN(audiofx)
 303 AG_GST_CHECK_PLUGIN(auparse)
 304 AG_GST_CHECK_PLUGIN(autodetect)
 305 AG_GST_CHECK_PLUGIN(avi)
 306 AG_GST_CHECK_PLUGIN(cutter)
 307 AG_GST_CHECK_PLUGIN(debugutils)
 308 AG_GST_CHECK_PLUGIN(deinterlace)
 309 AG_GST_CHECK_PLUGIN(effectv)
 310 AG_GST_CHECK_PLUGIN(equalizer)
 311 AG_GST_CHECK_PLUGIN(flv)
 312 AG_GST_CHECK_PLUGIN(id3demux)
 313 AG_GST_CHECK_PLUGIN(icydemux)
 314 AG_GST_CHECK_PLUGIN(interleave)
 315 AG_GST_CHECK_PLUGIN(flx)
 316 AG_GST_CHECK_PLUGIN(goom)
 317 AG_GST_CHECK_PLUGIN(goom2k1)
 318 AG_GST_CHECK_PLUGIN(imagefreeze)
 319 AG_GST_CHECK_PLUGIN(law)
 320 AG_GST_CHECK_PLUGIN(level)
 321 AG_GST_CHECK_PLUGIN(matroska)
 322 AG_GST_CHECK_PLUGIN(monoscope)
 323 AG_GST_CHECK_PLUGIN(multifile)
 324 AG_GST_CHECK_PLUGIN(multipart)
 325 AG_GST_CHECK_PLUGIN(qtdemux)
 326 AG_GST_CHECK_PLUGIN(replaygain)
 327 AG_GST_CHECK_PLUGIN(rtp)
 328 AG_GST_CHECK_PLUGIN(rtpmanager)
 329 AG_GST_CHECK_PLUGIN(rtsp)
 330 AG_GST_CHECK_PLUGIN(shapewipe)
 331 AG_GST_CHECK_PLUGIN(smpte)
 332 AG_GST_CHECK_PLUGIN(spectrum)
 333 AG_GST_CHECK_PLUGIN(udp)
 334 AG_GST_CHECK_PLUGIN(videobox)
 335 AG_GST_CHECK_PLUGIN(videocrop)
 336 AG_GST_CHECK_PLUGIN(videomixer)
 337 AG_GST_CHECK_PLUGIN(wavenc)
 338 AG_GST_CHECK_PLUGIN(wavparse)
 339 AG_GST_CHECK_PLUGIN(y4m)
 340
 341 dnl *** checks for socket and nsl libraries ***
 342 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 343
 344 dnl disable gst plugins we might not be able to build on this
 345 dnl platform: udp and rtsp (ugly but minimally invasive)
 346 dnl FIXME: maybe move to sys
 347 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 348 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 349
 350 if test "x$HAVE_SYS_SOCKET_H" != "xyes" -a "x$HAVE_WINSOCK2_H" != "xyes"; then
 351   AG_GST_DISABLE_PLUGIN(udp)
 352   AG_GST_DISABLE_PLUGIN(rtsp)
 353 fi
 354
 355 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 356   WIN32_LIBS="-lws2_32"
 357   AC_SUBST(WIN32_LIBS)
 358 fi
 359
 360 dnl disable experimental plug-ins
 361 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 362   AG_GST_DISABLE_PLUGIN(monoscope)
 363 fi
 364
 365 dnl *** sys plug-ins ***
 366
 367 echo
 368 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 369 echo
 370
 371 dnl DirectSound
 372 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 373 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 374   HAVE_DIRECTSOUND="no"
 375   save_CFLAGS="$CFLAGS"
 376   save_LDFLAGS="$LDFLAGS"
 377   save_LIBS="$LIBS"
 378   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 379   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 380   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 381   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 382   AC_LINK_IFELSE([
 383 #include <windows.h>
 384 #include <dxerr9.h>
 385 #include <dsound.h>
 386
 387 int main ()
 388 {
 389   DXGetErrorString9 (0);
 390   DirectSoundCreate(NULL, NULL, NULL);
 391
 392   return 0;
 393 }
 394 ],
 395     [HAVE_DIRECTSOUND="yes"],
 396     [HAVE_DIRECTSOUND="no"])
 397   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 398   CFLAGS=$save_CFLAGS
 399   LDFLAGS=$save_LDFLAGS
 400   LIBS=$save_LIBS
 401
 402   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 403     dnl this is much more than we want
 404     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 405     AC_SUBST(DIRECTSOUND_CFLAGS)
 406     AC_SUBST(DIRECTSOUND_LDFLAGS)
 407     AC_SUBST(DIRECTSOUND_LIBS)
 408   fi
 409   AC_SUBST(HAVE_DIRECTSOUND)
 410 ])
 411
 412 dnl *** OSS audio *** (Linux, *BSD)
 413 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 414 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 415  HAVE_OSS="yes"
 416 dnl Linux and newer BSD versions :
 417  AC_CHECK_HEADER(sys/soundcard.h, [
 418    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 419    ] , [
 420 dnl Some old BSD versions and also newer OpenBSD versions :
 421    AC_CHECK_HEADER(soundcard.h, [
 422      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 423      ], [
 424   dnl Some old BSD versions :
 425      AC_CHECK_HEADER(machine/soundcard.h, [
 426        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 427          [Define if OSS includes are in /machine/])
 428        ], [
 429        HAVE_OSS="no"
 430      ])
 431    ])
 432  ])
 433 ])
 434
 435 dnl *** oss4 ***
 436 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 437 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 438   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 439   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 440       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 441       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 442 ])
 443
 444 dnl *** Sun Audio ***
 445 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 446 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 447   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 448 ])
 449
 450 dnl *** OSX Audio ***
 451 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 452 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 453   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 454 ])
 455
 456 dnl *** OS X video ***
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 458 HAVE_OSX_VIDEO="no"
 459 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 460   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 461 ])
 462 dnl in case header OpenGL/gl.h is found on other platforms
 463 case "$host" in
 464   *-*darwin*)
 465     dnl do nothing
 466     ;;
 467   *)
 468     HAVE_OSX_VIDEO="no"
 469     ;;
 470 esac
 471
 472
 473 dnl *** Video 4 Linux 2 ***
 474 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 475 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 477 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 478   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 479   AC_TRY_COMPILE([
 480 #include <sys/types.h>
 481 #ifdef __sun /* Solaris */
 482 #include <sys/types.h>
 483 #include <sys/videodev2.h>
 484 #else /* Linux */
 485 #include <linux/types.h>
 486 #define _LINUX_TIME_H
 487 #define __user
 488 #include <linux/videodev2.h>
 489 #endif
 490 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 491 #error too early v4l2 version or no v4l2 at all
 492 #endif
 493     ], [
 494 return 0;
 495     ], [
 496       HAVE_GST_V4L2="yes"
 497       AC_MSG_RESULT(yes)
 498     ], [
 499       HAVE_GST_V4L2="no"
 500       AC_MSG_RESULT(no)
 501
 502       HAVE_VIDEODEV=no
 503       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 504       [
 505         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 506       ])
 507
 508       if test "x$HAVE_VIDEODEV" = "xyes"; then
 509         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 510         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 511       else
 512         AC_MSG_WARN([video4linux2 was not found])
 513       fi
 514     ])
 515
 516   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 517     dnl check for missing v4l2_buffer declaration (see #135919)
 518     MISSING_DECL=0
 519     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 520     AC_TRY_COMPILE([
 521 #include <sys/types.h>
 522 #ifdef __sun /* Solaris */
 523 #include <sys/types.h>
 524 #include <sys/videodev2.h>
 525 #else /* Linux */
 526 #include <linux/types.h>
 527 #define _LINUX_TIME_H
 528 #define __user
 529 #include <linux/videodev2.h>
 530 #endif
 531     ],[
 532 struct v4l2_buffer buf;
 533 buf.index = 0;
 534 return 0;
 535     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 536     if [ test x$MISSING_DECL = x1 ]; then
 537       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 538     fi
 539
 540     dnl check for XOverlay libraries
 541     AG_GST_CHECK_XV
 542   fi
 543 ])
 544
 545 # Optional gudev for device probing
 546 AC_ARG_WITH([gudev],
 547   AC_HELP_STRING([--with-gudev],
 548     [device detection with gudev]),
 549   [],
 550   [with_gudev=check])
 551 if test x$HAVE_GST_V4L2 = xyes; then
 552   if test x$with_gudev != xno; then
 553       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 554           [ have_gudev=yes
 555             AC_DEFINE(HAVE_GUDEV, 1,
 556                [Whether gudev is available for device detection])
 557             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 558           ], [
 559           have_gudev=no
 560           ])
 561   else
 562     have_gudev=no
 563   fi
 564 fi
 565 AC_SUBST(GUDEV_CFLAGS)
 566 AC_SUBST(GUDEV_LIBS)
 567
 568 # Make libv4l2 non-automagic
 569 AC_ARG_WITH([libv4l2],
 570   AC_HELP_STRING([--with-libv4l2],
 571     [support video buffer conversion using libv4l2]),
 572   [],
 573   [with_libv4l2=check])
 574 if test x$HAVE_GST_V4L2 = xyes; then
 575   if test x$with_libv4l2 != xno; then
 576       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 577           [ have_libv4l2=yes
 578             AC_DEFINE(HAVE_LIBV4L2, 1,
 579                 [Whether libv4l2 is available for video buffer conversion])
 580           ], [
 581           have_libv4l2=no
 582           ])
 583   else
 584     have_libv4l2=no
 585   fi
 586 fi
 587
 588 dnl Check for X11
 589 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 590 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 591                   [ximagesrc], [
 592   AC_PATH_XTRA
 593
 594   dnl now try to find the HEADER
 595   ac_cflags_save="$CFLAGS"
 596   ac_cppflags_save="$CPPFLAGS"
 597   CFLAGS="$CFLAGS $X_CFLAGS"
 598   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 599   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 600
 601   if test "x$HAVE_X" = "xno"
 602   then
 603     AC_MSG_NOTICE([cannot find X11 development files])
 604   else
 605     dnl this is much more than we want
 606     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 607     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 608     dnl it does not add the libs; therefore we add them here
 609     X_LIBS="$X_LIBS -lX11"
 610     AC_SUBST(X_CFLAGS)
 611     AC_SUBST(X_LIBS)
 612
 613     dnl check for Xfixes
 614     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 615     if test "x$HAVE_XFIXES" = "xyes"
 616     then
 617         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 618     fi
 619     AC_SUBST(XFIXES_LIBS)
 620     AC_SUBST(XFIXES_CFLAGS)
 621
 622     dnl check for Xdamage
 623     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 624     if test "x$HAVE_XDAMAGE" = "xyes"
 625     then
 626         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 627     fi
 628     AC_SUBST(XDAMAGE_LIBS)
 629     AC_SUBST(XDAMAGE_CFLAGS)
 630   fi
 631   AC_SUBST(HAVE_X)
 632   CFLAGS="$ac_cflags_save"
 633   CPPFLAGS="$ac_cppflags_save"
 634 ])
 635
 636 dnl FIXME: this should be rolled into the test above, it's just an additional
 637 dnl feature of the ximagesrc plug-in
 638 dnl This is the same as in gst-plugins-base
 639 dnl check for X Shm
 640 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 641 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 642   if test x$HAVE_X = xyes; then
 643     AC_CHECK_LIB(Xext, XShmAttach,
 644                  HAVE_XSHM="yes", HAVE_XSHM="no",
 645                  $X_LIBS)
 646     if test "x$HAVE_XSHM" = "xyes"; then
 647       XSHM_LIBS="-lXext"
 648     else
 649       dnl On AIX, it is in XextSam instead, but we still need -lXext
 650       AC_CHECK_LIB(XextSam, XShmAttach,
 651                    HAVE_XSHM="yes", HAVE_XSHM="no",
 652                    $X_LIBS)
 653       if test "x$HAVE_XSHM" = "xyes"; then
 654         XSHM_LIBS="-lXext -lXextSam"
 655       fi
 656     fi
 657   fi
 658 ], ,[
 659   AC_SUBST(HAVE_XSHM)
 660   AC_SUBST(XSHM_LIBS)
 661 ])
 662
 663 dnl for V4L2, we also need to know if we have XVIDEO
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 665 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 666                   [], [
 667   AG_GST_CHECK_XV
 668 ])
 669
 670 dnl *** ext plug-ins ***
 671 dnl keep this list sorted alphabetically !
 672
 673 if test "x$BUILD_EXTERNAL" = "xyes"; then
 674
 675 echo
 676 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 677 echo
 678
 679 dnl *** aalib ***
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 681 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 682   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 683   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 684 ])
 685
 686 dnl *** annodex ***
 687 translit(dnm, m, l) AM_CONDITIONAL(USE_ANNODEX, true)
 688 AG_GST_CHECK_FEATURE(ANNODEX, [XML library], annodex, [
 689   AG_GST_PKG_CHECK_MODULES(ANNODEX, libxml-2.0 >= 2.4.9)
 690 ])
 691
 692 dnl *** cairo ***
 693 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 694 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering], cairo, [
 695   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.0.0)
 696 ])
 697
 698 dnl **** ESound ****
 699 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 700 AG_GST_CHECK_FEATURE(ESD, [ESounD sound daemon], esdsink, [
 701   AG_GST_PKG_CHECK_MODULES(ESD, esound >= 0.2.12)
 702   if test $HAVE_ESD = no
 703   then
 704     AM_PATH_ESD(0.2.12, HAVE_ESD="yes")
 705     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 706   fi
 707 ])
 708
 709 dnl *** FLAC ***
 710 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 711 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 712   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 713 ])
 714
 715 dnl *** GConf ***
 716 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 717 AG_GST_CHECK_FEATURE(GCONF, [GConf libraries], gconfelements, [
 718   AG_GST_PKG_CHECK_MODULES(GCONF, gconf-2.0)
 719 ])
 720
 721 dnl *** GDK pixbuf ***
 722 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 723 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 724   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 725 ])
 726
 727 dnl *** HAL ***
 728 translit(dnm, m, l) AM_CONDITIONAL(USE_HAL, true)
 729 AG_GST_CHECK_FEATURE(HAL, [HAL libraries], halelements, [
 730   AG_GST_PKG_CHECK_MODULES(HAL, [hal >= 0.5.6, dbus-1 >= 0.32])
 731 ])
 732
 733 dnl *** jpeg ***
 734 dnl FIXME: we could use header checks here as well IMO
 735 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 736 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 737   AC_ARG_WITH(jpeg-mmx,
 738     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 739   OLD_LIBS="$LIBS"
 740   if test x$with_jpeg_mmx != x; then
 741     LIBS="$LIBS -L$with_jpeg_mmx"
 742   fi
 743   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 744   JPEG_LIBS="$LIBS -ljpeg-mmx"
 745   LIBS="$OLD_LIBS"
 746   if test x$HAVE_JPEG != xyes; then
 747     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 748     JPEG_LIBS="-ljpeg"
 749   fi
 750   AC_SUBST(JPEG_LIBS)
 751 ])
 752
 753 dnl *** libcaca ***
 754 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 755 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 756   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 757   dnl only newer versions of libcaca ship caca.pc, so try caca-config as well
 758   if test "x$HAVE_LIBCACA" != "xyes"; then
 759     AG_GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
 760     dnl see if it compilation works too, might not if we are cross-compiling
 761     if test "x$HAVE_LIBCACA" = "xyes"; then
 762       AC_CHECK_LIB([caca], [caca_init], [HAVE_LIBCACA=yes],
 763                    [HAVE_LIBCACA=no], [$LIBCACA_LIBS])
 764     fi
 765   fi
 766 ])
 767
 768 dnl *** libdv ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 770 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 771   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 772 ])
 773
 774 dnl *** libpng ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 776 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 777   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 778 ])
 779
 780 dnl *** pulseaudio ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 782 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 783
 784   dnl used in ext/pulse/pulseutil.c
 785   AC_CHECK_HEADERS([process.h])
 786
 787   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 0.9.10)
 788   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_11, libpulse >= 0.9.11)
 789   if test x$HAVE_PULSE_0_9_11 = xyes; then
 790     AC_DEFINE(HAVE_PULSE_0_9_11, 1, [defined if pulseaudio >= 0.9.11 is available])
 791   fi
 792   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_12, libpulse >= 0.9.12)
 793   if test x$HAVE_PULSE_0_9_12 = xyes; then
 794     AC_DEFINE(HAVE_PULSE_0_9_12, 1, [defined if pulseaudio >= 0.9.12 is available])
 795   fi
 796   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_13, libpulse >= 0.9.13)
 797   if test x$HAVE_PULSE_0_9_13 = xyes; then
 798     AC_DEFINE(HAVE_PULSE_0_9_13, 1, [defined if pulseaudio >= 0.9.13 is available])
 799   fi
 800   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_15, libpulse >= 0.9.15)
 801   if test x$HAVE_PULSE_0_9_15 = xyes; then
 802     AC_DEFINE(HAVE_PULSE_0_9_15, 1, [defined if pulseaudio >= 0.9.15 is available])
 803   fi
 804   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_16, libpulse >= 0.9.16)
 805   if test x$HAVE_PULSE_0_9_16 = xyes; then
 806     AC_DEFINE(HAVE_PULSE_0_9_16, 1, [defined if pulseaudio >= 0.9.16 is available])
 807   fi
 808   AG_GST_PKG_CHECK_MODULES(PULSE_0_9_20, libpulse >= 0.9.20)
 809   if test x$HAVE_PULSE_0_9_20 = xyes; then
 810     AC_DEFINE(HAVE_PULSE_0_9_20, 1, [defined if pulseaudio >= 0.9.20 is available])
 811   fi
 812 ])
 813
 814 dnl *** dv1394 ***
 815 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 816 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 817   dnl first test for libraw1394 >= 2.0.0
 818   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 819   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 820   dnl now see how far we got
 821   if test x$HAVE_RAW1394 = xyes && \
 822      test x$HAVE_LIBIEC61883 = xyes; then
 823        AG_GST_CHECK_LIBHEADER(AVC1394,
 824         avc1394, avc1394_send_command, $RAW1394_LIBS,
 825         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 826        AG_GST_CHECK_LIBHEADER(ROM1394,
 827         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 828         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 829        if test x$HAVE_AVC1394 = xyes && \
 830           test x$HAVE_AVC1394 = xyes && \
 831           test x$HAVE_ROM1394 = xyes; then
 832           HAVE_DV1394=yes
 833           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 834           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 835           AC_SUBST(DV1394_CFLAGS)
 836           AC_SUBST(DV1394_LIBS)
 837         fi
 838   else
 839        if test x$HAVE_RAW1394 = xno; then
 840           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 841           AG_GST_CHECK_LIBHEADER(AVC1394,
 842            avc1394, avc1394_send_command, $RAW1394_LIBS,
 843            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 844           AG_GST_CHECK_LIBHEADER(ROM1394,
 845            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 846            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 847           if test x$HAVE_RAW1394 = xyes && \
 848              test x$HAVE_AVC1394 = xyes && \
 849              test x$HAVE_ROM1394 = xyes; then
 850              HAVE_DV1394=yes
 851              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 852              DV1394_CFLAGS="$RAW1394_CFLAGS"
 853              if test x$HAVE_LIBIEC61883 = xyes; then
 854                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 855                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 856              fi
 857              AC_SUBST(DV1394_CFLAGS)
 858              AC_SUBST(DV1394_LIBS)
 859            fi
 860          fi
 861   fi
 862 ])
 863
 864 dnl *** shout2 ***
 865 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 866 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 867   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 868   if test $HAVE_SHOUT2 = no
 869   then
 870     AM_PATH_SHOUT2(HAVE_SHOUT2="yes")
 871     AC_SUBST(SHOUT2_CFLAGS)
 872     AC_SUBST(SHOUT2_LIBS)
 873   fi
 874 ])
 875
 876 dnl *** soup ***
 877 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 878 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 879   PKG_CHECK_MODULES(SOUP, libsoup-gnome-2.4 >= 2.3.2, [
 880     HAVE_SOUP="yes"
 881     AC_DEFINE(HAVE_LIBSOUP_GNOME, 1, [soup gnome integration])
 882   ],[
 883     PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26, HAVE_SOUP="yes", [
 884       HAVE_SOUP="no"
 885       AC_MSG_RESULT(no)
 886     ])
 887   ])
 888   AC_SUBST(SOUP_CFLAGS)
 889   AC_SUBST(SOUP_LIBS)
 890 ])
 891
 892 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 893 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 894 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 895 dnl   speex_jitter.h is 1.1.x only
 896 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 897 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 898   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 899   if test $HAVE_SPEEX = no
 900   then
 901     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 902       AC_CHECK_HEADER(speex/speex_jitter.h, [
 903         dnl speex 1.1.x :
 904         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 905           dnl speex 1.1.5 or + :
 906           HAVE_SPEEX="yes"
 907           SPEEX_LIBS="-lspeex"
 908           AC_SUBST(SPEEX_CFLAGS)
 909           AC_SUBST(SPEEX_LIBS)
 910         ],[
 911           HAVE_SPEEX="no"
 912         ])
 913       ],[
 914         dnl speex 1.0.x :
 915           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 916             dnl speex 1.0.4
 917             HAVE_SPEEX="yes"
 918             SPEEX_LIBS="-lspeex"
 919             AC_SUBST(SPEEX_CFLAGS)
 920             AC_SUBST(SPEEX_LIBS)
 921
 922             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 923               [defined if speex 1.0.x API detected])
 924         ],[
 925             HAVE_SPEEX="no"
 926             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 927         ], [
 928 #include <speex/speex.h>
 929         ])
 930       ])
 931     ])
 932   fi
 933 ])
 934
 935 dnl *** taglib ***
 936 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 937 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 938   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 939   if test "x$HAVE_CXX" != "xyes"; then
 940     USE_TAGLIB=false
 941     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 942   else
 943     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 944     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 945         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 946       ], [
 947         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 948     ])
 949     AC_SUBST(TAGLIB_CXXFLAGS)
 950   fi
 951 ])
 952
 953 dnl *** wavpack ***
 954 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 955 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 956   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 957     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 958       HAVE_WAVPACK=yes
 959       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 960     ],[
 961       HAVE_WAVPACK=no
 962       AC_MSG_RESULT(no)
 963     ])
 964   ])
 965   AC_SUBST(WAVPACK_CFLAGS)
 966   AC_SUBST(WAVPACK_LIBS)
 967 ])
 968
 969 dnl *** qtdemux & id3demux & matroska prefer to have zlib ***
 970 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 971 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for id3demux/qtdemux/matroska],, [
 972   AG_GST_CHECK_LIBHEADER(ZLIB,
 973     z, uncompress,, zlib.h, [
 974     HAVE_ZLIB="yes"
 975     ZLIB_LIBS="-lz"
 976     AC_SUBST(ZLIB_LIBS)
 977   ])
 978 ])
 979
 980 dnl *** matroska prefers to have bz2 ***
 981 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 982 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 983   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 984   AC_SUBST(BZ2_LIBS)
 985 ])
 986
 987 else
 988
 989 dnl not building plugins with external dependencies,
 990 dnl but we still need to set the conditionals
 991 AM_CONDITIONAL(USE_AALIB, false)
 992 AM_CONDITIONAL(USE_ANNODEX, false)
 993 AM_CONDITIONAL(USE_BZ2, false)
 994 AM_CONDITIONAL(USE_CAIRO, false)
 995 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 996 AM_CONDITIONAL(USE_DV1394, false)
 997 AM_CONDITIONAL(USE_ESD, false)
 998 AM_CONDITIONAL(USE_FLAC, false)
 999 AM_CONDITIONAL(USE_GCONF, false)
1000 AM_CONDITIONAL(USE_GCONFTOOL, false)
1001 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
1002 AM_CONDITIONAL(USE_GST_V4L2, false)
1003 AM_CONDITIONAL(USE_HAL, false)
1004 AM_CONDITIONAL(USE_JPEG, false)
1005 AM_CONDITIONAL(USE_LIBCACA, false)
1006 AM_CONDITIONAL(USE_LIBDV, false)
1007 AM_CONDITIONAL(USE_LIBPNG, false)
1008 AM_CONDITIONAL(USE_OSS, false)
1009 AM_CONDITIONAL(USE_OSS4, false)
1010 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1011 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1012 AM_CONDITIONAL(USE_PULSE, false)
1013 AM_CONDITIONAL(USE_SHOUT2, false)
1014 AM_CONDITIONAL(USE_SOUP, false)
1015 AM_CONDITIONAL(USE_SPEEX, false)
1016 AM_CONDITIONAL(USE_SUNAUDIO, false)
1017 AM_CONDITIONAL(USE_TAGLIB, false)
1018 AM_CONDITIONAL(USE_WAVPACK, false)
1019 AM_CONDITIONAL(USE_X, false)
1020 AM_CONDITIONAL(USE_XSHM, false)
1021 AM_CONDITIONAL(USE_XVIDEO, false)
1022 AM_CONDITIONAL(USE_ZLIB, false)
1023
1024 fi dnl of EXT plugins
1025
1026 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1027
1028 dnl Overview:
1029 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1030 dnl GST_*:              flags shared by all built objects
1031 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1032 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1033 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1034 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1035
1036 dnl GST_OPTION_CFLAGS
1037 if test "x$USE_DEBUG" = xyes; then
1038    PROFILE_CFLAGS="-g"
1039 fi
1040 AC_SUBST(PROFILE_CFLAGS)
1041
1042 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1043   dnl Define _only_ for git (not pre-releases or releases)
1044   dnl FIXME: temporarily disabled: DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1045   DEPRECATED_CFLAGS=""
1046 else
1047   DEPRECATED_CFLAGS=""
1048 fi
1049 AC_SUBST(DEPRECATED_CFLAGS)
1050
1051 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
1052 dnl at make time with e.g. make ERROR_CFLAGS=""
1053 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1054 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1055 AC_SUBST(GST_OPTION_CFLAGS)
1056 AC_SUBST(GST_OPTION_CXXFLAGS)
1057
1058 dnl our libraries need to be versioned correctly
1059 AC_SUBST(GST_LT_LDFLAGS)
1060
1061 dnl FIXME: do we want to rename to GST_ALL_* ?
1062 dnl prefer internal headers to already installed ones
1063 dnl also add builddir include for enumtypes and marshal
1064 dnl add ERROR_CFLAGS, but overridable
1065 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1066 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1067 AC_SUBST(GST_CFLAGS)
1068 AC_SUBST(GST_CXXFLAGS)
1069 AC_SUBST(GST_LIBS)
1070
1071 dnl LDFLAGS really should only contain flags, not libs - they get added before
1072 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1073 GST_ALL_LDFLAGS="-no-undefined"
1074 AC_SUBST(GST_ALL_LDFLAGS)
1075
1076 dnl this really should only contain flags, not libs - they get added before
1077 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1078 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
1079 AC_SUBST(GST_PLUGIN_LDFLAGS)
1080
1081 dnl *** output files ***
1082
1083 dnl keep this alphabetic per directory, please
1084 AC_CONFIG_FILES(
1085 Makefile
1086 gst/Makefile
1087 gst/alpha/Makefile
1088 gst/apetag/Makefile
1089 gst/audiofx/Makefile
1090 gst/auparse/Makefile
1091 gst/autodetect/Makefile
1092 gst/avi/Makefile
1093 gst/cutter/Makefile
1094 gst/deinterlace/Makefile
1095 gst/debugutils/Makefile
1096 gst/effectv/Makefile
1097 gst/equalizer/Makefile
1098 gst/flv/Makefile
1099 gst/id3demux/Makefile
1100 gst/icydemux/Makefile
1101 gst/imagefreeze/Makefile
1102 gst/interleave/Makefile
1103 gst/goom/Makefile
1104 gst/goom2k1/Makefile
1105 gst/law/Makefile
1106 gst/level/Makefile
1107 gst/matroska/Makefile
1108 gst/monoscope/Makefile
1109 gst/multifile/Makefile
1110 gst/multipart/Makefile
1111 gst/qtdemux/Makefile
1112 gst/replaygain/Makefile
1113 gst/rtp/Makefile
1114 gst/rtpmanager/Makefile
1115 gst/rtsp/Makefile
1116 gst/shapewipe/Makefile
1117 gst/smpte/Makefile
1118 gst/spectrum/Makefile
1119 gst/udp/Makefile
1120 gst/videobox/Makefile
1121 gst/videocrop/Makefile
1122 gst/videofilter/Makefile
1123 gst/videomixer/Makefile
1124 gst/wavenc/Makefile
1125 gst/wavparse/Makefile
1126 gst/flx/Makefile
1127 gst/y4m/Makefile
1128 ext/jpeg/Makefile
1129 ext/Makefile
1130 ext/aalib/Makefile
1131 ext/annodex/Makefile
1132 ext/cairo/Makefile
1133 ext/dv/Makefile
1134 ext/esd/Makefile
1135 ext/flac/Makefile
1136 ext/gconf/Makefile
1137 ext/gdk_pixbuf/Makefile
1138 ext/hal/Makefile
1139 ext/libcaca/Makefile
1140 ext/libpng/Makefile
1141 ext/pulse/Makefile
1142 ext/raw1394/Makefile
1143 ext/shout2/Makefile
1144 ext/soup/Makefile
1145 ext/speex/Makefile
1146 ext/taglib/Makefile
1147 ext/wavpack/Makefile
1148 sys/Makefile
1149 sys/directsound/Makefile
1150 sys/oss/Makefile
1151 sys/oss4/Makefile
1152 sys/osxaudio/Makefile
1153 sys/osxvideo/Makefile
1154 sys/sunaudio/Makefile
1155 sys/v4l2/Makefile
1156 sys/waveform/Makefile
1157 sys/ximage/Makefile
1158 po/Makefile.in
1159 tests/Makefile
1160 tests/check/Makefile
1161 tests/examples/Makefile
1162 tests/examples/audiofx/Makefile
1163 tests/examples/equalizer/Makefile
1164 tests/examples/level/Makefile
1165 tests/examples/rtp/Makefile
1166 tests/examples/shapewipe/Makefile
1167 tests/examples/spectrum/Makefile
1168 tests/examples/v4l2/Makefile
1169 tests/files/Makefile
1170 tests/icles/Makefile
1171 gconf/Makefile
1172 gconf/gstreamer.schemas
1173 common/Makefile
1174 common/m4/Makefile
1175 m4/Makefile
1176 docs/Makefile
1177 docs/plugins/Makefile
1178 docs/version.entities
1179 pkgconfig/Makefile
1180 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1181 gst-plugins-good.spec
1182 )
1183
1184 dnl Create the config.h file for Visual Studio builds
1185 dnl Beware of spaces and /'s in some of the shell variable contents.
1186 sed \
1187     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1188     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1189     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1190     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1191     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1192     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1193     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1194     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1195     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1196     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1197     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1198     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1199     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1200     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1201     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1202     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1203     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1204     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1205     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1206     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1207     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1208     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1209     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1210     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1211     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1212     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1213     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1214     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1215     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1216     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1217     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1218     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
1219     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1220     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1221     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1222     config.h.in >win32/common/config.h-new
1223
1224 AC_OUTPUT
1225
1226 AG_GST_OUTPUT_PLUGINS
1227 ORC_OUTPUT
1228