configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [57])
  34 m4_define([glib_micro_version], [3])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [https://gitlab.gnome.org/GNOME/glib/issues/new])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.13.3 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar subdir-objects])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_pid_format='p'
 129     glib_pollfd_format='%#x'
 130     glib_dir_separator='\\\\'
 131     glib_searchpath_separator=';'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       glib_pollfd_format='%#I64x'
 146       ;;
 147     esac
 148
 149     AC_DEFINE([_WIN32_WINNT], [0x0601], [Target the Windows 7 API])
 150     ;;
 151   *)
 152     glib_native_win32=no
 153     glib_pid_type=int
 154     glib_pid_format='i'
 155     glib_pollfd_format='%d'
 156     glib_dir_separator='/'
 157     glib_searchpath_separator=':'
 158     ;;
 159 esac
 160 case $host in
 161   *-*-linux*)
 162     glib_os_linux=yes
 163     ;;
 164 esac
 165
 166 AC_MSG_RESULT([$glib_native_win32])
 167
 168 AC_MSG_CHECKING([for the Android])
 169 case $host in
 170   *android*)
 171     glib_native_android="yes"
 172     ;;
 173   *)
 174     glib_native_android="no"
 175     ;;
 176 esac
 177 AC_MSG_RESULT([$glib_native_android])
 178
 179 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 180
 181 glib_have_carbon=no
 182 AC_MSG_CHECKING([for Mac OS X Carbon support])
 183 AC_TRY_CPP([
 184 #include <Carbon/Carbon.h>
 185 #include <CoreServices/CoreServices.h>
 186 ], glib_have_carbon=yes)
 187
 188 AC_MSG_RESULT([$glib_have_carbon])
 189
 190 glib_have_cocoa=no
 191 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 192 AC_TRY_CPP([
 193 #include <Cocoa/Cocoa.h>
 194 #ifdef GNUSTEP_BASE_VERSION
 195 #error "Detected GNUstep, not Cocoa"
 196 #endif
 197 ], glib_have_cocoa=yes)
 198
 199 AC_MSG_RESULT([$glib_have_cocoa])
 200
 201 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 202 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 203 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 204 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 205 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 206 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 207
 208 AS_IF([test "$glib_native_win32" = "yes"], [
 209   AC_CHECK_TOOL(WINDRES, windres, no)
 210   if test "$WINDRES" = no; then
 211     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 212   fi
 213   AC_CHECK_TOOL(NM, nm, no)
 214   if test "$NM" = no; then
 215     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 216   fi
 217   AC_CHECK_TOOL(RANLIB, ranlib, :)
 218   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 219   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 220 ])
 221 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 222
 223 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 224   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 225   CARBON_LIBS="-Wl,-framework,Carbon"
 226   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 227 ], [CARBON_LIBS=""])
 228
 229 AC_SUBST([CARBON_LIBS])
 230 ac_cv_have_os_x_9_or_later="no"
 231 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 232   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 233   COCOA_LIBS="-Wl,-framework,Foundation -Wl,-framework,AppKit"
 234   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 235   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 236 #include <AvailabilityMacros.h>
 237 #if MAC_OS_X_VERSION_MIN_REQUIRED < 1090
 238 #error Compiling for minimum OS X version before 10.9
 239 #endif
 240   ]])],[ac_cv_have_os_x_9_or_later="yes"])
 241 ], [COCOA_LIBS=""])
 242 AM_CONDITIONAL([MAC_OS_X_9], [test "x$ac_cv_have_os_x_9_or_later" = xyes])
 243 AC_SUBST([COCOA_LIBS])
 244
 245 dnl declare --enable-* args and collect ac_help strings
 246 AC_ARG_ENABLE(debug,
 247               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 248                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 249               enable_debug=glib_debug_default)
 250
 251 GLIB_TESTS
 252
 253 dnl location to install runtime libraries, e.g. ../../lib to install
 254 dnl to /lib if libdir is /usr/lib
 255 AC_ARG_WITH(runtime-libdir,
 256            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 257                            [install runtime libraries relative to libdir])],
 258            [],
 259            [with_runtime_libdir=""])
 260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 261 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 262 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 263
 264 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 265 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 266 AC_LANG_SAVE
 267 AC_LANG_CPLUSPLUS
 268 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 269 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 270 AC_LANG_RESTORE
 271
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test "x$cflags_set" != "x" ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 287 else
 288   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 289
 290   if test "x$enable_debug" = "xno"; then
 291     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 292   fi
 293 fi
 294
 295 # Ensure MSVC-compatible struct packing convention is used when
 296 # compiling for Win32 with gcc.
 297 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 298 # gcc2 uses "-fnative-struct".
 299 if test x"$glib_native_win32" = xyes; then
 300   if test x"$GCC" = xyes; then
 301     msnative_struct=''
 302     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 303     if test -z "$ac_cv_prog_CC"; then
 304       our_gcc="$CC"
 305     else
 306       our_gcc="$ac_cv_prog_CC"
 307     fi
 308     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 309       2.)
 310         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 311           msnative_struct='-fnative-struct'
 312         fi
 313         ;;
 314       *)
 315         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 316           msnative_struct='-mms-bitfields'
 317         fi
 318         ;;
 319     esac
 320     if test x"$msnative_struct" = x ; then
 321       AC_MSG_RESULT([no way])
 322       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 323     else
 324       CFLAGS="$CFLAGS $msnative_struct"
 325       AC_MSG_RESULT([${msnative_struct}])
 326     fi
 327   fi
 328 fi
 329 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 330 AC_SUBST(GLIB_EXTRA_CFLAGS)
 331
 332 AC_EXEEXT
 333
 334 AC_PROG_AWK
 335
 336 # option to specify python interpreter to use; this just sets $PYTHON, so that
 337 # we will fallback to reading $PYTHON if --with-python is not given, and
 338 # python.m4 will get the expected input
 339 AC_ARG_WITH(python,
 340             AS_HELP_STRING([--with-python=PATH],
 341                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 342             [PYTHON="$withval"], [])
 343 if test x"$PYTHON" = xyes; then
 344   AC_MSG_ERROR([--with-python option requires a path or program argument])
 345 fi
 346 AM_PATH_PYTHON(2.7,,PYTHON="python2.7")
 347
 348
 349 dnl ***********************
 350 dnl *** Tests for iconv ***
 351 dnl ***********************
 352 dnl
 353 dnl We do this before the gettext checks, to avoid distortion
 354
 355 dnl On Windows we use a native implementation
 356
 357 AS_IF([ test x"$glib_native_win32" = xyes], [
 358   with_libiconv=native
 359 ], [
 360   AC_ARG_WITH(libiconv,
 361               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 362                               [use the libiconv library])],,
 363               [with_libiconv=maybe])
 364
 365   found_iconv=no
 366   case $with_libiconv in
 367     maybe)
 368       # Check in the C library first
 369       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 370       # Check if we have GNU libiconv
 371       if test $found_iconv = "no"; then
 372         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 373       fi
 374       # Check if we have a iconv in -liconv, possibly from vendor
 375       if test $found_iconv = "no"; then
 376         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 377       fi
 378       ;;
 379     no)
 380       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 381       ;;
 382     gnu|yes)
 383       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 384       ;;
 385     native)
 386       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 387       ;;
 388   esac
 389
 390   if test "x$found_iconv" = "xno" ; then
 391      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 392   fi
 393 ])
 394
 395 dnl
 396 dnl zlib support
 397 dnl
 398 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 399 AS_IF([test "x$found_zlib" = "xno"], [
 400   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 401   if test "x$found_zlib" = "xno" ; then
 402     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 403   fi
 404   ZLIB_LIBS='-lz'
 405   AC_SUBST(ZLIB_LIBS)
 406 ])
 407
 408 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 409 AC_SUBST(LIBFFI_CFLAGS)
 410 AC_SUBST(LIBFFI_LIBS)
 411
 412 dnl
 413 dnl gettext support
 414 dnl
 415
 416 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 417 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 418 GLIB_GNU_GETTEXT
 419
 420 if test "$gt_cv_have_gettext" != "yes" ; then
 421   AC_MSG_ERROR([
 422 *** You must have either have gettext support in your C library, or use the
 423 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html)
 424 ])
 425 fi
 426
 427 LIBS="$INTLLIBS $LIBS"
 428
 429 GETTEXT_PACKAGE=glib20
 430 AC_SUBST(GETTEXT_PACKAGE)
 431 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 432   [Define the gettext package to be used])
 433
 434 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 435
 436 dnl
 437 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 438 dnl
 439
 440 AS_IF([test x"$glib_native_win32" != xyes], [
 441   if test x$with_libiconv != xno ; then
 442     case " $INTLLIBS " in
 443     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 444     *) ICONV_LIBS="-liconv" ;;
 445     esac
 446   fi
 447 ])
 448 AC_SUBST(ICONV_LIBS)
 449
 450 case $with_libiconv in
 451   gnu)
 452     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 453     ;;
 454   native)
 455     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 456     ;;
 457 esac
 458
 459 dnl Initialize libtool
 460 LT_PREREQ([2.2])
 461 LT_INIT([disable-static win32-dll])
 462 dnl when using libtool 2.x create libtool early, because it's used in configure
 463 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 464
 465
 466 AS_IF([test "$glib_native_win32" = "yes"], [
 467   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 468     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 469   fi
 470   if test x$enable_static = xyes; then
 471     glib_win32_static_compilation=yes
 472     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 473 #define GOBJECT_STATIC_COMPILATION 1"
 474     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 475   fi
 476 ])
 477 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 478
 479 # Checks for library functions.
 480 AC_FUNC_ALLOCA
 481 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 482 AC_CHECK_FUNCS(timegm gmtime_r posix_spawn)
 483 AC_FUNC_STRERROR_R()
 484
 485 AC_CHECK_SIZEOF(char)
 486 AC_CHECK_SIZEOF(short)
 487 AC_CHECK_SIZEOF(long)
 488 AC_CHECK_SIZEOF(int)
 489 AC_CHECK_SIZEOF(void *)
 490 AC_CHECK_SIZEOF(long long)
 491 AC_CHECK_SIZEOF(__int64)
 492
 493 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 494   [AC_TRY_LINK([#include <signal.h>
 495      #include <sys/types.h>
 496      sig_atomic_t val = 42;],
 497     [return val == 42 ? 0 : 1],
 498    ac_cv_type_sig_atomic_t=yes,
 499    ac_cv_type_sig_atomic_t=no)])
 500 if test x$ac_cv_type_sig_atomic_t = xyes; then
 501    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 502      [Define if you have the 'sig_atomic_t' type.])
 503 fi
 504
 505 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 506   :
 507 else
 508   AC_MSG_ERROR([
 509 *** GLib requires a 64 bit type. You might want to consider
 510 *** using the GNU C compiler.
 511 ])
 512 fi
 513
 514 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 515         # long long is a 64 bit integer.
 516         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 517         AC_CACHE_VAL(glib_cv_long_long_format,[
 518                 for format in ll q I64; do
 519                   AC_TRY_RUN([#include <stdio.h>
 520                         int main()
 521                         {
 522                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 523                           char buffer[1000];
 524                           sprintf (buffer, "%${format}u", a);
 525                           sscanf (buffer, "%${format}u", &b);
 526                           exit (b!=a);
 527                         }
 528                         ],
 529                         [glib_cv_long_long_format=${format}
 530                         break],
 531                         [],[:])
 532                 done])
 533         AS_IF([ test -n "$glib_cv_long_long_format"], [
 534           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 535         ], [AC_MSG_RESULT(none)])
 536 ],[ test x$ac_cv_sizeof___int64 = x8], [
 537         # __int64 is a 64 bit integer.
 538         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 539         # We know this is MSVCRT.DLL, and what the formats are
 540         glib_cv_long_long_format=I64
 541         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 542 ])
 543
 544 AC_C_CONST
 545
 546 dnl
 547 dnl check in which direction the stack grows
 548 dnl
 549 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 550         AC_TRY_RUN([
 551         volatile int *a = 0, *b = 0;
 552         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 553         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 554         ],
 555         glib_cv_stack_grows=yes
 556         ,
 557         glib_cv_stack_grows=no
 558         ,)
 559 ])
 560
 561 # check for flavours of varargs macros
 562 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 563 AC_TRY_COMPILE([],[
 564 int a(int p1, int p2, int p3);
 565 #define call_a(...) a(1,__VA_ARGS__)
 566 call_a(2,3);
 567 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 568 AC_MSG_RESULT($g_have_iso_c_varargs)
 569
 570 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 571 AS_IF([test "$CXX" = ""], [
 572 dnl No C++ compiler
 573   g_have_iso_cxx_varargs=no
 574 else
 575   AC_LANG_CPLUSPLUS
 576   AC_TRY_COMPILE([],[
 577 int a(int p1, int p2, int p3);
 578 #define call_a(...) a(1,__VA_ARGS__)
 579 call_a(2,3);
 580 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 581   AC_LANG_C
 582 ])
 583 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 584
 585 AC_MSG_CHECKING(for GNUC varargs macros)
 586 AC_TRY_COMPILE([],[
 587 int a(int p1, int p2, int p3);
 588 #define call_a(params...) a(1,params)
 589 call_a(2,3);
 590 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 591 AC_MSG_RESULT($g_have_gnuc_varargs)
 592
 593 # check for GNUC visibility support
 594 AC_MSG_CHECKING(for GNUC visibility attribute)
 595 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 596 void
 597 __attribute__ ((visibility ("hidden")))
 598      f_hidden (void)
 599 {
 600 }
 601 void
 602 __attribute__ ((visibility ("internal")))
 603      f_internal (void)
 604 {
 605 }
 606 void
 607 __attribute__ ((visibility ("protected")))
 608      f_protected (void)
 609 {
 610 }
 611 void
 612 __attribute__ ((visibility ("default")))
 613      f_default (void)
 614 {
 615 }
 616 int main (void)
 617 {
 618         f_hidden();
 619         f_internal();
 620         f_protected();
 621         f_default();
 622         return 0;
 623 }
 624 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 625 AC_MSG_RESULT($g_have_gnuc_visibility)
 626 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 627
 628 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 629 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 630 #else
 631 # include "error: this is not Sun Studio."
 632 #endif
 633 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 634 AC_MSG_RESULT($g_have_sunstudio_visibility)
 635 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 636
 637 # check for bytesex stuff
 638 AC_C_BIGENDIAN
 639 if test x$ac_cv_c_bigendian = xuniversal ; then
 640   AC_MSG_ERROR([Universal builds not supported: see https://bugzilla.gnome.org/show_bug.cgi?id=742548])
 641 fi
 642
 643
 644 # check for header files
 645 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 646 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 647 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h sys/auxv.h])
 648 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 649 AC_CHECK_HEADERS([linux/magic.h])
 650 AC_CHECK_HEADERS([termios.h])
 651
 652 # Some versions of MSC lack these
 653 AC_CHECK_HEADERS([dirent.h sys/time.h])
 654
 655 # We don't care about this, but we need to keep including it in
 656 # glibconfig.h for backward compatibility
 657 AC_CHECK_HEADERS([values.h])
 658
 659 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 660 [#if HAVE_SYS_PARAM_H
 661  #include <sys/param.h>
 662  #endif
 663 ])
 664 AC_CHECK_FUNCS(sysctlbyname)
 665
 666 AC_HEADER_MAJOR
 667 AS_IF([test "$ac_cv_header_sys_types_h_makedev" = "yes"],
 668       [AC_DEFINE([MAJOR_IN_TYPES], [1], [Define to 1 if `major', `minor', and `makedev' are declared in <sys/types.h>.])])
 669 AC_CHECK_HEADERS([xlocale.h])
 670
 671 # check for structure fields
 672 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec, struct stat.st_birthtime, struct stat.st_birthtimensec, struct stat.st_birthtim, struct stat.st_birthtim.tv_nsec])
 673 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 674 #include <sys/stat.h>
 675 #ifdef G_OS_UNIX
 676 #include <unistd.h>
 677 #endif
 678 #ifdef HAVE_SYS_STATFS_H
 679 #include <sys/statfs.h>
 680 #endif
 681 #ifdef HAVE_SYS_PARAM_H
 682 #include <sys/param.h>
 683 #endif
 684 #ifdef HAVE_SYS_MOUNT_H
 685 #include <sys/mount.h>
 686 #endif])
 687 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 688 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 689 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 690 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 691
 692 AC_STRUCT_DIRENT_D_TYPE
 693
 694 # Checks for libcharset
 695 AM_LANGINFO_CODESET
 696 gl_GLIBC21
 697 AC_ARG_WITH(charsetalias-dir,
 698             AS_HELP_STRING([--with-charsetalias-dir=DIR], [directory for charset.alias file [LIBDIR]]),
 699            [],
 700            [with_charsetalias_dir='${libdir}'])
 701 GLIB_CHARSETALIAS_DIR=$with_charsetalias_dir
 702 AC_SUBST(GLIB_CHARSETALIAS_DIR)
 703
 704 # check additional type sizes
 705 AC_CHECK_SIZEOF(size_t)
 706
 707 dnl Try to figure out whether gsize should be long or int
 708 AC_MSG_CHECKING([for the appropriate definition for size_t])
 709
 710 case $ac_cv_sizeof_size_t in
 711   $ac_cv_sizeof_short)
 712       glib_size_type=short
 713       ;;
 714   $ac_cv_sizeof_int)
 715       glib_size_type=int
 716       ;;
 717   $ac_cv_sizeof_long)
 718       glib_size_type=long
 719       ;;
 720   $ac_cv_sizeof_long_long)
 721       glib_size_type='long long'
 722       ;;
 723   $ac_cv_sizeof__int64)
 724       glib_size_type='__int64'
 725       ;;
 726   *)  AC_MSG_ERROR([No type matching size_t in size])
 727       ;;
 728 esac
 729
 730 dnl If int/long are the same size, we see which one produces
 731 dnl warnings when used in the location as size_t. (This matters
 732 dnl on AIX with xlc)
 733 dnl
 734 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 735        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 736   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 737 #if defined(_AIX) && !defined(__GNUC__)
 738 #pragma options langlvl=stdc89
 739 #endif
 740 #include <stddef.h>
 741 int main ()
 742 {
 743   size_t s = 1;
 744   unsigned int *size_int = &s;
 745   return (int)*size_int;
 746 }
 747     ]])],glib_size_type=int,
 748       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 749 #if defined(_AIX) && !defined(__GNUC__)
 750 #pragma options langlvl=stdc89
 751 #endif
 752 #include <stddef.h>
 753 int main ()
 754 {
 755    size_t s = 1;
 756    unsigned long *size_long = &s;
 757    return (int)*size_long;
 758 }
 759         ]])],glib_size_type=long)])
 760 ])
 761
 762 AC_MSG_RESULT(unsigned $glib_size_type)
 763
 764 AC_CHECK_SIZEOF(ssize_t)
 765
 766 dnl Try to figure out whether gssize should be long or int
 767 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 768
 769 case $ac_cv_sizeof_ssize_t in
 770   $ac_cv_sizeof_short)
 771       glib_ssize_type=short
 772       ;;
 773   $ac_cv_sizeof_int)
 774       glib_ssize_type=int
 775       ;;
 776   $ac_cv_sizeof_long)
 777       glib_ssize_type=long
 778       ;;
 779   $ac_cv_sizeof_long_long)
 780       glib_ssize_type='long long'
 781       ;;
 782   $ac_cv_sizeof__int64)
 783       glib_ssize_type='__int64'
 784       ;;
 785   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 786       ;;
 787 esac
 788
 789 dnl If int/long are the same size, we see which one produces
 790 dnl warnings when used in the location as ssize_t. (This matters
 791 dnl on Android where ssize_t is long and size_t is unsigned int)
 792 dnl
 793 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 794        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 795   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 796 #if defined(_AIX) && !defined(__GNUC__)
 797 #pragma options langlvl=stdc89
 798 #endif
 799 #include <stddef.h>
 800 #ifdef HAVE_INTTYPES_H
 801 # include <inttypes.h>
 802 #endif
 803 #ifdef HAVE_STDINT_H
 804 # include <stdint.h>
 805 #endif
 806 #include <sys/types.h>
 807 int main ()
 808 {
 809   ssize_t s = 1;
 810   int *size_int = &s;
 811   return (int)*size_int;
 812 }
 813     ]])],glib_ssize_type=int,
 814       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 815 #if defined(_AIX) && !defined(__GNUC__)
 816 #pragma options langlvl=stdc89
 817 #endif
 818 #include <stddef.h>
 819 #ifdef HAVE_INTTYPES_H
 820 # include <inttypes.h>
 821 #endif
 822 #ifdef HAVE_STDINT_H
 823 # include <stdint.h>
 824 #endif
 825 #include <sys/types.h>
 826 int main ()
 827 {
 828    ssize_t s = 1;
 829    long *size_long = &s;
 830    return (int)*size_long;
 831 }
 832         ]])],glib_ssize_type=long)])
 833 ])
 834
 835 AC_MSG_RESULT($glib_ssize_type)
 836
 837 dnl Some platforms (Apple) hard-code int64_t to long long instead of
 838 dnl using long on 64-bit architectures. This can cause type mismatch
 839 dnl warnings when trying to interface with code using the standard
 840 dnl library type. Test for the warnings and set gint64 to whichever
 841 dnl works.
 842 dnl
 843 AS_IF([test $ac_cv_sizeof_long_long = $ac_cv_sizeof_long], [
 844   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 845 #if defined(_AIX) && !defined(__GNUC__)
 846 #pragma options langlvl=stdc99
 847 #endif
 848 #include <stdint.h>
 849 #include <stdio.h>
 850 int main ()
 851 {
 852   int64_t i1 = 1;
 853   long *i2 = &i1;
 854   return 1;
 855 }
 856     ]])],[ glib_cv_int64_t=long ],
 857       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 858 #if defined(_AIX) && !defined(__GNUC__)
 859 #pragma options langlvl=stdc99
 860 #endif
 861 #include <stdint.h>
 862 #include <stdio.h>
 863 int main ()
 864 {
 865   int64_t i1 = 1;
 866   long long *i2 = &i1;
 867   return 1;
 868 }
 869         ]])],[ glib_cv_int64_t=long_long ])])
 870 ])
 871
 872 # Check for some functions
 873 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk mkostemp link)
 874 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 875 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 876 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 877 AC_CHECK_FUNCS(splice)
 878 AC_CHECK_FUNCS(prlimit)
 879
 880 # To avoid finding a compatibility unusable statfs, which typically
 881 # successfully compiles, but warns to use the newer statvfs interface:
 882 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 883 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 884
 885 AC_MSG_CHECKING([whether to use statfs or statvfs])
 886 # Some systems have both statfs and statvfs, pick the most "native" for these
 887 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 888    [
 889    # on solaris and irix, statfs doesn't even have the f_bavail field
 890    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 891       [ac_cv_func_statfs=no],
 892    # else, at least on linux, statfs is the actual syscall
 893       [ac_cv_func_statvfs=no])
 894    ])
 895
 896 AS_IF([test x$ac_cv_func_statfs = xyes],
 897       [
 898          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 899          AC_MSG_RESULT([statfs])
 900       ],
 901       [test x$ac_cv_func_statvfs = xyes],
 902       [
 903          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 904          AC_MSG_RESULT([statvfs])
 905       ],
 906       [  AC_MSG_RESULT([neither])])
 907
 908 AC_CHECK_HEADERS(crt_externs.h)
 909 AC_CHECK_FUNCS(_NSGetEnviron)
 910
 911 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
 912
 913 # Internet address families
 914 if test $glib_native_win32 = yes; then
 915   glib_inet_includes=["
 916 #include <winsock2.h>
 917   "]
 918 else
 919   glib_inet_includes=["
 920 #include <sys/types.h>
 921 #include <sys/socket.h>
 922   "]
 923 fi
 924
 925 glib_failed=false
 926 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 927 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 928 # winsock defines this even though it doesn't support it
 929 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 930 if $glib_failed ; then
 931   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 932 fi
 933
 934 glib_failed=false
 935 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
 936 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
 937 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
 938 if $glib_failed ; then
 939   AC_MSG_ERROR([Could not determine values for MSG_* constants])
 940 fi
 941
 942 AC_CHECK_FUNCS(endservent if_nametoindex if_indextoname sendmmsg recvmmsg)
 943
 944 AC_MSG_CHECKING([for SIOCGIFADDR])
 945 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 946     [[
 947         #include <sys/ioctl.h>
 948         #include <net/if.h>
 949     ]],
 950     [[
 951         struct ifreq ifr;
 952         ioctl(0, SIOCGIFADDR, &ifr);
 953     ]])], [
 954         AC_MSG_RESULT(yes)
 955         AC_DEFINE(HAVE_SIOCGIFADDR, 1, [SIOCGIFADDR is available])
 956     ], [
 957         AC_MSG_RESULT(no)
 958 ])
 959
 960 # See https://bugzilla.gnome.org/show_bug.cgi?id=740791
 961 AS_IF([test $glib_native_android = yes], [
 962   AC_MSG_CHECKING([if ip_mreq_source.imr_interface has s_addr member])
 963   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 964       [[
 965           #include <netinet/in.h>
 966       ]],
 967       [[
 968           struct ip_mreq_source mc_req_src;
 969           mc_req_src.imr_interface.s_addr = 0;
 970       ]])], [
 971           AC_MSG_RESULT(yes)
 972       ], [
 973           AC_MSG_RESULT(no)
 974           AC_DEFINE(BROKEN_IP_MREQ_SOURCE_STRUCT, 1, [struct ip_mreq_source definition is broken on Android NDK <= r16])
 975   ])])
 976
 977 AS_IF([test $glib_native_win32 = yes], [
 978   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
 979   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
 980   # they aren't present at run-time (on Windows 2000).
 981   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
 982   AC_SUBST(WSPIAPI_INCLUDE)
 983 ], [
 984   # Android does not have C_IN in public headers, we define it wherever necessary
 985   AS_IF([test $glib_native_android != yes], [
 986     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
 987     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 988                                         #include <arpa/nameser.h>],
 989                                        [int qclass = C_IN;])],
 990                       [AC_MSG_RESULT([no])],
 991                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 992                                                            #include <arpa/nameser.h>
 993                                                            #include <arpa/nameser_compat.h>],
 994                                                           [int qclass = C_IN;])],
 995                                          [AC_MSG_RESULT([yes])
 996                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
 997                                          [AC_MSG_ERROR([could not compile test program either way])])])])
 998   AC_SUBST(NAMESER_COMPAT_INCLUDE)
 999
1000   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1001   NETWORK_LIBS=""
1002   AC_MSG_CHECKING([for res_query])
1003   AC_TRY_LINK([#include <sys/types.h>
1004                #include <netinet/in.h>
1005                #include <arpa/nameser.h>
1006                #include <resolv.h>
1007               ],[
1008                res_query("test", 0, 0, (void *)0, 0);
1009               ],[AC_MSG_RESULT([yes])],
1010               [save_libs="$LIBS"
1011                LIBS="-lresolv $LIBS"
1012                AC_TRY_LINK([#include <sys/types.h>
1013                             #include <netinet/in.h>
1014                             #include <arpa/nameser.h>
1015                             #include <resolv.h>
1016                            ],[
1017                             res_query("test", 0, 0, (void *)0, 0);
1018                            ],[AC_MSG_RESULT([in -lresolv])
1019                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1020                            [LIBS="-lbind $save_libs"
1021                             AC_TRY_LINK([#include <resolv.h>],
1022                                         [res_query("test", 0, 0, (void *)0, 0);],
1023                                         [AC_MSG_RESULT([in -lbind])
1024                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1025                                         [AC_MSG_ERROR(not found)])])
1026                LIBS="$save_libs"])
1027   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1028                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1029                                         [AC_MSG_ERROR(Could not find socket())]))
1030   save_libs="$LIBS"
1031   LIBS="$LIBS $NETWORK_LIBS"
1032
1033   AC_MSG_CHECKING([for res_init])
1034   AC_TRY_LINK([#include <sys/types.h>
1035                #include <netinet/in.h>
1036                #include <arpa/nameser.h>
1037                #include <resolv.h>
1038               ],[
1039                res_init();
1040               ],[AC_MSG_RESULT([yes])
1041                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1042               ],[AC_MSG_RESULT([no])])
1043
1044   AC_MSG_CHECKING([for res_nclose])
1045   AC_TRY_LINK([#include <sys/types.h>
1046                #include <netinet/in.h>
1047                #include <arpa/nameser.h>
1048                #include <resolv.h>
1049               ],[
1050                struct __res_state res;
1051                res_nclose(&res);
1052               ],[AC_MSG_RESULT([yes])
1053                  AC_DEFINE(HAVE_RES_NCLOSE, 1, [Define to 1 if you have the 'res_nclose' function.])
1054               ],[AC_MSG_RESULT([no])])
1055
1056   AC_MSG_CHECKING([for res_ndestroy])
1057   AC_TRY_LINK([#include <sys/types.h>
1058                #include <netinet/in.h>
1059                #include <arpa/nameser.h>
1060                #include <resolv.h>
1061               ],[
1062                struct __res_state res;
1063                res_ndestroy(&res);
1064               ],[AC_MSG_RESULT([yes])
1065                  AC_DEFINE(HAVE_RES_NDESTROY, 1, [Define to 1 if you have the 'res_ndestroy' function.])
1066               ],[AC_MSG_RESULT([no])])
1067
1068   AC_MSG_CHECKING([for res_ninit])
1069   AC_TRY_LINK([#include <sys/types.h>
1070                #include <netinet/in.h>
1071                #include <arpa/nameser.h>
1072                #include <resolv.h>
1073               ],[
1074                struct __res_state res;
1075                res_ninit(&res);
1076               ],[AC_MSG_RESULT([yes])
1077                  AC_DEFINE(HAVE_RES_NINIT, 1, [Define to 1 if you have the 'res_ninit' function.])
1078               ],[AC_MSG_RESULT([no])])
1079
1080   AC_MSG_CHECKING([for res_nquery])
1081   AC_TRY_LINK([#include <sys/types.h>
1082                #include <netinet/in.h>
1083                #include <arpa/nameser.h>
1084                #include <resolv.h>
1085               ],[
1086                struct __res_state res;
1087                res_nquery(&res, "test", 0, 0, (void *)0, 0);
1088               ],[AC_MSG_RESULT([yes])
1089                  AC_DEFINE(HAVE_RES_NQUERY, 1, [Define to 1 if you have the 'res_nquery' function.])
1090               ],[AC_MSG_RESULT([no])])
1091   LIBS="$save_libs"
1092 ])
1093 AC_SUBST(NETWORK_LIBS)
1094
1095 AC_CHECK_HEADER([linux/netlink.h],
1096                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1097                 [#include <sys/socket.h>])
1098 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1099
1100 AC_CHECK_TYPE([struct ip_mreqn], [
1101               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1102               [#include <netinet/in.h>])
1103
1104 case $host in
1105   *-*-solaris* )
1106      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1107      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1108      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      ;;
1110 esac
1111
1112 dnl
1113 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1114 dnl
1115 AS_IF([test "$ac_cv_func_statfs" = yes], [
1116   AC_MSG_CHECKING([number of arguments to statfs()])
1117   AC_TRY_COMPILE([#include <unistd.h>
1118   #ifdef HAVE_SYS_PARAM_H
1119   #include <sys/param.h>
1120   #endif
1121   #ifdef HAVE_SYS_VFS_H
1122   #include <sys/vfs.h>
1123   #endif
1124   #ifdef HAVE_SYS_MOUNT_H
1125   #include <sys/mount.h>
1126   #endif
1127   #ifdef HAVE_SYS_STATFS_H
1128   #include <sys/statfs.h>
1129   #endif], [struct statfs st;
1130   statfs("/", &st);],[
1131     AC_MSG_RESULT([2])
1132     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1133     AC_TRY_COMPILE([#include <unistd.h>
1134   #ifdef HAVE_SYS_PARAM_H
1135   #include <sys/param.h>
1136   #endif
1137   #ifdef HAVE_SYS_VFS_H
1138   #include <sys/vfs.h>
1139   #endif
1140   #ifdef HAVE_SYS_MOUNT_H
1141   #include <sys/mount.h>
1142   #endif
1143   #ifdef HAVE_SYS_STATFS_H
1144   #include <sys/statfs.h>
1145   #endif], [struct statfs st;
1146   statfs("/", &st, sizeof (st), 0);],[
1147       AC_MSG_RESULT([4])
1148       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1149       AC_MSG_RESULT(unknown)
1150       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1151 ])
1152
1153 dnl
1154 dnl open takes O_DIRECTORY as an option
1155 dnl
1156 AC_MSG_CHECKING([open() option O_DIRECTORY])
1157 AC_TRY_COMPILE([#include <fcntl.h>
1158 #include <sys/types.h>
1159 #include <sys/stat.h>],
1160 [open(0, O_DIRECTORY, 0);],[
1161         AC_MSG_RESULT([yes])
1162         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1163         AC_MSG_RESULT([no])])
1164
1165 #
1166 # Check whether to use an included printf
1167 #
1168 AC_FUNC_VSNPRINTF_C99
1169 AC_FUNC_PRINTF_UNIX98
1170
1171 AC_ARG_ENABLE(included-printf,
1172               [AS_HELP_STRING([--enable-included-printf],
1173                               [use included printf [default=auto]])],
1174               enable_included_printf="$enableval")
1175
1176 need_included_printf=no
1177 if test "x$enable_included_printf" = "xyes" ; then
1178   need_included_printf=yes
1179 fi
1180 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1181   need_included_printf=yes
1182 fi
1183 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1184   need_included_printf=yes
1185 fi
1186 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1187    test -z "$glib_cv_long_long_format" ; then
1188   need_included_printf=yes
1189 fi
1190
1191 if test "x$enable_included_printf" = "xno" &&
1192    test "x$need_included_printf" = "xyes" ; then
1193   AC_MSG_ERROR([
1194 *** Your C library's printf doesn't appear to have the features that
1195 *** GLib needs, but you specified --enable-included-printf=no.])
1196 fi
1197
1198 enable_included_printf=$need_included_printf
1199
1200 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1201 AS_IF([test "$enable_included_printf" != "yes"], [
1202   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1203 ], [
1204   if test -z "$glib_cv_long_long_format" ; then
1205     glib_cv_long_long_format="ll"
1206   fi
1207   AC_DEFINE(HAVE_VASPRINTF,1)
1208 ])
1209
1210 # Checks needed for gnulib vasnprintf
1211 bh_C_SIGNED
1212 jm_AC_TYPE_LONG_LONG
1213 gt_TYPE_LONGDOUBLE
1214 gt_TYPE_WCHAR_T
1215 gt_TYPE_WINT_T
1216 AC_TYPE_SIZE_T
1217 AC_CHECK_TYPES(ptrdiff_t)
1218 jm_AC_TYPE_INTMAX_T
1219 AC_CHECK_FUNCS([snprintf strnlen wcslen wcsnlen mbrtowc wcrtomb])
1220 AC_FUNC_SNPRINTF_C99
1221
1222 dnl Check for nl_langinfo and CODESET
1223 AC_LANG_SAVE
1224 AC_LANG_C
1225 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1226         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1227                        [char *codeset = nl_langinfo (CODESET);])],
1228                 [glib_cv_langinfo_codeset=yes],
1229                 [glib_cv_langinfo_codeset=no])])
1230 if test x$glib_cv_langinfo_codeset = xyes; then
1231   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1232 fi
1233
1234 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1235 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1236         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1237                  [char *str;
1238                  str = nl_langinfo (PM_STR);
1239                  str = nl_langinfo (D_T_FMT);
1240                  str = nl_langinfo (D_FMT);
1241                  str = nl_langinfo (T_FMT);
1242                  str = nl_langinfo (T_FMT_AMPM);
1243                  str = nl_langinfo (MON_1);
1244                  str = nl_langinfo (ABMON_12);
1245                  str = nl_langinfo (DAY_1);
1246                  str = nl_langinfo (ABDAY_7);])],
1247                 [glib_cv_langinfo_time=yes],
1248                 [glib_cv_langinfo_time=no])])
1249 if test x$glib_cv_langinfo_time = xyes; then
1250   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1251 fi
1252
1253 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1254 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1255         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1256                 [char *str;
1257                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1258                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1259                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1260                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1261                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1262                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1263                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1264                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1265                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1266                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1267                 [glib_cv_langinfo_outdigit=yes],
1268                 [glib_cv_langinfo_outdigit=no])])
1269 if test x$glib_cv_langinfo_outdigit = xyes; then
1270   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1271 fi
1272
1273 dnl Check for nl_langinfo and ALTMON_n
1274 AC_CACHE_CHECK([for nl_langinfo (ALTMON_n)], glib_cv_langinfo_altmon,[
1275         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1276                 [char *str;
1277                  str = nl_langinfo (ALTMON_1);
1278                  str = nl_langinfo (ALTMON_2);
1279                  str = nl_langinfo (ALTMON_3);
1280                  str = nl_langinfo (ALTMON_4);
1281                  str = nl_langinfo (ALTMON_5);
1282                  str = nl_langinfo (ALTMON_6);
1283                  str = nl_langinfo (ALTMON_7);
1284                  str = nl_langinfo (ALTMON_8);
1285                  str = nl_langinfo (ALTMON_9);
1286                  str = nl_langinfo (ALTMON_10);
1287                  str = nl_langinfo (ALTMON_11);
1288                  str = nl_langinfo (ALTMON_12);])],
1289                 [glib_cv_langinfo_altmon=yes],
1290                 [glib_cv_langinfo_altmon=no])])
1291 if test x$glib_cv_langinfo_altmon = xyes; then
1292   AC_DEFINE(HAVE_LANGINFO_ALTMON,1,[Have nl_langinfo (ALTMON_n)])
1293 fi
1294
1295 dnl Check for nl_langinfo and _NL_ABALTMON_n
1296 AC_CACHE_CHECK([for nl_langinfo (_NL_ABALTMON_n)], glib_cv_langinfo_abaltmon,[
1297         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1298                 [char *str;
1299                  str = nl_langinfo (_NL_ABALTMON_1);
1300                  str = nl_langinfo (_NL_ABALTMON_2);
1301                  str = nl_langinfo (_NL_ABALTMON_3);
1302                  str = nl_langinfo (_NL_ABALTMON_4);
1303                  str = nl_langinfo (_NL_ABALTMON_5);
1304                  str = nl_langinfo (_NL_ABALTMON_6);
1305                  str = nl_langinfo (_NL_ABALTMON_7);
1306                  str = nl_langinfo (_NL_ABALTMON_8);
1307                  str = nl_langinfo (_NL_ABALTMON_9);
1308                  str = nl_langinfo (_NL_ABALTMON_10);
1309                  str = nl_langinfo (_NL_ABALTMON_11);
1310                  str = nl_langinfo (_NL_ABALTMON_12);])],
1311                 [glib_cv_langinfo_abaltmon=yes],
1312                 [glib_cv_langinfo_abaltmon=no])])
1313 if test x$glib_cv_langinfo_abaltmon = xyes; then
1314   AC_DEFINE(HAVE_LANGINFO_ABALTMON,1,[Have nl_langinfo (_NL_ABALTMON_n)])
1315 fi
1316 AC_LANG_RESTORE
1317
1318
1319 dnl ****************************************
1320 dnl *** strlcpy/strlcat                  ***
1321 dnl ****************************************
1322 # Check for strlcpy
1323 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1324 AC_TRY_RUN([#include <stdlib.h>
1325 #include <string.h>
1326 int main() {
1327   char p[10];
1328   (void) strlcpy (p, "hi", 10);
1329   if (strlcat (p, "bye", 0) != 3)
1330     return 1;
1331   return 0;
1332 }], glib_cv_have_strlcpy=yes,
1333     glib_cv_have_strlcpy=no,
1334     glib_cv_have_strlcpy=no)])
1335 if test "$glib_cv_have_strlcpy" = "yes"; then
1336     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1337 fi
1338
1339
1340 dnl **********************
1341 dnl *** va_copy checks ***
1342 dnl **********************
1343 dnl we currently check for all three va_copy possibilities, so we get
1344 dnl all results in config.log for bug reports.
1345 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1346         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1347 #include <stdlib.h>
1348         void f (int i, ...) {
1349         va_list args1, args2;
1350         va_start (args1, i);
1351         va_copy (args2, args1);
1352         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1353           exit (1);
1354         va_end (args1); va_end (args2);
1355         }
1356         int main() {
1357           f (0, 42);
1358           return 0;
1359         }]])],
1360         [glib_cv_va_copy=yes],
1361         [glib_cv_va_copy=no])
1362 ])
1363 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1364         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1365 #include <stdlib.h>
1366         void f (int i, ...) {
1367         va_list args1, args2;
1368         va_start (args1, i);
1369         __va_copy (args2, args1);
1370         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1371           exit (1);
1372         va_end (args1); va_end (args2);
1373         }
1374         int main() {
1375           f (0, 42);
1376           return 0;
1377         }]])],
1378         [glib_cv___va_copy=yes],
1379         [glib_cv___va_copy=no])
1380 ])
1381
1382 if test "x$glib_cv_va_copy" = "xyes"; then
1383   g_va_copy_func=va_copy
1384 else if test "x$glib_cv___va_copy" = "xyes"; then
1385   g_va_copy_func=__va_copy
1386 fi
1387 fi
1388
1389 if test -n "$g_va_copy_func"; then
1390   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1391 fi
1392
1393 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1394         AC_TRY_RUN([#include <stdarg.h>
1395 #include <stdlib.h>
1396         void f (int i, ...) {
1397         va_list args1, args2;
1398         va_start (args1, i);
1399         args2 = args1;
1400         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1401           exit (1);
1402         va_end (args1); va_end (args2);
1403         }
1404         int main() {
1405           f (0, 42);
1406           return 0;
1407         }],
1408         [glib_cv_va_val_copy=yes],
1409         [glib_cv_va_val_copy=no],
1410         [glib_cv_va_val_copy=yes])
1411 ])
1412
1413 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1414   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1415 ])
1416
1417 dnl ***********************
1418 dnl *** g_module checks ***
1419 dnl ***********************
1420 G_MODULE_LIBS=
1421 G_MODULE_LIBS_EXTRA=
1422 G_MODULE_PLUGIN_LIBS=
1423 if test x"$glib_native_win32" = xyes; then
1424   dnl No use for this on Win32
1425   G_MODULE_LDFLAGS=
1426 else
1427   export SED
1428   eval G_MODULE_LDFLAGS=$export_dynamic_flag_spec
1429 fi
1430 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1431 G_MODULE_NEED_USCORE=0
1432 G_MODULE_BROKEN_RTLD_GLOBAL=0
1433 G_MODULE_HAVE_DLERROR=0
1434 dnl *** force native WIN32 shared lib loader
1435 if test -z "$G_MODULE_IMPL"; then
1436   case "$host" in
1437   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1438   esac
1439 fi
1440 dnl *** force native AIX library loader
1441 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1442 if test -z "$G_MODULE_IMPL"; then
1443   case "$host" in
1444   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1445   esac
1446 fi
1447 dnl *** dlopen() and dlsym() in system libraries
1448 AS_IF([ test -z "$G_MODULE_IMPL"], [
1449         AC_CHECK_FUNC(dlopen,
1450                       [AC_CHECK_FUNC(dlsym,
1451                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1452                       [])
1453 ])
1454 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1455 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1456         AC_CHECK_FUNC(NSLinkModule,
1457                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1458                        G_MODULE_NEED_USCORE=1],
1459                       [])
1460 ])
1461 dnl *** dlopen() and dlsym() in libdl
1462 AS_IF([ test -z "$G_MODULE_IMPL"], [
1463         AC_CHECK_LIB(dl, dlopen,
1464                      [AC_CHECK_LIB(dl, dlsym,
1465                                    [G_MODULE_LIBS=-ldl
1466                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1467                      [])
1468 ])
1469 dnl *** additional checks for G_MODULE_IMPL_DL
1470 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1471         LIBS_orig="$LIBS"
1472         LDFLAGS_orig="$LDFLAGS"
1473         LIBS="$G_MODULE_LIBS $LIBS"
1474         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1475 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1476         echo "void glib_plugin_test(void) { }" > plugin.c
1477         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1478                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1479         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1480                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1481                 -shrext ".o" -avoid-version plugin.lo \
1482                 -rpath /dont/care >/dev/null 2>&1
1483         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1484                 glib_cv_rtldglobal_broken,[
1485                 AC_TRY_RUN([
1486 #include <dlfcn.h>
1487 #ifndef RTLD_GLOBAL
1488 #  define RTLD_GLOBAL 0
1489 #endif
1490 #ifndef RTLD_LAZY
1491 #  define RTLD_LAZY 0
1492 #endif
1493 int glib_plugin_test;
1494 int main () {
1495     void *handle, *global, *local;
1496     global = &glib_plugin_test;
1497     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1498     if (!handle) return 0;
1499     local = dlsym (handle, "glib_plugin_test");
1500     return global == local;
1501 }                       ],
1502                         [glib_cv_rtldglobal_broken=no],
1503                         [glib_cv_rtldglobal_broken=yes],
1504                         [glib_cv_rtldglobal_broken=no])
1505                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1506                 rmdir ${objdir} 2>/dev/null
1507         ])
1508         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1509                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1510         else
1511                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1512         fi
1513 dnl *** check whether we need preceeding underscores
1514         AC_CACHE_CHECK([for preceeding underscore in symbols],
1515                 glib_cv_uscore,[
1516                 AC_TRY_RUN([#include <dlfcn.h>
1517                 int glib_underscore_test (void) { return 42; }
1518                 int main() {
1519                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1520                   handle = dlopen ((void*)0, 0);
1521                   if (handle) {
1522                     f1 = dlsym (handle, "glib_underscore_test");
1523                     f2 = dlsym (handle, "_glib_underscore_test");
1524                   } return (!f2 || f1);
1525                 }],
1526                         [glib_cv_uscore=yes],
1527                         [glib_cv_uscore=no],
1528                         [])
1529                 rm -f plugin.c plugin.$ac_objext plugin.lo
1530         ])
1531         GLIB_ASSERT_SET(glib_cv_uscore)
1532         if test "x$glib_cv_uscore" = "xyes"; then
1533                 G_MODULE_NEED_USCORE=1
1534         else
1535                 G_MODULE_NEED_USCORE=0
1536         fi
1537
1538         AC_CHECK_DECL([RTLD_LAZY],
1539                       [AC_DEFINE(HAVE_RTLD_LAZY, 1, [Define to 1 if RTLD_LAZY is available])],
1540                       [], [[#include <dlfcn.h>]])
1541         AC_CHECK_DECL([RTLD_NOW],
1542                       [AC_DEFINE(HAVE_RTLD_NOW, 1, [Define to 1 if RTLD_NOW is available])],
1543                       [], [[#include <dlfcn.h>]])
1544         AC_CHECK_DECL([RTLD_GLOBAL],
1545                       [AC_DEFINE(HAVE_RTLD_GLOBAL, 1, [Define to 1 if RTLD_GLOBAL is available])],
1546                       [], [[#include <dlfcn.h>]])
1547
1548         LDFLAGS="$LDFLAGS_orig"
1549 dnl *** check for having dlerror()
1550         AC_CHECK_FUNC(dlerror,
1551                 [G_MODULE_HAVE_DLERROR=1],
1552                 [G_MODULE_HAVE_DLERROR=0])
1553         LIBS="$LIBS_orig"
1554 ])
1555 dnl *** done, have we got an implementation?
1556 if test -z "$G_MODULE_IMPL"; then
1557         G_MODULE_IMPL=0
1558         G_MODULE_SUPPORTED=false
1559 else
1560         G_MODULE_SUPPORTED=true
1561 fi
1562
1563 AC_MSG_CHECKING(for the suffix of module shared libraries)
1564 export SED
1565 module=yes eval std_shrext=$shrext_cmds
1566 # chop the initial dot
1567 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1568 AC_MSG_RESULT(.$glib_gmodule_suffix)
1569 # any reason it may fail?
1570 if test "x$glib_gmodule_suffix" = x; then
1571         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1572 fi
1573
1574 AC_SUBST(G_MODULE_SUPPORTED)
1575 AC_SUBST(G_MODULE_IMPL)
1576 AC_SUBST(G_MODULE_LIBS)
1577 AC_SUBST(G_MODULE_LIBS_EXTRA)
1578 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1579 AC_SUBST(G_MODULE_LDFLAGS)
1580 AC_SUBST(G_MODULE_HAVE_DLERROR)
1581 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1582 AC_SUBST(G_MODULE_NEED_USCORE)
1583 AC_SUBST(GLIB_DEBUG_FLAGS)
1584
1585 dnl **********************
1586 dnl *** g_spawn checks ***
1587 dnl **********************
1588
1589 AC_MSG_CHECKING(for gspawn implementation)
1590 case "$host" in
1591   *-*-mingw*)
1592     g_spawn_impl=win32
1593     ;;
1594   *)
1595     g_spawn_impl=unix
1596     ;;
1597 esac
1598 AC_MSG_RESULT($g_spawn_impl)
1599 AM_CONDITIONAL(G_SPAWN_WIN32, [test "$g_spawn_impl" = "win32"])
1600
1601 dnl *************************
1602 dnl *** GIOChannel checks ***
1603 dnl *************************
1604
1605 AC_MSG_CHECKING(for GIOChannel implementation)
1606 case "$host" in
1607   *-*-mingw*)
1608     g_io_channel_impl=win32
1609     ;;
1610   *)
1611     g_io_channel_impl=unix
1612     ;;
1613 esac
1614 AC_MSG_RESULT($g_io_channel_impl)
1615 AM_CONDITIONAL(G_IO_CHANNEL_WIN32, [test "$g_io_channel_impl" = "win32"])
1616
1617 dnl *********************************
1618 dnl *** Directory for GIO modules ***
1619 dnl *********************************
1620
1621 AC_ARG_WITH(gio-module-dir,
1622            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1623                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1624            [],
1625            [with_gio_module_dir='${libdir}/gio/modules'])
1626 GIO_MODULE_DIR=$with_gio_module_dir
1627 AC_SUBST(GIO_MODULE_DIR)
1628
1629 dnl **********************************
1630 dnl *** Check for libselinux (GIO) ***
1631 dnl **********************************
1632 AC_ARG_ENABLE(selinux,
1633               AS_HELP_STRING([--disable-selinux],
1634                              [build without selinux support]))
1635 msg_selinux=no
1636 SELINUX_LIBS=
1637 AS_IF([ test "x$enable_selinux" != "xno"], [
1638
1639  AC_CHECK_LIB(selinux, is_selinux_enabled,
1640    [AC_CHECK_HEADERS(selinux/selinux.h,
1641      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1642        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1643         SELINUX_LIBS="-lselinux"
1644         msg_selinux=yes])
1645      ])
1646    ])
1647 ])
1648 AC_SUBST(SELINUX_LIBS)
1649
1650 dnl *****************************
1651 dnl ** Check for inotify (GIO) **
1652 dnl *****************************
1653 inotify_support=no
1654 AC_CHECK_HEADERS([sys/inotify.h],
1655 [
1656   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1657 ])
1658
1659 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1660
1661 dnl ****************************
1662 dnl ** Check for kqueue (GIO) **
1663 dnl ****************************
1664 kqueue_support=no
1665 AC_CHECK_HEADERS([sys/event.h],
1666 [
1667         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1668 ])
1669
1670 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1671
1672 dnl ****************************
1673 dnl *** Checks for FAM (GIO) ***
1674 dnl ****************************
1675
1676 should_disable_fam=no
1677
1678 AC_ARG_ENABLE(fam,
1679               AS_HELP_STRING([--disable-fam],
1680                              [don't use fam for file system monitoring]),
1681                          [
1682                                 if test "x$enable_fam" = "xno"; then
1683                                         should_disable_fam=yes
1684                                 fi
1685                          ]
1686                          )
1687 fam_support=no
1688 FAM_LIBS=
1689 if test "x$should_disable_fam" = "xno"; then
1690 AC_CHECK_LIB(fam, FAMOpen,
1691   [AC_CHECK_HEADERS(fam.h,
1692     [AC_CHECK_LIB(fam, FAMNoExists,
1693                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1694      FAM_LIBS="-lfam"]
1695      fam_support=yes,
1696     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1697   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1698 AC_SUBST(FAM_LIBS)
1699 fi
1700 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1701
1702
1703 dnl *****************************
1704 dnl *** Check for xattr (GIO) ***
1705 dnl *****************************
1706 AC_ARG_ENABLE(xattr,
1707               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1708 msg_xattr=no
1709 XATTR_LIBS=
1710 AS_IF([ test "x$enable_xattr" != "xno"], [
1711
1712 dnl either glibc or libattr can provide xattr support
1713
1714 dnl for both of them, we check for getxattr being in
1715 dnl the library and a valid xattr header.
1716
1717 dnl try glibc
1718  AC_CHECK_LIB(c, getxattr,
1719    [AC_CHECK_HEADERS(sys/xattr.h,
1720      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1721       msg_xattr=yes])
1722    ])
1723
1724   AS_IF([ test "x$msg_xattr" != "xyes"], [
1725 dnl   failure. try libattr
1726    AC_CHECK_LIB(attr, getxattr,
1727       [AC_CHECK_HEADERS(attr/xattr.h,
1728        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1729         XATTR_LIBS="-lattr"
1730         msg_xattr=yes])
1731       ])
1732   ])
1733
1734   AS_IF([ test "x$msg_xattr" = "xyes"], [
1735     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1736     AC_TRY_COMPILE([
1737       #include <stdio.h>
1738       #ifdef HAVE_SYS_TYPES_H
1739       #include <sys/types.h>
1740       #endif
1741       #ifdef HAVE_SYS_XATTR_H
1742       #include <sys/xattr.h>
1743       #elif HAVE_ATTR_XATTR_H
1744       #include <attr/xattr.h>
1745       #endif
1746     ],
1747     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1748     [
1749       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1750       AC_MSG_RESULT([yes])
1751     ],
1752     [AC_MSG_RESULT([no])]
1753     )
1754   ])
1755 ])
1756 AC_SUBST(XATTR_LIBS)
1757
1758 dnl ************************
1759 dnl *** check for libelf ***
1760 dnl ************************
1761 AC_ARG_ENABLE(libelf,
1762               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1763 AS_IF([ test "x$enable_libelf" != "xno"],[
1764 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1765 AS_IF([ test $have_libelf = maybe ], [
1766   glib_save_LIBS=$LIBS
1767   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1768   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1769   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1770   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1771   LIBS=$glib_save_LIBS
1772
1773   if test $have_libelf != no; then
1774     LIBELF_LIBS=-lelf
1775     have_libelf=yes
1776   fi
1777 ])
1778 ])
1779
1780 if test x$have_libelf = xyes; then
1781   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1782 fi
1783
1784 dnl ************************
1785 dnl *** check for libmount ***
1786 dnl ************************
1787
1788 dnl The fallback code doesn't really implement the same behaviors - e.g.
1789 dnl so on linux we want to require libmount unless specifically disabled
1790 dnl
1791 enable_libmount_default=${glib_os_linux:-no}
1792 AC_ARG_ENABLE(libmount,
1793               [AS_HELP_STRING([--enable-libmount],
1794                               [build with libmount support [default for Linux]])],,
1795               [enable_libmount=$enable_libmount_default])
1796 AS_IF([ test "x$enable_libmount" = "xyes"],[
1797 PKG_CHECK_MODULES([LIBMOUNT], [mount >= 2.23], [have_libmount=yes], [have_libmount=no])
1798 if test $have_libmount = no ; then
1799    AC_MSG_ERROR([*** Could not find libmount])
1800 fi
1801 ])
1802
1803 if test x$have_libmount = xyes; then
1804   AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available])
1805 fi
1806 AM_CONDITIONAL(HAVE_LIBMOUNT, [test x$have_libmount = xyes])
1807
1808 dnl ****************************************
1809 dnl *** platform dependent source checks ***
1810 dnl ****************************************
1811
1812 AC_MSG_CHECKING([whether to compile timeloop])
1813 case "$host" in
1814   *-*-cygwin*|*-*-mingw*|*-*-minix)
1815     enable_timeloop=no
1816     ;;
1817   *)
1818     enable_timeloop=yes
1819     ;;
1820 esac
1821 AC_MSG_RESULT($enable_timeloop)
1822 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1823
1824 AC_MSG_CHECKING([if building for some Win32 platform])
1825 case "$host" in
1826   *-*-mingw*|*-*-cygwin*)
1827     platform_win32=yes
1828     ;;
1829   *)
1830     platform_win32=no
1831     ;;
1832 esac
1833 AC_MSG_RESULT($platform_win32)
1834 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1835
1836 dnl ***********************
1837 dnl *** g_thread checks ***
1838 dnl ***********************
1839
1840 AC_ARG_WITH(threads,
1841            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1842                            [specify a thread implementation to use])],
1843            [],
1844            [with_threads=yes])
1845
1846 dnl error and warning message
1847 dnl *************************
1848
1849 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1850
1851 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1852                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1853                 compilation now, but then your programs might not work.
1854                 Please provide information on how it is done on your system."
1855
1856 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1857                  "
1858
1859 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1860                   provide information on your thread implementation."
1861
1862 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1863                 functions will not be MT-safe during their first call because
1864                 there is no working 'getpwuid_r' on your system."
1865
1866 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1867                 because there is no 'localtime_r' on your system."
1868
1869 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1870                 linking threaded applications. As GLib cannot do that
1871                 automatically, you will get an linkg error everytime you are
1872                 not using the right compiler. In that case you have to relink
1873                 with the right compiler. Ususally just '_r' is appended
1874                 to the compiler name."
1875
1876 dnl determination of thread implementation
1877 dnl ***************************************
1878
1879 AC_MSG_CHECKING(for thread implementation)
1880
1881 have_threads=no
1882 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1883         AS_IF([ test "x$have_threads" = xno], [
1884                 AC_TRY_COMPILE([#include <pthread.h>],
1885                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1886                         have_threads=posix)
1887         ])
1888         # Tru64Unix requires -pthread to find pthread.h. See #103020
1889         if test "x$have_threads" = xno; then
1890                 glib_save_CPPFLAGS="$CPPFLAGS"
1891                 CPPFLAGS="$CPPFLAGS -pthread"
1892                 AC_TRY_COMPILE([#include <pthread.h>],
1893                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1894                        have_threads=posix)
1895                 CPPFLAGS="$glib_save_CPPFLAGS"
1896         fi
1897 ])
1898 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1899         case $host in
1900                 *-*-mingw*)
1901                 have_threads=win32
1902                 ;;
1903         esac
1904 fi
1905
1906 if test "x$have_threads" = xno; then
1907         AC_MSG_RESULT(none available)
1908         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1909 else
1910         AC_MSG_RESULT($have_threads)
1911 fi
1912
1913
1914 dnl determination of G_THREAD_CFLAGS
1915 dnl ********************************
1916
1917 G_THREAD_LIBS=
1918 G_THREAD_LIBS_EXTRA=
1919 G_THREAD_CFLAGS=
1920
1921 dnl
1922 dnl Test program for basic POSIX threads functionality
1923 dnl
1924 m4_define([glib_thread_test],[
1925 #include <pthread.h>
1926 int check_me = 0;
1927 void* func(void* data) {check_me = 42; return &check_me;}
1928 int main()
1929  { pthread_t t;
1930    void *ret;
1931    pthread_create (&t, $1, func, 0);
1932    pthread_join (t, &ret);
1933    return (check_me != 42 || ret != &check_me);
1934 }])
1935
1936 AS_IF([ test x"$have_threads" = xposix], [
1937   # First we test for posix, whether -pthread or -pthreads do the trick as
1938   # both CPPFLAG and LIBS.
1939   # One of them does for most gcc versions and some other platforms/compilers
1940   # too and could be considered as the canonical way to go.
1941   case $host in
1942     *-*-cygwin*|*-*-darwin*)
1943        # skip cygwin and darwin -pthread or -pthreads test
1944        ;;
1945     *-solaris*)
1946       # These compiler/linker flags work with both Sun Studio and gcc
1947       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1948       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1949       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1950       G_THREAD_LIBS="-lpthread -lthread"
1951       ;;
1952     *)
1953       for flag in pthread pthreads mt; do
1954         glib_save_CFLAGS="$CFLAGS"
1955         CFLAGS="$CFLAGS -$flag"
1956         AC_TRY_RUN(glib_thread_test(0),
1957                    glib_flag_works=yes,
1958                    glib_flag_works=no,
1959                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1960                                    glib_flag_works=yes,
1961                                    glib_flag_works=no)])
1962         CFLAGS="$glib_save_CFLAGS"
1963         if test $glib_flag_works = yes ; then
1964            G_THREAD_CFLAGS=-$flag
1965         G_THREAD_LIBS=-$flag
1966         break;
1967         fi
1968       done
1969        ;;
1970   esac
1971 ])
1972
1973 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1974
1975   # The canonical -pthread[s] does not work. Try something different.
1976
1977   case $host in
1978         *-aix*)
1979                 if test x"$GCC" = xyes; then
1980                         # GCC 3.0 and above needs -pthread.
1981                         # Should be coverd by the case above.
1982                         # GCC 2.x and below needs -mthreads
1983                         G_THREAD_CFLAGS="-mthreads"
1984                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1985                 else
1986                         # We are probably using the aix compiler. Normaly a
1987                         # program would have to be compiled with the _r variant
1988                         # of the corresponding compiler, but we as GLib cannot
1989                         # do that: but the good news is that for compiling the
1990                         # only difference is the added -D_THREAD_SAFE compile
1991                         # option. This is according to the "C for AIX User's
1992                         # Guide".
1993                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1994                 fi
1995                 ;;
1996         *-sysv5uw7*) # UnixWare 7
1997                 # We are not using gcc with -pthread. Catched above.
1998                 G_THREAD_CFLAGS="-Kthread"
1999                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2000                 ;;
2001         *-mingw*)
2002                 # No flag needed when using MSVCRT.DLL
2003                 G_THREAD_CFLAGS=""
2004                 ;;
2005         *)
2006                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2007                 ;;
2008   esac
2009 ])
2010
2011 # if we are not finding the localtime_r function, then we probably are
2012 # not using the proper multithread flag
2013
2014 glib_save_CPPFLAGS="$CPPFLAGS"
2015 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2016
2017 # First we test, whether localtime_r is declared in time.h
2018 # directly. Then we test whether a macro localtime_r exists, in
2019 # which case localtime_r in the test program is replaced and thus
2020 # if we still find localtime_r in the output, it is not defined as
2021 # a macro.
2022
2023 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2024   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2025                                                            localtime_r(a,b)],
2026                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2027
2028 CPPFLAGS="$glib_save_CPPFLAGS"
2029
2030 AC_MSG_CHECKING(thread related cflags)
2031 AC_MSG_RESULT($G_THREAD_CFLAGS)
2032 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2033
2034 dnl determination of G_THREAD_LIBS
2035 dnl ******************************
2036
2037 AS_IF([test x$have_threads = xposix], [
2038           glib_save_CPPFLAGS="$CPPFLAGS"
2039           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2040           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2041             case $host in
2042               *-aix*)
2043                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2044                 # probably using the aix compiler.
2045                 AC_MSG_WARN($AIX_COMPILE_INFO)
2046                 ;;
2047               *)
2048                 G_THREAD_LIBS=error
2049                 glib_save_LIBS="$LIBS"
2050                 for thread_lib in "" pthread pthread32 pthreads thread; do
2051                         if test x"$thread_lib" = x; then
2052                                 add_thread_lib=""
2053                                 IN=""
2054                         else
2055                                 add_thread_lib="-l$thread_lib"
2056                                 IN=" in -l$thread_lib"
2057                         fi
2058                         if test x"$have_threads" = xposix; then
2059                                 defattr=0
2060                         else
2061                                 defattr=pthread_attr_default
2062                         fi
2063
2064                         LIBS="$add_thread_lib $glib_save_LIBS"
2065
2066                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2067                         AC_TRY_RUN(glib_thread_test($defattr),
2068                                    glib_result=yes,
2069                                    glib_result=no,
2070                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2071                                                    glib_result=yes,
2072                                                    glib_result=no)])
2073                         AC_MSG_RESULT($glib_result)
2074
2075                         if test "$glib_result" = "yes" ; then
2076                           G_THREAD_LIBS="$add_thread_lib"
2077                           break
2078                         fi
2079                 done
2080                 if test "x$G_THREAD_LIBS" = xerror; then
2081                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2082                 fi
2083                 LIBS="$glib_save_LIBS"
2084                 ;;
2085             esac
2086           ])
2087
2088           g_threads_impl="POSIX"
2089           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2090           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2091           CPPFLAGS="$glib_save_CPPFLAGS"
2092 ], [test x$have_threads = xwin32], [
2093            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2094            g_threads_impl="WIN32"
2095 ], [
2096            g_threads_impl="NONE"
2097            G_THREAD_LIBS=error
2098 ])
2099 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2100 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2101
2102 if test "x$G_THREAD_LIBS" = xerror; then
2103         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2104 fi
2105
2106 AC_MSG_CHECKING(thread related libraries)
2107 AC_MSG_RESULT($G_THREAD_LIBS)
2108
2109 dnl check for mt safe function variants and some posix functions
2110 dnl ************************************************************
2111
2112 glib_save_LIBS="$LIBS"
2113 # we are not doing the following for now, as this might require glib
2114 # to always be linked with the thread libs on some platforms.
2115 # LIBS="$LIBS $G_THREAD_LIBS"
2116 AC_CHECK_FUNCS(localtime_r gmtime_r getpwuid_r getgrgid_r)
2117
2118 LIBS="$G_THREAD_LIBS $LIBS"
2119 AS_IF([ test x"$have_threads" = xposix], [
2120         glib_save_CPPFLAGS="$CPPFLAGS"
2121         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2122         # This is not AC_CHECK_FUNC to also work with function
2123         # name mangling in header files.
2124         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2125         AC_LINK_IFELSE(
2126             [AC_LANG_PROGRAM(
2127                 [#include <pthread.h>],
2128                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2129             [AC_MSG_RESULT(yes)
2130              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2131                 [Have function pthread_attr_setstacksize])],
2132             [AC_MSG_RESULT(no)])
2133         AC_MSG_CHECKING(for pthread_condattr_setclock)
2134         AC_LINK_IFELSE(
2135             [AC_LANG_PROGRAM(
2136                 [#include <pthread.h>],
2137                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2138             [AC_MSG_RESULT(yes)
2139              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2140                 [Have function pthread_condattr_setclock])],
2141             [AC_MSG_RESULT(no)])
2142         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2143         AC_LINK_IFELSE(
2144             [AC_LANG_PROGRAM(
2145                 [#include <pthread.h>],
2146                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2147             [AC_MSG_RESULT(yes)
2148              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2149                 [Have function pthread_cond_timedwait_relative_np])],
2150             [AC_MSG_RESULT(no)])
2151         dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2152         AC_MSG_CHECKING(for pthread_setname_np(const char*))
2153         AC_LINK_IFELSE(
2154             [AC_LANG_PROGRAM(
2155                 [#include <pthread.h>],
2156                 [pthread_setname_np("example")])],
2157             [AC_MSG_RESULT(yes)
2158              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2159                 [Have function pthread_setname_np(const char*)])],
2160             [AC_MSG_RESULT(no)])
2161         dnl Sets thread names on Solaris 11.3 & higher
2162         AC_MSG_CHECKING(for pthread_setname_np(pthread_t, const char*))
2163         AC_LINK_IFELSE(
2164             [AC_LANG_PROGRAM(
2165                 [#include <pthread.h>],
2166                 [pthread_setname_np(pthread_self(), "example")])],
2167             [AC_MSG_RESULT(yes)
2168              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITH_TID,1,
2169                 [Have function pthread_setname_np(pthread_t, const char*)])],
2170             [AC_MSG_RESULT(no)])
2171         AC_MSG_CHECKING(for pthread_getname_np(pthread_t, name, len))
2172         AC_LINK_IFELSE(
2173             [AC_LANG_PROGRAM(
2174                 [#include <pthread.h>],
2175                 [[char name[16]; pthread_getname_np(pthread_self(), name, 16);]])],
2176             [AC_MSG_RESULT(yes)
2177              AC_DEFINE(HAVE_PTHREAD_GETNAME_NP,1,
2178                 [Have function pthread_getname_np(pthread_t, name, len)])],
2179             [AC_MSG_RESULT(no)])
2180         CPPFLAGS="$glib_save_CPPFLAGS"
2181 ])
2182
2183 LIBS="$glib_save_LIBS"
2184
2185 # now spit out all the warnings.
2186 if test "$ac_cv_func_getpwuid_r" != "yes"; then
2187         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2188 fi
2189 if test "$ac_cv_func_localtime_r" != "yes"; then
2190         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2191 fi
2192
2193 #
2194 # Hack to deal with:
2195 #
2196 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2197 #     building shared libraries with linux.
2198 #  b) FreeBSD doesn't do this either.
2199 #
2200 case $host in
2201   *android*)
2202     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2203     ;;
2204   *-*-freebsd*|*-*-linux*)
2205     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2206     ;;
2207   *)
2208     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2209     ;;
2210 esac
2211
2212 AC_SUBST(G_THREAD_CFLAGS)
2213 AC_SUBST(G_THREAD_LIBS)
2214 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2215 AC_SUBST(G_THREAD_LIBS_EXTRA)
2216
2217 AC_CHECK_FUNCS(clock_gettime, [], [
2218   AC_CHECK_LIB(rt, clock_gettime, [
2219     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2220     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2221   ])
2222 ])
2223
2224
2225 dnl ************************
2226 dnl *** g_atomic_* tests ***
2227 dnl ************************
2228
2229 dnl We need to decide at configure time if GLib will use real atomic
2230 dnl operations ("lock free") or emulated ones with a mutex.  This is
2231 dnl because we must put this information in glibconfig.h so we know if
2232 dnl it is safe or not to inline using compiler intrinsics directly from
2233 dnl the header.
2234 dnl
2235 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2236 dnl user is interested in knowing if they can use the atomic ops across
2237 dnl processes.
2238 dnl
2239 dnl We can currently support the atomic ops natively when building GLib
2240 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2241 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2242 dnl we are using GCC (and not mingw*).
2243 dnl
2244 dnl Note that the atomic ops are only available with GCC on x86 when
2245 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2246 dnl not available but would be available given the right flags, we want
2247 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2248 dnl that then to silently fall back on emulated atomic ops just because
2249 dnl the user had the wrong build environment.
2250
2251 dnl We may add other compilers here in the future...
2252
2253 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2254   case $host in
2255     *-*-mingw*)
2256       glib_cv_g_atomic_lock_free=yes
2257       ;;
2258     *)
2259       AC_TRY_LINK([],
2260                      [volatile int atomic = 2;\
2261                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2262                      [glib_cv_g_atomic_lock_free=yes],
2263                      [glib_cv_g_atomic_lock_free=no])
2264       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2265         SAVE_CFLAGS="${CFLAGS}"
2266         CFLAGS="-march=i486"
2267         AC_TRY_LINK([],
2268                        [volatile int atomic = 2;\
2269                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2270                        [AC_MSG_ERROR([GLib must be built with -march=i486 or later.])],
2271                        [])
2272         CFLAGS="${SAVE_CFLAGS}"
2273       fi
2274       ;;
2275   esac])
2276
2277
2278 case $host in
2279   *-*-mingw*)
2280     ;;
2281   *)
2282     # Some compilers support atomic operations but do not define
2283     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2284     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2285       AC_TRY_LINK([],
2286                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2287                      [],
2288                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2289     fi
2290     ;;
2291  esac
2292
2293 dnl We need a more robust approach here...
2294 case $host_cpu in
2295   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2296     glib_memory_barrier_needed=no
2297     ;;
2298   sparc*|alpha*|powerpc*|ia64)
2299     glib_memory_barrier_needed=yes
2300     ;;
2301   *)
2302     glib_memory_barrier_needed=yes
2303     ;;
2304 esac
2305
2306 dnl ************************
2307 dnl ** Check for futex(2) **
2308 dnl ************************
2309 AC_CACHE_CHECK(for futex(2) system call,
2310     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2311 #include <linux/futex.h>
2312 #include <sys/syscall.h>
2313 #include <unistd.h>
2314 ],[
2315   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2316 ])],glib_cv_futex=yes,glib_cv_futex=no))
2317 if test x"$glib_cv_futex" = xyes; then
2318   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2319 fi
2320
2321 AC_CACHE_CHECK(for eventfd(2) system call,
2322     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2323 #include <sys/eventfd.h>
2324 #include <unistd.h>
2325 ],[
2326   eventfd (0, EFD_CLOEXEC);
2327 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2328 if test x"$glib_cv_eventfd" = x"yes"; then
2329   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2330 fi
2331 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2332
2333 dnl ****************************************
2334 dnl *** GLib POLL* compatibility defines ***
2335 dnl ****************************************
2336
2337 glib_poll_includes=["
2338 #include <sys/types.h>
2339 #include <poll.h>
2340 "]
2341
2342 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2343    test $ac_cv_func_poll = yes ], [
2344   glib_failed=false
2345   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2346   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2347   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2348   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2349   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2350   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2351   if $glib_failed ; then
2352     AC_MSG_ERROR([Could not determine values for POLL* constants])
2353   fi
2354 ], [
2355   glib_cv_value_POLLIN=1
2356   glib_cv_value_POLLOUT=4
2357   glib_cv_value_POLLPRI=2
2358   glib_cv_value_POLLERR=8
2359   glib_cv_value_POLLHUP=16
2360   glib_cv_value_POLLNVAL=32
2361 ])
2362
2363 AC_MSG_CHECKING([for broken poll])
2364 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2365         #include <stdlib.h>
2366         #include <fcntl.h>
2367         #include <poll.h>
2368         int main(void) {
2369           struct pollfd fds[1];
2370           int fd;
2371           fd = open("/dev/null", 1);
2372           fds[0].fd = fd;
2373           fds[0].events = POLLIN;
2374           fds[0].revents = 0;
2375           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2376                 exit(1);  /* Does not work for devices -- fail */
2377           }
2378           exit(0);
2379         }]])],
2380   [broken_poll=no],
2381   [broken_poll=yes
2382    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2383   [broken_poll="no (cross compiling)"])
2384 AC_MSG_RESULT($broken_poll)
2385
2386 dnl *********************
2387 dnl *** GRegex checks ***
2388 dnl *********************
2389
2390 PCRE_REQUIRED_VERSION=8.31
2391
2392 # Check if we should use the internal or the system-supplied pcre
2393 AC_ARG_WITH(pcre,
2394             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2395                             [whether to use system PCRE [default=system]])],
2396             [],
2397             [with_pcre=system])
2398
2399 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2400
2401 AS_IF([ test "x$with_pcre" = xsystem], [
2402   PKG_CHECK_MODULES(PCRE,
2403                     libpcre >= $PCRE_REQUIRED_VERSION)
2404   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2405                   glib_save_CFLAGS="$CFLAGS"
2406                   glib_save_LIBS="$LIBS"
2407                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2408                   AC_TRY_RUN([#include <pcre.h>
2409                               int main () {
2410                                 int support;
2411                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2412                                 if (!support)
2413                                   return 1;
2414                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2415                                 if (!support)
2416                                   return 1;
2417                                 return 0;
2418                               }],
2419                   glib_cv_pcre_has_unicode=yes,
2420                   glib_cv_pcre_has_unicode=no,
2421                   glib_cv_pcre_has_unicode=yes)
2422                   CFLAGS="$glib_save_CFLAGS"
2423                   LIBS="$glib_save_LIBS"
2424       ])
2425   if test "$glib_cv_pcre_has_unicode" = "no"; then
2426     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2427   fi
2428   AC_SUBST(PCRE_CFLAGS)
2429   AC_SUBST(PCRE_LIBS)
2430   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2431   PCRE_REQUIRES=libpcre
2432   AC_SUBST(PCRE_REQUIRES)
2433 ], [
2434   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2435   AS_IF([ test x"$GCC" = xyes], [
2436     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2437     save_CFLAGS="$CFLAGS"
2438     CFLAGS="$CFLAGS -Wno-pointer-sign"
2439     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2440                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2441     CFLAGS="$save_CFLAGS"
2442   ])
2443 ])
2444 AC_SUBST(PCRE_WARN_CFLAGS)
2445
2446 dnl **********************
2447 dnl *** Win32 API libs ***
2448 dnl **********************
2449
2450 case $host in
2451   *-*-cygwin*)
2452         G_LIBS_EXTRA="-luser32 -lkernel32"
2453     ;;
2454   *-*-mingw*)
2455         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2456     ;;
2457   *)
2458         G_LIBS_EXTRA=""
2459     ;;
2460 esac
2461 AC_SUBST(G_LIBS_EXTRA)
2462
2463 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2464 dnl since we need it for g_iconv()
2465
2466 AC_MSG_CHECKING([for EILSEQ])
2467 AC_TRY_COMPILE([
2468 #include <errno.h>
2469 ],
2470 [
2471 int error = EILSEQ;
2472 ], have_eilseq=yes, have_eilseq=no);
2473 AC_MSG_RESULT($have_eilseq)
2474
2475 dnl Add a conditional we can use when cross-compiling, so we avoid running
2476 dnl binaries
2477 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2478
2479 dnl **************************
2480 dnl *** Checks for gtk-doc ***
2481 dnl **************************
2482 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2483 # it on it's own line.
2484 m4_ifdef([GTK_DOC_CHECK], [
2485 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2486 ],[
2487 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2488 ])
2489
2490 AC_ARG_ENABLE(man,
2491               [AS_HELP_STRING([--enable-man],
2492                               [generate man pages [default=auto]])],,
2493               enable_man=maybe)
2494
2495 AS_IF([test "$enable_man" != no], [
2496   AC_PATH_PROG([XSLTPROC], [xsltproc])
2497   AS_IF([test -z "$XSLTPROC"], [
2498     AS_IF([test "$enable_man" = yes], [
2499       AC_MSG_ERROR([xsltproc is required for --enable-man])
2500     ])
2501     enable_man=no
2502   ])
2503 ])
2504
2505 AS_IF([ test "$enable_man" != no ], [
2506   dnl check for DocBook DTD in the local catalog
2507   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2508      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2509   AS_IF([test "$have_docbook_dtd" != yes], [
2510     AS_IF([test "$enable_man" = yes ], [
2511       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2512     ])
2513     enable_man=no
2514   ])
2515 ])
2516
2517 AS_IF([test "$enable_man" != no], [
2518   dnl check for DocBook XSL stylesheets in the local catalog
2519   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2520      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2521   AS_IF([ test "$have_docbook_style" != yes ], [
2522     AS_IF([ test "$enable_man" = yes ], [
2523       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2524     ])
2525     enable_man=no
2526   ])
2527 ])
2528
2529 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2530
2531 AC_MSG_CHECKING([whether to generate man pages])
2532 AS_IF([ test "$enable_man" != no ], [
2533   AC_MSG_RESULT([yes])
2534 ], [
2535   AC_MSG_RESULT([no])
2536 ])
2537
2538 dnl
2539 dnl Tracing
2540 dnl
2541
2542 AC_ARG_ENABLE([dtrace],
2543              [AS_HELP_STRING([--enable-dtrace],
2544                               [include tracing support for dtrace])])
2545 have_dtrace=no
2546 AC_MSG_CHECKING([whether to include dtrace tracing support])
2547 AS_IF([ test "x$enable_dtrace" != xno], [
2548   if test x$glib_have_carbon = xyes; then
2549     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2550   else
2551     AC_MSG_RESULT([yes])
2552     AC_CHECK_PROGS(DTRACE, dtrace)
2553     if test -z "$DTRACE"; then
2554       if test "x$enable_dtrace" = xyes; then
2555         AC_MSG_ERROR([dtrace not found])
2556       fi
2557     else
2558       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2559                       [if test "x$enable_dtrace" = xyes; then
2560                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2561                        fi])
2562     fi
2563   fi
2564 ], [
2565   AC_MSG_RESULT([no])
2566 ])
2567 if test "x$have_dtrace" = xyes; then
2568   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2569 fi
2570 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2571
2572 AC_MSG_CHECKING([whether to include systemtap tracing support])
2573 AC_ARG_ENABLE([systemtap],
2574              [AS_HELP_STRING([--enable-systemtap],
2575                               [include tracing support for systemtap])])
2576 have_systemtap=no
2577 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2578   have_systemtap=yes
2579 fi
2580 AC_MSG_RESULT(${have_systemtap})
2581
2582 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2583
2584 AC_ARG_WITH([tapset-install-dir],
2585             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2586                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset/HOST_CPU]]),
2587             [if test "x${withval}" = x; then
2588                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"
2589              else
2590                ABS_TAPSET_DIR="${withval}"
2591               fi],
2592             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset/${host_cpu}"])
2593 AC_SUBST(ABS_TAPSET_DIR)
2594
2595 dnl ************************************
2596 dnl *** Enable lcov coverage reports ***
2597 dnl ************************************
2598
2599 AC_ARG_ENABLE(coverage,
2600   AS_HELP_STRING([--enable-coverage],
2601                  [enable coverage testing with gcov]),
2602   [use_gcov=$enableval], [use_gcov=no])
2603
2604 AS_IF([ test "x$use_gcov" = "xyes"], [
2605   dnl we need gcc:
2606   if test "$GCC" != "yes"; then
2607     AC_MSG_ERROR([GCC is required for --enable-coverage])
2608   fi
2609
2610   dnl Check if ccache is being used
2611   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2612   case `$SHTOOL path $CC` in
2613     *ccache*[)] gcc_ccache=yes;;
2614     *[)] gcc_ccache=no;;
2615   esac
2616
2617   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2618     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2619   fi
2620
2621   ltp_version_list="1.6 1.7 1.8 1.9 1.10 1.12"
2622   AC_CHECK_PROG(LTP, lcov, lcov)
2623   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2624
2625   AS_IF([ test "$LTP" ], [
2626     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2627       glib_cv_ltp_version=invalid
2628       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2629       for ltp_check_version in $ltp_version_list; do
2630         if test "$ltp_version" = "$ltp_check_version"; then
2631           glib_cv_ltp_version="$ltp_check_version (ok)"
2632         fi
2633       done
2634     ])
2635   ], [
2636     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2637     AC_MSG_ERROR([$ltp_msg])
2638   ])
2639
2640   case $glib_cv_ltp_version in
2641     ""|invalid[)]
2642       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2643       AC_MSG_ERROR([$ltp_msg])
2644       LTP="exit 0;"
2645       ;;
2646   esac
2647
2648   if test -z "$LTP_GENHTML"; then
2649     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2650   fi
2651
2652   dnl Remove all optimization flags from CFLAGS
2653   changequote({,})
2654   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2655   changequote([,])
2656
2657   dnl Add the special gcc flags
2658   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2659   LDFLAGS="$LDFLAGS -lgcov"
2660 ])
2661
2662 dnl *******************************
2663 dnl *** Disable strict aliasing ***
2664 dnl *******************************
2665 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=791622
2666 AS_IF([test "${GCC}" = "yes"],[
2667   CFLAGS="$CFLAGS -fno-strict-aliasing"
2668 ])
2669
2670 dnl ******************************
2671 dnl *** output the whole stuff ***
2672 dnl ******************************
2673
2674 dnl this section will only be run if config.status is invoked with no
2675 dnl arguments, or with "glib/glibconfig.h" as an argument.
2676 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2677 [
2678         outfile=glib/glibconfig.h-tmp
2679         cat > $outfile <<\_______EOF
2680 /* glibconfig.h
2681  *
2682  * This is a generated file.  Please modify 'configure.ac'
2683  */
2684
2685 #ifndef __GLIBCONFIG_H__
2686 #define __GLIBCONFIG_H__
2687
2688 #include <glib/gmacros.h>
2689
2690 _______EOF
2691
2692         echo '#include <limits.h>' >> $outfile
2693         echo '#include <float.h>' >> $outfile
2694         if test x$glib_values_h = xyes; then
2695           echo '#include <values.h>' >> $outfile
2696         fi
2697         if test "$glib_header_alloca_h" = "yes"; then
2698           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2699         fi
2700         if test x$glib_included_printf != xyes; then
2701           echo "
2702 /* Specifies that GLib's g_print*() functions wrap the
2703  * system printf functions.  This is useful to know, for example,
2704  * when using glibc's register_printf_function().
2705  */" >> $outfile
2706           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2707         fi
2708
2709         cat >> $outfile <<_______EOF
2710
2711 G_BEGIN_DECLS
2712
2713 #define G_MINFLOAT      FLT_MIN
2714 #define G_MAXFLOAT      FLT_MAX
2715 #define G_MINDOUBLE     DBL_MIN
2716 #define G_MAXDOUBLE     DBL_MAX
2717 #define G_MINSHORT      SHRT_MIN
2718 #define G_MAXSHORT      SHRT_MAX
2719 #define G_MAXUSHORT     USHRT_MAX
2720 #define G_MININT        INT_MIN
2721 #define G_MAXINT        INT_MAX
2722 #define G_MAXUINT       UINT_MAX
2723 #define G_MINLONG       LONG_MIN
2724 #define G_MAXLONG       LONG_MAX
2725 #define G_MAXULONG      ULONG_MAX
2726
2727 _______EOF
2728
2729
2730         ### this should always be true in a modern C/C++ compiler
2731         ### and is statically asserted by glib-init.c
2732         cat >>$outfile <<_______EOF
2733 typedef signed char gint8;
2734 typedef unsigned char guint8;
2735 _______EOF
2736
2737
2738         if test -n "$gint16"; then
2739           cat >>$outfile <<_______EOF
2740 typedef signed $gint16 gint16;
2741 typedef unsigned $gint16 guint16;
2742 #define G_GINT16_MODIFIER $gint16_modifier
2743 #define G_GINT16_FORMAT $gint16_format
2744 #define G_GUINT16_FORMAT $guint16_format
2745 _______EOF
2746         fi
2747
2748
2749         if test -n "$gint32"; then
2750           cat >>$outfile <<_______EOF
2751 typedef signed $gint32 gint32;
2752 typedef unsigned $gint32 guint32;
2753 #define G_GINT32_MODIFIER $gint32_modifier
2754 #define G_GINT32_FORMAT $gint32_format
2755 #define G_GUINT32_FORMAT $guint32_format
2756 _______EOF
2757         fi
2758
2759         cat >>$outfile <<_______EOF
2760 #define G_HAVE_GINT64 1          /* deprecated, always true */
2761
2762 ${glib_extension}typedef signed $gint64 gint64;
2763 ${glib_extension}typedef unsigned $gint64 guint64;
2764
2765 #define G_GINT64_CONSTANT(val)  $gint64_constant
2766 #define G_GUINT64_CONSTANT(val) $guint64_constant
2767 _______EOF
2768
2769         if test x$gint64_format != x ; then
2770           cat >>$outfile <<_______EOF
2771 #define G_GINT64_MODIFIER $gint64_modifier
2772 #define G_GINT64_FORMAT $gint64_format
2773 #define G_GUINT64_FORMAT $guint64_format
2774 _______EOF
2775         else
2776           cat >>$outfile <<_______EOF
2777 #undef G_GINT64_MODIFIER
2778 #undef G_GINT64_FORMAT
2779 #undef G_GUINT64_FORMAT
2780 _______EOF
2781         fi
2782
2783         cat >>$outfile <<_______EOF
2784
2785 #define GLIB_SIZEOF_VOID_P $glib_void_p
2786 #define GLIB_SIZEOF_LONG   $glib_long
2787 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2788 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2789
2790 _______EOF
2791
2792         cat >>$outfile <<_______EOF
2793 typedef signed $glib_ssize_type_define gssize;
2794 typedef unsigned $glib_size_type_define gsize;
2795 #define G_GSIZE_MODIFIER $gsize_modifier
2796 #define G_GSSIZE_MODIFIER $gssize_modifier
2797 #define G_GSIZE_FORMAT $gsize_format
2798 #define G_GSSIZE_FORMAT $gssize_format
2799
2800 #define G_MAXSIZE       G_MAXU$glib_msize_type
2801 #define G_MINSSIZE      G_MIN$glib_mssize_type
2802 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2803
2804 typedef gint64 goffset;
2805 #define G_MINOFFSET     G_MININT64
2806 #define G_MAXOFFSET     G_MAXINT64
2807
2808 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2809 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2810 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2811
2812 #define G_POLLFD_FORMAT $g_pollfd_format
2813
2814 _______EOF
2815
2816         if test -z "$glib_unknown_void_p"; then
2817           cat >>$outfile <<_______EOF
2818
2819 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2820 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2821
2822 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2823 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2824
2825 typedef signed $glib_intptr_type_define gintptr;
2826 typedef unsigned $glib_intptr_type_define guintptr;
2827
2828 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2829 #define G_GINTPTR_FORMAT        $gintptr_format
2830 #define G_GUINTPTR_FORMAT       $guintptr_format
2831 _______EOF
2832         else
2833           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2834         fi
2835
2836
2837
2838         cat >>$outfile <<_______EOF
2839 #ifndef G_DISABLE_DEPRECATED
2840 #define g_ATEXIT(proc)  (atexit (proc))
2841 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2842 #endif
2843 $glib_defines
2844 $glib_os
2845 $glib_static_compilation
2846
2847 $glib_vacopy
2848
2849 _______EOF
2850
2851         if test x$g_have_iso_c_varargs = xyes ; then
2852                 cat >>$outfile <<_______EOF
2853 #ifndef __cplusplus
2854 # define G_HAVE_ISO_VARARGS 1
2855 #endif
2856 _______EOF
2857         fi
2858         if test x$g_have_iso_cxx_varargs = xyes ; then
2859                 cat >>$outfile <<_______EOF
2860 #ifdef __cplusplus
2861 # define G_HAVE_ISO_VARARGS 1
2862 #endif
2863 _______EOF
2864         fi
2865         if test x$g_have_gnuc_varargs = xyes ; then
2866                 cat >>$outfile <<_______EOF
2867
2868 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2869  * is passed ISO vararg support is turned off, and there is no work
2870  * around to turn it on, so we unconditionally turn it off.
2871  */
2872 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2873 #  undef G_HAVE_ISO_VARARGS
2874 #endif
2875
2876 #define G_HAVE_GNUC_VARARGS 1
2877 _______EOF
2878         fi
2879
2880         case x$g_stack_grows in
2881         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2882         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2883         esac
2884
2885
2886         echo >>$outfile
2887         if test x$g_have_eilseq = xno; then
2888                 cat >>$outfile <<_______EOF
2889 #ifndef EILSEQ
2890 /* On some pre-C99 systems, EILSEQ is not defined.
2891  * The correspondence between this and the corresponding definition
2892  * in libiconv is essential.
2893  */
2894 #  define EILSEQ ENOENT
2895 #endif
2896 _______EOF
2897
2898         fi
2899
2900         if test x$g_have_gnuc_visibility = xyes; then
2901                 cat >>$outfile <<_______EOF
2902 #define G_HAVE_GNUC_VISIBILITY 1
2903 _______EOF
2904         fi
2905                 cat >>$outfile <<_______EOF
2906 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2907 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2908 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2909 #define G_GNUC_INTERNAL __hidden
2910 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2911 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2912 #else
2913 #define G_GNUC_INTERNAL
2914 #endif
2915 _______EOF
2916
2917         echo >>$outfile
2918         cat >>$outfile <<_______EOF
2919 #define G_THREADS_ENABLED
2920 #define G_THREADS_IMPL_$g_threads_impl_def
2921 _______EOF
2922
2923         if test x"$g_memory_barrier_needed" != xno; then
2924           echo >>$outfile
2925           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2926         fi
2927         if test x"$g_atomic_lock_free" = xyes; then
2928           echo >>$outfile
2929           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2930         fi
2931         echo >>$outfile
2932         g_bit_sizes="16 32 64"
2933         for bits in $g_bit_sizes; do
2934           cat >>$outfile <<_______EOF
2935 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2936 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2937 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2938 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2939 _______EOF
2940         done
2941
2942         cat >>$outfile <<_______EOF
2943 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2944 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2945 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2946 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2947 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2948 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2949 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2950 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2951 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
2952 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
2953 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
2954 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
2955 #define G_BYTE_ORDER $g_byte_order
2956
2957 #define GLIB_SYSDEF_POLLIN =$g_pollin
2958 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2959 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2960 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2961 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2962 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2963
2964 #define G_MODULE_SUFFIX "$g_module_suffix"
2965
2966 typedef $g_pid_type GPid;
2967 #define G_PID_FORMAT $g_pid_format
2968
2969 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
2970 #define GLIB_SYSDEF_AF_INET $g_af_inet
2971 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
2972
2973 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
2974 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
2975 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
2976
2977 #define G_DIR_SEPARATOR '$g_dir_separator'
2978 #define G_DIR_SEPARATOR_S "$g_dir_separator"
2979 #define G_SEARCHPATH_SEPARATOR '$g_searchpath_separator'
2980 #define G_SEARCHPATH_SEPARATOR_S "$g_searchpath_separator"
2981
2982 G_END_DECLS
2983
2984 #endif /* __GLIBCONFIG_H__ */
2985 _______EOF
2986
2987
2988         if cmp -s $outfile glib/glibconfig.h; then
2989           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
2990           rm -f $outfile
2991         else
2992           mv $outfile glib/glibconfig.h
2993         fi
2994 ],[
2995
2996 # Note that if two cases are the same, case goes with the first one.
2997 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2998 # on variable expansion in case labels.  Look at the generated config.status
2999 # for a hint.
3000
3001 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3002   glib_header_alloca_h="$ac_cv_working_alloca_h"
3003 else
3004   glib_header_alloca_h="$ac_cv_header_alloca_h"
3005 fi
3006
3007 if test x$enable_included_printf = xyes ; then
3008   glib_included_printf=yes
3009 fi
3010
3011 case 2 in
3012 $ac_cv_sizeof_short)
3013   gint16=short
3014   gint16_modifier='"h"'
3015   gint16_format='"hi"'
3016   guint16_format='"hu"'
3017   ;;
3018 $ac_cv_sizeof_int)
3019   gint16=int
3020   gint16_modifier='""'
3021   gint16_format='"i"'
3022   guint16_format='"u"'
3023   ;;
3024 esac
3025 case 4 in
3026 $ac_cv_sizeof_short)
3027   gint32=short
3028   gint32_modifier='"h"'
3029   gint32_format='"hi"'
3030   guint32_format='"hu"'
3031   ;;
3032 $ac_cv_sizeof_int)
3033   gint32=int
3034   gint32_modifier='""'
3035   gint32_format='"i"'
3036   guint32_format='"u"'
3037   ;;
3038 $ac_cv_sizeof_long)
3039   gint32=long
3040   gint32_modifier='"l"'
3041   gint32_format='"li"'
3042   guint32_format='"lu"'
3043   ;;
3044 esac
3045 case 8 in
3046 $ac_cv_sizeof_int)
3047   gint64=int
3048   gint64_modifier='""'
3049   gint64_format='"i"'
3050   guint64_format='"u"'
3051   glib_extension=
3052   gint64_constant='(val)'
3053   guint64_constant='(val)'
3054   ;;
3055 $ac_cv_sizeof_long)
3056   if test "x$glib_cv_int64_t" = "xlong_long"; then
3057     gint64='long long'
3058     if test -n "$glib_cv_long_long_format"; then
3059       gint64_modifier='"'$glib_cv_long_long_format'"'
3060       gint64_format='"'$glib_cv_long_long_format'i"'
3061       guint64_format='"'$glib_cv_long_long_format'u"'
3062     fi
3063     glib_extension='G_GNUC_EXTENSION '
3064     gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3065     guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3066   else
3067     gint64=long
3068     gint64_modifier='"l"'
3069     gint64_format='"li"'
3070     guint64_format='"lu"'
3071     glib_extension=
3072     gint64_constant='(val##L)'
3073     guint64_constant='(val##UL)'
3074   fi
3075   ;;
3076 $ac_cv_sizeof_long_long)
3077   gint64='long long'
3078   if test -n "$glib_cv_long_long_format"; then
3079     gint64_modifier='"'$glib_cv_long_long_format'"'
3080     gint64_format='"'$glib_cv_long_long_format'i"'
3081     guint64_format='"'$glib_cv_long_long_format'u"'
3082   fi
3083   glib_extension='G_GNUC_EXTENSION '
3084   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3085   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3086   ;;
3087 $ac_cv_sizeof___int64)
3088   gint64='__int64'
3089   if test -n "$glib_cv_long_long_format"; then
3090     gint64_modifier='"'$glib_cv_long_long_format'"'
3091     gint64_format='"'$glib_cv_long_long_format'i"'
3092     guint64_format='"'$glib_cv_long_long_format'u"'
3093   fi
3094   glib_extension=
3095   gint64_constant='(val##i64)'
3096   guint64_constant='(val##ui64)'
3097   ;;
3098 esac
3099 glib_size_t=$ac_cv_sizeof_size_t
3100 glib_ssize_t=$ac_cv_sizeof_ssize_t
3101 glib_size_type_define="$glib_size_type"
3102 glib_ssize_type_define="$glib_ssize_type"
3103 glib_void_p=$ac_cv_sizeof_void_p
3104 glib_long=$ac_cv_sizeof_long
3105
3106 case "$glib_size_type" in
3107 short)
3108   gsize_modifier='"h"'
3109   gsize_format='"hu"'
3110   glib_msize_type='SHRT'
3111   ;;
3112 int)
3113   gsize_modifier='""'
3114   gsize_format='"u"'
3115   glib_msize_type='INT'
3116   ;;
3117 long)
3118   gsize_modifier='"l"'
3119   gsize_format='"lu"'
3120   glib_msize_type='LONG'
3121   ;;
3122 "long long"|__int64)
3123   gsize_modifier='"I64"'
3124   gsize_format='"I64u"'
3125   glib_msize_type='INT64'
3126   ;;
3127 esac
3128
3129 case "$glib_ssize_type" in
3130 short)
3131   gssize_modifier='"h"'
3132   gssize_format='"hi"'
3133   glib_mssize_type='SHRT'
3134   ;;
3135 int)
3136   gssize_modifier='""'
3137   gssize_format='"i"'
3138   glib_mssize_type='INT'
3139   ;;
3140 long)
3141   gssize_modifier='"l"'
3142   gssize_format='"li"'
3143   glib_mssize_type='LONG'
3144   ;;
3145 "long long"|__int64)
3146   gssize_modifier='"I64"'
3147   gssize_format='"I64i"'
3148   glib_mssize_type='INT64'
3149   ;;
3150 esac
3151
3152 gintbits=`expr $ac_cv_sizeof_int \* 8`
3153 glongbits=`expr $ac_cv_sizeof_long \* 8`
3154 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3155 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3156
3157 case $ac_cv_sizeof_void_p in
3158 $ac_cv_sizeof_int)
3159   glib_intptr_type_define=int
3160   gintptr_modifier='""'
3161   gintptr_format='"i"'
3162   guintptr_format='"u"'
3163   glib_gpi_cast='(gint)'
3164   glib_gpui_cast='(guint)'
3165   ;;
3166 $ac_cv_sizeof_long)
3167   glib_intptr_type_define=long
3168   gintptr_modifier='"l"'
3169   gintptr_format='"li"'
3170   guintptr_format='"lu"'
3171   glib_gpi_cast='(glong)'
3172   glib_gpui_cast='(gulong)'
3173   ;;
3174 $ac_cv_sizeof_long_long)
3175   glib_intptr_type_define='long long'
3176   gintptr_modifier='"I64"'
3177   gintptr_format='"I64i"'
3178   guintptr_format='"I64u"'
3179   glib_gpi_cast='(gint64)'
3180   glib_gpui_cast='(guint64)'
3181   ;;
3182 $ac_cv_sizeof___int64)
3183   glib_intptr_type_define=__int64
3184   gintptr_modifier='"I64"'
3185   gintptr_format='"I64i"'
3186   guintptr_format='"I64u"'
3187   glib_gpi_cast='(gint64)'
3188   glib_gpui_cast='(guint64)'
3189   ;;
3190 *)
3191   glib_unknown_void_p=yes
3192   ;;
3193 esac
3194
3195
3196 glib_defines="
3197 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3198 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3199 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3200 "
3201
3202 case xyes in
3203 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3204 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3205 *)                      glib_vacopy=''
3206 esac
3207
3208 if test x$glib_cv_va_val_copy = xno; then
3209   glib_vacopy="\$glib_vacopy
3210 #define G_VA_COPY_AS_ARRAY 1"
3211 fi
3212
3213 g_have_gnuc_varargs=$g_have_gnuc_varargs
3214 g_have_iso_c_varargs=$g_have_iso_c_varargs
3215 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3216
3217 g_have_gnuc_visibility=$g_have_gnuc_visibility
3218 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3219
3220 if test x$ac_cv_c_bigendian = xyes; then
3221   g_byte_order=G_BIG_ENDIAN
3222   g_bs_native=BE
3223   g_bs_alien=LE
3224 else
3225   g_byte_order=G_LITTLE_ENDIAN
3226   g_bs_native=LE
3227   g_bs_alien=BE
3228 fi
3229
3230 g_pollin=$glib_cv_value_POLLIN
3231 g_pollout=$glib_cv_value_POLLOUT
3232 g_pollpri=$glib_cv_value_POLLPRI
3233 g_pollhup=$glib_cv_value_POLLHUP
3234 g_pollerr=$glib_cv_value_POLLERR
3235 g_pollnval=$glib_cv_value_POLLNVAL
3236
3237 # If a family is not found on the system, define that family to
3238 # a negative value, picking a different one for each undefined
3239 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3240 # This is needed because glib-mkenums doesn't handle optional
3241 # values in enums, and thus we have to have all existing values
3242 # defined in the enum.
3243 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3244   g_af_unix=$glib_cv_value_AF_UNIX
3245 else
3246   g_af_unix=-1
3247 fi
3248 g_af_inet=$glib_cv_value_AF_INET
3249 g_af_inet6=$glib_cv_value_AF_INET6
3250
3251 g_msg_peek=$glib_cv_value_MSG_PEEK
3252 g_msg_oob=$glib_cv_value_MSG_OOB
3253 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3254
3255 g_stack_grows=$glib_cv_stack_grows
3256
3257 g_have_eilseq=$have_eilseq
3258
3259 g_threads_impl_def=$g_threads_impl
3260
3261 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3262 g_memory_barrier_needed="$glib_memory_barrier_needed"
3263 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3264
3265 g_module_suffix="$glib_gmodule_suffix"
3266 g_dir_separator="$glib_dir_separator"
3267 g_searchpath_separator="$glib_searchpath_separator"
3268
3269 g_pid_type="$glib_pid_type"
3270 g_pid_format="\"$glib_pid_format\""
3271 g_pollfd_format="\"$glib_pollfd_format\""
3272
3273 case $host in
3274   *-*-cygwin*)
3275     glib_os="#define G_OS_UNIX
3276 #define G_PLATFORM_WIN32
3277 #define G_WITH_CYGWIN"
3278     ;;
3279   *-*-mingw*)
3280     glib_os="#define G_OS_WIN32
3281 #define G_PLATFORM_WIN32"
3282     ;;
3283   *)
3284     glib_os="#define G_OS_UNIX"
3285     ;;
3286 esac
3287 glib_static_compilation=""
3288 if test x$glib_win32_static_compilation = xyes; then
3289   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3290 #define GOBJECT_STATIC_COMPILATION 1"
3291 fi
3292 ])
3293
3294 # Redo enough to get guint32 and guint64 for the alignment checks below
3295 case 4 in
3296 $ac_cv_sizeof_short)
3297   gint32=short
3298   ;;
3299 $ac_cv_sizeof_int)
3300   gint32=int
3301   ;;
3302 $ac_cv_sizeof_long)
3303   gint32=long
3304   ;;
3305 esac
3306 case 8 in
3307 $ac_cv_sizeof_int)
3308   gint64=int
3309   ;;
3310 $ac_cv_sizeof_long)
3311   gint64=long
3312   ;;
3313 $ac_cv_sizeof_long_long)
3314   gint64='long long'
3315   ;;
3316 $ac_cv_sizeof___int64)
3317   gint64='__int64'
3318   ;;
3319 esac
3320
3321 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3322 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3323 typedef unsigned $gint32 guint32;])
3324 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3325 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3326 typedef unsigned $gint64 guint64;])
3327 AC_CHECK_TYPE([unsigned long])
3328 AC_CHECK_ALIGNOF([unsigned long])
3329
3330 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3331 #
3332 # 1.2.14 required for dbus_message_set_serial
3333 PKG_CHECK_MODULES(DBUS1,
3334      dbus-1 >= 1.2.14,
3335      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3336      have_dbus1=no)
3337 AC_SUBST(DBUS1_CFLAGS)
3338 AC_SUBST(DBUS1_LIBS)
3339 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3340
3341 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3342 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3343
3344 # Check whether MSVC toolset is explicitly set
3345 AM_CONDITIONAL(MSVC_BASE_NO_TOOLSET_SET, [test x$MSVC_BASE_TOOLSET = x])
3346 AM_CONDITIONAL(MSVC_NO_TOOLSET_SET, [test x$MSVC_TOOLSET = x])
3347
3348 dnl
3349 dnl Check for -Bsymbolic-functions linker flag used to avoid
3350 dnl intra-library PLT jumps, if available.
3351 dnl
3352
3353 AC_ARG_ENABLE(Bsymbolic,
3354               [AS_HELP_STRING([--disable-Bsymbolic],
3355                               [avoid linking with -Bsymbolic])],,
3356               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3357                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3358                LDFLAGS=-Wl,-Bsymbolic-functions
3359                LIBS=
3360                AC_TRY_LINK([], [return 0],
3361                            AC_MSG_RESULT(yes)
3362                            enable_Bsymbolic=yes,
3363                            AC_MSG_RESULT(no)
3364                            enable_Bsymbolic=no)
3365                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3366
3367 if test "x${enable_Bsymbolic}" = "xyes"; then
3368   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3369 fi
3370
3371 dnl
3372 dnl Check for -z,nodelete linker flag: the type system assumes that
3373 dnl libgobject stays loaded for the lifetime of the process.
3374 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3375 dnl we also try to check for the --fatal-warnings linker flag if
3376 dnl auto-detecting.
3377 dnl
3378
3379 SAVED_CFLAGS="${CFLAGS}" SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3380 AC_MSG_CHECKING([for --fatal-warnings linker flag])
3381 CFLAGS="${SAVED_CFLAGS} ${shared_flag:- -shared}"
3382 LDFLAGS=-Wl,--fatal-warnings
3383 LIBS=
3384 AC_TRY_LINK([], [return 0],
3385             AC_MSG_RESULT(yes)
3386             [ldflags_fatal=-Wl,--fatal-warnings],
3387             AC_MSG_RESULT(no)
3388             ldflags_fatal=)
3389
3390 AC_MSG_CHECKING([for -z,nodelete linker flag])
3391 LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3392 AC_TRY_LINK([], [return 0],
3393             AC_MSG_RESULT(yes)
3394             enable_znodelete=yes,
3395             AC_MSG_RESULT(no)
3396             enable_znodelete=no)
3397 CFLAGS="${SAVED_CFLAGS}" LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"
3398
3399 if test "x${enable_znodelete}" = "xyes"; then
3400   GLIB_LINK_FLAGS="$GLIB_LINK_FLAGS -Wl,-z,nodelete"
3401 fi
3402
3403 AC_SUBST(GLIB_LINK_FLAGS)
3404
3405 dnl
3406 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3407 dnl visibility attributes for symbol export control
3408 dnl
3409 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3410 case "$host" in
3411   *-*-mingw*)
3412     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3413     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3414               [defines how to decorate public symbols while building])
3415     CFLAGS="${CFLAGS} -fvisibility=hidden"
3416     ;;
3417   *)
3418     dnl on other compilers, check if we can do -fvisibility=hidden
3419     SAVED_CFLAGS="${CFLAGS}"
3420     CFLAGS="-fvisibility=hidden"
3421     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3422     AC_TRY_COMPILE([], [return 0],
3423                    AC_MSG_RESULT(yes)
3424                    enable_fvisibility_hidden=yes,
3425                    AC_MSG_RESULT(no)
3426                    enable_fvisibility_hidden=no)
3427     CFLAGS="${SAVED_CFLAGS}"
3428
3429     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3430       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3431                 [defines how to decorate public symbols while building])
3432       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3433     ])
3434     ;;
3435 esac
3436 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3437
3438 dnl Compiler flags; macro originates from systemd
3439 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3440 AC_ARG_ENABLE(compile-warnings,
3441               [AS_HELP_STRING([--disable-compile-warnings],
3442                               [Don't use builtin compiler warnings])],,
3443                               enable_compile_warnings=yes)
3444 AS_IF([test "x$enable_compile_warnings" != xno], [
3445   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3446    -Wall -Wstrict-prototypes -Wduplicated-branches -Wmisleading-indentation \
3447    -Wno-bad-function-cast \
3448    -Werror=declaration-after-statement \
3449    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3450    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3451    -Werror=format=2 -Werror=missing-include-dirs])
3452 ])
3453 AC_SUBST(GLIB_WARN_CFLAGS)
3454
3455 #
3456 # Define variables corresponding to the correct include paths to use for
3457 # in-tree building.
3458 #
3459
3460 # for config.h:
3461 config_h_INCLUDES='-I$(top_builddir)'
3462 AC_SUBST(config_h_INCLUDES)
3463
3464 # glib:
3465 #   config.h
3466 #   $(top_builddir)/glib: for glibconfig.h
3467 #   $(top_srcdir)/glib:   for glib.h
3468 #   $(top_srcdir):        for everything
3469 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3470 AC_SUBST(glib_INCLUDES)
3471
3472 # gobject:
3473 #   same as glib
3474 gobject_INCLUDES='$(glib_INCLUDES)'
3475 AC_SUBST(gobject_INCLUDES)
3476
3477 # gmodule:
3478 #   glib includes
3479 #   $(top_srcdir)/gmodule: for gmodule.h
3480 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3481 AC_SUBST(gmodule_INCLUDES)
3482
3483 # gio:
3484 #   same as gmodule
3485 gio_INCLUDES='$(gmodule_INCLUDES)'
3486 AC_SUBST(gio_INCLUDES)
3487
3488
3489 AC_CONFIG_FILES([
3490 glib-2.0.pc
3491 gmodule-2.0.pc
3492 gmodule-export-2.0.pc
3493 gmodule-no-export-2.0.pc
3494 gthread-2.0.pc
3495 gobject-2.0.pc
3496 gio-2.0.pc
3497 gio-unix-2.0.pc
3498 gio-windows-2.0.pc
3499 glib-gettextize
3500 Makefile
3501 build/Makefile
3502 build/win32/Makefile
3503 build/win32/dirent/Makefile
3504 glib/Makefile
3505 glib/libcharset/Makefile
3506 glib/gnulib/Makefile
3507 glib/pcre/Makefile
3508 glib/update-pcre/Makefile
3509 glib/tests/Makefile
3510 gmodule/Makefile
3511 gmodule/gmoduleconf.h
3512 gobject/Makefile
3513 gobject/glib-genmarshal
3514 gobject/glib-mkenums
3515 gobject/tests/Makefile
3516 gthread/Makefile
3517 gio/Makefile
3518 gio/gdbus-2.0/codegen/Makefile
3519 gio/gdbus-2.0/codegen/config.py
3520 gio/gnetworking.h
3521 gio/xdgmime/Makefile
3522 gio/inotify/Makefile
3523 gio/kqueue/Makefile
3524 gio/fam/Makefile
3525 gio/win32/Makefile
3526 gio/tests/Makefile
3527 gio/tests/gdbus-object-manager-example/Makefile
3528 gio/tests/services/Makefile
3529 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3530 gio/tests/modules/Makefile
3531 po/Makefile.in
3532 docs/Makefile
3533 docs/reference/Makefile
3534 docs/reference/glib/Makefile
3535 docs/reference/glib/version.xml
3536 docs/reference/gobject/Makefile
3537 docs/reference/gobject/version.xml
3538 docs/reference/gio/Makefile
3539 docs/reference/gio/version.xml
3540 tests/Makefile
3541 tests/gobject/Makefile
3542 tests/refcount/Makefile
3543 m4macros/Makefile
3544 subprojects/Makefile
3545 ])
3546
3547 # We need this command because the configure script will not preserve
3548 # the same attributes of the template files
3549 AC_CONFIG_COMMANDS([chmod-scripts],
3550 [chmod 0755 glib-gettextize
3551 chmod 0755 gobject/glib-genmarshal
3552 chmod 0755 gobject/glib-mkenums])
3553
3554 # we want to invoke this macro solely so that the config.status script
3555 # and automake generated makefiles know about these generated files.
3556 # They are only needed to distcheck the package
3557 if false; then
3558   AC_CONFIG_FILES([
3559     INSTALL
3560     glib/glib.rc
3561     gmodule/gmodule.rc
3562     gobject/gobject.rc
3563     gthread/gthread.rc
3564     gio/gio.rc
3565   ])
3566 fi
3567
3568 AC_OUTPUT