configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([gupnp],
   3         [0.19.1],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=gupnp&component=gupnp],
   5         [gupnp],
   6         [http://www.gupnp.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_SRCDIR([libgupnp/gupnp.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 AC_CANONICAL_HOST
  14 AC_CANONICAL_TARGET
  15
  16 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-xz])
  17 AM_MAINTAINER_MODE([enable])
  18
  19 AM_SILENT_RULES([yes])
  20
  21 # Check for programs
  22 AC_PROG_CC
  23 AC_FUNC_MMAP
  24 AC_SYS_LARGEFILE
  25
  26 # Initialize libtool
  27 LT_PREREQ([2.2])
  28 LT_INIT
  29
  30
  31 PKG_CHECK_MODULES(GTest, glib-2.0 >= 2.16, [gtest=yes], [gtest=no])
  32 AM_CONDITIONAL(HAVE_GTEST, [test x$gtest = xyes])
  33
  34 AC_MSG_CHECKING([operating system])
  35 case "$target_os" in
  36      mingw*|cygwin*)
  37         AC_MSG_RESULT(Win32)
  38         UUID=uuid
  39         ;;
  40      darwin*)
  41         AC_MSG_RESULT(Darwin)
  42         UUID=
  43         ;;
  44      *)
  45         AC_MSG_RESULT($target_os)
  46         UUID=uuid
  47         ;;
  48 esac
  49
  50 PKG_CHECK_MODULES(LIBGUPNP, glib-2.0 >= 2.24.0 \
  51                             gio-2.0 \
  52                             gmodule-2.0 \
  53                             gssdp-1.0 >= 0.13.0 \
  54                             libsoup-2.4 >= 2.28.2 \
  55                             libxml-2.0 \
  56                             $UUID)
  57
  58 PKG_CHECK_MODULES(GTHREAD, gthread-2.0)
  59
  60 AC_ARG_WITH([context_manager],
  61             AS_HELP_STRING(
  62                         [--with-context-manager=@<:@network-manager/connman/unix/linux@:>@],
  63                         [Context Manager backend to use]),,
  64             [with_context_manager="none"])
  65
  66 if test "x$with_context_manager" = "xnone"; then
  67         case "$target_os" in
  68         linux*)
  69                 with_context_manager="linux"
  70                 ;;
  71         *)
  72                 with_context_manager="unix"
  73                 ;;
  74         esac
  75 fi
  76
  77 AC_CHECK_HEADERS([sys/socket.h linux/rtnetlink.h],
  78                 [ HAVE_NETLINK=yes ],
  79                 [ HAVE_NETLINK=no ],
  80                 [ #ifdef HAVE_SYS_SOCKET_H
  81                   #include <sys/socket.h>
  82                   #endif
  83                 ])
  84 AM_CONDITIONAL([HAVE_NETLINK], [test "x$HAVE_NETLINK" = "xyes"])
  85 AC_SUBST(HAVE_NETLINK)
  86
  87 AC_CHECK_HEADERS([linux/wireless.h], [], [],
  88                 [ #ifdef HAVE_SYS_SOCKET_H
  89                   #include <sys/socket.h>
  90                   #endif
  91                 ])
  92
  93 AC_MSG_CHECKING([Context Manager backend to use])
  94 AC_MSG_RESULT([${with_context_manager}])
  95
  96 AM_CONDITIONAL([USE_NETWORK_MANAGER],
  97                [test "x$with_context_manager" = "xnetwork-manager"])
  98 AS_IF([test "x$with_context_manager" = "xnetwork-manager"],
  99       [PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.26)])
 100
 101 AM_CONDITIONAL([USE_CONNMAN],
 102                [test "x$with_context_manager" = "xconnman"])
 103
 104 if test "x$with_context_manager" = "xconnman"; then
 105         PKG_CHECK_MODULES(CONNMAN, glib-2.0 >= 2.28 connman >= 0.80)
 106 fi
 107
 108 USE_NETLINK=no
 109 AS_IF([test "x$with_context_manager" = "xlinux"],
 110       [AS_IF([test "x$HAVE_NETLINK" = "xno"],
 111              [AC_MSG_NOTICE([No rtnetlink found, falling back to static context manager])],
 112              [USE_NETLINK=yes])
 113       ],[])
 114
 115 AM_CONDITIONAL(USE_NETLINK, test "x$USE_NETLINK" = "xyes")
 116 AC_SUBST(USE_NETLINK)
 117
 118 # glib-genmarshal
 119 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
 120 AC_SUBST(GLIB_GENMARSHAL)
 121
 122 # Debugging
 123 AC_ARG_ENABLE(debug,
 124         AS_HELP_STRING([--enable-debug], [enable debugging]),,
 125         enable_debug=no)
 126 if test "x$enable_debug" = "xyes"; then
 127         CFLAGS="$CFLAGS -g -Wall -Werror"
 128 fi
 129
 130 GOBJECT_INTROSPECTION_CHECK([0.6.4])
 131
 132 # vapigen
 133 AS_IF([test "x$found_introspection" = "xyes"],
 134       [
 135        VALA_PROG_VAPIGEN([0.14])
 136       ]
 137 )
 138 AM_CONDITIONAL([HAVE_VAPIGEN], [test "x$VAPIGEN" != "x"])
 139
 140 # Gtk-doc
 141 GTK_DOC_CHECK([1.0])
 142
 143 AC_CONFIG_FILES([
 144 Makefile
 145 libgupnp/Makefile
 146 examples/Makefile
 147 tools/Makefile
 148 tests/Makefile
 149 tests/gtest/Makefile
 150 doc/Makefile
 151 doc/version.xml
 152 vala/Makefile
 153 gupnp-1.0.pc
 154 gupnp-1.0-uninstalled.pc
 155 ])
 156 AC_OUTPUT