configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24 AC_INIT([libxkbcommon], [0.1.0],
  25     [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg])
  26 AM_INIT_AUTOMAKE([dist-bzip2 foreign])
  27 AM_MAINTAINER_MODE
  28 AC_CONFIG_HEADERS([src/config.h])
  29
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32
  33 m4_ifndef([PKG_PROG_PKG_CONFIG],
  34     [m4_fatal([Could not locate the pkg-config autoconf macros.
  35     These are usually located in /usr/share/aclocal/pkg.m4. If your
  36     macros are in a different location, try setting the environment
  37     variable ACLOCAL="aclocal -I/other/macro/dir" before running
  38     autoreconf/autogen.sh.])])
  39 PKG_PROG_PKG_CONFIG
  40
  41 dnl Build native compiler needed for makekeys
  42 AC_ARG_VAR([CC_FOR_BUILD], [Build native C compiler program])
  43 if test "x$CC_FOR_BUILD" = x; then
  44     if test "$cross_compiling" != no; then
  45         AC_PATH_PROGS([CC_FOR_BUILD], [gcc cc], [cc])
  46     else
  47         CC_FOR_BUILD="$CC"
  48     fi
  49 fi
  50
  51 PKG_CHECK_MODULES([X11], [xproto kbproto >= 1.0.99.1])
  52
  53 dnl Ensure we have keysym headers
  54 AC_MSG_CHECKING([for X11 includedir])
  55 x11includedir="`$PKG_CONFIG --variable=includedir xproto`/X11"
  56 AC_MSG_RESULT([$x11includedir])
  57
  58 AC_MSG_CHECKING([for keysymdef.h])
  59 KEYSYMDEF_H="$x11includedir/keysymdef.h"
  60 test -f "$KEYSYMDEF_H" || AC_MSG_ERROR([can't locate keysymdef.h in $x11includedir])
  61 AC_MSG_RESULT([$KEYSYMDEF_H])
  62 AC_SUBST([KEYSYMDEF_H])
  63
  64 AC_MSG_CHECKING([for XF86keysym.h])
  65 XF86KEYSYM_H="$x11includedir/XF86keysym.h"
  66 test -f "$XF86KEYSYM_H" || AC_MSG_ERROR([can't locate XF86keysym.h in $x11includedir])
  67 AC_MSG_RESULT([$XF86KEYSYM_H])
  68 AC_SUBST([XF86KEYSYM_H])
  69
  70 # Require xorg-macros version 1.2.0 or newer for XORG_CHANGELOG macro
  71 m4_ifndef([XORG_MACROS_VERSION],
  72     [m4_fatal([must install xorg-macros before running autoconf/autogen.sh])])
  73 XORG_MACROS_VERSION([1.2.0])
  74 XORG_RELEASE_VERSION
  75 XORG_CHECK_MALLOC_ZERO
  76 XORG_CWARNFLAGS
  77 XORG_CHANGELOG
  78
  79 AC_OUTPUT([
  80 Makefile
  81 include/Makefile
  82 src/Makefile
  83 src/makekeys/Makefile
  84 test/Makefile
  85 ])