configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.3.3.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar subdir-objects])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 303, 0, 303)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.3.3.1
  50 GSTPB_REQ=1.3.3.1
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 dnl build static plugins or not
 269 AC_MSG_CHECKING([whether to build static plugins or not])
 270 AC_ARG_ENABLE(
 271   static-plugins,
 272   AC_HELP_STRING(
 273     [--enable-static-plugins],
 274     [build static plugins @<:@default=no@:>@]),
 275   [AS_CASE(
 276     [$enableval], [no], [], [yes], [],
 277     [AC_MSG_ERROR([bad value "$enableval" for --enable-static-plugins])])],
 278   [enable_static_plugins=no])
 279 AC_MSG_RESULT([$enable_static_plugins])
 280 if test "x$enable_static_plugins" = xyes; then
 281   AC_DEFINE(GST_PLUGIN_BUILD_STATIC, 1,
 282     [Define if static plugins should be built])
 283   GST_PLUGIN_LIBTOOLFLAGS=""
 284 else
 285   GST_PLUGIN_LIBTOOLFLAGS="--tag=disable-static"
 286 fi
 287 AC_SUBST(GST_PLUGIN_LIBTOOLFLAGS)
 288 AM_CONDITIONAL(GST_PLUGIN_BUILD_STATIC, test "x$enable_static_plugins" = "xyes")
 289
 290 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 291 dnl make sure it doesn't complain about unused variables if debugging is disabled
 292 NO_WARNINGS=""
 293 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 294
 295 dnl define an ERROR_CFLAGS Makefile variable
 296 dnl -Wundef: too many broken headers
 297 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 298       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 299       -Wwrite-strings -Wold-style-definition -Waggregate-return
 300       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 301       -Wnested-externs $NO_WARNINGS])
 302
 303 dnl define an ERROR_CXXFLAGS Makefile variable
 304 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 305         -Wmissing-declarations -Wredundant-decls
 306         -Wwrite-strings
 307         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 308         $NO_WARNINGS])
 309
 310 dnl define an ERROR_OBJCFLAGS Makefile variable
 311 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 312       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 313       -Wwrite-strings -Wold-style-definition
 314       -Winit-self -Wmissing-include-dirs -Wno-multichar
 315       -Wnested-externs $NO_WARNINGS])
 316
 317 dnl define correct level for debugging messages
 318 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 319
 320 dnl used in examples
 321 AG_GST_DEFAULT_ELEMENTS
 322
 323 dnl *** plug-ins to include ***
 324
 325 dnl these are all the gst plug-ins, compilable without additional libs
 326 dnl videofilter is at the top because others depend on it
 327 AG_GST_CHECK_PLUGIN(alpha)
 328 AG_GST_CHECK_PLUGIN(apetag)
 329 AG_GST_CHECK_PLUGIN(audiofx)
 330 AG_GST_CHECK_PLUGIN(audioparsers)
 331 AG_GST_CHECK_PLUGIN(auparse)
 332 AG_GST_CHECK_PLUGIN(autodetect)
 333 AG_GST_CHECK_PLUGIN(avi)
 334 AG_GST_CHECK_PLUGIN(cutter)
 335 AG_GST_CHECK_PLUGIN(debugutils)
 336 AG_GST_CHECK_PLUGIN(deinterlace)
 337 AG_GST_CHECK_PLUGIN(dtmf)
 338 AG_GST_CHECK_PLUGIN(effectv)
 339 AG_GST_CHECK_PLUGIN(equalizer)
 340 AG_GST_CHECK_PLUGIN(flv)
 341 AG_GST_CHECK_PLUGIN(flx)
 342 AG_GST_CHECK_PLUGIN(goom)
 343 AG_GST_CHECK_PLUGIN(goom2k1)
 344 AG_GST_CHECK_PLUGIN(icydemux)
 345 AG_GST_CHECK_PLUGIN(id3demux)
 346 AG_GST_CHECK_PLUGIN(imagefreeze)
 347 AG_GST_CHECK_PLUGIN(interleave)
 348 AG_GST_CHECK_PLUGIN(isomp4)
 349 AG_GST_CHECK_PLUGIN(law)
 350 AG_GST_CHECK_PLUGIN(level)
 351 AG_GST_CHECK_PLUGIN(matroska)
 352 AG_GST_CHECK_PLUGIN(monoscope)
 353 AG_GST_CHECK_PLUGIN(multifile)
 354 AG_GST_CHECK_PLUGIN(multipart)
 355 AG_GST_CHECK_PLUGIN(replaygain)
 356 AG_GST_CHECK_PLUGIN(rtp)
 357 AG_GST_CHECK_PLUGIN(rtpmanager)
 358 AG_GST_CHECK_PLUGIN(rtsp)
 359 AG_GST_CHECK_PLUGIN(shapewipe)
 360 AG_GST_CHECK_PLUGIN(smpte)
 361 AG_GST_CHECK_PLUGIN(spectrum)
 362 AG_GST_CHECK_PLUGIN(udp)
 363 AG_GST_CHECK_PLUGIN(videobox)
 364 AG_GST_CHECK_PLUGIN(videocrop)
 365 AG_GST_CHECK_PLUGIN(videofilter)
 366 AG_GST_CHECK_PLUGIN(videomixer)
 367 AG_GST_CHECK_PLUGIN(wavenc)
 368 AG_GST_CHECK_PLUGIN(wavparse)
 369 AG_GST_CHECK_PLUGIN(y4m)
 370
 371 dnl disable experimental plug-ins
 372 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 373   AG_GST_DISABLE_PLUGIN(monoscope)
 374 fi
 375
 376 dnl *** sys plug-ins ***
 377
 378 echo
 379 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 380 echo
 381
 382 dnl DirectSound
 383 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 384 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 385   HAVE_DIRECTSOUND="no"
 386   save_CFLAGS="$CFLAGS"
 387   save_LDFLAGS="$LDFLAGS"
 388   save_LIBS="$LIBS"
 389   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 390   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 391   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 392   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 393   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 394 #include <windows.h>
 395 #include <dxerr9.h>
 396 #include <dsound.h>
 397 ]], [[
 398   DXGetErrorString9 (0);
 399   DirectSoundCreate(NULL, NULL, NULL);
 400 ]])
 401 ],
 402     [HAVE_DIRECTSOUND="yes"],
 403     [HAVE_DIRECTSOUND="no"])
 404   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 405   CFLAGS=$save_CFLAGS
 406   LDFLAGS=$save_LDFLAGS
 407   LIBS=$save_LIBS
 408
 409   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 410     dnl this is much more than we want
 411     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 412     AC_SUBST(DIRECTSOUND_CFLAGS)
 413     AC_SUBST(DIRECTSOUND_LDFLAGS)
 414     AC_SUBST(DIRECTSOUND_LIBS)
 415   fi
 416   AC_SUBST(HAVE_DIRECTSOUND)
 417 ])
 418
 419 dnl *** Win32 WaveOut ***
 420 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 421 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 422   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 423 ])
 424
 425 dnl *** OSS audio *** (Linux, *BSD)
 426 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 427 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 428  HAVE_OSS="yes"
 429 dnl Linux and newer BSD versions :
 430  AC_CHECK_HEADER(sys/soundcard.h, [
 431    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 432    ] , [
 433 dnl Some old BSD versions and also newer OpenBSD versions :
 434    AC_CHECK_HEADER(soundcard.h, [
 435      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 436      ], [
 437   dnl Some old BSD versions :
 438      AC_CHECK_HEADER(machine/soundcard.h, [
 439        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 440          [Define if OSS includes are in /machine/])
 441        ], [
 442        HAVE_OSS="no"
 443      ])
 444    ])
 445  ])
 446 ])
 447
 448 dnl *** oss4 ***
 449 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 450 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 451   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 452   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 453       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 454       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 455 ])
 456
 457 dnl *** Sun Audio ***
 458 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 459 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 460   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 461 ])
 462
 463 dnl *** OSX Audio ***
 464 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 465 HAVE_IOS="no"
 466 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 467   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 468     [HAVE_OSX_AUDIO="yes"],
 469     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 470     [
 471       HAVE_OSX_AUDIO="yes"
 472       HAVE_IOS="yes"
 473     ], [
 474       HAVE_OSX_AUDIO="no"
 475       HAVE_IOS="no"
 476     ])]
 477   )
 478 ])
 479 if test "x$HAVE_IOS" = "xyes"; then
 480   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 481 fi
 482 AM_CONDITIONAL(HAVE_IOS, test "x$HAVE_IOS" = "xyes")
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489
 490   dnl in case header OpenGL/gl.h is found on other platforms (or older, unsupported OS X)
 491   dnl also require Snow Leopard or newer
 492
 493   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 494         #include <AvailabilityMacros.h>
 495         #if MAC_OS_X_VERSION_MIN_REQUIRED < 1060
 496         #error Too old OSX version
 497         #endif
 498       ]], [[return 0;]])],[HAVE_OSX_VIDEO="yes"],[HAVE_OSX_VIDEO="no"])
 499 ])
 500
 501 dnl *** Video 4 Linux 2 ***
 502 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 503 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 504 HAVE_GST_V4L2=no
 505 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], video4linux2, [
 506   AC_MSG_CHECKING([Checking for video4linux2 header ...])
 507   AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_GST_V4L2=yes ],
 508   [
 509     AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_GST_V4L2=yes ])
 510   ])
 511   if test "x$HAVE_VIDEODEV" = "xno"; then
 512      AC_MSG_WARN([video4linux2 was not found])
 513   fi
 514 ])
 515
 516 # Optional gudev for device probing
 517 AC_ARG_WITH([gudev],
 518   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 519   [],
 520   [with_gudev=check])
 521 if test x$HAVE_GST_V4L2 = xyes; then
 522   if test x$with_gudev != xno; then
 523     PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 147 ],
 524       [ AC_DEFINE(HAVE_GUDEV, 1,
 525           [Whether gudev is available for device detection])
 526       ],
 527       [true])
 528   fi
 529 fi
 530
 531 AC_SUBST(GUDEV_CFLAGS)
 532 AC_SUBST(GUDEV_LIBS)
 533
 534 # Make libv4l2 non-automagic
 535 AC_ARG_WITH([libv4l2],
 536   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 537   [],
 538   [with_libv4l2=check])
 539 if test x$HAVE_GST_V4L2 = xyes; then
 540   if test x$with_libv4l2 != xno; then
 541       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 542           [ have_libv4l2=yes
 543             AC_DEFINE(HAVE_LIBV4L2, 1,
 544                 [Whether libv4l2 is available for video buffer conversion])
 545           ], [
 546           have_libv4l2=no
 547           ])
 548   else
 549     have_libv4l2=no
 550   fi
 551 fi
 552
 553 dnl Check for X11
 554 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 555 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 556                   [ximagesrc], [
 557   AG_GST_CHECK_X
 558
 559   if test "x$HAVE_X" = "xyes"
 560   then
 561     dnl check for Xfixes
 562     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 563     if test "x$HAVE_XFIXES" = "xyes"
 564     then
 565         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 566     fi
 567     AC_SUBST(XFIXES_LIBS)
 568     AC_SUBST(XFIXES_CFLAGS)
 569
 570     dnl check for Xdamage
 571     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 572     if test "x$HAVE_XDAMAGE" = "xyes"
 573     then
 574         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 575     fi
 576     AC_SUBST(XDAMAGE_LIBS)
 577     AC_SUBST(XDAMAGE_CFLAGS)
 578   fi
 579 ])
 580
 581 dnl FIXME: this should be rolled into the test above, it's just an additional
 582 dnl feature of the ximagesrc plug-in
 583 dnl This is the same as in gst-plugins-base
 584 dnl check for X Shm
 585 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 586 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 587   if test x$HAVE_X = xyes; then
 588     AC_CHECK_LIB(Xext, XShmAttach,
 589                  HAVE_XSHM="yes", HAVE_XSHM="no",
 590                  $X_LIBS)
 591     if test "x$HAVE_XSHM" = "xyes"; then
 592       XSHM_LIBS="-lXext"
 593     else
 594       dnl On AIX, it is in XextSam instead, but we still need -lXext
 595       AC_CHECK_LIB(XextSam, XShmAttach,
 596                    HAVE_XSHM="yes", HAVE_XSHM="no",
 597                    $X_LIBS)
 598       if test "x$HAVE_XSHM" = "xyes"; then
 599         XSHM_LIBS="-lXext -lXextSam"
 600       fi
 601     fi
 602   fi
 603 ], ,[
 604   AC_SUBST(HAVE_XSHM)
 605   AC_SUBST(XSHM_LIBS)
 606 ])
 607
 608 dnl *** ext plug-ins ***
 609 dnl keep this list sorted alphabetically !
 610
 611 if test "x$BUILD_EXTERNAL" = "xyes"; then
 612
 613 echo
 614 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 615 echo
 616
 617 dnl *** aalib ***
 618 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 619 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 620   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 621 ])
 622
 623 dnl *** cairo ***
 624 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 625 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 626   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 627 ])
 628
 629 dnl *** FLAC ***
 630 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 631 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 632   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 633 ])
 634
 635 dnl *** GDK pixbuf ***
 636 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 637 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 638   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 639 ])
 640
 641 dnl *** Jack ***
 642 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 643 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 644   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 645   AC_SUBST(JACK_CFLAGS)
 646   AC_SUBST(JACK_LIBS)
 647
 648   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 649   if test x$HAVE_JACK_0_120_1 = xyes; then
 650     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 651   fi
 652   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 653   if test x$HAVE_JACK_1_9_7 = xyes; then
 654     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 655   fi
 656
 657 ])
 658
 659 dnl *** jpeg ***
 660 dnl FIXME: we could use header checks here as well IMO
 661 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 662 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 663   AC_ARG_WITH(jpeg-mmx,
 664     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 665   OLD_LIBS="$LIBS"
 666   if test x$with_jpeg_mmx != x; then
 667     LIBS="$LIBS -L$with_jpeg_mmx"
 668   fi
 669   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 670   JPEG_LIBS="$LIBS -ljpeg-mmx"
 671   LIBS="$OLD_LIBS"
 672   if test x$HAVE_JPEG != xyes; then
 673     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 674     JPEG_LIBS="-ljpeg"
 675   fi
 676   AC_SUBST(JPEG_LIBS)
 677 ])
 678
 679 dnl *** libcaca ***
 680 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 681 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 682   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 683 ])
 684
 685 dnl *** libdv ***
 686 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 687 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 688   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 689 ])
 690
 691 dnl *** libpng ***
 692 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 693 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 694   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 695 ])
 696
 697 dnl *** pulseaudio ***
 698 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 699 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 700
 701   dnl used in ext/pulse/pulseutil.c
 702   AC_CHECK_HEADERS([process.h])
 703
 704   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 2.0)
 705 ])
 706
 707 dnl *** dv1394 ***
 708 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 709 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 710   dnl first test for libraw1394 >= 2.0.0
 711   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 712   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 713   dnl now see how far we got
 714   if test x$HAVE_RAW1394 = xyes && \
 715      test x$HAVE_LIBIEC61883 = xyes; then
 716        AG_GST_CHECK_LIBHEADER(AVC1394,
 717         avc1394, avc1394_send_command, $RAW1394_LIBS,
 718         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 719        AG_GST_CHECK_LIBHEADER(ROM1394,
 720         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 721         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 722        if test x$HAVE_AVC1394 = xyes && \
 723           test x$HAVE_AVC1394 = xyes && \
 724           test x$HAVE_ROM1394 = xyes; then
 725           HAVE_DV1394=yes
 726           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 727           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 728           AC_SUBST(DV1394_CFLAGS)
 729           AC_SUBST(DV1394_LIBS)
 730         fi
 731   else
 732        if test x$HAVE_RAW1394 = xno; then
 733           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 734           AG_GST_CHECK_LIBHEADER(AVC1394,
 735            avc1394, avc1394_send_command, $RAW1394_LIBS,
 736            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 737           AG_GST_CHECK_LIBHEADER(ROM1394,
 738            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 739            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 740           if test x$HAVE_RAW1394 = xyes && \
 741              test x$HAVE_AVC1394 = xyes && \
 742              test x$HAVE_ROM1394 = xyes; then
 743              HAVE_DV1394=yes
 744              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 745              DV1394_CFLAGS="$RAW1394_CFLAGS"
 746              if test x$HAVE_LIBIEC61883 = xyes; then
 747                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 748                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 749              fi
 750              AC_SUBST(DV1394_CFLAGS)
 751              AC_SUBST(DV1394_LIBS)
 752            fi
 753          fi
 754   fi
 755 ])
 756 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 757
 758 dnl *** shout2 ***
 759 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 760 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 761   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 762 ])
 763
 764 dnl *** soup ***
 765 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 766 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 767   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.40, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 768   AC_SUBST(SOUP_CFLAGS)
 769   AC_SUBST(SOUP_LIBS)
 770 ])
 771
 772 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 773 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 774 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 775 dnl   speex_jitter.h is 1.1.x only
 776 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 777 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 778   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 779   if test $HAVE_SPEEX = no
 780   then
 781     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 782       AC_CHECK_HEADER(speex/speex_jitter.h, [
 783         dnl speex 1.1.x :
 784         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 785           dnl speex 1.1.5 or + :
 786           HAVE_SPEEX="yes"
 787           SPEEX_LIBS="-lspeex"
 788           AC_SUBST(SPEEX_CFLAGS)
 789           AC_SUBST(SPEEX_LIBS)
 790         ],[
 791           HAVE_SPEEX="no"
 792         ])
 793       ],[
 794         dnl speex 1.0.x :
 795           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 796             dnl speex 1.0.4
 797             HAVE_SPEEX="yes"
 798             SPEEX_LIBS="-lspeex"
 799             AC_SUBST(SPEEX_CFLAGS)
 800             AC_SUBST(SPEEX_LIBS)
 801
 802             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 803               [defined if speex 1.0.x API detected])
 804         ],[
 805             HAVE_SPEEX="no"
 806             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 807         ], [
 808 #include <speex/speex.h>
 809         ])
 810       ])
 811     ])
 812   fi
 813 ])
 814
 815 dnl *** taglib ***
 816 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 817 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 818   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 819   if test "x$HAVE_CXX" != "xyes"; then
 820     USE_TAGLIB=false
 821     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 822   else
 823     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 824     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 825         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 826       ], [
 827         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 828     ])
 829     AC_SUBST(TAGLIB_CXXFLAGS)
 830   fi
 831 ])
 832
 833 dnl *** vpx ***
 834 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 835 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 836   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 837   HAVE_VP8=no
 838   HAVE_VP9=no
 839
 840   if test $HAVE_VPX = "yes"; then
 841     OLD_LIBS="$LIBS"
 842     OLD_CFLAGS="$CFLAGS"
 843     CFLAGS="$CFLAGS $VPX_CFLAGS"
 844     LIBS="$LIBS $VPX_LIBS"
 845     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 846       HAVE_VP8=yes
 847       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 848     ])
 849     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 850       HAVE_VP8=yes
 851       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 852     ])
 853
 854     PKG_CHECK_MODULES(VPX_130, vpx >= 1.3.0, [
 855       AC_CHECK_LIB(vpx, vpx_codec_vp9_cx_algo, [
 856         HAVE_VP9=yes
 857         AC_DEFINE(HAVE_VP9_ENCODER, 1, [Defined if the VP9 encoder is available])
 858       ])
 859       AC_CHECK_LIB(vpx, vpx_codec_vp9_dx_algo, [
 860         HAVE_VP9=yes
 861         AC_DEFINE(HAVE_VP9_DECODER, 1, [Defined if the VP9 decoder is available])
 862       ])
 863     ], [true])
 864     LIBS="$OLD_LIBS"
 865     CFLAGS="$OLD_CFLAGS"
 866   fi
 867   AC_SUBST(VPX_LIBS)
 868   AC_SUBST(VPX_CFLAGS)
 869 ])
 870
 871 dnl *** wavpack ***
 872 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 873 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 874   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 875     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 876       HAVE_WAVPACK=yes
 877       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 878     ],[
 879       HAVE_WAVPACK=no
 880     ])
 881   ])
 882   AC_SUBST(WAVPACK_CFLAGS)
 883   AC_SUBST(WAVPACK_LIBS)
 884 ])
 885
 886 dnl *** qtdemux & matroska prefer to have zlib ***
 887 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 888 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 889   AG_GST_CHECK_LIBHEADER(ZLIB,
 890     z, uncompress,, zlib.h, [
 891     HAVE_ZLIB="yes"
 892     ZLIB_LIBS="-lz"
 893     AC_SUBST(ZLIB_LIBS)
 894   ])
 895 ])
 896
 897 dnl *** matroska prefers to have bz2 ***
 898 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 899 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 900   save_LIBS=$LIBS
 901   LIBS="$LIBS -lbz2"
 902   AC_MSG_CHECKING([for BZ2_bzlibVersion in -lbz2])
 903   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <bzlib.h>]], [[const char *version = BZ2_bzlibVersion ();]])],[HAVE_BZ2=yes],[HAVE_BZ2=no])
 904   AC_MSG_RESULT($HAVE_BZ2)
 905   LIBS=$save_LIBS
 906   if test "x$HAVE_BZ2" = "xyes"; then
 907     BZ2_LIBS="-lbz2"
 908   fi
 909   AC_SUBST(BZ2_LIBS)
 910 ])
 911
 912 else
 913
 914 dnl not building plugins with external dependencies,
 915 dnl but we still need to set the conditionals
 916 AM_CONDITIONAL(USE_AALIB, false)
 917 AM_CONDITIONAL(USE_BZ2, false)
 918 AM_CONDITIONAL(USE_CAIRO, false)
 919 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 920 AM_CONDITIONAL(USE_DV1394, false)
 921 AM_CONDITIONAL(USE_FLAC, false)
 922 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 923 AM_CONDITIONAL(USE_JACK, false)
 924 AM_CONDITIONAL(USE_JPEG, false)
 925 AM_CONDITIONAL(USE_LIBCACA, false)
 926 AM_CONDITIONAL(USE_LIBDV, false)
 927 AM_CONDITIONAL(USE_LIBIEC61883, false)
 928 AM_CONDITIONAL(USE_LIBPNG, false)
 929 AM_CONDITIONAL(USE_OSS, false)
 930 AM_CONDITIONAL(USE_OSS4, false)
 931 AM_CONDITIONAL(USE_OSX_AUDIO, false)
 932 AM_CONDITIONAL(USE_OSX_VIDEO, false)
 933 AM_CONDITIONAL(USE_PULSE, false)
 934 AM_CONDITIONAL(USE_SHOUT2, false)
 935 AM_CONDITIONAL(USE_SOUP, false)
 936 AM_CONDITIONAL(USE_SPEEX, false)
 937 AM_CONDITIONAL(USE_SUNAUDIO, false)
 938 AM_CONDITIONAL(USE_TAGLIB, false)
 939 AM_CONDITIONAL(USE_VPX, false)
 940 AM_CONDITIONAL(USE_WAVEFORM, false)
 941 AM_CONDITIONAL(USE_WAVPACK, false)
 942 AM_CONDITIONAL(USE_X, false)
 943 AM_CONDITIONAL(USE_XSHM, false)
 944 AM_CONDITIONAL(USE_ZLIB, false)
 945
 946 fi dnl of EXT plugins
 947
 948 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 949
 950 dnl Overview:
 951 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 952 dnl GST_*:              flags shared by all built objects
 953 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 954 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
 955 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 956 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 957
 958 dnl GST_OPTION_CFLAGS
 959 if test "x$USE_DEBUG" = xyes; then
 960    PROFILE_CFLAGS="-g"
 961 fi
 962 AC_SUBST(PROFILE_CFLAGS)
 963
 964 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 965   dnl Define _only_ for git (not pre-releases or releases)
 966   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 967 else
 968   DEPRECATED_CFLAGS=""
 969 fi
 970 AC_SUBST(DEPRECATED_CFLAGS)
 971
 972 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
 973 dnl at make time with e.g. make ERROR_CFLAGS=""
 974 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 975 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 976 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 977 AC_SUBST(GST_OPTION_CFLAGS)
 978 AC_SUBST(GST_OPTION_CXXFLAGS)
 979 AC_SUBST(GST_OPTION_OBJCFLAGS)
 980
 981 dnl our libraries need to be versioned correctly
 982 AC_SUBST(GST_LT_LDFLAGS)
 983
 984 dnl FIXME: do we want to rename to GST_ALL_* ?
 985 dnl prefer internal headers to already installed ones
 986 dnl also add builddir include for enumtypes and marshal
 987 dnl add ERROR_CFLAGS, but overridable
 988 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 989 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 990 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
 991 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 992 AC_SUBST(GST_CFLAGS)
 993 AC_SUBST(GST_CXXFLAGS)
 994 AC_SUBST(GST_OBJCFLAGS)
 995 AC_SUBST(GST_LIBS)
 996
 997 dnl LDFLAGS really should only contain flags, not libs - they get added before
 998 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 999 GST_ALL_LDFLAGS="-no-undefined"
1000 AC_SUBST(GST_ALL_LDFLAGS)
1001
1002 dnl this really should only contain flags, not libs - they get added before
1003 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1004 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_.*' $GST_ALL_LDFLAGS"
1005 AC_SUBST(GST_PLUGIN_LDFLAGS)
1006
1007 dnl *** output files ***
1008
1009 $MKDIR_P tests/check/orc
1010
1011 dnl keep this alphabetic per directory, please
1012 AC_CONFIG_FILES(
1013 Makefile
1014 gst/Makefile
1015 gst/alpha/Makefile
1016 gst/apetag/Makefile
1017 gst/audiofx/Makefile
1018 gst/audioparsers/Makefile
1019 gst/auparse/Makefile
1020 gst/autodetect/Makefile
1021 gst/avi/Makefile
1022 gst/cutter/Makefile
1023 gst/deinterlace/Makefile
1024 gst/dtmf/Makefile
1025 gst/debugutils/Makefile
1026 gst/effectv/Makefile
1027 gst/equalizer/Makefile
1028 gst/flv/Makefile
1029 gst/goom/Makefile
1030 gst/goom2k1/Makefile
1031 gst/id3demux/Makefile
1032 gst/icydemux/Makefile
1033 gst/imagefreeze/Makefile
1034 gst/interleave/Makefile
1035 gst/isomp4/Makefile
1036 gst/law/Makefile
1037 gst/level/Makefile
1038 gst/matroska/Makefile
1039 gst/monoscope/Makefile
1040 gst/multifile/Makefile
1041 gst/multipart/Makefile
1042 gst/replaygain/Makefile
1043 gst/rtp/Makefile
1044 gst/rtpmanager/Makefile
1045 gst/rtsp/Makefile
1046 gst/shapewipe/Makefile
1047 gst/smpte/Makefile
1048 gst/spectrum/Makefile
1049 gst/udp/Makefile
1050 gst/videobox/Makefile
1051 gst/videocrop/Makefile
1052 gst/videofilter/Makefile
1053 gst/videomixer/Makefile
1054 gst/wavenc/Makefile
1055 gst/wavparse/Makefile
1056 gst/flx/Makefile
1057 gst/y4m/Makefile
1058 ext/Makefile
1059 ext/aalib/Makefile
1060 ext/cairo/Makefile
1061 ext/dv/Makefile
1062 ext/flac/Makefile
1063 ext/gdk_pixbuf/Makefile
1064 ext/jack/Makefile
1065 ext/jpeg/Makefile
1066 ext/libcaca/Makefile
1067 ext/libpng/Makefile
1068 ext/pulse/Makefile
1069 ext/raw1394/Makefile
1070 ext/shout2/Makefile
1071 ext/soup/Makefile
1072 ext/speex/Makefile
1073 ext/taglib/Makefile
1074 ext/vpx/Makefile
1075 ext/wavpack/Makefile
1076 sys/Makefile
1077 sys/directsound/Makefile
1078 sys/oss/Makefile
1079 sys/oss4/Makefile
1080 sys/osxaudio/Makefile
1081 sys/osxvideo/Makefile
1082 sys/sunaudio/Makefile
1083 sys/v4l2/Makefile
1084 sys/waveform/Makefile
1085 sys/ximage/Makefile
1086 po/Makefile.in
1087 tests/Makefile
1088 tests/check/Makefile
1089 tests/examples/Makefile
1090 tests/examples/audiofx/Makefile
1091 tests/examples/cairo/Makefile
1092 tests/examples/equalizer/Makefile
1093 tests/examples/jack/Makefile
1094 tests/examples/level/Makefile
1095 tests/examples/pulse/Makefile
1096 tests/examples/rtp/Makefile
1097 tests/examples/shapewipe/Makefile
1098 tests/examples/spectrum/Makefile
1099 tests/examples/v4l2/Makefile
1100 tests/files/Makefile
1101 tests/icles/Makefile
1102 common/Makefile
1103 common/m4/Makefile
1104 m4/Makefile
1105 docs/Makefile
1106 docs/plugins/Makefile
1107 docs/version.entities
1108 pkgconfig/Makefile
1109 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1110 gst-plugins-good.spec
1111 )
1112
1113 dnl Create the config.h file for Visual Studio builds
1114 dnl Beware of spaces and /'s in some of the shell variable contents.
1115 sed \
1116     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1117     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1118     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1119     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1120     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1121     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1122     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1123     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1124     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1125     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1126     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1127     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1128     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1129     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1130     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1131     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1132     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1133     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1134     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1135     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1136     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1137     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1138     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1139     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1140     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1141     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1142     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1143     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1144     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1145     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1146     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1147     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1148     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1149     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1150     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1151     config.h.in >win32/common/config.h-new
1152
1153 AC_OUTPUT
1154
1155 AG_GST_OUTPUT_PLUGINS
1156 ORC_OUTPUT
1157