configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [39])
  34 m4_define([glib_micro_version], [2])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 217 ])
 218
 219 if test "x$glib_have_cocoa" = "xyes"; then
 220   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 221   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 222 fi
 223
 224 dnl declare --enable-* args and collect ac_help strings
 225 AC_ARG_ENABLE(debug,
 226               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 227                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 228               enable_debug=glib_debug_default)
 229
 230 AC_ARG_ENABLE(gc_friendly,
 231               [AS_HELP_STRING([--enable-gc-friendly],
 232                               [turn on garbage collector friendliness [default=no]])],,
 233               [enable_gc_friendly=no])
 234 AC_ARG_ENABLE(mem_pools,
 235               [AS_HELP_STRING([--disable-mem-pools],
 236                               [disable all glib memory pools])],,
 237               [disable_mem_pools=no])
 238 AC_ARG_ENABLE(rebuilds,
 239               [AS_HELP_STRING([--disable-rebuilds],
 240                               [disable all source autogeneration rules])],,
 241               [enable_rebuilds=yes])
 242
 243 GLIB_TESTS
 244
 245 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 246 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 247   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 248   AC_MSG_RESULT([yes])
 249 ], [ AC_MSG_RESULT([no]) ])
 250
 251 AC_MSG_CHECKING([whether to disable memory pools])
 252 AS_IF([test "x$disable_mem_pools" = "xno"], [
 253   AC_MSG_RESULT([no])
 254 ], [
 255   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 256   AC_MSG_RESULT([yes])
 257 ])
 258
 259 dnl location to install runtime libraries, e.g. ../../lib to install
 260 dnl to /lib if libdir is /usr/lib
 261 AC_ARG_WITH(runtime-libdir,
 262            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 263                            [install runtime libraries relative to libdir])],
 264            [],
 265            [with_runtime_libdir=""])
 266 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 267 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 268 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 269 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 270 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 271
 272 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 273 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 274 AC_LANG_SAVE
 275 AC_LANG_CPLUSPLUS
 276 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 277 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 278 AC_LANG_RESTORE
 279
 280 AM_PROG_CC_C_O
 281 AC_PROG_INSTALL
 282
 283 AC_SYS_LARGEFILE
 284
 285 PKG_PROG_PKG_CONFIG(0.16)
 286
 287 if test "x$enable_debug" = "xyes"; then
 288   if test x$cflags_set != xset ; then
 289       case " $CFLAGS " in
 290       *[[\ \    ]]-g[[\ \       ]]*) ;;
 291       *) CFLAGS="$CFLAGS -g" ;;
 292       esac
 293   fi
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # option to specify python interpreter to use; this just sets $PYTHON, so that
 368 # we will fallback to reading $PYTHON if --with-python is not given, and
 369 # python.m4 will get the expected input
 370 AC_ARG_WITH(python,
 371             AS_HELP_STRING([--with-python=PATH],
 372                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 373             [PYTHON="$withval"], [])
 374 if test x"$PYTHON" = xyes; then
 375   AC_MSG_ERROR([--with-python option requires a path or program argument])
 376 fi
 377 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 378
 379
 380 dnl ***********************
 381 dnl *** Tests for iconv ***
 382 dnl ***********************
 383 dnl
 384 dnl We do this before the gettext checks, to avoid distortion
 385
 386 dnl On Windows we use a native implementation
 387
 388 AS_IF([ test x"$glib_native_win32" = xyes], [
 389   with_libiconv=native
 390 ], [
 391   AC_ARG_WITH(libiconv,
 392               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 393                               [use the libiconv library])],,
 394               [with_libiconv=maybe])
 395
 396   found_iconv=no
 397   case $with_libiconv in
 398     maybe)
 399       # Check in the C library first
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       # Check if we have GNU libiconv
 402       if test $found_iconv = "no"; then
 403         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       fi
 405       # Check if we have a iconv in -liconv, possibly from vendor
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 408       fi
 409       ;;
 410     no)
 411       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 412       ;;
 413     gnu|yes)
 414       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 415       ;;
 416     native)
 417       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 418       ;;
 419   esac
 420
 421   if test "x$found_iconv" = "xno" ; then
 422      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 423   fi
 424 ])
 425
 426 dnl
 427 dnl zlib support
 428 dnl
 429 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 430 AS_IF([test "x$found_zlib" = "xno"], [
 431   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 432   if test "x$found_zlib" = "xno" ; then
 433     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 434   fi
 435   ZLIB_LIBS='-lz'
 436   AC_SUBST(ZLIB_LIBS)
 437 ])
 438
 439 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 440 AC_SUBST(LIBFFI_CFLAGS)
 441 AC_SUBST(LIBFFI_LIBS)
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 AS_IF([test x"$glib_native_win32" != xyes], [
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 ])
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 LT_PREREQ([2.2])
 492 LT_INIT([disable-static win32-dll])
 493 dnl when using libtool 2.x create libtool early, because it's used in configure
 494 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 495
 496
 497 AS_IF([test "$glib_native_win32" = "yes"], [
 498   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 499     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 500   fi
 501   if test x$enable_static = xyes; then
 502     glib_win32_static_compilation=yes
 503     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 504 #define GOBJECT_STATIC_COMPILATION 1"
 505     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 506   fi
 507 ])
 508 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 509
 510 # Checks for library functions.
 511 AC_FUNC_VPRINTF
 512 AC_FUNC_ALLOCA
 513 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 514 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 515
 516 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 517   [AC_TRY_LINK([#include <unistd.h>
 518     extern int __libc_enable_secure;],
 519     [return __libc_enable_secure;],
 520    glib_cv_have_libc_enable_secure=yes,
 521    glib_cv_have_libc_enable_secure=no)])
 522 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 523    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 524      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 525 ])
 526
 527 AC_CHECK_SIZEOF(char)
 528 AC_CHECK_SIZEOF(short)
 529 AC_CHECK_SIZEOF(long)
 530 AC_CHECK_SIZEOF(int)
 531 AC_CHECK_SIZEOF(void *)
 532 AC_CHECK_SIZEOF(long long)
 533 AC_CHECK_SIZEOF(__int64)
 534
 535 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 536   [AC_TRY_LINK([#include <signal.h>
 537      #include <sys/types.h>
 538      sig_atomic_t val = 42;],
 539     [return val == 42 ? 0 : 1],
 540    ac_cv_type_sig_atomic_t=yes,
 541    ac_cv_type_sig_atomic_t=no)])
 542 if test x$ac_cv_type_sig_atomic_t = xyes; then
 543    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 544      [Define if you have the 'sig_atomic_t' type.])
 545 fi
 546
 547 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 548   :
 549 else
 550   AC_MSG_ERROR([
 551 *** GLib requires a 64 bit type. You might want to consider
 552 *** using the GNU C compiler.
 553 ])
 554 fi
 555
 556 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 557         # long long is a 64 bit integer.
 558         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 559         AC_CACHE_VAL(glib_cv_long_long_format,[
 560                 for format in ll q I64; do
 561                   AC_TRY_RUN([#include <stdio.h>
 562                         int main()
 563                         {
 564                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 565                           char buffer[1000];
 566                           sprintf (buffer, "%${format}u", a);
 567                           sscanf (buffer, "%${format}u", &b);
 568                           exit (b!=a);
 569                         }
 570                         ],
 571                         [glib_cv_long_long_format=${format}
 572                         break],
 573                         [],[:])
 574                 done])
 575         AS_IF([ test -n "$glib_cv_long_long_format"], [
 576           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 577           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 578           if test x"$glib_cv_long_long_format" = xI64; then
 579             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 580           fi
 581         ], [AC_MSG_RESULT(none)])
 582 ],[ test x$ac_cv_sizeof___int64 = x8], [
 583         # __int64 is a 64 bit integer.
 584         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 585         # We know this is MSVCRT.DLL, and what the formats are
 586         glib_cv_long_long_format=I64
 587         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 588         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 589         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 590 ])
 591
 592 AC_C_CONST
 593
 594 dnl
 595 dnl check in which direction the stack grows
 596 dnl
 597 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 598         AC_TRY_RUN([
 599         volatile int *a = 0, *b = 0;
 600         void foo (void);
 601         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 602         void foo (void) { volatile int x = 5; b = &x; }
 603         ],
 604         glib_cv_stack_grows=no
 605         ,
 606         glib_cv_stack_grows=yes
 607         ,)
 608 ])
 609
 610 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 611 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 612 dnl actually supported.
 613 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 614         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 615         __inline int foo () { return 0; }
 616         int main () { return foo (); }
 617         ]])],
 618         glib_cv_has__inline=yes
 619         ,
 620         glib_cv_has__inline=no
 621         ,)
 622 ])
 623 case x$glib_cv_has__inline in
 624 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 625 esac
 626 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 627         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 628         __inline__ int foo () { return 0; }
 629         int main () { return foo (); }
 630         ]])],
 631         glib_cv_has__inline__=yes
 632         ,
 633         glib_cv_has__inline__=no
 634         ,)
 635 ])
 636 case x$glib_cv_has__inline__ in
 637 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 638 esac
 639 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 640         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 641         #undef inline
 642         inline int foo () { return 0; }
 643         int main () { return foo (); }
 644         ]])],
 645         glib_cv_hasinline=yes
 646         ,
 647         glib_cv_hasinline=no
 648         ,)
 649 ])
 650 case x$glib_cv_hasinline in
 651 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 652 esac
 653
 654 # if we can use inline functions in headers
 655 AC_MSG_CHECKING(if inline functions in headers work)
 656 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 657 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 658 #  undef inline
 659 #  define inline __inline__
 660 #elif !defined (G_HAVE_INLINE)
 661 #  undef inline
 662 #  if defined (G_HAVE___INLINE__)
 663 #    define inline __inline__
 664 #  elif defined (G_HAVE___INLINE)
 665 #    define inline __inline
 666 #  endif
 667 #endif
 668
 669 int glib_test_func2 (int);
 670
 671 static inline int
 672 glib_test_func1 (void) {
 673   return glib_test_func2 (1);
 674 }
 675
 676 int
 677 main (void) {
 678   int i = 1;
 679 }]])],[g_can_inline=yes],[g_can_inline=no])
 680 AC_MSG_RESULT($g_can_inline)
 681
 682 dnl *** check for working do while(0) macros ***
 683 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 684         AC_TRY_COMPILE([],[
 685         #define STMT_START do
 686         #define STMT_END while(0)
 687         #define STMT_TEST STMT_START { i = 0; } STMT_END
 688         int main(void) { int i = 1; STMT_TEST; return i; }],
 689         [g_cv_support_dowhile_macros=yes],
 690         [g_cv_support_dowhile_macros=no],
 691         [g_cv_support_dowhile_macros=yes])
 692 ])
 693 if test x$g_cv_support_dowhile_macros = xyes; then
 694   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 695 fi
 696
 697 # check for flavours of varargs macros
 698 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 699 AC_TRY_COMPILE([],[
 700 int a(int p1, int p2, int p3);
 701 #define call_a(...) a(1,__VA_ARGS__)
 702 call_a(2,3);
 703 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 704 AC_MSG_RESULT($g_have_iso_c_varargs)
 705
 706 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 707 AS_IF([test "$CXX" = ""], [
 708 dnl No C++ compiler
 709   g_have_iso_cxx_varargs=no
 710 else
 711   AC_LANG_CPLUSPLUS
 712   AC_TRY_COMPILE([],[
 713 int a(int p1, int p2, int p3);
 714 #define call_a(...) a(1,__VA_ARGS__)
 715 call_a(2,3);
 716 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 717   AC_LANG_C
 718 ])
 719 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 720
 721 AC_MSG_CHECKING(for GNUC varargs macros)
 722 AC_TRY_COMPILE([],[
 723 int a(int p1, int p2, int p3);
 724 #define call_a(params...) a(1,params)
 725 call_a(2,3);
 726 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 727 AC_MSG_RESULT($g_have_gnuc_varargs)
 728
 729 # check for GNUC visibility support
 730 AC_MSG_CHECKING(for GNUC visibility attribute)
 731 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 732 void
 733 __attribute__ ((visibility ("hidden")))
 734      f_hidden (void)
 735 {
 736 }
 737 void
 738 __attribute__ ((visibility ("internal")))
 739      f_internal (void)
 740 {
 741 }
 742 void
 743 __attribute__ ((visibility ("protected")))
 744      f_protected (void)
 745 {
 746 }
 747 void
 748 __attribute__ ((visibility ("default")))
 749      f_default (void)
 750 {
 751 }
 752 int main (void)
 753 {
 754         f_hidden();
 755         f_internal();
 756         f_protected();
 757         f_default();
 758         return 0;
 759 }
 760 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 761 AC_MSG_RESULT($g_have_gnuc_visibility)
 762 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 763
 764 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 765 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 766 #else
 767 # include "error: this is not Sun Studio."
 768 #endif
 769 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 770 AC_MSG_RESULT($g_have_sunstudio_visibility)
 771 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 772
 773 # check for bytesex stuff
 774 AC_C_BIGENDIAN
 775 if test x$ac_cv_c_bigendian = xuniversal ; then
 776 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 777 #else
 778 #error Not a big endian.
 779 #endif],
 780     ac_cv_c_bigendian=yes
 781     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 782 #else
 783 #error Not a little endian.
 784 #endif],
 785     ac_cv_c_bigendian=no
 786     ,AC_MSG_WARN([Could not determine endianness.])))
 787 fi
 788
 789
 790 # check for header files
 791 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 792 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 793 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 794 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 795 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 796 AC_CHECK_HEADERS([sys/uio.h])
 797 AC_CHECK_HEADERS([linux/magic.h])
 798 AC_CHECK_HEADERS([sys/prctl.h])
 799
 800 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 801 [#if HAVE_SYS_PARAM_H
 802  #include <sys/param.h>
 803  #endif
 804 ])
 805 AC_CHECK_FUNCS(sysctlbyname)
 806
 807 AC_HEADER_MAJOR
 808 AC_CHECK_HEADERS([xlocale.h])
 809
 810 # check for structure fields
 811 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 812 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 813 #include <sys/stat.h>
 814 #include <unistd.h>
 815 #ifdef HAVE_SYS_STATFS_H
 816 #include <sys/statfs.h>
 817 #endif
 818 #ifdef HAVE_SYS_PARAM_H
 819 #include <sys/param.h>
 820 #endif
 821 #ifdef HAVE_SYS_MOUNT_H
 822 #include <sys/mount.h>
 823 #endif])
 824 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 825 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 826 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 827 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 828
 829 AC_STRUCT_DIRENT_D_TYPE
 830
 831 # Checks for libcharset
 832 AM_LANGINFO_CODESET
 833 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 834 AC_CHECK_FUNCS(setlocale)
 835 gl_GLIBC21
 836
 837 # check additional type sizes
 838 AC_CHECK_SIZEOF(size_t)
 839
 840 dnl Try to figure out whether gsize should be long or int
 841 AC_MSG_CHECKING([for the appropriate definition for size_t])
 842
 843 case $ac_cv_sizeof_size_t in
 844   $ac_cv_sizeof_short)
 845       glib_size_type=short
 846       ;;
 847   $ac_cv_sizeof_int)
 848       glib_size_type=int
 849       ;;
 850   $ac_cv_sizeof_long)
 851       glib_size_type=long
 852       ;;
 853   $ac_cv_sizeof_long_long)
 854       glib_size_type='long long'
 855       ;;
 856   $ac_cv_sizeof__int64)
 857       glib_size_type='__int64'
 858       ;;
 859   *)  AC_MSG_ERROR([No type matching size_t in size])
 860       ;;
 861 esac
 862
 863 dnl If int/long are the same size, we see which one produces
 864 dnl warnings when used in the location as size_t. (This matters
 865 dnl on AIX with xlc)
 866 dnl
 867 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 868        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 869   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 870 #if defined(_AIX) && !defined(__GNUC__)
 871 #pragma options langlvl=stdc89
 872 #endif
 873 #include <stddef.h>
 874 int main ()
 875 {
 876   size_t s = 1;
 877   unsigned int *size_int = &s;
 878   return (int)*size_int;
 879 }
 880     ]])],glib_size_type=int,
 881       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 882 #if defined(_AIX) && !defined(__GNUC__)
 883 #pragma options langlvl=stdc89
 884 #endif
 885 #include <stddef.h>
 886 int main ()
 887 {
 888    size_t s = 1;
 889    unsigned long *size_long = &s;
 890    return (int)*size_long;
 891 }
 892         ]])],glib_size_type=long)])
 893 ])
 894
 895 AC_MSG_RESULT(unsigned $glib_size_type)
 896
 897 AC_CHECK_SIZEOF(ssize_t)
 898
 899 dnl Try to figure out whether gssize should be long or int
 900 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 901
 902 case $ac_cv_sizeof_ssize_t in
 903   $ac_cv_sizeof_short)
 904       glib_ssize_type=short
 905       ;;
 906   $ac_cv_sizeof_int)
 907       glib_ssize_type=int
 908       ;;
 909   $ac_cv_sizeof_long)
 910       glib_ssize_type=long
 911       ;;
 912   $ac_cv_sizeof_long_long)
 913       glib_ssize_type='long long'
 914       ;;
 915   $ac_cv_sizeof__int64)
 916       glib_ssize_type='__int64'
 917       ;;
 918   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 919       ;;
 920 esac
 921
 922 dnl If int/long are the same size, we see which one produces
 923 dnl warnings when used in the location as ssize_t. (This matters
 924 dnl on Android where ssize_t is long and size_t is unsigned int)
 925 dnl
 926 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 927        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 928   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 929 #if defined(_AIX) && !defined(__GNUC__)
 930 #pragma options langlvl=stdc89
 931 #endif
 932 #include <stddef.h>
 933 #ifdef HAVE_INTTYPES_H
 934 # include <inttypes.h>
 935 #endif
 936 #ifdef HAVE_STDINT_H
 937 # include <stdint.h>
 938 #endif
 939 #ifdef HAVE_UNISTD_H
 940 # include <unistd.h>
 941 #endif
 942 #ifdef HAVE_SYS_TYPES_H
 943 # include <sys/types.h>
 944 #endif
 945 int main ()
 946 {
 947   ssize_t s = 1;
 948   int *size_int = &s;
 949   return (int)*size_int;
 950 }
 951     ]])],glib_ssize_type=int,
 952       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 953 #if defined(_AIX) && !defined(__GNUC__)
 954 #pragma options langlvl=stdc89
 955 #endif
 956 #include <stddef.h>
 957 #ifdef HAVE_INTTYPES_H
 958 # include <inttypes.h>
 959 #endif
 960 #ifdef HAVE_STDINT_H
 961 # include <stdint.h>
 962 #endif
 963 #ifdef HAVE_UNISTD_H
 964 # include <unistd.h>
 965 #endif
 966 #ifdef HAVE_SYS_TYPES_H
 967 # include <sys/types.h>
 968 #endif
 969 int main ()
 970 {
 971    ssize_t s = 1;
 972    long *size_long = &s;
 973    return (int)*size_long;
 974 }
 975         ]])],glib_ssize_type=long)])
 976 ])
 977
 978 AC_MSG_RESULT($glib_ssize_type)
 979
 980 # Check for some functions
 981 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 982 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 983 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 984 # Check for high-resolution sleep functions
 985 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 986 AC_CHECK_FUNCS(splice)
 987 AC_CHECK_FUNCS(prlimit)
 988
 989 # To avoid finding a compatibility unusable statfs, which typically
 990 # successfully compiles, but warns to use the newer statvfs interface:
 991 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 992 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 993
 994 AC_MSG_CHECKING([whether to use statfs or statvfs])
 995 # Some systems have both statfs and statvfs, pick the most "native" for these
 996 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 997    [
 998    # on solaris and irix, statfs doesn't even have the f_bavail field
 999    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1000       [ac_cv_func_statfs=no],
1001    # else, at least on linux, statfs is the actual syscall
1002       [ac_cv_func_statvfs=no])
1003    ])
1004
1005 AS_IF([test x$ac_cv_func_statfs = xyes],
1006       [
1007          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1008          AC_MSG_RESULT([statfs])
1009       ],
1010       [test x$ac_cv_func_statvfs = xyes],
1011       [
1012          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1013          AC_MSG_RESULT([statvfs])
1014       ],
1015       [  AC_MSG_RESULT([neither])])
1016
1017 AC_CHECK_HEADERS(crt_externs.h)
1018 AC_CHECK_FUNCS(_NSGetEnviron)
1019
1020 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1021
1022 AC_FUNC_VSNPRINTF_C99
1023 AC_FUNC_PRINTF_UNIX98
1024
1025 # Internet address families
1026 if test $glib_native_win32 = yes; then
1027   glib_inet_includes=["
1028 #include <winsock2.h>
1029   "]
1030 else
1031   glib_inet_includes=["
1032 #include <sys/types.h>
1033 #include <sys/socket.h>
1034   "]
1035 fi
1036
1037 glib_failed=false
1038 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1039 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1040 # winsock defines this even though it doesn't support it
1041 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1042 if $glib_failed ; then
1043   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1044 fi
1045
1046 glib_failed=false
1047 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1048 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1049 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1050 if $glib_failed ; then
1051   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1052 fi
1053
1054 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname)
1055
1056 AS_IF([test $glib_native_win32 = yes], [
1057   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1058   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1059   # they aren't present at run-time (on Windows 2000).
1060   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1061   AC_SUBST(WSPIAPI_INCLUDE)
1062 ], [
1063   # Android does not have C_IN in public headers, we define it wherever necessary
1064   AS_IF([test $glib_native_android != yes], [
1065     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1066     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1067                                         #include <arpa/nameser.h>],
1068                                        [int qclass = C_IN;])],
1069                       [AC_MSG_RESULT([no])],
1070                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1071                                                            #include <arpa/nameser.h>
1072                                                            #include <arpa/nameser_compat.h>],
1073                                                           [int qclass = C_IN;])],
1074                                          [AC_MSG_RESULT([yes])
1075                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1076                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1077   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1078
1079   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1080   NETWORK_LIBS=""
1081   AC_MSG_CHECKING([for res_query])
1082   AC_TRY_LINK([#include <sys/types.h>
1083                #include <netinet/in.h>
1084                #include <arpa/nameser.h>
1085                #include <resolv.h>
1086               ],[
1087                res_query("test", 0, 0, (void *)0, 0);
1088               ],[AC_MSG_RESULT([yes])],
1089               [save_libs="$LIBS"
1090                LIBS="-lresolv $LIBS"
1091                AC_TRY_LINK([#include <sys/types.h>
1092                             #include <netinet/in.h>
1093                             #include <arpa/nameser.h>
1094                             #include <resolv.h>
1095                            ],[
1096                             res_query("test", 0, 0, (void *)0, 0);
1097                            ],[AC_MSG_RESULT([in -lresolv])
1098                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1099                            [LIBS="-lbind $save_libs"
1100                             AC_TRY_LINK([#include <resolv.h>],
1101                                         [res_query("test", 0, 0, (void *)0, 0);],
1102                                         [AC_MSG_RESULT([in -lbind])
1103                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1104                                         [AC_MSG_ERROR(not found)])])
1105                LIBS="$save_libs"])
1106   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1107                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1108                                         [AC_MSG_ERROR(Could not find socket())]))
1109   save_libs="$LIBS"
1110   LIBS="$LIBS $NETWORK_LIBS"
1111   AC_MSG_CHECKING([for res_init])
1112   AC_TRY_LINK([#include <sys/types.h>
1113                #include <netinet/in.h>
1114                #include <arpa/nameser.h>
1115                #include <resolv.h>
1116               ],[
1117                res_init();
1118               ],[AC_MSG_RESULT([yes])
1119                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1120               ],[AC_MSG_RESULT([no])])
1121   LIBS="$save_libs"
1122 ])
1123 AC_SUBST(NETWORK_LIBS)
1124
1125 AC_CHECK_HEADER([linux/netlink.h],
1126                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1127                 [#include <sys/socket.h>])
1128 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1129
1130 AC_CHECK_TYPE([struct ip_mreqn], [
1131               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1132               [#include <netinet/in.h>])
1133
1134 case $host in
1135   *-*-solaris* )
1136      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1137      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1138      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1139      ;;
1140 esac
1141
1142 dnl
1143 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1144 dnl
1145 AS_IF([test "$ac_cv_func_statfs" = yes], [
1146   AC_MSG_CHECKING([number of arguments to statfs()])
1147   AC_TRY_COMPILE([#include <unistd.h>
1148   #ifdef HAVE_SYS_PARAM_H
1149   #include <sys/param.h>
1150   #endif
1151   #ifdef HAVE_SYS_VFS_H
1152   #include <sys/vfs.h>
1153   #endif
1154   #ifdef HAVE_SYS_MOUNT_H
1155   #include <sys/mount.h>
1156   #endif
1157   #ifdef HAVE_SYS_STATFS_H
1158   #include <sys/statfs.h>
1159   #endif], [struct statfs st;
1160   statfs(NULL, &st);],[
1161     AC_MSG_RESULT([2])
1162     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1163     AC_TRY_COMPILE([#include <unistd.h>
1164   #ifdef HAVE_SYS_PARAM_H
1165   #include <sys/param.h>
1166   #endif
1167   #ifdef HAVE_SYS_VFS_H
1168   #include <sys/vfs.h>
1169   #endif
1170   #ifdef HAVE_SYS_MOUNT_H
1171   #include <sys/mount.h>
1172   #endif
1173   #ifdef HAVE_SYS_STATFS_H
1174   #include <sys/statfs.h>
1175   #endif], [struct statfs st;
1176   statfs(NULL, &st, sizeof (st), 0);],[
1177       AC_MSG_RESULT([4])
1178       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1179       AC_MSG_RESULT(unknown)
1180       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1181 ])
1182
1183 dnl
1184 dnl open takes O_DIRECTORY as an option
1185 dnl
1186 AC_MSG_CHECKING([open() option O_DIRECTORY])
1187 AC_TRY_COMPILE([#include <fcntl.h>
1188 #include <sys/types.h>
1189 #include <sys/stat.h>],
1190 [open(0, O_DIRECTORY, 0);],[
1191         AC_MSG_RESULT([yes])
1192         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1193         AC_MSG_RESULT([no])])
1194
1195 #
1196 # Check whether to use an included printf
1197 #
1198
1199 AC_ARG_ENABLE(included-printf,
1200               [AS_HELP_STRING([--enable-included-printf],
1201                               [use included printf [default=auto]])],
1202               enable_included_printf="$enableval")
1203
1204 need_included_printf=no
1205 if test "x$enable_included_printf" = "xyes" ; then
1206   need_included_printf=yes
1207 fi
1208 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1209   need_included_printf=yes
1210 fi
1211 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1212   need_included_printf=yes
1213 fi
1214 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1215    test -z "$glib_cv_long_long_format" ; then
1216   need_included_printf=yes
1217 fi
1218
1219 if test "x$enable_included_printf" = "xno" &&
1220    test "x$need_included_printf" = "xyes" ; then
1221   AC_MSG_ERROR([
1222 *** Your C library's printf doesn't appear to have the features that
1223 *** GLib needs, but you specified --enable-included-printf=no.])
1224 fi
1225
1226 enable_included_printf=$need_included_printf
1227
1228 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1229 AS_IF([test "$enable_included_printf" != "yes"], [
1230   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1231 ], [
1232   if test -z "$glib_cv_long_long_format" ; then
1233     glib_cv_long_long_format="ll"
1234   fi
1235   AC_DEFINE(HAVE_VASPRINTF,1)
1236 ])
1237
1238 # Checks needed for gnulib vasnprintf
1239 bh_C_SIGNED
1240 jm_AC_TYPE_LONG_LONG
1241 gt_TYPE_LONGDOUBLE
1242 gt_TYPE_WCHAR_T
1243 gt_TYPE_WINT_T
1244 AC_TYPE_SIZE_T
1245 AC_CHECK_TYPES(ptrdiff_t)
1246 jm_AC_TYPE_INTMAX_T
1247 AC_CHECK_FUNCS([snprintf wcslen])
1248 AC_FUNC_SNPRINTF_C99
1249
1250 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1251 # The check is borrowed from the PERL Configure script.
1252 AS_IF([test "$ac_cv_func_memmove" != "yes"], [
1253   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1254     glib_cv_working_bcopy,[AC_TRY_RUN([
1255       int main() {
1256         char buf[128], abc[128], *b;
1257         int len, off, align;
1258         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1259         for (align = 7; align >= 0; align--) {
1260           for (len = 36; len; len--) {
1261             b = buf+align; bcopy(abc, b, len);
1262             for (off = 1; off <= len; off++) {
1263               bcopy(b, b+off, len); bcopy(b+off, b, len);
1264                 if (bcmp(b, abc, len)) return(1);
1265             }
1266           }
1267         }
1268         return(0);
1269       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1270
1271   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1272   if test "$glib_cv_working_bcopy" = "yes"; then
1273     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1274   fi
1275 ])
1276
1277 # Check if <sys/select.h> needs to be included for fd_set
1278 AC_MSG_CHECKING([for fd_set])
1279 AC_TRY_COMPILE([#include <sys/types.h>],
1280         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1281 AS_IF([test "$gtk_ok" = "yes"], [
1282     AC_MSG_RESULT([yes, found in sys/types.h])
1283 ], [
1284     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1285     if test "$gtk_ok" = "yes"; then
1286         # *** FIXME: give it a different name
1287         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1288         AC_MSG_RESULT([yes, found in sys/select.h])
1289     else
1290         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1291         AC_MSG_RESULT(no)
1292     fi
1293 ])
1294
1295 dnl Check for nl_langinfo and CODESET
1296 AC_LANG_SAVE
1297 AC_LANG_C
1298 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1299         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1300                        [char *codeset = nl_langinfo (CODESET);])],
1301                 [glib_cv_langinfo_codeset=yes],
1302                 [glib_cv_langinfo_codeset=no])])
1303 if test x$glib_cv_langinfo_codeset = xyes; then
1304   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1305 fi
1306
1307 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1308 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1309         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1310                  [char *str;
1311                  str = nl_langinfo (PM_STR);
1312                  str = nl_langinfo (D_T_FMT);
1313                  str = nl_langinfo (D_FMT);
1314                  str = nl_langinfo (T_FMT);
1315                  str = nl_langinfo (T_FMT_AMPM);
1316                  str = nl_langinfo (MON_1);
1317                  str = nl_langinfo (ABMON_12);
1318                  str = nl_langinfo (DAY_1);
1319                  str = nl_langinfo (ABDAY_7);])],
1320                 [glib_cv_langinfo_time=yes],
1321                 [glib_cv_langinfo_time=no])])
1322 if test x$glib_cv_langinfo_time = xyes; then
1323   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1324 fi
1325
1326 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1327 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1328         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1329                 [char *str;
1330                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1340                 [glib_cv_langinfo_outdigit=yes],
1341                 [glib_cv_langinfo_outdigit=no])])
1342 if test x$glib_cv_langinfo_outdigit = xyes; then
1343   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1344 fi
1345 AC_LANG_RESTORE
1346
1347 dnl ****************************************
1348 dnl *** posix_memalign                   ***
1349 dnl ****************************************
1350 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1351 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1352     glib_cv_compliant_posix_memalign=0
1353     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1354         AC_TRY_RUN([
1355                 #define _XOPEN_SOURCE 600
1356                 #include <stdlib.h> /* posix_memalign() should be defined here */
1357                 /* some systems break if #include <malloc.h> used */
1358                 static void test_memalign (size_t boundary, size_t size) {
1359                     void *mem = 0;
1360                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1361                         exit (1);
1362                     else
1363                       free (mem);
1364                 }
1365                 int main() {
1366                     test_memalign (  128,   128 - 2 * sizeof (void*));
1367                     test_memalign (  256,   256 - 2 * sizeof (void*));
1368                     test_memalign (  512,   512 - 2 * sizeof (void*));
1369                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1370                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1371                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1372                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1373                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1374                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1375                     exit (0); /* success */
1376                 }
1377                 ],
1378             [glib_cv_compliant_posix_memalign=1], [], [:])
1379       :
1380     fi
1381     ])
1382 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1383     AC_MSG_RESULT(yes)
1384     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1385 ], [
1386     AC_MSG_RESULT(no)
1387 ])
1388
1389
1390 dnl ****************************************
1391 dnl *** strlcpy/strlcat                  ***
1392 dnl ****************************************
1393 # Check for strlcpy
1394 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1395 AC_TRY_RUN([#include <stdlib.h>
1396 #include <string.h>
1397 int main() {
1398   char p[10];
1399   (void) strlcpy (p, "hi", 10);
1400   if (strlcat (p, "bye", 0) != 3)
1401     return 1;
1402   return 0;
1403 }], glib_cv_have_strlcpy=yes,
1404     glib_cv_have_strlcpy=no,
1405     glib_cv_have_strlcpy=no)])
1406 if test "$glib_cv_have_strlcpy" = "yes"; then
1407     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1408 fi
1409
1410
1411 dnl **********************
1412 dnl *** va_copy checks ***
1413 dnl **********************
1414 dnl we currently check for all three va_copy possibilities, so we get
1415 dnl all results in config.log for bug reports.
1416 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1417         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1418 #include <stdlib.h>
1419         void f (int i, ...) {
1420         va_list args1, args2;
1421         va_start (args1, i);
1422         va_copy (args2, args1);
1423         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1424           exit (1);
1425         va_end (args1); va_end (args2);
1426         }
1427         int main() {
1428           f (0, 42);
1429           return 0;
1430         }]])],
1431         [glib_cv_va_copy=yes],
1432         [glib_cv_va_copy=no])
1433 ])
1434 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1435         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1436 #include <stdlib.h>
1437         void f (int i, ...) {
1438         va_list args1, args2;
1439         va_start (args1, i);
1440         __va_copy (args2, args1);
1441         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1442           exit (1);
1443         va_end (args1); va_end (args2);
1444         }
1445         int main() {
1446           f (0, 42);
1447           return 0;
1448         }]])],
1449         [glib_cv___va_copy=yes],
1450         [glib_cv___va_copy=no])
1451 ])
1452
1453 if test "x$glib_cv_va_copy" = "xyes"; then
1454   g_va_copy_func=va_copy
1455 else if test "x$glib_cv___va_copy" = "xyes"; then
1456   g_va_copy_func=__va_copy
1457 fi
1458 fi
1459
1460 if test -n "$g_va_copy_func"; then
1461   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1462 fi
1463
1464 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1465         AC_TRY_RUN([#include <stdarg.h>
1466 #include <stdlib.h>
1467         void f (int i, ...) {
1468         va_list args1, args2;
1469         va_start (args1, i);
1470         args2 = args1;
1471         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1472           exit (1);
1473         va_end (args1); va_end (args2);
1474         }
1475         int main() {
1476           f (0, 42);
1477           return 0;
1478         }],
1479         [glib_cv_va_val_copy=yes],
1480         [glib_cv_va_val_copy=no],
1481         [glib_cv_va_val_copy=yes])
1482 ])
1483
1484 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1485   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1486 ])
1487
1488 dnl ***********************
1489 dnl *** g_module checks ***
1490 dnl ***********************
1491 G_MODULE_LIBS=
1492 G_MODULE_LIBS_EXTRA=
1493 G_MODULE_PLUGIN_LIBS=
1494 if test x"$glib_native_win32" = xyes; then
1495   dnl No use for this on Win32
1496   G_MODULE_LDFLAGS=
1497 else
1498   export SED
1499   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1500 fi
1501 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1502 G_MODULE_NEED_USCORE=0
1503 G_MODULE_BROKEN_RTLD_GLOBAL=0
1504 G_MODULE_HAVE_DLERROR=0
1505 dnl *** force native WIN32 shared lib loader
1506 if test -z "$G_MODULE_IMPL"; then
1507   case "$host" in
1508   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1509   esac
1510 fi
1511 dnl *** force native AIX library loader
1512 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1513 if test -z "$G_MODULE_IMPL"; then
1514   case "$host" in
1515   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1516   esac
1517 fi
1518 dnl *** dlopen() and dlsym() in system libraries
1519 AS_IF([ test -z "$G_MODULE_IMPL"], [
1520         AC_CHECK_FUNC(dlopen,
1521                       [AC_CHECK_FUNC(dlsym,
1522                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1523                       [])
1524 ])
1525 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1526 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1527         AC_CHECK_FUNC(NSLinkModule,
1528                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1529                        G_MODULE_NEED_USCORE=1],
1530                       [])
1531 ])
1532 dnl *** dlopen() and dlsym() in libdl
1533 AS_IF([ test -z "$G_MODULE_IMPL"], [
1534         AC_CHECK_LIB(dl, dlopen,
1535                      [AC_CHECK_LIB(dl, dlsym,
1536                                    [G_MODULE_LIBS=-ldl
1537                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1538                      [])
1539 ])
1540 dnl *** additional checks for G_MODULE_IMPL_DL
1541 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1542         LIBS_orig="$LIBS"
1543         LDFLAGS_orig="$LDFLAGS"
1544         LIBS="$G_MODULE_LIBS $LIBS"
1545         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1546 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1547         echo "void glib_plugin_test(void) { }" > plugin.c
1548         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1549                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1550         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1551                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1552                 -shrext ".o" -avoid-version plugin.lo \
1553                 -rpath /dont/care >/dev/null 2>&1
1554         eval `./libtool --config | grep ^objdir`
1555         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1556                 glib_cv_rtldglobal_broken,[
1557                 AC_TRY_RUN([
1558 #include <dlfcn.h>
1559 #ifndef RTLD_GLOBAL
1560 #  define RTLD_GLOBAL 0
1561 #endif
1562 #ifndef RTLD_LAZY
1563 #  define RTLD_LAZY 0
1564 #endif
1565 int glib_plugin_test;
1566 int main () {
1567     void *handle, *global, *local;
1568     global = &glib_plugin_test;
1569     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1570     if (!handle) return 0;
1571     local = dlsym (handle, "glib_plugin_test");
1572     return global == local;
1573 }                       ],
1574                         [glib_cv_rtldglobal_broken=no],
1575                         [glib_cv_rtldglobal_broken=yes],
1576                         [glib_cv_rtldglobal_broken=no])
1577                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1578                 rmdir ${objdir} 2>/dev/null
1579         ])
1580         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1581                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1582         else
1583                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1584         fi
1585 dnl *** check whether we need preceeding underscores
1586         AC_CACHE_CHECK([for preceeding underscore in symbols],
1587                 glib_cv_uscore,[
1588                 AC_TRY_RUN([#include <dlfcn.h>
1589                 int glib_underscore_test (void) { return 42; }
1590                 int main() {
1591                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1592                   handle = dlopen ((void*)0, 0);
1593                   if (handle) {
1594                     f1 = dlsym (handle, "glib_underscore_test");
1595                     f2 = dlsym (handle, "_glib_underscore_test");
1596                   } return (!f2 || f1);
1597                 }],
1598                         [glib_cv_uscore=yes],
1599                         [glib_cv_uscore=no],
1600                         [])
1601                 rm -f plugin.c plugin.$ac_objext plugin.lo
1602         ])
1603         GLIB_ASSERT_SET(glib_cv_uscore)
1604         if test "x$glib_cv_uscore" = "xyes"; then
1605                 G_MODULE_NEED_USCORE=1
1606         else
1607                 G_MODULE_NEED_USCORE=0
1608         fi
1609
1610         LDFLAGS="$LDFLAGS_orig"
1611 dnl *** check for having dlerror()
1612         AC_CHECK_FUNC(dlerror,
1613                 [G_MODULE_HAVE_DLERROR=1],
1614                 [G_MODULE_HAVE_DLERROR=0])
1615         LIBS="$LIBS_orig"
1616 ])
1617 dnl *** done, have we got an implementation?
1618 if test -z "$G_MODULE_IMPL"; then
1619         G_MODULE_IMPL=0
1620         G_MODULE_SUPPORTED=false
1621 else
1622         G_MODULE_SUPPORTED=true
1623 fi
1624
1625 AC_MSG_CHECKING(for the suffix of module shared libraries)
1626 export SED
1627 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1628 eval $shrext_cmds
1629 module=yes eval std_shrext=$shrext_cmds
1630 # chop the initial dot
1631 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1632 AC_MSG_RESULT(.$glib_gmodule_suffix)
1633 # any reason it may fail?
1634 if test "x$glib_gmodule_suffix" = x; then
1635         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1636 fi
1637
1638 AC_SUBST(G_MODULE_SUPPORTED)
1639 AC_SUBST(G_MODULE_IMPL)
1640 AC_SUBST(G_MODULE_LIBS)
1641 AC_SUBST(G_MODULE_LIBS_EXTRA)
1642 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1643 AC_SUBST(G_MODULE_LDFLAGS)
1644 AC_SUBST(G_MODULE_HAVE_DLERROR)
1645 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1646 AC_SUBST(G_MODULE_NEED_USCORE)
1647 AC_SUBST(GLIB_DEBUG_FLAGS)
1648
1649 dnl **********************
1650 dnl *** g_spawn checks ***
1651 dnl **********************
1652
1653 AC_MSG_CHECKING(for gspawn implementation)
1654 case "$host" in
1655   *-*-mingw*)
1656     GSPAWN=gspawn-win32.lo
1657     ;;
1658   *)
1659     GSPAWN=gspawn.lo
1660     ;;
1661 esac
1662 AC_MSG_RESULT($GSPAWN)
1663 AC_SUBST(GSPAWN)
1664
1665 dnl *************************
1666 dnl *** GIOChannel checks ***
1667 dnl *************************
1668
1669 AC_MSG_CHECKING(for GIOChannel implementation)
1670 case "$host" in
1671   *-*-mingw*)
1672     GIO=giowin32.lo
1673     ;;
1674   *)
1675     GIO=giounix.lo
1676     ;;
1677 esac
1678 AC_MSG_RESULT($GIO)
1679 AC_SUBST(GIO)
1680
1681 dnl *********************************
1682 dnl *** Directory for GIO modules ***
1683 dnl *********************************
1684
1685 AC_ARG_WITH(gio-module-dir,
1686            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1687                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1688            [],
1689            [with_gio_module_dir='${libdir}/gio/modules'])
1690 GIO_MODULE_DIR=$with_gio_module_dir
1691 AC_SUBST(GIO_MODULE_DIR)
1692
1693 dnl **********************************
1694 dnl *** Check for libselinux (GIO) ***
1695 dnl **********************************
1696 AC_ARG_ENABLE(selinux,
1697               AS_HELP_STRING([--disable-selinux],
1698                              [build without selinux support]))
1699 msg_selinux=no
1700 SELINUX_LIBS=
1701 AS_IF([ test "x$enable_selinux" != "xno"], [
1702
1703  AC_CHECK_LIB(selinux, is_selinux_enabled,
1704    [AC_CHECK_HEADERS(selinux/selinux.h,
1705      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1706        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1707         SELINUX_LIBS="-lselinux"
1708         msg_selinux=yes])
1709      ])
1710    ])
1711 ])
1712 AC_SUBST(SELINUX_LIBS)
1713
1714 dnl *****************************
1715 dnl ** Check for inotify (GIO) **
1716 dnl *****************************
1717 inotify_support=no
1718 AC_CHECK_HEADERS([sys/inotify.h],
1719 [
1720         inotify_support=yes
1721         AC_CHECK_FUNCS(inotify_init1)
1722 ])
1723
1724 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1725
1726 dnl ****************************
1727 dnl ** Check for kqueue (GIO) **
1728 dnl ****************************
1729 kqueue_support=no
1730 AC_CHECK_HEADERS([sys/event.h],
1731 [
1732         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1733 ])
1734
1735 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1736
1737 dnl *********************************
1738 dnl ** Check for Solaris FEN (GIO) **
1739 dnl *********************************
1740 fen_support=no
1741 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1742 #include <port.h>
1743 #ifndef PORT_SOURCE_FILE
1744 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1745 #endif
1746 int main() { return 0; } ]])],
1747 [
1748         fen_support=yes
1749 ],)
1750
1751 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1752
1753 dnl ****************************
1754 dnl *** Checks for FAM (GIO) ***
1755 dnl ****************************
1756
1757 should_disable_fam=no
1758
1759 AC_ARG_ENABLE(fam,
1760               AS_HELP_STRING([--disable-fam],
1761                              [don't use fam for file system monitoring]),
1762                          [
1763                                 if test "x$enable_fam" = "xno"; then
1764                                         should_disable_fam=yes
1765                                 fi
1766                          ]
1767                          )
1768 fam_support=no
1769 FAM_LIBS=
1770 if test "x$should_disable_fam" = "xno"; then
1771 AC_CHECK_LIB(fam, FAMOpen,
1772   [AC_CHECK_HEADERS(fam.h,
1773     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1774      AC_CHECK_LIB(fam, FAMNoExists,
1775                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1776      FAM_LIBS="-lfam"]
1777      fam_support=yes,
1778     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1779   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1780 AC_SUBST(FAM_LIBS)
1781 fi
1782 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1783
1784
1785 dnl *****************************
1786 dnl *** Check for xattr (GIO) ***
1787 dnl *****************************
1788 AC_ARG_ENABLE(xattr,
1789               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1790 msg_xattr=no
1791 XATTR_LIBS=
1792 AS_IF([ test "x$enable_xattr" != "xno"], [
1793
1794 dnl either glibc or libattr can provide xattr support
1795
1796 dnl for both of them, we check for getxattr being in
1797 dnl the library and a valid xattr header.
1798
1799 dnl try glibc
1800  AC_CHECK_LIB(c, getxattr,
1801    [AC_CHECK_HEADERS(sys/xattr.h,
1802      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1803       msg_xattr=yes])
1804    ])
1805
1806   AS_IF([ test "x$msg_xattr" != "xyes"], [
1807 dnl   failure. try libattr
1808    AC_CHECK_LIB(attr, getxattr,
1809       [AC_CHECK_HEADERS(attr/xattr.h,
1810        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1811         XATTR_LIBS="-lattr"
1812         msg_xattr=yes])
1813       ])
1814   ])
1815
1816   AS_IF([ test "x$msg_xattr" = "xyes"], [
1817     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1818     AC_TRY_COMPILE([
1819       #include <stdio.h>
1820       #ifdef HAVE_SYS_TYPES_H
1821       #include <sys/types.h>
1822       #endif
1823       #ifdef HAVE_SYS_XATTR_H
1824       #include <sys/xattr.h>
1825       #elif HAVE_ATTR_XATTR_H
1826       #include <attr/xattr.h>
1827       #endif
1828     ],
1829     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1830     [
1831       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1832       AC_MSG_RESULT([yes])
1833     ],
1834     [AC_MSG_RESULT([no])]
1835     )
1836   ])
1837 ])
1838 AC_SUBST(XATTR_LIBS)
1839
1840 dnl ************************
1841 dnl *** check for libelf ***
1842 dnl ************************
1843 AC_ARG_ENABLE(libelf,
1844               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1845 AS_IF([ test "x$enable_libelf" != "xno"],[
1846 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1847 AS_IF([ test $have_libelf = maybe ], [
1848   glib_save_LIBS=$LIBS
1849   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1850   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1851   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1852   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1853   LIBS=$glib_save_LIBS
1854
1855   if test $have_libelf != no; then
1856     LIBELF_LIBS=-lelf
1857     have_libelf=yes
1858   fi
1859 ])
1860 ])
1861
1862 if test x$have_libelf = xyes; then
1863   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1864 fi
1865
1866 dnl ****************************************
1867 dnl *** platform dependent source checks ***
1868 dnl ****************************************
1869
1870 AC_MSG_CHECKING(for platform-dependent source)
1871 case "$host" in
1872   *-*-cygwin*|*-*-mingw*)
1873     PLATFORMDEP=gwin32.lo
1874     ;;
1875   *)
1876     PLATFORMDEP=
1877     ;;
1878 esac
1879 AC_MSG_RESULT($PLATFORMDEP)
1880 AC_SUBST(PLATFORMDEP)
1881
1882 AC_MSG_CHECKING([whether to compile timeloop])
1883 case "$host" in
1884   *-*-cygwin*|*-*-mingw*|*-*-minix)
1885     enable_timeloop=no
1886     ;;
1887   *)
1888     enable_timeloop=yes
1889     ;;
1890 esac
1891 AC_MSG_RESULT($enable_timeloop)
1892 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1893
1894 AC_MSG_CHECKING([if building for some Win32 platform])
1895 case "$host" in
1896   *-*-mingw*|*-*-cygwin*)
1897     platform_win32=yes
1898     ;;
1899   *)
1900     platform_win32=no
1901     ;;
1902 esac
1903 AC_MSG_RESULT($platform_win32)
1904 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1905
1906 dnl ***********************
1907 dnl *** g_thread checks ***
1908 dnl ***********************
1909
1910 AC_ARG_WITH(threads,
1911            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1912                            [specify a thread implementation to use])],
1913            [],
1914            [with_threads=yes])
1915
1916 dnl error and warning message
1917 dnl *************************
1918
1919 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1920
1921 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1922                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1923                 compilation now, but then your programs might not work.
1924                 Please provide information on how it is done on your system."
1925
1926 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1927                  "
1928
1929 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1930                   provide information on your thread implementation."
1931
1932 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1933                 functions will not be MT-safe during their first call because
1934                 there is no working 'getpwuid_r' on your system."
1935
1936 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1937                 because there is no 'localtime_r' on your system."
1938
1939 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1940                 linking threaded applications. As GLib cannot do that
1941                 automatically, you will get an linkg error everytime you are
1942                 not using the right compiler. In that case you have to relink
1943                 with the right compiler. Ususally just '_r' is appended
1944                 to the compiler name."
1945
1946 dnl determination of thread implementation
1947 dnl ***************************************
1948
1949 AC_MSG_CHECKING(for thread implementation)
1950
1951 have_threads=no
1952 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1953         AS_IF([ test "x$have_threads" = xno], [
1954                 AC_TRY_COMPILE([#include <pthread.h>],
1955                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1956                         have_threads=posix)
1957         ])
1958         # Tru64Unix requires -pthread to find pthread.h. See #103020
1959         if test "x$have_threads" = xno; then
1960                 glib_save_CPPFLAGS="$CPPFLAGS"
1961                 CPPFLAGS="$CPPFLAGS -pthread"
1962                 AC_TRY_COMPILE([#include <pthread.h>],
1963                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1964                        have_threads=posix)
1965                 CPPFLAGS="$glib_save_CPPFLAGS"
1966         fi
1967 ])
1968 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1969         case $host in
1970                 *-*-mingw*)
1971                 have_threads=win32
1972                 ;;
1973         esac
1974 fi
1975
1976 if test "x$have_threads" = xno; then
1977         AC_MSG_RESULT(none available)
1978         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1979 else
1980         AC_MSG_RESULT($have_threads)
1981 fi
1982
1983
1984 dnl determination of G_THREAD_CFLAGS
1985 dnl ********************************
1986
1987 G_THREAD_LIBS=
1988 G_THREAD_LIBS_EXTRA=
1989 G_THREAD_CFLAGS=
1990
1991 dnl
1992 dnl Test program for basic POSIX threads functionality
1993 dnl
1994 m4_define([glib_thread_test],[
1995 #include <pthread.h>
1996 int check_me = 0;
1997 void* func(void* data) {check_me = 42; return &check_me;}
1998 int main()
1999  { pthread_t t;
2000    void *ret;
2001    pthread_create (&t, $1, func, 0);
2002    pthread_join (t, &ret);
2003    return (check_me != 42 || ret != &check_me);
2004 }])
2005
2006 AS_IF([ test x"$have_threads" = xposix], [
2007   # First we test for posix, whether -pthread or -pthreads do the trick as
2008   # both CPPFLAG and LIBS.
2009   # One of them does for most gcc versions and some other platforms/compilers
2010   # too and could be considered as the canonical way to go.
2011   case $host in
2012     *-*-cygwin*|*-*-darwin*)
2013        # skip cygwin and darwin -pthread or -pthreads test
2014        ;;
2015     *-solaris*)
2016       # These compiler/linker flags work with both Sun Studio and gcc
2017       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2018       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2019       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2020       G_THREAD_LIBS="-lpthread -lthread"
2021       ;;
2022     *)
2023       for flag in pthread pthreads mt; do
2024         glib_save_CFLAGS="$CFLAGS"
2025         CFLAGS="$CFLAGS -$flag"
2026         AC_TRY_RUN(glib_thread_test(0),
2027                    glib_flag_works=yes,
2028                    glib_flag_works=no,
2029                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2030                                    glib_flag_works=yes,
2031                                    glib_flag_works=no)])
2032         CFLAGS="$glib_save_CFLAGS"
2033         if test $glib_flag_works = yes ; then
2034            G_THREAD_CFLAGS=-$flag
2035         G_THREAD_LIBS=-$flag
2036         break;
2037         fi
2038       done
2039        ;;
2040   esac
2041 ])
2042
2043 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2044
2045   # The canonical -pthread[s] does not work. Try something different.
2046
2047   case $host in
2048         *-aix*)
2049                 if test x"$GCC" = xyes; then
2050                         # GCC 3.0 and above needs -pthread.
2051                         # Should be coverd by the case above.
2052                         # GCC 2.x and below needs -mthreads
2053                         G_THREAD_CFLAGS="-mthreads"
2054                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2055                 else
2056                         # We are probably using the aix compiler. Normaly a
2057                         # program would have to be compiled with the _r variant
2058                         # of the corresponding compiler, but we as GLib cannot
2059                         # do that: but the good news is that for compiling the
2060                         # only difference is the added -D_THREAD_SAFE compile
2061                         # option. This is according to the "C for AIX User's
2062                         # Guide".
2063                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2064                 fi
2065                 ;;
2066         *-sysv5uw7*) # UnixWare 7
2067                 # We are not using gcc with -pthread. Catched above.
2068                 G_THREAD_CFLAGS="-Kthread"
2069                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2070                 ;;
2071         *-mingw*)
2072                 # No flag needed when using MSVCRT.DLL
2073                 G_THREAD_CFLAGS=""
2074                 ;;
2075         *)
2076                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2077                 ;;
2078   esac
2079 ])
2080
2081 # if we are not finding the localtime_r function, then we probably are
2082 # not using the proper multithread flag
2083
2084 glib_save_CPPFLAGS="$CPPFLAGS"
2085 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2086
2087 # First we test, whether localtime_r is declared in time.h
2088 # directly. Then we test whether a macro localtime_r exists, in
2089 # which case localtime_r in the test program is replaced and thus
2090 # if we still find localtime_r in the output, it is not defined as
2091 # a macro.
2092
2093 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2094   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2095                                                            localtime_r(a,b)],
2096                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2097
2098 CPPFLAGS="$glib_save_CPPFLAGS"
2099
2100 AC_MSG_CHECKING(thread related cflags)
2101 AC_MSG_RESULT($G_THREAD_CFLAGS)
2102 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2103
2104 dnl determination of G_THREAD_LIBS
2105 dnl ******************************
2106
2107 AS_IF([test x$have_threads = xposix], [
2108           glib_save_CPPFLAGS="$CPPFLAGS"
2109           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2110           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2111             case $host in
2112               *-aix*)
2113                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2114                 # probably using the aix compiler.
2115                 AC_MSG_WARN($AIX_COMPILE_INFO)
2116                 ;;
2117               *)
2118                 G_THREAD_LIBS=error
2119                 glib_save_LIBS="$LIBS"
2120                 for thread_lib in "" pthread pthread32 pthreads thread; do
2121                         if test x"$thread_lib" = x; then
2122                                 add_thread_lib=""
2123                                 IN=""
2124                         else
2125                                 add_thread_lib="-l$thread_lib"
2126                                 IN=" in -l$thread_lib"
2127                         fi
2128                         if test x"$have_threads" = xposix; then
2129                                 defattr=0
2130                         else
2131                                 defattr=pthread_attr_default
2132                         fi
2133
2134                         LIBS="$add_thread_lib $glib_save_LIBS"
2135
2136                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2137                         AC_TRY_RUN(glib_thread_test($defattr),
2138                                    glib_result=yes,
2139                                    glib_result=no,
2140                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2141                                                    glib_result=yes,
2142                                                    glib_result=no)])
2143                         AC_MSG_RESULT($glib_result)
2144
2145                         if test "$glib_result" = "yes" ; then
2146                           G_THREAD_LIBS="$add_thread_lib"
2147                           break
2148                         fi
2149                 done
2150                 if test "x$G_THREAD_LIBS" = xerror; then
2151                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2152                 fi
2153                 LIBS="$glib_save_LIBS"
2154                 ;;
2155             esac
2156           ])
2157
2158           g_threads_impl="POSIX"
2159           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2160           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2161           CPPFLAGS="$glib_save_CPPFLAGS"
2162 ], [test x$have_threads = xwin32], [
2163            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2164            g_threads_impl="WIN32"
2165 ], [
2166            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2167            g_threads_impl="NONE"
2168            G_THREAD_LIBS=error
2169 ])
2170 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2171 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2172 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2173
2174 if test "x$G_THREAD_LIBS" = xerror; then
2175         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2176 fi
2177
2178 AC_MSG_CHECKING(thread related libraries)
2179 AC_MSG_RESULT($G_THREAD_LIBS)
2180
2181 dnl check for mt safe function variants and some posix functions
2182 dnl ************************************************************
2183
2184 glib_save_LIBS="$LIBS"
2185 # we are not doing the following for now, as this might require glib
2186 # to always be linked with the thread libs on some platforms.
2187 # LIBS="$LIBS $G_THREAD_LIBS"
2188 AC_CHECK_FUNCS(localtime_r gmtime_r)
2189 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2190         AC_CACHE_CHECK([for posix getpwuid_r],
2191                 ac_cv_func_posix_getpwuid_r,
2192                 [AC_TRY_RUN([
2193 #include <errno.h>
2194 #include <pwd.h>
2195 int main () {
2196     char buffer[10000];
2197     struct passwd pwd, *pwptr = &pwd;
2198     int error;
2199     errno = 0;
2200     error = getpwuid_r (0, &pwd, buffer,
2201                         sizeof (buffer), &pwptr);
2202    return (error < 0 && errno == ENOSYS)
2203            || error == ENOSYS;
2204 }                               ],
2205                         [ac_cv_func_posix_getpwuid_r=yes],
2206                         [ac_cv_func_posix_getpwuid_r=no])])
2207         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2208         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2209                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2210                         [Have POSIX function getpwuid_r])
2211         else
2212                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2213                         ac_cv_func_nonposix_getpwuid_r,
2214                         [AC_TRY_LINK([#include <pwd.h>],
2215                                 [char buffer[10000];
2216                                 struct passwd pwd;
2217                                 getpwuid_r (0, &pwd, buffer,
2218                                                 sizeof (buffer));],
2219                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2220                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2221                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2222                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2223                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2224                                 [Have non-POSIX function getpwuid_r])
2225                 fi
2226         fi
2227 ])
2228 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2229         AC_CACHE_CHECK([for posix getgrgid_r],
2230                 ac_cv_func_posix_getgrgid_r,
2231                 [AC_TRY_RUN([
2232 #include <errno.h>
2233 #include <grp.h>
2234 int main () {
2235     char buffer[10000];
2236     struct group grp, *grpptr = &grp;
2237     int error;
2238     errno = 0;
2239     error = getgrgid_r (0, &grp, buffer,
2240                         sizeof (buffer), &grpptr);
2241    return (error < 0 && errno == ENOSYS)
2242            || error == ENOSYS;
2243 }                              ],
2244                        [ac_cv_func_posix_getgrgid_r=yes],
2245                        [ac_cv_func_posix_getgrgid_r=no])])
2246         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2247         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2248                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2249                         [Have POSIX function getgrgid_r])
2250         ], [
2251                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2252                         ac_cv_func_nonposix_getgrgid_r,
2253                         [AC_TRY_LINK([#include <grp.h>],
2254                                 [char buffer[10000];
2255                                 struct group grp;
2256                                 getgrgid_r (0, &grp, buffer,
2257                                 sizeof (buffer));],
2258                         [ac_cv_func_nonposix_getgrgid_r=yes],
2259                         [ac_cv_func_nonposix_getgrgid_r=no])])
2260                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2261                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2262                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2263                                 [Have non-POSIX function getgrgid_r])
2264                 fi
2265         ])
2266 ])
2267 LIBS="$G_THREAD_LIBS $LIBS"
2268 AS_IF([ test x"$have_threads" = xposix], [
2269         glib_save_CPPFLAGS="$CPPFLAGS"
2270         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2271         # This is not AC_CHECK_FUNC to also work with function
2272         # name mangling in header files.
2273         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2274         AC_LINK_IFELSE(
2275             [AC_LANG_PROGRAM(
2276                 [#include <pthread.h>],
2277                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2278             [AC_MSG_RESULT(yes)
2279              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2280                 [Have function pthread_attr_setstacksize])],
2281             [AC_MSG_RESULT(no)])
2282         AC_MSG_CHECKING(for pthread_condattr_setclock)
2283         AC_LINK_IFELSE(
2284             [AC_LANG_PROGRAM(
2285                 [#include <pthread.h>],
2286                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2287             [AC_MSG_RESULT(yes)
2288              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2289                 [Have function pthread_condattr_setclock])],
2290             [AC_MSG_RESULT(no)])
2291         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic)
2292         AC_LINK_IFELSE(
2293             [AC_LANG_PROGRAM(
2294                 [#include <pthread.h>],
2295                 [pthread_cond_timedwait_monotonic(NULL, NULL, NULL)])],
2296             [AC_MSG_RESULT(yes)
2297              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC,1,
2298                 [Have function pthread_cond_timedwait_monotonic])],
2299             [AC_MSG_RESULT(no)])
2300         AC_MSG_CHECKING(for pthread_cond_timedwait_monotonic_np)
2301         AC_LINK_IFELSE(
2302             [AC_LANG_PROGRAM(
2303                 [#include <pthread.h>],
2304                 [pthread_cond_timedwait_monotonic_np(NULL, NULL, NULL)])],
2305             [AC_MSG_RESULT(yes)
2306              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_MONOTONIC_NP,1,
2307                 [Have function pthread_cond_timedwait_monotonic_np])],
2308             [AC_MSG_RESULT(no)])
2309         CPPFLAGS="$glib_save_CPPFLAGS"
2310 ])
2311
2312 LIBS="$glib_save_LIBS"
2313
2314 # now spit out all the warnings.
2315 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2316    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2317         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2318 fi
2319 if test "$ac_cv_func_localtime_r" != "yes"; then
2320         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2321 fi
2322
2323 #
2324 # Hack to deal with:
2325 #
2326 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2327 #     building shared libraries with linux.
2328 #  b) FreeBSD doesn't do this either.
2329 #
2330 case $host in
2331   *android*)
2332     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2333     ;;
2334   *-*-freebsd*|*-*-linux*)
2335     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2336     ;;
2337   *-*-openbsd*)
2338     LDFLAGS="$LDFLAGS -pthread"
2339     ;;
2340   *)
2341     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2342     ;;
2343 esac
2344
2345 AC_SUBST(G_THREAD_CFLAGS)
2346 AC_SUBST(G_THREAD_LIBS)
2347 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2348 AC_SUBST(G_THREAD_LIBS_EXTRA)
2349
2350 AC_CHECK_FUNCS(clock_gettime, [], [
2351   AC_CHECK_LIB(rt, clock_gettime, [
2352     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2353     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2354     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2355   ])
2356 ])
2357
2358
2359 dnl ************************
2360 dnl *** g_atomic_* tests ***
2361 dnl ************************
2362
2363 dnl We need to decide at configure time if GLib will use real atomic
2364 dnl operations ("lock free") or emulated ones with a mutex.  This is
2365 dnl because we must put this information in glibconfig.h so we know if
2366 dnl it is safe or not to inline using compiler intrinsics directly from
2367 dnl the header.
2368 dnl
2369 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2370 dnl user is interested in knowing if they can use the atomic ops across
2371 dnl processes.
2372 dnl
2373 dnl We can currently support the atomic ops natively when building GLib
2374 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2375 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2376 dnl we are using GCC (and not mingw*).
2377 dnl
2378 dnl Note that the atomic ops are only available with GCC on x86 when
2379 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2380 dnl not available but would be available given the right flags, we want
2381 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2382 dnl that then to silently fall back on emulated atomic ops just because
2383 dnl the user had the wrong build environment.
2384
2385 dnl We may add other compilers here in the future...
2386
2387 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2388   case $host in
2389     *-*-mingw*)
2390       glib_cv_g_atomic_lock_free=yes
2391       ;;
2392     *)
2393       AC_TRY_LINK([],
2394                      [volatile int atomic = 2;\
2395                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2396                      [glib_cv_g_atomic_lock_free=yes],
2397                      [glib_cv_g_atomic_lock_free=no])
2398       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2399         SAVE_CFLAGS="${CFLAGS}"
2400         CFLAGS="-march=i486"
2401         AC_TRY_LINK([],
2402                        [volatile int atomic = 2;\
2403                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2404                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2405                        [])
2406         CFLAGS="${SAVE_CFLAGS}"
2407       fi
2408       ;;
2409   esac])
2410
2411
2412 case $host in
2413   *-*-mingw*)
2414     ;;
2415   *)
2416     # Some compilers support atomic operations but do not define
2417     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2418     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2419       AC_TRY_LINK([],
2420                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2421                      [],
2422                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2423     fi
2424     ;;
2425  esac
2426
2427 dnl We need a more robust approach here...
2428 case $host_cpu in
2429   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2430     glib_memory_barrier_needed=no
2431     ;;
2432   sparc*|alpha*|powerpc*|ia64)
2433     glib_memory_barrier_needed=yes
2434     ;;
2435   *)
2436     glib_memory_barrier_needed=yes
2437     ;;
2438 esac
2439
2440 dnl ************************
2441 dnl ** Check for futex(2) **
2442 dnl ************************
2443 AC_CACHE_CHECK(for futex(2) system call,
2444     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2445 #include <linux/futex.h>
2446 #include <sys/syscall.h>
2447 #include <unistd.h>
2448 ],[
2449 int
2450 main (void)
2451 {
2452   /* it is not like this actually runs or anything... */
2453   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2454   return 0;
2455 }
2456 ])],glib_cv_futex=yes,glib_cv_futex=no))
2457 if test x"$glib_cv_futex" = xyes; then
2458   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2459 fi
2460
2461 AC_CACHE_CHECK(for eventfd(2) system call,
2462     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2463 #include <sys/eventfd.h>
2464 #include <unistd.h>
2465 ],[
2466 int
2467 main (void)
2468 {
2469   eventfd (0, EFD_CLOEXEC);
2470   return 0;
2471 }
2472 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2473 if test x"$glib_cv_eventfd" = x"yes"; then
2474   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2475 fi
2476 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2477
2478 dnl ****************************************
2479 dnl *** GLib POLL* compatibility defines ***
2480 dnl ****************************************
2481
2482 glib_poll_includes=["
2483 #include <sys/types.h>
2484 #include <sys/poll.h>
2485 "]
2486
2487 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2488    test $ac_cv_header_sys_poll_h = yes ], [
2489   glib_failed=false
2490   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2491   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2492   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2493   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2494   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2495   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2496   if $glib_failed ; then
2497     AC_MSG_ERROR([Could not determine values for POLL* constants])
2498   fi
2499 ], [
2500   glib_cv_value_POLLIN=1
2501   glib_cv_value_POLLOUT=4
2502   glib_cv_value_POLLPRI=2
2503   glib_cv_value_POLLERR=8
2504   glib_cv_value_POLLHUP=16
2505   glib_cv_value_POLLNVAL=32
2506 ])
2507
2508 AC_MSG_CHECKING([for broken poll])
2509 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2510         #include <stdlib.h>
2511         #include <fcntl.h>
2512         #include <poll.h>
2513         #ifdef HAVE_SYS_POLL_H
2514         #include <sys/poll.h>
2515         #endif
2516         int main(void) {
2517           struct pollfd fds[1];
2518           int fd;
2519           fd = open("/dev/null", 1);
2520           fds[0].fd = fd;
2521           fds[0].events = POLLIN;
2522           fds[0].revents = 0;
2523           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2524                 exit(1);  /* Does not work for devices -- fail */
2525           }
2526           exit(0);
2527         }]])],
2528   [broken_poll=no],
2529   [broken_poll=yes
2530    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2531   [broken_poll="no (cross compiling)"])
2532 AC_MSG_RESULT($broken_poll)
2533
2534 dnl *********************
2535 dnl *** GRegex checks ***
2536 dnl *********************
2537
2538 PCRE_REQUIRED_VERSION=8.13
2539
2540 # Check if we should use the internal or the system-supplied pcre
2541 AC_ARG_WITH(pcre,
2542             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2543                             [whether to use system PCRE [default=internal]])])
2544
2545 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2546
2547 AS_IF([ test "x$with_pcre" = xsystem], [
2548   PKG_CHECK_MODULES(PCRE,
2549                     libpcre >= $PCRE_REQUIRED_VERSION)
2550   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2551                   glib_save_CFLAGS="$CFLAGS"
2552                   glib_save_LIBS="$LIBS"
2553                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2554                   AC_TRY_RUN([#include <pcre.h>
2555                               int main () {
2556                                 int support;
2557                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2558                                 if (!support)
2559                                   return 1;
2560                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2561                                 if (!support)
2562                                   return 1;
2563                                 return 0;
2564                               }],
2565                   glib_cv_pcre_has_unicode=yes,
2566                   glib_cv_pcre_has_unicode=no,
2567                   glib_cv_pcre_has_unicode=yes)
2568                   CFLAGS="$glib_save_CFLAGS"
2569                   LIBS="$glib_save_LIBS"
2570       ])
2571   if test "$glib_cv_pcre_has_unicode" = "no"; then
2572     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2573   fi
2574   AC_SUBST(PCRE_CFLAGS)
2575   AC_SUBST(PCRE_LIBS)
2576   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2577   PCRE_REQUIRES=libpcre
2578   AC_SUBST(PCRE_REQUIRES)
2579 ], [
2580   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2581   AS_IF([ test x"$GCC" = xyes], [
2582     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2583     save_CFLAGS="$CFLAGS"
2584     CFLAGS="$CFLAGS -Wno-pointer-sign"
2585     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2586                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2587     CFLAGS="$save_CFLAGS"
2588   ])
2589 ])
2590 AC_SUBST(PCRE_WARN_CFLAGS)
2591
2592 dnl **********************
2593 dnl *** Win32 API libs ***
2594 dnl **********************
2595
2596 case $host in
2597   *-*-cygwin*)
2598         G_LIBS_EXTRA="-luser32 -lkernel32"
2599     ;;
2600   *-*-mingw*)
2601         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2602     ;;
2603   *)
2604         G_LIBS_EXTRA=""
2605     ;;
2606 esac
2607 AC_SUBST(G_LIBS_EXTRA)
2608
2609 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2610 dnl since we need it for g_iconv()
2611
2612 AC_MSG_CHECKING([for EILSEQ])
2613 AC_TRY_COMPILE([
2614 #include <errno.h>
2615 ],
2616 [
2617 int error = EILSEQ;
2618 ], have_eilseq=yes, have_eilseq=no);
2619 AC_MSG_RESULT($have_eilseq)
2620
2621 dnl ******************************************************************
2622 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2623 dnl *** glib-compile-schemas in PATH                               ***
2624 dnl ******************************************************************
2625
2626 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2627
2628 AS_IF([ test $cross_compiling = yes ], [
2629   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2630   if test x$GLIB_GENMARSHAL = xno; then
2631     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2632   fi
2633
2634   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2635   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2636     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2637   fi
2638
2639   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2640   if test x$GLIB_COMPILE_RESOURCES = xno; then
2641     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2642   fi
2643 ])
2644
2645 dnl **************************
2646 dnl *** Checks for gtk-doc ***
2647 dnl **************************
2648 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2649 # it on it's own line.
2650 m4_ifdef([GTK_DOC_CHECK], [
2651 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2652 ],[
2653 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2654 ])
2655
2656 AC_ARG_ENABLE(man,
2657               [AS_HELP_STRING([--enable-man],
2658                               [generate man pages [default=auto]])],,
2659               enable_man=maybe)
2660
2661 AS_IF([test "$enable_man" != no], [
2662   AC_PATH_PROG([XSLTPROC], [xsltproc])
2663   AS_IF([test -z "$XSLTPROC"], [
2664     AS_IF([test "$enable_man" = yes], [
2665       AC_MSG_ERROR([xsltproc is required for --enable-man])
2666     ])
2667     enable_man=no
2668   ])
2669 ])
2670
2671 AS_IF([ test "$enable_man" != no ], [
2672   dnl check for DocBook DTD in the local catalog
2673   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2674      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2675   AS_IF([test "$have_docbook_dtd" != yes], [
2676     AS_IF([test "$enable_man" = yes ], [
2677       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2678     ])
2679     enable_man=no
2680   ])
2681 ])
2682
2683 AS_IF([test "$enable_man" != no], [
2684   dnl check for DocBook XSL stylesheets in the local catalog
2685   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2686      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2687   AS_IF([ test "$have_docbook_dtd" != yes ], [
2688     AS_IF([ test "$enable_man" = yes ], [
2689       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2690     ])
2691     enable_man=no
2692   ])
2693 ])
2694
2695 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2696
2697 AC_MSG_CHECKING([whether to generate man pages])
2698 AS_IF([ test "$enable_man" != no ], [
2699   AC_MSG_RESULT([yes])
2700 ], [
2701   AC_MSG_RESULT([no])
2702 ])
2703
2704 dnl
2705 dnl Tracing
2706 dnl
2707
2708 AC_ARG_ENABLE([dtrace],
2709              [AS_HELP_STRING([--enable-dtrace],
2710                               [include tracing support for dtrace])])
2711 have_dtrace=no
2712 AC_MSG_CHECKING([whether to include dtrace tracing support])
2713 AS_IF([ test "x$enable_dtrace" != xno], [
2714   if test x$glib_have_carbon = xyes; then
2715     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2716   else
2717     AC_MSG_RESULT([yes])
2718     AC_CHECK_PROGS(DTRACE, dtrace)
2719     if test -z "$DTRACE"; then
2720       if test "x$enable_dtrace" = xyes; then
2721         AC_MSG_ERROR([dtrace not found])
2722       fi
2723     else
2724       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2725                       [if test "x$enable_dtrace" = xyes; then
2726                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2727                        fi])
2728     fi
2729   fi
2730 ], [
2731   AC_MSG_RESULT([no])
2732 ])
2733 if test "x$have_dtrace" = xyes; then
2734   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2735 fi
2736 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2737
2738 AC_MSG_CHECKING([whether to include systemtap tracing support])
2739 AC_ARG_ENABLE([systemtap],
2740              [AS_HELP_STRING([--enable-systemtap],
2741                               [include tracing support for systemtap])])
2742 have_systemtap=no
2743 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2744   have_systemtap=yes
2745 fi
2746 AC_MSG_RESULT(${have_systemtap})
2747
2748 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2749
2750 AC_ARG_WITH([tapset-install-dir],
2751             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2752                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2753             [if test "x${withval}" = x; then
2754                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2755              else
2756                ABS_TAPSET_DIR="${withval}"
2757               fi],
2758             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2759 AC_SUBST(ABS_TAPSET_DIR)
2760
2761 dnl ************************************
2762 dnl *** Enable lcov coverage reports ***
2763 dnl ************************************
2764
2765 AC_ARG_ENABLE(gcov,
2766   AS_HELP_STRING([--enable-gcov],
2767                  [enable coverage testing with gcov]),
2768   [use_gcov=$enableval], [use_gcov=no])
2769
2770 AS_IF([ test "x$use_gcov" = "xyes"], [
2771   dnl we need gcc:
2772   if test "$GCC" != "yes"; then
2773     AC_MSG_ERROR([GCC is required for --enable-gcov])
2774   fi
2775
2776   dnl Check if ccache is being used
2777   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2778   case `$SHTOOL path $CC` in
2779     *ccache*[)] gcc_ccache=yes;;
2780     *[)] gcc_ccache=no;;
2781   esac
2782
2783   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2784     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2785   fi
2786
2787   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2788   AC_CHECK_PROG(LTP, lcov, lcov)
2789   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2790
2791   AS_IF([ test "$LTP" ], [
2792     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2793       glib_cv_ltp_version=invalid
2794       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2795       for ltp_check_version in $ltp_version_list; do
2796         if test "$ltp_version" = "$ltp_check_version"; then
2797           glib_cv_ltp_version="$ltp_check_version (ok)"
2798         fi
2799       done
2800     ])
2801   ], [
2802     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2803     AC_MSG_ERROR([$ltp_msg])
2804   ])
2805
2806   case $glib_cv_ltp_version in
2807     ""|invalid[)]
2808       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2809       AC_MSG_ERROR([$ltp_msg])
2810       LTP="exit 0;"
2811       ;;
2812   esac
2813
2814   if test -z "$LTP_GENHTML"; then
2815     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2816   fi
2817
2818   dnl Remove all optimization flags from CFLAGS
2819   changequote({,})
2820   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2821   changequote([,])
2822
2823   dnl Add the special gcc flags
2824   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2825   LDFLAGS="$LDFLAGS -lgcov"
2826 ])
2827
2828 dnl ******************************
2829 dnl *** output the whole stuff ***
2830 dnl ******************************
2831
2832 dnl this section will only be run if config.status is invoked with no
2833 dnl arguments, or with "glib/glibconfig.h" as an argument.
2834 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2835 [
2836         outfile=glib/glibconfig.h-tmp
2837         cat > $outfile <<\_______EOF
2838 /* glibconfig.h
2839  *
2840  * This is a generated file.  Please modify 'configure.ac'
2841  */
2842
2843 #ifndef __GLIBCONFIG_H__
2844 #define __GLIBCONFIG_H__
2845
2846 #include <glib/gmacros.h>
2847
2848 _______EOF
2849
2850         if test x$glib_limits_h = xyes; then
2851           echo '#include <limits.h>' >> $outfile
2852         fi
2853         if test x$glib_float_h = xyes; then
2854           echo '#include <float.h>' >> $outfile
2855         fi
2856         if test x$glib_values_h = xyes; then
2857           echo '#include <values.h>' >> $outfile
2858         fi
2859         if test "$glib_header_alloca_h" = "yes"; then
2860           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2861         fi
2862         if test x$glib_sys_poll_h = xyes; then
2863           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2864         fi
2865         if test x$glib_included_printf != xyes; then
2866           echo "
2867 /* Specifies that GLib's g_print*() functions wrap the
2868  * system printf functions.  This is useful to know, for example,
2869  * when using glibc's register_printf_function().
2870  */" >> $outfile
2871           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2872         fi
2873
2874         cat >> $outfile <<_______EOF
2875
2876 G_BEGIN_DECLS
2877
2878 #define G_MINFLOAT      $glib_mf
2879 #define G_MAXFLOAT      $glib_Mf
2880 #define G_MINDOUBLE     $glib_md
2881 #define G_MAXDOUBLE     $glib_Md
2882 #define G_MINSHORT      $glib_ms
2883 #define G_MAXSHORT      $glib_Ms
2884 #define G_MAXUSHORT     $glib_Mus
2885 #define G_MININT        $glib_mi
2886 #define G_MAXINT        $glib_Mi
2887 #define G_MAXUINT       $glib_Mui
2888 #define G_MINLONG       $glib_ml
2889 #define G_MAXLONG       $glib_Ml
2890 #define G_MAXULONG      $glib_Mul
2891
2892 _______EOF
2893
2894
2895         ### this should always be true in a modern C/C++ compiler
2896         cat >>$outfile <<_______EOF
2897 typedef signed char gint8;
2898 typedef unsigned char guint8;
2899 _______EOF
2900
2901
2902         if test -n "$gint16"; then
2903           cat >>$outfile <<_______EOF
2904 typedef signed $gint16 gint16;
2905 typedef unsigned $gint16 guint16;
2906 #define G_GINT16_MODIFIER $gint16_modifier
2907 #define G_GINT16_FORMAT $gint16_format
2908 #define G_GUINT16_FORMAT $guint16_format
2909 _______EOF
2910         fi
2911
2912
2913         if test -n "$gint32"; then
2914           cat >>$outfile <<_______EOF
2915 typedef signed $gint32 gint32;
2916 typedef unsigned $gint32 guint32;
2917 #define G_GINT32_MODIFIER $gint32_modifier
2918 #define G_GINT32_FORMAT $gint32_format
2919 #define G_GUINT32_FORMAT $guint32_format
2920 _______EOF
2921         fi
2922
2923         cat >>$outfile <<_______EOF
2924 #define G_HAVE_GINT64 1          /* deprecated, always true */
2925
2926 ${glib_extension}typedef signed $gint64 gint64;
2927 ${glib_extension}typedef unsigned $gint64 guint64;
2928
2929 #define G_GINT64_CONSTANT(val)  $gint64_constant
2930 #define G_GUINT64_CONSTANT(val) $guint64_constant
2931 _______EOF
2932
2933         if test x$gint64_format != x ; then
2934           cat >>$outfile <<_______EOF
2935 #define G_GINT64_MODIFIER $gint64_modifier
2936 #define G_GINT64_FORMAT $gint64_format
2937 #define G_GUINT64_FORMAT $guint64_format
2938 _______EOF
2939         else
2940           cat >>$outfile <<_______EOF
2941 #undef G_GINT64_MODIFIER
2942 #undef G_GINT64_FORMAT
2943 #undef G_GUINT64_FORMAT
2944 _______EOF
2945         fi
2946
2947         cat >>$outfile <<_______EOF
2948
2949 #define GLIB_SIZEOF_VOID_P $glib_void_p
2950 #define GLIB_SIZEOF_LONG   $glib_long
2951 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2952 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2953
2954 _______EOF
2955
2956         cat >>$outfile <<_______EOF
2957 typedef signed $glib_ssize_type_define gssize;
2958 typedef unsigned $glib_size_type_define gsize;
2959 #define G_GSIZE_MODIFIER $gsize_modifier
2960 #define G_GSSIZE_MODIFIER $gssize_modifier
2961 #define G_GSIZE_FORMAT $gsize_format
2962 #define G_GSSIZE_FORMAT $gssize_format
2963
2964 #define G_MAXSIZE       G_MAXU$glib_msize_type
2965 #define G_MINSSIZE      G_MIN$glib_mssize_type
2966 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2967
2968 typedef gint64 goffset;
2969 #define G_MINOFFSET     G_MININT64
2970 #define G_MAXOFFSET     G_MAXINT64
2971
2972 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2973 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2974 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2975
2976 _______EOF
2977
2978         if test -z "$glib_unknown_void_p"; then
2979           cat >>$outfile <<_______EOF
2980
2981 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2982 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2983
2984 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2985 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2986
2987 typedef signed $glib_intptr_type_define gintptr;
2988 typedef unsigned $glib_intptr_type_define guintptr;
2989
2990 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2991 #define G_GINTPTR_FORMAT        $gintptr_format
2992 #define G_GUINTPTR_FORMAT       $guintptr_format
2993 _______EOF
2994         else
2995           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2996         fi
2997
2998
2999
3000         cat >>$outfile <<_______EOF
3001 $glib_atexit
3002 $glib_memmove
3003 $glib_defines
3004 $glib_os
3005 $glib_static_compilation
3006
3007 $glib_vacopy
3008
3009 #ifdef  __cplusplus
3010 #define G_HAVE_INLINE   1
3011 #else   /* !__cplusplus */
3012 $glib_inline
3013 #endif  /* !__cplusplus */
3014
3015 #ifdef  __cplusplus
3016 #define G_CAN_INLINE    1
3017 _______EOF
3018
3019         if test x$g_can_inline = xyes ; then
3020                 cat >>$outfile <<_______EOF
3021 #else   /* !__cplusplus */
3022 #define G_CAN_INLINE    1
3023 _______EOF
3024         fi
3025
3026         cat >>$outfile <<_______EOF
3027 #endif
3028
3029 _______EOF
3030
3031         if test x$g_have_iso_c_varargs = xyes ; then
3032                 cat >>$outfile <<_______EOF
3033 #ifndef __cplusplus
3034 # define G_HAVE_ISO_VARARGS 1
3035 #endif
3036 _______EOF
3037         fi
3038         if test x$g_have_iso_cxx_varargs = xyes ; then
3039                 cat >>$outfile <<_______EOF
3040 #ifdef __cplusplus
3041 # define G_HAVE_ISO_VARARGS 1
3042 #endif
3043 _______EOF
3044         fi
3045         if test x$g_have_gnuc_varargs = xyes ; then
3046                 cat >>$outfile <<_______EOF
3047
3048 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3049  * is passed ISO vararg support is turned off, and there is no work
3050  * around to turn it on, so we unconditionally turn it off.
3051  */
3052 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3053 #  undef G_HAVE_ISO_VARARGS
3054 #endif
3055
3056 #define G_HAVE_GNUC_VARARGS 1
3057 _______EOF
3058         fi
3059
3060         case x$g_stack_grows in
3061         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3062         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3063         esac
3064
3065
3066         echo >>$outfile
3067         if test x$g_have_eilseq = xno; then
3068                 cat >>$outfile <<_______EOF
3069 #ifndef EILSEQ
3070 /* On some pre-C99 systems, EILSEQ is not defined.
3071  * The correspondence between this and the corresponding definition
3072  * in libiconv is essential.
3073  */
3074 #  define EILSEQ ENOENT
3075 #endif
3076 _______EOF
3077
3078         fi
3079
3080         if test x$g_have_gnuc_visibility = xyes; then
3081                 cat >>$outfile <<_______EOF
3082 #define G_HAVE_GNUC_VISIBILITY 1
3083 _______EOF
3084         fi
3085                 cat >>$outfile <<_______EOF
3086 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3087 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3088 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3089 #define G_GNUC_INTERNAL __hidden
3090 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3091 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3092 #else
3093 #define G_GNUC_INTERNAL
3094 #endif
3095 _______EOF
3096
3097         echo >>$outfile
3098         cat >>$outfile <<_______EOF
3099 #define G_THREADS_ENABLED
3100 #define G_THREADS_IMPL_$g_threads_impl_def
3101 _______EOF
3102
3103         if test x"$g_memory_barrier_needed" != xno; then
3104           echo >>$outfile
3105           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3106         fi
3107         if test x"$g_atomic_lock_free" = xyes; then
3108           echo >>$outfile
3109           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3110         fi
3111         echo >>$outfile
3112         g_bit_sizes="16 32 64"
3113         for bits in $g_bit_sizes; do
3114           cat >>$outfile <<_______EOF
3115 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3116 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3117 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3118 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3119 _______EOF
3120         done
3121
3122         cat >>$outfile <<_______EOF
3123 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3124 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3125 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3126 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3127 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3128 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3129 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3130 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3131 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3132 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3133 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3134 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3135 #define G_BYTE_ORDER $g_byte_order
3136
3137 #define GLIB_SYSDEF_POLLIN =$g_pollin
3138 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3139 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3140 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3141 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3142 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3143
3144 #define G_MODULE_SUFFIX "$g_module_suffix"
3145
3146 typedef $g_pid_type GPid;
3147
3148 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3149 #define GLIB_SYSDEF_AF_INET $g_af_inet
3150 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3151
3152 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3153 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3154 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3155
3156 G_END_DECLS
3157
3158 #endif /* __GLIBCONFIG_H__ */
3159 _______EOF
3160
3161
3162         if cmp -s $outfile glib/glibconfig.h; then
3163           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3164           rm -f $outfile
3165         else
3166           mv $outfile glib/glibconfig.h
3167         fi
3168 ],[
3169
3170 # Note that if two cases are the same, case goes with the first one.
3171 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3172 # on variable expansion in case labels.  Look at the generated config.status
3173 # for a hint.
3174
3175 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3176   glib_header_alloca_h="$ac_cv_working_alloca_h"
3177 else
3178   glib_header_alloca_h="$ac_cv_header_alloca_h"
3179 fi
3180
3181 case xyes in
3182 x$ac_cv_header_float_h)
3183   glib_float_h=yes
3184   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3185   glib_md=DBL_MIN glib_Md=DBL_MAX
3186   ;;
3187 x$ac_cv_header_values_h)
3188   glib_values_h=yes
3189   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3190   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3191   ;;
3192 esac
3193
3194 case xyes in
3195 x$ac_cv_header_limits_h)
3196   glib_limits_h=yes
3197   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3198   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3199   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3200   ;;
3201 x$ac_cv_header_values_h)
3202   glib_values_h=yes
3203   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3204   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3205   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3206   ;;
3207 esac
3208
3209 if test x$ac_cv_header_sys_poll_h = xyes ; then
3210   glib_sys_poll_h=yes
3211 fi
3212
3213 if test x$enable_included_printf = xyes ; then
3214   glib_included_printf=yes
3215 fi
3216
3217 case 2 in
3218 $ac_cv_sizeof_short)
3219   gint16=short
3220   gint16_modifier='"h"'
3221   gint16_format='"hi"'
3222   guint16_format='"hu"'
3223   ;;
3224 $ac_cv_sizeof_int)
3225   gint16=int
3226   gint16_modifier='""'
3227   gint16_format='"i"'
3228   guint16_format='"u"'
3229   ;;
3230 esac
3231 case 4 in
3232 $ac_cv_sizeof_short)
3233   gint32=short
3234   gint32_modifier='"h"'
3235   gint32_format='"hi"'
3236   guint32_format='"hu"'
3237   ;;
3238 $ac_cv_sizeof_int)
3239   gint32=int
3240   gint32_modifier='""'
3241   gint32_format='"i"'
3242   guint32_format='"u"'
3243   ;;
3244 $ac_cv_sizeof_long)
3245   gint32=long
3246   gint32_modifier='"l"'
3247   gint32_format='"li"'
3248   guint32_format='"lu"'
3249   ;;
3250 esac
3251 case 8 in
3252 $ac_cv_sizeof_int)
3253   gint64=int
3254   gint64_modifier='""'
3255   gint64_format='"i"'
3256   guint64_format='"u"'
3257   glib_extension=
3258   gint64_constant='(val)'
3259   guint64_constant='(val)'
3260   ;;
3261 $ac_cv_sizeof_long)
3262   gint64=long
3263   gint64_modifier='"l"'
3264   gint64_format='"li"'
3265   guint64_format='"lu"'
3266   glib_extension=
3267   gint64_constant='(val##L)'
3268   guint64_constant='(val##UL)'
3269   ;;
3270 $ac_cv_sizeof_long_long)
3271   gint64='long long'
3272   if test -n "$glib_cv_long_long_format"; then
3273     gint64_modifier='"'$glib_cv_long_long_format'"'
3274     gint64_format='"'$glib_cv_long_long_format'i"'
3275     guint64_format='"'$glib_cv_long_long_format'u"'
3276   fi
3277   glib_extension='G_GNUC_EXTENSION '
3278   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3279   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3280   ;;
3281 $ac_cv_sizeof___int64)
3282   gint64='__int64'
3283   if test -n "$glib_cv_long_long_format"; then
3284     gint64_modifier='"'$glib_cv_long_long_format'"'
3285     gint64_format='"'$glib_cv_long_long_format'i"'
3286     guint64_format='"'$glib_cv_long_long_format'u"'
3287   fi
3288   glib_extension=
3289   gint64_constant='(val##i64)'
3290   guint64_constant='(val##ui64)'
3291   ;;
3292 esac
3293 glib_size_t=$ac_cv_sizeof_size_t
3294 glib_ssize_t=$ac_cv_sizeof_ssize_t
3295 glib_size_type_define="$glib_size_type"
3296 glib_ssize_type_define="$glib_ssize_type"
3297 glib_void_p=$ac_cv_sizeof_void_p
3298 glib_long=$ac_cv_sizeof_long
3299
3300 case "$glib_size_type" in
3301 short)
3302   gsize_modifier='"h"'
3303   gsize_format='"hu"'
3304   glib_msize_type='SHRT'
3305   ;;
3306 int)
3307   gsize_modifier='""'
3308   gsize_format='"u"'
3309   glib_msize_type='INT'
3310   ;;
3311 long)
3312   gsize_modifier='"l"'
3313   gsize_format='"lu"'
3314   glib_msize_type='LONG'
3315   ;;
3316 "long long"|__int64)
3317   gsize_modifier='"I64"'
3318   gsize_format='"I64u"'
3319   glib_msize_type='INT64'
3320   ;;
3321 esac
3322
3323 case "$glib_ssize_type" in
3324 short)
3325   gssize_modifier='"h"'
3326   gssize_format='"hi"'
3327   glib_mssize_type='SHRT'
3328   ;;
3329 int)
3330   gssize_modifier='""'
3331   gssize_format='"i"'
3332   glib_mssize_type='INT'
3333   ;;
3334 long)
3335   gssize_modifier='"l"'
3336   gssize_format='"li"'
3337   glib_mssize_type='LONG'
3338   ;;
3339 "long long"|__int64)
3340   gssize_modifier='"I64"'
3341   gssize_format='"I64i"'
3342   glib_mssize_type='INT64'
3343   ;;
3344 esac
3345
3346 gintbits=`expr $ac_cv_sizeof_int \* 8`
3347 glongbits=`expr $ac_cv_sizeof_long \* 8`
3348 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3349 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3350
3351 case $ac_cv_sizeof_void_p in
3352 $ac_cv_sizeof_int)
3353   glib_intptr_type_define=int
3354   gintptr_modifier='""'
3355   gintptr_format='"i"'
3356   guintptr_format='"u"'
3357   glib_gpi_cast='(gint)'
3358   glib_gpui_cast='(guint)'
3359   ;;
3360 $ac_cv_sizeof_long)
3361   glib_intptr_type_define=long
3362   gintptr_modifier='"l"'
3363   gintptr_format='"li"'
3364   guintptr_format='"lu"'
3365   glib_gpi_cast='(glong)'
3366   glib_gpui_cast='(gulong)'
3367   ;;
3368 $ac_cv_sizeof_long_long)
3369   glib_intptr_type_define='long long'
3370   gintptr_modifier='"I64"'
3371   gintptr_format='"I64i"'
3372   guintptr_format='"I64u"'
3373   glib_gpi_cast='(gint64)'
3374   glib_gpui_cast='(guint64)'
3375   ;;
3376 $ac_cv_sizeof___int64)
3377   glib_intptr_type_define=__int64
3378   gintptr_modifier='"I64"'
3379   gintptr_format='"I64i"'
3380   guintptr_format='"I64u"'
3381   glib_gpi_cast='(gint64)'
3382   glib_gpui_cast='(guint64)'
3383   ;;
3384 *)
3385   glib_unknown_void_p=yes
3386   ;;
3387 esac
3388
3389
3390 case xyes in
3391 x$ac_cv_func_atexit)
3392   glib_atexit="
3393 #define g_ATEXIT(proc)  (atexit (proc))"
3394   ;;
3395 x$ac_cv_func_on_exit)
3396   glib_atexit="
3397 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3398   ;;
3399 esac
3400
3401 case xyes in
3402 x$ac_cv_func_memmove)
3403   glib_memmove='
3404 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3405   ;;
3406 x$glib_cv_working_bcopy)
3407   glib_memmove="
3408 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3409 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3410   ;;
3411 *)
3412   glib_memmove="
3413 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3414  * so we have to roll our own copy routine. */
3415 void g_memmove (void* dest, const void * src, unsigned long len);"
3416   ;;
3417 esac
3418
3419 glib_defines="
3420 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3421 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3422 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3423 "
3424
3425 case xyes in
3426 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3427 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3428 *)                      glib_vacopy=''
3429 esac
3430
3431 if test x$glib_cv_va_val_copy = xno; then
3432   glib_vacopy="\$glib_vacopy
3433 #define G_VA_COPY_AS_ARRAY 1"
3434 fi
3435
3436 if test x$glib_cv_hasinline = xyes; then
3437     glib_inline='#define G_HAVE_INLINE 1'
3438 fi
3439 if test x$glib_cv_has__inline = xyes; then
3440     glib_inline="\$glib_inline
3441 #define G_HAVE___INLINE 1"
3442 fi
3443 if test x$glib_cv_has__inline__ = xyes; then
3444     glib_inline="\$glib_inline
3445 #define G_HAVE___INLINE__ 1"
3446 fi
3447
3448 g_have_gnuc_varargs=$g_have_gnuc_varargs
3449 g_have_iso_c_varargs=$g_have_iso_c_varargs
3450 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3451
3452 g_can_inline=$g_can_inline
3453 g_have_gnuc_visibility=$g_have_gnuc_visibility
3454 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3455
3456 if test x$ac_cv_c_bigendian = xyes; then
3457   g_byte_order=G_BIG_ENDIAN
3458   g_bs_native=BE
3459   g_bs_alien=LE
3460 else
3461   g_byte_order=G_LITTLE_ENDIAN
3462   g_bs_native=LE
3463   g_bs_alien=BE
3464 fi
3465
3466 g_pollin=$glib_cv_value_POLLIN
3467 g_pollout=$glib_cv_value_POLLOUT
3468 g_pollpri=$glib_cv_value_POLLPRI
3469 g_pollhup=$glib_cv_value_POLLHUP
3470 g_pollerr=$glib_cv_value_POLLERR
3471 g_pollnval=$glib_cv_value_POLLNVAL
3472
3473 # If a family is not found on the system, define that family to
3474 # a negative value, picking a different one for each undefined
3475 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3476 # This is needed because glib-mkenums doesn't handle optional
3477 # values in enums, and thus we have to have all existing values
3478 # defined in the enum.
3479 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3480   g_af_unix=$glib_cv_value_AF_UNIX
3481 else
3482   g_af_unix=-1
3483 fi
3484 g_af_inet=$glib_cv_value_AF_INET
3485 g_af_inet6=$glib_cv_value_AF_INET6
3486
3487 g_msg_peek=$glib_cv_value_MSG_PEEK
3488 g_msg_oob=$glib_cv_value_MSG_OOB
3489 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3490
3491 g_stack_grows=$glib_cv_stack_grows
3492
3493 g_have_eilseq=$have_eilseq
3494
3495 g_threads_impl_def=$g_threads_impl
3496
3497 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3498 g_memory_barrier_needed="$glib_memory_barrier_needed"
3499 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3500
3501 g_module_suffix="$glib_gmodule_suffix"
3502
3503 g_pid_type="$glib_pid_type"
3504 case $host in
3505   *-*-cygwin*)
3506     glib_os="#define G_OS_UNIX
3507 #define G_PLATFORM_WIN32
3508 #define G_WITH_CYGWIN"
3509     ;;
3510   *-*-mingw*)
3511     glib_os="#define G_OS_WIN32
3512 #define G_PLATFORM_WIN32"
3513     ;;
3514   *)
3515     glib_os="#define G_OS_UNIX"
3516     ;;
3517 esac
3518 glib_static_compilation=""
3519 if test x$glib_win32_static_compilation = xyes; then
3520   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3521 #define GOBJECT_STATIC_COMPILATION 1"
3522 fi
3523 ])
3524
3525 # Redo enough to get guint32 and guint64 for the alignment checks below
3526 case 4 in
3527 $ac_cv_sizeof_short)
3528   gint32=short
3529   ;;
3530 $ac_cv_sizeof_int)
3531   gint32=int
3532   ;;
3533 $ac_cv_sizeof_long)
3534   gint32=long
3535   ;;
3536 esac
3537 case 8 in
3538 $ac_cv_sizeof_int)
3539   gint64=int
3540   ;;
3541 $ac_cv_sizeof_long)
3542   gint64=long
3543   ;;
3544 $ac_cv_sizeof_long_long)
3545   gint64='long long'
3546   ;;
3547 $ac_cv_sizeof___int64)
3548   gint64='__int64'
3549   ;;
3550 esac
3551
3552 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3553 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3554 typedef unsigned $gint32 guint32;])
3555 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3556 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3557 typedef unsigned $gint64 guint64;])
3558 AC_CHECK_TYPE([unsigned long])
3559 AC_CHECK_ALIGNOF([unsigned long])
3560
3561 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3562 #
3563 # 1.2.14 required for dbus_message_set_serial
3564 PKG_CHECK_MODULES(DBUS1,
3565      dbus-1 >= 1.2.14,
3566      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3567      have_dbus1=no)
3568 AC_SUBST(DBUS1_CFLAGS)
3569 AC_SUBST(DBUS1_LIBS)
3570 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3571
3572 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3573 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3574
3575 dnl
3576 dnl Check for -Bsymbolic-functions linker flag used to avoid
3577 dnl intra-library PLT jumps, if available.
3578 dnl
3579
3580 AC_ARG_ENABLE(Bsymbolic,
3581               [AS_HELP_STRING([--disable-Bsymbolic],
3582                               [avoid linking with -Bsymbolic])],,
3583               [SAVED_LDFLAGS="${LDFLAGS}"
3584                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3585                LDFLAGS=-Wl,-Bsymbolic-functions
3586                AC_TRY_LINK([], [int main (void) { return 0; }],
3587                            AC_MSG_RESULT(yes)
3588                            enable_Bsymbolic=yes,
3589                            AC_MSG_RESULT(no)
3590                            enable_Bsymbolic=no)
3591                LDFLAGS="${SAVED_LDFLAGS}"])
3592
3593 if test "x${enable_Bsymbolic}" = "xyes"; then
3594   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3595 fi
3596
3597 AC_SUBST(GLIB_LINK_FLAGS)
3598
3599 dnl
3600 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3601 dnl visibility attributes for symbol export control
3602 dnl
3603 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3604 case "$host" in
3605   *-*-mingw*)
3606     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3607     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3608               [defines how to decorate public symbols while building])
3609     CFLAGS="${CFLAGS} -fvisibility=hidden"
3610     ;;
3611   *)
3612     dnl on other compilers, check if we can do -fvisibility=hidden
3613     SAVED_CFLAGS="${CFLAGS}"
3614     CFLAGS="-fvisibility=hidden"
3615     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3616     AC_TRY_COMPILE([], [int main (void) { return 0; }],
3617                    AC_MSG_RESULT(yes)
3618                    enable_fvisibility_hidden=yes,
3619                    AC_MSG_RESULT(no)
3620                    enable_fvisibility_hidden=no)
3621     CFLAGS="${SAVED_CFLAGS}"
3622
3623     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3624       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3625                 [defines how to decorate public symbols while building])
3626       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3627     ])
3628     ;;
3629 esac
3630 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3631
3632 dnl Compiler flags; macro originates from systemd
3633 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3634 AC_ARG_ENABLE(compile-warnings,
3635               [AS_HELP_STRING([--disable-compile-warnings],
3636                               [Don't use builtin compiler warnings])],,
3637                               enable_compile_warnings=yes)
3638 AS_IF([test "x$enable_compile_warnings" = xyes], [
3639   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3640    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3641    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3642    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3643    -Werror=format=2 -Werror=missing-include-dirs])
3644 ])
3645 AC_SUBST(GLIB_WARN_CFLAGS)
3646
3647 #
3648 # Define variables corresponding to the correct include paths to use for
3649 # in-tree building.
3650 #
3651
3652 # for config.h:
3653 config_h_INCLUDES='-I$(top_builddir)'
3654 AC_SUBST(config_h_INCLUDES)
3655
3656 # glib:
3657 #   config.h
3658 #   $(top_builddir)/glib: for glibconfig.h
3659 #   $(top_srcdir)/glib:   for glib.h
3660 #   $(top_srcdir):        for everything
3661 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3662 AC_SUBST(glib_INCLUDES)
3663
3664 # gobject:
3665 #   same as glib
3666 gobject_INCLUDES='$(glib_INCLUDES)'
3667 AC_SUBST(gobject_INCLUDES)
3668
3669 # gmodule:
3670 #   glib includes
3671 #   $(top_srcdir)/gmodule: for gmodule.h
3672 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3673 AC_SUBST(gmodule_INCLUDES)
3674
3675 # gio:
3676 #   same as gmodule
3677 gio_INCLUDES='$(gmodule_INCLUDES)'
3678 AC_SUBST(gio_INCLUDES)
3679
3680
3681 AC_CONFIG_FILES([
3682 glib-2.0.pc
3683 gmodule-2.0.pc
3684 gmodule-export-2.0.pc
3685 gmodule-no-export-2.0.pc
3686 gthread-2.0.pc
3687 gobject-2.0.pc
3688 gio-2.0.pc
3689 gio-unix-2.0.pc
3690 gio-windows-2.0.pc
3691 glib-zip
3692 glib-gettextize
3693 Makefile
3694 build/Makefile
3695 build/win32/Makefile
3696 build/win32/dirent/Makefile
3697 build/win32/vs9/Makefile
3698 build/win32/vs10/Makefile
3699 build/win32/vs11/Makefile
3700 glib/Makefile
3701 glib/glib.stp
3702 glib/libcharset/Makefile
3703 glib/gnulib/Makefile
3704 glib/pcre/Makefile
3705 glib/update-pcre/Makefile
3706 glib/tests/Makefile
3707 gmodule/Makefile
3708 gmodule/gmoduleconf.h
3709 gobject/Makefile
3710 gobject/gobject.stp
3711 gobject/glib-mkenums
3712 gobject/tests/Makefile
3713 gthread/Makefile
3714 gio/Makefile
3715 gio/gdbus-2.0/codegen/Makefile
3716 gio/gdbus-2.0/codegen/config.py
3717 gio/gnetworking.h
3718 gio/xdgmime/Makefile
3719 gio/inotify/Makefile
3720 gio/kqueue/Makefile
3721 gio/fen/Makefile
3722 gio/fam/Makefile
3723 gio/win32/Makefile
3724 gio/tests/Makefile
3725 gio/tests/gdbus-object-manager-example/Makefile
3726 gio/tests/services/Makefile
3727 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3728 po/Makefile.in
3729 docs/Makefile
3730 docs/reference/Makefile
3731 docs/reference/glib/Makefile
3732 docs/reference/glib/version.xml
3733 docs/reference/gobject/Makefile
3734 docs/reference/gobject/version.xml
3735 docs/reference/gio/Makefile
3736 docs/reference/gio/gdbus-object-manager-example/Makefile
3737 docs/reference/gio/version.xml
3738 tests/Makefile
3739 tests/gobject/Makefile
3740 tests/refcount/Makefile
3741 m4macros/Makefile
3742 ])
3743
3744 AC_CONFIG_COMMANDS([chmod-scripts],
3745 [chmod 0755 glib-zip
3746 chmod 0755 glib-gettextize
3747 chmod 0755 gobject/glib-mkenums])
3748
3749 # we want to invoke this macro solely so that the config.status script
3750 # and automake generated makefiles know about these generated files.
3751 # They are only needed to distcheck the package
3752 if false; then
3753   AC_CONFIG_FILES([
3754     INSTALL
3755     README
3756     config.h.win32
3757     glib/glibconfig.h.win32
3758     glib/makefile.msc
3759     glib/glib.rc
3760     gmodule/makefile.msc
3761     gmodule/gmodule.rc
3762     gobject/makefile.msc
3763     gobject/gobject.rc
3764     gthread/makefile.msc
3765     gthread/gthread.rc
3766     gio/gio.rc
3767     tests/makefile.msc
3768   ])
3769 fi
3770
3771 AC_OUTPUT