configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([weston],
   3         [0.95.0],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=weston],
   5         [weston],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16 AC_PROG_CXX
  17 AC_PROG_SED
  18
  19 # Initialize libtool
  20 LT_PREREQ([2.2])
  21 LT_INIT([disable-static])
  22
  23 PKG_PROG_PKG_CONFIG()
  24
  25 AC_CHECK_FUNC([dlopen], [],
  26               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  27 AC_SUBST(DLOPEN_LIBS)
  28
  29 AC_CHECK_HEADERS([execinfo.h])
  30
  31 AC_CHECK_FUNCS([mkostemp strchrnul])
  32
  33 PKG_CHECK_MODULES(COMPOSITOR,
  34                   [wayland-server egl >= 7.10 glesv2 xkbcommon pixman-1])
  35
  36
  37 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  38               enable_setuid_install=yes)
  39 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  40
  41
  42 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  43               enable_xwayland=yes)
  44 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  45 if test x$enable_xwayland = xyes; then
  46   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  47   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  48
  49   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  50               [Path to X server]), [XSERVER_PATH="$withval"],
  51               [XSERVER_PATH="$bindir/Xorg"])
  52   AC_SUBST([XSERVER_PATH])
  53 fi
  54
  55
  56 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  57               enable_x11_compositor=yes)
  58 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
  59 if test x$enable_x11_compositor = xyes; then
  60   PKG_CHECK_MODULES([XCB], xcb)
  61   xcb_save_LIBS=$LIBS
  62   xcb_save_CFLAGS=$CFLAGS
  63   CFLAGS=$XCB_CFLAGS
  64   LIBS=$XCB_LIBS
  65   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  66   LIBS=$xcb_save_LIBS
  67   CFLAGS=$xcb_save_CFLAGS
  68
  69   X11_COMPOSITOR_MODULES="x11 x11-xcb"
  70
  71   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
  72                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
  73   if test "x$have_xcb_xkb" = xyes; then
  74         # Most versions of XCB have totally broken XKB bindings, where the
  75         # events don't work.  Make sure we can actually use them.
  76         xcb_xkb_save_CFLAGS=$CFLAGS
  77         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
  78         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
  79                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
  80         CFLAGS=$xcb_xkb_save_CFLAGS
  81   fi
  82   if test "x$have_xcb_xkb" = xyes; then
  83         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
  84         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
  85   fi
  86
  87   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
  88   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
  89 fi
  90
  91
  92 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
  93               enable_drm_compositor=yes)
  94 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes)
  95 if test x$enable_drm_compositor = xyes; then
  96   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
  97   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
  98 fi
  99
 100
 101 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 102               enable_wayland_compositor=yes)
 103 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 104                test x$enable_wayland_compositor = xyes)
 105 if test x$enable_wayland_compositor = xyes; then
 106   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 107             [Build the Wayland (nested) compositor])
 108   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 109 fi
 110
 111
 112 AC_ARG_ENABLE(android-compositor,
 113               AS_HELP_STRING([--disable-android-compositor],
 114                              [do not build-test the Android 4.0 backend]),,
 115               enable_android_compositor=yes)
 116 AM_CONDITIONAL(ENABLE_ANDROID_COMPOSITOR, test x$enable_android_compositor = xyes)
 117 if test x$enable_android_compositor = xyes; then
 118   AC_DEFINE([BUILD_ANDROID_COMPOSITOR], [1], [Build the compositor for Android 4.0])
 119   PKG_CHECK_MODULES(ANDROID_COMPOSITOR, [mtdev >= 1.1.0])
 120 fi
 121
 122
 123 AC_ARG_WITH(cairo-glesv2, AS_HELP_STRING([--with-cairo-glesv2],
 124               [Use GLESv2 cairo instead of full GL]),
 125               [cairo_modules="cairo-glesv2"],
 126               [cairo_modules="cairo-gl"])
 127 if test x$cairo_modules = xcairo-glesv2; then
 128   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 129 fi
 130
 131 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 132 PKG_CHECK_MODULES(PNG, [libpng])
 133 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 134 AS_IF([test "x$have_webp" = "xyes"],
 135       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 136
 137 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 138 if test x$have_jpeglib = xyes; then
 139   IMAGE_LIBS="$IMAGE_LIBS -ljpeg"
 140 else
 141   AC_ERROR([libjpeg not found])
 142 fi
 143
 144 PKG_CHECK_MODULES(CAIRO, [cairo])
 145 SHARED_LIBS="$CAIRO_LIBS $PIXMAN_LIBS $PNG_LIBS $WEBP_LIBS $IMAGE_LIBS"
 146 SHARED_CFLAGS="$CAIRO_CFLAGS $PIXMAN_CFLAGS $PNG_CFLAGS $WEBP_CFLAGS"
 147 AC_SUBST(SHARED_LIBS)
 148 AC_SUBST(SHARED_CFLAGS)
 149
 150 COMPOSITOR_LIBS="$COMPOSITOR_LIBS $IMAGE_LIBS"
 151 COMPOSITOR_CFLAGS="$COMPOSITOR_CFLAGS $IMAGE_CFLAGS"
 152
 153 AC_ARG_ENABLE(simple-clients, [  --enable-simple-clients],, enable_simple_clients=yes)
 154 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test x$enable_simple_clients = xyes)
 155 if test x$enable_simple_clients = xyes; then
 156   AC_DEFINE([BUILD_SIMPLE_CLIENTS], [1], [Build the Wayland simple clients])
 157   PKG_CHECK_MODULES(SIMPLE_CLIENT,
 158                     [egl >= 7.10 glesv2 wayland-client wayland-egl])
 159 fi
 160
 161 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 162 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 163 if test x$enable_clients = xyes; then
 164   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 165
 166   PKG_CHECK_MODULES(CLIENT, [wayland-client wayland-egl egl >= 7.10 cairo >= 1.10.0 xkbcommon wayland-cursor])
 167   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 168
 169   CLIENT_CFLAGS="$CLIENT_CFLAGS $IMAGE_CFLAGS"
 170   CLIENT_LIBS="$CLIENT_LIBS $IMAGE_LIBS"
 171
 172   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 173                              [have_poppler=yes], [have_poppler=no])
 174   PKG_CHECK_MODULES(CAIRO_EGL, [cairo-egl >= 1.11.3 $cairo_modules],
 175                     [have_cairo_egl=yes], [have_cairo_egl=no])
 176   AS_IF([test "x$have_cairo_egl" = "xyes"],
 177         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 178         [AC_MSG_WARN([Cairo-EGL not found - clients will use cairo image])])
 179 fi
 180
 181 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 182 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 183 if test x$enable_weston_launch == xyes; then
 184   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 185   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 186                     [have_systemd_login=yes], [have_systemd_login=no])
 187   AS_IF([test "x$have_systemd_login" = "xyes"],
 188         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 189
 190   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 191   if test x$have_pam == xno; then
 192     AC_ERROR([weston-launch requires pam])
 193   fi
 194   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 195 fi
 196
 197 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 198
 199 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 200                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes")
 201
 202 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 203
 204 AC_ARG_ENABLE(tablet-shell, [  --enable-tablet-shell],,
 205               enable_tablet_shell=yes)
 206 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 207                test x$enable_tablet_shell = xyes)
 208
 209
 210 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 211 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 212 if test x$enable_wcap_tools = xyes; then
 213   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 214   PKG_CHECK_MODULES(WCAP, [cairo])
 215   WCAP_LIBS="$WCAP_LIBS -lm"
 216 fi
 217
 218 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 219 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 220
 221 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 222 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 223
 224 if test "x$GCC" = "xyes"; then
 225         my_common_gcc_flags="-Wall -Wextra -Wno-unused-parameter \
 226                 -Wno-missing-field-initializers -g -fvisibility=hidden"
 227         GCC_CFLAGS="$my_common_gcc_flags \
 228                 -Wstrict-prototypes -Wmissing-prototypes"
 229         GCC_CXXFLAGS="$my_common_gcc_flags"
 230 fi
 231 AC_SUBST(GCC_CFLAGS)
 232 AC_SUBST(GCC_CXXFLAGS)
 233
 234 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 235
 236 AC_CONFIG_FILES([Makefile
 237                  shared/Makefile
 238                  src/Makefile
 239                  src/xwayland/Makefile
 240                  clients/Makefile
 241                  wcap/Makefile
 242                  data/Makefile
 243                  protocol/Makefile
 244                  man/Makefile
 245                  tests/Makefile])
 246 AC_OUTPUT