configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.63)
   4
   5 AC_INIT([libffi], [3.0.10rc0], [http://gcc.gnu.org/bugs.html])
   6 AC_CONFIG_HEADERS([fficonfig.h])
   7
   8 AC_CANONICAL_SYSTEM
   9 target_alias=${target_alias-$host_alias}
  10
  11 . ${srcdir}/configure.host
  12
  13 AM_INIT_AUTOMAKE
  14
  15 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  16 # We must force CC to /not/ be precious variables; otherwise
  17 # the wrong, non-multilib-adjusted value will be used in multilibs.
  18 # As a side effect, we have to subst CFLAGS ourselves.
  19 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
  20 # defaults of its own if none are provided.
  21
  22 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  23 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  24 save_CFLAGS=$CFLAGS
  25 AC_PROG_CC
  26 CFLAGS=$save_CFLAGS
  27 m4_undefine([_AC_ARG_VAR_PRECIOUS])
  28 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  29
  30 AC_SUBST(CFLAGS)
  31
  32 AM_PROG_AS
  33 AM_PROG_CC_C_O
  34 AC_PROG_LIBTOOL
  35 AC_CONFIG_MACRO_DIR([m4])
  36
  37 AM_MAINTAINER_MODE
  38
  39 AC_CHECK_HEADERS(sys/mman.h)
  40 AC_CHECK_FUNCS(mmap)
  41 AC_FUNC_MMAP_BLACKLIST
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 TARGETDIR="unknown"
  47 case "$host" in
  48   alpha*-*-*)
  49         TARGET=ALPHA; TARGETDIR=alpha;
  50         # Support 128-bit long double, changeable via command-line switch.
  51         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  52         ;;
  53
  54   arm*-*-*)
  55         TARGET=ARM; TARGETDIR=arm
  56         ;;
  57
  58   amd64-*-freebsd* | amd64-*-openbsd*)
  59         TARGET=X86_64; TARGETDIR=x86
  60         ;;
  61
  62   amd64-*-freebsd*)
  63         TARGET=X86_64; TARGETDIR=x86
  64         ;;
  65
  66   avr32*-*-*)
  67         TARGET=AVR32; TARGETDIR=avr32
  68         ;;
  69
  70   cris-*-*)
  71         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  72         ;;
  73
  74   frv-*-*)
  75         TARGET=FRV; TARGETDIR=frv
  76         ;;
  77
  78   hppa*-*-linux* | parisc*-*-linux*)
  79         TARGET=PA_LINUX; TARGETDIR=pa
  80         ;;
  81   hppa*64-*-hpux*)
  82         TARGET=PA64_HPUX; TARGETDIR=pa
  83         ;;
  84   hppa*-*-hpux*)
  85         TARGET=PA_HPUX; TARGETDIR=pa
  86         ;;
  87
  88   i?86-*-freebsd* | i?86-*-openbsd*)
  89         TARGET=X86_FREEBSD; TARGETDIR=x86
  90         ;;
  91   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw* | i?86-*-os2*)
  92         TARGET=X86_WIN32; TARGETDIR=x86
  93         # All mingw/cygwin/win32 builds require this for sharedlib
  94         AM_LTLDFLAGS="-no-undefined"
  95         ;;
  96   i?86-*-darwin*)
  97         TARGET=X86_DARWIN; TARGETDIR=x86
  98         ;;
  99   i?86-*-solaris2.1[[0-9]]*)
 100         TARGET=X86_64; TARGETDIR=x86
 101         ;;
 102   i?86-*-*)
 103         TARGET=X86; TARGETDIR=x86
 104         ;;
 105
 106   ia64*-*-*)
 107         TARGET=IA64; TARGETDIR=ia64
 108         ;;
 109
 110   m32r*-*-*)
 111         TARGET=M32R; TARGETDIR=m32r
 112         ;;
 113
 114   m68k-*-*)
 115         TARGET=M68K; TARGETDIR=m68k
 116         ;;
 117
 118   mips-sgi-irix5.* | mips-sgi-irix6.*)
 119         TARGET=MIPS; TARGETDIR=mips
 120         ;;
 121   mips*-*-linux*)
 122         # Support 128-bit long double for NewABI.
 123         HAVE_LONG_DOUBLE='defined(__mips64)'
 124         TARGET=MIPS; TARGETDIR=mips
 125         ;;
 126
 127   powerpc*-*-linux* | powerpc-*-sysv*)
 128         TARGET=POWERPC; TARGETDIR=powerpc
 129         ;;
 130   powerpc-*-beos*)
 131         TARGET=POWERPC; TARGETDIR=powerpc
 132         ;;
 133   powerpc-*-darwin*)
 134         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 135         ;;
 136   powerpc-*-aix* | rs6000-*-aix*)
 137         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 138         ;;
 139   powerpc-*-freebsd*)
 140         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 141         ;;
 142  powerpc64-*-freebsd*)
 143         TARGET=POWERPC; TARGETDIR=powerpc
 144         ;;
 145   powerpc*-*-rtems*)
 146         TARGET=POWERPC; TARGETDIR=powerpc
 147         ;;
 148
 149   s390-*-* | s390x-*-*)
 150         TARGET=S390; TARGETDIR=s390
 151         ;;
 152
 153   sh-*-* | sh[[34]]*-*-*)
 154         TARGET=SH; TARGETDIR=sh
 155         ;;
 156   sh64-*-* | sh5*-*-*)
 157         TARGET=SH64; TARGETDIR=sh64
 158         ;;
 159
 160   sparc*-*-*)
 161         TARGET=SPARC; TARGETDIR=sparc
 162         ;;
 163
 164   x86_64-*-darwin*)
 165         TARGET=X86_DARWIN; TARGETDIR=x86
 166         ;;
 167
 168   x86_64-*-cygwin* | x86_64-*-mingw*)
 169         TARGET=X86_WIN64; TARGETDIR=x86
 170         ;;
 171
 172   x86_64-*-*)
 173         TARGET=X86_64; TARGETDIR=x86
 174         ;;
 175 esac
 176
 177 AC_SUBST(AM_RUNTESTFLAGS)
 178 AC_SUBST(AM_LTLDFLAGS)
 179
 180 if test $TARGETDIR = unknown; then
 181   AC_MSG_ERROR(["libffi has not been ported to $host."])
 182 fi
 183
 184 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 185 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 186 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 187 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 188 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 189 AM_CONDITIONAL(X86_WIN64, test x$TARGET = xX86_WIN64)
 190 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 191 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 192 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 193 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 194 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 195 AM_CONDITIONAL(MOXIE, test x$TARGET = xMOXIE)
 196 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 197 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 198 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 199 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 200 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 201 AM_CONDITIONAL(AVR32, test x$TARGET = xAVR32)
 202 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 203 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 204 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 205 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 206 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 207 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 208 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 209 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 210 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 211
 212 AC_HEADER_STDC
 213 AC_CHECK_FUNCS(memcpy)
 214 AC_FUNC_ALLOCA
 215
 216 AC_CHECK_SIZEOF(double)
 217 AC_CHECK_SIZEOF(long double)
 218
 219 # Also AC_SUBST this variable for ffi.h.
 220 if test -z "$HAVE_LONG_DOUBLE"; then
 221   HAVE_LONG_DOUBLE=0
 222   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 223     if test $ac_cv_sizeof_long_double != 0; then
 224       HAVE_LONG_DOUBLE=1
 225       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 226     fi
 227   fi
 228 fi
 229 AC_SUBST(HAVE_LONG_DOUBLE)
 230
 231 AC_C_BIGENDIAN
 232
 233 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 234     libffi_cv_as_cfi_pseudo_op, [
 235     libffi_cv_as_cfi_pseudo_op=unknown
 236     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 237                    [libffi_cv_as_cfi_pseudo_op=yes],
 238                    [libffi_cv_as_cfi_pseudo_op=no])
 239 ])
 240 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 241     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 242               [Define if your assembler supports .cfi_* directives.])
 243 fi
 244
 245 if test x$TARGET = xSPARC; then
 246     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 247         libffi_cv_as_sparc_ua_pcrel, [
 248         save_CFLAGS="$CFLAGS"
 249         save_LDFLAGS="$LDFLAGS"
 250         CFLAGS="$CFLAGS -fpic"
 251         LDFLAGS="$LDFLAGS -shared"
 252         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 253                     [libffi_cv_as_sparc_ua_pcrel=yes],
 254                     [libffi_cv_as_sparc_ua_pcrel=no])
 255         CFLAGS="$save_CFLAGS"
 256         LDFLAGS="$save_LDFLAGS"])
 257     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 258         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 259                   [Define if your assembler and linker support unaligned PC relative relocs.])
 260     fi
 261
 262     AC_CACHE_CHECK([assembler .register pseudo-op support],
 263        libffi_cv_as_register_pseudo_op, [
 264        libffi_cv_as_register_pseudo_op=unknown
 265        # Check if we have .register
 266        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 267                        [libffi_cv_as_register_pseudo_op=yes],
 268                        [libffi_cv_as_register_pseudo_op=no])
 269     ])
 270     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 271        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 272                [Define if your assembler supports .register.])
 273     fi
 274 fi
 275
 276 if test x$TARGET = xX86 || test x$TARGET = xX86_WIN32 || test x$TARGET = xX86_64; then
 277     AC_CACHE_CHECK([assembler supports pc related relocs],
 278         libffi_cv_as_x86_pcrel, [
 279         libffi_cv_as_x86_pcrel=yes
 280         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 281         if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 282             libffi_cv_as_x86_pcrel=no
 283         fi
 284         ])
 285     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 286         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 287                   [Define if your assembler supports PC relative relocs.])
 288     fi
 289
 290     AC_CACHE_CHECK([assembler .ascii pseudo-op support],
 291        libffi_cv_as_ascii_pseudo_op, [
 292        libffi_cv_as_ascii_pseudo_op=unknown
 293        # Check if we have .ascii
 294        AC_TRY_COMPILE([asm (".ascii \"string\"");],,
 295                        [libffi_cv_as_ascii_pseudo_op=yes],
 296                        [libffi_cv_as_ascii_pseudo_op=no])
 297     ])
 298     if test "x$libffi_cv_as_ascii_pseudo_op" = xyes; then
 299        AC_DEFINE(HAVE_AS_ASCII_PSEUDO_OP, 1,
 300                [Define if your assembler supports .ascii.])
 301     fi
 302
 303     AC_CACHE_CHECK([assembler .string pseudo-op support],
 304        libffi_cv_as_string_pseudo_op, [
 305        libffi_cv_as_string_pseudo_op=unknown
 306        # Check if we have .string
 307        AC_TRY_COMPILE([asm (".string \"string\"");],,
 308                        [libffi_cv_as_string_pseudo_op=yes],
 309                        [libffi_cv_as_string_pseudo_op=no])
 310     ])
 311     if test "x$libffi_cv_as_string_pseudo_op" = xyes; then
 312        AC_DEFINE(HAVE_AS_STRING_PSEUDO_OP, 1,
 313                [Define if your assembler supports .string.])
 314     fi
 315 fi
 316
 317 case "$target" in
 318      *-apple-darwin10* | *-*-freebsd* | *-*-openbsd* | *-pc-solaris*)
 319        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 320                  [Cannot use malloc on this target, so, we revert to
 321                    alternative means])
 322      ;;
 323 esac
 324
 325 if test x$TARGET = xX86_64; then
 326     AC_CACHE_CHECK([assembler supports unwind section type],
 327         libffi_cv_as_x86_64_unwind_section_type, [
 328         libffi_cv_as_x86_64_unwind_section_type=yes
 329         echo '.section .eh_frame,"a",@unwind' > conftest.s
 330         if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 331             libffi_cv_as_x86_64_unwind_section_type=no
 332         fi
 333         ])
 334     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 335         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 336                   [Define if your assembler supports unwind section type.])
 337     fi
 338 fi
 339
 340 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 341     libffi_cv_ro_eh_frame, [
 342         libffi_cv_ro_eh_frame=no
 343         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 344         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 345             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 346                 libffi_cv_ro_eh_frame=yes
 347             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 348                  | grep -v '#write' > /dev/null; then
 349                 libffi_cv_ro_eh_frame=yes
 350             fi
 351         fi
 352         rm -f conftest.*
 353     ])
 354 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 355     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 356               [Define if .eh_frame sections should be read-only.])
 357     AC_DEFINE(EH_FRAME_FLAGS, "a",
 358               [Define to the flags needed for the .section .eh_frame directive.])
 359 else
 360     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 361               [Define to the flags needed for the .section .eh_frame directive.])
 362 fi
 363
 364 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 365     libffi_cv_hidden_visibility_attribute, [
 366         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 367         libffi_cv_hidden_visibility_attribute=no
 368         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 369             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 370                 libffi_cv_hidden_visibility_attribute=yes
 371             fi
 372         fi
 373         rm -f conftest.*
 374     ])
 375 if test $libffi_cv_hidden_visibility_attribute = yes; then
 376     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 377               [Define if __attribute__((visibility("hidden"))) is supported.])
 378 fi
 379
 380 AH_BOTTOM([
 381 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 382 #ifdef LIBFFI_ASM
 383 #define FFI_HIDDEN(name) .hidden name
 384 #else
 385 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 386 #endif
 387 #else
 388 #ifdef LIBFFI_ASM
 389 #define FFI_HIDDEN(name)
 390 #else
 391 #define FFI_HIDDEN
 392 #endif
 393 #endif
 394 ])
 395
 396 AC_SUBST(TARGET)
 397 AC_SUBST(TARGETDIR)
 398
 399 AC_SUBST(SHELL)
 400
 401 AC_ARG_ENABLE(debug,
 402 [  --enable-debug          debugging mode],
 403   if test "$enable_debug" = "yes"; then
 404     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 405   fi)
 406 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 407
 408 AC_ARG_ENABLE(structs,
 409 [  --disable-structs       omit code for struct support],
 410   if test "$enable_structs" = "no"; then
 411     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 412   fi)
 413
 414 AC_ARG_ENABLE(raw-api,
 415 [  --disable-raw-api       make the raw api unavailable],
 416   if test "$enable_raw_api" = "no"; then
 417     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 418   fi)
 419
 420 AC_ARG_ENABLE(purify-safety,
 421 [  --enable-purify-safety  purify-safe mode],
 422   if test "$enable_purify_safety" = "yes"; then
 423     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 424   fi)
 425
 426 if test -n "$with_cross_host" &&
 427    test x"$with_cross_host" != x"no"; then
 428   toolexecdir='$(exec_prefix)/$(target_alias)'
 429   toolexeclibdir='$(toolexecdir)/lib'
 430 else
 431   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 432   toolexeclibdir='$(libdir)'
 433 fi
 434 multi_os_directory=`$CC -print-multi-os-directory`
 435 case $multi_os_directory in
 436   .) ;; # Avoid trailing /.
 437   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 438 esac
 439 AC_SUBST(toolexecdir)
 440 AC_SUBST(toolexeclibdir)
 441
 442 if test "${multilib}" = "yes"; then
 443   multilib_arg="--enable-multilib"
 444 else
 445   multilib_arg=
 446 fi
 447
 448 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 449 AC_CONFIG_COMMANDS(src, [
 450 test -d src || mkdir src
 451 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 452 ], [TARGETDIR="$TARGETDIR"])
 453
 454 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 455
 456 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
 457
 458 AC_OUTPUT