configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.22.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_CVS="no", GST_CVS="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl our libraries and install dirs use major.minor as a version
  36 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  37 dnl we override it here if we need to for the release candidate of new series
  38 GST_MAJORMINOR=0.10
  39 AC_SUBST(GST_MAJORMINOR)
  40
  41 dnl CURRENT, REVISION, AGE
  42 dnl - library source changed -> increment REVISION
  43 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  44 dnl - interfaces added -> increment AGE
  45 dnl - interfaces removed -> AGE = 0
  46 dnl sets GST_LT_LDFLAGS
  47 AS_LIBTOOL(GST, 16, 0, 16)
  48
  49 dnl FIXME: this macro doesn't actually work;
  50 dnl the generated libtool script has no support for the listed tags.
  51 dnl So this needs to be fixed first if we want to use this
  52 dnl AS_LIBTOOL_TAGS
  53
  54 AC_LIBTOOL_WIN32_DLL
  55 AM_PROG_LIBTOOL
  56
  57 dnl *** required versions of GStreamer stuff ***
  58 GST_REQ=0.10.21.1
  59
  60 dnl *** autotools stuff ****
  61
  62 dnl allow for different autotools
  63 AS_AUTOTOOLS_ALTERNATE
  64
  65 dnl Add parameters for aclocal
  66 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  67
  68 dnl set up gettext
  69 dnl the version check needs to stay here because autopoint greps for it
  70 AM_GNU_GETTEXT_VERSION([0.17])
  71 AM_GNU_GETTEXT([external])
  72 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  73
  74 dnl *** check for arguments to configure ***
  75
  76 AG_GST_ARG_DEBUG
  77 AG_GST_ARG_PROFILING
  78 AG_GST_ARG_VALGRIND
  79 AG_GST_ARG_GCOV
  80
  81 AG_GST_ARG_EXAMPLES
  82
  83 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  84 AG_GST_ARG_WITH_PACKAGE_NAME
  85 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  86
  87 dnl let distro override plugin install helper path
  88 AC_ARG_WITH(install-plugins-helper,
  89   AC_HELP_STRING([--with-install-plugins-helper],
  90     [specify path of helper script to call to install plugins]),
  91   [
  92     case "${withval}" in
  93       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  94       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  95       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  96     esac
  97   ],
  98   [
  99     dnl Default value
 100     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 101   ]
 102 )
 103 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 104 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 105     [plugin install helper script])
 106 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 107
 108 AG_GST_ARG_WITH_PLUGINS
 109
 110 AG_GST_ARG_ENABLE_EXTERNAL
 111
 112 AG_GST_ARG_ENABLE_EXPERIMENTAL
 113
 114 dnl *** checks for platform ***
 115
 116 dnl * hardware/architecture *
 117
 118 dnl common/m4/gst-arch.m4
 119 dnl check CPU type
 120 AG_GST_ARCH
 121
 122 dnl check for large file support
 123 dnl affected plugins must include config.h
 124 AC_SYS_LARGEFILE
 125
 126 dnl *** checks for programs ***
 127
 128 dnl find a compiler
 129 AC_PROG_CC
 130
 131 dnl check if the compiler supports '-c' and '-o' options
 132 AM_PROG_CC_C_O
 133
 134 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 135 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 136
 137 dnl check for documentation tools
 138 GTK_DOC_CHECK([1.3])
 139 AS_PATH_PYTHON([2.1])
 140 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 141
 142 dnl *** checks for libraries ***
 143
 144 dnl libm, for sin() etc.
 145 AC_CHECK_LIBM
 146 AC_SUBST(LIBM)
 147
 148 dnl *** checks for header files ***
 149
 150 dnl check if we have ANSI C header files
 151 AC_HEADER_STDC
 152
 153 dnl used in gst/ffmpegcolorspace/mem.c
 154 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 155 AC_CHECK_HEADERS([malloc.h])
 156
 157 dnl used in gst/subparse/gstsubparse.c
 158 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 159 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 160
 161 if test "x$HAVE_REGEX_H" = "xyes"; then
 162   ac_cppflags_save="$CPPFLAGS"
 163   CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 164   AC_COMPILE_IFELSE(
 165     AC_LANG_PROGRAM([
 166 #include <libxml/HTMLparser.h>
 167                      ],[
 168 #ifndef LIBXML_HTML_ENABLED
 169 #error libxml2 has no HTML support
 170 #endif /* LIBXML_HTML_ENABLED */
 171                      ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 172   CPPFLAGS="$ac_cppflags_save"
 173 else
 174   HAVE_LIBXML_HTML="no"
 175 fi
 176 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 177
 178 dnl used in gst/tcp
 179 AC_CHECK_HEADERS([sys/socket.h],
 180   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 181 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 182
 183 dnl used in gst-libs/gst/rtsp
 184 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 185 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 186   WIN32_LIBS="-lws2_32"
 187   AC_SUBST(WIN32_LIBS)
 188 fi
 189
 190 dnl check for hstrerror, for gst-libs/gst/rtsp
 191 save_libs="$LIBS"
 192 AC_CHECK_FUNC(hstrerror, ,
 193     AC_CHECK_LIB(resolv, hstrerror, ,
 194         [AC_DEFINE(NO_HSTRERROR, 1,
 195              [Define if you have no native hstrerror() function.])]))
 196 HSTRERROR_LIBS=$LIBS
 197 AC_SUBST(HSTRERROR_LIBS)
 198 LIBS="$save_libs"
 199
 200 dnl used in gst-libs/gst/pbutils and associated unit test
 201 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 202
 203 dnl ffmpegcolorspace includes _stdint.h
 204 dnl also, Windows does not have long long
 205 AX_CREATE_STDINT_H
 206
 207 dnl *** checks for functions ***
 208 AC_CHECK_FUNCS([localtime_r gmtime_r])
 209
 210 dnl *** checks for types/defines ***
 211
 212 dnl Check for FIONREAD ioctl declaration
 213 dnl used in gst/tcp
 214 GST_CHECK_FIONREAD
 215
 216 dnl *** checks for structures ***
 217
 218 dnl *** checks for compiler characteristics ***
 219
 220 dnl make sure we can use "inline" from C code
 221 AC_C_INLINE
 222
 223 dnl *** checks for library functions ***
 224
 225 dnl check for fseeko()
 226 AC_FUNC_FSEEKO
 227
 228 dnl Check for fast float to int casting as defined in C99
 229 dnl used in gst-libs/gst/floatcast/floatcast.h
 230 save_libs=$LIBS
 231 LIBS="$LIBS $LIBM"
 232 AC_C99_FUNC_LRINT
 233 AC_C99_FUNC_LRINTF
 234 LIBS=$save_libs
 235
 236 dnl Check for a way to display the function name in debug output
 237 AG_GST_CHECK_FUNCTION
 238
 239 dnl *** checks for socket and nsl libraries ***
 240 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 241 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 242
 243 dnl *** checks for dependency libraries ***
 244
 245 dnl GLib is required
 246 AG_GST_GLIB_CHECK([2.14])
 247
 248 dnl liboil is required
 249 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.14, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 250 if test "x$HAVE_LIBOIL" != "xyes"; then
 251   AC_ERROR([liboil-0.3.14 or later is required])
 252 fi
 253
 254 dnl checks for gstreamer
 255 dnl uninstalled is selected preferentially -- see pkg-config(1)
 256 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 257 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 258 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 259 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 260 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 261 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 262
 263 dnl Check for documentation xrefs
 264 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 265 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 266 AC_SUBST(GLIB_PREFIX)
 267 AC_SUBST(GST_PREFIX)
 268
 269 dnl GTK is optional and only used in examples
 270 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.12.0, HAVE_GTK=yes, HAVE_GTK=no)
 271 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 272
 273 dnl some examples need gtk+-x11
 274 PKG_CHECK_MODULES(GTK_X11, gtk+-x11-2.0 >= 2.12.0,
 275     HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 276 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 277
 278 dnl *** set variables based on configure arguments ***
 279
 280 dnl set license and copyright notice
 281 GST_LICENSE="LGPL"
 282 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 283 AC_SUBST(GST_LICENSE)
 284
 285 dnl set location of plugin directory
 286 AG_GST_SET_PLUGINDIR
 287
 288 dnl define an ERROR_CFLAGS Makefile variable
 289 AG_GST_SET_ERROR_CFLAGS($GST_CVS)
 290
 291 dnl define correct level for debugging messages
 292 AG_GST_SET_LEVEL_DEFAULT($GST_CVS)
 293
 294 dnl used in examples
 295 AG_GST_DEFAULT_ELEMENTS
 296
 297 dnl behaviour of speex based audio resampler
 298 AC_MSG_CHECKING(which audio resample format to use for integer)
 299 AC_ARG_WITH([audioresample_format],
 300         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 301         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 302 AC_MSG_RESULT($ac_cv_audioresample_format)
 303 case $ac_cv_audioresample_format in
 304   int)
 305     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 306     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 307   ;;
 308   float)
 309     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 310     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 311   ;;
 312   auto)
 313     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 314     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 315 esac
 316 AM_CONDITIONAL(AUDIORESAMPLE_NEEDS_LIBOIL, test "$ac_cv_audioresample_format" = "auto")
 317
 318 dnl *** plug-ins to include ***
 319
 320 dnl these are all the gst plug-ins, compilable without additional libs
 321 AG_GST_CHECK_PLUGIN(adder)
 322 AG_GST_CHECK_PLUGIN(app)
 323 AG_GST_CHECK_PLUGIN(audioconvert)
 324 AG_GST_CHECK_PLUGIN(audiorate)
 325 AG_GST_CHECK_PLUGIN(audiotestsrc)
 326 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 327 AG_GST_CHECK_PLUGIN(gdp)
 328 AG_GST_CHECK_PLUGIN(playback)
 329 AG_GST_CHECK_PLUGIN(audioresample)
 330 AG_GST_CHECK_PLUGIN(subparse)
 331 AG_GST_CHECK_PLUGIN(tcp)
 332 AG_GST_CHECK_PLUGIN(typefind)
 333 AG_GST_CHECK_PLUGIN(videotestsrc)
 334 AG_GST_CHECK_PLUGIN(videorate)
 335 AG_GST_CHECK_PLUGIN(videoscale)
 336 AG_GST_CHECK_PLUGIN(volume)
 337
 338 dnl check for gstreamer core features (subsystems)
 339 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 340 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 341 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 342
 343 dnl disable plug-ins that require libxml2's HTML support if it is not available
 344 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 345   AG_GST_DISABLE_PLUGIN(subparse)
 346 fi
 347
 348 dnl disable plug-ins that require sys/socket.h if it is not available
 349 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 350   AG_GST_DISABLE_PLUGIN(tcp)
 351 fi
 352
 353 dnl *** sys plug-ins ***
 354
 355 echo
 356 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 357 echo
 358
 359 dnl *** X11 ***
 360 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 361 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 362                   [ximagesink], [
 363   AC_PATH_XTRA
 364   ac_cflags_save="$CFLAGS"
 365   ac_cppflags_save="$CPPFLAGS"
 366   CFLAGS="$CFLAGS $X_CFLAGS"
 367   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 368
 369   dnl now try to find the HEADER
 370   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 371
 372   if test "x$HAVE_X" = "xno"
 373   then
 374     AC_MSG_NOTICE([cannot find X11 development files])
 375   else
 376     dnl this is much more than we want
 377     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 378     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 379     dnl it does not add the libs; therefore we add them here
 380     X_LIBS="$X_LIBS -lX11"
 381     AC_SUBST(X_CFLAGS)
 382     AC_SUBST(X_LIBS)
 383   fi
 384   AC_SUBST(HAVE_X)
 385   CFLAGS="$ac_cflags_save"
 386   CPPFLAGS="$ac_cppflags_save"
 387 ])
 388
 389 dnl Check for Xv extension
 390 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 391 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 392                   [xvimagesink], [
 393   AG_GST_CHECK_XV
 394 ])
 395
 396 dnl check for X Shm
 397 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 398 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 399   if test x$HAVE_X = xyes; then
 400     AC_CHECK_LIB(Xext, XShmAttach,
 401                  HAVE_XSHM="yes", HAVE_XSHM="no",
 402                  $X_LIBS)
 403     if test "x$HAVE_XSHM" = "xyes"; then
 404       XSHM_LIBS="-lXext"
 405     else
 406       dnl On AIX, it is in XextSam instead, but we still need -lXext
 407       AC_CHECK_LIB(XextSam, XShmAttach,
 408                    HAVE_XSHM="yes", HAVE_XSHM="no",
 409                    $X_LIBS)
 410       if test "x$HAVE_XSHM" = "xyes"; then
 411         XSHM_LIBS="-lXext -lXextSam"
 412       fi
 413     fi
 414   fi
 415 ], , [
 416   AC_SUBST(HAVE_XSHM)
 417   AC_SUBST(XSHM_LIBS)
 418 ])
 419
 420 dnl v4l/v4l2 checks have been moved down because they require X
 421
 422 dnl *** Video 4 Linux ***
 423 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 424 dnl renamed to GST_V4L in accordance with V4L2 below
 425 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 426 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 427   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 428 #include <sys/types.h>
 429 #define _LINUX_TIME_H
 430 #define __user
 431 #include <linux/videodev.h>
 432   ])
 433
 434   dnl we can build v4l without Xv, but then we won't have XOverlay support
 435   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 436   then
 437     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 438     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 439   fi
 440 ])
 441
 442 dnl *** ext plug-ins ***
 443 dnl keep this list sorted alphabetically !
 444
 445 if test "x$BUILD_EXTERNAL" = "xyes"; then
 446
 447 echo
 448 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 449 echo
 450
 451 dnl *** alsa ***
 452 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 453 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 454   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 455     HAVE_ALSA="yes"
 456     AC_SUBST(ALSA_CFLAGS)
 457     AC_SUBST(ALSA_LIBS)
 458   ], [
 459     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 460   ])
 461 ])
 462
 463 dnl *** CDParanoia ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 465 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 466   AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 467                       cdda_open, -lm,
 468                       cdda_interface.h,
 469                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 470                       HEADER_DIR="no"
 471                       FOUND_CDPARANOIA="yes")
 472   if test "x$FOUND_CDPARANOIA" != "xyes";
 473   then
 474     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 475                         cdda_open, -lm,
 476                         cdda/cdda_interface.h,
 477                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 478                         HEADER_DIR="yes"
 479                         FOUND_CDPARANOIA="yes")
 480   fi
 481   if test "x$HEADER_DIR" = "xyes";
 482   then
 483     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 484                        defined if cdda headers are in a cdda/ directory)
 485   fi
 486   AC_SUBST(CDPARANOIA_LIBS)
 487 ])
 488 dnl FIXME : add second check somehow if that is necessary
 489 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 490 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 491
 492 dnl *** GNOME VFS ***
 493 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 494 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 495   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 496       HAVE_GNOME_VFS="yes"
 497       AC_SUBST(GNOME_VFS_CFLAGS)
 498       AC_SUBST(GNOME_VFS_LIBS)
 499       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 500       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 501              [The GnomeVFS modules directory.])
 502     ],[
 503       HAVE_GNOME_VFS="no"
 504     ]
 505     )
 506 ])
 507
 508 dnl *** libgio ***
 509 USE_GIO=$BUILD_EXPERIMENTAL
 510 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 511 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 512   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.15.2, [
 513     HAVE_GIO="yes"
 514     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 515     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 516            [The GIO modules directory.])
 517     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 518     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 519            [The GIO library directory.])
 520   ], [
 521     HAVE_GIO="no"
 522     AC_MSG_RESULT(no)
 523   ])
 524   AC_SUBST(GIO_CFLAGS)
 525   AC_SUBST(GIO_LIBS)
 526   AC_SUBST(GIO_LDFLAGS)
 527 ])
 528
 529 dnl *** libvisual ***
 530 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 531 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 532   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 533   if test $HAVE_LIBVISUAL = no
 534   then
 535     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 536     if test x$HAVE_LIBVISUAL == xyes; then
 537       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 538     fi
 539   else
 540     if test x$HAVE_LIBVISUAL == xyes; then
 541       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 542     fi
 543   fi
 544   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 545   if test x$LIBVIS_PLUGINSDIR != x; then
 546     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 547         "$LIBVIS_PLUGINSDIR",
 548         [directory in which the detected libvisual's plugins are located])
 549   fi
 550 ])
 551
 552 dnl *** ogg ***
 553 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 554 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 555   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 556   if test $HAVE_OGG = no
 557   then
 558     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 559     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 560   fi
 561 ])
 562
 563 dnl *** pango ***
 564 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 565 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 566   AG_GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 567 ])
 568
 569 dnl *** theora ***
 570 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 571 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 572   dnl theora uses pkg-config version incorrectly, for pkg-config:
 573   dnl 1.0 < 1.0RCX < 1.0alphaX < 1.0betaX < 1.0.0
 574   dnl theoraenc and theoradec appeared in 1.0beta3
 575
 576   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec theoraenc)
 577   if test x$HAVE_THEORA = xno; then
 578     AG_GST_PKG_CHECK_MODULES(THEORA, theora >= 1.0alpha5)
 579   fi
 580 ])
 581
 582 dnl *** vorbis ***
 583 dnl AM_PATH_VORBIS only takes two options
 584 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 585 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 586   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 587   if test $HAVE_VORBIS = no
 588   then
 589     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 590     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 591   fi
 592 ])
 593
 594 if test "x$HAVE_VORBIS" = "xyes"; then
 595   ac_cflags_save="$CFLAGS"
 596   AC_COMPILE_IFELSE(
 597     AC_LANG_PROGRAM([
 598 #include <vorbis/codec.h>
 599                      ],[
 600 vorbis_dsp_state *v;
 601
 602 vorbis_synthesis_restart (v);
 603                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 604   if test "x$HAVE_VSR" = "xyes"; then
 605     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 606                        [defined if vorbis_synthesis_restart is present])
 607   fi
 608   CFLAGS="$ac_cflags_save"
 609 fi
 610
 611 else
 612
 613 dnl not building plugins with external dependencies,
 614 dnl but we still need to set the conditionals
 615 AM_CONDITIONAL(USE_ALSA, false)
 616 AM_CONDITIONAL(USE_CDPARANOIA, false)
 617 AM_CONDITIONAL(USE_GNOME_VFS, false)
 618 AM_CONDITIONAL(USE_GIO, false)
 619 AM_CONDITIONAL(USE_LIBVISUAL, false)
 620 AM_CONDITIONAL(USE_OGG, false)
 621 AM_CONDITIONAL(USE_PANGO, false)
 622 AM_CONDITIONAL(USE_THEORA, false)
 623 AM_CONDITIONAL(USE_VORBIS, false)
 624
 625 fi dnl of EXT plugins
 626
 627 dnl seeking needs freetype, so check for it here
 628 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 629   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 630 ])
 631 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 632 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 633 AC_SUBST(FT2_CFLAGS)
 634 AC_SUBST(FT2_LIBS)
 635
 636 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 637
 638 dnl Overview:
 639 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 640 dnl GST_*:              flags shared by built objects to link against GStreamer
 641 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 642 dnl                          (compare to other modules) or for i18n
 643 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 644 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 645 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 646 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 647
 648 dnl GST_OPTION_CFLAGS
 649 if test "x$USE_DEBUG" = xyes; then
 650    PROFILE_CFLAGS="-g"
 651 fi
 652 AC_SUBST(PROFILE_CFLAGS)
 653
 654 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 655   dnl Define _only_ during CVS (not pre-releases or releases)
 656   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 657 else
 658   DEPRECATED_CFLAGS=""
 659 fi
 660 AC_SUBST(DEPRECATED_CFLAGS)
 661
 662 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 663 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 664 AC_SUBST(GST_OPTION_CFLAGS)
 665
 666 dnl our libraries need to be versioned correctly
 667 AC_SUBST(GST_LT_LDFLAGS)
 668
 669 dnl GST_PLUGINS_BASE_CFLAGS
 670 dnl prefer internal headers to already installed ones
 671 dnl also add builddir include for enumtypes and marshal
 672 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 673 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 674
 675 dnl FIXME: do we want to rename to GST_ALL_* ?
 676 dnl add GST_OPTION_CFLAGS, but overridable
 677 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 678 AC_SUBST(GST_CFLAGS)
 679 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 680 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 681 AC_SUBST(GST_LIBS)
 682
 683 dnl LDFLAGS really should only contain flags, not libs - they get added before
 684 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 685 GST_ALL_LDFLAGS="-no-undefined"
 686 AC_SUBST(GST_ALL_LDFLAGS)
 687
 688 dnl GST_LIB_LDFLAGS
 689 dnl linker flags shared by all libraries
 690 dnl LDFLAGS modifier defining exported symbols from built libraries
 691 dnl (export _gst_foo but not __gst_foo)
 692 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 693 AC_SUBST(GST_LIB_LDFLAGS)
 694
 695 dnl this really should only contain flags, not libs - they get added before
 696 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 697 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 698 AC_SUBST(GST_PLUGIN_LDFLAGS)
 699
 700 SHAVE_INIT([common],[enable])
 701
 702 dnl *** output files ***
 703
 704 AC_CONFIG_FILES(
 705 Makefile
 706 common/shave
 707 common/shave-libtool
 708 gst-plugins-base.spec
 709 gst/Makefile
 710 gst/adder/Makefile
 711 gst/app/Makefile
 712 gst/audioconvert/Makefile
 713 gst/audiorate/Makefile
 714 gst/audiotestsrc/Makefile
 715 gst/ffmpegcolorspace/Makefile
 716 gst/gdp/Makefile
 717 gst/playback/Makefile
 718 gst/audioresample/Makefile
 719 gst/subparse/Makefile
 720 gst/tcp/Makefile
 721 gst/typefind/Makefile
 722 gst/videotestsrc/Makefile
 723 gst/videorate/Makefile
 724 gst/videoscale/Makefile
 725 gst/volume/Makefile
 726 sys/Makefile
 727 sys/ximage/Makefile
 728 sys/xvimage/Makefile
 729 sys/v4l/Makefile
 730 ext/Makefile
 731 ext/alsa/Makefile
 732 ext/cdparanoia/Makefile
 733 ext/gnomevfs/Makefile
 734 ext/gio/Makefile
 735 ext/libvisual/Makefile
 736 ext/ogg/Makefile
 737 ext/pango/Makefile
 738 ext/theora/Makefile
 739 ext/vorbis/Makefile
 740 gst-libs/Makefile
 741 gst-libs/gst/Makefile
 742 gst-libs/gst/audio/Makefile
 743 gst-libs/gst/app/Makefile
 744 gst-libs/gst/cdda/Makefile
 745 gst-libs/gst/fft/Makefile
 746 gst-libs/gst/floatcast/Makefile
 747 gst-libs/gst/interfaces/Makefile
 748 gst-libs/gst/netbuffer/Makefile
 749 gst-libs/gst/riff/Makefile
 750 gst-libs/gst/rtp/Makefile
 751 gst-libs/gst/rtsp/Makefile
 752 gst-libs/gst/sdp/Makefile
 753 gst-libs/gst/tag/Makefile
 754 gst-libs/gst/pbutils/Makefile
 755 gst-libs/gst/video/Makefile
 756 tools/Makefile
 757 pkgconfig/Makefile
 758 pkgconfig/gstreamer-audio.pc
 759 pkgconfig/gstreamer-audio-uninstalled.pc
 760 pkgconfig/gstreamer-app.pc
 761 pkgconfig/gstreamer-app-uninstalled.pc
 762 pkgconfig/gstreamer-cdda.pc
 763 pkgconfig/gstreamer-cdda-uninstalled.pc
 764 pkgconfig/gstreamer-fft.pc
 765 pkgconfig/gstreamer-fft-uninstalled.pc
 766 pkgconfig/gstreamer-floatcast.pc
 767 pkgconfig/gstreamer-floatcast-uninstalled.pc
 768 pkgconfig/gstreamer-interfaces.pc
 769 pkgconfig/gstreamer-interfaces-uninstalled.pc
 770 pkgconfig/gstreamer-netbuffer.pc
 771 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 772 pkgconfig/gstreamer-pbutils.pc
 773 pkgconfig/gstreamer-pbutils-uninstalled.pc
 774 pkgconfig/gstreamer-riff.pc
 775 pkgconfig/gstreamer-riff-uninstalled.pc
 776 pkgconfig/gstreamer-rtp.pc
 777 pkgconfig/gstreamer-rtp-uninstalled.pc
 778 pkgconfig/gstreamer-rtsp.pc
 779 pkgconfig/gstreamer-rtsp-uninstalled.pc
 780 pkgconfig/gstreamer-sdp.pc
 781 pkgconfig/gstreamer-sdp-uninstalled.pc
 782 pkgconfig/gstreamer-tag.pc
 783 pkgconfig/gstreamer-tag-uninstalled.pc
 784 pkgconfig/gstreamer-video.pc
 785 pkgconfig/gstreamer-video-uninstalled.pc
 786 pkgconfig/gstreamer-plugins-base.pc
 787 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 788 tests/Makefile
 789 tests/check/Makefile
 790 tests/examples/Makefile
 791 tests/examples/app/Makefile
 792 tests/examples/dynamic/Makefile
 793 tests/examples/seek/Makefile
 794 tests/examples/volume/Makefile
 795 tests/examples/snapshot/Makefile
 796 tests/icles/Makefile
 797 docs/Makefile
 798 docs/design/Makefile
 799 docs/libs/Makefile
 800 docs/plugins/Makefile
 801 docs/version.entities
 802 po/Makefile.in
 803 common/Makefile
 804 common/m4/Makefile
 805 m4/Makefile
 806 )
 807
 808 dnl Create the config.h file for Visual Studio builds
 809 dnl Beware of spaces and /'s in some of the shell variable contents.
 810 sed \
 811     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 812     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 813     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 814     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 815     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 816     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 817     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 818     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 819     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 820     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 821     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 822     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 823     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 824     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 825     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 826     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 827     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 828     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 829     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 830     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 831     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 832     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 833     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 834     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 835     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 836     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 837     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 838     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 839     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 840     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 841     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 842     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 843     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directaudiosink\"/" \
 844     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 845     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 846     config.h.in >win32/common/config.h-new
 847
 848
 849
 850 AC_OUTPUT
 851
 852 AG_GST_OUTPUT_PLUGINS