configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [43])
  34 m4_define([glib_micro_version], [91])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   CARBON_LIBS="-Wl,-framework,Carbon"
 217   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 218 ], [CARBON_LIBS=""])
 219
 220 AC_SUBST([CARBON_LIBS])
 221
 222 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   COCOA_LIBS="-Wl,-framework,Foundation"
 225   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 226 ], [COCOA_LIBS=""])
 227
 228 AC_SUBST([COCOA_LIBS])
 229
 230 dnl declare --enable-* args and collect ac_help strings
 231 AC_ARG_ENABLE(debug,
 232               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 233                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 234               enable_debug=glib_debug_default)
 235
 236 AC_ARG_ENABLE(gc_friendly,
 237               [AS_HELP_STRING([--enable-gc-friendly],
 238                               [turn on garbage collector friendliness [default=no]])],,
 239               [enable_gc_friendly=no])
 240 AC_ARG_ENABLE(mem_pools,
 241               [AS_HELP_STRING([--disable-mem-pools],
 242                               [disable all glib memory pools])],,
 243               [disable_mem_pools=no])
 244 AC_ARG_ENABLE(rebuilds,
 245               [AS_HELP_STRING([--disable-rebuilds],
 246                               [disable all source autogeneration rules])],,
 247               [enable_rebuilds=yes])
 248
 249 GLIB_TESTS
 250
 251 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 252 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 253   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 254   AC_MSG_RESULT([yes])
 255 ], [ AC_MSG_RESULT([no]) ])
 256
 257 AC_MSG_CHECKING([whether to disable memory pools])
 258 AS_IF([test "x$disable_mem_pools" = "xno"], [
 259   AC_MSG_RESULT([no])
 260 ], [
 261   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 262   AC_MSG_RESULT([yes])
 263 ])
 264
 265 dnl location to install runtime libraries, e.g. ../../lib to install
 266 dnl to /lib if libdir is /usr/lib
 267 AC_ARG_WITH(runtime-libdir,
 268            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 269                            [install runtime libraries relative to libdir])],
 270            [],
 271            [with_runtime_libdir=""])
 272 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 273 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 274 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 275 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 276 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 277
 278 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 279 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 280 AC_LANG_SAVE
 281 AC_LANG_CPLUSPLUS
 282 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 283 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 284 AC_LANG_RESTORE
 285
 286 AM_PROG_CC_C_O
 287 AC_PROG_INSTALL
 288
 289 AC_SYS_LARGEFILE
 290
 291 PKG_PROG_PKG_CONFIG(0.16)
 292
 293 if test "x$enable_debug" = "xyes"; then
 294   if test "x$cflags_set" != "x" ; then
 295       case " $CFLAGS " in
 296       *[[\ \    ]]-g[[\ \       ]]*) ;;
 297       *) CFLAGS="$CFLAGS -g" ;;
 298       esac
 299   fi
 300   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 301 else
 302   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 303
 304   if test "x$enable_debug" = "xno"; then
 305     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 306   fi
 307 fi
 308
 309 # Ensure MSVC-compatible struct packing convention is used when
 310 # compiling for Win32 with gcc.
 311 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 312 # gcc2 uses "-fnative-struct".
 313 if test x"$glib_native_win32" = xyes; then
 314   if test x"$GCC" = xyes; then
 315     msnative_struct=''
 316     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 317     if test -z "$ac_cv_prog_CC"; then
 318       our_gcc="$CC"
 319     else
 320       our_gcc="$ac_cv_prog_CC"
 321     fi
 322     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 323       2.)
 324         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 325           msnative_struct='-fnative-struct'
 326         fi
 327         ;;
 328       *)
 329         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 330           msnative_struct='-mms-bitfields'
 331         fi
 332         ;;
 333     esac
 334     if test x"$msnative_struct" = x ; then
 335       AC_MSG_RESULT([no way])
 336       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 337     else
 338       CFLAGS="$CFLAGS $msnative_struct"
 339       AC_MSG_RESULT([${msnative_struct}])
 340     fi
 341   fi
 342 fi
 343 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 344 AC_SUBST(GLIB_EXTRA_CFLAGS)
 345
 346 AC_EXEEXT
 347
 348 # define a MAINT-like variable REBUILD which is set if Perl
 349 # and awk are found, so autogenerated sources can be rebuilt
 350 AC_PROG_AWK
 351 AC_CHECK_PROGS(PERL, [perl5 perl])
 352 # We would like indent, but don't require it.
 353 AC_CHECK_PROG(INDENT, indent, indent)
 354 REBUILD=\#
 355 if test "x$enable_rebuilds" = "xyes" && \
 356      test -n "$PERL" && \
 357      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 358      test -n "$AWK" ; then
 359   REBUILD=
 360 fi
 361 AC_SUBST(REBUILD)
 362
 363 # Need full path to Perl for glib-mkenums
 364 #
 365 if test "x$PERL" != x ; then
 366   AC_PATH_PROG(PERL_PATH, [$PERL])
 367 fi
 368 if test "x$PERL_PATH" = x ; then
 369   PERL_PATH="/usr/bin/env perl"
 370 fi
 371 AC_SUBST(PERL_PATH)
 372
 373 # option to specify python interpreter to use; this just sets $PYTHON, so that
 374 # we will fallback to reading $PYTHON if --with-python is not given, and
 375 # python.m4 will get the expected input
 376 AC_ARG_WITH(python,
 377             AS_HELP_STRING([--with-python=PATH],
 378                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 379             [PYTHON="$withval"], [])
 380 if test x"$PYTHON" = xyes; then
 381   AC_MSG_ERROR([--with-python option requires a path or program argument])
 382 fi
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 dnl
 433 dnl zlib support
 434 dnl
 435 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 436 AS_IF([test "x$found_zlib" = "xno"], [
 437   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 438   if test "x$found_zlib" = "xno" ; then
 439     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 440   fi
 441   ZLIB_LIBS='-lz'
 442   AC_SUBST(ZLIB_LIBS)
 443 ])
 444
 445 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 446 AC_SUBST(LIBFFI_CFLAGS)
 447 AC_SUBST(LIBFFI_LIBS)
 448
 449 dnl
 450 dnl gettext support
 451 dnl
 452
 453 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 454 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 455 GLIB_GNU_GETTEXT
 456
 457 if test "$gt_cv_have_gettext" != "yes" ; then
 458   AC_MSG_ERROR([
 459 *** You must have either have gettext support in your C library, or use the
 460 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 461 ])
 462 fi
 463
 464 LIBS="$INTLLIBS $LIBS"
 465
 466 GETTEXT_PACKAGE=glib20
 467 AC_SUBST(GETTEXT_PACKAGE)
 468 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 469   [Define the gettext package to be used])
 470
 471 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 472
 473 dnl
 474 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 475 dnl
 476
 477 AS_IF([test x"$glib_native_win32" != xyes], [
 478   if test x$with_libiconv != xno ; then
 479     case " $INTLLIBS " in
 480     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 481     *) ICONV_LIBS="-liconv" ;;
 482     esac
 483   fi
 484 ])
 485 AC_SUBST(ICONV_LIBS)
 486
 487 case $with_libiconv in
 488   gnu)
 489     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 490     ;;
 491   native)
 492     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 493     ;;
 494 esac
 495
 496 dnl Initialize libtool
 497 LT_PREREQ([2.2])
 498 LT_INIT([disable-static win32-dll])
 499 dnl when using libtool 2.x create libtool early, because it's used in configure
 500 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 501
 502
 503 AS_IF([test "$glib_native_win32" = "yes"], [
 504   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 505     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 506   fi
 507   if test x$enable_static = xyes; then
 508     glib_win32_static_compilation=yes
 509     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 510 #define GOBJECT_STATIC_COMPILATION 1"
 511     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 512   fi
 513 ])
 514 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 515
 516 # Checks for library functions.
 517 AC_FUNC_ALLOCA
 518 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 519 AC_CHECK_FUNCS(timegm gmtime_r)
 520
 521 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 522   [AC_TRY_LINK([#include <unistd.h>
 523     extern int __libc_enable_secure;],
 524     [return __libc_enable_secure;],
 525    glib_cv_have_libc_enable_secure=yes,
 526    glib_cv_have_libc_enable_secure=no)])
 527 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 528    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 529      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 530 ])
 531
 532 AC_CHECK_SIZEOF(char)
 533 AC_CHECK_SIZEOF(short)
 534 AC_CHECK_SIZEOF(long)
 535 AC_CHECK_SIZEOF(int)
 536 AC_CHECK_SIZEOF(void *)
 537 AC_CHECK_SIZEOF(long long)
 538 AC_CHECK_SIZEOF(__int64)
 539
 540 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 541   [AC_TRY_LINK([#include <signal.h>
 542      #include <sys/types.h>
 543      sig_atomic_t val = 42;],
 544     [return val == 42 ? 0 : 1],
 545    ac_cv_type_sig_atomic_t=yes,
 546    ac_cv_type_sig_atomic_t=no)])
 547 if test x$ac_cv_type_sig_atomic_t = xyes; then
 548    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 549      [Define if you have the 'sig_atomic_t' type.])
 550 fi
 551
 552 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 553   :
 554 else
 555   AC_MSG_ERROR([
 556 *** GLib requires a 64 bit type. You might want to consider
 557 *** using the GNU C compiler.
 558 ])
 559 fi
 560
 561 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 562         # long long is a 64 bit integer.
 563         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 564         AC_CACHE_VAL(glib_cv_long_long_format,[
 565                 for format in ll q I64; do
 566                   AC_TRY_RUN([#include <stdio.h>
 567                         int main()
 568                         {
 569                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 570                           char buffer[1000];
 571                           sprintf (buffer, "%${format}u", a);
 572                           sscanf (buffer, "%${format}u", &b);
 573                           exit (b!=a);
 574                         }
 575                         ],
 576                         [glib_cv_long_long_format=${format}
 577                         break],
 578                         [],[:])
 579                 done])
 580         AS_IF([ test -n "$glib_cv_long_long_format"], [
 581           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 582           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 583           if test x"$glib_cv_long_long_format" = xI64; then
 584             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 585           fi
 586         ], [AC_MSG_RESULT(none)])
 587 ],[ test x$ac_cv_sizeof___int64 = x8], [
 588         # __int64 is a 64 bit integer.
 589         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 590         # We know this is MSVCRT.DLL, and what the formats are
 591         glib_cv_long_long_format=I64
 592         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 593         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 594         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 595 ])
 596
 597 AC_C_CONST
 598
 599 dnl
 600 dnl check in which direction the stack grows
 601 dnl
 602 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 603         AC_TRY_RUN([
 604         volatile int *a = 0, *b = 0;
 605         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 606         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 607         ],
 608         glib_cv_stack_grows=yes
 609         ,
 610         glib_cv_stack_grows=no
 611         ,)
 612 ])
 613
 614 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 615 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 616 dnl actually supported.
 617 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 618         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 619         __inline int foo () { return 0; }
 620         int main () { return foo (); }
 621         ]])],
 622         glib_cv_has__inline=yes
 623         ,
 624         glib_cv_has__inline=no
 625         ,)
 626 ])
 627 case x$glib_cv_has__inline in
 628 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 629 esac
 630 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 631         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 632         __inline__ int foo () { return 0; }
 633         int main () { return foo (); }
 634         ]])],
 635         glib_cv_has__inline__=yes
 636         ,
 637         glib_cv_has__inline__=no
 638         ,)
 639 ])
 640 case x$glib_cv_has__inline__ in
 641 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 642 esac
 643 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 644         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 645         #undef inline
 646         inline int foo () { return 0; }
 647         int main () { return foo (); }
 648         ]])],
 649         glib_cv_hasinline=yes
 650         ,
 651         glib_cv_hasinline=no
 652         ,)
 653 ])
 654 case x$glib_cv_hasinline in
 655 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 656 esac
 657
 658 # if we can use inline functions in headers
 659 AC_MSG_CHECKING(if inline functions in headers work)
 660 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 661 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 662 #  undef inline
 663 #  define inline __inline__
 664 #elif !defined (G_HAVE_INLINE)
 665 #  undef inline
 666 #  if defined (G_HAVE___INLINE__)
 667 #    define inline __inline__
 668 #  elif defined (G_HAVE___INLINE)
 669 #    define inline __inline
 670 #  endif
 671 #endif
 672
 673 int glib_test_func2 (int);
 674
 675 static inline int
 676 glib_test_func1 (void) {
 677   return glib_test_func2 (1);
 678 }
 679
 680 int
 681 main (void) {
 682   int i = 1;
 683 }]])],[g_can_inline=yes],[g_can_inline=no])
 684 AC_MSG_RESULT($g_can_inline)
 685
 686 # check for flavours of varargs macros
 687 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 688 AC_TRY_COMPILE([],[
 689 int a(int p1, int p2, int p3);
 690 #define call_a(...) a(1,__VA_ARGS__)
 691 call_a(2,3);
 692 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 693 AC_MSG_RESULT($g_have_iso_c_varargs)
 694
 695 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 696 AS_IF([test "$CXX" = ""], [
 697 dnl No C++ compiler
 698   g_have_iso_cxx_varargs=no
 699 else
 700   AC_LANG_CPLUSPLUS
 701   AC_TRY_COMPILE([],[
 702 int a(int p1, int p2, int p3);
 703 #define call_a(...) a(1,__VA_ARGS__)
 704 call_a(2,3);
 705 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 706   AC_LANG_C
 707 ])
 708 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 709
 710 AC_MSG_CHECKING(for GNUC varargs macros)
 711 AC_TRY_COMPILE([],[
 712 int a(int p1, int p2, int p3);
 713 #define call_a(params...) a(1,params)
 714 call_a(2,3);
 715 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 716 AC_MSG_RESULT($g_have_gnuc_varargs)
 717
 718 # check for GNUC visibility support
 719 AC_MSG_CHECKING(for GNUC visibility attribute)
 720 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 721 void
 722 __attribute__ ((visibility ("hidden")))
 723      f_hidden (void)
 724 {
 725 }
 726 void
 727 __attribute__ ((visibility ("internal")))
 728      f_internal (void)
 729 {
 730 }
 731 void
 732 __attribute__ ((visibility ("protected")))
 733      f_protected (void)
 734 {
 735 }
 736 void
 737 __attribute__ ((visibility ("default")))
 738      f_default (void)
 739 {
 740 }
 741 int main (void)
 742 {
 743         f_hidden();
 744         f_internal();
 745         f_protected();
 746         f_default();
 747         return 0;
 748 }
 749 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 750 AC_MSG_RESULT($g_have_gnuc_visibility)
 751 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 752
 753 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 754 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 755 #else
 756 # include "error: this is not Sun Studio."
 757 #endif
 758 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 759 AC_MSG_RESULT($g_have_sunstudio_visibility)
 760 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 761
 762 # check for bytesex stuff
 763 AC_C_BIGENDIAN
 764 if test x$ac_cv_c_bigendian = xuniversal ; then
 765   AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
 766 fi
 767
 768
 769 # check for header files
 770 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 771 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 772 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 773 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 774 AC_CHECK_HEADERS([linux/magic.h sys/prctl.h])
 775
 776 # Some versions of MSC lack these
 777 AC_CHECK_HEADERS([dirent.h sys/time.h])
 778
 779 # We don't care about this, but we need to keep including it in
 780 # glibconfig.h for backward compatibility
 781 AC_CHECK_HEADERS([values.h])
 782
 783 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 784 [#if HAVE_SYS_PARAM_H
 785  #include <sys/param.h>
 786  #endif
 787 ])
 788 AC_CHECK_FUNCS(sysctlbyname)
 789
 790 AC_HEADER_MAJOR
 791 AC_CHECK_HEADERS([xlocale.h])
 792
 793 # check for structure fields
 794 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 795 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 796 #include <sys/stat.h>
 797 #ifdef G_OS_UNIX
 798 #include <unistd.h>
 799 #endif
 800 #ifdef HAVE_SYS_STATFS_H
 801 #include <sys/statfs.h>
 802 #endif
 803 #ifdef HAVE_SYS_PARAM_H
 804 #include <sys/param.h>
 805 #endif
 806 #ifdef HAVE_SYS_MOUNT_H
 807 #include <sys/mount.h>
 808 #endif])
 809 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 810 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 811 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 812 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 813
 814 AC_STRUCT_DIRENT_D_TYPE
 815
 816 # Checks for libcharset
 817 AM_LANGINFO_CODESET
 818 gl_GLIBC21
 819
 820 # check additional type sizes
 821 AC_CHECK_SIZEOF(size_t)
 822
 823 dnl Try to figure out whether gsize should be long or int
 824 AC_MSG_CHECKING([for the appropriate definition for size_t])
 825
 826 case $ac_cv_sizeof_size_t in
 827   $ac_cv_sizeof_short)
 828       glib_size_type=short
 829       ;;
 830   $ac_cv_sizeof_int)
 831       glib_size_type=int
 832       ;;
 833   $ac_cv_sizeof_long)
 834       glib_size_type=long
 835       ;;
 836   $ac_cv_sizeof_long_long)
 837       glib_size_type='long long'
 838       ;;
 839   $ac_cv_sizeof__int64)
 840       glib_size_type='__int64'
 841       ;;
 842   *)  AC_MSG_ERROR([No type matching size_t in size])
 843       ;;
 844 esac
 845
 846 dnl If int/long are the same size, we see which one produces
 847 dnl warnings when used in the location as size_t. (This matters
 848 dnl on AIX with xlc)
 849 dnl
 850 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 851        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 852   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 853 #if defined(_AIX) && !defined(__GNUC__)
 854 #pragma options langlvl=stdc89
 855 #endif
 856 #include <stddef.h>
 857 int main ()
 858 {
 859   size_t s = 1;
 860   unsigned int *size_int = &s;
 861   return (int)*size_int;
 862 }
 863     ]])],glib_size_type=int,
 864       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 865 #if defined(_AIX) && !defined(__GNUC__)
 866 #pragma options langlvl=stdc89
 867 #endif
 868 #include <stddef.h>
 869 int main ()
 870 {
 871    size_t s = 1;
 872    unsigned long *size_long = &s;
 873    return (int)*size_long;
 874 }
 875         ]])],glib_size_type=long)])
 876 ])
 877
 878 AC_MSG_RESULT(unsigned $glib_size_type)
 879
 880 AC_CHECK_SIZEOF(ssize_t)
 881
 882 dnl Try to figure out whether gssize should be long or int
 883 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 884
 885 case $ac_cv_sizeof_ssize_t in
 886   $ac_cv_sizeof_short)
 887       glib_ssize_type=short
 888       ;;
 889   $ac_cv_sizeof_int)
 890       glib_ssize_type=int
 891       ;;
 892   $ac_cv_sizeof_long)
 893       glib_ssize_type=long
 894       ;;
 895   $ac_cv_sizeof_long_long)
 896       glib_ssize_type='long long'
 897       ;;
 898   $ac_cv_sizeof__int64)
 899       glib_ssize_type='__int64'
 900       ;;
 901   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 902       ;;
 903 esac
 904
 905 dnl If int/long are the same size, we see which one produces
 906 dnl warnings when used in the location as ssize_t. (This matters
 907 dnl on Android where ssize_t is long and size_t is unsigned int)
 908 dnl
 909 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 910        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 911   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 912 #if defined(_AIX) && !defined(__GNUC__)
 913 #pragma options langlvl=stdc89
 914 #endif
 915 #include <stddef.h>
 916 #ifdef HAVE_INTTYPES_H
 917 # include <inttypes.h>
 918 #endif
 919 #ifdef HAVE_STDINT_H
 920 # include <stdint.h>
 921 #endif
 922 #include <sys/types.h>
 923 int main ()
 924 {
 925   ssize_t s = 1;
 926   int *size_int = &s;
 927   return (int)*size_int;
 928 }
 929     ]])],glib_ssize_type=int,
 930       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 931 #if defined(_AIX) && !defined(__GNUC__)
 932 #pragma options langlvl=stdc89
 933 #endif
 934 #include <stddef.h>
 935 #ifdef HAVE_INTTYPES_H
 936 # include <inttypes.h>
 937 #endif
 938 #ifdef HAVE_STDINT_H
 939 # include <stdint.h>
 940 #endif
 941 #include <sys/types.h>
 942 int main ()
 943 {
 944    ssize_t s = 1;
 945    long *size_long = &s;
 946    return (int)*size_long;
 947 }
 948         ]])],glib_ssize_type=long)])
 949 ])
 950
 951 AC_MSG_RESULT($glib_ssize_type)
 952
 953 # Check for some functions
 954 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 955 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 956 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 957 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 958 AC_CHECK_FUNCS(splice)
 959 AC_CHECK_FUNCS(prlimit)
 960
 961 # To avoid finding a compatibility unusable statfs, which typically
 962 # successfully compiles, but warns to use the newer statvfs interface:
 963 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 964 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 965
 966 AC_MSG_CHECKING([whether to use statfs or statvfs])
 967 # Some systems have both statfs and statvfs, pick the most "native" for these
 968 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 969    [
 970    # on solaris and irix, statfs doesn't even have the f_bavail field
 971    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 972       [ac_cv_func_statfs=no],
 973    # else, at least on linux, statfs is the actual syscall
 974       [ac_cv_func_statvfs=no])
 975    ])
 976
 977 AS_IF([test x$ac_cv_func_statfs = xyes],
 978       [
 979          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 980          AC_MSG_RESULT([statfs])
 981       ],
 982       [test x$ac_cv_func_statvfs = xyes],
 983       [
 984          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 985          AC_MSG_RESULT([statvfs])
 986       ],
 987       [  AC_MSG_RESULT([neither])])
 988
 989 AC_CHECK_HEADERS(crt_externs.h)
 990 AC_CHECK_FUNCS(_NSGetEnviron)
 991
 992 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
 993
 994 # Internet address families
 995 if test $glib_native_win32 = yes; then
 996   glib_inet_includes=["
 997 #include <winsock2.h>
 998   "]
 999 else
1000   glib_inet_includes=["
1001 #include <sys/types.h>
1002 #include <sys/socket.h>
1003   "]
1004 fi
1005
1006 glib_failed=false
1007 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1008 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1009 # winsock defines this even though it doesn't support it
1010 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1011 if $glib_failed ; then
1012   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1013 fi
1014
1015 glib_failed=false
1016 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1017 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1018 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1019 if $glib_failed ; then
1020   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1021 fi
1022
1023 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg)
1024
1025 AS_IF([test $glib_native_win32 = yes], [
1026   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1027   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1028   # they aren't present at run-time (on Windows 2000).
1029   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1030   AC_SUBST(WSPIAPI_INCLUDE)
1031 ], [
1032   # Android does not have C_IN in public headers, we define it wherever necessary
1033   AS_IF([test $glib_native_android != yes], [
1034     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1035     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1036                                         #include <arpa/nameser.h>],
1037                                        [int qclass = C_IN;])],
1038                       [AC_MSG_RESULT([no])],
1039                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1040                                                            #include <arpa/nameser.h>
1041                                                            #include <arpa/nameser_compat.h>],
1042                                                           [int qclass = C_IN;])],
1043                                          [AC_MSG_RESULT([yes])
1044                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1045                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1046   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1047
1048   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1049   NETWORK_LIBS=""
1050   AC_MSG_CHECKING([for res_query])
1051   AC_TRY_LINK([#include <sys/types.h>
1052                #include <netinet/in.h>
1053                #include <arpa/nameser.h>
1054                #include <resolv.h>
1055               ],[
1056                res_query("test", 0, 0, (void *)0, 0);
1057               ],[AC_MSG_RESULT([yes])],
1058               [save_libs="$LIBS"
1059                LIBS="-lresolv $LIBS"
1060                AC_TRY_LINK([#include <sys/types.h>
1061                             #include <netinet/in.h>
1062                             #include <arpa/nameser.h>
1063                             #include <resolv.h>
1064                            ],[
1065                             res_query("test", 0, 0, (void *)0, 0);
1066                            ],[AC_MSG_RESULT([in -lresolv])
1067                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1068                            [LIBS="-lbind $save_libs"
1069                             AC_TRY_LINK([#include <resolv.h>],
1070                                         [res_query("test", 0, 0, (void *)0, 0);],
1071                                         [AC_MSG_RESULT([in -lbind])
1072                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1073                                         [AC_MSG_ERROR(not found)])])
1074                LIBS="$save_libs"])
1075   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1076                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1077                                         [AC_MSG_ERROR(Could not find socket())]))
1078   save_libs="$LIBS"
1079   LIBS="$LIBS $NETWORK_LIBS"
1080   AC_MSG_CHECKING([for res_init])
1081   AC_TRY_LINK([#include <sys/types.h>
1082                #include <netinet/in.h>
1083                #include <arpa/nameser.h>
1084                #include <resolv.h>
1085               ],[
1086                res_init();
1087               ],[AC_MSG_RESULT([yes])
1088                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1089               ],[AC_MSG_RESULT([no])])
1090   LIBS="$save_libs"
1091 ])
1092 AC_SUBST(NETWORK_LIBS)
1093
1094 AC_CHECK_HEADER([linux/netlink.h],
1095                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1096                 [#include <sys/socket.h>])
1097 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1098
1099 AC_CHECK_TYPE([struct ip_mreqn], [
1100               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1101               [#include <netinet/in.h>])
1102
1103 case $host in
1104   *-*-solaris* )
1105      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1106      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1107      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1108      ;;
1109 esac
1110
1111 dnl
1112 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1113 dnl
1114 AS_IF([test "$ac_cv_func_statfs" = yes], [
1115   AC_MSG_CHECKING([number of arguments to statfs()])
1116   AC_TRY_COMPILE([#include <unistd.h>
1117   #ifdef HAVE_SYS_PARAM_H
1118   #include <sys/param.h>
1119   #endif
1120   #ifdef HAVE_SYS_VFS_H
1121   #include <sys/vfs.h>
1122   #endif
1123   #ifdef HAVE_SYS_MOUNT_H
1124   #include <sys/mount.h>
1125   #endif
1126   #ifdef HAVE_SYS_STATFS_H
1127   #include <sys/statfs.h>
1128   #endif], [struct statfs st;
1129   statfs(NULL, &st);],[
1130     AC_MSG_RESULT([2])
1131     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1132     AC_TRY_COMPILE([#include <unistd.h>
1133   #ifdef HAVE_SYS_PARAM_H
1134   #include <sys/param.h>
1135   #endif
1136   #ifdef HAVE_SYS_VFS_H
1137   #include <sys/vfs.h>
1138   #endif
1139   #ifdef HAVE_SYS_MOUNT_H
1140   #include <sys/mount.h>
1141   #endif
1142   #ifdef HAVE_SYS_STATFS_H
1143   #include <sys/statfs.h>
1144   #endif], [struct statfs st;
1145   statfs(NULL, &st, sizeof (st), 0);],[
1146       AC_MSG_RESULT([4])
1147       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1148       AC_MSG_RESULT(unknown)
1149       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1150 ])
1151
1152 dnl
1153 dnl open takes O_DIRECTORY as an option
1154 dnl
1155 AC_MSG_CHECKING([open() option O_DIRECTORY])
1156 AC_TRY_COMPILE([#include <fcntl.h>
1157 #include <sys/types.h>
1158 #include <sys/stat.h>],
1159 [open(0, O_DIRECTORY, 0);],[
1160         AC_MSG_RESULT([yes])
1161         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1162         AC_MSG_RESULT([no])])
1163
1164 #
1165 # Check whether to use an included printf
1166 #
1167 AC_FUNC_VSNPRINTF_C99
1168 AC_FUNC_PRINTF_UNIX98
1169
1170 AC_ARG_ENABLE(included-printf,
1171               [AS_HELP_STRING([--enable-included-printf],
1172                               [use included printf [default=auto]])],
1173               enable_included_printf="$enableval")
1174
1175 need_included_printf=no
1176 if test "x$enable_included_printf" = "xyes" ; then
1177   need_included_printf=yes
1178 fi
1179 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1180   need_included_printf=yes
1181 fi
1182 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1183   need_included_printf=yes
1184 fi
1185 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1186    test -z "$glib_cv_long_long_format" ; then
1187   need_included_printf=yes
1188 fi
1189
1190 if test "x$enable_included_printf" = "xno" &&
1191    test "x$need_included_printf" = "xyes" ; then
1192   AC_MSG_ERROR([
1193 *** Your C library's printf doesn't appear to have the features that
1194 *** GLib needs, but you specified --enable-included-printf=no.])
1195 fi
1196
1197 enable_included_printf=$need_included_printf
1198
1199 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1200 AS_IF([test "$enable_included_printf" != "yes"], [
1201   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1202 ], [
1203   if test -z "$glib_cv_long_long_format" ; then
1204     glib_cv_long_long_format="ll"
1205   fi
1206   AC_DEFINE(HAVE_VASPRINTF,1)
1207 ])
1208
1209 # Checks needed for gnulib vasnprintf
1210 bh_C_SIGNED
1211 jm_AC_TYPE_LONG_LONG
1212 gt_TYPE_LONGDOUBLE
1213 gt_TYPE_WCHAR_T
1214 gt_TYPE_WINT_T
1215 AC_TYPE_SIZE_T
1216 AC_CHECK_TYPES(ptrdiff_t)
1217 jm_AC_TYPE_INTMAX_T
1218 AC_CHECK_FUNCS([snprintf wcslen])
1219 AC_FUNC_SNPRINTF_C99
1220
1221 # Check if <sys/select.h> needs to be included for fd_set
1222 AC_MSG_CHECKING([for fd_set])
1223 AC_TRY_COMPILE([#include <sys/types.h>],
1224         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1225 AS_IF([test "$gtk_ok" = "yes"], [
1226     AC_MSG_RESULT([yes, found in sys/types.h])
1227 ], [
1228     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1229     if test "$gtk_ok" = "yes"; then
1230         # *** FIXME: give it a different name
1231         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1232         AC_MSG_RESULT([yes, found in sys/select.h])
1233     else
1234         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1235         AC_MSG_RESULT(no)
1236     fi
1237 ])
1238
1239 dnl Check for nl_langinfo and CODESET
1240 AC_LANG_SAVE
1241 AC_LANG_C
1242 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1243         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1244                        [char *codeset = nl_langinfo (CODESET);])],
1245                 [glib_cv_langinfo_codeset=yes],
1246                 [glib_cv_langinfo_codeset=no])])
1247 if test x$glib_cv_langinfo_codeset = xyes; then
1248   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1249 fi
1250
1251 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1252 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1253         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1254                  [char *str;
1255                  str = nl_langinfo (PM_STR);
1256                  str = nl_langinfo (D_T_FMT);
1257                  str = nl_langinfo (D_FMT);
1258                  str = nl_langinfo (T_FMT);
1259                  str = nl_langinfo (T_FMT_AMPM);
1260                  str = nl_langinfo (MON_1);
1261                  str = nl_langinfo (ABMON_12);
1262                  str = nl_langinfo (DAY_1);
1263                  str = nl_langinfo (ABDAY_7);])],
1264                 [glib_cv_langinfo_time=yes],
1265                 [glib_cv_langinfo_time=no])])
1266 if test x$glib_cv_langinfo_time = xyes; then
1267   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1268 fi
1269
1270 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1271 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1272         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1273                 [char *str;
1274                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1275                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1276                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1277                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1278                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1279                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1280                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1281                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1282                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1283                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1284                 [glib_cv_langinfo_outdigit=yes],
1285                 [glib_cv_langinfo_outdigit=no])])
1286 if test x$glib_cv_langinfo_outdigit = xyes; then
1287   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1288 fi
1289 AC_LANG_RESTORE
1290
1291 dnl ****************************************
1292 dnl *** posix_memalign                   ***
1293 dnl ****************************************
1294 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1295 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1296     glib_cv_compliant_posix_memalign=0
1297     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1298         AC_TRY_RUN([
1299                 #define _XOPEN_SOURCE 600
1300                 #include <stdlib.h> /* posix_memalign() should be defined here */
1301                 /* some systems break if #include <malloc.h> used */
1302                 static void test_memalign (size_t boundary, size_t size) {
1303                     void *mem = 0;
1304                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1305                         exit (1);
1306                     else
1307                       free (mem);
1308                 }
1309                 int main() {
1310                     test_memalign (  128,   128 - 2 * sizeof (void*));
1311                     test_memalign (  256,   256 - 2 * sizeof (void*));
1312                     test_memalign (  512,   512 - 2 * sizeof (void*));
1313                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1314                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1315                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1316                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1317                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1318                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1319                     exit (0); /* success */
1320                 }
1321                 ],
1322             [glib_cv_compliant_posix_memalign=1], [], [:])
1323       :
1324     fi
1325     ])
1326 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1327     AC_MSG_RESULT(yes)
1328     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1329 ], [
1330     AC_MSG_RESULT(no)
1331 ])
1332
1333
1334 dnl ****************************************
1335 dnl *** strlcpy/strlcat                  ***
1336 dnl ****************************************
1337 # Check for strlcpy
1338 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1339 AC_TRY_RUN([#include <stdlib.h>
1340 #include <string.h>
1341 int main() {
1342   char p[10];
1343   (void) strlcpy (p, "hi", 10);
1344   if (strlcat (p, "bye", 0) != 3)
1345     return 1;
1346   return 0;
1347 }], glib_cv_have_strlcpy=yes,
1348     glib_cv_have_strlcpy=no,
1349     glib_cv_have_strlcpy=no)])
1350 if test "$glib_cv_have_strlcpy" = "yes"; then
1351     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1352 fi
1353
1354
1355 dnl **********************
1356 dnl *** va_copy checks ***
1357 dnl **********************
1358 dnl we currently check for all three va_copy possibilities, so we get
1359 dnl all results in config.log for bug reports.
1360 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1361         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1362 #include <stdlib.h>
1363         void f (int i, ...) {
1364         va_list args1, args2;
1365         va_start (args1, i);
1366         va_copy (args2, args1);
1367         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1368           exit (1);
1369         va_end (args1); va_end (args2);
1370         }
1371         int main() {
1372           f (0, 42);
1373           return 0;
1374         }]])],
1375         [glib_cv_va_copy=yes],
1376         [glib_cv_va_copy=no])
1377 ])
1378 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1379         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1380 #include <stdlib.h>
1381         void f (int i, ...) {
1382         va_list args1, args2;
1383         va_start (args1, i);
1384         __va_copy (args2, args1);
1385         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1386           exit (1);
1387         va_end (args1); va_end (args2);
1388         }
1389         int main() {
1390           f (0, 42);
1391           return 0;
1392         }]])],
1393         [glib_cv___va_copy=yes],
1394         [glib_cv___va_copy=no])
1395 ])
1396
1397 if test "x$glib_cv_va_copy" = "xyes"; then
1398   g_va_copy_func=va_copy
1399 else if test "x$glib_cv___va_copy" = "xyes"; then
1400   g_va_copy_func=__va_copy
1401 fi
1402 fi
1403
1404 if test -n "$g_va_copy_func"; then
1405   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1406 fi
1407
1408 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1409         AC_TRY_RUN([#include <stdarg.h>
1410 #include <stdlib.h>
1411         void f (int i, ...) {
1412         va_list args1, args2;
1413         va_start (args1, i);
1414         args2 = args1;
1415         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1416           exit (1);
1417         va_end (args1); va_end (args2);
1418         }
1419         int main() {
1420           f (0, 42);
1421           return 0;
1422         }],
1423         [glib_cv_va_val_copy=yes],
1424         [glib_cv_va_val_copy=no],
1425         [glib_cv_va_val_copy=yes])
1426 ])
1427
1428 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1429   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1430 ])
1431
1432 dnl ***********************
1433 dnl *** g_module checks ***
1434 dnl ***********************
1435 G_MODULE_LIBS=
1436 G_MODULE_LIBS_EXTRA=
1437 G_MODULE_PLUGIN_LIBS=
1438 if test x"$glib_native_win32" = xyes; then
1439   dnl No use for this on Win32
1440   G_MODULE_LDFLAGS=
1441 else
1442   export SED
1443   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1444 fi
1445 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1446 G_MODULE_NEED_USCORE=0
1447 G_MODULE_BROKEN_RTLD_GLOBAL=0
1448 G_MODULE_HAVE_DLERROR=0
1449 dnl *** force native WIN32 shared lib loader
1450 if test -z "$G_MODULE_IMPL"; then
1451   case "$host" in
1452   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1453   esac
1454 fi
1455 dnl *** force native AIX library loader
1456 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1457 if test -z "$G_MODULE_IMPL"; then
1458   case "$host" in
1459   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1460   esac
1461 fi
1462 dnl *** dlopen() and dlsym() in system libraries
1463 AS_IF([ test -z "$G_MODULE_IMPL"], [
1464         AC_CHECK_FUNC(dlopen,
1465                       [AC_CHECK_FUNC(dlsym,
1466                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1467                       [])
1468 ])
1469 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1470 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1471         AC_CHECK_FUNC(NSLinkModule,
1472                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1473                        G_MODULE_NEED_USCORE=1],
1474                       [])
1475 ])
1476 dnl *** dlopen() and dlsym() in libdl
1477 AS_IF([ test -z "$G_MODULE_IMPL"], [
1478         AC_CHECK_LIB(dl, dlopen,
1479                      [AC_CHECK_LIB(dl, dlsym,
1480                                    [G_MODULE_LIBS=-ldl
1481                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1482                      [])
1483 ])
1484 dnl *** additional checks for G_MODULE_IMPL_DL
1485 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1486         LIBS_orig="$LIBS"
1487         LDFLAGS_orig="$LDFLAGS"
1488         LIBS="$G_MODULE_LIBS $LIBS"
1489         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1490 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1491         echo "void glib_plugin_test(void) { }" > plugin.c
1492         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1493                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1494         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1495                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1496                 -shrext ".o" -avoid-version plugin.lo \
1497                 -rpath /dont/care >/dev/null 2>&1
1498         eval `./libtool --config | grep ^objdir`
1499         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1500                 glib_cv_rtldglobal_broken,[
1501                 AC_TRY_RUN([
1502 #include <dlfcn.h>
1503 #ifndef RTLD_GLOBAL
1504 #  define RTLD_GLOBAL 0
1505 #endif
1506 #ifndef RTLD_LAZY
1507 #  define RTLD_LAZY 0
1508 #endif
1509 int glib_plugin_test;
1510 int main () {
1511     void *handle, *global, *local;
1512     global = &glib_plugin_test;
1513     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1514     if (!handle) return 0;
1515     local = dlsym (handle, "glib_plugin_test");
1516     return global == local;
1517 }                       ],
1518                         [glib_cv_rtldglobal_broken=no],
1519                         [glib_cv_rtldglobal_broken=yes],
1520                         [glib_cv_rtldglobal_broken=no])
1521                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1522                 rmdir ${objdir} 2>/dev/null
1523         ])
1524         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1525                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1526         else
1527                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1528         fi
1529 dnl *** check whether we need preceeding underscores
1530         AC_CACHE_CHECK([for preceeding underscore in symbols],
1531                 glib_cv_uscore,[
1532                 AC_TRY_RUN([#include <dlfcn.h>
1533                 int glib_underscore_test (void) { return 42; }
1534                 int main() {
1535                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1536                   handle = dlopen ((void*)0, 0);
1537                   if (handle) {
1538                     f1 = dlsym (handle, "glib_underscore_test");
1539                     f2 = dlsym (handle, "_glib_underscore_test");
1540                   } return (!f2 || f1);
1541                 }],
1542                         [glib_cv_uscore=yes],
1543                         [glib_cv_uscore=no],
1544                         [])
1545                 rm -f plugin.c plugin.$ac_objext plugin.lo
1546         ])
1547         GLIB_ASSERT_SET(glib_cv_uscore)
1548         if test "x$glib_cv_uscore" = "xyes"; then
1549                 G_MODULE_NEED_USCORE=1
1550         else
1551                 G_MODULE_NEED_USCORE=0
1552         fi
1553
1554         LDFLAGS="$LDFLAGS_orig"
1555 dnl *** check for having dlerror()
1556         AC_CHECK_FUNC(dlerror,
1557                 [G_MODULE_HAVE_DLERROR=1],
1558                 [G_MODULE_HAVE_DLERROR=0])
1559         LIBS="$LIBS_orig"
1560 ])
1561 dnl *** done, have we got an implementation?
1562 if test -z "$G_MODULE_IMPL"; then
1563         G_MODULE_IMPL=0
1564         G_MODULE_SUPPORTED=false
1565 else
1566         G_MODULE_SUPPORTED=true
1567 fi
1568
1569 AC_MSG_CHECKING(for the suffix of module shared libraries)
1570 export SED
1571 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1572 eval $shrext_cmds
1573 module=yes eval std_shrext=$shrext_cmds
1574 # chop the initial dot
1575 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1576 AC_MSG_RESULT(.$glib_gmodule_suffix)
1577 # any reason it may fail?
1578 if test "x$glib_gmodule_suffix" = x; then
1579         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1580 fi
1581
1582 AC_SUBST(G_MODULE_SUPPORTED)
1583 AC_SUBST(G_MODULE_IMPL)
1584 AC_SUBST(G_MODULE_LIBS)
1585 AC_SUBST(G_MODULE_LIBS_EXTRA)
1586 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1587 AC_SUBST(G_MODULE_LDFLAGS)
1588 AC_SUBST(G_MODULE_HAVE_DLERROR)
1589 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1590 AC_SUBST(G_MODULE_NEED_USCORE)
1591 AC_SUBST(GLIB_DEBUG_FLAGS)
1592
1593 dnl **********************
1594 dnl *** g_spawn checks ***
1595 dnl **********************
1596
1597 AC_MSG_CHECKING(for gspawn implementation)
1598 case "$host" in
1599   *-*-mingw*)
1600     GSPAWN=gspawn-win32.lo
1601     ;;
1602   *)
1603     GSPAWN=gspawn.lo
1604     ;;
1605 esac
1606 AC_MSG_RESULT($GSPAWN)
1607 AC_SUBST(GSPAWN)
1608
1609 dnl *************************
1610 dnl *** GIOChannel checks ***
1611 dnl *************************
1612
1613 AC_MSG_CHECKING(for GIOChannel implementation)
1614 case "$host" in
1615   *-*-mingw*)
1616     GIO=giowin32.lo
1617     ;;
1618   *)
1619     GIO=giounix.lo
1620     ;;
1621 esac
1622 AC_MSG_RESULT($GIO)
1623 AC_SUBST(GIO)
1624
1625 dnl *********************************
1626 dnl *** Directory for GIO modules ***
1627 dnl *********************************
1628
1629 AC_ARG_WITH(gio-module-dir,
1630            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1631                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1632            [],
1633            [with_gio_module_dir='${libdir}/gio/modules'])
1634 GIO_MODULE_DIR=$with_gio_module_dir
1635 AC_SUBST(GIO_MODULE_DIR)
1636
1637 dnl **********************************
1638 dnl *** Check for libselinux (GIO) ***
1639 dnl **********************************
1640 AC_ARG_ENABLE(selinux,
1641               AS_HELP_STRING([--disable-selinux],
1642                              [build without selinux support]))
1643 msg_selinux=no
1644 SELINUX_LIBS=
1645 AS_IF([ test "x$enable_selinux" != "xno"], [
1646
1647  AC_CHECK_LIB(selinux, is_selinux_enabled,
1648    [AC_CHECK_HEADERS(selinux/selinux.h,
1649      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1650        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1651         SELINUX_LIBS="-lselinux"
1652         msg_selinux=yes])
1653      ])
1654    ])
1655 ])
1656 AC_SUBST(SELINUX_LIBS)
1657
1658 dnl *****************************
1659 dnl ** Check for inotify (GIO) **
1660 dnl *****************************
1661 inotify_support=no
1662 AC_CHECK_HEADERS([sys/inotify.h],
1663 [
1664   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1665 ])
1666
1667 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1668
1669 dnl ****************************
1670 dnl ** Check for kqueue (GIO) **
1671 dnl ****************************
1672 kqueue_support=no
1673 AC_CHECK_HEADERS([sys/event.h],
1674 [
1675         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1676 ])
1677
1678 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1679
1680 dnl *********************************
1681 dnl ** Check for Solaris FEN (GIO) **
1682 dnl *********************************
1683 fen_support=no
1684 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1685 #include <port.h>
1686 #ifndef PORT_SOURCE_FILE
1687 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1688 #endif
1689 int main() { return 0; } ]])],
1690 [
1691         fen_support=yes
1692 ],)
1693
1694 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1695
1696 dnl ****************************
1697 dnl *** Checks for FAM (GIO) ***
1698 dnl ****************************
1699
1700 should_disable_fam=no
1701
1702 AC_ARG_ENABLE(fam,
1703               AS_HELP_STRING([--disable-fam],
1704                              [don't use fam for file system monitoring]),
1705                          [
1706                                 if test "x$enable_fam" = "xno"; then
1707                                         should_disable_fam=yes
1708                                 fi
1709                          ]
1710                          )
1711 fam_support=no
1712 FAM_LIBS=
1713 if test "x$should_disable_fam" = "xno"; then
1714 AC_CHECK_LIB(fam, FAMOpen,
1715   [AC_CHECK_HEADERS(fam.h,
1716     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1717      AC_CHECK_LIB(fam, FAMNoExists,
1718                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1719      FAM_LIBS="-lfam"]
1720      fam_support=yes,
1721     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1722   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1723 AC_SUBST(FAM_LIBS)
1724 fi
1725 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1726
1727
1728 dnl *****************************
1729 dnl *** Check for xattr (GIO) ***
1730 dnl *****************************
1731 AC_ARG_ENABLE(xattr,
1732               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1733 msg_xattr=no
1734 XATTR_LIBS=
1735 AS_IF([ test "x$enable_xattr" != "xno"], [
1736
1737 dnl either glibc or libattr can provide xattr support
1738
1739 dnl for both of them, we check for getxattr being in
1740 dnl the library and a valid xattr header.
1741
1742 dnl try glibc
1743  AC_CHECK_LIB(c, getxattr,
1744    [AC_CHECK_HEADERS(sys/xattr.h,
1745      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1746       msg_xattr=yes])
1747    ])
1748
1749   AS_IF([ test "x$msg_xattr" != "xyes"], [
1750 dnl   failure. try libattr
1751    AC_CHECK_LIB(attr, getxattr,
1752       [AC_CHECK_HEADERS(attr/xattr.h,
1753        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1754         XATTR_LIBS="-lattr"
1755         msg_xattr=yes])
1756       ])
1757   ])
1758
1759   AS_IF([ test "x$msg_xattr" = "xyes"], [
1760     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1761     AC_TRY_COMPILE([
1762       #include <stdio.h>
1763       #ifdef HAVE_SYS_TYPES_H
1764       #include <sys/types.h>
1765       #endif
1766       #ifdef HAVE_SYS_XATTR_H
1767       #include <sys/xattr.h>
1768       #elif HAVE_ATTR_XATTR_H
1769       #include <attr/xattr.h>
1770       #endif
1771     ],
1772     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1773     [
1774       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1775       AC_MSG_RESULT([yes])
1776     ],
1777     [AC_MSG_RESULT([no])]
1778     )
1779   ])
1780 ])
1781 AC_SUBST(XATTR_LIBS)
1782
1783 dnl ************************
1784 dnl *** check for libelf ***
1785 dnl ************************
1786 AC_ARG_ENABLE(libelf,
1787               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1788 AS_IF([ test "x$enable_libelf" != "xno"],[
1789 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1790 AS_IF([ test $have_libelf = maybe ], [
1791   glib_save_LIBS=$LIBS
1792   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1793   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1794   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1795   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1796   LIBS=$glib_save_LIBS
1797
1798   if test $have_libelf != no; then
1799     LIBELF_LIBS=-lelf
1800     have_libelf=yes
1801   fi
1802 ])
1803 ])
1804
1805 if test x$have_libelf = xyes; then
1806   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1807 fi
1808
1809 dnl ****************************************
1810 dnl *** platform dependent source checks ***
1811 dnl ****************************************
1812
1813 AC_MSG_CHECKING(for platform-dependent source)
1814 case "$host" in
1815   *-*-cygwin*|*-*-mingw*)
1816     PLATFORMDEP=gwin32.lo
1817     ;;
1818   *)
1819     PLATFORMDEP=
1820     ;;
1821 esac
1822 AC_MSG_RESULT($PLATFORMDEP)
1823 AC_SUBST(PLATFORMDEP)
1824
1825 AC_MSG_CHECKING([whether to compile timeloop])
1826 case "$host" in
1827   *-*-cygwin*|*-*-mingw*|*-*-minix)
1828     enable_timeloop=no
1829     ;;
1830   *)
1831     enable_timeloop=yes
1832     ;;
1833 esac
1834 AC_MSG_RESULT($enable_timeloop)
1835 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1836
1837 AC_MSG_CHECKING([if building for some Win32 platform])
1838 case "$host" in
1839   *-*-mingw*|*-*-cygwin*)
1840     platform_win32=yes
1841     ;;
1842   *)
1843     platform_win32=no
1844     ;;
1845 esac
1846 AC_MSG_RESULT($platform_win32)
1847 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1848
1849 dnl ***********************
1850 dnl *** g_thread checks ***
1851 dnl ***********************
1852
1853 AC_ARG_WITH(threads,
1854            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1855                            [specify a thread implementation to use])],
1856            [],
1857            [with_threads=yes])
1858
1859 dnl error and warning message
1860 dnl *************************
1861
1862 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1863
1864 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1865                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1866                 compilation now, but then your programs might not work.
1867                 Please provide information on how it is done on your system."
1868
1869 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1870                  "
1871
1872 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1873                   provide information on your thread implementation."
1874
1875 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1876                 functions will not be MT-safe during their first call because
1877                 there is no working 'getpwuid_r' on your system."
1878
1879 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1880                 because there is no 'localtime_r' on your system."
1881
1882 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1883                 linking threaded applications. As GLib cannot do that
1884                 automatically, you will get an linkg error everytime you are
1885                 not using the right compiler. In that case you have to relink
1886                 with the right compiler. Ususally just '_r' is appended
1887                 to the compiler name."
1888
1889 dnl determination of thread implementation
1890 dnl ***************************************
1891
1892 AC_MSG_CHECKING(for thread implementation)
1893
1894 have_threads=no
1895 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1896         AS_IF([ test "x$have_threads" = xno], [
1897                 AC_TRY_COMPILE([#include <pthread.h>],
1898                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1899                         have_threads=posix)
1900         ])
1901         # Tru64Unix requires -pthread to find pthread.h. See #103020
1902         if test "x$have_threads" = xno; then
1903                 glib_save_CPPFLAGS="$CPPFLAGS"
1904                 CPPFLAGS="$CPPFLAGS -pthread"
1905                 AC_TRY_COMPILE([#include <pthread.h>],
1906                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1907                        have_threads=posix)
1908                 CPPFLAGS="$glib_save_CPPFLAGS"
1909         fi
1910 ])
1911 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1912         case $host in
1913                 *-*-mingw*)
1914                 have_threads=win32
1915                 ;;
1916         esac
1917 fi
1918
1919 if test "x$have_threads" = xno; then
1920         AC_MSG_RESULT(none available)
1921         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1922 else
1923         AC_MSG_RESULT($have_threads)
1924 fi
1925
1926
1927 dnl determination of G_THREAD_CFLAGS
1928 dnl ********************************
1929
1930 G_THREAD_LIBS=
1931 G_THREAD_LIBS_EXTRA=
1932 G_THREAD_CFLAGS=
1933
1934 dnl
1935 dnl Test program for basic POSIX threads functionality
1936 dnl
1937 m4_define([glib_thread_test],[
1938 #include <pthread.h>
1939 int check_me = 0;
1940 void* func(void* data) {check_me = 42; return &check_me;}
1941 int main()
1942  { pthread_t t;
1943    void *ret;
1944    pthread_create (&t, $1, func, 0);
1945    pthread_join (t, &ret);
1946    return (check_me != 42 || ret != &check_me);
1947 }])
1948
1949 AS_IF([ test x"$have_threads" = xposix], [
1950   # First we test for posix, whether -pthread or -pthreads do the trick as
1951   # both CPPFLAG and LIBS.
1952   # One of them does for most gcc versions and some other platforms/compilers
1953   # too and could be considered as the canonical way to go.
1954   case $host in
1955     *-*-cygwin*|*-*-darwin*)
1956        # skip cygwin and darwin -pthread or -pthreads test
1957        ;;
1958     *-solaris*)
1959       # These compiler/linker flags work with both Sun Studio and gcc
1960       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1961       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1962       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1963       G_THREAD_LIBS="-lpthread -lthread"
1964       ;;
1965     *)
1966       for flag in pthread pthreads mt; do
1967         glib_save_CFLAGS="$CFLAGS"
1968         CFLAGS="$CFLAGS -$flag"
1969         AC_TRY_RUN(glib_thread_test(0),
1970                    glib_flag_works=yes,
1971                    glib_flag_works=no,
1972                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1973                                    glib_flag_works=yes,
1974                                    glib_flag_works=no)])
1975         CFLAGS="$glib_save_CFLAGS"
1976         if test $glib_flag_works = yes ; then
1977            G_THREAD_CFLAGS=-$flag
1978         G_THREAD_LIBS=-$flag
1979         break;
1980         fi
1981       done
1982        ;;
1983   esac
1984 ])
1985
1986 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1987
1988   # The canonical -pthread[s] does not work. Try something different.
1989
1990   case $host in
1991         *-aix*)
1992                 if test x"$GCC" = xyes; then
1993                         # GCC 3.0 and above needs -pthread.
1994                         # Should be coverd by the case above.
1995                         # GCC 2.x and below needs -mthreads
1996                         G_THREAD_CFLAGS="-mthreads"
1997                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1998                 else
1999                         # We are probably using the aix compiler. Normaly a
2000                         # program would have to be compiled with the _r variant
2001                         # of the corresponding compiler, but we as GLib cannot
2002                         # do that: but the good news is that for compiling the
2003                         # only difference is the added -D_THREAD_SAFE compile
2004                         # option. This is according to the "C for AIX User's
2005                         # Guide".
2006                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2007                 fi
2008                 ;;
2009         *-sysv5uw7*) # UnixWare 7
2010                 # We are not using gcc with -pthread. Catched above.
2011                 G_THREAD_CFLAGS="-Kthread"
2012                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2013                 ;;
2014         *-mingw*)
2015                 # No flag needed when using MSVCRT.DLL
2016                 G_THREAD_CFLAGS=""
2017                 ;;
2018         *)
2019                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2020                 ;;
2021   esac
2022 ])
2023
2024 # if we are not finding the localtime_r function, then we probably are
2025 # not using the proper multithread flag
2026
2027 glib_save_CPPFLAGS="$CPPFLAGS"
2028 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2029
2030 # First we test, whether localtime_r is declared in time.h
2031 # directly. Then we test whether a macro localtime_r exists, in
2032 # which case localtime_r in the test program is replaced and thus
2033 # if we still find localtime_r in the output, it is not defined as
2034 # a macro.
2035
2036 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2037   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2038                                                            localtime_r(a,b)],
2039                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2040
2041 CPPFLAGS="$glib_save_CPPFLAGS"
2042
2043 AC_MSG_CHECKING(thread related cflags)
2044 AC_MSG_RESULT($G_THREAD_CFLAGS)
2045 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2046
2047 dnl determination of G_THREAD_LIBS
2048 dnl ******************************
2049
2050 AS_IF([test x$have_threads = xposix], [
2051           glib_save_CPPFLAGS="$CPPFLAGS"
2052           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2053           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2054             case $host in
2055               *-aix*)
2056                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2057                 # probably using the aix compiler.
2058                 AC_MSG_WARN($AIX_COMPILE_INFO)
2059                 ;;
2060               *)
2061                 G_THREAD_LIBS=error
2062                 glib_save_LIBS="$LIBS"
2063                 for thread_lib in "" pthread pthread32 pthreads thread; do
2064                         if test x"$thread_lib" = x; then
2065                                 add_thread_lib=""
2066                                 IN=""
2067                         else
2068                                 add_thread_lib="-l$thread_lib"
2069                                 IN=" in -l$thread_lib"
2070                         fi
2071                         if test x"$have_threads" = xposix; then
2072                                 defattr=0
2073                         else
2074                                 defattr=pthread_attr_default
2075                         fi
2076
2077                         LIBS="$add_thread_lib $glib_save_LIBS"
2078
2079                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2080                         AC_TRY_RUN(glib_thread_test($defattr),
2081                                    glib_result=yes,
2082                                    glib_result=no,
2083                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2084                                                    glib_result=yes,
2085                                                    glib_result=no)])
2086                         AC_MSG_RESULT($glib_result)
2087
2088                         if test "$glib_result" = "yes" ; then
2089                           G_THREAD_LIBS="$add_thread_lib"
2090                           break
2091                         fi
2092                 done
2093                 if test "x$G_THREAD_LIBS" = xerror; then
2094                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2095                 fi
2096                 LIBS="$glib_save_LIBS"
2097                 ;;
2098             esac
2099           ])
2100
2101           g_threads_impl="POSIX"
2102           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2103           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2104           CPPFLAGS="$glib_save_CPPFLAGS"
2105 ], [test x$have_threads = xwin32], [
2106            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2107            g_threads_impl="WIN32"
2108 ], [
2109            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2110            g_threads_impl="NONE"
2111            G_THREAD_LIBS=error
2112 ])
2113 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2114 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2115 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2116
2117 if test "x$G_THREAD_LIBS" = xerror; then
2118         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2119 fi
2120
2121 AC_MSG_CHECKING(thread related libraries)
2122 AC_MSG_RESULT($G_THREAD_LIBS)
2123
2124 dnl check for mt safe function variants and some posix functions
2125 dnl ************************************************************
2126
2127 glib_save_LIBS="$LIBS"
2128 # we are not doing the following for now, as this might require glib
2129 # to always be linked with the thread libs on some platforms.
2130 # LIBS="$LIBS $G_THREAD_LIBS"
2131 AC_CHECK_FUNCS(localtime_r gmtime_r)
2132 AS_IF([ test "$glib_native_win32" != "yes"], [
2133         AC_CACHE_CHECK([for posix getpwuid_r],
2134                 ac_cv_func_posix_getpwuid_r,
2135                 [AC_TRY_RUN([
2136 #include <errno.h>
2137 #include <pwd.h>
2138 int main () {
2139     char buffer[10000];
2140     struct passwd pwd, *pwptr = &pwd;
2141     int error;
2142     errno = 0;
2143     error = getpwuid_r (0, &pwd, buffer,
2144                         sizeof (buffer), &pwptr);
2145    return (error < 0 && errno == ENOSYS)
2146            || error == ENOSYS;
2147 }                               ],
2148                         [ac_cv_func_posix_getpwuid_r=yes],
2149                         [ac_cv_func_posix_getpwuid_r=no])])
2150         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2151         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2152                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2153                         [Have POSIX function getpwuid_r])
2154         else
2155                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2156                         ac_cv_func_nonposix_getpwuid_r,
2157                         [AC_TRY_LINK([#include <pwd.h>],
2158                                 [char buffer[10000];
2159                                 struct passwd pwd;
2160                                 getpwuid_r (0, &pwd, buffer,
2161                                                 sizeof (buffer));],
2162                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2163                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2164                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2165                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2166                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2167                                 [Have non-POSIX function getpwuid_r])
2168                 fi
2169         fi
2170 ])
2171 AS_IF([ test "$glib_native_win32" != "yes"], [
2172         AC_CACHE_CHECK([for posix getgrgid_r],
2173                 ac_cv_func_posix_getgrgid_r,
2174                 [AC_TRY_RUN([
2175 #include <errno.h>
2176 #include <grp.h>
2177 int main () {
2178     char buffer[10000];
2179     struct group grp, *grpptr = &grp;
2180     int error;
2181     errno = 0;
2182     error = getgrgid_r (0, &grp, buffer,
2183                         sizeof (buffer), &grpptr);
2184    return (error < 0 && errno == ENOSYS)
2185            || error == ENOSYS;
2186 }                              ],
2187                        [ac_cv_func_posix_getgrgid_r=yes],
2188                        [ac_cv_func_posix_getgrgid_r=no])])
2189         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2190         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2191                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2192                         [Have POSIX function getgrgid_r])
2193         ], [
2194                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2195                         ac_cv_func_nonposix_getgrgid_r,
2196                         [AC_TRY_LINK([#include <grp.h>],
2197                                 [char buffer[10000];
2198                                 struct group grp;
2199                                 getgrgid_r (0, &grp, buffer,
2200                                 sizeof (buffer));],
2201                         [ac_cv_func_nonposix_getgrgid_r=yes],
2202                         [ac_cv_func_nonposix_getgrgid_r=no])])
2203                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2204                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2205                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2206                                 [Have non-POSIX function getgrgid_r])
2207                 fi
2208         ])
2209 ])
2210 LIBS="$G_THREAD_LIBS $LIBS"
2211 AS_IF([ test x"$have_threads" = xposix], [
2212         glib_save_CPPFLAGS="$CPPFLAGS"
2213         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2214         # This is not AC_CHECK_FUNC to also work with function
2215         # name mangling in header files.
2216         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2217         AC_LINK_IFELSE(
2218             [AC_LANG_PROGRAM(
2219                 [#include <pthread.h>],
2220                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2221             [AC_MSG_RESULT(yes)
2222              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2223                 [Have function pthread_attr_setstacksize])],
2224             [AC_MSG_RESULT(no)])
2225         AC_MSG_CHECKING(for pthread_condattr_setclock)
2226         AC_LINK_IFELSE(
2227             [AC_LANG_PROGRAM(
2228                 [#include <pthread.h>],
2229                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2230             [AC_MSG_RESULT(yes)
2231              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2232                 [Have function pthread_condattr_setclock])],
2233             [AC_MSG_RESULT(no)])
2234         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2235         AC_LINK_IFELSE(
2236             [AC_LANG_PROGRAM(
2237                 [#include <pthread.h>],
2238                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2239             [AC_MSG_RESULT(yes)
2240              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2241                 [Have function pthread_cond_timedwait_relative_np])],
2242             [AC_MSG_RESULT(no)])
2243         dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2244         AC_MSG_CHECKING(for pthread_setname_np(const char*))
2245         AC_LINK_IFELSE(
2246             [AC_LANG_PROGRAM(
2247                 [#include <pthread.h>],
2248                 [pthread_setname_np("example")])],
2249             [AC_MSG_RESULT(yes)
2250              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2251                 [Have function pthread_setname_np(const char*)])],
2252             [AC_MSG_RESULT(no)])
2253         CPPFLAGS="$glib_save_CPPFLAGS"
2254 ])
2255
2256 LIBS="$glib_save_LIBS"
2257
2258 # now spit out all the warnings.
2259 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2260    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2261         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2262 fi
2263 if test "$ac_cv_func_localtime_r" != "yes"; then
2264         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2265 fi
2266
2267 #
2268 # Hack to deal with:
2269 #
2270 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2271 #     building shared libraries with linux.
2272 #  b) FreeBSD doesn't do this either.
2273 #
2274 case $host in
2275   *android*)
2276     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2277     ;;
2278   *-*-freebsd*|*-*-linux*)
2279     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2280     ;;
2281   *)
2282     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2283     ;;
2284 esac
2285
2286 AC_SUBST(G_THREAD_CFLAGS)
2287 AC_SUBST(G_THREAD_LIBS)
2288 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2289 AC_SUBST(G_THREAD_LIBS_EXTRA)
2290
2291 AC_CHECK_FUNCS(clock_gettime, [], [
2292   AC_CHECK_LIB(rt, clock_gettime, [
2293     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2294     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2295   ])
2296 ])
2297
2298
2299 dnl ************************
2300 dnl *** g_atomic_* tests ***
2301 dnl ************************
2302
2303 dnl We need to decide at configure time if GLib will use real atomic
2304 dnl operations ("lock free") or emulated ones with a mutex.  This is
2305 dnl because we must put this information in glibconfig.h so we know if
2306 dnl it is safe or not to inline using compiler intrinsics directly from
2307 dnl the header.
2308 dnl
2309 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2310 dnl user is interested in knowing if they can use the atomic ops across
2311 dnl processes.
2312 dnl
2313 dnl We can currently support the atomic ops natively when building GLib
2314 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2315 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2316 dnl we are using GCC (and not mingw*).
2317 dnl
2318 dnl Note that the atomic ops are only available with GCC on x86 when
2319 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2320 dnl not available but would be available given the right flags, we want
2321 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2322 dnl that then to silently fall back on emulated atomic ops just because
2323 dnl the user had the wrong build environment.
2324
2325 dnl We may add other compilers here in the future...
2326
2327 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2328   case $host in
2329     *-*-mingw*)
2330       glib_cv_g_atomic_lock_free=yes
2331       ;;
2332     *)
2333       AC_TRY_LINK([],
2334                      [volatile int atomic = 2;\
2335                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2336                      [glib_cv_g_atomic_lock_free=yes],
2337                      [glib_cv_g_atomic_lock_free=no])
2338       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2339         SAVE_CFLAGS="${CFLAGS}"
2340         CFLAGS="-march=i486"
2341         AC_TRY_LINK([],
2342                        [volatile int atomic = 2;\
2343                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2344                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2345                        [])
2346         CFLAGS="${SAVE_CFLAGS}"
2347       fi
2348       ;;
2349   esac])
2350
2351
2352 case $host in
2353   *-*-mingw*)
2354     ;;
2355   *)
2356     # Some compilers support atomic operations but do not define
2357     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2358     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2359       AC_TRY_LINK([],
2360                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2361                      [],
2362                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2363     fi
2364     ;;
2365  esac
2366
2367 dnl We need a more robust approach here...
2368 case $host_cpu in
2369   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2370     glib_memory_barrier_needed=no
2371     ;;
2372   sparc*|alpha*|powerpc*|ia64)
2373     glib_memory_barrier_needed=yes
2374     ;;
2375   *)
2376     glib_memory_barrier_needed=yes
2377     ;;
2378 esac
2379
2380 dnl ************************
2381 dnl ** Check for futex(2) **
2382 dnl ************************
2383 AC_CACHE_CHECK(for futex(2) system call,
2384     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2385 #include <linux/futex.h>
2386 #include <sys/syscall.h>
2387 #include <unistd.h>
2388 ],[
2389   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2390 ])],glib_cv_futex=yes,glib_cv_futex=no))
2391 if test x"$glib_cv_futex" = xyes; then
2392   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2393 fi
2394
2395 AC_CACHE_CHECK(for eventfd(2) system call,
2396     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2397 #include <sys/eventfd.h>
2398 #include <unistd.h>
2399 ],[
2400   eventfd (0, EFD_CLOEXEC);
2401 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2402 if test x"$glib_cv_eventfd" = x"yes"; then
2403   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2404 fi
2405 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2406
2407 dnl ****************************************
2408 dnl *** GLib POLL* compatibility defines ***
2409 dnl ****************************************
2410
2411 glib_poll_includes=["
2412 #include <sys/types.h>
2413 #include <poll.h>
2414 "]
2415
2416 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2417    test $ac_cv_func_poll = yes ], [
2418   glib_failed=false
2419   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2420   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2421   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2422   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2423   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2424   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2425   if $glib_failed ; then
2426     AC_MSG_ERROR([Could not determine values for POLL* constants])
2427   fi
2428 ], [
2429   glib_cv_value_POLLIN=1
2430   glib_cv_value_POLLOUT=4
2431   glib_cv_value_POLLPRI=2
2432   glib_cv_value_POLLERR=8
2433   glib_cv_value_POLLHUP=16
2434   glib_cv_value_POLLNVAL=32
2435 ])
2436
2437 AC_MSG_CHECKING([for broken poll])
2438 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2439         #include <stdlib.h>
2440         #include <fcntl.h>
2441         #include <poll.h>
2442         int main(void) {
2443           struct pollfd fds[1];
2444           int fd;
2445           fd = open("/dev/null", 1);
2446           fds[0].fd = fd;
2447           fds[0].events = POLLIN;
2448           fds[0].revents = 0;
2449           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2450                 exit(1);  /* Does not work for devices -- fail */
2451           }
2452           exit(0);
2453         }]])],
2454   [broken_poll=no],
2455   [broken_poll=yes
2456    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2457   [broken_poll="no (cross compiling)"])
2458 AC_MSG_RESULT($broken_poll)
2459
2460 dnl *********************
2461 dnl *** GRegex checks ***
2462 dnl *********************
2463
2464 PCRE_REQUIRED_VERSION=8.13
2465
2466 # Check if we should use the internal or the system-supplied pcre
2467 AC_ARG_WITH(pcre,
2468             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2469                             [whether to use system PCRE [default=internal]])])
2470
2471 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2472
2473 AS_IF([ test "x$with_pcre" = xsystem], [
2474   PKG_CHECK_MODULES(PCRE,
2475                     libpcre >= $PCRE_REQUIRED_VERSION)
2476   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2477                   glib_save_CFLAGS="$CFLAGS"
2478                   glib_save_LIBS="$LIBS"
2479                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2480                   AC_TRY_RUN([#include <pcre.h>
2481                               int main () {
2482                                 int support;
2483                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2484                                 if (!support)
2485                                   return 1;
2486                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2487                                 if (!support)
2488                                   return 1;
2489                                 return 0;
2490                               }],
2491                   glib_cv_pcre_has_unicode=yes,
2492                   glib_cv_pcre_has_unicode=no,
2493                   glib_cv_pcre_has_unicode=yes)
2494                   CFLAGS="$glib_save_CFLAGS"
2495                   LIBS="$glib_save_LIBS"
2496       ])
2497   if test "$glib_cv_pcre_has_unicode" = "no"; then
2498     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2499   fi
2500   AC_SUBST(PCRE_CFLAGS)
2501   AC_SUBST(PCRE_LIBS)
2502   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2503   PCRE_REQUIRES=libpcre
2504   AC_SUBST(PCRE_REQUIRES)
2505 ], [
2506   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2507   AS_IF([ test x"$GCC" = xyes], [
2508     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2509     save_CFLAGS="$CFLAGS"
2510     CFLAGS="$CFLAGS -Wno-pointer-sign"
2511     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2512                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2513     CFLAGS="$save_CFLAGS"
2514   ])
2515 ])
2516 AC_SUBST(PCRE_WARN_CFLAGS)
2517
2518 dnl **********************
2519 dnl *** Win32 API libs ***
2520 dnl **********************
2521
2522 case $host in
2523   *-*-cygwin*)
2524         G_LIBS_EXTRA="-luser32 -lkernel32"
2525     ;;
2526   *-*-mingw*)
2527         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2528     ;;
2529   *)
2530         G_LIBS_EXTRA=""
2531     ;;
2532 esac
2533 AC_SUBST(G_LIBS_EXTRA)
2534
2535 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2536 dnl since we need it for g_iconv()
2537
2538 AC_MSG_CHECKING([for EILSEQ])
2539 AC_TRY_COMPILE([
2540 #include <errno.h>
2541 ],
2542 [
2543 int error = EILSEQ;
2544 ], have_eilseq=yes, have_eilseq=no);
2545 AC_MSG_RESULT($have_eilseq)
2546
2547 dnl ******************************************************************
2548 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2549 dnl *** glib-compile-schemas in PATH                               ***
2550 dnl ******************************************************************
2551
2552 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2553
2554 AS_IF([ test $cross_compiling = yes ], [
2555   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2556   if test x$GLIB_GENMARSHAL = xno; then
2557     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2558   fi
2559
2560   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2561   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2562     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2563   fi
2564
2565   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2566   if test x$GLIB_COMPILE_RESOURCES = xno; then
2567     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2568   fi
2569 ])
2570
2571 dnl **************************
2572 dnl *** Checks for gtk-doc ***
2573 dnl **************************
2574 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2575 # it on it's own line.
2576 m4_ifdef([GTK_DOC_CHECK], [
2577 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2578 ],[
2579 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2580 ])
2581
2582 AC_ARG_ENABLE(man,
2583               [AS_HELP_STRING([--enable-man],
2584                               [generate man pages [default=auto]])],,
2585               enable_man=maybe)
2586
2587 AS_IF([test "$enable_man" != no], [
2588   AC_PATH_PROG([XSLTPROC], [xsltproc])
2589   AS_IF([test -z "$XSLTPROC"], [
2590     AS_IF([test "$enable_man" = yes], [
2591       AC_MSG_ERROR([xsltproc is required for --enable-man])
2592     ])
2593     enable_man=no
2594   ])
2595 ])
2596
2597 AS_IF([ test "$enable_man" != no ], [
2598   dnl check for DocBook DTD in the local catalog
2599   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2600      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2601   AS_IF([test "$have_docbook_dtd" != yes], [
2602     AS_IF([test "$enable_man" = yes ], [
2603       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2604     ])
2605     enable_man=no
2606   ])
2607 ])
2608
2609 AS_IF([test "$enable_man" != no], [
2610   dnl check for DocBook XSL stylesheets in the local catalog
2611   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2612      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2613   AS_IF([ test "$have_docbook_dtd" != yes ], [
2614     AS_IF([ test "$enable_man" = yes ], [
2615       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2616     ])
2617     enable_man=no
2618   ])
2619 ])
2620
2621 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2622
2623 AC_MSG_CHECKING([whether to generate man pages])
2624 AS_IF([ test "$enable_man" != no ], [
2625   AC_MSG_RESULT([yes])
2626 ], [
2627   AC_MSG_RESULT([no])
2628 ])
2629
2630 dnl
2631 dnl Tracing
2632 dnl
2633
2634 AC_ARG_ENABLE([dtrace],
2635              [AS_HELP_STRING([--enable-dtrace],
2636                               [include tracing support for dtrace])])
2637 have_dtrace=no
2638 AC_MSG_CHECKING([whether to include dtrace tracing support])
2639 AS_IF([ test "x$enable_dtrace" != xno], [
2640   if test x$glib_have_carbon = xyes; then
2641     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2642   else
2643     AC_MSG_RESULT([yes])
2644     AC_CHECK_PROGS(DTRACE, dtrace)
2645     if test -z "$DTRACE"; then
2646       if test "x$enable_dtrace" = xyes; then
2647         AC_MSG_ERROR([dtrace not found])
2648       fi
2649     else
2650       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2651                       [if test "x$enable_dtrace" = xyes; then
2652                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2653                        fi])
2654     fi
2655   fi
2656 ], [
2657   AC_MSG_RESULT([no])
2658 ])
2659 if test "x$have_dtrace" = xyes; then
2660   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2661 fi
2662 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2663
2664 AC_MSG_CHECKING([whether to include systemtap tracing support])
2665 AC_ARG_ENABLE([systemtap],
2666              [AS_HELP_STRING([--enable-systemtap],
2667                               [include tracing support for systemtap])])
2668 have_systemtap=no
2669 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2670   have_systemtap=yes
2671 fi
2672 AC_MSG_RESULT(${have_systemtap})
2673
2674 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2675
2676 AC_ARG_WITH([tapset-install-dir],
2677             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2678                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2679             [if test "x${withval}" = x; then
2680                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2681              else
2682                ABS_TAPSET_DIR="${withval}"
2683               fi],
2684             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2685 AC_SUBST(ABS_TAPSET_DIR)
2686
2687 dnl ************************************
2688 dnl *** Enable lcov coverage reports ***
2689 dnl ************************************
2690
2691 AC_ARG_ENABLE(coverage,
2692   AS_HELP_STRING([--enable-coverage],
2693                  [enable coverage testing with gcov]),
2694   [use_gcov=$enableval], [use_gcov=no])
2695
2696 AS_IF([ test "x$use_gcov" = "xyes"], [
2697   dnl we need gcc:
2698   if test "$GCC" != "yes"; then
2699     AC_MSG_ERROR([GCC is required for --enable-coverage])
2700   fi
2701
2702   dnl Check if ccache is being used
2703   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2704   case `$SHTOOL path $CC` in
2705     *ccache*[)] gcc_ccache=yes;;
2706     *[)] gcc_ccache=no;;
2707   esac
2708
2709   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2710     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2711   fi
2712
2713   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2714   AC_CHECK_PROG(LTP, lcov, lcov)
2715   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2716
2717   AS_IF([ test "$LTP" ], [
2718     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2719       glib_cv_ltp_version=invalid
2720       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2721       for ltp_check_version in $ltp_version_list; do
2722         if test "$ltp_version" = "$ltp_check_version"; then
2723           glib_cv_ltp_version="$ltp_check_version (ok)"
2724         fi
2725       done
2726     ])
2727   ], [
2728     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2729     AC_MSG_ERROR([$ltp_msg])
2730   ])
2731
2732   case $glib_cv_ltp_version in
2733     ""|invalid[)]
2734       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2735       AC_MSG_ERROR([$ltp_msg])
2736       LTP="exit 0;"
2737       ;;
2738   esac
2739
2740   if test -z "$LTP_GENHTML"; then
2741     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2742   fi
2743
2744   dnl Remove all optimization flags from CFLAGS
2745   changequote({,})
2746   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2747   changequote([,])
2748
2749   dnl Add the special gcc flags
2750   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2751   LDFLAGS="$LDFLAGS -lgcov"
2752 ])
2753
2754 dnl ******************************
2755 dnl *** output the whole stuff ***
2756 dnl ******************************
2757
2758 dnl this section will only be run if config.status is invoked with no
2759 dnl arguments, or with "glib/glibconfig.h" as an argument.
2760 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2761 [
2762         outfile=glib/glibconfig.h-tmp
2763         cat > $outfile <<\_______EOF
2764 /* glibconfig.h
2765  *
2766  * This is a generated file.  Please modify 'configure.ac'
2767  */
2768
2769 #ifndef __GLIBCONFIG_H__
2770 #define __GLIBCONFIG_H__
2771
2772 #include <glib/gmacros.h>
2773
2774 _______EOF
2775
2776         echo '#include <limits.h>' >> $outfile
2777         echo '#include <float.h>' >> $outfile
2778         if test x$glib_values_h = xyes; then
2779           echo '#include <values.h>' >> $outfile
2780         fi
2781         if test "$glib_header_alloca_h" = "yes"; then
2782           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2783         fi
2784         if test x$glib_included_printf != xyes; then
2785           echo "
2786 /* Specifies that GLib's g_print*() functions wrap the
2787  * system printf functions.  This is useful to know, for example,
2788  * when using glibc's register_printf_function().
2789  */" >> $outfile
2790           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2791         fi
2792
2793         cat >> $outfile <<_______EOF
2794
2795 G_BEGIN_DECLS
2796
2797 #define G_MINFLOAT      FLT_MIN
2798 #define G_MAXFLOAT      FLT_MAX
2799 #define G_MINDOUBLE     DBL_MIN
2800 #define G_MAXDOUBLE     DBL_MAX
2801 #define G_MINSHORT      SHRT_MIN
2802 #define G_MAXSHORT      SHRT_MAX
2803 #define G_MAXUSHORT     USHRT_MAX
2804 #define G_MININT        INT_MIN
2805 #define G_MAXINT        INT_MAX
2806 #define G_MAXUINT       UINT_MAX
2807 #define G_MINLONG       LONG_MIN
2808 #define G_MAXLONG       LONG_MAX
2809 #define G_MAXULONG      ULONG_MAX
2810
2811 _______EOF
2812
2813
2814         ### this should always be true in a modern C/C++ compiler
2815         ### and is statically asserted by glib-init.c
2816         cat >>$outfile <<_______EOF
2817 typedef signed char gint8;
2818 typedef unsigned char guint8;
2819 _______EOF
2820
2821
2822         if test -n "$gint16"; then
2823           cat >>$outfile <<_______EOF
2824 typedef signed $gint16 gint16;
2825 typedef unsigned $gint16 guint16;
2826 #define G_GINT16_MODIFIER $gint16_modifier
2827 #define G_GINT16_FORMAT $gint16_format
2828 #define G_GUINT16_FORMAT $guint16_format
2829 _______EOF
2830         fi
2831
2832
2833         if test -n "$gint32"; then
2834           cat >>$outfile <<_______EOF
2835 typedef signed $gint32 gint32;
2836 typedef unsigned $gint32 guint32;
2837 #define G_GINT32_MODIFIER $gint32_modifier
2838 #define G_GINT32_FORMAT $gint32_format
2839 #define G_GUINT32_FORMAT $guint32_format
2840 _______EOF
2841         fi
2842
2843         cat >>$outfile <<_______EOF
2844 #define G_HAVE_GINT64 1          /* deprecated, always true */
2845
2846 ${glib_extension}typedef signed $gint64 gint64;
2847 ${glib_extension}typedef unsigned $gint64 guint64;
2848
2849 #define G_GINT64_CONSTANT(val)  $gint64_constant
2850 #define G_GUINT64_CONSTANT(val) $guint64_constant
2851 _______EOF
2852
2853         if test x$gint64_format != x ; then
2854           cat >>$outfile <<_______EOF
2855 #define G_GINT64_MODIFIER $gint64_modifier
2856 #define G_GINT64_FORMAT $gint64_format
2857 #define G_GUINT64_FORMAT $guint64_format
2858 _______EOF
2859         else
2860           cat >>$outfile <<_______EOF
2861 #undef G_GINT64_MODIFIER
2862 #undef G_GINT64_FORMAT
2863 #undef G_GUINT64_FORMAT
2864 _______EOF
2865         fi
2866
2867         cat >>$outfile <<_______EOF
2868
2869 #define GLIB_SIZEOF_VOID_P $glib_void_p
2870 #define GLIB_SIZEOF_LONG   $glib_long
2871 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2872 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2873
2874 _______EOF
2875
2876         cat >>$outfile <<_______EOF
2877 typedef signed $glib_ssize_type_define gssize;
2878 typedef unsigned $glib_size_type_define gsize;
2879 #define G_GSIZE_MODIFIER $gsize_modifier
2880 #define G_GSSIZE_MODIFIER $gssize_modifier
2881 #define G_GSIZE_FORMAT $gsize_format
2882 #define G_GSSIZE_FORMAT $gssize_format
2883
2884 #define G_MAXSIZE       G_MAXU$glib_msize_type
2885 #define G_MINSSIZE      G_MIN$glib_mssize_type
2886 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2887
2888 typedef gint64 goffset;
2889 #define G_MINOFFSET     G_MININT64
2890 #define G_MAXOFFSET     G_MAXINT64
2891
2892 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2893 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2894 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2895
2896 _______EOF
2897
2898         if test -z "$glib_unknown_void_p"; then
2899           cat >>$outfile <<_______EOF
2900
2901 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2902 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2903
2904 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2905 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2906
2907 typedef signed $glib_intptr_type_define gintptr;
2908 typedef unsigned $glib_intptr_type_define guintptr;
2909
2910 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2911 #define G_GINTPTR_FORMAT        $gintptr_format
2912 #define G_GUINTPTR_FORMAT       $guintptr_format
2913 _______EOF
2914         else
2915           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2916         fi
2917
2918
2919
2920         cat >>$outfile <<_______EOF
2921 #ifndef G_DISABLE_DEPRECATED
2922 #define g_ATEXIT(proc)  (atexit (proc))
2923 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2924 #endif
2925 $glib_defines
2926 $glib_os
2927 $glib_static_compilation
2928
2929 $glib_vacopy
2930
2931 #ifdef  __cplusplus
2932 #define G_HAVE_INLINE   1
2933 #else   /* !__cplusplus */
2934 $glib_inline
2935 #endif  /* !__cplusplus */
2936
2937 #ifdef  __cplusplus
2938 #define G_CAN_INLINE    1
2939 _______EOF
2940
2941         if test x$g_can_inline = xyes ; then
2942                 cat >>$outfile <<_______EOF
2943 #else   /* !__cplusplus */
2944 #define G_CAN_INLINE    1
2945 _______EOF
2946         fi
2947
2948         cat >>$outfile <<_______EOF
2949 #endif
2950
2951 _______EOF
2952
2953         if test x$g_have_iso_c_varargs = xyes ; then
2954                 cat >>$outfile <<_______EOF
2955 #ifndef __cplusplus
2956 # define G_HAVE_ISO_VARARGS 1
2957 #endif
2958 _______EOF
2959         fi
2960         if test x$g_have_iso_cxx_varargs = xyes ; then
2961                 cat >>$outfile <<_______EOF
2962 #ifdef __cplusplus
2963 # define G_HAVE_ISO_VARARGS 1
2964 #endif
2965 _______EOF
2966         fi
2967         if test x$g_have_gnuc_varargs = xyes ; then
2968                 cat >>$outfile <<_______EOF
2969
2970 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2971  * is passed ISO vararg support is turned off, and there is no work
2972  * around to turn it on, so we unconditionally turn it off.
2973  */
2974 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2975 #  undef G_HAVE_ISO_VARARGS
2976 #endif
2977
2978 #define G_HAVE_GNUC_VARARGS 1
2979 _______EOF
2980         fi
2981
2982         case x$g_stack_grows in
2983         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2984         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2985         esac
2986
2987
2988         echo >>$outfile
2989         if test x$g_have_eilseq = xno; then
2990                 cat >>$outfile <<_______EOF
2991 #ifndef EILSEQ
2992 /* On some pre-C99 systems, EILSEQ is not defined.
2993  * The correspondence between this and the corresponding definition
2994  * in libiconv is essential.
2995  */
2996 #  define EILSEQ ENOENT
2997 #endif
2998 _______EOF
2999
3000         fi
3001
3002         if test x$g_have_gnuc_visibility = xyes; then
3003                 cat >>$outfile <<_______EOF
3004 #define G_HAVE_GNUC_VISIBILITY 1
3005 _______EOF
3006         fi
3007                 cat >>$outfile <<_______EOF
3008 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3009 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3010 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3011 #define G_GNUC_INTERNAL __hidden
3012 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3013 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3014 #else
3015 #define G_GNUC_INTERNAL
3016 #endif
3017 _______EOF
3018
3019         echo >>$outfile
3020         cat >>$outfile <<_______EOF
3021 #define G_THREADS_ENABLED
3022 #define G_THREADS_IMPL_$g_threads_impl_def
3023 _______EOF
3024
3025         if test x"$g_memory_barrier_needed" != xno; then
3026           echo >>$outfile
3027           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3028         fi
3029         if test x"$g_atomic_lock_free" = xyes; then
3030           echo >>$outfile
3031           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3032         fi
3033         echo >>$outfile
3034         g_bit_sizes="16 32 64"
3035         for bits in $g_bit_sizes; do
3036           cat >>$outfile <<_______EOF
3037 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3038 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3039 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3040 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3041 _______EOF
3042         done
3043
3044         cat >>$outfile <<_______EOF
3045 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3046 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3047 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3048 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3049 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3050 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3051 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3052 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3053 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3054 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3055 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3056 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3057 #define G_BYTE_ORDER $g_byte_order
3058
3059 #define GLIB_SYSDEF_POLLIN =$g_pollin
3060 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3061 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3062 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3063 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3064 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3065
3066 #define G_MODULE_SUFFIX "$g_module_suffix"
3067
3068 typedef $g_pid_type GPid;
3069
3070 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3071 #define GLIB_SYSDEF_AF_INET $g_af_inet
3072 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3073
3074 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3075 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3076 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3077
3078 G_END_DECLS
3079
3080 #endif /* __GLIBCONFIG_H__ */
3081 _______EOF
3082
3083
3084         if cmp -s $outfile glib/glibconfig.h; then
3085           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3086           rm -f $outfile
3087         else
3088           mv $outfile glib/glibconfig.h
3089         fi
3090 ],[
3091
3092 # Note that if two cases are the same, case goes with the first one.
3093 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3094 # on variable expansion in case labels.  Look at the generated config.status
3095 # for a hint.
3096
3097 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3098   glib_header_alloca_h="$ac_cv_working_alloca_h"
3099 else
3100   glib_header_alloca_h="$ac_cv_header_alloca_h"
3101 fi
3102
3103 if test x$enable_included_printf = xyes ; then
3104   glib_included_printf=yes
3105 fi
3106
3107 case 2 in
3108 $ac_cv_sizeof_short)
3109   gint16=short
3110   gint16_modifier='"h"'
3111   gint16_format='"hi"'
3112   guint16_format='"hu"'
3113   ;;
3114 $ac_cv_sizeof_int)
3115   gint16=int
3116   gint16_modifier='""'
3117   gint16_format='"i"'
3118   guint16_format='"u"'
3119   ;;
3120 esac
3121 case 4 in
3122 $ac_cv_sizeof_short)
3123   gint32=short
3124   gint32_modifier='"h"'
3125   gint32_format='"hi"'
3126   guint32_format='"hu"'
3127   ;;
3128 $ac_cv_sizeof_int)
3129   gint32=int
3130   gint32_modifier='""'
3131   gint32_format='"i"'
3132   guint32_format='"u"'
3133   ;;
3134 $ac_cv_sizeof_long)
3135   gint32=long
3136   gint32_modifier='"l"'
3137   gint32_format='"li"'
3138   guint32_format='"lu"'
3139   ;;
3140 esac
3141 case 8 in
3142 $ac_cv_sizeof_int)
3143   gint64=int
3144   gint64_modifier='""'
3145   gint64_format='"i"'
3146   guint64_format='"u"'
3147   glib_extension=
3148   gint64_constant='(val)'
3149   guint64_constant='(val)'
3150   ;;
3151 $ac_cv_sizeof_long)
3152   gint64=long
3153   gint64_modifier='"l"'
3154   gint64_format='"li"'
3155   guint64_format='"lu"'
3156   glib_extension=
3157   gint64_constant='(val##L)'
3158   guint64_constant='(val##UL)'
3159   ;;
3160 $ac_cv_sizeof_long_long)
3161   gint64='long long'
3162   if test -n "$glib_cv_long_long_format"; then
3163     gint64_modifier='"'$glib_cv_long_long_format'"'
3164     gint64_format='"'$glib_cv_long_long_format'i"'
3165     guint64_format='"'$glib_cv_long_long_format'u"'
3166   fi
3167   glib_extension='G_GNUC_EXTENSION '
3168   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3169   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3170   ;;
3171 $ac_cv_sizeof___int64)
3172   gint64='__int64'
3173   if test -n "$glib_cv_long_long_format"; then
3174     gint64_modifier='"'$glib_cv_long_long_format'"'
3175     gint64_format='"'$glib_cv_long_long_format'i"'
3176     guint64_format='"'$glib_cv_long_long_format'u"'
3177   fi
3178   glib_extension=
3179   gint64_constant='(val##i64)'
3180   guint64_constant='(val##ui64)'
3181   ;;
3182 esac
3183 glib_size_t=$ac_cv_sizeof_size_t
3184 glib_ssize_t=$ac_cv_sizeof_ssize_t
3185 glib_size_type_define="$glib_size_type"
3186 glib_ssize_type_define="$glib_ssize_type"
3187 glib_void_p=$ac_cv_sizeof_void_p
3188 glib_long=$ac_cv_sizeof_long
3189
3190 case "$glib_size_type" in
3191 short)
3192   gsize_modifier='"h"'
3193   gsize_format='"hu"'
3194   glib_msize_type='SHRT'
3195   ;;
3196 int)
3197   gsize_modifier='""'
3198   gsize_format='"u"'
3199   glib_msize_type='INT'
3200   ;;
3201 long)
3202   gsize_modifier='"l"'
3203   gsize_format='"lu"'
3204   glib_msize_type='LONG'
3205   ;;
3206 "long long"|__int64)
3207   gsize_modifier='"I64"'
3208   gsize_format='"I64u"'
3209   glib_msize_type='INT64'
3210   ;;
3211 esac
3212
3213 case "$glib_ssize_type" in
3214 short)
3215   gssize_modifier='"h"'
3216   gssize_format='"hi"'
3217   glib_mssize_type='SHRT'
3218   ;;
3219 int)
3220   gssize_modifier='""'
3221   gssize_format='"i"'
3222   glib_mssize_type='INT'
3223   ;;
3224 long)
3225   gssize_modifier='"l"'
3226   gssize_format='"li"'
3227   glib_mssize_type='LONG'
3228   ;;
3229 "long long"|__int64)
3230   gssize_modifier='"I64"'
3231   gssize_format='"I64i"'
3232   glib_mssize_type='INT64'
3233   ;;
3234 esac
3235
3236 gintbits=`expr $ac_cv_sizeof_int \* 8`
3237 glongbits=`expr $ac_cv_sizeof_long \* 8`
3238 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3239 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3240
3241 case $ac_cv_sizeof_void_p in
3242 $ac_cv_sizeof_int)
3243   glib_intptr_type_define=int
3244   gintptr_modifier='""'
3245   gintptr_format='"i"'
3246   guintptr_format='"u"'
3247   glib_gpi_cast='(gint)'
3248   glib_gpui_cast='(guint)'
3249   ;;
3250 $ac_cv_sizeof_long)
3251   glib_intptr_type_define=long
3252   gintptr_modifier='"l"'
3253   gintptr_format='"li"'
3254   guintptr_format='"lu"'
3255   glib_gpi_cast='(glong)'
3256   glib_gpui_cast='(gulong)'
3257   ;;
3258 $ac_cv_sizeof_long_long)
3259   glib_intptr_type_define='long long'
3260   gintptr_modifier='"I64"'
3261   gintptr_format='"I64i"'
3262   guintptr_format='"I64u"'
3263   glib_gpi_cast='(gint64)'
3264   glib_gpui_cast='(guint64)'
3265   ;;
3266 $ac_cv_sizeof___int64)
3267   glib_intptr_type_define=__int64
3268   gintptr_modifier='"I64"'
3269   gintptr_format='"I64i"'
3270   guintptr_format='"I64u"'
3271   glib_gpi_cast='(gint64)'
3272   glib_gpui_cast='(guint64)'
3273   ;;
3274 *)
3275   glib_unknown_void_p=yes
3276   ;;
3277 esac
3278
3279
3280 glib_defines="
3281 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3282 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3283 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3284 "
3285
3286 case xyes in
3287 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3288 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3289 *)                      glib_vacopy=''
3290 esac
3291
3292 if test x$glib_cv_va_val_copy = xno; then
3293   glib_vacopy="\$glib_vacopy
3294 #define G_VA_COPY_AS_ARRAY 1"
3295 fi
3296
3297 if test x$glib_cv_hasinline = xyes; then
3298     glib_inline='#define G_HAVE_INLINE 1'
3299 fi
3300 if test x$glib_cv_has__inline = xyes; then
3301     glib_inline="\$glib_inline
3302 #define G_HAVE___INLINE 1"
3303 fi
3304 if test x$glib_cv_has__inline__ = xyes; then
3305     glib_inline="\$glib_inline
3306 #define G_HAVE___INLINE__ 1"
3307 fi
3308
3309 g_have_gnuc_varargs=$g_have_gnuc_varargs
3310 g_have_iso_c_varargs=$g_have_iso_c_varargs
3311 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3312
3313 g_can_inline=$g_can_inline
3314 g_have_gnuc_visibility=$g_have_gnuc_visibility
3315 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3316
3317 if test x$ac_cv_c_bigendian = xyes; then
3318   g_byte_order=G_BIG_ENDIAN
3319   g_bs_native=BE
3320   g_bs_alien=LE
3321 else
3322   g_byte_order=G_LITTLE_ENDIAN
3323   g_bs_native=LE
3324   g_bs_alien=BE
3325 fi
3326
3327 g_pollin=$glib_cv_value_POLLIN
3328 g_pollout=$glib_cv_value_POLLOUT
3329 g_pollpri=$glib_cv_value_POLLPRI
3330 g_pollhup=$glib_cv_value_POLLHUP
3331 g_pollerr=$glib_cv_value_POLLERR
3332 g_pollnval=$glib_cv_value_POLLNVAL
3333
3334 # If a family is not found on the system, define that family to
3335 # a negative value, picking a different one for each undefined
3336 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3337 # This is needed because glib-mkenums doesn't handle optional
3338 # values in enums, and thus we have to have all existing values
3339 # defined in the enum.
3340 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3341   g_af_unix=$glib_cv_value_AF_UNIX
3342 else
3343   g_af_unix=-1
3344 fi
3345 g_af_inet=$glib_cv_value_AF_INET
3346 g_af_inet6=$glib_cv_value_AF_INET6
3347
3348 g_msg_peek=$glib_cv_value_MSG_PEEK
3349 g_msg_oob=$glib_cv_value_MSG_OOB
3350 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3351
3352 g_stack_grows=$glib_cv_stack_grows
3353
3354 g_have_eilseq=$have_eilseq
3355
3356 g_threads_impl_def=$g_threads_impl
3357
3358 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3359 g_memory_barrier_needed="$glib_memory_barrier_needed"
3360 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3361
3362 g_module_suffix="$glib_gmodule_suffix"
3363
3364 g_pid_type="$glib_pid_type"
3365 case $host in
3366   *-*-cygwin*)
3367     glib_os="#define G_OS_UNIX
3368 #define G_PLATFORM_WIN32
3369 #define G_WITH_CYGWIN"
3370     ;;
3371   *-*-mingw*)
3372     glib_os="#define G_OS_WIN32
3373 #define G_PLATFORM_WIN32"
3374     ;;
3375   *)
3376     glib_os="#define G_OS_UNIX"
3377     ;;
3378 esac
3379 glib_static_compilation=""
3380 if test x$glib_win32_static_compilation = xyes; then
3381   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3382 #define GOBJECT_STATIC_COMPILATION 1"
3383 fi
3384 ])
3385
3386 # Redo enough to get guint32 and guint64 for the alignment checks below
3387 case 4 in
3388 $ac_cv_sizeof_short)
3389   gint32=short
3390   ;;
3391 $ac_cv_sizeof_int)
3392   gint32=int
3393   ;;
3394 $ac_cv_sizeof_long)
3395   gint32=long
3396   ;;
3397 esac
3398 case 8 in
3399 $ac_cv_sizeof_int)
3400   gint64=int
3401   ;;
3402 $ac_cv_sizeof_long)
3403   gint64=long
3404   ;;
3405 $ac_cv_sizeof_long_long)
3406   gint64='long long'
3407   ;;
3408 $ac_cv_sizeof___int64)
3409   gint64='__int64'
3410   ;;
3411 esac
3412
3413 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3414 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3415 typedef unsigned $gint32 guint32;])
3416 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3417 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3418 typedef unsigned $gint64 guint64;])
3419 AC_CHECK_TYPE([unsigned long])
3420 AC_CHECK_ALIGNOF([unsigned long])
3421
3422 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3423 #
3424 # 1.2.14 required for dbus_message_set_serial
3425 PKG_CHECK_MODULES(DBUS1,
3426      dbus-1 >= 1.2.14,
3427      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3428      have_dbus1=no)
3429 AC_SUBST(DBUS1_CFLAGS)
3430 AC_SUBST(DBUS1_LIBS)
3431 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3432
3433 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3434 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3435
3436 dnl
3437 dnl Check for -Bsymbolic-functions linker flag used to avoid
3438 dnl intra-library PLT jumps, if available.
3439 dnl
3440
3441 AC_ARG_ENABLE(Bsymbolic,
3442               [AS_HELP_STRING([--disable-Bsymbolic],
3443                               [avoid linking with -Bsymbolic])],,
3444               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3445                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3446                LDFLAGS=-Wl,-Bsymbolic-functions
3447                LIBS=
3448                AC_TRY_LINK([], [return 0],
3449                            AC_MSG_RESULT(yes)
3450                            enable_Bsymbolic=yes,
3451                            AC_MSG_RESULT(no)
3452                            enable_Bsymbolic=no)
3453                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3454
3455 if test "x${enable_Bsymbolic}" = "xyes"; then
3456   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3457 fi
3458
3459 AC_SUBST(GLIB_LINK_FLAGS)
3460
3461 dnl
3462 dnl Check for -z,nodelete linker flag: the type system assumes that
3463 dnl libgobject stays loaded for the lifetime of the process.
3464 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3465 dnl we also try to check for the --fatal-warnings linker flag if
3466 dnl auto-detecting.
3467 dnl
3468
3469 AC_ARG_ENABLE([znodelete],
3470               [AS_HELP_STRING([--disable-znodelete],
3471                               [avoid linking with -z,nodelete])],,
3472               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3473                AC_MSG_CHECKING([for --fatal-warnings linker flag])
3474                LDFLAGS=-Wl,--fatal-warnings
3475                LIBS=
3476                AC_TRY_LINK([], [return 0],
3477                            AC_MSG_RESULT(yes)
3478                            [ldflags_fatal=-Wl,--fatal-warnings],
3479                            AC_MSG_RESULT(no)
3480                            ldflags_fatal=)
3481                AC_MSG_CHECKING([for -z,nodelete linker flag])
3482                LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3483                AC_TRY_LINK([], [return 0],
3484                            AC_MSG_RESULT(yes)
3485                            enable_znodelete=yes,
3486                            AC_MSG_RESULT(no)
3487                            enable_znodelete=no)
3488                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3489
3490 if test "x${enable_znodelete}" = "xyes"; then
3491   GOBJECT_LINK_FLAGS=-Wl,-z,nodelete
3492 fi
3493
3494 AC_SUBST(GOBJECT_LINK_FLAGS)
3495
3496 dnl
3497 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3498 dnl visibility attributes for symbol export control
3499 dnl
3500 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3501 case "$host" in
3502   *-*-mingw*)
3503     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3504     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3505               [defines how to decorate public symbols while building])
3506     CFLAGS="${CFLAGS} -fvisibility=hidden"
3507     ;;
3508   *)
3509     dnl on other compilers, check if we can do -fvisibility=hidden
3510     SAVED_CFLAGS="${CFLAGS}"
3511     CFLAGS="-fvisibility=hidden"
3512     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3513     AC_TRY_COMPILE([], [return 0],
3514                    AC_MSG_RESULT(yes)
3515                    enable_fvisibility_hidden=yes,
3516                    AC_MSG_RESULT(no)
3517                    enable_fvisibility_hidden=no)
3518     CFLAGS="${SAVED_CFLAGS}"
3519
3520     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3521       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3522                 [defines how to decorate public symbols while building])
3523       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3524     ])
3525     ;;
3526 esac
3527 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3528
3529 dnl Compiler flags; macro originates from systemd
3530 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3531 AC_ARG_ENABLE(compile-warnings,
3532               [AS_HELP_STRING([--disable-compile-warnings],
3533                               [Don't use builtin compiler warnings])],,
3534                               enable_compile_warnings=yes)
3535 AS_IF([test "x$enable_compile_warnings" = xyes], [
3536   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3537    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3538    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3539    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3540    -Werror=format=2 -Werror=missing-include-dirs])
3541 ])
3542 AC_SUBST(GLIB_WARN_CFLAGS)
3543
3544 #
3545 # Define variables corresponding to the correct include paths to use for
3546 # in-tree building.
3547 #
3548
3549 # for config.h:
3550 config_h_INCLUDES='-I$(top_builddir)'
3551 AC_SUBST(config_h_INCLUDES)
3552
3553 # glib:
3554 #   config.h
3555 #   $(top_builddir)/glib: for glibconfig.h
3556 #   $(top_srcdir)/glib:   for glib.h
3557 #   $(top_srcdir):        for everything
3558 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3559 AC_SUBST(glib_INCLUDES)
3560
3561 # gobject:
3562 #   same as glib
3563 gobject_INCLUDES='$(glib_INCLUDES)'
3564 AC_SUBST(gobject_INCLUDES)
3565
3566 # gmodule:
3567 #   glib includes
3568 #   $(top_srcdir)/gmodule: for gmodule.h
3569 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3570 AC_SUBST(gmodule_INCLUDES)
3571
3572 # gio:
3573 #   same as gmodule
3574 gio_INCLUDES='$(gmodule_INCLUDES)'
3575 AC_SUBST(gio_INCLUDES)
3576
3577
3578 AC_CONFIG_FILES([
3579 glib-2.0.pc
3580 gmodule-2.0.pc
3581 gmodule-export-2.0.pc
3582 gmodule-no-export-2.0.pc
3583 gthread-2.0.pc
3584 gobject-2.0.pc
3585 gio-2.0.pc
3586 gio-unix-2.0.pc
3587 gio-windows-2.0.pc
3588 glib-zip
3589 glib-gettextize
3590 Makefile
3591 build/Makefile
3592 build/win32/Makefile
3593 build/win32/dirent/Makefile
3594 build/win32/vs9/Makefile
3595 build/win32/vs10/Makefile
3596 build/win32/vs11/Makefile
3597 build/win32/vs12/Makefile
3598 glib/Makefile
3599 glib/glib.stp
3600 glib/libcharset/Makefile
3601 glib/gnulib/Makefile
3602 glib/pcre/Makefile
3603 glib/update-pcre/Makefile
3604 glib/tests/Makefile
3605 gmodule/Makefile
3606 gmodule/gmoduleconf.h
3607 gobject/Makefile
3608 gobject/gobject.stp
3609 gobject/glib-mkenums
3610 gobject/tests/Makefile
3611 gthread/Makefile
3612 gio/Makefile
3613 gio/gdbus-2.0/codegen/Makefile
3614 gio/gdbus-2.0/codegen/config.py
3615 gio/gnetworking.h
3616 gio/xdgmime/Makefile
3617 gio/inotify/Makefile
3618 gio/kqueue/Makefile
3619 gio/fen/Makefile
3620 gio/fam/Makefile
3621 gio/win32/Makefile
3622 gio/tests/Makefile
3623 gio/tests/gdbus-object-manager-example/Makefile
3624 gio/tests/services/Makefile
3625 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3626 gio/tests/modules/Makefile
3627 po/Makefile.in
3628 docs/Makefile
3629 docs/reference/Makefile
3630 docs/reference/glib/Makefile
3631 docs/reference/glib/version.xml
3632 docs/reference/gobject/Makefile
3633 docs/reference/gobject/version.xml
3634 docs/reference/gio/Makefile
3635 docs/reference/gio/gdbus-object-manager-example/Makefile
3636 docs/reference/gio/version.xml
3637 tests/Makefile
3638 tests/gobject/Makefile
3639 tests/refcount/Makefile
3640 m4macros/Makefile
3641 ])
3642
3643 AC_CONFIG_COMMANDS([chmod-scripts],
3644 [chmod 0755 glib-zip
3645 chmod 0755 glib-gettextize
3646 chmod 0755 gobject/glib-mkenums])
3647
3648 # we want to invoke this macro solely so that the config.status script
3649 # and automake generated makefiles know about these generated files.
3650 # They are only needed to distcheck the package
3651 if false; then
3652   AC_CONFIG_FILES([
3653     INSTALL
3654     README
3655     config.h.win32
3656     glib/glibconfig.h.win32
3657     glib/makefile.msc
3658     glib/glib.rc
3659     gmodule/makefile.msc
3660     gmodule/gmodule.rc
3661     gobject/makefile.msc
3662     gobject/gobject.rc
3663     gthread/makefile.msc
3664     gthread/gthread.rc
3665     gio/gio.rc
3666     tests/makefile.msc
3667   ])
3668 fi
3669
3670 AC_OUTPUT