configure.ac

   1 # gstreamer-vaapi package version number
   2 m4_define([gst_vaapi_major_version], [0])
   3 m4_define([gst_vaapi_minor_version], [5])
   4 m4_define([gst_vaapi_micro_version], [0])
   5 m4_define([gst_vaapi_pre_version],   [1])
   6 m4_define([gst_vaapi_version],
   7           [gst_vaapi_major_version.gst_vaapi_minor_version.gst_vaapi_micro_version])
   8 m4_if(gst_vaapi_pre_version, [0], [], [
   9 m4_append([gst_vaapi_version], gst_vaapi_pre_version, [.pre])
  10 ])
  11
  12 # gstreamer-vaapi library (libtool) version number
  13 m4_define([gst_vaapi_lt_current],  [1])
  14 m4_define([gst_vaapi_lt_revision], [0])
  15 m4_define([gst_vaapi_lt_age],      [0])
  16
  17 # glib version number
  18 m4_define([glib_major_version], [2])
  19 m4_define([glib_minor_version], [28])
  20 m4_define([glib_micro_version], [0])
  21 m4_define([glib_major_minor_version],
  22           [glib_major_version.glib_minor_version])
  23 m4_define([glib_version],
  24           [glib_major_version.glib_minor_version.glib_micro_version])
  25
  26 # gst version number
  27 m4_define([gst_major_version], [0])
  28 m4_define([gst_minor_version], [10])
  29 m4_define([gst_micro_version], [36])
  30 m4_define([gst_major_minor_version],
  31           [gst_major_version.gst_minor_version])
  32 m4_define([gst_version],
  33           [gst_major_version.gst_minor_version.gst_micro_version])
  34
  35 # gst plugins-base version number
  36 m4_define([gst_plugins_base_major_version], [0])
  37 m4_define([gst_plugins_base_minor_version], [10])
  38 m4_define([gst_plugins_base_micro_version], [31])
  39 m4_define([gst_plugins_base_version],
  40           [gst_plugins_base_major_version.gst_plugins_base_minor_version.gst_plugins_base_micro_version])
  41
  42 # gst plugins-bad version number
  43 m4_define([gst_plugins_bad_major_version], [0])
  44 m4_define([gst_plugins_bad_minor_version], [10])
  45 m4_define([gst_plugins_bad_micro_version], [22])
  46 m4_define([gst_plugins_bad_version],
  47           [gst_plugins_bad_major_version.gst_plugins_bad_minor_version.gst_plugins_bad_micro_version])
  48
  49 # Wayland minimum version number
  50 m4_define([wayland_api_version], [1.0.0])
  51
  52 # VA-API minimum version number
  53 m4_define([va_api_version],     [0.30.4])
  54 m4_define([va_api_drm_version], [0.33.0])
  55 m4_define([va_api_x11_version], [0.31.0])
  56 m4_define([va_api_glx_version], [0.32.0])
  57 m4_define([va_api_wld_version], [0.33.0])
  58
  59 # libva package version number
  60 m4_define([libva_drm_package_version], [1.1.0])
  61 m4_define([libva_x11_package_version], [1.0.3])
  62 m4_define([libva_glx_package_version], [1.0.9])
  63 m4_define([libva_wld_package_version], [1.1.0])
  64
  65 # gtk-doc version number
  66 # XXX: introspection annotations require gtk-doc >= 1.12
  67 m4_define([gtkdoc_major_version], [1])
  68 m4_define([gtkdoc_minor_version], [9])
  69 m4_define([gtkdoc_version], [gtkdoc_major_version.gtkdoc_minor_version])
  70
  71 AC_PREREQ([2.58])
  72 AC_INIT([gst_vaapi], [gst_vaapi_version],
  73     [gwenole.beauchesne@intel.com],
  74     [gstreamer-vaapi])
  75
  76 AC_CONFIG_HEADERS([config.h])
  77 AC_CONFIG_SRCDIR([Makefile.am])
  78 AC_CONFIG_MACRO_DIR([m4])
  79 AC_CONFIG_AUX_DIR([build-aux])
  80
  81 AC_CANONICAL_TARGET
  82
  83 AM_INIT_AUTOMAKE([1.11 tar-ustar no-dist-gzip dist-bzip2])
  84
  85 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  86 AC_SUBST(TODAY)
  87
  88 GST_VAAPI_MAJOR_VERSION=gst_vaapi_lt_current
  89 AC_SUBST(GST_VAAPI_MAJOR_VERSION)
  90
  91 LIBVA_PACKAGE_VERSION=libva_x11_package_version
  92 AC_SUBST(LIBVA_PACKAGE_VERSION)
  93
  94 WAYLAND_API_VERSION=wayland_api_version
  95 AC_SUBST(WAYLAND_API_VERSION)
  96
  97 dnl Versions for GStreamer and plugins-base
  98 GST_MAJORMINOR=gst_major_minor_version
  99 GST_VERSION_REQUIRED=gst_version
 100 GST_PLUGINS_BASE_VERSION_REQUIRED=gst_plugins_base_version
 101 GST_PLUGINS_BAD_VERSION_REQUIRED=gst_plugins_bad_version
 102 AC_SUBST(GST_MAJORMINOR)
 103 AC_SUBST(GST_VERSION_REQUIRED)
 104 AC_SUBST(GST_PLUGINS_BASE_VERSION_REQUIRED)
 105 AC_SUBST(GST_PLUGINS_BAD_VERSION_REQUIRED)
 106
 107 dnl Use pretty build output with automake >= 1.11
 108 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
 109   AM_DEFAULT_VERBOSITY=1
 110   AC_SUBST(AM_DEFAULT_VERBOSITY)
 111 ])
 112
 113 dnl Check for tools
 114 AC_PROG_CC
 115 AM_PROG_CC_C_O
 116
 117 dnl Initialize libtool
 118 LT_PREREQ([2.2])
 119 LT_INIT
 120
 121 AC_ARG_ENABLE(drm,
 122     AS_HELP_STRING([--enable-drm],
 123                    [enable DRM backend @<:@default=yes@:>@]),
 124     [], [enable_drm="yes"])
 125
 126 AC_ARG_ENABLE(x11,
 127     AS_HELP_STRING([--enable-x11],
 128                    [enable X11 output @<:@default=yes@:>@]),
 129     [], [enable_x11="yes"])
 130
 131 AC_ARG_ENABLE(glx,
 132     AS_HELP_STRING([--enable-glx],
 133                    [enable OpenGL/X11 output @<:@default=yes@:>@]),
 134     [], [enable_glx="yes"])
 135
 136 AC_ARG_ENABLE(wayland,
 137     AC_HELP_STRING([--enable-wayland],
 138                    [enable Wayland output @<:@default=yes@:>@]),
 139     [], [enable_wayland="yes"])
 140
 141 dnl Check for basic libraries
 142 AC_CHECK_LIB(m, tan)
 143
 144 dnl Check for Gtk doc
 145 GTKDOC_VERSION=gtkdoc_version
 146 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
 147 m4_ifdef([GTK_DOC_CHECK], [
 148 GTK_DOC_CHECK([$GTKDOC_VERSION], [--flavour no-tmpl])], [
 149 AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
 150 AC_SUBST(GTKDOC_VERSION)
 151
 152 dnl Check for GLib
 153 GLIB_VERSION_REQUIRED=glib_version
 154 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= $GLIB_VERSION_REQUIRED])
 155 AC_SUBST(GLIB_VERSION_REQUIRED)
 156
 157 dnl ---------------------------------------------------------------------------
 158 dnl -- GStreamer                                                             --
 159 dnl ---------------------------------------------------------------------------
 160
 161 dnl GStreamer Core
 162 PKG_CHECK_MODULES([GST],      [gstreamer-$GST_MAJORMINOR >= gst_version])
 163 PKG_CHECK_MODULES([GST_BASE], [gstreamer-base-$GST_MAJORMINOR >= gst_version])
 164
 165 AC_CACHE_CHECK([for GstBaseSink::query hook], ac_cv_have_gst_base_sink_query, [
 166     saved_CPPFLAGS="$CPPFLAGS"
 167     CPPFLAGS="$CPPFLAGS $GST_BASE_CFLAGS"
 168     saved_LIBS="$LIBS"
 169     LIBS="$LIBS $GST_BASE_LIBS"
 170     AC_COMPILE_IFELSE(
 171         [AC_LANG_PROGRAM(
 172             [[#include <gst/base/gstbasesink.h>]],
 173             [[GstBaseSinkClass klass; klass.query = NULL;]])],
 174         [ac_cv_have_gst_base_sink_query="yes"],
 175         [ac_cv_have_gst_base_sink_query="no"]
 176     )
 177     CPPFLAGS="$saved_CPPFLAGS"
 178     LIBS="$saved_LIBS"
 179 ])
 180 if test "$ac_cv_have_gst_base_sink_query" != "yes"; then
 181     AC_MSG_ERROR([GstBaseSink does not contain the 'query' vfunc])
 182 fi
 183
 184 dnl GStreamer -base plugins
 185 PKG_CHECK_MODULES([GST_PLUGINS_BASE],
 186     [gstreamer-plugins-base-$GST_MAJORMINOR >= gst_plugins_base_version])
 187 PKG_CHECK_MODULES([GST_INTERFACES],
 188     [gstreamer-interfaces-$GST_MAJORMINOR >= gst_plugins_base_version])
 189
 190 dnl ... GstVideoOverlayComposition (gstreamer-video)
 191 PKG_CHECK_MODULES([GST_VIDEO],
 192     [gstreamer-video-$GST_MAJORMINOR >= gst_plugins_base_version])
 193
 194 AC_CACHE_CHECK([for GstVideoOverlayComposition],
 195     ac_cv_have_gst_video_overlay_composition, [
 196     saved_CPPFLAGS="$CPPFLAGS"
 197     CPPFLAGS="$CPPFLAGS $GST_CFLAGS"
 198     saved_LIBS="$LIBS"
 199     LIBS="$LIBS $GST_LIBS"
 200     AC_COMPILE_IFELSE(
 201         [AC_LANG_PROGRAM(
 202             [[#include <gst/video/video-overlay-composition.h>]],
 203             [[GstVideoOverlayComposition *c = gst_video_overlay_composition_new(0);]])],
 204         [ac_cv_have_gst_video_overlay_composition="yes"],
 205         [ac_cv_have_gst_video_overlay_composition="no"]
 206     )
 207     CPPFLAGS="$saved_CPPFLAGS"
 208     LIBS="$saved_LIBS"
 209 ])
 210 if test "$ac_cv_have_gst_video_overlay_composition" != "yes"; then
 211     AC_MSG_ERROR([GstVideoOverlayComposition is not available])
 212 fi
 213
 214 dnl ... GstVideoDecoder (gstreamer-video)
 215 AC_CACHE_CHECK([for GstVideoDecoder],
 216     ac_cv_have_gst_video_decoder, [
 217     saved_CPPFLAGS="$CPPFLAGS"
 218     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_VIDEO_CFLAGS"
 219     saved_LIBS="$LIBS"
 220     LIBS="$LIBS $GST_LIBS $GST_VIDEO_LIBS"
 221     AC_COMPILE_IFELSE(
 222         [AC_LANG_PROGRAM(
 223             [[#include <gst/video/gstvideodecoder.h>]],
 224             [[GstVideoCodecFrame *f;
 225               GstVideoDecoder vdec;
 226               f = g_slice_new0(GstVideoCodecFrame);
 227               f->ref_count = 1;
 228               gst_video_decoder_have_frame(&vdec);
 229               gst_video_decoder_finish_frame(&vdec, f);
 230               gst_video_codec_frame_unref(f);]])],
 231         [ac_cv_have_gst_video_decoder="yes"],
 232         [ac_cv_have_gst_video_decoder="no"]
 233     )
 234     CPPFLAGS="$saved_CPPFLAGS"
 235     LIBS="$saved_LIBS"
 236 ])
 237 AM_CONDITIONAL([USE_LOCAL_GST_VIDEO_DECODER],
 238     [test "$ac_cv_have_gst_video_decoder" != "yes"])
 239
 240 dnl GStreamer -bad plugins
 241 PKG_CHECK_MODULES([GST_BASEVIDEO],
 242     [gstreamer-basevideo-$GST_MAJORMINOR >= gst_plugins_bad_version])
 243
 244 dnl ... bitstream parsers
 245 PKG_CHECK_MODULES([GST_CODEC_PARSERS],
 246     [gstreamer-codecparsers-$GST_MAJORMINOR >= gst_plugins_bad_version])
 247
 248 dnl ... MPEG-2 parser, with the required extensions
 249 AC_CACHE_CHECK([for MPEG-2 parser],
 250     ac_cv_have_gst_mpeg2_parser, [
 251     saved_CPPFLAGS="$CPPFLAGS"
 252     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 253     saved_LIBS="$LIBS"
 254     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 255     AC_COMPILE_IFELSE(
 256         [AC_LANG_PROGRAM(
 257             [[#include <gst/codecparsers/gstmpegvideoparser.h>]],
 258             [[GstMpegVideoSequenceHdr seq_hdr;
 259               GstMpegVideoSequenceExt seq_ext;
 260               GstMpegVideoSequenceDisplayExt seq_dpy;
 261               gst_mpeg_video_finalise_mpeg2_sequence_header(&seq_hdr,
 262                   &seq_ext, &seq_dpy);]])],
 263         [ac_cv_have_gst_mpeg2_parser="yes"],
 264         [ac_cv_have_gst_mpeg2_parser="no"]
 265     )
 266     CPPFLAGS="$saved_CPPFLAGS"
 267     LIBS="$saved_LIBS"
 268 ])
 269 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_MPEG2],
 270     [test "$ac_cv_have_gst_mpeg2_parser" != "yes"])
 271
 272 dnl ... H.264 parser, with the required extensions
 273 AC_CACHE_CHECK([for H.264 parser],
 274     ac_cv_have_gst_h264_parser, [
 275     saved_CPPFLAGS="$CPPFLAGS"
 276     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 277     saved_LIBS="$LIBS"
 278     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 279     AC_COMPILE_IFELSE(
 280         [AC_LANG_PROGRAM(
 281             [[#include <gst/codecparsers/gsth264parser.h>]],
 282             [[GstH264SliceHdr slice_hdr;
 283               GstH264VUIParams vui_params;
 284               slice_hdr.n_emulation_prevention_bytes = 0;
 285               vui_params.par_n = 0;
 286               vui_params.par_d = 0;]])],
 287         [ac_cv_have_gst_h264_parser="yes"],
 288         [ac_cv_have_gst_h264_parser="no"]
 289     )
 290     CPPFLAGS="$saved_CPPFLAGS"
 291     LIBS="$saved_LIBS"
 292 ])
 293 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_H264],
 294     [test "$ac_cv_have_gst_h264_parser" != "yes"])
 295
 296 dnl ... JPEG parser, not upstream yet
 297 AC_CACHE_CHECK([for JPEG parser],
 298     ac_cv_have_gst_jpeg_parser, [
 299     saved_CPPFLAGS="$CPPFLAGS"
 300     CPPFLAGS="$CPPFLAGS $GST_CFLAGS $GST_CODEC_PARSERS_CFLAGS"
 301     saved_LIBS="$LIBS"
 302     LIBS="$LIBS $GST_LIBS $GST_CODEC_PARSERS_LIBS"
 303     AC_COMPILE_IFELSE(
 304         [AC_LANG_PROGRAM(
 305             [[#include <gst/codecparsers/gstjpegparser.h>]],
 306             [[GstJpegImage jpeg_image;]])],
 307         [ac_cv_have_gst_jpeg_parser="yes"],
 308         [ac_cv_have_gst_jpeg_parser="no"]
 309     )
 310     CPPFLAGS="$saved_CPPFLAGS"
 311     LIBS="$saved_LIBS"
 312 ])
 313 AM_CONDITIONAL([USE_LOCAL_CODEC_PARSERS_JPEG],
 314     [test "$ac_cv_have_gst_jpeg_parser" != "yes"])
 315
 316 dnl GST_VAAPI_LT_LDFLAGS:
 317 GST_VAAPI_LT_CURRENT=gst_vaapi_lt_current
 318 GST_VAAPI_LT_REV=gst_vaapi_lt_revision
 319 GST_VAAPI_LT_AGE=gst_vaapi_lt_age
 320 GST_VAAPI_LT_VERSION="$GST_VAAPI_LT_CURRENT:$GST_VAAPI_LT_REV:$GST_VAAPI_LT_AGE"
 321 GST_VAAPI_LT_LDFLAGS="-version-info $GST_VAAPI_LT_VERSION"
 322 AC_SUBST(GST_VAAPI_LT_VERSION)
 323 AC_SUBST(GST_VAAPI_LT_LDFLAGS)
 324
 325 dnl GST_ALL_LDFLAGS:
 326 dnl LDFLAGS really should only contain flags, not libs - they get added before
 327 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 328 GST_ALL_LDFLAGS="-no-undefined"
 329 AC_SUBST(GST_ALL_LDFLAGS)
 330
 331 dnl GST_PLUGIN_LDFLAGS:
 332 dnl this really should only contain flags, not libs - they get added before
 333 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 334 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^([_]*gst_plugin_desc|gst_.*_get_type)\$\$' $GST_ALL_LDFLAGS"
 335 AC_SUBST(GST_PLUGIN_LDFLAGS)
 336
 337 dnl Check for the GStreamer plugins directory
 338 AC_ARG_VAR([GST_PLUGIN_PATH], [installation path for gstreamer-vaapi plugin elements])
 339 AC_MSG_CHECKING([for GStreamer plugins directory])
 340 if test -d "$GST_PLUGIN_PATH"; then
 341     GST_PLUGINS_DIR="$GST_PLUGIN_PATH"
 342 else
 343     GST_PLUGINS_DIR=`$PKG_CONFIG gstreamer-$GST_MAJORMINOR --variable pluginsdir`
 344     if test -z "$GST_PLUGINS_DIR"; then
 345         GST_PLUGINS_DIR="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 346     fi
 347 fi
 348 AC_MSG_RESULT([$GST_PLUGINS_DIR])
 349 plugindir="$GST_PLUGINS_DIR"
 350 AC_SUBST(plugindir)
 351
 352 dnl ---------------------------------------------------------------------------
 353 dnl -- Renderers                                                             --
 354 dnl ---------------------------------------------------------------------------
 355
 356 dnl Check for DRM/libudev
 357 USE_DRM=0
 358 if test "$enable_drm" = "yes"; then
 359     PKG_CHECK_MODULES(DRM, [libdrm], [USE_DRM=1], [USE_DRM=0])
 360     PKG_CHECK_MODULES(UDEV, [libudev], [:], [USE_DRM=0])
 361
 362     if test $USE_DRM -eq 1; then
 363         saved_CPPFLAGS="$CPPFLAGS"
 364         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 365         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM=0])
 366         CPPFLAGS="$saved_CPPFLAGS"
 367     fi
 368 fi
 369
 370 dnl Check for X11
 371 USE_X11=0
 372 if test "$enable_x11" = "yes"; then
 373     PKG_CHECK_MODULES(X11, [x11], [USE_X11=1], [USE_X11=0])
 374     if test $USE_X11 -eq 1; then
 375         saved_CPPFLAGS="$CPPFLAGS"
 376         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 377         AC_CHECK_HEADERS([X11/Xlib.h X11/Xutil.h X11/Xatom.h], [:], [USE_X11=0])
 378         CPPFLAGS="$saved_CPPFLAGS"
 379     fi
 380 fi
 381
 382 dnl Check for XRandR
 383 HAVE_XRANDR=0
 384 if test $USE_X11 -eq 1; then
 385     HAVE_XRANDR=1
 386     PKG_CHECK_MODULES([XRANDR], [xrandr], [:], [HAVE_XRANDR=0])
 387     if test $HAVE_XRANDR -eq 1; then
 388         saved_CPPFLAGS="$CPPFLAGS"
 389         CPPFLAGS="$CPPFLAGS $XRANDR_CFLAGS"
 390         AC_CHECK_HEADERS([X11/extensions/Xrandr.h], [:], [HAVE_XRANDR=0])
 391         CPPFLAGS="$saved_CPPFLAGS"
 392     fi
 393 fi
 394 if test $HAVE_XRANDR -eq 1; then
 395     AC_DEFINE_UNQUOTED(HAVE_XRANDR, 1,
 396         [Defined to 1 if the XRandR extension exists.])
 397 fi
 398
 399 dnl OpenGL
 400 enable_opengl="no"
 401 if test "$enable_glx" = "yes"; then
 402     enable_opengl="yes"
 403 fi
 404
 405 HAVE_GL=0
 406 if test "$enable_opengl" = "yes"; then
 407     HAVE_GL=1
 408     PKG_CHECK_MODULES([GL], [gl], [:], [HAVE_GL=0])
 409     saved_CPPFLAGS="$CPPFLAGS"
 410     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 411     AC_CHECK_HEADERS([GL/gl.h GL/glext.h], [:], [HAVE_GL=0], [
 412 #ifdef HAVE_GL_GL_H
 413 # include <GL/gl.h>
 414 #endif
 415     ])
 416     CPPFLAGS="$saved_CPPFLAGS"
 417 fi
 418
 419 dnl ... GLX
 420 USE_GLX=0
 421 if test "$enable_glx" = "yes" -a $HAVE_GL -eq 1 -a $USE_X11 -eq 1; then
 422     USE_GLX=1
 423     saved_CPPFLAGS="$CPPFLAGS"
 424     saved_LIBS="$LIBS"
 425     CPPFLAGS="$CPPFLAGS $GL_CFLAGS"
 426     LIBS="$LIBS $GL_LIBS"
 427     AC_CHECK_HEADERS([GL/glx.h], [:], [USE_GLX=0], [
 428 #ifdef HAVE_GL_GL_H
 429 # include <GL/gl.h>
 430 #endif
 431     ])
 432     AC_CHECK_LIB([GL], [glXCreateContext], [:], [USE_GLX=0])
 433     CPPFLAGS="$saved_CPPFLAGS"
 434     LIBS="$saved_LIBS"
 435 fi
 436
 437 dnl Check for Wayland
 438 USE_WAYLAND=0
 439 if test "$enable_wayland" = "yes"; then
 440     PKG_CHECK_MODULES(WAYLAND, [wayland-client >= wayland_api_version],
 441         [USE_WAYLAND=1], [USE_WAYLAND=0])
 442
 443     if test $USE_WAYLAND -eq 1; then
 444         saved_CPPFLAGS="$CPPFLAGS"
 445         CPPFLAGS="$CPPFLAGS $WAYLAND_CFLAGS"
 446         AC_CHECK_HEADERS([wayland-client.h], [:], [USE_WAYLAND=0])
 447         CPPFLAGS="$saved_CPPFLAGS"
 448     fi
 449 fi
 450
 451 dnl ---------------------------------------------------------------------------
 452 dnl -- VA-API                                                                --
 453 dnl ---------------------------------------------------------------------------
 454
 455 dnl Core API
 456 LIBVA_PKGNAME="libva"
 457 PKG_CHECK_MODULES(LIBVA, [$LIBVA_PKGNAME >= va_api_version])
 458 AC_SUBST(LIBVA_PKGNAME)
 459
 460 VA_VERSION=`$PKG_CONFIG --modversion libva`
 461 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 462 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 463 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 464 VA_VERSION_STR="$VA_VERSION"
 465
 466 dnl VA/DRM API
 467 HAVE_VA_DRM=0
 468 if test $USE_DRM -eq 1; then
 469     PKG_CHECK_MODULES([LIBVA_DRM], [libva-drm >= va_api_drm_version],
 470         [HAVE_VA_DRM=1], [USE_DRM=0])
 471
 472     if test $HAVE_VA_DRM -eq 1; then
 473         saved_CPPFLAGS="$CPPFLAGS"
 474         CPPFLAGS="$LIBVA_DRM_CFLAGS"
 475         AC_CHECK_HEADERS([va/va_drm.h], [:], [HAVE_VA_DRM=0 USE_DRM=0])
 476         CPPFLAGS="$saved_CPPFLAGS"
 477     fi
 478 fi
 479
 480 dnl VA/X11 API
 481 HAVE_VA_X11=0
 482 LIBVA_X11_PKGNAME="libva-x11"
 483 if test $USE_X11 -eq 1; then
 484     PKG_CHECK_MODULES(LIBVA_X11, [$LIBVA_X11_PKGNAME >= va_api_x11_version],
 485         [HAVE_VA_X11=1], [USE_X11=0])
 486 fi
 487 AC_SUBST(LIBVA_X11_PKGNAME)
 488
 489 dnl VA/GLX API
 490 HAVE_VA_GLX=0
 491 LIBVA_GLX_PKGNAME="libva-glx"
 492 if test $USE_GLX -eq 1; then
 493     PKG_CHECK_MODULES(LIBVA_GLX, [$LIBVA_GLX_PKGNAME >= va_api_glx_version],
 494         [HAVE_VA_GLX=1], [LIBVA_GLX_PKGNAME="$LIBVA_X11_PKGNAME"])
 495
 496     if test $HAVE_VA_GLX -eq 1; then
 497         saved_CPPFLAGS="$CPPFLAGS"
 498         CPPFLAGS="$LIBVA_GLX_CFLAGS"
 499         AC_CHECK_HEADERS([va/va_glx.h], [:], [HAVE_VA_GLX=0])
 500         CPPFLAGS="$saved_CPPFLAGS"
 501     fi
 502 fi
 503 AC_SUBST(LIBVA_GLX_PKGNAME)
 504
 505 dnl Check for JPEG decoding API (0.32.1+)
 506 USE_JPEG_DECODER=0
 507 AC_CACHE_CHECK([for JPEG decoding API],
 508     ac_cv_have_jpeg_decoding_api, [
 509     saved_CPPFLAGS="$CPPFLAGS"
 510     CPPFLAGS="$CPPFLAGS $LIBVA_CFLAGS"
 511     saved_LIBS="$LIBS"
 512     LIBS="$LIBS $LIBVA_LIBS"
 513     AC_COMPILE_IFELSE(
 514         [AC_LANG_PROGRAM(
 515             [[#include <va/va.h>]],
 516             [[VAPictureParameterBufferJPEGBaseline pic_param;
 517               VASliceParameterBufferJPEGBaseline slice_param;
 518               VAHuffmanTableBufferJPEGBaseline huffman_table;
 519               VAIQMatrixBufferJPEGBaseline iq_matrix;]])],
 520         [ac_cv_have_jpeg_decoding_api="yes" USE_JPEG_DECODER=1],
 521         [ac_cv_have_jpeg_decoding_api="no"]
 522     )
 523     CPPFLAGS="$saved_CPPFLAGS"
 524     LIBS="$saved_LIBS"
 525 ])
 526
 527 dnl VA/Wayland API
 528 if test "$enable_wayland" = "yes"; then
 529     PKG_CHECK_MODULES([LIBVA_WAYLAND], [libva-wayland >= va_api_wld_version],
 530         [:], [USE_WAYLAND=0])
 531 fi
 532
 533 dnl ---------------------------------------------------------------------------
 534 dnl -- Generate files and summary                                            --
 535 dnl ---------------------------------------------------------------------------
 536
 537 case ":$USE_X11:$USE_GLX:$USE_WAYLAND:$USE_DRM:" in
 538 *:1:*)
 539     ;;
 540 *)
 541     AC_MSG_ERROR([No renderer is enabled])
 542     ;;
 543 esac
 544
 545 AC_DEFINE_UNQUOTED(USE_JPEG_DECODER, $USE_JPEG_DECODER,
 546     [Defined to 1 if JPEG decoder is used])
 547 AM_CONDITIONAL(USE_JPEG_DECODER, test $USE_JPEG_DECODER -eq 1)
 548
 549 AC_DEFINE_UNQUOTED(USE_DRM, $USE_DRM,
 550     [Defined to 1 if DRM is enabled])
 551 AM_CONDITIONAL(USE_DRM, test $USE_DRM -eq 1)
 552
 553 AC_DEFINE_UNQUOTED(USE_X11, $USE_X11,
 554     [Defined to 1 if X11 is enabled])
 555 AM_CONDITIONAL(USE_X11, test $USE_X11 -eq 1)
 556
 557 AC_DEFINE_UNQUOTED(USE_GLX, $USE_GLX,
 558     [Defined to 1 if GLX is enabled])
 559 AM_CONDITIONAL(USE_GLX, test $USE_GLX -eq 1)
 560
 561 AC_DEFINE_UNQUOTED(USE_WAYLAND, $USE_WAYLAND,
 562     [Defined to 1 if WAYLAND is enabled])
 563 AM_CONDITIONAL(USE_WAYLAND, test $USE_WAYLAND -eq 1)
 564
 565 pkgconfigdir=${libdir}/pkgconfig
 566 AC_SUBST(pkgconfigdir)
 567
 568 AC_CONFIG_FILES([
 569     Makefile
 570     debian.upstream/Makefile
 571     debian.upstream/changelog
 572     debian.upstream/control
 573     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi-doc.install:\
 574 debian.upstream/gstreamer-vaapi-doc.install.in
 575     debian.upstream/gstreamer$GST_MAJORMINOR-vaapi.install:\
 576 debian.upstream/gstreamer-vaapi.install.in
 577     debian.upstream/libgstvaapi$GST_VAAPI_MAJOR_VERSION.install:\
 578 debian.upstream/libgstvaapi.install.in
 579     debian.upstream/libgstvaapi-dev.install
 580     debian.upstream/libgstvaapi-drm-$GST_VAAPI_MAJOR_VERSION.install:\
 581 debian.upstream/libgstvaapi-drm.install.in
 582     debian.upstream/libgstvaapi-glx-$GST_VAAPI_MAJOR_VERSION.install:\
 583 debian.upstream/libgstvaapi-glx.install.in
 584     debian.upstream/libgstvaapi-wayland-$GST_VAAPI_MAJOR_VERSION.install:\
 585 debian.upstream/libgstvaapi-wayland.install.in
 586     debian.upstream/libgstvaapi-x11-$GST_VAAPI_MAJOR_VERSION.install:\
 587 debian.upstream/libgstvaapi-x11.install.in
 588     docs/Makefile
 589     docs/reference/Makefile
 590     docs/reference/libs/Makefile
 591     docs/reference/libs/libs-docs.xml
 592     docs/reference/plugins/Makefile
 593     docs/reference/plugins/plugins-docs.xml
 594     ext/Makefile
 595     gst-libs/Makefile
 596     gst-libs/gst/Makefile
 597     gst-libs/gst/codecparsers/Makefile
 598     gst-libs/gst/vaapi/Makefile
 599     gst-libs/gst/video/Makefile
 600     gst/Makefile
 601     gst/vaapi/Makefile
 602     pkgconfig/Makefile
 603     pkgconfig/gstreamer-vaapi-$GST_MAJORMINOR.pc:\
 604 pkgconfig/gstreamer-vaapi.pc.in
 605     pkgconfig/gstreamer-vaapi-drm-$GST_MAJORMINOR.pc:\
 606 pkgconfig/gstreamer-vaapi-drm.pc.in
 607     pkgconfig/gstreamer-vaapi-glx-$GST_MAJORMINOR.pc:\
 608 pkgconfig/gstreamer-vaapi-glx.pc.in
 609     pkgconfig/gstreamer-vaapi-wayland-$GST_MAJORMINOR.pc:\
 610 pkgconfig/gstreamer-vaapi-wayland.pc.in
 611     pkgconfig/gstreamer-vaapi-x11-$GST_MAJORMINOR.pc:\
 612 pkgconfig/gstreamer-vaapi-x11.pc.in
 613     tests/Makefile
 614 ])
 615 AC_OUTPUT
 616
 617 dnl Print summary
 618 yesno() {
 619     test $1 -eq 1 && echo yes || echo no
 620 }
 621
 622 VIDEO_OUTPUTS=""
 623 AS_IF([test $USE_DRM -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS drm"])
 624 AS_IF([test $USE_X11 -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS x11"])
 625 AS_IF([test $USE_GLX -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS glx"])
 626 AS_IF([test $USE_WAYLAND -eq 1], [VIDEO_OUTPUTS="$VIDEO_OUTPUTS wayland"])
 627
 628 echo
 629 echo $PACKAGE configuration summary:
 630 echo
 631 echo VA-API version ................... : $VA_VERSION_STR
 632 echo Video outputs .................... : $VIDEO_OUTPUTS
 633 echo