configure.ac

   1 dnl These m4 macros are whitespace sensitive and break if moved around much.
   2 m4_define([LU_VERSION_H], m4_include([libusb/version.h]))
   3 m4_define([LU_DEFINE_VERSION_ATOM],
   4         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   5         [^#define\s*$1\s*\([0-9]*\).*], [\1]))])
   6 m4_define([LU_DEFINE_VERSION_RC_ATOM],
   7         [m4_define([$1], m4_bregexp(LU_VERSION_H,
   8         [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))])
   9 dnl The m4_bregexp() returns (only) the numbers following the #define named
  10 dnl in the first macro parameter. m4_define() then defines the name for use
  11 dnl in AC_INIT.
  12
  13 LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR])
  14 LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR])
  15 LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO])
  16 LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC])
  17
  18 AC_INIT([libusb],[LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC],[libusb-devel@lists.sourceforge.net],[libusb],[http://libusb.info])
  19
  20 # Library versioning
  21 # These numbers should be tweaked on every release. Read carefully:
  22 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  23 # http://sourceware.org/autobook/autobook/autobook_91.html
  24 lt_current="1"
  25 lt_revision="0"
  26 lt_age="1"
  27 LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}"
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_CONFIG_SRCDIR([libusb/core.c])
  33 AC_CONFIG_MACRO_DIR([m4])
  34 AC_CONFIG_HEADERS([config.h])
  35 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  36
  37 AC_PREREQ([2.50])
  38 AC_PROG_CC
  39 LT_INIT
  40 LT_LANG([Windows Resource])
  41 AC_C_INLINE
  42 AM_PROG_CC_C_O
  43 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  44
  45 LTLDFLAGS="${LTLDFLAGS} -no-undefined"
  46
  47 AC_MSG_CHECKING([operating system])
  48
  49 dnl on linux-android platform, some functions are in different places
  50 case $host in
  51 *-linux-android*)
  52         AC_MSG_RESULT([This is a Linux-Android system])
  53         is_backend_android="yes"
  54         ;;
  55 *)
  56         is_backend_android="no"
  57 esac
  58
  59 case $host in
  60 *-linux* | *-uclinux*)
  61         AC_MSG_RESULT([Linux])
  62         backend="linux"
  63         threads="posix"
  64         ;;
  65 *-darwin*)
  66         AC_MSG_RESULT([Darwin/Mac OS X])
  67         backend="darwin"
  68         threads="posix"
  69         ;;
  70 *-openbsd*)
  71         AC_MSG_RESULT([OpenBSD])
  72         backend="openbsd"
  73         threads="posix"
  74         ;;
  75 *-netbsd*)
  76         AC_MSG_RESULT([NetBSD])
  77         backend="netbsd"
  78         threads="posix"
  79         ;;
  80 *-mingw*)
  81         AC_MSG_RESULT([Windows])
  82         backend="windows"
  83         threads="windows"
  84         create_import_lib="yes"
  85         AM_CFLAGS="${AM_CFLAGS} -fno-omit-frame-pointer"
  86         ;;
  87 *-cygwin*)
  88         AC_MSG_RESULT([Cygwin (using Windows backend)])
  89         backend="windows"
  90         threads="posix"
  91         ;;
  92 *-haiku*)
  93         AC_MSG_RESULT([Haiku])
  94         AC_CONFIG_SUBDIRS([libusb/os/haiku])
  95         backend="haiku"
  96         threads="posix"
  97         ;;
  98 *)
  99         AC_MSG_ERROR([unsupported operating system])
 100 esac
 101
 102 case $backend in
 103 linux)
 104         AC_DEFINE(OS_LINUX, 1, [Linux backend])
 105         AC_SUBST(OS_LINUX)
 106         AC_SEARCH_LIBS(clock_gettime, rt, [], [], -pthread)
 107         AC_ARG_ENABLE([udev],
 108                 [AC_HELP_STRING([--enable-udev], [use udev for device enumeration and hotplug support (recommended) [default=yes]])],
 109                 [], [enable_udev="yes"])
 110                 if test "x$enable_udev" = "xyes" ; then
 111                         # system has udev. use it or fail!
 112                         AC_CHECK_HEADERS([libudev.h],[],[AC_ERROR(["udev support requested but libudev not installed"])])
 113                         AC_CHECK_LIB([udev], [udev_new], [], [AC_ERROR(["udev support requested but libudev not installed"])])
 114                         AC_DEFINE(USE_UDEV, 1, [Use udev for device enumeration/hotplug])
 115                 else
 116                         AC_CHECK_HEADERS([asm/types.h sys/socket.h], [], [])
 117                         AC_CHECK_HEADERS([linux/netlink.h linux/filter.h], [], [AC_ERROR(["Linux netlink headers not found"])], [
 118 #ifdef HAVE_ASM_TYPES_H
 119 #include <asm/types.h>
 120 #endif
 121 #ifdef HAVE_SYS_SOCKET_H
 122 #include <sys/socket.h>
 123 #endif
 124 ])
 125                 fi
 126                 AC_SUBST(USE_UDEV)
 127
 128 case $is_backend_android in
 129 yes)
 130         dnl there are gettimeofday function but configure doesn't seem to be able to find it.
 131         AC_DEFINE([HAVE_GETTIMEOFDAY], [1], [Define if you have gettimeofday])
 132         ;;
 133 *)
 134         THREAD_CFLAGS="-pthread"
 135         LIBS="${LIBS} -pthread"
 136 esac
 137
 138         AC_CHECK_HEADERS([poll.h])
 139         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 140         ;;
 141 darwin)
 142         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
 143         AC_SUBST(OS_DARWIN)
 144         LIBS="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation"
 145         LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind"
 146         AC_CHECK_HEADERS([poll.h])
 147         AC_CHECK_TYPE([nfds_t],
 148                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
 149                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
 150                 [#include <poll.h>])
 151         ;;
 152 openbsd)
 153         AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend])
 154         AC_SUBST(OS_OPENBSD)
 155         THREAD_CFLAGS="-pthread"
 156         LIBS="-pthread"
 157         AC_CHECK_HEADERS([poll.h])
 158         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 159         ;;
 160 netbsd)
 161         AC_DEFINE(OS_NETBSD, 1, [NetBSD backend])
 162         AC_SUBST(OS_NETBSD)
 163         THREAD_CFLAGS="-pthread"
 164         LIBS="-pthread"
 165         AC_CHECK_HEADERS([poll.h])
 166         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 167         ;;
 168 windows)
 169         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
 170         AC_SUBST(OS_WINDOWS)
 171         LIBS=""
 172         LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias"
 173         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
 174         AC_DEFINE([WINVER], 0x0501, [Oldest Windows version supported])
 175         ;;
 176 haiku)
 177         AC_DEFINE(OS_HAIKU, 1, [Haiku backend])
 178         AC_SUBST(OS_HAIKU)
 179         LIBS="${LIBS} -lbe"
 180         AC_CHECK_HEADERS([poll.h])
 181         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
 182         ;;
 183 esac
 184
 185 AC_SUBST(LIBS)
 186
 187 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
 188 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
 189 AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd)
 190 AM_CONDITIONAL(OS_NETBSD, test "x$backend" = xnetbsd)
 191 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
 192 AM_CONDITIONAL(OS_HAIKU, test "x$backend" = xhaiku)
 193 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
 194 AM_CONDITIONAL(CREATE_IMPORT_LIB, test "x$create_import_lib" = "xyes")
 195 AM_CONDITIONAL(USE_UDEV, test "x$enable_udev" = xyes)
 196 if test "$threads" = posix; then
 197         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
 198 fi
 199
 200 # timerfd
 201 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 202 AC_ARG_ENABLE([timerfd],
 203         [AS_HELP_STRING([--enable-timerfd],
 204                 [use timerfd for timing [default=auto]])],
 205         [use_timerfd=$enableval], [use_timerfd='auto'])
 206
 207 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 208         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 209 fi
 210
 211 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 212 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 213         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 214 fi
 215
 216 AC_MSG_CHECKING([whether to use timerfd for timing])
 217 if test "x$use_timerfd" = "xno"; then
 218         AC_MSG_RESULT([no (disabled by user)])
 219 else
 220         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 221                 AC_MSG_RESULT([yes])
 222                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 223         else
 224                 AC_MSG_RESULT([no (header not available)])
 225         fi
 226 fi
 227
 228 AC_CHECK_TYPES(struct timespec)
 229
 230 # Message logging
 231 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 232         [log_enabled=$enableval],
 233         [log_enabled='yes'])
 234 if test "x$log_enabled" != "xno"; then
 235         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 236 fi
 237
 238 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 239         [start with debug message logging enabled [default=no]])],
 240         [debug_log_enabled=$enableval],
 241         [debug_log_enabled='no'])
 242 if test "x$debug_log_enabled" != "xno"; then
 243         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Start with debug message logging enabled])
 244 fi
 245
 246 AC_ARG_ENABLE([system-log], [AS_HELP_STRING([--enable-system-log],
 247         [output logging messages to system wide log, if supported by the OS [default=no]])],
 248         [system_log_enabled=$enableval],
 249         [system_log_enabled='no'])
 250 if test "x$system_log_enabled" != "xno"; then
 251         AC_DEFINE([USE_SYSTEM_LOGGING_FACILITY], 1, [Enable output to system log])
 252 fi
 253
 254 # Check if syslog is available in standard C library
 255 AC_CHECK_HEADERS(syslog.h)
 256 AC_CHECK_FUNC([syslog], [have_syslog=yes], [have_syslog=no])
 257 if test "x$have_syslog" != "xno"; then
 258         AC_DEFINE([HAVE_SYSLOG_FUNC], 1, [syslog() function available])
 259 fi
 260
 261 # Examples build
 262 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 263         [build example applications [default=no]])],
 264         [build_examples=$enableval],
 265         [build_examples='no'])
 266 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 267
 268 # Tests build
 269 AC_ARG_ENABLE([tests-build], [AS_HELP_STRING([--enable-tests-build],
 270         [build test applications [default=no]])],
 271         [build_tests=$enableval],
 272         [build_tests='no'])
 273 AM_CONDITIONAL([BUILD_TESTS], [test "x$build_tests" != "xno"])
 274
 275 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 276 saved_cflags="$CFLAGS"
 277 # -Werror required for cygwin
 278 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 279 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 280         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 281          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 282         [ VISIBILITY_CFLAGS=""
 283          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 284         ])
 285 CFLAGS="$saved_cflags"
 286
 287 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 288 saved_cflags="$CFLAGS"
 289 CFLAGS="$CFLAGS -Wno-pointer-sign"
 290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 291         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 292 CFLAGS="$saved_cflags"
 293
 294 # sigaction not available on MinGW
 295 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 296 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 297
 298 # headers not available on all platforms but required on others
 299 AC_CHECK_HEADERS([sys/time.h])
 300 AC_CHECK_FUNCS(gettimeofday)
 301 AC_CHECK_HEADERS([signal.h])
 302
 303 # check for -std=gnu99 compiler support
 304 saved_cflags="$CFLAGS"
 305 CFLAGS="-std=gnu99"
 306 AC_MSG_CHECKING([whether CC supports -std=gnu99])
 307 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 308     [AC_MSG_RESULT([yes])]
 309     [AM_CFLAGS="${AM_CFLAGS} -std=gnu99"],
 310     [AC_MSG_RESULT([no])]
 311 )
 312 CFLAGS="$saved_cflags"
 313
 314 AM_CFLAGS="${AM_CFLAGS} -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow ${THREAD_CFLAGS} ${VISIBILITY_CFLAGS}"
 315
 316 AC_SUBST(AM_CFLAGS)
 317 AC_SUBST(LTLDFLAGS)
 318
 319 AC_CONFIG_FILES([libusb-1.0.pc])
 320 AC_CONFIG_FILES([Makefile])
 321 AC_CONFIG_FILES([libusb/Makefile])
 322 AC_CONFIG_FILES([examples/Makefile])
 323 AC_CONFIG_FILES([tests/Makefile])
 324 AC_CONFIG_FILES([doc/Makefile])
 325 AC_CONFIG_FILES([doc/doxygen.cfg])
 326 AC_OUTPUT