configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [4])
   4 m4_define([gst_vaapi_micro_version], [3])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # glib version number
  13 m4_define([glib_major_version], [2])
  14 m4_define([glib_minor_version], [28])
  15 m4_define([glib_micro_version], [0])
  16 m4_define([glib_major_minor_version],
  17           [glib_major_version.glib_minor_version])
  18 m4_define([glib_version],
  19           [glib_major_version.glib_minor_version.glib_micro_version])
  20
  21 # gst version number
  22 m4_define([gst_major_version], [0])
  23 m4_define([gst_minor_version], [10])
  24 m4_define([gst_micro_version], [36])
  25 m4_define([gst_major_minor_version],
  26           [gst_major_version.gst_minor_version])
  27 m4_define([gst_version],
  28           [gst_major_version.gst_minor_version.gst_micro_version])
  29
  30 # gst plugins-base version number
  31 m4_define([gst_plugins_base_major_version], [0])
  32 m4_define([gst_plugins_base_minor_version], [10])
  33 m4_define([gst_plugins_base_micro_version], [31])
  34 m4_define([gst_plugins_base_version],
  35           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  36
  37 # gst plugins-bad version number
  38 m4_define([gst_plugins_bad_major_version], [0])
  39 m4_define([gst_plugins_bad_minor_version], [10])
  40 m4_define([gst_plugins_bad_micro_version], [22])
  41 m4_define([gst_plugins_bad_version],
  42           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  43
  44 # Wayland minimum version number
  45 m4_define([wayland_api_version], [1.0.0])
  46
  47 # VA-API minimum version number
  48 m4_define([va_api_version],     [0.30.4])
  49 m4_define([va_api_drm_version], [0.33.0])
  50 m4_define([va_api_x11_version], [0.31.0])
  51 m4_define([va_api_glx_version], [0.32.0])
  52 m4_define([va_api_wld_version], [0.33.0])
  53
  54 # libva package version number
  55 m4_define([libva_drm_package_version], [1.1.0])
  56 m4_define([libva_x11_package_version], [1.0.3])
  57 m4_define([libva_glx_package_version], [1.0.9])
  58 m4_define([libva_wld_package_version], [1.1.0])
  59
  60 # gtk-doc version number
  61 # XXX: introspection annotations require gtk-doc >= 1.12
  62 m4_define([gtkdoc_major_version], [1])
  63 m4_define([gtkdoc_minor_version], [9])
  64 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  65
  66 AC_PREREQ([2.58])
  67 AC_INIT([gst_vaapi], [gst_vaapi_version],
  68     [gwenole.beauchesne@intel.com],
  69     [gstreamer-vaapi])
  70
  71 AC_CONFIG_HEADERS([config.h])
  72 AC_CONFIG_SRCDIR([Makefile.am])
  73 AC_CONFIG_MACRO_DIR([m4])
  74 AC_CONFIG_AUX_DIR([build-aux])
  75
  76 AC_CANONICAL_TARGET
  77
  78 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  79
  80 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  81 AC_SUBST(TODAY)
  82
  83 GST_VAAPI_MAJOR_VERSION=gst_vaapi_major_version
  84 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  85
  86 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  87 AC_SUBST(LIBVA_PACKAGE_VERSION)
  88
  89 WAYLAND_API_VERSION=wayland_api_version
  90 AC_SUBST(WAYLAND_API_VERSION)
  91
  92 dnl Versions for GStreamer and plugins-base
  93 GST_MAJORMINOR=gst_major_minor_version
  94 GST_VERSION_REQUIRED=gst_version
  95 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
  96 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
  97 AC_SUBST(GST_MAJORMINOR)
  98 AC_SUBST(GST_VERSION_REQUIRED)
  99 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 100 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 101
 102 dnl Use pretty build output with automake >= 1.11
 103 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 104   AM_DEFAULT_VERBOSITY=1
 105   AC_SUBST(AM_DEFAULT_VERBOSITY)
 106 ])
 107
 108 dnl Check for tools
 109 AC_PROG_CC
 110 AM_PROG_CC_C_O
 111
 112 dnl Initialize libtool
 113 LT_PREREQ([2.2])
 114 LT_INIT
 115
 116 AC_ARG_ENABLE(drm,
 117     AS_HELP_STRING([--enable-drm],
 118                    [enable DRM backend @<:@default=yes@:>@]),
 119     [], [enable_drm="yes"])
 120
 121 AC_ARG_ENABLE(x11,
 122     AS_HELP_STRING([--enable-x11],
 123                    [enable X11 output @<:@default=yes@:>@]),
 124     [], [enable_x11="yes"])
 125
 126 AC_ARG_ENABLE(glx,
 127     AS_HELP_STRING([--enable-glx],
 128                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 129     [], [enable_glx="yes"])
 130
 131 AC_ARG_ENABLE(wayland,
 132     AC_HELP_STRING([--enable-wayland],
 133                    [enable Wayland output @<:@default=yes@:>@]),
 134     [], [enable_wayland="yes"])
 135
 136 dnl Check for basic libraries
 137 AC_CHECK_LIB(m, tan)
 138
 139 dnl Check for Gtk doc
 140 GTKDOC_VERSION=gtkdoc_version
 141 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 142 m4_ifdef([GTK_DOC_CHECK], [
 143 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 144 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 145 AC_SUBST(GTKDOC_VERSION)
 146
 147 dnl Check for GLib
 148 GLIB_VERSION_REQUIRED=glib_version
 149 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 150 AC_SUBST(GLIB_VERSION_REQUIRED)
 151
 152 dnl ---------------------------------------------------------------------------
 153 dnl -- GStreamer                                                             --
 154 dnl ---------------------------------------------------------------------------
 155
 156 dnl GStreamer Core
 157 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 158 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 159
 160 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 161     saved_CFLAGS="$CFLAGS"
 162     CFLAGS="$CFLAGS $GST_BASE_CFLAGS"
 163     saved_LIBS="$LIBS"
 164     LIBS="$LIBS $GST_BASE_LIBS"
 165     AC_COMPILE_IFELSE(
 166         [AC_LANG_PROGRAM(
 167             [[#include <gst/base/gstbasesink.h>]],
 168             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 169         [ac_cv_have_gst_base_sink_query="yes"],
 170         [ac_cv_have_gst_base_sink_query="no"]
 171     )
 172     CFLAGS="$saved_CFLAGS"
 173     LIBS="$saved_LIBS"
 174 ])
 175 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 176     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 177 fi
 178
 179 dnl GStreamer -base plugins
 180 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 181     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 182 PKG_CHECK_MODULES([GST_INTERFACES],
 183     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 184
 185 dnl ... GstVideoOverlayComposition (gstreamer-video)
 186 PKG_CHECK_MODULES([GST_VIDEO],
 187     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 188
 189 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 190     ac_cv_have_gst_video_overlay_composition, [
 191     saved_CFLAGS="$CFLAGS"
 192     CFLAGS="$CFLAGS $GST_CFLAGS"
 193     saved_LIBS="$LIBS"
 194     LIBS="$LIBS $GST_LIBS"
 195     AC_COMPILE_IFELSE(
 196         [AC_LANG_PROGRAM(
 197             [[#include <gst/video/video-overlay-composition.h>]],
 198             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 199         [ac_cv_have_gst_video_overlay_composition="yes"],
 200         [ac_cv_have_gst_video_overlay_composition="no"]
 201     )
 202     CFLAGS="$saved_CFLAGS"
 203     LIBS="$saved_LIBS"
 204 ])
 205 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 206     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 207 fi
 208
 209 dnl GStreamer -bad plugins
 210 PKG_CHECK_MODULES([GST_BASEVIDEO],
 211     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 212
 213 dnl ... bitstream parsers
 214 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 215     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 216
 217 dnl ... MPEG-2 parser, with the required extensions
 218 AC_CACHE_CHECK([for MPEG-2 parser],
 219     ac_cv_have_gst_mpeg2_parser, [
 220     saved_CPPFLAGS="$CPPFLAGS"
 221     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 222     saved_LIBS="$LIBS"
 223     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 224     AC_COMPILE_IFELSE(
 225         [AC_LANG_PROGRAM(
 226             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 227             [[GstMpegVideoSequenceHdr seq_hdr;
 228               GstMpegVideoSequenceExt seq_ext;
 229               GstMpegVideoSequenceDisplayExt seq_dpy;
 230               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 231                   &seq_ext, &seq_dpy);]])],
 232         [ac_cv_have_gst_mpeg2_parser="yes"],
 233         [ac_cv_have_gst_mpeg2_parser="no"]
 234     )
 235     CPPFLAGS="$saved_CPPFLAGS"
 236     LIBS="$saved_LIBS"
 237 ])
 238 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 239     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 240
 241 dnl ... H.264 parser, with the required extensions
 242 AC_CACHE_CHECK([for H.264 parser],
 243     ac_cv_have_gst_h264_parser, [
 244     saved_CPPFLAGS="$CPPFLAGS"
 245     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 246     saved_LIBS="$LIBS"
 247     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 248     AC_COMPILE_IFELSE(
 249         [AC_LANG_PROGRAM(
 250             [[#include <gst/codecparsers/gsth264parser.h>]],
 251             [[GstH264SliceHdr slice_hdr;
 252               GstH264VUIParams vui_params;
 253               slice_hdr.n_emulation_prevention_bytes = 0;
 254               vui_params.par_n = 0;
 255               vui_params.par_d = 0;]])],
 256         [ac_cv_have_gst_h264_parser="yes"],
 257         [ac_cv_have_gst_h264_parser="no"]
 258     )
 259     CPPFLAGS="$saved_CPPFLAGS"
 260     LIBS="$saved_LIBS"
 261 ])
 262 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 263     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 264
 265 dnl ... JPEG parser, not upstream yet
 266 AC_CACHE_CHECK([for JPEG parser],
 267     ac_cv_have_gst_jpeg_parser, [
 268     saved_CPPFLAGS="$CPPFLAGS"
 269     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 270     saved_LIBS="$LIBS"
 271     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 272     AC_COMPILE_IFELSE(
 273         [AC_LANG_PROGRAM(
 274             [[#include <gst/codecparsers/gstjpegparser.h>]],
 275             [[GstJpegImage jpeg_image;]])],
 276         [ac_cv_have_gst_jpeg_parser="yes"],
 277         [ac_cv_have_gst_jpeg_parser="no"]
 278     )
 279     CPPFLAGS="$saved_CPPFLAGS"
 280     LIBS="$saved_LIBS"
 281 ])
 282 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 283     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 284
 285 dnl GST_ALL_LDFLAGS:
 286 dnl LDFLAGS really should only contain flags, not libs - they get added before
 287 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 288 GST_ALL_LDFLAGS="-no-undefined"
 289 AC_SUBST(GST_ALL_LDFLAGS)
 290
 291 dnl GST_PLUGIN_LDFLAGS:
 292 dnl this really should only contain flags, not libs - they get added before
 293 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 294 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 295 AC_SUBST(GST_PLUGIN_LDFLAGS)
 296
 297 dnl Check for the GStreamer plugins directory
 298 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 299 AC_MSG_CHECKING([for GStreamer plugins directory])
 300 if test -d "$GST_PLUGIN_PATH"; then
 301     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 302 else
 303     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 304     if test -z "$GST_PLUGINS_DIR"; then
 305         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 306     fi
 307 fi
 308 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 309 plugindir="$GST_PLUGINS_DIR"
 310 AC_SUBST(plugindir)
 311
 312 dnl ---------------------------------------------------------------------------
 313 dnl -- Renderers                                                             --
 314 dnl ---------------------------------------------------------------------------
 315
 316 dnl Check for DRM/libudev
 317 USE_DRM=0
 318 if test "$enable_drm" = "yes"; then
 319     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 320     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 321
 322     if test $USE_DRM -eq 1; then
 323         saved_CPPFLAGS="$CPPFLAGS"
 324         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 325         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 326         CPPFLAGS="$saved_CPPFLAGS"
 327     fi
 328 fi
 329
 330 dnl Check for X11
 331 USE_X11=0
 332 if test "$enable_x11" = "yes"; then
 333     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 334     if test $USE_X11 -eq 1; then
 335         saved_CPPFLAGS="$CPPFLAGS"
 336         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 337         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 338         CPPFLAGS="$saved_CPPFLAGS"
 339     fi
 340 fi
 341
 342 dnl Check for XRandR
 343 HAVE_XRANDR=0
 344 if test $USE_X11 -eq 1; then
 345     HAVE_XRANDR=1
 346     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 347     if test $HAVE_XRANDR -eq 1; then
 348         saved_CPPFLAGS="$CPPFLAGS"
 349         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 350         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 351         CPPFLAGS="$saved_CPPFLAGS"
 352     fi
 353 fi
 354 if test $HAVE_XRANDR -eq 1; then
 355     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 356         [Defined to 1 if the XRandR extension exists.])
 357 fi
 358
 359 dnl OpenGL
 360 enable_opengl="no"
 361 if test "$enable_glx" = "yes"; then
 362     enable_opengl="yes"
 363 fi
 364
 365 HAVE_GL=0
 366 if test "$enable_opengl" = "yes"; then
 367     HAVE_GL=1
 368     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 369     saved_CPPFLAGS="$CPPFLAGS"
 370     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 371     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 372 #ifdef HAVE_GL_GL_H
 373 # include <GL/gl.h>
 374 #endif
 375     ])
 376     CPPFLAGS="$saved_CPPFLAGS"
 377 fi
 378
 379 dnl ... GLX
 380 USE_GLX=0
 381 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 382     USE_GLX=1
 383     saved_CPPFLAGS="$CPPFLAGS"
 384     saved_LIBS="$LIBS"
 385     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 386     LIBS="$LIBS $GL_LIBS"
 387     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 388 #ifdef HAVE_GL_GL_H
 389 # include <GL/gl.h>
 390 #endif
 391     ])
 392     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 393     CPPFLAGS="$saved_CPPFLAGS"
 394     LIBS="$saved_LIBS"
 395 fi
 396
 397 dnl Check for Wayland
 398 USE_WAYLAND=0
 399 if test "$enable_wayland" = "yes"; then
 400     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 401         [USE_WAYLAND=1], [USE_WAYLAND=0])
 402
 403     if test $USE_WAYLAND -eq 1; then
 404         saved_CPPFLAGS="$CPPFLAGS"
 405         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 406         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 407         CPPFLAGS="$saved_CPPFLAGS"
 408     fi
 409 fi
 410
 411 dnl ---------------------------------------------------------------------------
 412 dnl -- VA-API                                                                --
 413 dnl ---------------------------------------------------------------------------
 414
 415 dnl Core API
 416 LIBVA_PKGNAME="libva"
 417 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 418 AC_SUBST(LIBVA_PKGNAME)
 419
 420 VA_VERSION=`$PKG_CONFIG --modversion libva`
 421 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 422 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 423 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 424 VA_VERSION_STR="$VA_VERSION"
 425
 426 dnl VA/DRM API
 427 HAVE_VA_DRM=0
 428 if test $USE_DRM -eq 1; then
 429     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 430         [HAVE_VA_DRM=1], [USE_DRM=0])
 431
 432     if test $HAVE_VA_DRM -eq 1; then
 433         saved_CPPFLAGS="$CPPFLAGS"
 434         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 435         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 436         CPPFLAGS="$saved_CPPFLAGS"
 437     fi
 438 fi
 439
 440 dnl VA/X11 API
 441 HAVE_VA_X11=0
 442 LIBVA_X11_PKGNAME="libva-x11"
 443 if test $USE_X11 -eq 1; then
 444     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 445         [HAVE_VA_X11=1], [USE_X11=0])
 446 fi
 447 AC_SUBST(LIBVA_X11_PKGNAME)
 448
 449 dnl VA/GLX API
 450 HAVE_VA_GLX=0
 451 LIBVA_GLX_PKGNAME="libva-glx"
 452 if test $USE_GLX -eq 1; then
 453     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 454         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 455
 456     if test $HAVE_VA_GLX -eq 1; then
 457         saved_CPPFLAGS="$CPPFLAGS"
 458         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 459         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 460         CPPFLAGS="$saved_CPPFLAGS"
 461     fi
 462 fi
 463 AC_SUBST(LIBVA_GLX_PKGNAME)
 464
 465 dnl Check for JPEG decoding API (0.32.1+)
 466 USE_JPEG_DECODER=0
 467 AC_CACHE_CHECK([for JPEG decoding API],
 468     ac_cv_have_jpeg_decoding_api, [
 469     saved_CFLAGS="$CFLAGS"
 470     CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 471     saved_LIBS="$LIBS"
 472     LIBS="$CFLAGS $LIBVA_LIBS"
 473     AC_COMPILE_IFELSE(
 474         [AC_LANG_PROGRAM(
 475             [[#include <va/va.h>]],
 476             [[VAPictureParameterBufferJPEGBaseline pic_param;
 477               VASliceParameterBufferJPEGBaseline slice_param;
 478               VAHuffmanTableBufferJPEGBaseline huffman_table;
 479               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 480         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 481         [ac_cv_have_jpeg_decoding_api="no"]
 482     )
 483     CFLAGS="$saved_CFLAGS"
 484     LIBS="$saved_LIBS"
 485 ])
 486
 487 dnl Check for vpp (video post-processing) support
 488 HAVE_VA_VPP=1
 489 saved_CFLAGS="$CFLAGS"
 490 CFLAGS="$CFLAGS $LIBVA_CFLAGS"
 491 AC_CHECK_HEADERS([va/va_vpp.h], [:], [HAVE_VA_VPP=0],
 492                  [[#include <va/va.h>
 493                    #include <va/va_vpp.h>]])
 494 CFLAGS="$saved_CFLAGS"
 495
 496 dnl VA/Wayland API
 497 if test "$enable_wayland" = "yes"; then
 498     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 499         [:], [USE_WAYLAND=0])
 500 fi
 501
 502 dnl ---------------------------------------------------------------------------
 503 dnl -- Generate files and summary                                            --
 504 dnl ---------------------------------------------------------------------------
 505
 506 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 507 *:1:*)
 508     ;;
 509 *)
 510     AC_MSG_ERROR([No renderer is enabled])
 511     ;;
 512 esac
 513
 514 AC_DEFINE_UNQUOTED(USE_VA_VPP, $HAVE_VA_VPP,
 515     [Defined to 1 if video post-processing is used])
 516 AM_CONDITIONAL(USE_VA_VPP, test $HAVE_VA_VPP -eq 1)
 517
 518 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 519     [Defined to 1 if JPEG decoder is used])
 520 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 521
 522 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 523     [Defined to 1 if DRM is enabled])
 524 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 525
 526 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 527     [Defined to 1 if X11 is enabled])
 528 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 529
 530 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 531     [Defined to 1 if GLX is enabled])
 532 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 533
 534 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 535     [Defined to 1 if WAYLAND is enabled])
 536 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 537
 538 pkgconfigdir=${libdir}/pkgconfig
 539 AC_SUBST(pkgconfigdir)
 540
 541 AC_CONFIG_FILES([
 542     Makefile
 543     debian.upstream/Makefile
 544     debian.upstream/changelog
 545     debian.upstream/control
 546     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 547 debian.upstream/gstreamer-vaapi-doc.install.in
 548     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 549 debian.upstream/gstreamer-vaapi.install.in
 550     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 551 debian.upstream/libgstvaapi.install.in
 552     debian.upstream/libgstvaapi-dev.install
 553     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 554 debian.upstream/libgstvaapi-drm.install.in
 555     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 556 debian.upstream/libgstvaapi-glx.install.in
 557     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 558 debian.upstream/libgstvaapi-wayland.install.in
 559     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 560 debian.upstream/libgstvaapi-x11.install.in
 561     docs/Makefile
 562     docs/reference/Makefile
 563     docs/reference/libs/Makefile
 564     docs/reference/libs/libs-docs.xml
 565     docs/reference/plugins/Makefile
 566     docs/reference/plugins/plugins-docs.xml
 567     ext/Makefile
 568     gst-libs/Makefile
 569     gst-libs/gst/Makefile
 570     gst-libs/gst/codecparsers/Makefile
 571     gst-libs/gst/vaapi/Makefile
 572     gst/Makefile
 573     gst/vaapi/Makefile
 574     pkgconfig/Makefile
 575     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 576 pkgconfig/gstreamer-vaapi.pc.in
 577     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 578 pkgconfig/gstreamer-vaapi-drm.pc.in
 579     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 580 pkgconfig/gstreamer-vaapi-glx.pc.in
 581     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 582 pkgconfig/gstreamer-vaapi-wayland.pc.in
 583     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 584 pkgconfig/gstreamer-vaapi-x11.pc.in
 585     tests/Makefile
 586 ])
 587 AC_OUTPUT
 588
 589 dnl Print summary
 590 yesno() {
 591     test $1 -eq 1 && echo yes || echo no
 592 }
 593
 594 VIDEO_OUTPUTS=""
 595 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 596 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 597 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 598 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 599
 600 echo
 601 echo $PACKAGE configuration summary:
 602 echo
 603 echo VA-API version ................... : $VA_VERSION_STR
 604 echo Video outputs .................... : $VIDEO_OUTPUTS
 605 echo