configure.ac

   1 m4_define([weston_major_version], [4])
   2 m4_define([weston_minor_version], [0])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6 m4_define([libweston_major_version], [5])
   7 m4_define([libweston_minor_version], [0])
   8 m4_define([libweston_patch_version], [0])
   9
  10 AC_PREREQ([2.64])
  11 AC_INIT([weston],
  12         [weston_version],
  13         [https://gitlab.freedesktop.org/wayland/weston/issues/],
  14         [weston],
  15         [https://wayland.freedesktop.org])
  16
  17 WAYLAND_PREREQ_VERSION="1.12.0"
  18
  19 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  20 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  21 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  22 AC_SUBST([WESTON_VERSION], [weston_version])
  23 AC_SUBST([LIBWESTON_MAJOR], [libweston_major_version])
  24 # We use minor as current and age since on ABI/API break/removal we bump major
  25 # so minor will be reset to 0.
  26 m4_define([lt_current], [libweston_minor_version])
  27 m4_define([lt_revision], [libweston_patch_version])
  28 m4_define([lt_age], [libweston_minor_version])
  29 AC_SUBST([LT_VERSION_INFO], [lt_current:lt_revision:lt_age])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_HEADERS([config.h])
  33 AC_CONFIG_MACRO_DIR([m4])
  34
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_SYS_LARGEFILE
  37
  38 save_CFLAGS="$CFLAGS"
  39 export CFLAGS="$CFLAGS -Werror"
  40 AC_HEADER_MAJOR
  41 CFLAGS="$save_CFLAGS"
  42
  43 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests subdir-objects])
  44
  45 AM_SILENT_RULES([yes])
  46
  47 # Check Weston and libweston version consistency
  48 m4_if(m4_cmp(weston_micro_version, [90]), [-1],
  49       [
  50         dnl micro < 90
  51         dnl A final or stable release, not a pre-release:
  52         dnl Weston and libweston versions must match.
  53         m4_if(weston_version, libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  54               [],
  55               [AC_MSG_ERROR([Weston and libweston version mismatch for a final release])])
  56       ],
  57       [
  58         dnl A pre-release:
  59         dnl libweston must be equal or greater than weston.
  60         m4_case(m4_list_cmp([weston_major_version, weston_minor_version, weston_micro_version],
  61                              [libweston_major_version, libweston_minor_version, libweston_patch_version]),
  62                  [-1], [
  63                         dnl weston < libweston
  64                         dnl libweston must be weston_major+1.0.0
  65                         m4_if(m4_eval(weston_major_version+1)[.0.0],
  66                               libweston_major_version[.]libweston_minor_version[.]libweston_patch_version,
  67                               [],
  68                               [AC_MSG_ERROR([libweston version is greater but not (weston_major+1).0.0])])
  69                  ],
  70                  [0], [
  71                         dnl weston == libweston, all ok
  72                  ],
  73                  [1], [
  74                         dnl weston > libweston, wrong
  75                         AC_MSG_ERROR([Weston version is greater than libweston.])
  76                  ])
  77        ])
  78
  79 # Check for programs
  80 AC_PROG_CC
  81 AC_PROG_SED
  82
  83 # Initialize libtool
  84 LT_PREREQ([2.2])
  85 LT_INIT([disable-static])
  86
  87 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  88            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  89 AC_ARG_VAR([WESTON_SHELL_CLIENT],
  90            [Set the default desktop shell client to load if none is specified in weston.ini. @<:@default=weston-desktop-shell@:>@])
  91
  92 PKG_PROG_PKG_CONFIG()
  93
  94 # Check for dlsym instead of dlopen because ASAN hijacks the latter
  95 WESTON_SEARCH_LIBS([DL], [dl], [dlsym])
  96
  97 # In old glibc versions (< 2.17) clock_gettime() and clock_getres() are in librt
  98 WESTON_SEARCH_LIBS([CLOCK_GETTIME], [rt], [clock_gettime])
  99 WESTON_SEARCH_LIBS([CLOCK_GETRES], [rt], [clock_getres])
 100
 101 AC_CHECK_DECL(SFD_CLOEXEC,[],
 102               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
 103               [[#include <sys/signalfd.h>]])
 104 AC_CHECK_DECL(TFD_CLOEXEC,[],
 105               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
 106               [[#include <sys/timerfd.h>]])
 107 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
 108               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
 109               [[#include <time.h>]])
 110 AC_CHECK_HEADERS([execinfo.h])
 111
 112 AC_CHECK_FUNCS([mkostemp strchrnul initgroups posix_fallocate])
 113
 114 # check for libdrm as a build-time dependency only
 115 # libdrm 2.4.30 introduced drm_fourcc.h.
 116 PKG_CHECK_MODULES(LIBDRM, [libdrm >= 2.4.68], [], [AC_MSG_ERROR([
 117      libdrm is a hard build-time dependency for libweston core,
 118      but a sufficient version was not found. However, libdrm
 119      is not a runtime dependency unless you have features
 120      enabled that require it.])])
 121
 122 COMPOSITOR_MODULES="wayland-server >= $WAYLAND_PREREQ_VERSION pixman-1 >= 0.25.2"
 123
 124 AC_CONFIG_FILES([doc/doxygen/tools.doxygen doc/doxygen/tooldev.doxygen])
 125
 126 AC_ARG_ENABLE(devdocs,
 127               AS_HELP_STRING([--disable-devdocs],
 128                              [do not enable building of developer documentation]),,
 129               enable_devdocs=auto)
 130 if test "x$enable_devdocs" != "xno"; then
 131         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 132         if test "x$DOXYGEN" = "x" -a "x$enable_devdocs" = "xyes"; then
 133                 AC_MSG_ERROR([Developer documentation explicitly requested, but Doxygen couldn't be found])
 134         fi
 135         if test "x$DOXYGEN" != "x"; then
 136                 enable_devdocs=yes
 137         else
 138                 enable_devdocs=no
 139         fi
 140 fi
 141 AM_CONDITIONAL(ENABLE_DEVDOCS, test "x$enable_devdocs" = "xyes")
 142
 143 AC_ARG_ENABLE(egl, [  --disable-egl],,
 144               enable_egl=yes)
 145 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
 146 if test x$enable_egl = xyes; then
 147         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
 148         PKG_CHECK_MODULES(EGL, [egl glesv2])
 149         PKG_CHECK_MODULES([EGL_TESTS], [egl glesv2 wayland-client wayland-egl])
 150         AC_CHECK_HEADERS([linux/sync_file.h])
 151 fi
 152
 153 COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon >= 0.3.0"
 154
 155 PKG_CHECK_MODULES(XKBCOMMON_COMPOSE, [xkbcommon >= 0.5.0],
 156                   [AC_DEFINE(HAVE_XKBCOMMON_COMPOSE, 1,
 157                      [Define if xkbcommon is 0.5.0 or newer])],true)
 158
 159 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
 160               enable_setuid_install=yes)
 161 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
 162
 163
 164 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
 165               enable_xwayland=yes)
 166 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
 167               enable_xwayland_test=yes)
 168 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
 169 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
 170 if test x$enable_xwayland = xyes; then
 171   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcb-composite xcb-shape xcursor cairo-xcb)
 172   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
 173
 174   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
 175               [Path to X server]), [XSERVER_PATH="$withval"],
 176               [XSERVER_PATH="/usr/bin/Xwayland"])
 177   AC_SUBST([XSERVER_PATH])
 178   if test x$enable_xwayland_test = xyes; then
 179     PKG_CHECK_MODULES([XWAYLAND_TEST], x11)
 180   fi
 181 fi
 182
 183 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 184               enable_x11_compositor=yes)
 185 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 186 have_xcb_xkb=no
 187 if test x$enable_x11_compositor = xyes; then
 188   PKG_CHECK_MODULES([XCB], xcb >= 1.8)
 189   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 190
 191   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb >= 1.9],
 192                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 193   if test "x$have_xcb_xkb" = xyes; then
 194         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 195         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 196   fi
 197
 198   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 199   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 200 fi
 201
 202
 203 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 204               enable_drm_compositor=yes)
 205 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
 206 if test x$enable_drm_compositor = xyes; then
 207   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 208   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm])
 209   PKG_CHECK_MODULES(DRM_COMPOSITOR_MODIFIERS, [libdrm >= 2.4.71],
 210                     [AC_DEFINE([HAVE_DRM_ADDFB2_MODIFIERS], 1, [libdrm supports modifiers])],
 211                     [AC_MSG_WARN([libdrm does not support AddFB2 with modifiers])])
 212   PKG_CHECK_MODULES(DRM_COMPOSITOR_ATOMIC, [libdrm >= 2.4.78],
 213                     [AC_DEFINE([HAVE_DRM_ATOMIC], 1, [libdrm supports atomic API])],
 214                     [AC_MSG_WARN([libdrm does not support atomic modesetting, will omit that capability])])
 215   PKG_CHECK_MODULES(DRM_COMPOSITOR_GBM, [gbm >= 10.2],
 216                     [AC_DEFINE([HAVE_GBM_FD_IMPORT], 1, [gbm supports dmabuf import])],
 217                     [AC_MSG_WARN([gbm does not support dmabuf import, will omit that capability])])
 218 fi
 219
 220
 221 PKG_CHECK_MODULES(LIBINPUT_BACKEND, [libinput >= 0.8.0])
 222 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
 223
 224 PKG_CHECK_MODULES(WAYLAND_PROTOCOLS, [wayland-protocols >= 1.13],
 225                   [ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`])
 226 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
 227
 228 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 229               enable_wayland_compositor=yes)
 230 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 231                test x$enable_wayland_compositor = xyes)
 232 if test x$enable_wayland_compositor = xyes; then
 233   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 234             [Build the Wayland (nested) compositor])
 235   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client >= $WAYLAND_PREREQ_VERSION wayland-cursor])
 236   if test x$enable_egl = xyes; then
 237     PKG_CHECK_MODULES(WAYLAND_COMPOSITOR_EGL, [wayland-egl])
 238   fi
 239 fi
 240
 241
 242 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 243               enable_headless_compositor=yes)
 244 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 245                test x$enable_headless_compositor = xyes)
 246 if test x$enable_headless_compositor = xyes; then
 247   AC_DEFINE([BUILD_HEADLESS_COMPOSITOR], [1], [Build the headless compositor])
 248 fi
 249
 250
 251 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 252               enable_fbdev_compositor=yes)
 253 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 254                [test x$enable_fbdev_compositor = xyes])
 255 AS_IF([test x$enable_fbdev_compositor = xyes], [
 256   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 257   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136])
 258 ])
 259
 260 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 261               enable_rdp_compositor=no)
 262 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 263                [test x$enable_rdp_compositor = xyes])
 264 if test x$enable_rdp_compositor = xyes; then
 265   AC_DEFINE([BUILD_RDP_COMPOSITOR], [1], [Build the RDP compositor])
 266   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp2 >= 2.0.0],
 267     [],
 268     [PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0],[])]
 269   )
 270   SAVED_CPPFLAGS="$CPPFLAGS"
 271   CPPFLAGS="$CPPFLAGS $RDP_COMPOSITOR_CFLAGS"
 272
 273   AC_CHECK_HEADERS([freerdp/version.h])
 274   AC_CHECK_MEMBER([SURFACE_BITS_COMMAND.bmp],
 275         [AC_DEFINE([HAVE_SURFACE_BITS_BMP], [1], [SURFACE_BITS_CMD has bmp field])],
 276         [],
 277         [[#include <freerdp/update.h>]]
 278   )
 279
 280
 281   CPPFLAGS="$SAVED_CPPFLAGS"
 282 fi
 283
 284 AC_ARG_ENABLE([screen-sharing], [  --enable-screen-sharing],,
 285               enable_screen_sharing=no)
 286 AM_CONDITIONAL([ENABLE_SCREEN_SHARING],
 287                [test x$enable_screen_sharing = xyes])
 288 if test x$enable_screen_sharing = xyes; then
 289   PKG_CHECK_MODULES(SCREEN_SHARE, [wayland-client])
 290
 291   if test x$enable_rdp_compositor != xyes; then
 292     AC_MSG_WARN([The screen-share.so module requires the RDP backend.])
 293   fi
 294 fi
 295
 296 AC_ARG_WITH(cairo,
 297             AS_HELP_STRING([--with-cairo=@<:@image|gl|glesv2@:>@]
 298                            [Which Cairo renderer to use for the clients]),
 299                            [],[with_cairo="image"])
 300
 301 if test "x$with_cairo" = "ximage"; then
 302         cairo_modules="cairo"
 303 else
 304 if test "x$with_cairo" = "xgl"; then
 305         cairo_modules="cairo-gl"
 306         AC_MSG_WARN([The --with-cairo=gl option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 307 else
 308 if test "x$with_cairo" = "xglesv2"; then
 309         cairo_modules="cairo-glesv2"
 310         AC_MSG_WARN([The --with-cairo=gles2 option can cause increased resource usage and potential instability, and thus is not recommended.  It is needed only for a few special demo programs.])
 311 else
 312         AC_ERROR([Unknown cairo renderer requested])
 313 fi
 314 fi
 315 fi
 316
 317 # Included for legacy compat
 318 AC_ARG_WITH(cairo-glesv2,
 319             AS_HELP_STRING([--with-cairo-glesv2],
 320                            [Use GLESv2 cairo]))
 321 if test "x$with_cairo_glesv2" = "xyes"; then
 322   cairo_modules="cairo-glesv2"
 323   with_cairo="glesv2"
 324 fi
 325
 326 if test "x$cairo_modules" = "xcairo-glesv2"; then
 327 AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 328 fi
 329
 330 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 331 PKG_CHECK_MODULES(PNG, [libpng])
 332
 333 AC_ARG_WITH([jpeg],
 334             AS_HELP_STRING([--without-jpeg],
 335                            [Use jpeglib for JPEG decoding support [default=auto]]))
 336 AS_IF([test "x$with_jpeg" != "xno"],
 337       [WESTON_SEARCH_LIBS([JPEG], [jpeg], [jpeg_CreateDecompress], [have_jpeglib=yes], [have_jpeglib=no])],
 338       [have_jpeglib=no])
 339 AS_IF([test "x$have_jpeglib" = "xyes"],
 340       [AC_DEFINE([HAVE_JPEG], [1], [Have jpeglib])],
 341       [AS_IF([test "x$with_jpeg" = "xyes"],
 342              [AC_MSG_ERROR([JPEG support explicitly requested, but jpeglib couldn't be found])])])
 343
 344 AC_ARG_WITH([webp],
 345             AS_HELP_STRING([--without-webp],
 346                            [Use libwebp for WebP decoding support [default=auto]]))
 347 AS_IF([test "x$with_webp" != "xno"],
 348       [PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])],
 349       [have_webp=no])
 350 AS_IF([test "x$have_webp" = "xyes"],
 351       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])],
 352       [AS_IF([test "x$with_webp" = "xyes"],
 353              [AC_MSG_ERROR([WebP support explicitly requested, but libwebp couldn't be found])])])
 354
 355 AC_ARG_ENABLE(vaapi-recorder, [  --enable-vaapi-recorder],,
 356               enable_vaapi_recorder=auto)
 357 have_libva=no
 358 if test x$enable_vaapi_recorder != xno; then
 359   PKG_CHECK_MODULES(LIBVA, [libva >= 0.34.0 libva-drm >= 0.34.0],
 360                     [have_libva=yes], [have_libva=no])
 361   if test "x$have_libva" = "xno" -a "x$enable_vaapi_recorder" = "xyes"; then
 362     AC_MSG_ERROR([vaapi-recorder explicitly enabled, but libva couldn't be found])
 363   fi
 364   AS_IF([test "x$have_libva" = "xyes"],
 365         [AC_DEFINE([BUILD_VAAPI_RECORDER], [1], [Build the vaapi recorder])])
 366 fi
 367 AM_CONDITIONAL(ENABLE_VAAPI_RECORDER, test "x$have_libva" = xyes)
 368
 369 PKG_CHECK_MODULES(CAIRO, [cairo])
 370
 371 PKG_CHECK_MODULES(TEST_CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION pixman-1])
 372
 373 AC_ARG_ENABLE(simple-clients,
 374               AS_HELP_STRING([--disable-simple-clients],
 375                              [do not build the simple wl_shm clients]),,
 376               enable_simple_clients=yes)
 377 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 378 if test x$enable_simple_clients = xyes; then
 379   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 380 fi
 381
 382 AC_ARG_ENABLE(simple-egl-clients,
 383               AS_HELP_STRING([--disable-simple-egl-clients],
 384                              [do not build the simple EGL clients]),,
 385               enable_simple_egl_clients="$enable_egl")
 386 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes")
 387 if test x$enable_simple_egl_clients = xyes; then
 388   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 389                     [egl glesv2 wayland-client wayland-egl wayland-cursor])
 390 fi
 391
 392 AC_ARG_ENABLE(simple-dmabuf-drm-client,
 393               AS_HELP_STRING([--disable-simple-dmabuf-drm-client],
 394                              [do not build the simple dmabuf drm client]),,
 395               enable_simple_dmabuf_drm_client="auto")
 396 if ! test "x$enable_simple_dmabuf_drm_client" = "xno"; then
 397   PKG_CHECK_MODULES(SIMPLE_DMABUF_DRM_CLIENT, [wayland-client libdrm egl], [have_simple_dmabuf_libs=yes],
 398                     [have_simple_dmabuf_libs=no])
 399
 400   PKG_CHECK_MODULES(LIBDRM_PLATFORM_FREEDRENO, [libdrm_freedreno],
 401       AC_DEFINE([HAVE_LIBDRM_FREEDRENO], [1], [Build freedreno dmabuf client]) have_simple_dmabuf_drm_client=yes,
 402       [true])
 403   PKG_CHECK_MODULES(LIBDRM_PLATFORM_INTEL, [libdrm_intel],
 404       AC_DEFINE([HAVE_LIBDRM_INTEL], [1], [Build intel dmabuf client]) have_simple_dmabuf_drm_client=yes,
 405       [true])
 406   PKG_CHECK_MODULES(LIBDRM_PLATFORM_ETNAVIV, [libdrm_etnaviv],
 407       AC_DEFINE([HAVE_LIBDRM_ETNAVIV], [1], [Build etnaviv dmabuf client]) have_simple_dmabuf_drm_client=yes,
 408       [true])
 409
 410   if test "x$have_simple_dmabuf_drm_client" != "xyes" -o \
 411           "x$have_simple_dmabuf_libs" = "xno" && \
 412      test "x$enable_simple_dmabuf_drm_client" = "xyes"; then
 413     AC_MSG_ERROR([DRM dmabuf client explicitly enabled, but none of libdrm_{intel,freedreno,etnaviv} found])
 414   fi
 415
 416   if test "x$have_simple_dmabuf_drm_client" = "xyes" -a "x$have_simple_dmabuf_libs" = "xyes"; then
 417     enable_simple_dmabuf_drm_client="yes"
 418   fi
 419 fi
 420 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_DRM_CLIENT, test "x$enable_simple_dmabuf_drm_client" = "xyes")
 421
 422 AC_ARG_ENABLE(simple-dmabuf-v4l-client,
 423               AS_HELP_STRING([--disable-simple-dmabuf-v4l-client],
 424                              [do not build the simple dmabuf v4l client]),,
 425               enable_simple_dmabuf_v4l_client="auto")
 426 if ! test "x$enable_simple_dmabuf_v4l_client" = "xno"; then
 427   PKG_CHECK_MODULES(SIMPLE_DMABUF_V4L_CLIENT, [wayland-client libdrm],
 428                     have_simple_dmabuf_v4l_client=yes, have_simple_dmabuf_v4l_client=no)
 429   if test "x$have_simple_dmabuf_v4l_client" = "xno" -a "x$enable_simple_dmabuf_v4l_client" = "xyes"; then
 430     AC_MSG_ERROR([V4L dmabuf client explicitly enabled, but libdrm couldn't be found])
 431   fi
 432   enable_simple_dmabuf_v4l_client="$have_simple_dmabuf_v4l_client"
 433 fi
 434 AM_CONDITIONAL(BUILD_SIMPLE_DMABUF_V4L_CLIENT, test "x$enable_simple_dmabuf_v4l_client" = "xyes")
 435
 436 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 437 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 438 have_cairo_egl=no
 439 if test x$enable_clients = xyes; then
 440   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 441
 442   PKG_CHECK_MODULES(CLIENT, [wayland-client >= $WAYLAND_PREREQ_VERSION cairo >= 1.10.0 xkbcommon wayland-cursor])
 443   PKG_CHECK_MODULES(SERVER, [wayland-server])
 444   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client >= $WAYLAND_PREREQ_VERSION])
 445
 446   # Only check for cairo-egl if a GL or GLES renderer requested
 447   AS_IF([test "x$cairo_modules" = "xcairo-gl" -o "x$cairo_modules" = "xcairo-glesv2"], [
 448     PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl cairo-egl >= 1.11.3 $cairo_modules],
 449                       [have_cairo_egl=yes], [have_cairo_egl=no])
 450     AS_IF([test "x$have_cairo_egl" = "xyes"],
 451           [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 452           [AC_ERROR([cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])],
 453   [have_cairo_egl=no])
 454
 455   PKG_CHECK_MODULES(PANGO, [pangocairo pango glib-2.0 >= 2.36], [have_pango=yes], [have_pango=no])
 456 fi
 457
 458 AC_ARG_ENABLE(resize-optimization,
 459               AS_HELP_STRING([--disable-resize-optimization],
 460                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 461               enable_resize_optimization=yes)
 462 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 463       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 464
 465 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 466 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch = xyes)
 467 if test x$enable_weston_launch = xyes; then
 468   WESTON_SEARCH_LIBS([PAM], [pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 469   if test x$have_pam = xno; then
 470     AC_ERROR([weston-launch requires pam])
 471   fi
 472 fi
 473
 474 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 475 if test "x$have_pango" = "xyes"; then
 476   AC_DEFINE([HAVE_PANGO], [1], [Have pango])
 477 fi
 478
 479 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 480                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 481
 482 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 483                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 484
 485 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 486                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 487
 488 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 489
 490 AC_ARG_ENABLE(fullscreen-shell,
 491               AS_HELP_STRING([--disable-fullscreen-shell],
 492                              [do not build fullscreen-shell server plugin]),,
 493               enable_fullscreen_shell=yes)
 494 AM_CONDITIONAL(ENABLE_FULLSCREEN_SHELL,
 495                test "x$enable_fullscreen_shell" = "xyes")
 496
 497 # CMS modules
 498 AC_ARG_ENABLE(colord,
 499               AS_HELP_STRING([--disable-colord],
 500                              [do not build colord CMS support]),,
 501               enable_colord=auto)
 502 have_colord=no
 503 if test "x$enable_colord" != "xno"; then
 504         PKG_CHECK_MODULES(COLORD,
 505                           colord >= 0.1.27,
 506                           have_colord=yes,
 507                           have_colord=no)
 508         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 509           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 510         fi
 511         if test "x$have_colord" = "xyes"; then
 512              enable_colord=yes
 513         fi
 514 fi
 515 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 516
 517 # dbus support
 518 AC_ARG_ENABLE(dbus,
 519               AS_HELP_STRING([--disable-dbus],
 520                              [do not build with dbus support]),,
 521               enable_dbus=auto)
 522 have_dbus=no
 523 if test "x$enable_dbus" != "xno"; then
 524         PKG_CHECK_MODULES(DBUS,
 525                           dbus-1 >= 1.6,
 526                           have_dbus=yes,
 527                           have_dbus=no)
 528         if test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"; then
 529                 AC_MSG_ERROR([dbus support explicitly requested, but libdbus couldn't be found])
 530         fi
 531         if test "x$have_dbus" = "xyes"; then
 532                 enable_dbus=yes
 533                 AC_DEFINE([HAVE_DBUS], [1], [Build with dbus support])
 534         else
 535                 enable_dbus=no
 536         fi
 537 fi
 538 AM_CONDITIONAL(ENABLE_DBUS, test "x$enable_dbus" = "xyes")
 539
 540 # systemd-login support
 541 AC_ARG_ENABLE(systemd-login,
 542               AS_HELP_STRING([--enable-systemd-login],
 543                              [Enable logind support]),,
 544               enable_systemd_login=auto)
 545 if test x$enable_systemd_login != xno -a x$have_dbus != xno; then
 546   PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 547                     [libsystemd >= 209],
 548                     [have_systemd_login_209=yes;have_systemd_login=yes],
 549                     [have_systemd_login_209=no;have_systemd_login=no])
 550
 551   # Older versions of systemd package systemd-login separately. Fall back on that
 552   AS_IF([test x$have_systemd_login != xyes],[
 553         PKG_CHECK_MODULES(SYSTEMD_LOGIN,
 554                           [libsystemd-login >= 198],
 555                           [have_systemd_login=yes],
 556                           [have_systemd_login=no])
 557         ])
 558 else
 559   have_systemd_login=no
 560 fi
 561
 562 if test "x$have_systemd_login" = "xno" -a "x$enable_systemd_login" = "xyes"; then
 563   AC_MSG_ERROR([systemd-login support explicitly enabled, but can't find libsystemd>=209, libsystemd-login or dbus])
 564 fi
 565
 566 AS_IF([test "x$have_systemd_login" = "xyes"],
 567       [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 568 AM_CONDITIONAL(HAVE_SYSTEMD_LOGIN, test "x$have_systemd_login" = "xyes")
 569
 570 AS_IF([test "x$have_systemd_login_209" = "xyes"],
 571       [AC_DEFINE([HAVE_SYSTEMD_LOGIN_209], [1], [Have systemd-login >= 209])])
 572
 573
 574 # Note that other features might want libxml2, or this feature might use
 575 # alternative xml libraries at some point. Therefore the feature and
 576 # pre-requisite concepts are split.
 577 AC_ARG_ENABLE(junit_xml,
 578               AS_HELP_STRING([--disable-junit-xml],
 579                              [do not build with JUnit XML output]),,
 580               enable_junit_xml=auto)
 581 if test "x$enable_junit_xml" != "xno"; then
 582         PKG_CHECK_MODULES(LIBXML2,
 583                           [libxml-2.0 >= 2.6],
 584                           have_libxml2=yes,
 585                           have_libxml2=no)
 586         if test "x$have_libxml2" = "xno" -a "x$enable_junit_xml" = "xyes"; then
 587                 AC_MSG_ERROR([JUnit XML support explicitly requested, but libxml2 couldn't be found])
 588         fi
 589         if test "x$have_libxml2" = "xyes"; then
 590                 enable_junit_xml=yes
 591                 AC_DEFINE(ENABLE_JUNIT_XML, [1], [Build Weston with JUnit output support])
 592         else
 593                 enable_junit_xml=no
 594         fi
 595 fi
 596 AM_CONDITIONAL(ENABLE_JUNIT_XML, test "x$enable_junit_xml" = "xyes")
 597
 598 # ivi-shell support
 599 AC_ARG_ENABLE(ivi-shell,
 600               AS_HELP_STRING([--disable-ivi-shell],
 601                              [do not build ivi-shell server plugin and client]),,
 602               enable_ivi_shell=yes)
 603 AM_CONDITIONAL(ENABLE_IVI_SHELL, test "x$enable_ivi_shell" = "xyes")
 604
 605 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 606 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 607 if test x$enable_wcap_tools = xyes; then
 608   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 609   PKG_CHECK_MODULES(WCAP, [cairo])
 610   WCAP_LIBS="$WCAP_LIBS -lm"
 611 fi
 612
 613 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 614 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 615
 616 if test "x$GCC" = "xyes"; then
 617         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 618                 -Wno-shift-negative-value -Wno-missing-field-initializers \
 619                 -g -fvisibility=hidden \
 620                 -Wstrict-prototypes -Wmissing-prototypes -Wsign-compare"
 621 fi
 622 AC_SUBST(GCC_CFLAGS)
 623
 624
 625 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 626         WESTON_NATIVE_BACKEND="drm-backend.so"
 627 fi
 628 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 629 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 630                    [The default backend to load, if not wayland nor x11.])
 631
 632 if test "x$WESTON_SHELL_CLIENT" = "x"; then
 633         WESTON_SHELL_CLIENT="weston-desktop-shell"
 634 fi
 635 AC_MSG_NOTICE([Weston's default desktop shell client: $WESTON_SHELL_CLIENT])
 636 AC_DEFINE_UNQUOTED([WESTON_SHELL_CLIENT], ["$WESTON_SHELL_CLIENT"],
 637                    [The default desktop shell client to load.])
 638
 639 AC_ARG_ENABLE(demo-clients-install,
 640               AS_HELP_STRING([--enable-demo-clients-install],
 641                              [Install demo clients built with weston]),,
 642                              enable_demo_clients_install=no)
 643 AM_CONDITIONAL(INSTALL_DEMO_CLIENTS, [test "x$enable_demo_clients_install" = "xyes"])
 644
 645 AC_ARG_ENABLE(lcms,
 646               AS_HELP_STRING([--disable-lcms],
 647                              [Disable lcms support]),,
 648               enable_lcms=auto)
 649 have_lcms=no
 650 if test "x$enable_lcms" != "xno"; then
 651         PKG_CHECK_MODULES(LCMS,
 652                           lcms2,
 653                           have_lcms=yes,
 654                           have_lcms=no)
 655         if test "x$have_lcms" = "xno" -a "x$enable_lcms" = "xyes"; then
 656           AC_MSG_ERROR([lcms support explicitly requested, but lcms couldn't be found])
 657         fi
 658         if test "x$have_lcms" = "xyes"; then
 659                 enable_lcms=yes
 660                 AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 661         fi
 662 fi
 663 AM_CONDITIONAL(HAVE_LCMS, [test "x$enable_lcms" = xyes])
 664
 665 AC_PATH_PROG([wayland_scanner], [wayland-scanner])
 666 if test x$wayland_scanner = x; then
 667         PKG_CHECK_MODULES(WAYLAND_SCANNER, [wayland-scanner])
 668         wayland_scanner=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`
 669 fi
 670
 671 AC_ARG_ENABLE(systemd_notify,
 672               AS_HELP_STRING([--enable-systemd-notify],
 673                              [Enables systemd notifications to
 674                               notify systemd about weston state
 675                               and update watchdog.
 676                               Also sockets provided by systemd
 677                               in case of socket-base activation
 678                               are added to wayland display]),,
 679               enable_systemd_notify=no)
 680 AM_CONDITIONAL(SYSTEMD_NOTIFY_SUPPORT, test x$enable_systemd_notify = xyes)
 681 if test "x$enable_systemd_notify" = "xyes"; then
 682   AC_DEFINE([SYSTEMD_NOTIFY_SUPPORT], [1], [Build the systemd sd_notify support])
 683   PKG_CHECK_MODULES(SYSTEMD_DAEMON, [libsystemd])
 684 fi
 685
 686 AC_CONFIG_FILES([Makefile libweston/version.h compositor/weston.pc])
 687
 688 # AC_CONFIG_FILES needs the full name when running autoconf, so we need to use
 689 # libweston_abi_version here, and outside [] because of m4 quoting rules
 690 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[.pc:libweston/libweston.pc.in])
 691 AC_CONFIG_FILES([libweston/libweston-]libweston_major_version[-uninstalled.pc:libweston/libweston-uninstalled.pc.in])
 692 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[.pc:libweston-desktop/libweston-desktop.pc.in])
 693 AC_CONFIG_FILES([libweston-desktop/libweston-desktop-]libweston_major_version[-uninstalled.pc:libweston-desktop/libweston-desktop-uninstalled.pc.in])
 694
 695 AM_CONDITIONAL([HAVE_GIT_REPO], [test -f $srcdir/.git/logs/HEAD])
 696
 697 AC_OUTPUT
 698
 699 AC_MSG_RESULT([
 700         Native Backend                  ${WESTON_NATIVE_BACKEND}
 701         setuid Install                  ${enable_setuid_install}
 702
 703         Cairo Renderer                  ${with_cairo}
 704         EGL                             ${enable_egl}
 705         xcb_xkb                         ${have_xcb_xkb}
 706         XWayland                        ${enable_xwayland}
 707         dbus                            ${enable_dbus}
 708
 709         ivi-shell                       ${enable_ivi_shell}
 710
 711         Build wcap utility              ${enable_wcap_tools}
 712         Build Fullscreen Shell          ${enable_fullscreen_shell}
 713         Enable developer documentation  ${enable_devdocs}
 714
 715         weston-launch utility           ${enable_weston_launch}
 716         systemd-login support           ${have_systemd_login}
 717         systemd notify support          ${enable_systemd_notify}
 718
 719         DRM Compositor                  ${enable_drm_compositor}
 720         X11 Compositor                  ${enable_x11_compositor}
 721         Wayland Compositor              ${enable_wayland_compositor}
 722         Headless Compositor             ${enable_headless_compositor}
 723         FBDEV Compositor                ${enable_fbdev_compositor}
 724         RDP Compositor                  ${enable_rdp_compositor}
 725         Screen Sharing                  ${enable_screen_sharing}
 726         JUnit XML output                ${enable_junit_xml}
 727
 728         Build Clients                   ${enable_clients}
 729         Build EGL Clients               ${have_cairo_egl}
 730         Build Simple Clients            ${enable_simple_clients}
 731         Build Simple EGL Clients        ${enable_simple_egl_clients}
 732
 733         Install Demo Clients            ${enable_demo_clients_install}
 734
 735         Colord Support                  ${have_colord}
 736         LCMS2 Support                   ${have_lcms}
 737         libjpeg Support                 ${have_jpeglib}
 738         libwebp Support                 ${have_webp}
 739         VA H.264 encoding Support       ${have_libva}
 740 ])