configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [0])
   4 m4_define([v_min], [20])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(git rev-list --count HEAD 2>/dev/null || echo 0) | tr -d '\n']))dnl
   7 ##--   When released, remove the dnl on the below line
   8 m4_undefine([v_rev])
   9 m4_define([relname], [0.20.0])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 m4_define([relname], [ver-autocannoli-0.20])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_cur], m4_eval(v_maj + v_min))
  16 m4_define([lt_rev], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([enlightenment], [v_ver], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.52])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27
  28 AC_CONFIG_HEADERS([config.h])
  29 AH_TOP([
  30 #ifndef EFL_CONFIG_H__
  31 #define EFL_CONFIG_H__
  32 ])
  33 AH_BOTTOM([
  34 #endif /* EFL_CONFIG_H__ */
  35 ])
  36
  37 AM_INIT_AUTOMAKE([1.11 dist-xz -Wno-portability])
  38 AM_SILENT_RULES([yes])
  39
  40 AC_USE_SYSTEM_EXTENSIONS
  41 AC_PROG_MKDIR_P
  42 AC_C_BIGENDIAN
  43 AC_PROG_CC_C99
  44 AC_PROG_CXX
  45 AM_PROG_CC_C_O
  46 AC_FUNC_ALLOCA
  47
  48 LT_INIT([disable-static])
  49
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  53 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  54 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  55 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  56 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  57 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  58 AC_DEFINE_UNQUOTED(E_RELEASE_BUILD, [1], [doin it])
  59 version_info="lt_cur:lt_rev:lt_age"
  60 release_info="v_rel"
  61 AC_SUBST([version_info])
  62 AC_SUBST([release_info])
  63 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  64 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  65
  66 AC_ARG_VAR([TIZEN_REL_VERSION], [Tizen release version])
  67 if test x"${TIZEN_REL_VERSION}" != x""; then
  68        AC_DEFINE_UNQUOTED([TIZEN_REL_VERSION], ["${TIZEN_REL_VERSION}"], [Tizen release version])
  69        AC_SUBST(TIZEN_REL_VERSION)
  70 else
  71        echo "TIZEN_REL_VERSION is empty !"
  72 fi
  73
  74 release=relname
  75 AC_SUBST([release])
  76
  77 PKG_PROG_PKG_CONFIG
  78
  79 EFL_CHECK_PATH_MAX
  80
  81 AC_CHECK_FUNCS(setenv)
  82 AC_CHECK_FUNCS(unsetenv)
  83 AC_CHECK_FUNCS(clearenv)
  84 AC_CHECK_HEADERS(features.h)
  85
  86 case "$host_os" in
  87    darwin*)
  88       AC_DEFINE([environ], [(*_NSGetEnviron())],
  89                 ["apple doesn't follow POSIX in this case."])
  90       ;;
  91    *)
  92       ;;
  93 esac
  94 AC_TRY_COMPILE([
  95 #define _GNU_SOURCE 1
  96 #include <unistd.h>
  97     ],[
  98 extern char **environ;
  99     ],[
 100 AC_DEFINE(HAVE_ENVIRON, 1, [Have environ var])
 101     ])
 102
 103 efl_version="1.15.2"
 104 AC_SUBST(efl_version)
 105
 106 AC_CHECK_HEADERS([sys/timerfd.h sys/ptrace.h arpa/inet.h netinet/in.h])
 107
 108 AC_CHECK_HEADERS(fnmatch.h,, AC_MSG_ERROR([Cannot find fnmatch.h. Make sure your CFLAGS environment variable contains include lines for the location of this file]))
 109
 110 AC_CHECK_FUNCS(fnmatch, res=yes, res=no)
 111 if test "x$res" = "xno"; then
 112   AC_CHECK_LIB(fnmatch, fnmatch, res=yes, res=no)
 113   if test "x$res" = "xno"; then
 114     AC_MSG_ERROR([Cannot find fnmatch() in neither libc nor libfnmatch])
 115   else
 116     fnmatch_libs="-lfnmatch"
 117   fi
 118 fi
 119
 120 AC_SUBST([fnmatch_libs])
 121
 122 dnl AC_E_CHECK_PKG(VALGRIND, [valgrind >= 2.4.0], [], [:])
 123 AC_SUBST([VALGRIND_CFLAGS])
 124 AC_SUBST([VALGRIND_LIBS])
 125
 126 MODULE_ARCH="$host_os-$host_cpu-relname"
 127 AC_SUBST([MODULE_ARCH])
 128 AC_DEFINE_UNQUOTED(MODULE_ARCH, "$MODULE_ARCH", "Module architecture")
 129
 130 if test "x${bindir}" = 'xNONE'; then
 131   if test "x${prefix}" = "xNONE"; then
 132     PACKAGE_BIN_DIR="${ac_default_prefix}/bin"
 133   else
 134     PACKAGE_BIN_DIR="${prefix}/bin"
 135   fi
 136 else
 137   PACKAGE_BIN_DIR="${bindir}"
 138 fi
 139 AC_SUBST([PACKAGE_BIN_DIR])
 140
 141 if test "x${libdir}" = 'xNONE'; then
 142   if test "x${prefix}" = "xNONE"; then
 143     PACKAGE_LIB_DIR="${ac_default_prefix}/lib"
 144   else
 145     PACKAGE_LIB_DIR="${prefix}/lib"
 146   fi
 147 else
 148   PACKAGE_LIB_DIR="${libdir}"
 149 fi
 150 AC_SUBST([PACKAGE_LIB_DIR])
 151
 152 if test "x${prefix}" = "xNONE"; then
 153   PACKAGE_DATA_DIR="${ac_default_prefix}/share/${PACKAGE}"
 154   LOCALE_DIR="${ac_default_prefix}/share/locale"
 155   PACKAGE_SYSCONF_DIR="${ac_default_prefix}/etc"
 156 else
 157   PACKAGE_DATA_DIR="${prefix}/share/${PACKAGE}"
 158   LOCALE_DIR="${prefix}/share/locale"
 159   PACKAGE_SYSCONF_DIR="${sysconfdir}"
 160 fi
 161 AC_SUBST([PACKAGE_DATA_DIR])
 162 AC_SUBST([LOCALE_DIR])
 163 AC_SUBST([PACKAGE_SYSCONF_DIR])
 164
 165 cf_cflags=""
 166 cf_libs=""
 167 PCPPFLAGS="${CPPFLAGS}"
 168 CPPFLAGS="${CPPFLAGS} -I /System/Library/Frameworks/CoreFoundation.framework/Headers"
 169 AC_CHECK_HEADERS(CFBase.h,
 170   [
 171     cf_cflags="-I /System/Library/Frameworks/CoreFoundation.framework/Headers"
 172     cf_cflags="${cf_cflags} -I /System/Library/Frameworks/IOKit.framework/Headers"
 173     cf_libs="-framework 'CoreFoundation' -framework 'IOKit'"
 174   ]
 175 )
 176 CPPFLAGS="${PCPPFLAGS}"
 177 AC_SUBST([cf_cflags])
 178 AC_SUBST([cf_libs])
 179
 180 execinfo_libs=""
 181 AC_CHECK_HEADERS([execinfo.h], [have_execinfo="yes"], [have_execinfo="no"])
 182 if test "x${have_execinfo}" = "xyes" ; then
 183   AC_MSG_CHECKING([whether backtrace_symbols_fd() is in libc])
 184
 185   AC_LINK_IFELSE(
 186     [AC_LANG_PROGRAM(
 187       [[
 188 #include <stdlib.h>
 189 #include <execinfo.h>
 190       ]],
 191       [[
 192 backtrace_symbols_fd(NULL, 0, 0);
 193       ]])],
 194     [link_execinfo="yes"],
 195     [link_execinfo="no"])
 196
 197   AC_MSG_RESULT([${link_execinfo}])
 198 fi
 199
 200 if test "x${link_execinfo}" = "xno" ; then
 201   AC_MSG_CHECKING([whether backtrace_symbols_fd() is in libexecinfo])
 202
 203   LDFLAGS_save="${LDFLAGS}"
 204   LDFLAGS="${LDFLAGS} -lexecinfo"
 205   AC_LINK_IFELSE(
 206     [AC_LANG_PROGRAM(
 207       [[
 208 #include <stdlib.h>
 209 #include <execinfo.h>
 210       ]],
 211       [[
 212 backtrace_symbols_fd(NULL, 0, 0);
 213       ]])],
 214     [
 215       link_execinfo="yes"
 216       execinfo_libs="-lexecinfo"
 217     ],
 218     [link_execinfo="no"])
 219   LDFLAGS="${LDFLAGS_save}"
 220
 221   AC_MSG_RESULT([${link_execinfo}])
 222 fi
 223
 224 AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 225 AC_SUBST([dlopen_libs])
 226
 227 AC_MSG_CHECKING([whether to enable Files menu item])
 228 AC_ARG_ENABLE([files],
 229   AS_HELP_STRING([--disable-files],[disable Files menu item @<:@default=enabled@:>@]),
 230     [e_cv_enable_files=$enableval],
 231     AC_CACHE_VAL([e_cv_enable_files], [e_cv_enable_files=yes]))
 232 if test "[${e_cv_enable_files}]" = yes; then
 233   AC_DEFINE_UNQUOTED([ENABLE_FILES],[1],[enable Files menu item])
 234 fi
 235 AC_MSG_RESULT([$e_cv_enable_files])
 236
 237
 238 # verify "wayland-only" early to adapt dependencies
 239
 240 have_wayland_only=no
 241 AC_ARG_ENABLE([wayland],
 242   AS_HELP_STRING([--enable-wayland],[enable wayland support in enlightenment @<:@default=disabled@:>@]),
 243   [e_cv_want_wayland_only=$enableval],
 244   [e_cv_want_wayland_only=no])
 245 AC_MSG_CHECKING([whether wayland support is enabled])
 246 AC_MSG_RESULT([${e_cv_want_wayland_only}])
 247
 248 quick_init=no
 249 AC_ARG_ENABLE([quick-init],
 250   AS_HELP_STRING([--enable-quick-init],[]),
 251   [
 252    quick_init=yes
 253    AC_DEFINE_UNQUOTED([ENABLE_QUICK_INIT], [1], [enable quick init])
 254   ],
 255   [quick_init=no])
 256 AC_MSG_CHECKING([whether enlightenment quick initialization is enabled])
 257 AC_MSG_RESULT([${quick_init}])
 258
 259 function_trace=no
 260 AC_ARG_ENABLE([function-trace],
 261   AS_HELP_STRING([--enable-function-trace],[]),
 262   [
 263    function_trace=yes
 264    AC_DEFINE_UNQUOTED([ENABLE_FUNCTION_TRACE], [1], [enable function trace])
 265   ],
 266   [function_trace=no])
 267 AC_MSG_CHECKING([whether enlightenment function trace is enabled])
 268 AC_MSG_RESULT([${function_trace}])
 269
 270 e_requires="\
 271   evas >= $efl_version \
 272   ecore >= $efl_version \
 273   ecore-evas >= $efl_version \
 274   ecore-input >= $efl_version \
 275   ecore-input-evas >= $efl_version \
 276   ecore-con >= $efl_version \
 277   ecore-ipc >= $efl_version \
 278   ecore-file >= $efl_version \
 279   eet >= $efl_version \
 280   edje >= $efl_version \
 281   eina >= $efl_version \
 282   eldbus >= $efl_version \
 283   eio >= $efl_version \
 284   eo >= $efl_version \
 285   eeze >= $efl_version \
 286   libinput \
 287   libtbm \
 288   libtdm >= "1.0.0" \
 289   "
 290
 291 PKG_CHECK_MODULES(E_INFO, [
 292   eina >= ${efl_version}
 293   ecore >= ${efl_version}
 294   eldbus >= ${efl_version}
 295   xkbcommon
 296   capi-media-streamrecorder
 297   wayland-client
 298 ])
 299
 300 PKG_CHECK_EXISTS([xkeyboard-config],[
 301   xkb_base=`$PKG_CONFIG --variable=xkb_base xkeyboard-config 2>/dev/null`
 302   AC_DEFINE_UNQUOTED([XKB_BASE],["$xkb_base"],[Define to the base directory for X keyboard configuration data])
 303 ])
 304
 305 profile="SLOW_PC"
 306 AC_ARG_WITH(profile,
 307   AS_HELP_STRING([--with-profile=TARGET_PROFILE],
 308   [specify a target format profile of:
 309                                     LOWRES_PDA, MEDIUMRES_PDA, HIRES_PDA, SLOW_PC, MEDIUM_PC, FAST_PC]),
 310   [profile=$withval])
 311 AC_MSG_NOTICE([Enlightenment build profile set to $profile])
 312 EDJE_DEF="-DLOWRES_PDA=1 -DMEDIUMRES_PDA=2 -DHIRES_PDA=3 -DSLOW_PC=4 -DMEDIUM_PC=5 -DFAST_PC=6"
 313 EDJE_DEF=$EDJE_DEF" -DE_PROFILE"=$profile
 314 AC_SUBST([EDJE_DEF])
 315
 316 PKG_CHECK_MODULES(EET, [eet >= ${efl_version}])
 317 EFL_WITH_BIN([edje], [edje-cc], [edje_cc])
 318 EFL_WITH_BIN([eet], [eet-eet], [eet])
 319 EFL_WITH_BIN([eldbus], [eldbus_codegen], [eldbus-codegen])
 320
 321 AC_DEFINE(E_INTERNAL, 1, "This define can be used to wrap internal E stuff, as config.h isn't exported")
 322
 323 have_enotify=no
 324 AM_CONDITIONAL([HAVE_ENOTIFY], [false])
 325 AC_ARG_ENABLE([enotify],
 326   AS_HELP_STRING([--disable-enotify], [disable Enotify support @<:@default=detect@:>@]),
 327   [e_cv_want_enotify=$enableval],
 328   AC_CACHE_VAL([e_cv_want_enotify], [e_cv_want_enotify=yes])
 329 )
 330 if test "x$e_cv_want_enotify" != "xno" ; then
 331   AC_E_CHECK_PKG(ENOTIFY, [ eldbus >= $efl_version ],
 332   [
 333     AC_DEFINE_UNQUOTED([HAVE_ENOTIFY], [1], [enable enotify])
 334   ],
 335   [
 336     AC_MSG_NOTICE([enotify disabled])
 337     e_cv_want_enotify=no
 338   ])
 339 else
 340   AC_MSG_NOTICE([enotify disabled])
 341     e_cv_want_enotify=no
 342 fi
 343 AC_SUBST([ENOTIFY_CFLAGS])
 344 AC_SUBST([ENOTIFY_LIBS])
 345
 346 SHM_OPEN_LIBS=""
 347 AC_MSG_CHECKING([whether shm_open() is present])
 348 LIBS_save=${LIBS}
 349 LIBS="${LIBS} -lrt"
 350 AC_LINK_IFELSE(
 351    [AC_LANG_PROGRAM(
 352       [[
 353 #include <sys/stat.h>
 354 #include <sys/mman.h>
 355 #include <fcntl.h>
 356       ]],
 357       [[
 358 int fd;
 359 fd = shm_open("/", O_RDWR | O_CREAT, S_IRUSR |
 360 S_IWUSR);
 361 shm_unlink("/");
 362       ]])],
 363    [
 364     have_shm_open="yes"
 365     AC_DEFINE(HAVE_SHM_OPEN, 1, [Have shm_open() call])
 366     SHM_OPEN_LIBS="-lrt"
 367    ])
 368 LIBS=${LIBS_save}
 369 AC_MSG_RESULT([${have_shm_open}])
 370 AC_SUBST(SHM_OPEN_LIBS)
 371
 372 if test "x${e_cv_want_wayland_only}" != "xno" || test "x${e_cv_want_wayland_clients}" != "xno";then
 373   PKG_CHECK_MODULES([WAYLAND], [wayland-server >= 1.8.0 xkbcommon uuid xdg-shell-unstable-v5-server xdg-shell-unstable-v6-server tizen-remote-surface-server scaler-server screenshooter-server tizen-extension-server tizen-launch-server tizen-surface-server tizen-dpms-server eom-server presentation-time-server tizen-hwc-server linux-explicit-synchronization-unstable-v1-server wtz-foreign-server wtz-screen-server wtz-shell-server],
 374     [
 375       have_wayland=yes
 376       AC_DEFINE_UNQUOTED([HAVE_WAYLAND],[1],[enable wayland support])
 377     ])
 378 else
 379   have_wayland=no
 380 fi
 381
 382 if test "x${have_wayland}" = "xyes"; then
 383   if test "x${e_cv_want_wayland_only}" != "xno"; then
 384     have_wayland_only=yes
 385     AC_DEFINE_UNQUOTED([HAVE_WAYLAND_ONLY],[1],[enable wayland-only version of enlightenment])
 386   fi
 387
 388   have_wayland_tbm=no
 389   AC_ARG_ENABLE([wayland-tbm],
 390     AS_HELP_STRING([--enable-wayland-tbm],[enable wayland-tbm @<:@default=enabled@:>@]),
 391     [e_cv_want_wayland_tbm=$enableval],
 392     [e_cv_want_wayland_tbm=yes])
 393   AC_MSG_CHECKING([whether wayland TBM support is enabled])
 394   AC_MSG_RESULT([${e_cv_want_wayland_tbm}])
 395
 396   if test "x$e_cv_want_wayland_tbm" != "xno";then
 397     PKG_CHECK_MODULES([WAYLAND_TBM], [wayland-tbm-server],
 398       [
 399         have_wayland_tbm=yes
 400         AC_DEFINE_UNQUOTED([HAVE_WAYLAND_TBM],[1],[enable wayland-tbm support])
 401       ])
 402   else
 403     have_wayland_tbm=no
 404   fi
 405
 406   have_hwc=no
 407   AC_ARG_ENABLE([hwc],
 408     AS_HELP_STRING([--enable-hwc],[enable hwc @<:@default=enabled@:>@]),
 409     [e_cv_want_hwc=$enableval],
 410     [e_cv_want_hwc=yes])
 411   AC_MSG_CHECKING([whether HWC support is enabled])
 412   AC_MSG_RESULT([${e_cv_want_hwc}])
 413
 414   if test "x$e_cv_want_hwc" != "xno";then
 415     PKG_CHECK_MODULES([HWC], [gbm],
 416       [
 417         have_hwc=yes
 418         AC_DEFINE_UNQUOTED([HAVE_HWC],[1],[enable hwc support])
 419       ])
 420   else
 421     have_hwc=no
 422   fi
 423 fi
 424
 425 # does this compiler support -fopenmp, does it have the include file
 426 # <omp.h> and does it have libgomp ?
 427
 428 AC_MSG_CHECKING([for OpenMP])
 429
 430 safe_CFLAGS=$CFLAGS
 431 CFLAGS="-fopenmp $mflag_primary -Werror"
 432
 433 AC_LINK_IFELSE([AC_LANG_SOURCE([
 434 #include <omp.h>
 435 int main(int argc, char** argv)
 436 {
 437   omp_set_dynamic(0);
 438   return 0;
 439 }
 440 ])],
 441 [
 442    have_libgomp=yes
 443    AC_MSG_RESULT([yes])
 444 ], [
 445    have_libgomp=no
 446    AC_MSG_RESULT([no])
 447 ])
 448 CFLAGS=$safe_CFLAGS
 449
 450 if test "x$have_libgomp" != "xno"; then
 451 AC_DEFINE([HAVE_LIBGOMP], [1], [Enable libgomp])
 452    have_libgomp=yes
 453 else
 454 AC_DEFINE([HAVE_LIBGOMP], [0], [Disable libgomp])
 455    have_libgomp=no
 456 fi
 457 AM_CONDITIONAL([HAVE_LIBGOMP], [test "x${have_libgomp}" = "xyes"])
 458
 459 # Check for ttrace header files
 460 PKG_CHECK_MODULES(TTRACE,
 461                 [ttrace],
 462                 [have_ttrace="yes"], [have_ttrace="no"])
 463
 464 if test "x$have_ttrace" = "xyes"; then
 465         AC_DEFINE(ENABLE_TTRACE, 1, [ttrace available])
 466 fi
 467
 468 # dlog
 469 PKG_CHECK_EXISTS([dlog], [have_dlog="yes"], [have_dlog="no"])
 470 AC_MSG_CHECKING([Have dlog logger])
 471 AC_MSG_RESULT([${have_dlog}])
 472 if test "x${have_dlog}" = "xyes"; then
 473     AC_DEFINE([HAVE_DLOG], [1], [Define to 1 if you have dlog])
 474     PKG_CHECK_MODULES(DLOG, dlog)
 475 fi
 476
 477 AM_CONDITIONAL([HAVE_DLOG], [test "x${have_dlog}" = "xyes"])
 478
 479 AM_CONDITIONAL([HAVE_WAYLAND], [test "x${have_wayland}" = "xyes"])
 480 AM_CONDITIONAL([HAVE_WAYLAND_TBM], [test "x${have_wayland_tbm}" = "xyes"])
 481 AM_CONDITIONAL([HAVE_HWC], [test "x${have_hwc}" = "xyes"])
 482
 483 #pixman
 484 PKG_CHECK_MODULES([PIXMAN], [pixman-1])
 485
 486 #egl
 487 PKG_CHECK_MODULES([EGL], [egl])
 488
 489 # Check for systemd
 490 want_systemd="yes"
 491 AC_ARG_ENABLE([systemd],
 492   [AS_HELP_STRING([--disable-systemd], [disable systemd @<:@default=enabled@:>@])],
 493   [
 494     if test "x${enableval}" = "xyes"; then
 495       want_systemd="yes"
 496     else
 497       want_systemd="no"
 498     fi
 499   ])
 500 AC_MSG_CHECKING([whether systemd is enabled])
 501 AC_MSG_RESULT([${want_systemd}])
 502
 503 have_systemd="no"
 504 if test "x$want_systemd" = "xyes"; then
 505   PKG_CHECK_MODULES([SYSTEMD], [libsystemd >= 209],
 506     [
 507       have_systemd="yes"
 508       AC_DEFINE_UNQUOTED([HAVE_SYSTEMD], [1], [enable systemd support])
 509     ])
 510 else
 511   have_systemd="no"
 512 fi
 513
 514 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x${have_systemd}" = "xyes"])
 515
 516 #libinput
 517 PKG_CHECK_MODULES([LIBINPUT], [libinput])
 518
 519 have_extra_touch_event="no"
 520 AC_CHECK_LIB(input, libinput_event_touch_get_major, [have_extra_touch_event="yes"])
 521 if test "x${have_extra_touch_event}" = "xyes";then
 522 AC_DEFINE_UNQUOTED([LIBINPUT_SUPPORT_EXTRA_TOUCH_EVENT], [1], [libinput support extra touch event])
 523 fi
 524
 525 have_scroll_value_v120="no"
 526 AC_CHECK_LIB(input, libinput_event_pointer_get_scroll_value_v120, [have_scroll_value_v120="yes"])
 527 if test "x${have_scroll_value_v120}" = "xyes";then
 528 AC_DEFINE_UNQUOTED([LIBINPUT_HAVE_SCROLL_VALUE_V120], [1], [libinput have get_scroll_value_v120])
 529 fi
 530
 531 #capi-system-device
 532 PKG_CHECK_MODULES([CAPI_SYSTEM_DEVICE],
 533                   [capi-system-device])
 534 #cynara
 535 PKG_CHECK_MODULES(CYNARA,
 536                   [cynara-client, cynara-creds-socket, cynara-session, libsmack],
 537                   [have_cynara="yes"], [have_cynara="no"])
 538 if test "x${have_cynara}" = "xyes"; then
 539     AC_DEFINE([HAVE_CYNARA], [1], [Define to 1 if you have cynara])
 540 fi
 541
 542 #tzsh-server
 543 PKG_CHECK_MODULES(TZSH,
 544                   [tzsh-server],
 545                   [have_tzsh="yes"])
 546
 547 #gmock
 548 PKG_CHECK_MODULES(GMOCK,
 549                   [gmock],
 550                   [have_gmock]="yes")
 551
 552 POLICY_CFLAGS="${CAPI_SYSTEM_DEVICE_CFLAGS} ${CYNARA_CFLAGS} ${TZSH_CFLAGS}"
 553 POLICY_LIBS="${CAPI_SYSTEM_DEVICE_LIBS} ${CYNARA_LIBS} ${TZSH_LIBS}"
 554 AC_SUBST(POLICY_CFLAGS)
 555 AC_SUBST(POLICY_LIBS)
 556
 557 define([CHECK_MODULE_BUFFERQUEUE],
 558 [
 559   if test "x${have_wayland_clients}" = "xyes" || test "x${e_cv_want_wayland_only}" = "xyes"; then
 560     AC_E_CHECK_PKG(BUFFERQUEUE, [ ecore >= $efl_version eina >= $efl_version ], [BUFFERQUEUE=true], [BUFFERQUEUE=false])
 561   else
 562     BUFFERQUEUE=false
 563   fi
 564 ])
 565 AM_CONDITIONAL([HAVE_BUFFERQUEUE], [test "x${BUFFERQUEUE}" = "xtrue"])
 566
 567 AC_E_OPTIONAL_MODULE([bufferqueue], $have_wayland, [CHECK_MODULE_BUFFERQUEUE])
 568
 569 if test "x${have_wayland}" = "xyes"; then
 570   AC_DEFINE_UNQUOTED([HAVE_WAYLAND_ONLY],[1],[enable wayland-only version of enlightenment])
 571   have_wayland_only=yes
 572 else
 573   have_wayland_only=no
 574 fi
 575
 576 AM_CONDITIONAL([HAVE_WAYLAND_ONLY], [test "x${have_wayland_only}" = "xyes"])
 577
 578 PKG_CHECK_MODULES(E, [$e_requires])
 579 requirements_e="\
 580 evas >= ${efl_version} \
 581 ecore >= ${efl_version} \
 582 ecore-evas >= ${efl_version} \
 583 ecore-con >= ${efl_version} \
 584 ecore-ipc >= ${efl_version} \
 585 ecore-file >= ${efl_version} \
 586 eet >= ${efl_version} \
 587 edje >= ${efl_version} \
 588 eina >= ${efl_version} \
 589 eldbus >= ${efl_version} \
 590 eio >= ${efl_version} \
 591 eo >= ${efl_version} \
 592 eeze >= ${efl_version} \
 593 "
 594
 595 e_libs="$E_LIBS $fnmatch_libs $execinfo_libs $DLOG_LIBS"
 596 e_cflags="-DUSE_E_CONFIG_H $E_CFLAGS -D_F_ZONE_WINDOW_ROTATION_ -D_F_E_VIRTUAL_KEYBOARD_TYPE_ -D_F_E_CLIENT_NEW_CLIENT_POST_HOOK_ -D_F_E_COMP_OBJECT_INTERCEPT_HOOK_ -D_F_TRANSIENT_FOR_PATCH -D_F_DISABLE_BACKLIGHT_MOD_SUPPORT $DLOG_CFLAGS"
 597 e_configflags="-DUSE_E_CONFIG_H -D_F_ZONE_WINDOW_ROTATION_ -D_F_E_VIRTUAL_KEYBOARD_TYPE_ -D_F_E_CLIENT_NEW_CLIENT_POST_HOOK_ -D_F_E_COMP_OBJECT_INTERCEPT_HOOK_ -D_F_TRANSIENT_FOR_PATCH -D_F_DISABLE_BACKLIGHT_MOD_SUPPORT"
 598
 599 AC_SUBST([e_libs])
 600 AC_SUBST([e_cflags])
 601 AC_SUBST([e_configflags])
 602 AC_SUBST([requirements_e])
 603
 604 m4_ifndef([v_rel],
 605    [
 606     EFL_COMPILER_FLAG([-Wshadow])
 607     EFL_COMPILER_FLAG([-Wall])
 608     EFL_COMPILER_FLAG([-Wpointer-arith])
 609     EFL_COMPILER_FLAG([-W])
 610     EFL_COMPILER_FLAG([-Wno-missing-field-initializers])
 611     EFL_COMPILER_FLAG([-Wfloat-equal])
 612     EFL_COMPILER_FLAG([-Wuninitialized])
 613     EFL_COMPILER_FLAG([-Wundef])
 614     EFL_COMPILER_FLAG([-Wcast-align])
 615     EFL_COMPILER_FLAG([-Wformat=2])
 616    ])
 617
 618 SUID_CFLAGS=-fPIE
 619 SUID_LDFLAGS=-pie
 620 case "$host_os" in
 621    freebsd*|pcbsd*)
 622       SUID_CFLAGS=
 623       SUID_LDFLAGS=
 624       ;;
 625 esac
 626 AC_SUBST([SUID_CFLAGS])
 627 AC_SUBST([SUID_LDFLAGS])
 628
 629 AC_OUTPUT([
 630 Makefile
 631 tests/Makefile
 632 enlightenment.pc
 633 ])
 634
 635 # report
 636 txt_strip() {
 637   echo "[$]@" | sed -e 's/^[[ \t]]*\([[^ \t]]*\)[[ \t]]*$/\1/g'
 638 }
 639
 640 echo
 641 cat << SUMMARY_EOF
 642 Summary:
 643  * project.........: $PACKAGE $VERSION
 644  * prefix..........: $(txt_strip $prefix)
 645  * CFLAGS..........: $(txt_strip $CFLAGS)
 646  * LDFLAGS.........: $(txt_strip $LDFLAGS)
 647  * edje_cc.........: ${edje_cc}
 648  * eet.............: ${eet_eet}
 649  * eldbus-codegen..: ${eldbus_codegen}
 650 SUMMARY_EOF
 651
 652 echo
 653
 654 UNUSED_MODS=""
 655 for mod in $UNUSED_OPTIONAL_MODULES; do
 656   UNUSED_MODS="$UNUSED_MODS${COLOR_HRED}$mod${COLOR_END} "
 657 done
 658
 659 cat << MODULES_EOF
 660 Modules:
 661  * disabled........: $(txt_strip $UNUSED_MODS)
 662 MODULES_EOF
 663 echo
 664
 665 cat << COMPILE_EOF
 666 Compilation........: make (or gmake)
 667 COMPILE_EOF
 668 echo
 669
 670 cat << INSTALL_EOF
 671 Installation.......: make all install (as root if needed, with 'su' or 'sudo')
 672 INSTALL_EOF
 673 echo