configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [4])
   6 m4_define([dbus_micro_version], [13])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_CONFIG_HEADERS([config.h])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE([1.10 tar-ustar -Wno-portability])
  17
  18 GETTEXT_PACKAGE=dbus-1
  19 AC_SUBST(GETTEXT_PACKAGE)
  20 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  21
  22  ## must come before we use the $USE_MAINTAINER_MODE variable later
  23 AM_MAINTAINER_MODE
  24
  25 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  26
  27 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  28
  29 # libtool versioning - this applies to libdbus
  30 #
  31 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  32 #
  33
  34 ## increment if the interface has additions, changes, removals.
  35 LT_CURRENT=8
  36
  37 ## increment any time the source changes; set to
  38 ##  0 if you increment CURRENT
  39 LT_REVISION=7
  40
  41 ## increment if any interfaces have been added; set to 0
  42 ## if any interfaces have been changed or removed. removal has
  43 ## precedence over adding, so set to 0 if both happened.
  44 LT_AGE=5
  45
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 AC_SUBST(LT_AGE)
  49
  50 DBUS_MAJOR_VERSION=dbus_major_version
  51 DBUS_MINOR_VERSION=dbus_minor_version
  52 DBUS_MICRO_VERSION=dbus_micro_version
  53 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  54
  55 AC_SUBST(DBUS_MAJOR_VERSION)
  56 AC_SUBST(DBUS_MINOR_VERSION)
  57 AC_SUBST(DBUS_MICRO_VERSION)
  58 AC_SUBST(DBUS_VERSION)
  59
  60 AC_PROG_CC
  61 AM_PROG_CC_C_O
  62 AC_PROG_CXX
  63 AC_USE_SYSTEM_EXTENSIONS
  64 AC_ISC_POSIX
  65 AC_HEADER_STDC
  66 AC_C_INLINE
  67 AM_PROG_LIBTOOL
  68 AC_PROG_MKDIR_P
  69 COMPILER_COVERAGE
  70 COMPILER_OPTIMISATIONS
  71
  72 # Initialize libtool
  73 LT_INIT([win32-dll])
  74 LT_LANG([Windows Resource])
  75
  76 # Set some internal variables depending on the platform for later use.
  77 dbus_win=no
  78 dbus_cygwin=no
  79 dbus_unix=no
  80 case "${host}" in
  81     *-mingw32ce*)
  82         dbus_win=yes
  83         dbus_wince=yes
  84         ;;
  85     *-mingw32*)
  86         dbus_win=yes
  87         ;;
  88     *-cygwin*)
  89         dbus_cygwin=yes
  90         dbus_unix=yes
  91         ;;
  92     *)
  93         dbus_unix=yes
  94        ;;
  95 esac
  96
  97 # Special defines for certain platforms
  98 if test "$dbus_win" = yes; then
  99     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 100     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 101     AC_SUBST(BUILD_TIMESTAMP)
 102     # Assume DBUS_VERSION is always three numbers
 103     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 104     AC_SUBST(BUILD_FILEVERSION)
 105     AC_CHECK_TOOL(WINDRES, windres, no)
 106     if test "$WINDRES" = no; then
 107       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 108     fi
 109     if test "$dbus_wince" = yes; then
 110       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 111       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 112     fi
 113 else
 114     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 115 fi
 116 if test "$dbus_cygwin" = yes; then
 117     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 118 fi
 119
 120 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 121 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 122 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 123 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 124
 125 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 126 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
 127 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
 128 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 129 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 130 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 131 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 132 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 133 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 134 AC_ARG_ENABLE(dnotify, AS_HELP_STRING([--enable-dnotify],[build with dnotify support (linux only)]),enable_dnotify=$enableval,enable_dnotify=auto)
 135 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 136 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 137 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 138 AC_ARG_ENABLE(userdb-cache, AS_HELP_STRING([--enable-userdb-cache],[build with userdb-cache support]),enable_userdb_cache=$enableval,enable_userdb_cache=yes)
 139 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 140
 141 AC_ARG_WITH(xml, AS_HELP_STRING([--with-xml=[libxml/expat]],[XML library to use (libxml may be named libxml2 on some systems)]))
 142 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 143 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 144 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 145 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 146 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 147 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 148 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 149 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 150 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 151 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 152
 153 AC_ARG_ENABLE([embedded-tests],
 154   AS_HELP_STRING([--enable-embedded-tests],
 155     [enable unit test code in the library and binaries]),
 156   [], [enable_embedded_tests=$USE_MAINTAINER_MODE])
 157 AC_ARG_ENABLE([modular-tests],
 158   AS_HELP_STRING([--enable-modular-tests],
 159     [enable modular regression tests (requires GLib)]),
 160   [], [enable_modular_tests=auto])
 161 # --enable-tests overrides both --enable-embedded-tests and
 162 # --enable-modular-tests
 163 AC_ARG_ENABLE([tests],
 164   AS_HELP_STRING([--enable-tests],
 165     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 166   [enable_embedded_tests=$enableval; enable_modular_tests=$enableval],
 167   [])
 168
 169 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 170 # and also some stuff in the test/ subdir. DBUS_BUILD_TESTS was an older
 171 # name for this.
 172 AM_CONDITIONAL([DBUS_BUILD_TESTS], [test "x$enable_embedded_tests" = xyes])
 173 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 174   [test "x$enable_embedded_tests" = xyes])
 175 if test "x$enable_embedded_tests" = xyes; then
 176     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 177       [Define to build test code into the library and binaries])
 178     AC_DEFINE([DBUS_BUILD_TESTS], [1],
 179       [Define to build test code into the library and binaries])
 180 fi
 181
 182 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 183 # These use GTest, from GLib, because life's too short. They're enabled by
 184 # default (unless you don't have GLib), because they don't bloat the library
 185 # or binaries.
 186 if test "x$enable_modular_tests" != xno; then
 187   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22, gio-2.0 >= 2.22],
 188     [],
 189     [if test "x$enable_modular_tests" = xyes; then
 190       AC_MSG_ERROR([GLib is required by the modular tests])
 191     else # assumed to be "auto"
 192       enable_modular_tests=no
 193     fi])
 194   # If dbus-gmain.[ch] returned to libdbus then we wouldn't need this
 195   PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1],
 196     [],
 197     [if test "x$enable_modular_tests" = xyes; then
 198       AC_MSG_ERROR([dbus-glib is required by the modular tests (for now)])
 199     else # assumed to be "auto"
 200       enable_modular_tests=no
 201     fi])
 202   if test "x$enable_modular_tests" != xno; then
 203     # dependencies checked, switch from auto to yes
 204     enable_modular_tests=yes
 205   fi
 206 fi
 207 if test "x$enable_modular_tests" = xyes; then
 208   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 209     [Define to build independent test binaries (requires GLib)])
 210 fi
 211 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 212   [test "x$enable_modular_tests" = xyes])
 213
 214 AC_ARG_ENABLE([installed-tests],
 215   AS_HELP_STRING([--enable-installed-tests],
 216     [enable unit test code in the library and binaries]),
 217   [], [enable_installed_tests=no])
 218 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 219   [test "x$enable_installed_tests" = xyes])
 220
 221 if test x$enable_verbose_mode = xyes; then
 222     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 223 fi
 224
 225 if test x$enable_asserts = xno; then
 226     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 227     R_DYNAMIC_LDFLAG=""
 228 else
 229     # -rdynamic is needed for glibc's backtrace_symbols to work.
 230     # No clue how much overhead this adds, but it's useful
 231     # to do this on any assertion failure,
 232     # so for now it's enabled anytime asserts are (currently not
 233     # in production builds).
 234
 235     # To get -rdynamic you pass -export-dynamic to libtool.
 236     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 237     R_DYNAMIC_LDFLAG=-export-dynamic
 238 fi
 239 AC_SUBST(R_DYNAMIC_LDFLAG)
 240
 241 if test x$enable_checks = xno; then
 242     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 243     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 244 fi
 245
 246 if test x$enable_userdb_cache = xyes; then
 247     AC_DEFINE(DBUS_ENABLE_USERDB_CACHE,1,[Build with caching of user data])
 248 fi
 249
 250 if test x$enable_compiler_coverage = xyes; then
 251      ## so that config.h changes when you toggle gcov support
 252      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 253 fi
 254
 255 # glibc21.m4 serial 3
 256 dnl Copyright (C) 2000-2002, 2004 Free Software Foundation, Inc.
 257 dnl This file is free software; the Free Software Foundation
 258 dnl gives unlimited permission to copy and/or distribute it,
 259 dnl with or without modifications, as long as this notice is preserved.
 260
 261 # Test for the GNU C Library, version 2.1 or newer.
 262 # From Bruno Haible.
 263
 264 AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
 265   ac_cv_gnu_library_2_1,
 266   [AC_EGREP_CPP([Lucky GNU user],
 267     [
 268 #include <features.h>
 269 #ifdef __GNU_LIBRARY__
 270  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
 271   Lucky GNU user
 272  #endif
 273 #endif
 274     ],
 275     ac_cv_gnu_library_2_1=yes,
 276     ac_cv_gnu_library_2_1=no)
 277   ]
 278 )
 279
 280 #### Integer sizes
 281
 282 AC_CHECK_SIZEOF(char)
 283 AC_CHECK_SIZEOF(short)
 284 AC_CHECK_SIZEOF(long)
 285 AC_CHECK_SIZEOF(int)
 286 AC_CHECK_SIZEOF(void *)
 287 AC_CHECK_SIZEOF(long long)
 288 AC_CHECK_SIZEOF(__int64)
 289
 290 ### See what our 64 bit type is called
 291 AC_MSG_CHECKING([64-bit integer type])
 292
 293 case 8 in
 294 $ac_cv_sizeof_int)
 295   dbusint64=int
 296   dbusint64_constant='(val)'
 297   dbusuint64_constant='(val)'
 298   dbusint64_printf_modifier='""'
 299   ;;
 300 $ac_cv_sizeof_long)
 301   dbusint64=long
 302   dbusint64_constant='(val##L)'
 303   dbusuint64_constant='(val##UL)'
 304   dbusint64_printf_modifier='"l"'
 305   ;;
 306 $ac_cv_sizeof_long_long)
 307   dbusint64='long long'
 308   dbusint64_constant='(val##LL)'
 309   dbusuint64_constant='(val##ULL)'
 310   # Ideally we discover what the format is, but this is
 311   # only used in verbose mode, so eh...
 312   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 313     dbusint64_printf_modifier='"ll"'
 314   fi
 315   ;;
 316 $ac_cv_sizeof___int64)
 317   dbusint64=__int64
 318   dbusint64_constant='(val##i64)'
 319   dbusuint64_constant='(val##ui64)'
 320   # See above case
 321   if test x"$ac_cv_gnu_library_2_1" = xyes; then
 322     dbusint64_printf_modifier='"ll"'
 323   fi
 324   ;;
 325 esac
 326
 327 if test -z "$dbusint64" ; then
 328         DBUS_INT64_TYPE="no_int64_type_detected"
 329         DBUS_HAVE_INT64=0
 330         DBUS_INT64_CONSTANT=
 331         DBUS_UINT64_CONSTANT=
 332         AC_MSG_RESULT([none found])
 333 else
 334         DBUS_INT64_TYPE="$dbusint64"
 335         DBUS_HAVE_INT64=1
 336         DBUS_INT64_CONSTANT="$dbusint64_constant"
 337         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 338         if test x"$dbusint64_printf_modifier" != x; then
 339                 AC_DEFINE_UNQUOTED(DBUS_INT64_PRINTF_MODIFIER, [$dbusint64_printf_modifier], [Define to printf modifier for 64 bit integer type])
 340         fi
 341         AC_MSG_RESULT($DBUS_INT64_TYPE)
 342 fi
 343
 344 AC_SUBST(DBUS_INT64_TYPE)
 345 AC_SUBST(DBUS_INT64_CONSTANT)
 346 AC_SUBST(DBUS_UINT64_CONSTANT)
 347 AC_SUBST(DBUS_HAVE_INT64)
 348
 349 ### see what 32-bit int is called
 350 AC_MSG_CHECKING([32-bit integer type])
 351
 352 case 4 in
 353 $ac_cv_sizeof_short)
 354   dbusint32=short
 355   ;;
 356 $ac_cv_sizeof_int)
 357   dbusint32=int
 358   ;;
 359 $ac_cv_sizeof_long)
 360   dbusint32=long
 361   ;;
 362 esac
 363
 364 if test -z "$dbusint32" ; then
 365         DBUS_INT32_TYPE="no_int32_type_detected"
 366         AC_MSG_ERROR([No 32-bit integer type found])
 367 else
 368         DBUS_INT32_TYPE="$dbusint32"
 369         AC_MSG_RESULT($DBUS_INT32_TYPE)
 370 fi
 371
 372 AC_SUBST(DBUS_INT32_TYPE)
 373
 374 ### see what 16-bit int is called
 375 AC_MSG_CHECKING([16-bit integer type])
 376
 377 case 2 in
 378 $ac_cv_sizeof_short)
 379   dbusint16=short
 380   ;;
 381 $ac_cv_sizeof_int)
 382   dbusint16=int
 383   ;;
 384 esac
 385
 386 if test -z "$dbusint16" ; then
 387         DBUS_INT16_TYPE="no_int16_type_detected"
 388         AC_MSG_ERROR([No 16-bit integer type found])
 389 else
 390         DBUS_INT16_TYPE="$dbusint16"
 391         AC_MSG_RESULT($DBUS_INT16_TYPE)
 392 fi
 393
 394 AC_SUBST(DBUS_INT16_TYPE)
 395
 396 ## byte order
 397 case $host_os in
 398         darwin*)
 399                 # check at compile-time, so that it is possible to build universal
 400                 # (with multiple architectures at once on the compile line)
 401                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 402                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 403                         #if defined(__BIG_ENDIAN__)
 404                         #define WORDS_BIGENDIAN 1
 405                         #endif
 406                 ])
 407                 ;;
 408         *)
 409                 AC_C_BIGENDIAN
 410                 ;;
 411 esac
 412
 413 dnl **********************************
 414 dnl *** va_copy checks (from GLib) ***
 415 dnl **********************************
 416 dnl we currently check for all three va_copy possibilities, so we get
 417 dnl all results in config.log for bug reports.
 418 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 419         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 420 #include <stdlib.h>
 421         static void f (int i, ...) {
 422         va_list args1, args2;
 423         va_start (args1, i);
 424         va_copy (args2, args1);
 425         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 426           exit (1);
 427         va_end (args1); va_end (args2);
 428         }
 429         int main() {
 430           f (0, 42);
 431           return 0;
 432         }])],
 433         [dbus_cv_va_copy=yes],
 434         [dbus_cv_va_copy=no])
 435 ])
 436 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 437         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 438 #include <stdlib.h>
 439         static void f (int i, ...) {
 440         va_list args1, args2;
 441         va_start (args1, i);
 442         __va_copy (args2, args1);
 443         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 444           exit (1);
 445         va_end (args1); va_end (args2);
 446         }
 447         int main() {
 448           f (0, 42);
 449           return 0;
 450         }])],
 451         [dbus_cv___va_copy=yes],
 452         [dbus_cv___va_copy=no])
 453 ])
 454
 455 if test "x$dbus_cv_va_copy" = "xyes"; then
 456   dbus_va_copy_func=va_copy
 457 else if test "x$dbus_cv___va_copy" = "xyes"; then
 458   dbus_va_copy_func=__va_copy
 459 fi
 460 fi
 461
 462 if test -n "$dbus_va_copy_func"; then
 463   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 464 fi
 465
 466 AC_LANG_PUSH(C)
 467 AC_CACHE_CHECK([whether va_lists can be copied by value],
 468         dbus_cv_va_val_copy,
 469         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 470 [[
 471         #include <stdarg.h>
 472         #include <stdlib.h>
 473 ]],
 474 [[
 475         static void f (int i, ...) {
 476         va_list args1, args2;
 477         va_start (args1, i);
 478         args2 = args1;
 479         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 480           exit (1);
 481         va_end (args1); va_end (args2);
 482         }
 483         int main() {
 484           f (0, 42);
 485           return 0;
 486         }
 487 ]])],
 488         [dbus_cv_va_val_copy=yes],
 489         [dbus_cv_va_val_copy=no],
 490         [dbus_cv_va_val_copy=yes])
 491 ])
 492 AC_LANG_POP(C)
 493
 494 if test "x$dbus_cv_va_val_copy" = "xno"; then
 495   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 496 fi
 497
 498
 499 #### Atomic integers
 500
 501 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 502   dbus_cv_sync_sub_and_fetch,
 503   [AC_LINK_IFELSE([
 504      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 505      [dbus_cv_sync_sub_and_fetch=yes],
 506      [dbus_cv_sync_sub_and_fetch=no])
 507   ])
 508
 509 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 510    have_sync=1
 511 else
 512    have_sync=0
 513 fi
 514
 515 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 516
 517 #### Various functions
 518 AC_SEARCH_LIBS(socket,[socket network])
 519 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 520
 521 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull)
 522
 523 #### Check for broken poll; taken from Glib's configure
 524
 525 AC_MSG_CHECKING([for broken poll])
 526 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 527     #include <stdlib.h>
 528     #include <fcntl.h>
 529     #include <poll.h>
 530     #ifdef HAVE_SYS_POLL_H
 531     #include <sys/poll.h>
 532     #endif
 533     int main(void) {
 534       struct pollfd fds[1];
 535       int fd;
 536       fd = open("/dev/null", 1);
 537       fds[0].fd = fd;
 538       fds[0].events = POLLIN;
 539       fds[0].revents = 0;
 540       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 541             exit(1);  /* Does not work for devices -- fail */
 542       }
 543       exit(0);
 544     }]])],
 545   [broken_poll=no],
 546   [broken_poll=yes
 547    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 548   [broken_poll="no (cross compiling)"])
 549 AC_MSG_RESULT($broken_poll)
 550
 551 AC_MSG_CHECKING(for dirfd)
 552 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 553 #include <sys/types.h>
 554 #include <dirent.h>
 555 ]], [[
 556 DIR *dirp;
 557 dirp = opendir(".");
 558 dirfd(dirp);
 559 closedir(dirp);
 560 ]])],
 561 [dbus_have_dirfd=yes],
 562 [dbus_have_dirfd=no])
 563 AC_MSG_RESULT($dbus_have_dirfd)
 564 if test "$dbus_have_dirfd" = yes; then
 565         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 566 else
 567         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 568         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 569 #include <sys/types.h>
 570 #include <dirent.h>
 571         ]], [[
 572 DIR *dirp;
 573 int fd;
 574 dirp = opendir(".");
 575 fd = dirp->dd_fd;
 576 closedir(dirp);
 577         ]])],
 578         [dbus_have_ddfd=yes],
 579         [dbus_have_ddfd=no])
 580         AC_MSG_RESULT($dbus_have_ddfd)
 581         if test "$dbus_have_ddfd" = yes; then
 582                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 583         fi
 584 fi
 585
 586 AC_CHECK_HEADERS(sys/resource.h)
 587
 588 AC_CHECK_HEADERS(dirent.h)
 589
 590 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 591
 592 AC_CHECK_HEADERS(errno.h)
 593
 594 AC_CHECK_HEADERS(signal.h)
 595
 596 AC_CHECK_HEADERS(locale.h)
 597
 598 AC_CHECK_HEADERS(byteswap.h)
 599
 600 AC_CHECK_HEADERS(unistd.h)
 601
 602 AC_CHECK_HEADERS(ws2tcpip.h)
 603
 604 AC_CHECK_HEADERS(wspiapi.h)
 605
 606 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 607 #
 608 case $host_os in
 609     solaris*)
 610        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 611 esac
 612
 613 # checking for a posix version of getpwnam_r
 614 # if we are cross compiling and can not run the test
 615 # assume getpwnam_r is the posix version
 616 # it is up to the person cross compiling to change
 617 # this behavior if desired
 618 AC_LANG_PUSH(C)
 619 AC_CACHE_CHECK([for posix getpwnam_r],
 620                 ac_cv_func_posix_getpwnam_r,
 621                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 622 [[
 623 #include <errno.h>
 624 #include <pwd.h>
 625 ]],
 626 [[
 627     char buffer[10000];
 628     struct passwd pwd, *pwptr = &pwd;
 629     int error;
 630     errno = 0;
 631     error = getpwnam_r ("", &pwd, buffer,
 632                         sizeof (buffer), &pwptr);
 633    return (error < 0 && errno == ENOSYS)
 634            || error == ENOSYS;
 635 ]])],
 636         [ac_cv_func_posix_getpwnam_r=yes],
 637         [ac_cv_func_posix_getpwnam_r=no],
 638         [ac_cv_func_posix_getpwnam_r=yes]
 639 )])
 640 AC_LANG_POP(C)
 641
 642 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 643         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 644                 [Have POSIX function getpwnam_r])
 645 else
 646         AC_CACHE_CHECK([for nonposix getpwnam_r],
 647                 ac_cv_func_nonposix_getpwnam_r,
 648                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 649                         struct passwd pwd;
 650                         getpwnam_r ("", &pwd, buffer,
 651                                         sizeof (buffer));]])],
 652                         [ac_cv_func_nonposix_getpwnam_r=yes],
 653                         [ac_cv_func_nonposix_getpwnam_r=no])])
 654                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 655                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 656                         [Have non-POSIX function getpwnam_r])
 657         fi
 658 fi
 659
 660 dnl check for socklen_t
 661 AC_MSG_CHECKING(whether socklen_t is defined)
 662 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 663 #include <sys/types.h>
 664 #include <sys/socket.h>
 665 #include <netdb.h>
 666 ]], [[
 667 socklen_t foo;
 668 foo = 1;
 669 ]])],
 670 [dbus_have_socklen_t=yes],
 671 [dbus_have_socklen_t=no])
 672 AC_MSG_RESULT($dbus_have_socklen_t)
 673
 674 if test "x$dbus_have_socklen_t" = "xyes"; then
 675     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 676 fi
 677
 678 dnl check for writev header and writev function so we're
 679 dnl good to go if HAVE_WRITEV gets defined.
 680 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 681
 682 dnl needed on darwin for NAME_MAX
 683 AC_CHECK_HEADERS(sys/syslimits.h)
 684
 685 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 686 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/socket.h> ]])
 687
 688 dnl check for flavours of varargs macros (test from GLib)
 689 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 690 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 691 int a(int p1, int p2, int p3);
 692 #define call_a(...) a(1,__VA_ARGS__)
 693 call_a(2,3);
 694 ]])],
 695 [dbus_have_iso_c_varargs=yes],
 696 [dbus_have_iso_c_varargs=no])
 697 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 698
 699 AC_MSG_CHECKING(for GNUC varargs macros)
 700 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 701 int a(int p1, int p2, int p3);
 702 #define call_a(params...) a(1,params)
 703 call_a(2,3);
 704 ]])],
 705 [dbus_have_gnuc_varargs=yes],
 706 [dbus_have_gnuc_varargs=no])
 707 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 708
 709 dnl Output varargs tests
 710 if test x$dbus_have_iso_c_varargs = xyes; then
 711     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 712 fi
 713 if test x$dbus_have_gnuc_varargs = xyes; then
 714     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 715 fi
 716
 717 dnl Check for various credentials.
 718 AC_MSG_CHECKING(for struct cmsgcred)
 719 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 720 #include <sys/types.h>
 721 #include <sys/socket.h>
 722 ]], [[
 723 struct cmsgcred cred;
 724
 725 cred.cmcred_pid = 0;
 726 ]])],
 727 [dbus_have_struct_cmsgcred=yes],
 728 [dbus_have_struct_cmsgcred=no])
 729 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 730
 731 if test x$dbus_have_struct_cmsgcred = xyes; then
 732     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 733 fi
 734
 735 AC_CHECK_FUNCS(getpeerucred getpeereid)
 736
 737 AC_CHECK_FUNCS(pipe2 accept4)
 738
 739 #### Abstract sockets
 740
 741 if test x$enable_abstract_sockets = xauto; then
 742 AC_LANG_PUSH(C)
 743 warn_on_xcompile=no
 744 AC_CACHE_CHECK([abstract socket namespace],
 745                 ac_cv_have_abstract_sockets,
 746                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 747 [[
 748 #include <sys/types.h>
 749 #include <stdlib.h>
 750 #include <string.h>
 751 #include <stdio.h>
 752 #include <sys/socket.h>
 753 #include <sys/un.h>
 754 #include <errno.h>
 755 ]],
 756 [[
 757   size_t slen;
 758   int listen_fd;
 759   struct sockaddr_un addr;
 760
 761   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 762
 763   if (listen_fd < 0)
 764     {
 765       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 766       exit (1);
 767     }
 768
 769   memset (&addr, '\0', sizeof (addr));
 770   addr.sun_family = AF_UNIX;
 771   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 772   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 773    * beginning.
 774    */
 775   slen = SUN_LEN(&addr);
 776   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 777
 778   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 779     {
 780        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 781                 strerror (errno));
 782        exit (1);
 783     }
 784   else
 785     exit (0);
 786 ]])],
 787               [ac_cv_have_abstract_sockets=yes],
 788               [ac_cv_have_abstract_sockets=no],
 789               [
 790                 ac_cv_have_abstract_sockets=no
 791                 warn_on_xcompile=yes
 792               ]
 793 )])
 794 if test x$warn_on_xcompile = xyes ; then
 795   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 796 fi
 797 AC_LANG_POP(C)
 798 fi
 799
 800 if test x$enable_abstract_sockets = xyes; then
 801     if test x$ac_cv_have_abstract_sockets = xno; then
 802         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 803     fi
 804 fi
 805
 806 if test x$enable_abstract_sockets = xno; then
 807    ac_cv_have_abstract_sockets=no;
 808 fi
 809
 810 if test x$ac_cv_have_abstract_sockets = xyes ; then
 811    DBUS_PATH_OR_ABSTRACT=abstract
 812    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 813 else
 814    DBUS_PATH_OR_ABSTRACT=path
 815 fi
 816
 817 # this is used in addresses to prefer abstract, e.g.
 818 # unix:path=/foo or unix:abstract=/foo
 819 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 820
 821 PKG_PROG_PKG_CONFIG
 822
 823 #### Sort out XML library
 824
 825 # see what we have
 826 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 827              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 828              have_expat=false)
 829
 830 # see what we want to use
 831 dbus_use_libxml=false
 832 dbus_use_expat=false
 833 if test x$with_xml = xexpat; then
 834         if ! $have_expat ; then
 835            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 836         fi
 837         dbus_use_expat=true
 838 elif test x$with_xml = xlibxml; then
 839         PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= 2.6.0, have_libxml=true, have_libxml=false)
 840         if ! $have_libxml ; then
 841            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 842         fi
 843         dbus_use_libxml=true
 844 else
 845         ### expat is the default because libxml can't currently survive
 846         ### our brutal OOM-handling unit test setup.
 847         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 848         if test x$have_expat = xfalse; then
 849                 AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])
 850         fi
 851         ### By default, only use Expat since it's tested and known to work.  If you're a
 852         ### general-purpose OS vendor, please don't enable libxml.  For embedded use
 853         ### if your OS is built around libxml, that's another case.
 854         dbus_use_expat=true
 855 fi
 856
 857 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 858 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 859
 860 if $dbus_use_expat; then
 861    XML_LIBS=-lexpat
 862    XML_CFLAGS=
 863 fi
 864 if $dbus_use_libxml; then
 865    XML_LIBS=$LIBXML_LIBS
 866    XML_CFLAGS=$LIBXML_CFLAGS
 867 fi
 868
 869 # Thread lib detection
 870 AC_CHECK_FUNC(pthread_cond_timedwait,[AC_CHECK_LIB(pthread,pthread_cond_timedwait,
 871                                                     [THREAD_LIBS="-lpthread"])])
 872 save_libs="$LIBS"
 873 LIBS="$LIBS $THREAD_LIBS"
 874 AC_CHECK_FUNC(pthread_condattr_setclock,have_pthread_condattr_setclock=true,have_pthread_condattr_setclock=false)
 875 if test x$have_pthread_condattr_setclock = xtrue; then
 876     AC_SEARCH_LIBS([clock_getres],[rt],[THREAD_LIBS="$THREAD_LIBS -lrt"])
 877     AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 878     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>
 879 #include <pthread.h>
 880 ]], [[
 881 struct timespec monotonic_timer;
 882 pthread_condattr_t attr;
 883 pthread_condattr_init (&attr);
 884 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
 885 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
 886 ]])],
 887 [have_clock_monotonic=true],
 888 [have_clock_monotonic=false])
 889 if test x$have_clock_monotonic = xtrue; then
 890     AC_MSG_RESULT([found])
 891     AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
 892 else
 893     AC_MSG_RESULT([not found])
 894 fi
 895 fi
 896 LIBS="$save_libs"
 897
 898 # SELinux detection
 899 if test x$enable_selinux = xno ; then
 900     have_selinux=no;
 901 else
 902     # See if we have SELinux library
 903     AC_CHECK_LIB(selinux, is_selinux_enabled,
 904                  have_selinux=yes, have_selinux=no)
 905
 906     # see if we have the SELinux header with the new D-Bus stuff in it
 907     if test x$have_selinux = xyes ; then
 908         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
 909         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
 910                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
 911                             #else
 912                             #error DBUS__ACQUIRE_SVC not defined
 913                             #endif]])],
 914                           [have_selinux=yes],
 915                           [have_selinux=no])
 916         AC_MSG_RESULT($have_selinux)
 917     fi
 918
 919     if test x$enable_selinux = xauto ; then
 920         if test x$have_selinux = xno ; then
 921                 AC_MSG_WARN([Sufficiently new SELinux library not found])
 922         fi
 923     else
 924         if test x$have_selinux = xno ; then
 925                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
 926         fi
 927     fi
 928 fi
 929
 930 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 931
 932 if test x$have_selinux = xyes ; then
 933     # the selinux code creates threads
 934     # which requires libpthread even on linux
 935     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
 936                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
 937
 938     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
 939     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
 940 else
 941     SELINUX_LIBS=
 942 fi
 943
 944 # inotify checks
 945 if test x$enable_inotify = xno ; then
 946     have_inotify=no;
 947 else
 948     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
 949 fi
 950
 951 dnl check if inotify backend is enabled
 952 if test x$have_inotify = xyes; then
 953    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
 954    AC_CHECK_FUNCS(inotify_init1)
 955 fi
 956
 957 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
 958
 959 # dnotify checks
 960 if test x$enable_dnotify = xno ; then
 961     have_dnotify=no;
 962 else
 963     if test x$have_inotify = xno -a x$host_os = xlinux-gnu -o x$host_os = xlinux; then
 964         have_dnotify=yes;
 965     else
 966         have_dnotify=no;
 967     fi
 968 fi
 969
 970 dnl check if dnotify backend is enabled
 971 if test x$have_dnotify = xyes; then
 972    AC_DEFINE(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX,1,[Use dnotify on Linux])
 973 fi
 974
 975 AM_CONDITIONAL(DBUS_BUS_ENABLE_DNOTIFY_ON_LINUX, test x$have_dnotify = xyes)
 976
 977 # kqueue checks
 978 if test x$enable_kqueue = xno ; then
 979     have_kqueue=no
 980 else
 981     have_kqueue=yes
 982     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
 983     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
 984
 985     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
 986         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
 987     fi
 988 fi
 989
 990 dnl check if kqueue backend is enabled
 991 if test x$have_kqueue = xyes; then
 992    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
 993 fi
 994
 995 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
 996
 997 # launchd checks
 998 if test x$enable_launchd = xno ; then
 999     have_launchd=no
1000 else
1001     have_launchd=yes
1002     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1003     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1004     if test "x$LAUNCHCTL" = "x"; then
1005         have_launchd=no
1006     fi
1007
1008     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1009         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1010     fi
1011 fi
1012
1013 dnl check if launchd is enabled
1014 if test x$have_launchd = xyes; then
1015     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1016 fi
1017
1018 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1019
1020 #### Directory to place launchd agent file
1021 if test "x$with_launchd_agent_dir" = "x"; then
1022    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1023 else
1024    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1025 fi
1026
1027 AC_SUBST(LAUNCHD_AGENT_DIR)
1028
1029 dnl console owner file
1030 if test x$enable_console_owner_file = xno ; then
1031     have_console_owner_file=no;
1032 else
1033     case $host_os in
1034     solaris*)
1035         have_console_owner_file=yes;
1036         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1037         ;;
1038     *)
1039         have_console_owner_file=no;;
1040     esac
1041 fi
1042
1043 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1044
1045 # libaudit detection
1046 if test x$enable_libaudit = xno ; then
1047     have_libaudit=no;
1048 else
1049     # See if we have audit daemon & capabilities library
1050     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1051                  have_libaudit=yes, have_libaudit=no)
1052     if test x$have_libaudit = xyes ; then
1053         AC_CHECK_LIB(cap-ng, capng_clear,
1054                  have_libaudit=yes, have_libaudit=no)
1055     fi
1056 fi
1057
1058 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1059
1060 if test x$have_libaudit = xyes ; then
1061     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1062     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1063 fi
1064
1065 # Check for ADT API
1066 AC_MSG_CHECKING(for ADT API)
1067 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1068 #include <bsm/adt.h>
1069 adt_user_context = ADT_USER;
1070 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1071
1072 if test ${check_adt_audit} = yes
1073 then
1074    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1075    ADT_LIBS="-lbsm"
1076    LIBS="-lbsm $LIBS"
1077    AC_MSG_RESULT(yes)
1078 else
1079    AC_MSG_RESULT(no)
1080 fi
1081
1082 # Check for SCM_RIGHTS
1083 AC_MSG_CHECKING([for SCM_RIGHTS])
1084 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include <sys/socket.h>
1086 #include <sys/un.h>
1087 static int x = SCM_RIGHTS;
1088 ]], [[]])],
1089 [ AC_MSG_RESULT([supported])
1090   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1091 [ AC_MSG_RESULT([not supported]) ])
1092
1093 NETWORK_libs=
1094 if test x$dbus_win = xyes ; then
1095   if test x$dbus_wince = xyes ; then
1096     NETWORK_libs="-lws2"
1097   else
1098     NETWORK_libs="-lws2_32"
1099   fi
1100 fi
1101
1102 #### Set up final flags
1103 DBUS_CLIENT_CFLAGS=
1104 DBUS_CLIENT_LIBS="$THREAD_LIBS $NETWORK_libs"
1105 AC_SUBST(DBUS_CLIENT_CFLAGS)
1106 AC_SUBST(DBUS_CLIENT_LIBS)
1107
1108 DBUS_BUS_CFLAGS="$XML_CFLAGS"
1109 DBUS_BUS_LIBS="$XML_LIBS $SELINUX_LIBS $THREAD_LIBS $ADT_LIBS $NETWORK_libs"
1110 AC_SUBST(DBUS_BUS_CFLAGS)
1111 AC_SUBST(DBUS_BUS_LIBS)
1112
1113 DBUS_LAUNCHER_CFLAGS="$XML_CFLAGS"
1114 DBUS_LAUNCHER_LIBS="$XML_LIBS $THREAD_LIBS $NETWORK_libs"
1115 AC_SUBST(DBUS_LAUNCHER_CFLAGS)
1116 AC_SUBST(DBUS_LAUNCHER_LIBS)
1117
1118 DBUS_TEST_CFLAGS=
1119 DBUS_TEST_LIBS="$THREAD_LIBS $NETWORK_libs"
1120 AC_SUBST(DBUS_TEST_CFLAGS)
1121 AC_SUBST(DBUS_TEST_LIBS)
1122
1123 ### X11 detection
1124 DBUS_X_LIBS=
1125 DBUS_X_CFLAGS=
1126
1127 AC_ARG_ENABLE([x11-autolaunch],
1128   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1129   [], [enable_x11_autolaunch=auto])
1130
1131 if test "x$dbus_win" = xyes; then
1132     if test "x$enable_x11_autolaunch" = xyes; then
1133         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1134     fi
1135
1136     enable_x11_autolaunch=no
1137     have_x11=no
1138 else
1139     AC_PATH_XTRA
1140
1141     if test "x$no_x" = xyes; then
1142         have_x11=no
1143     else
1144         have_x11=yes
1145         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1146         DBUS_X_CFLAGS="$X_CFLAGS"
1147     fi
1148 fi
1149
1150 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1151     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1152 else
1153     # move from "auto" to "yes" or "no" if necessary
1154     if test "x$enable_x11_autolaunch" != xno; then
1155         enable_x11_autolaunch="$have_x11"
1156     fi
1157 fi
1158
1159 if test "x$have_x11" = xyes ; then
1160    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1161 fi
1162
1163 if test "x$enable_x11_autolaunch" = xyes ; then
1164    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1165 fi
1166
1167 AC_SUBST([DBUS_X_CFLAGS])
1168 AC_SUBST([DBUS_X_LIBS])
1169
1170 #### gcc warning flags
1171
1172 cc_supports_flag() {
1173   AC_MSG_CHECKING(whether $CC supports "$*")
1174   save_CFLAGS="$CFLAGS"
1175   CFLAGS="$*"
1176   AC_TRY_COMPILE([], [], [rc=yes], [rc=no])
1177   CFLAGS="$save_CFLAGS"
1178   AC_MSG_RESULT([$rc])
1179   test "x$rc" = xyes
1180 }
1181
1182 TP_COMPILER_WARNINGS([WARNING_CFLAGS],
1183   dnl Use -Werror by default if:
1184   dnl - we're not on Windows (too many warnings), and
1185   dnl - we're in maintainer mode (a D-Bus developer, not a distro or end-user)
1186   dnl Override with --enable-Werror or --disable-Werror
1187   [test x$dbus_win != xyes -a x$dbus_cygwin != xyes -a x$USE_MAINTAINER_MODE = xyes],
1188
1189   dnl enable these warnings if possible:
1190   [all \
1191    char-subscripts \
1192    missing-declarations \
1193    missing-prototypes \
1194    nested-externs \
1195    pointer-arith \
1196    cast-align \
1197    no-address \
1198    float-equal \
1199    declaration-after-statement \
1200   ],
1201
1202   dnl disable these warnings if possible, make them non-fatal if possible,
1203   dnl and don't enable -Werror unless we succeeded:
1204   dnl (unused is by design, sign-compare and pointer-sign are fd.o #17433)
1205   [unused \
1206    sign-compare \
1207    pointer-sign \
1208   ])
1209
1210 if test "x$GCC" = "xyes"; then
1211   # We're treating -fno-common like a warning: it makes the linker more
1212   # strict, because on some systems the linker is *always* this strict
1213   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-common])
1214
1215   # http://bugs.freedesktop.org/show_bug.cgi?id=10599
1216   TP_ADD_COMPILER_FLAG([WARNING_CFLAGS], [-fno-strict-aliasing])
1217
1218   if test "x$enable_ansi" = "xyes"; then
1219     TP_ADD_COMPILER_FLAG([WARNING_CFLAGS],
1220       [-ansi -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE -pedantic])
1221   fi
1222 fi
1223
1224 dnl In principle we should put WARNING_CFLAGS in each Makefile.am like
1225 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1226 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1227 dnl is the next best thing
1228 CFLAGS="$WARNING_CFLAGS $CFLAGS"
1229
1230 case $host_os in
1231     solaris*)
1232         # Solaris' C library apparently needs these runes to be threadsafe...
1233         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1234         # ... and this opt-in to get file descriptor passing support
1235         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1236         ;;
1237 esac
1238
1239 ### Doxygen Documentation
1240
1241 AC_PATH_PROG(DOXYGEN, doxygen, no)
1242
1243 AC_MSG_CHECKING([whether to build Doxygen documentation])
1244
1245 if test x$DOXYGEN = xno ; then
1246     have_doxygen=no
1247 else
1248     have_doxygen=yes
1249 fi
1250
1251 if test x$enable_doxygen_docs = xauto ; then
1252     if test x$have_doxygen = xno ; then
1253         enable_doxygen_docs=no
1254     else
1255         enable_doxygen_docs=yes
1256     fi
1257 fi
1258
1259 if test x$enable_doxygen_docs = xyes; then
1260     if test x$have_doxygen = xno; then
1261         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1262     fi
1263 fi
1264
1265 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1266 AC_MSG_RESULT($enable_doxygen_docs)
1267
1268 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1269 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1270
1271 ### XML Documentation
1272
1273 AC_PATH_PROG(XMLTO, xmlto, no)
1274
1275 AC_MSG_CHECKING([whether to build XML documentation])
1276
1277 if test x$XMLTO = xno ; then
1278     have_xmlto=no
1279 else
1280     have_xmlto=yes
1281 fi
1282
1283 if test x$enable_xml_docs = xauto ; then
1284     if test x$have_xmlto = xno ; then
1285         enable_xml_docs=no
1286     else
1287         enable_xml_docs=yes
1288     fi
1289 fi
1290
1291 if test x$enable_xml_docs = xyes; then
1292     if test x$have_xmlto = xno; then
1293         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1294     fi
1295 fi
1296
1297 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1298 AC_MSG_RESULT($enable_xml_docs)
1299
1300 AC_PATH_PROG([MAN2HTML], [man2html])
1301 AC_ARG_VAR([MAN2HTML], [Path to man2html (optional)])
1302 AM_CONDITIONAL(DBUS_HAVE_MAN2HTML, test x$MAN2HTML != x)
1303
1304 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1305     test x$enable_doxygen_docs = xyes -a x$enable_xml_docs = xyes -a \
1306          x$MAN2HTML != x)
1307
1308 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1309
1310 #### find the actual value for $prefix that we'll end up with
1311 ##   (I know this is broken and should be done in the Makefile, but
1312 ##    that's a major pain and almost nobody actually seems to care)
1313 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1314 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1315 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1316 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1317 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1318 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1319 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1320
1321 #### Check our operating system
1322 operating_system=unknown
1323 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1324    operating_system=redhat
1325 fi
1326
1327 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1328    operating_system=slackware
1329 fi
1330
1331 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1332    operating_system=cygwin
1333 fi
1334
1335 #### Sort out init scripts
1336
1337 if test x$with_init_scripts = x; then
1338     case x$operating_system in
1339         xredhat)        with_init_scripts=redhat ;;
1340         xslackware)     with_init_scripts=slackware ;;
1341         xcygwin)        with_init_scripts=cygwin ;;
1342         *)                      with_init_scripts=none ;;
1343     esac
1344 fi
1345
1346 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1347 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1348 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1349
1350 ##### systemd unit files
1351 AC_ARG_WITH([systemdsystemunitdir],
1352 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1353         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
1354 if test "x$with_systemdsystemunitdir" != xno; then
1355    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1356 fi
1357 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1358
1359 ##### Set up location for system bus socket
1360 if ! test -z "$with_system_socket"; then
1361    DBUS_SYSTEM_SOCKET=$with_system_socket
1362 else
1363    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1364 fi
1365
1366 AC_SUBST(DBUS_SYSTEM_SOCKET)
1367 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1368
1369 ## system bus only listens on local domain sockets, and never
1370 ## on an abstract socket (so only root can create the socket)
1371 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1372 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1373 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1374
1375 #### Set up the pid file
1376 if ! test -z "$with_system_pid_file"; then
1377    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1378 elif test x$with_init_scripts = xredhat ; then
1379    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1380 else
1381    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1382 fi
1383
1384 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1385
1386 #### Directory to check for console ownership
1387 if ! test -z "$with_console_auth_dir"; then
1388    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1389 else
1390    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1391 fi
1392
1393 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1394 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1395
1396 #### File to check for console ownership
1397 if test x$have_console_owner_file = xyes; then
1398    if ! test -z "$with_console_owner_file"; then
1399       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1400    else
1401       DBUS_CONSOLE_OWNER_FILE=/dev/console
1402    fi
1403 else
1404   DBUS_CONSOLE_OWNER_FILE=
1405 fi
1406
1407 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1408 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1409
1410 #### User to start the system bus as
1411 if test -z "$with_dbus_user" ; then
1412     DBUS_USER=messagebus
1413 else
1414     DBUS_USER=$with_dbus_user
1415 fi
1416 AC_SUBST(DBUS_USER)
1417 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1418
1419 #### Prefix to install into
1420 DBUS_PREFIX=$EXPANDED_PREFIX
1421 AC_SUBST(DBUS_PREFIX)
1422 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1423
1424 #### Direcotry to install data files into
1425 DBUS_DATADIR=$EXPANDED_DATADIR
1426 AC_SUBST(DBUS_DATADIR)
1427 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1428
1429 #### Directory to install dbus-daemon
1430 if test -z "$with_dbus_daemondir" ; then
1431     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1432 else
1433     DBUS_DAEMONDIR=$with_dbus_daemondir
1434 fi
1435 AC_SUBST(DBUS_DAEMONDIR)
1436 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1437
1438 #### Directory to install the other binaries
1439 DBUS_BINDIR="$EXPANDED_BINDIR"
1440 AC_SUBST(DBUS_BINDIR)
1441 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1442
1443 #### Directory to install the libexec binaries
1444 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1445 AC_SUBST(DBUS_LIBEXECDIR)
1446 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1447
1448 #### Tell tests where to find certain stuff in builddir
1449
1450 DBUS_PWD=`pwd`
1451 # Useful in a cross-compilation environment, where the tests are run on the host system.
1452 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1453                            DBUS_PWD=$withval)
1454 AC_DEFUN([TEST_PATH], [
1455 TEST_$1=${DBUS_PWD}/test/$2
1456 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
1457                    [Full path to test file test/$2 in builddir])
1458 AC_SUBST(TEST_$1)
1459 ])
1460 AC_DEFUN([TEST_PROG], [
1461 TEST_$1=${DBUS_PWD}/test/$2
1462 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1$EXEEXT",
1463                    [Full path to test file test/$2 in builddir])
1464 AC_SUBST(TEST_$1)
1465 ])
1466
1467 TEST_PATH(VALID_SERVICE_DIR, data/valid-service-files)
1468 TEST_PATH(INVALID_SERVICE_DIR, data/invalid-service-files)
1469 TEST_PATH(VALID_SERVICE_SYSTEM_DIR, data/valid-service-files-system)
1470 TEST_PATH(INVALID_SERVICE_SYSTEM_DIR, data/invalid-service-files-system)
1471 TEST_PROG(SERVICE_BINARY, test-service)
1472 TEST_PROG(SHELL_SERVICE_BINARY, test-shell-service)
1473 TEST_PROG(EXIT_BINARY, test-exit)
1474 TEST_PROG(SEGFAULT_BINARY, test-segfault)
1475 TEST_PROG(SLEEP_FOREVER_BINARY, test-sleep-forever)
1476 TEST_PROG(PRIVSERVER_BINARY, name-test/test-privserver)
1477
1478 AC_DEFINE_UNQUOTED(TEST_BUS_BINARY, "$DBUS_PWD/bus/dbus-daemon$EXEEXT",
1479                    [Full path to the daemon in the builddir])
1480 AC_SUBST(TEST_BUS_BINARY)
1481
1482 ## Export the non-setuid external helper
1483 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1484 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1485 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1486                    [Full path to the launch helper test program in the builddir])
1487
1488 #### Find socket directories
1489 if ! test -z "$TMPDIR" ; then
1490    DEFAULT_SOCKET_DIR=$TMPDIR
1491 elif ! test -z "$TEMP" ; then
1492    DEFAULT_SOCKET_DIR=$TEMP
1493 elif ! test -z "$TMP" ; then
1494    DEFAULT_SOCKET_DIR=$TMP
1495 else
1496    DEFAULT_SOCKET_DIR=/tmp
1497 fi
1498
1499 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1500
1501 if ! test -z "$with_test_socket_dir" ; then
1502    TEST_SOCKET_DIR="$with_test_socket_dir"
1503 else
1504    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1505 fi
1506 AC_SUBST(TEST_SOCKET_DIR)
1507 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1508
1509 if ! test -z "$with_session_socket_dir" ; then
1510    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1511 else
1512    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1513 fi
1514 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1515 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1516
1517 if test x$dbus_win = xyes; then
1518         DBUS_SESSION_BUS_DEFAULT_ADDRESS="nonce-tcp:"
1519 elif test x$have_launchd = xyes; then
1520         DBUS_SESSION_BUS_DEFAULT_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1521 else
1522         DBUS_SESSION_BUS_DEFAULT_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1523 fi
1524 AC_SUBST(DBUS_SESSION_BUS_DEFAULT_ADDRESS)
1525
1526 # darwin needs this to initialize the environment
1527 AC_CHECK_HEADERS(crt_externs.h)
1528 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1529 AH_VERBATIM(_DARWIN_ENVIRON,
1530 [
1531 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1532 # include <sys/time.h>
1533 # include <crt_externs.h>
1534 # define environ (*_NSGetEnviron())
1535 #endif
1536 ])
1537
1538 AC_CONFIG_FILES([
1539 Doxyfile
1540 dbus/versioninfo.rc
1541 dbus/dbus-arch-deps.h
1542 bus/system.conf
1543 bus/session.conf
1544 bus/messagebus
1545 bus/messagebus-config
1546 bus/org.freedesktop.dbus-session.plist
1547 bus/rc.messagebus
1548 bus/dbus.service
1549 bus/dbus.socket
1550 Makefile
1551 dbus/Makefile
1552 bus/Makefile
1553 tools/Makefile
1554 test/Makefile
1555 test/name-test/Makefile
1556 doc/Makefile
1557 doc/dbus-daemon.1
1558 dbus-1.pc
1559 dbus-1-uninstalled.pc
1560 test/data/valid-config-files/debug-allow-all.conf
1561 test/data/valid-config-files/debug-allow-all-sha1.conf
1562 test/data/valid-config-files-system/debug-allow-all-pass.conf
1563 test/data/valid-config-files-system/debug-allow-all-fail.conf
1564 test/data/valid-service-files/org.freedesktop.DBus.TestSuite.PrivServer.service
1565 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteEchoService.service
1566 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteForkingEchoService.service
1567 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteSegfaultService.service
1568 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1569 test/data/valid-service-files/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1570 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteEchoService.service
1571 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteSegfaultService.service
1572 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceSuccess.service
1573 test/data/valid-service-files-system/org.freedesktop.DBus.TestSuiteShellEchoServiceFail.service
1574 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoExec.service
1575 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoUser.service
1576 test/data/invalid-service-files-system/org.freedesktop.DBus.TestSuiteNoService.service
1577 ])
1578 AC_OUTPUT
1579
1580 dnl ==========================================================================
1581 echo "
1582                     D-Bus $VERSION
1583                   ==============
1584
1585         prefix:                   ${EXPANDED_PREFIX}
1586         exec_prefix:              ${exec_prefix}
1587         libdir:                   ${EXPANDED_LIBDIR}
1588         libexecdir:               ${EXPANDED_LIBEXECDIR}
1589         bindir:                   ${EXPANDED_BINDIR}
1590         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1591         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1592         datadir:                  ${EXPANDED_DATADIR}
1593         source code location:     ${srcdir}
1594         compiler:                 ${CC}
1595         cflags:                   ${CFLAGS}
1596         cppflags:                 ${CPPFLAGS}
1597         cxxflags:                 ${CXXFLAGS}
1598         64-bit int:               ${DBUS_INT64_TYPE}
1599         32-bit int:               ${DBUS_INT32_TYPE}
1600         16-bit int:               ${DBUS_INT16_TYPE}
1601         Doxygen:                  ${DOXYGEN:-not found}
1602         xmlto:                    ${XMLTO:-not found}
1603         man2html:                 ${MAN2HTML:-not found}"
1604
1605 echo "
1606         Maintainer mode:          ${USE_MAINTAINER_MODE}
1607         gcc coverage profiling:   ${enable_compiler_coverage}
1608         Building embedded tests:  ${enable_embedded_tests}
1609         Building modular tests:   ${enable_modular_tests}
1610         Building verbose mode:    ${enable_verbose_mode}
1611         Building assertions:      ${enable_asserts}
1612         Building checks:          ${enable_checks}
1613         Building SELinux support: ${have_selinux}
1614         Building inotify support: ${have_inotify}
1615         Building dnotify support: ${have_dnotify}
1616         Building kqueue support:  ${have_kqueue}
1617         Building X11 code:        ${enable_x11}
1618         Building Doxygen docs:    ${enable_doxygen_docs}
1619         Building XML docs:        ${enable_xml_docs}
1620         Building cache support:   ${enable_userdb_cache}
1621         Building launchd support: ${have_launchd}
1622         Using XML parser:         ${with_xml}
1623         Init scripts style:       ${with_init_scripts}
1624         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1625         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1626         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1627         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1628         Session bus address:      ${DBUS_SESSION_BUS_DEFAULT_ADDRESS}
1629         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1630         Console owner file:       ${have_console_owner_file}
1631         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1632         System bus user:          ${DBUS_USER}
1633         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1634         'make check' socket dir:  ${TEST_SOCKET_DIR}
1635 "
1636 if test x$have_launchd = xyes; then
1637         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1638 fi
1639 echo
1640
1641 if test x$enable_embedded_tests = xyes; then
1642         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1643 fi
1644 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1645         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1646 fi
1647 if test x$enable_compiler_coverage = xyes; then
1648         echo "NOTE: building with coverage profiling is definitely for developers only."
1649 fi
1650 if test x$enable_verbose_mode = xyes; then
1651         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1652 fi
1653 if test x$enable_asserts = xyes; then
1654         echo "NOTE: building with assertions increases library size and decreases performance."
1655 fi
1656 if test x$enable_checks = xno; then
1657         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1658 fi
1659 if test x$dbus_use_libxml = xtrue; then
1660         echo
1661         echo "WARNING: You have chosen to use libxml as your xml parser however this code path is not maintained by the D-Bus developers and if it breaks you get to keep the pieces.  If you have selected this option in err please reconfigure with expat (e.g. --with-xml=expat)."
1662 fi