configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[mzchyfrnhqvb (at) 0pointer (dot) net],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules dist-xz tar-ustar])
  30
  31 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  32 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  33
  34 AC_SUBST(PA_MAJOR, pa_major)
  35 AC_SUBST(PA_MINOR, pa_minor)
  36 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 23)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [13:5:13])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # CC
  77
  78 AC_PROG_CC
  79 AC_PROG_CC_C99
  80 AM_PROG_CC_C_O
  81 AC_PROG_GCC_TRADITIONAL
  82 AC_USE_SYSTEM_EXTENSIONS
  83
  84 # M4
  85
  86 AC_CHECK_PROGS([M4], gm4 m4, no)
  87 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  88
  89 # pkg-config
  90
  91 PKG_PROG_PKG_CONFIG
  92
  93 # gettext
  94
  95 IT_PROG_INTLTOOL([0.35.0])
  96 GETTEXT_PACKAGE=pulseaudio
  97 AC_SUBST([GETTEXT_PACKAGE])
  98 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
  99 AM_GLIB_GNU_GETTEXT
 100
 101 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 102 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 103
 104
 105 #### Determine host OS ####
 106
 107 os_is_linux=0
 108 os_is_win32=0
 109 os_is_darwin=0
 110
 111 AC_MSG_CHECKING([host operating system])
 112 case "$host_os" in
 113     linux*)
 114         AC_MSG_RESULT([linux])
 115         os_is_linux=1
 116     ;;
 117     darwin*)
 118         AC_MSG_RESULT([darwin])
 119         os_is_darwin=1
 120         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 121     ;;
 122     mingw*)
 123         AC_MSG_RESULT([win32])
 124         os_is_win32=1
 125         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 126     ;;
 127     *)
 128         AC_MSG_RESULT([unknown])
 129     ;;
 130 esac
 131
 132 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 135
 136 # Platform specific hacks
 137 case "$host_os" in
 138     darwin* )
 139         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 140     ;;
 141     mingw* )
 142         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 143     ;;
 144     solaris* )
 145         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 146         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 147     ;;
 148 esac
 149
 150
 151 #### Compiler flags ####
 152
 153 AX_APPEND_COMPILE_FLAGS(
 154     [-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 155     [], [-pedantic -Werror])
 156
 157
 158 #### Linker flags ####
 159
 160 # Check whether the linker supports the -version-script option.
 161 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 162 # so that it is expanded the right way in every subdir.
 163 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 164     [VERSIONING_LDFLAGS='-Wl,-version-script=$(srcdir)/map-file'])
 165 AC_SUBST([VERSIONING_LDFLAGS])
 166
 167 # Use immediate (now) bindings; avoids the funky re-call in itself.
 168 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 169 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 170 AC_SUBST([IMMEDIATE_LDFLAGS])
 171
 172 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 173 # so we request the nodelete flag to be enabled.
 174 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 175 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 176 AC_SUBST([NODELETE_LDFLAGS])
 177
 178 # Check for the proper way to build libraries that have no undefined symbols
 179 case $host in
 180     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 181     # are requested, as different implementations are present.
 182     *-freebsd* | *-openbsd*) ;;
 183     *)
 184         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 185             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 186         done
 187     ;;
 188 esac
 189 AC_SUBST([NOUNDEFINED_LDFLAGS])
 190
 191
 192 #### Atomic operations ####
 193
 194 # Native atomic operation support
 195 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 196     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 197
 198 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 199     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 200
 201 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 202     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 203 fi
 204
 205 # If everything else fails use libatomic_ops
 206 need_libatomic_ops=yes
 207
 208 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 209     pulseaudio_cv_sync_bool_compare_and_swap, [
 210     AC_LINK_IFELSE(
 211         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 212         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 213         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 214     ])
 215
 216 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 217     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 218     need_libatomic_ops=no
 219 else
 220     # HW specific atomic ops stuff
 221     AC_MSG_CHECKING([architecture for native atomic operations])
 222     case $host in
 223         arm*)
 224             AC_MSG_RESULT([arm])
 225             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 226             # The Linux kernel helper functions have been there since 2.6.16. However
 227             # compile time checking for kernel version in cross compile environment
 228             # (which is usually the case for arm cpu) is tricky (or impossible).
 229             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 230                 AC_MSG_RESULT([yes])
 231                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 232                 need_libatomic_ops=no
 233             else
 234                 AC_MSG_RESULT([no])
 235                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 236                     pulseaudio_cv_support_arm_atomic_ops, [
 237                     AC_COMPILE_IFELSE(
 238                         AC_LANG_PROGRAM([], [[
 239                             volatile int a=0;
 240                             int o=0, n=1, r;
 241                             asm volatile ("ldrex    %0, [%1]\n"
 242                                           "subs  %0, %0, %2\n"
 243                                           "strexeq %0, %3, [%1]\n"
 244                                           : "=&r" (r)
 245                                           : "r" (&a), "Ir" (o), "r" (n)
 246                                           : "cc");
 247                             return (a==1 ? 0 : -1);
 248                         ]]),
 249                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 250                         [pulseaudio_cv_support_arm_atomic_ops=no])
 251                 ])
 252                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 253                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 254                     need_libatomic_ops=no
 255                 ])
 256             fi
 257         ;;
 258         *-netbsdelf5*)
 259             AC_MSG_RESULT([yes])
 260             need_libatomic_ops=no
 261         ;;
 262         *-freebsd*)
 263             AC_MSG_RESULT([yes])
 264             need_libatomic_ops=no
 265         ;;
 266         *)
 267             AC_MSG_RESULT([unknown])
 268         ;;
 269     esac
 270 fi
 271
 272 # If we're on ARM, check for the ARMV6 instructions we need */
 273 case $host in
 274   arm*)
 275     AC_CACHE_CHECK([support for required armv6 instructions],
 276       pulseaudio_cv_support_armv6,
 277       [AC_COMPILE_IFELSE(
 278          AC_LANG_PROGRAM([],
 279            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 280              asm volatile ("ldr r0, %2 \n"
 281                            "ldr r2, %3 \n"
 282                            "ldr r3, %4 \n"
 283                            "ssat r1, #8, r0 \n"
 284                            "str r1, %0 \n"
 285                            "pkhbt r1, r3, r2, LSL #8 \n"
 286                            "str r1, %1 \n"
 287                            : "=m" (a), "=m" (b)
 288                            : "m" (a), "m" (b), "m" (c)
 289                            : "r0", "r1", "r2", "r3", "cc");
 290              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 291            ]]),
 292          [pulseaudio_cv_support_armv6=yes],
 293          [pulseaudio_cv_support_armv6=no])
 294       ])
 295     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 296         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 297       ])
 298   ;;
 299   *)
 300   ;;
 301 esac
 302
 303
 304 #### libtool stuff ####
 305
 306 LT_PREREQ(2.2)
 307 LT_INIT([dlopen win32-dll disable-static])
 308
 309 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
 310 dnl exactly which version of libltdl is present in the system, so we
 311 dnl just assume that it's a working version as long as we have the
 312 dnl library and the header files.
 313 dnl
 314 dnl As an extra safety device, check for lt_dladvise_init() which is
 315 dnl only implemented in libtool 2.x, and refine as we go if we have
 316 dnl refined requirements.
 317 dnl
 318 dnl Check the header files first since the system may have a
 319 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 320 dnl soon as possible.
 321 dnl
 322 dnl We don't need any special variable for this though, since the user
 323 dnl can give the proper place to find libltdl through the standard
 324 dnl variables like LDFLAGS and CPPFLAGS.
 325
 326 AC_CHECK_HEADER([ltdl.h],
 327     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 328     [LIBLTDL=])
 329
 330 AS_IF([test "x$LIBLTDL" = "x"],
 331     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
 332 AC_SUBST([LIBLTDL])
 333
 334
 335 ###################################
 336 #   Basic environment checks      #
 337 ###################################
 338
 339 #### Checks for header files. ####
 340
 341 # ISO
 342 AC_HEADER_STDC
 343
 344 # POSIX
 345 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 346     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 347     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 348     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 349 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 350                  [#include <sys/types.h>
 351                   #if HAVE_NETINET_IN_H
 352                   # include <netinet/in.h>
 353                   #endif
 354                   #if HAVE_NETINET_IN_SYSTM_H
 355                   # include <netinet/in_systm.h>
 356                   #endif
 357                  ])
 358 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 359 AC_SUBST(HAVE_SYS_RESOURCE_H)
 360 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 361 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 362 AC_SUBST(HAVE_AF_UNIX)
 363
 364 # Linux
 365 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 366 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 367
 368 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 369
 370 # Solaris
 371 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 372
 373 # Windows
 374 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 375
 376 # NetBSD
 377 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 378
 379 # Other
 380 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 381 AC_CHECK_HEADERS_ONCE([byteswap.h])
 382 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 383 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 384 AC_CHECK_HEADERS_ONCE([execinfo.h])
 385 AC_CHECK_HEADERS_ONCE([langinfo.h])
 386 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 387
 388
 389 #### Typdefs, structures, etc. ####
 390
 391 AC_C_CONST
 392 AC_C_BIGENDIAN
 393 AC_TYPE_PID_T
 394 AC_TYPE_SIZE_T
 395 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 396 AC_TYPE_OFF_T
 397
 398 AC_TYPE_UID_T
 399 AC_CHECK_DECLS(environ)
 400
 401 # SIGXCPU
 402 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 403 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 404 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 405
 406 # INADDR_NONE, Solaris lacks this
 407 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 408     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 409         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 410
 411
 412 # _Bool
 413 AC_CACHE_CHECK([whether $CC knows _Bool],
 414     pulseaudio_cv__Bool,
 415     [AC_COMPILE_IFELSE(
 416         AC_LANG_PROGRAM([], [[_Bool b;]]),
 417         [pulseaudio_cv__Bool=yes],
 418         [pulseaudio_cv__Bool=no])
 419     ])
 420
 421 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 422
 423
 424 #### Thread support ####
 425
 426 AX_TLS
 427 AS_IF([test "$ac_cv_tls" == "__thread"],
 428     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 429
 430 # Win32 build breaks with win32 pthread installed
 431 AS_IF([test "x$os_is_win32" != "x1"],
 432   [AX_PTHREAD])
 433
 434 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 435     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 436
 437
 438 #### Check for libs ####
 439
 440 # ISO
 441 AC_SEARCH_LIBS([pow], [m])
 442
 443 # POSIX
 444 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 445 AC_SEARCH_LIBS([dlopen], [dl])
 446 AC_SEARCH_LIBS([shm_open], [rt])
 447 AC_SEARCH_LIBS([inet_ntop], [nsl])
 448 AC_SEARCH_LIBS([timer_create], [rt])
 449 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 450 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 451 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 452
 453 # BSD
 454 AC_SEARCH_LIBS([connect], [socket])
 455 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 456
 457 # Darwin/OS X
 458 if test "x$os_is_darwin" = "x1" ; then
 459     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 460     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 461     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 462         [LIBS="$LIBS -framework CoreServices"],
 463         [AC_MSG_ERROR([CoreServices.h header file not found])]
 464     )
 465
 466     AC_MSG_RESULT([ok])
 467     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 468     HAVE_BONJOUR=1
 469 fi
 470
 471 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 472
 473 # Windows
 474 AC_SEARCH_LIBS([regexec], [pcreposix])
 475 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 476 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 477
 478
 479 #### Check for functions ####
 480
 481 # ISO
 482 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 483
 484 # POSIX
 485 AC_FUNC_FORK
 486 AC_FUNC_GETGROUPS
 487 AC_FUNC_SELECT_ARGTYPES
 488 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 489     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 490     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 491     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 492 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 493 AC_SUBST(HAVE_MKFIFO)
 494 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 495
 496 # X/OPEN
 497 AC_CHECK_FUNCS_ONCE([readlink])
 498
 499 # SUSv2
 500 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 501
 502 # SUSv3
 503 AC_CHECK_FUNCS_ONCE([strerror_r])
 504
 505 # BSD
 506 AC_CHECK_FUNCS_ONCE([lstat])
 507
 508 # Non-standard
 509 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 510
 511 AC_FUNC_ALLOCA
 512
 513 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 514 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 515
 516 # Large File-Support (LFS)
 517 AC_SYS_LARGEFILE
 518 # Check for open64 to know if the current system does have open64() and similar functions
 519 AC_CHECK_FUNCS_ONCE([open64])
 520
 521
 522 ###################################
 523 #      External libraries         #
 524 ###################################
 525
 526 #### [lib]iconv ####
 527
 528 AM_ICONV
 529
 530 #### X11 (optional) ####
 531
 532 AC_ARG_ENABLE([x11],
 533     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 534
 535 AS_IF([test "x$enable_x11" != "xno"],
 536     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 537     HAVE_X11=0)
 538
 539 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 540     [AC_MSG_ERROR([*** X11 not found])])
 541
 542 AC_SUBST(X11_CFLAGS)
 543 AC_SUBST(X11_LIBS)
 544 AC_SUBST(HAVE_X11)
 545 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 546 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 547
 548 #### Capabilities (optional) ####
 549
 550 CAP_LIBS=''
 551
 552 AC_ARG_WITH([caps],
 553     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 554
 555 if test "x${with_caps}" != "xno"; then
 556     AC_SEARCH_LIBS([cap_init], [cap], [], [
 557                     if test "x${with_caps}" = "xyes" ; then
 558                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 559                     fi])
 560     AC_CHECK_HEADERS([sys/capability.h], [], [
 561                     if test "x${with_caps}" = "xyes" ; then
 562                         AC_MSG_ERROR([*** POSIX caps headers not found])
 563                     fi])
 564 fi
 565
 566 #### Valgrind (optional) ####
 567
 568 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 569
 570 #### json parsing ####
 571
 572 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
 573 AC_SUBST(LIBJSON_CFLAGS)
 574 AC_SUBST(LIBJSON_LIBS)
 575
 576 #### Sound file ####
 577
 578 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 579 AC_SUBST(LIBSNDFILE_CFLAGS)
 580 AC_SUBST(LIBSNDFILE_LIBS)
 581
 582 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 583 AC_SUBST(LIBSPEEX_CFLAGS)
 584 AC_SUBST(LIBSPEEX_LIBS)
 585
 586 #### atomic-ops ####
 587
 588 AC_MSG_CHECKING([whether we need libatomic_ops])
 589 if test "x$need_libatomic_ops" = "xyes"; then
 590     AC_MSG_RESULT([yes])
 591     AC_CHECK_HEADERS([atomic_ops.h],
 592         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 593         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 594
 595     # Win32 does not need the lib and breaks horribly if we try to include it
 596     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 597 else
 598     AC_MSG_RESULT([no])
 599 fi
 600
 601 #### Libsamplerate support (optional) ####
 602
 603 AC_ARG_ENABLE([samplerate],
 604     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 605
 606 AS_IF([test "x$enable_samplerate" != "xno"],
 607     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 608     HAVE_LIBSAMPLERATE=0)
 609
 610 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 611     [AC_MSG_ERROR([*** Libsamplerate not found])])
 612
 613 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 614 AC_SUBST(LIBSAMPLERATE_LIBS)
 615 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 616 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 617
 618 #### Database support ####
 619
 620 AC_ARG_WITH([database],
 621     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 622
 623
 624 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 625     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 626     HAVE_TDB=0)
 627 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 628
 629 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 630     [AC_MSG_ERROR([*** tdb not found])])
 631
 632
 633 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 634     [
 635         HAVE_GDBM=1
 636         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 637         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 638     ],
 639     HAVE_GDBM=0)
 640 AS_IF([test "x$HAVE_GDBM" = "x1"],
 641     [
 642         with_database=gdbm
 643         GDBM_CFLAGS=
 644         GDBM_LIBS=-lgdbm
 645     ])
 646
 647 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 648     [AC_MSG_ERROR([*** gdbm not found])])
 649
 650
 651 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 652     HAVE_SIMPLEDB=1,
 653     HAVE_SIMPLEDB=0)
 654 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 655
 656 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 657     AC_MSG_ERROR([*** missing database backend]))
 658
 659
 660 AC_SUBST(TDB_CFLAGS)
 661 AC_SUBST(TDB_LIBS)
 662 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 663 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 664
 665 AC_SUBST(GDBM_CFLAGS)
 666 AC_SUBST(GDBM_LIBS)
 667 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 668 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 669
 670 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 671 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 672
 673 #### OSS support (optional) ####
 674
 675 AC_ARG_ENABLE([oss-output],
 676     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 677
 678 AC_ARG_ENABLE([oss-wrapper],
 679     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 680
 681 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 682     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 683     HAVE_OSS=0)
 684
 685 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 686     [AC_MSG_ERROR([*** OSS support not found])])
 687
 688 AS_IF([test "x$enable_oss_output" != "xno"],
 689     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 690     HAVE_OSS_OUTPUT=0)
 691
 692 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 693     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 694     HAVE_OSS_WRAPPER=0)
 695
 696 AC_SUBST(HAVE_OSS_OUTPUT)
 697 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 698 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 699 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 700 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 701
 702 #### CoreAudio support (optional) ####
 703
 704 AC_ARG_ENABLE([coreaudio-output],
 705     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 706
 707 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 708     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 709     HAVE_COREAUDIO=0)
 710
 711 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 712     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 713
 714 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 715
 716 #### ALSA support (optional) ####
 717
 718 AC_ARG_ENABLE([alsa],
 719     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 720
 721 AS_IF([test "x$enable_alsa" != "xno"],
 722     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 723     HAVE_ALSA=0)
 724
 725 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 726     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 727
 728 AC_SUBST(ASOUNDLIB_CFLAGS)
 729 AC_SUBST(ASOUNDLIB_LIBS)
 730 AC_SUBST(HAVE_ALSA)
 731 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 732 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 733
 734 #### Solaris audio support (optional) ####
 735
 736 AC_ARG_ENABLE([solaris],
 737     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 738
 739 AS_IF([test "x$enable_solaris" != "xno"],
 740     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 741     HAVE_SOLARIS=0)
 742
 743 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 744     [AC_MSG_ERROR([*** Solaris audio support not found])])
 745
 746 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 747 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 748
 749 #### WaveOut audio support (optional) ####
 750
 751 AC_ARG_ENABLE([waveout],
 752     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 753
 754 AS_IF([test "x$enable_waveout" != "xno"],
 755     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 756     HAVE_WAVEOUT=0)
 757
 758 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 759     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 760
 761 AC_SUBST(HAVE_WAVEOUT)
 762 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 763 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 764
 765 #### GLib 2 support (optional) ####
 766
 767 AC_ARG_ENABLE([glib2],
 768     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 769
 770 AS_IF([test "x$enable_glib2" != "xno"],
 771     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 772     HAVE_GLIB20=0)
 773
 774 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 775     [AC_MSG_ERROR([*** GLib 2 support not found])])
 776
 777 AC_SUBST(GLIB20_CFLAGS)
 778 AC_SUBST(GLIB20_LIBS)
 779 AC_SUBST(HAVE_GLIB20)
 780 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 781 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 782
 783 #### GTK2 support (optional) ####
 784
 785 AC_ARG_ENABLE([gtk2],
 786     AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
 787
 788 AS_IF([test "x$enable_gtk2" != "xno"],
 789     [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
 790     HAVE_GTK20=0)
 791
 792 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
 793     [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
 794
 795 AC_SUBST(GTK20_CFLAGS)
 796 AC_SUBST(GTK20_LIBS)
 797 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
 798 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 799
 800 #### GConf support (optional) ####
 801
 802 AC_ARG_ENABLE([gconf],
 803     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 804
 805 AS_IF([test "x$enable_gconf" != "xno"],
 806     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 807     HAVE_GCONF=0)
 808
 809 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 810     [AC_MSG_ERROR([*** GConf support not found])])
 811
 812 AC_SUBST(GCONF_CFLAGS)
 813 AC_SUBST(GCONF_LIBS)
 814 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 815
 816 #### Avahi support (optional) ####
 817
 818 AC_ARG_ENABLE([avahi],
 819     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 820
 821 AS_IF([test "x$enable_avahi" != "xno"],
 822     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 823     HAVE_AVAHI=0)
 824
 825 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 826     [AC_MSG_ERROR([*** Avahi support not found])])
 827
 828 AC_SUBST(AVAHI_CFLAGS)
 829 AC_SUBST(AVAHI_LIBS)
 830 AC_SUBST(HAVE_AVAHI)
 831 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 832
 833 #### JACK (optional) ####
 834
 835 AC_ARG_ENABLE([jack],
 836     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 837
 838 AS_IF([test "x$enable_jack" != "xno"],
 839     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 840     HAVE_JACK=0)
 841
 842 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 843     [AC_MSG_ERROR([*** JACK support not found])])
 844
 845 AC_SUBST(JACK_CFLAGS)
 846 AC_SUBST(JACK_LIBS)
 847 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 848
 849 #### Async DNS support (optional) ####
 850
 851 AC_ARG_ENABLE([asyncns],
 852     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 853
 854 AS_IF([test "x$enable_asyncns" != "xno"],
 855     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 856     HAVE_LIBASYNCNS=0)
 857
 858 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 859     [AC_MSG_ERROR([*** Async DNS support not found])])
 860
 861 AC_SUBST(LIBASYNCNS_CFLAGS)
 862 AC_SUBST(LIBASYNCNS_LIBS)
 863 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 864 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 865
 866 #### TCP wrappers (optional) ####
 867
 868 AC_ARG_ENABLE([tcpwrap],
 869     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 870
 871 AS_IF([test "x$enable_tcpwrap" != "xno"],
 872     [
 873         ACX_LIBWRAP
 874         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 875     ],
 876     HAVE_TCPWRAP=0)
 877
 878 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 879     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 880
 881 AC_SUBST(LIBWRAP_LIBS)
 882
 883 #### LIRC support (optional) ####
 884
 885 AC_ARG_ENABLE([lirc],
 886     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 887
 888 LIRC_CFLAGS=
 889 LIRC_LIBS=
 890
 891 AS_IF([test "x$enable_lirc" != "xno"],
 892     [
 893         HAVE_LIRC=1
 894         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 895         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 896     ],
 897     HAVE_LIRC=0)
 898
 899 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 900     [AC_MSG_ERROR([*** LIRC support not found])])
 901
 902 AC_SUBST(LIRC_CFLAGS)
 903 AC_SUBST(LIRC_LIBS)
 904 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 905
 906 #### D-Bus support (optional) ####
 907
 908 AC_ARG_ENABLE([dbus],
 909     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 910
 911 AS_IF([test "x$enable_dbus" != "xno"],
 912     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 913     HAVE_DBUS=0)
 914
 915 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 916     [AC_MSG_ERROR([*** D-Bus (1.3.0+) support not found])])
 917
 918 AS_IF([test "x$HAVE_DBUS" = "x1"],
 919     [
 920         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 921         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 922         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 923         CFLAGS="$save_CFLAGS"
 924         LIBS="$save_LIBS"
 925     ])
 926
 927 AC_SUBST(DBUS_CFLAGS)
 928 AC_SUBST(DBUS_LIBS)
 929 AC_SUBST(HAVE_DBUS)
 930 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 931 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 932
 933 PA_MACHINE_ID="${localstatedir}/lib/dbus/machine-id"
 934 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 935
 936 #### HAL support (optional), dependant on D-Bus ####
 937
 938 AC_ARG_ENABLE([hal],
 939     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]))
 940
 941 AS_IF([test "x$enable_hal" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 942     [PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ], HAVE_HAL=1, HAVE_HAL=0)],
 943     HAVE_HAL=0)
 944 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_HAL=0)
 945
 946 AS_IF([test "x$enable_hal" = "xyes" && test "x$HAVE_HAL" = "x0"],
 947     [AC_MSG_ERROR([*** HAL support not found (requires D-Bus)])])
 948
 949 AC_SUBST(HAL_CFLAGS)
 950 AC_SUBST(HAL_LIBS)
 951 AC_SUBST(HAVE_HAL)
 952 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 953 AS_IF([test "x$HAVE_HAL" = "x1"], AC_DEFINE([HAVE_HAL], 1, [Have HAL.]))
 954
 955 #### BlueZ support (optional, dependant on D-Bus) ####
 956
 957 AC_ARG_ENABLE([bluez],
 958     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
 959
 960 AS_IF([test "x$enable_bluez" != "xno"],
 961     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 962     HAVE_BLUEZ=0)
 963 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
 964
 965 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
 966     [AC_MSG_ERROR([*** BLUEZ support not found (requires D-Bus)])])
 967
 968 AC_SUBST(BLUEZ_CFLAGS)
 969 AC_SUBST(BLUEZ_LIBS)
 970 AC_SUBST(HAVE_BLUEZ)
 971 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 972
 973 #### UDEV support (optional) ####
 974
 975 AC_ARG_ENABLE([udev],
 976     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
 977
 978 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 979     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
 980     HAVE_UDEV=0)
 981
 982 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
 983     [AC_MSG_ERROR([*** UDEV support not found])])
 984
 985 AC_SUBST(UDEV_CFLAGS)
 986 AC_SUBST(UDEV_LIBS)
 987 AC_SUBST(HAVE_UDEV)
 988 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
 989 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
 990
 991 #### HAL compat support (optional, dependant on UDEV) ####
 992
 993 AC_ARG_ENABLE([hal-compat],
 994     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
 995
 996 AS_IF([test "x$enable_hal_compat" != "xno"],
 997     [AS_IF([test "x$HAVE_HAL" = "x0" -a "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
 998     HAVE_HAL_COMPAT=0)
 999
1000 AS_IF([test "x$enable_hal_compat" = "xyes" && test "x$HAVE_HAL_COMPAT" = "x0"],
1001     [AC_MSG_ERROR([*** HAL-compat support requires UDEV and no HAL])])
1002
1003 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1004 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1005
1006 #### IPv6 connection support (optional) ####
1007
1008 AC_ARG_ENABLE([ipv6],
1009     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1010
1011 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1012
1013 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1014
1015 #### OpenSSL support (optional) ####
1016
1017 AC_ARG_ENABLE([openssl],
1018     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1019
1020 AS_IF([test "x$enable_openssl" != "xno"],
1021     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1022     HAVE_OPENSSL=0)
1023
1024 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1025     [AC_MSG_ERROR([*** OpenSSL support not found])])
1026
1027 AC_SUBST(OPENSSL_CFLAGS)
1028 AC_SUBST(OPENSSL_LIBS)
1029 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1030 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1031
1032 #### FFTW (optional) ####
1033
1034 AC_ARG_WITH([fftw],
1035     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1036
1037 AS_IF([test "x$with_fftw" != "xno"],
1038     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1039     HAVE_FFTW=0)
1040
1041 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1042     [AC_MSG_ERROR([*** FFTW support not found])])
1043
1044 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1045
1046 #### ORC (optional) ####
1047
1048 ORC_CHECK([0.4.11])
1049
1050 #### Build and Install man pages ####
1051
1052 AC_ARG_ENABLE([manpages],
1053     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1054
1055 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1056
1057 #### PulseAudio system group & user  #####
1058
1059 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1060 if test -z "$with_system_user" ; then
1061     PA_SYSTEM_USER=pulse
1062 else
1063     PA_SYSTEM_USER=$with_system_user
1064 fi
1065 AC_SUBST(PA_SYSTEM_USER)
1066 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1067
1068 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1069 if test -z "$with_system_group" ; then
1070     PA_SYSTEM_GROUP=pulse
1071 else
1072     PA_SYSTEM_GROUP=$with_system_group
1073 fi
1074 AC_SUBST(PA_SYSTEM_GROUP)
1075 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1076
1077 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1078 if test -z "$with_access_group" ; then
1079     PA_ACCESS_GROUP=pulse-access
1080 else
1081     PA_ACCESS_GROUP=$with_access_group
1082 fi
1083 AC_SUBST(PA_ACCESS_GROUP)
1084 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1085
1086 AC_ARG_ENABLE([per-user-esound-socket],
1087     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1088
1089 if test "x$enable_per_user_esound_socket" != "xno"; then
1090     USE_PER_USER_ESOUND_SOCKET=1
1091     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1092 else
1093     USE_PER_USER_ESOUND_SOCKET=0
1094 fi
1095
1096 #### PulseAudio system runtime dir ####
1097
1098 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1099 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1100 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1101 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1102 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1103 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1104
1105 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1106 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1107
1108 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1109 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1110
1111 AC_SUBST(PA_SOEXT, [.so])
1112
1113 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1114 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1115
1116 AC_DEFINE_UNQUOTED(PA_BUILDDIR, "${ac_pwd}/src", [Location of uninstalled binaries])
1117
1118 #### Mac OSX specific stuff #####
1119
1120 AC_ARG_ENABLE(mac-universal,
1121     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1122     enable_mac_universal=$enableval, enable_mac_universal="no")
1123
1124 AC_ARG_WITH(mac-version-min,
1125     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1126     mac_version_min=$withval, mac_version_min="10.5")
1127
1128 AC_ARG_WITH(mac-sysroot,
1129     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1130     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1131
1132 if test "x$os_is_darwin" = "x1" ; then
1133     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1134     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1135
1136     if test "x$enable_mac_universal" = "xyes" ; then
1137         mac_arches="-arch i386 -arch x86_64"
1138         LDFLAGS="$LDFLAGS $mac_arches"
1139         CFLAGS="$CFLAGS $mac_arches"
1140     fi
1141 fi
1142
1143
1144 ###################################
1145 #            Output               #
1146 ###################################
1147
1148 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1149
1150 # Check whether to build tests by default (as compile-test) or not
1151 AC_ARG_ENABLE([default-build-tests],
1152     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1153 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1154
1155 AC_ARG_ENABLE([legacy-runtime-dir],
1156         AS_HELP_STRING([--disable-legacy-runtime-dir], [Try to connect on legacy (< 0.9.12) socket paths.]))
1157 if test "x$enable_legacy_runtime_dir" != "xno" ; then
1158         AC_DEFINE(ENABLE_LEGACY_RUNTIME_DIR, [1], [Legacy runtime dir])
1159 fi
1160
1161 AC_ARG_ENABLE([legacy-database-entry-format],
1162         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1163 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1164         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1165 fi
1166 AC_DEFINE([WIBBLE], 1, [Just a test.])
1167
1168 AC_ARG_ENABLE([static-bins],
1169     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1170 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1171
1172 AC_ARG_WITH(
1173         [preopen-mods],
1174         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1175         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1176 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1177 if test "x$PREOPEN_MODS" != "xall" ; then
1178     tmpLIBS=""
1179     for mod in $PREOPEN_MODS; do
1180         tmpLIBS="$tmpLIBS module-$mod.la"
1181     done
1182     PREOPEN_MODS="$tmpLIBS"
1183     AC_SUBST(PREOPEN_MODS)
1184 fi
1185
1186 AC_ARG_WITH(
1187         [module-dir],
1188         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1189         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1190
1191 AC_SUBST(modlibexecdir)
1192 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1193
1194 AC_ARG_WITH(
1195         [udev-rules-dir],
1196         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1197         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1198
1199 AC_SUBST(udevrulesdir)
1200
1201 AC_ARG_ENABLE([force-preopen],
1202     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1203
1204 if test "x$enable_force_preopen" = "xyes"; then
1205     FORCE_PREOPEN=yes
1206 else
1207     FORCE_PREOPEN=no
1208 fi
1209
1210 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1211
1212 AC_CONFIG_FILES([
1213 Makefile
1214 src/Makefile
1215 man/Makefile
1216 libpulse.pc
1217 libpulse-simple.pc
1218 libpulse-mainloop-glib.pc
1219 doxygen/Makefile
1220 doxygen/doxygen.conf
1221 src/pulse/version.h
1222 po/Makefile.in
1223 man/pulseaudio.1.xml
1224 man/esdcompat.1.xml
1225 man/pax11publish.1.xml
1226 man/paplay.1.xml
1227 man/pacat.1.xml
1228 man/pacmd.1.xml
1229 man/pactl.1.xml
1230 man/pasuspender.1.xml
1231 man/padsp.1.xml
1232 man/pulse-daemon.conf.5.xml
1233 man/pulse-client.conf.5.xml
1234 man/default.pa.5.xml
1235 man/start-pulseaudio-kde.1.xml
1236 man/start-pulseaudio-x11.1.xml
1237 ])
1238
1239 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1240 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1241 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1242 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1243 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1244     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1245 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1246     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1247 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1248     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1249
1250 # CMake related ProjectConfig files
1251 PA_LIBDIR="$libdir"
1252 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1253 PA_INCDIR="$includedir"
1254 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1255
1256 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1257     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1258 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1259
1260 AC_OUTPUT
1261
1262 # ==========================================================================
1263
1264 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1265 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1266 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1267 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1268 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1269 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1270 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1271 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1272 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1273 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1274 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1275 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1276 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1277 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1278 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1279 AS_IF([test "x$HAVE_HAL" = "x1"], ENABLE_HAL=yes, ENABLE_HAL=no)
1280 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1281 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1282 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1283 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1284 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1285 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1286 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1287 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1288 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1289 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1290 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1291 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1292 AS_IF([test "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1293 AS_IF([test "x$enable_legacy_runtime_dir" != "xno"], ENABLE_LEGACY_RUNTIME_DIR=yes, ENABLE_LEGACY_RUNTIME_DIR=no)
1294 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1295
1296 echo "
1297  ---{ $PACKAGE_NAME $VERSION }---
1298
1299     prefix:                        ${prefix}
1300     sysconfdir:                    ${sysconfdir}
1301     localstatedir:                 ${localstatedir}
1302     modlibexecdir:                 ${modlibexecdir}
1303     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1304     System State Path:             ${PA_SYSTEM_STATE_PATH}
1305     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1306     Compiler:                      ${CC}
1307     CFLAGS:                        ${CFLAGS}
1308     LIBS:                          ${LIBS}
1309
1310     Enable X11:                    ${ENABLE_X11}
1311     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1312     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1313     Enable Alsa:                   ${ENABLE_ALSA}
1314     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1315     Enable Solaris:                ${ENABLE_SOLARIS}
1316     Enable WaveOut:                ${ENABLE_WAVEOUT}
1317     Enable GLib 2.0:               ${ENABLE_GLIB20}
1318     Enable Gtk+ 2.0:               ${ENABLE_GTK20}
1319     Enable GConf:                  ${ENABLE_GCONF}
1320     Enable Avahi:                  ${ENABLE_AVAHI}
1321     Enable Jack:                   ${ENABLE_JACK}
1322     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1323     Enable LIRC:                   ${ENABLE_LIRC}
1324     Enable D-Bus:                  ${ENABLE_DBUS}
1325       Enable HAL:                  ${ENABLE_HAL}
1326       Enable BlueZ:                ${ENABLE_BLUEZ}
1327     Enable udev:                   ${ENABLE_UDEV}
1328       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1329     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1330     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1331     Enable IPv6:                   ${ENABLE_IPV6}
1332     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1333     Enable fftw:                   ${ENABLE_FFTW}
1334     Enable orc:                    ${ENABLE_ORC}
1335     Database
1336       tdb:                         ${ENABLE_TDB}
1337       gdbm:                        ${ENABLE_GDBM}
1338       simple database:             ${ENABLE_SIMPLEDB}
1339
1340     System User:                   ${PA_SYSTEM_USER}
1341     System Group:                  ${PA_SYSTEM_GROUP}
1342     Access Group:                  ${PA_ACCESS_GROUP}
1343     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1344     Force preopen:                 ${FORCE_PREOPEN}
1345     Preopened modules:             ${PREOPEN_MODS}
1346
1347     Legacy Runtime Dir Support:    ${ENABLE_LEGACY_RUNTIME_DIR}
1348     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1349 "
1350
1351 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1352    echo "
1353 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1354 You do not have D-Bus support enabled. It is strongly recommended
1355 that you enable D-Bus support if your platform supports it.
1356 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1357 to the Device Reservation Protocol to speak to JACK, Bluetooth
1358 support and even a native control protocol for communicating and
1359 controling the PulseAudio daemon itself.
1360 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1361 "
1362 fi
1363
1364 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1365    echo "
1366 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1367 You do not have udev support enabled. It is strongly recommended
1368 that you enable udev support if your platform supports it as it is
1369 the primary method used to detect hardware audio devices (on Linux)
1370 and is thus a critical part of PulseAudio on that platform.
1371 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1372 "
1373 fi