configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.1.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 26, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.1
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE(
 177   AC_LANG_PROGRAM([
 178 #include <libxml/HTMLparser.h>
 179                      ],[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/rtsp
 193 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 194 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 195   WIN32_LIBS="-lws2_32"
 196   AC_SUBST(WIN32_LIBS)
 197 fi
 198
 199 dnl check for hstrerror, for gst-libs/gst/rtsp
 200 save_libs="$LIBS"
 201 AC_CHECK_FUNC(hstrerror, ,
 202     AC_CHECK_LIB(resolv, hstrerror, ,
 203         [AC_DEFINE(NO_HSTRERROR, 1,
 204              [Define if you have no native hstrerror() function.])]))
 205 HSTRERROR_LIBS=$LIBS
 206 AC_SUBST(HSTRERROR_LIBS)
 207 LIBS="$save_libs"
 208
 209 dnl used in gst-libs/gst/pbutils and associated unit test
 210 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 211
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(log2)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used to be used in gst-libs/gst/floatcast/floatcast.h (FIXME: still needed?)
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.26])
 258
 259 ORC_CHECK([0.4.11])
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 269
 270 dnl Check for documentation xrefs
 271 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 272 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 273 AC_SUBST(GLIB_PREFIX)
 274 AC_SUBST(GST_PREFIX)
 275
 276 dnl GTK is optional and only used in examples
 277 HAVE_GTK=no
 278 HAVE_GTK_X11=no
 279 GTK_REQ=3.0.0
 280 if test "x$BUILD_EXAMPLES" = "xyes"; then
 281   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 282   dnl some examples need gtk+-x11
 283   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 284   AC_SUBST(GTK_LIBS)
 285   AC_SUBST(GTK_CFLAGS)
 286 fi
 287 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 288 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 289
 290 dnl QT is optional and only used in examples
 291 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 292   HAVE_QT_GV=yes
 293   HAVE_QT=yes
 294 ], [
 295   HAVE_QT_GV=no
 296   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 297 ])
 298 if test "x$HAVE_QT" = "xyes"; then
 299   AC_MSG_CHECKING([Qt moc])
 300   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 301   AC_MSG_RESULT($QT4_MOC)
 302   AC_SUBST(QT4_MOC)
 303 fi
 304 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 305 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 306
 307 dnl chck for linux headers needed by the joystick seek example
 308 AC_COMPILE_IFELSE(
 309 [
 310   AC_LANG_PROGRAM([
 311     #include <linux/input.h>
 312     #include <linux/joystick.h>
 313   ],[
 314     struct js_event js;
 315     js.type = JS_EVENT_AXIS;
 316   ])
 317 ], [
 318   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 319 ], [
 320   HAVE_LINUX_JOYSTICK_HEADERS="no"
 321 ])
 322 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 323
 324 dnl Check for -Bsymbolic-functions linker flag used to avoid
 325 dnl intra-library PLT jumps, if available.
 326 AC_ARG_ENABLE(Bsymbolic,
 327               [AC_HELP_STRING([--disable-Bsymbolic],
 328                               [avoid linking with -Bsymbolic])],,
 329               [SAVED_LDFLAGS="${LDFLAGS}"
 330                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 331                LDFLAGS=-Wl,-Bsymbolic-functions
 332                AC_TRY_LINK([], [int main (void) { return 0; }],
 333                            AC_MSG_RESULT(yes)
 334                            enable_Bsymbolic=yes,
 335                            AC_MSG_RESULT(no)
 336                            enable_Bsymbolic=no)
 337                LDFLAGS="${SAVED_LDFLAGS}"])
 338
 339
 340 dnl *** set variables based on configure arguments ***
 341
 342 dnl set license and copyright notice
 343 GST_LICENSE="LGPL"
 344 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 345 AC_SUBST(GST_LICENSE)
 346
 347 dnl set location of plugin directory
 348 AG_GST_SET_PLUGINDIR
 349
 350 dnl set release date/time
 351 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 352   ["${srcdir}/gst-plugins-base.doap"],
 353   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 354
 355 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 356 dnl make sure it doesn't complain about unused variables if debugging is disabled
 357 NO_WARNINGS=""
 358 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 359
 360 dnl define an ERROR_CFLAGS Makefile variable
 361 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 362 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 363     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 364     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 365     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 366     -Wno-multichar -Wnested-externs $NO_WARNINGS])
 367
 368 dnl define an ERROR_CXXFLAGS Makefile variable
 369 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 370     -Wmissing-declarations -Wredundant-decls -Wundef
 371     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 372     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 373     -Wno-multichar $NO_WARNINGS])
 374
 375 dnl define correct level for debugging messages
 376 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 377
 378 dnl used in examples
 379 AG_GST_DEFAULT_ELEMENTS
 380
 381 dnl needed for encoding-target
 382 GST_DATADIR="$GST_PREFIX/share"
 383 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 384 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 385
 386 dnl behaviour of speex based audio resampler
 387 AC_MSG_CHECKING(which audio resample format to use for integer)
 388 AC_ARG_WITH([audioresample_format],
 389         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 390         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 391 AC_MSG_RESULT($ac_cv_audioresample_format)
 392 case $ac_cv_audioresample_format in
 393   int)
 394     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 395     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 396   ;;
 397   float)
 398     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 399     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 400   ;;
 401   auto)
 402     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 403     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 404 esac
 405
 406 dnl *** plug-ins to include ***
 407
 408 dnl these are all the gst plug-ins, compilable without additional libs
 409 AG_GST_CHECK_PLUGIN(adder)
 410 AG_GST_CHECK_PLUGIN(app)
 411 AG_GST_CHECK_PLUGIN(audioconvert)
 412 AG_GST_CHECK_PLUGIN(audiorate)
 413 AG_GST_CHECK_PLUGIN(audiotestsrc)
 414 AG_GST_CHECK_PLUGIN(encoding)
 415 AG_GST_CHECK_PLUGIN(videoconvert)
 416 AG_GST_CHECK_PLUGIN(gdp)
 417 AG_GST_CHECK_PLUGIN(playback)
 418 AG_GST_CHECK_PLUGIN(audioresample)
 419 AG_GST_CHECK_PLUGIN(subparse)
 420 AG_GST_CHECK_PLUGIN(tcp)
 421 AG_GST_CHECK_PLUGIN(typefind)
 422 AG_GST_CHECK_PLUGIN(videotestsrc)
 423 AG_GST_CHECK_PLUGIN(videorate)
 424 AG_GST_CHECK_PLUGIN(videoscale)
 425 AG_GST_CHECK_PLUGIN(volume)
 426
 427 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 428 AM_CONDITIONAL(USE_XML, false)
 429 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 430
 431 dnl disable plug-ins that require libxml2's HTML support if it is not available
 432 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 433   AG_GST_DISABLE_PLUGIN(subparse)
 434 fi
 435
 436 dnl disable plug-ins that require sys/socket.h if it is not available
 437 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 438   AG_GST_DISABLE_PLUGIN(tcp)
 439 fi
 440
 441 dnl iso-codes is optional, used by libgsttag
 442 AC_ARG_ENABLE(iso-codes,
 443 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 444 [case "${enableval}" in
 445   yes) enable_iso_codes=yes ;;
 446   no)  enable_iso_codes=no ;;
 447   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 448 esac
 449 ],
 450 [enable_iso_codes=yes]) dnl Default value
 451
 452 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 453 if test "x$enable_iso_codes" = "xyes"; then
 454   AC_MSG_RESULT([yes])
 455   have_iso_codes=no
 456   AC_MSG_CHECKING([whether iso-codes are available on this system])
 457   if $PKG_CONFIG iso-codes; then
 458     AC_MSG_RESULT([yes])
 459     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 460     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 461       AC_MSG_RESULT([yes])
 462       AC_MSG_CHECKING([for iso-codes prefix])
 463       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 464       if test -d "$ISO_CODES_PREFIX"; then
 465         AC_MSG_RESULT([yes])
 466         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 467         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 468         ISO_639_DOMAIN="iso_639"
 469         AC_MSG_CHECKING([ISO_639_DOMAIN])
 470         AC_MSG_RESULT([$ISO_639_DOMAIN])
 471         have_iso_codes=yes
 472         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 473         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 474         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 475         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 476       else
 477         AC_MSG_RESULT([no])
 478       fi
 479     else
 480       AC_MSG_RESULT([no])
 481     fi
 482   else
 483     AC_MSG_RESULT([no])
 484   fi
 485   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 486 else
 487   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 488   AM_CONDITIONAL(USE_ISO_CODES, false)
 489 fi
 490
 491 dnl *** zlib is optionally used by id3 tag parsing in libgsttag ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 493 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for ID3 parsing in libgsttag],, [
 494   PKG_CHECK_MODULES(ZLIB, [ zlib ], [
 495       HAVE_ZLIB="yes"
 496     ], [
 497       AG_GST_CHECK_LIBHEADER(ZLIB, z, uncompress,, zlib.h, [
 498         HAVE_ZLIB="yes"
 499         ZLIB_LIBS="-lz"
 500         AC_SUBST(ZLIB_LIBS)
 501       ])
 502     ])
 503 ])
 504
 505 dnl *** sys plug-ins ***
 506
 507 echo
 508 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 509 echo
 510
 511 dnl *** X11 ***
 512 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 513 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 514                   [ximagesink], [
 515   AC_PATH_XTRA
 516   ac_cflags_save="$CFLAGS"
 517   ac_cppflags_save="$CPPFLAGS"
 518   CFLAGS="$CFLAGS $X_CFLAGS"
 519   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 520
 521   dnl now try to find the HEADER
 522   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 523
 524   if test "x$HAVE_X" = "xno"
 525   then
 526     AC_MSG_NOTICE([cannot find X11 development files])
 527   else
 528     dnl this is much more than we want
 529     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 530     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 531     dnl it does not add the libs; therefore we add them here
 532     X_LIBS="$X_LIBS -lX11"
 533     AC_SUBST(X_CFLAGS)
 534     AC_SUBST(X_LIBS)
 535   fi
 536   AC_SUBST(HAVE_X)
 537   CFLAGS="$ac_cflags_save"
 538   CPPFLAGS="$ac_cppflags_save"
 539 ])
 540
 541 dnl Check for Xv extension
 542 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 543 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 544                   [xvimagesink], [
 545   AG_GST_CHECK_XV
 546 ])
 547
 548 dnl check for X Shm
 549 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 550 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 551   if test x$HAVE_X = xyes; then
 552     AC_CHECK_LIB(Xext, XShmAttach,
 553                  HAVE_XSHM="yes", HAVE_XSHM="no",
 554                  $X_LIBS)
 555     if test "x$HAVE_XSHM" = "xyes"; then
 556       XSHM_LIBS="-lXext"
 557     else
 558       dnl On AIX, it is in XextSam instead, but we still need -lXext
 559       AC_CHECK_LIB(XextSam, XShmAttach,
 560                    HAVE_XSHM="yes", HAVE_XSHM="no",
 561                    $X_LIBS)
 562       if test "x$HAVE_XSHM" = "xyes"; then
 563         XSHM_LIBS="-lXext -lXextSam"
 564       fi
 565     fi
 566   fi
 567 ], , [
 568   AC_SUBST(HAVE_XSHM)
 569   AC_SUBST(XSHM_LIBS)
 570 ])
 571
 572 dnl *** ext plug-ins ***
 573 dnl keep this list sorted alphabetically !
 574
 575 if test "x$BUILD_EXTERNAL" = "xyes"; then
 576
 577 echo
 578 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 579 echo
 580
 581 dnl *** alsa ***
 582 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 583 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 584   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 585     HAVE_ALSA="yes"
 586     AC_SUBST(ALSA_CFLAGS)
 587     AC_SUBST(ALSA_LIBS)
 588   ], [
 589     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 590   ])
 591 ])
 592
 593 dnl *** CDParanoia ***
 594 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 595 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 596 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 597   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 598     HAVE_CDPARANOIA="yes"
 599   ], [
 600     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 601                         cdda_open, -lm,
 602                         cdda_interface.h,
 603                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 604                         HEADER_DIR="no"
 605                         FOUND_CDPARANOIA="yes")
 606     if test "x$FOUND_CDPARANOIA" != "xyes";
 607     then
 608       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 609                           cdda_open, -lm,
 610                           cdda/cdda_interface.h,
 611                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 612                           HEADER_DIR="yes"
 613                           FOUND_CDPARANOIA="yes")
 614     fi
 615     if test "x$HEADER_DIR" = "xyes";
 616     then
 617       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 618                          defined if cdda headers are in a cdda/ directory)
 619     fi
 620     if test "x$FOUND_CDPARANOIA" = "xyes";
 621     then
 622       AC_CHECK_LIB(cdda_paranoia,
 623                    paranoia_cachemodel_size,
 624                    : ,
 625                    HAVE_CDPARANOIA=no,
 626                  [-lcdda_interface])
 627     fi
 628
 629     AC_SUBST(CDPARANOIA_LIBS)
 630   ])
 631 ])
 632 dnl FIXME : add second check somehow if that is necessary
 633 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 634 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 635
 636 dnl *** ivorbis ***
 637 dnl AM_PATH_IVORBIS only takes two options
 638 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 639 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 640   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 641   if test $HAVE_IVORBIS = no
 642   then
 643     IVORBIS_LIBS=
 644     IVORBIS_CFLAGS=
 645     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 646       [IVORBIS_LIBS=-lvorbisidec
 647       HAVE_IVORBIS=yes
 648       case $host in
 649       arm-*-*)
 650         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 651       esac
 652       ],
 653       HAVE_IVORBIS=no)
 654     AC_SUBST(IVORBIS_LIBS)
 655     AC_SUBST(IVORBIS_CFLAGS)
 656   else
 657     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 658       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 659       USE_TREMOLO=no)
 660   fi
 661 ])
 662
 663 dnl *** libgio ***
 664 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 665 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 666   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 667     HAVE_GIO="yes"
 668     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 669     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 670            [The GIO modules directory.])
 671     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 672     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 673            [The GIO library directory.])
 674   ], [
 675     HAVE_GIO="no"
 676   ])
 677   AC_SUBST(GIO_CFLAGS)
 678   AC_SUBST(GIO_LIBS)
 679   AC_SUBST(GIO_LDFLAGS)
 680 ])
 681
 682 dnl *** libvisual ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 684 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 685   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 686   if test $HAVE_LIBVISUAL = no
 687   then
 688     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 689     if test x$HAVE_LIBVISUAL = xyes; then
 690       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 691     fi
 692   else
 693     if test x$HAVE_LIBVISUAL = xyes; then
 694       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 695     fi
 696   fi
 697   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 698   if test x$LIBVIS_PLUGINSDIR != x; then
 699     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 700         "$LIBVIS_PLUGINSDIR",
 701         [directory in which the detected libvisual's plugins are located])
 702   fi
 703 ])
 704
 705 dnl *** ogg ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 707 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 708   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 709   if test $HAVE_OGG = no
 710   then
 711     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 712     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 713   fi
 714 ])
 715
 716 dnl *** pango ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 718 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 719   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 720 ])
 721
 722 dnl *** theora ***
 723 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 724 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 725   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 726 ])
 727
 728 dnl *** vorbis ***
 729 dnl AM_PATH_VORBIS only takes two options
 730 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 731 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 732   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 733   if test $HAVE_VORBIS = no
 734   then
 735     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 736     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 737   fi
 738 ])
 739
 740 if test "x$HAVE_VORBIS" = "xyes"; then
 741   ac_cflags_save="$CFLAGS"
 742   AC_COMPILE_IFELSE(
 743     AC_LANG_PROGRAM([
 744 #include <vorbis/codec.h>
 745                      ],[
 746 vorbis_dsp_state *v;
 747
 748 vorbis_synthesis_restart (v);
 749                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 750   if test "x$HAVE_VSR" = "xyes"; then
 751     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 752                        [defined if vorbis_synthesis_restart is present])
 753   fi
 754   CFLAGS="$ac_cflags_save"
 755 fi
 756
 757 else
 758
 759 dnl not building plugins with external dependencies,
 760 dnl but we still need to set the conditionals
 761 AM_CONDITIONAL(USE_ALSA, false)
 762 AM_CONDITIONAL(USE_CDPARANOIA, false)
 763 AM_CONDITIONAL(USE_GIO, false)
 764 AM_CONDITIONAL(USE_IVORBIS, false)
 765 AM_CONDITIONAL(USE_LIBVISUAL, false)
 766 AM_CONDITIONAL(USE_OGG, false)
 767 AM_CONDITIONAL(USE_PANGO, false)
 768 AM_CONDITIONAL(USE_THEORA, false)
 769 AM_CONDITIONAL(USE_VORBIS, false)
 770
 771 fi dnl of EXT plugins
 772
 773 dnl seeking needs freetype, so check for it here
 774 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 775   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 776 ])
 777 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 778 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 779 AC_SUBST(FT2_CFLAGS)
 780 AC_SUBST(FT2_LIBS)
 781
 782 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 783
 784 dnl Overview:
 785 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 786 dnl GST_*:              flags shared by built objects to link against GStreamer
 787 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 788 dnl                          (compare to other modules) or for i18n
 789 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 790 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 791 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 792 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 793
 794 dnl GST_OPTION_CFLAGS
 795 if test "x$USE_DEBUG" = xyes; then
 796    PROFILE_CFLAGS="-g"
 797 fi
 798 AC_SUBST(PROFILE_CFLAGS)
 799
 800 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 801   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 802   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 803 else
 804   DEPRECATED_CFLAGS=""
 805 fi
 806 AC_SUBST(DEPRECATED_CFLAGS)
 807
 808 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 809 dnl at make time with e.g. make ERROR_CFLAGS=""
 810 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 811 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 812 AC_SUBST(GST_OPTION_CFLAGS)
 813 AC_SUBST(GST_OPTION_CXXFLAGS)
 814
 815 dnl our libraries need to be versioned correctly
 816 AC_SUBST(GST_LT_LDFLAGS)
 817
 818 dnl GST_PLUGINS_BASE_CFLAGS
 819 dnl prefer internal headers to already installed ones
 820 dnl also add builddir include for enumtypes and marshal
 821 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 822 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 823
 824 dnl FIXME: do we want to rename to GST_ALL_* ?
 825 dnl add GST_OPTION_CFLAGS, but overridable
 826 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 827 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CXXFLAGS)"
 828 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS \$(GLIB_EXTRA_CFLAGS) \$(GST_OPTION_CFLAGS)"
 829 AC_SUBST(GST_CFLAGS)
 830 AC_SUBST(GST_CXXFLAGS)
 831 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 832 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 833 AC_SUBST(GST_LIBS)
 834
 835 dnl LDFLAGS really should only contain flags, not libs - they get added before
 836 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 837 GST_ALL_LDFLAGS="-no-undefined"
 838 if test "x${enable_Bsymbolic}" = "xyes"; then
 839   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 840 fi
 841 AC_SUBST(GST_ALL_LDFLAGS)
 842
 843 dnl GST_LIB_LDFLAGS
 844 dnl linker flags shared by all libraries
 845 dnl LDFLAGS modifier defining exported symbols from built libraries
 846 dnl (export _gst_foo but not __gst_foo)
 847 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 848 AC_SUBST(GST_LIB_LDFLAGS)
 849
 850 dnl this really should only contain flags, not libs - they get added before
 851 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 852 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 853 AC_SUBST(GST_PLUGIN_LDFLAGS)
 854
 855 dnl *** output files ***
 856
 857 AC_CONFIG_FILES(
 858 Makefile
 859 gst-plugins-base.spec
 860 gst/Makefile
 861 gst/adder/Makefile
 862 gst/app/Makefile
 863 gst/audioconvert/Makefile
 864 gst/audiorate/Makefile
 865 gst/audiotestsrc/Makefile
 866 gst/encoding/Makefile
 867 gst/videoconvert/Makefile
 868 gst/gdp/Makefile
 869 gst/playback/Makefile
 870 gst/audioresample/Makefile
 871 gst/subparse/Makefile
 872 gst/tcp/Makefile
 873 gst/typefind/Makefile
 874 gst/videotestsrc/Makefile
 875 gst/videorate/Makefile
 876 gst/videoscale/Makefile
 877 gst/volume/Makefile
 878 sys/Makefile
 879 sys/ximage/Makefile
 880 sys/xvimage/Makefile
 881 ext/Makefile
 882 ext/alsa/Makefile
 883 ext/cdparanoia/Makefile
 884 ext/gio/Makefile
 885 ext/libvisual/Makefile
 886 ext/ogg/Makefile
 887 ext/pango/Makefile
 888 ext/theora/Makefile
 889 ext/vorbis/Makefile
 890 gst-libs/Makefile
 891 gst-libs/gst/Makefile
 892 gst-libs/gst/audio/Makefile
 893 gst-libs/gst/app/Makefile
 894 gst-libs/gst/fft/Makefile
 895 gst-libs/gst/interfaces/Makefile
 896 gst-libs/gst/riff/Makefile
 897 gst-libs/gst/rtp/Makefile
 898 gst-libs/gst/rtsp/Makefile
 899 gst-libs/gst/sdp/Makefile
 900 gst-libs/gst/tag/Makefile
 901 gst-libs/gst/pbutils/Makefile
 902 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 903 gst-libs/gst/video/Makefile
 904 tools/Makefile
 905 pkgconfig/Makefile
 906 pkgconfig/gstreamer-audio.pc
 907 pkgconfig/gstreamer-audio-uninstalled.pc
 908 pkgconfig/gstreamer-app.pc
 909 pkgconfig/gstreamer-app-uninstalled.pc
 910 pkgconfig/gstreamer-fft.pc
 911 pkgconfig/gstreamer-fft-uninstalled.pc
 912 pkgconfig/gstreamer-interfaces.pc
 913 pkgconfig/gstreamer-interfaces-uninstalled.pc
 914 pkgconfig/gstreamer-pbutils.pc
 915 pkgconfig/gstreamer-pbutils-uninstalled.pc
 916 pkgconfig/gstreamer-riff.pc
 917 pkgconfig/gstreamer-riff-uninstalled.pc
 918 pkgconfig/gstreamer-rtp.pc
 919 pkgconfig/gstreamer-rtp-uninstalled.pc
 920 pkgconfig/gstreamer-rtsp.pc
 921 pkgconfig/gstreamer-rtsp-uninstalled.pc
 922 pkgconfig/gstreamer-sdp.pc
 923 pkgconfig/gstreamer-sdp-uninstalled.pc
 924 pkgconfig/gstreamer-tag.pc
 925 pkgconfig/gstreamer-tag-uninstalled.pc
 926 pkgconfig/gstreamer-video.pc
 927 pkgconfig/gstreamer-video-uninstalled.pc
 928 pkgconfig/gstreamer-plugins-base.pc
 929 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 930 tests/Makefile
 931 tests/check/Makefile
 932 tests/examples/Makefile
 933 tests/examples/app/Makefile
 934 tests/examples/audio/Makefile
 935 tests/examples/dynamic/Makefile
 936 tests/examples/encoding/Makefile
 937 tests/examples/gio/Makefile
 938 tests/examples/overlay/Makefile
 939 tests/examples/seek/Makefile
 940 tests/examples/snapshot/Makefile
 941 tests/examples/playrec/Makefile
 942 tests/files/Makefile
 943 tests/icles/Makefile
 944 tests/icles/playback/Makefile
 945 docs/Makefile
 946 docs/design/Makefile
 947 docs/libs/Makefile
 948 docs/plugins/Makefile
 949 docs/version.entities
 950 po/Makefile.in
 951 common/Makefile
 952 common/m4/Makefile
 953 m4/Makefile
 954 )
 955
 956 dnl Create the config.h file for Visual Studio builds
 957 dnl Beware of spaces and /'s in some of the shell variable contents.
 958 sed \
 959     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 960     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 961     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 962     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 963     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 964     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 965     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 966     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 967     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 968     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 969     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 970     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 971     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 972     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 973     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 974     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 975     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 976     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 977     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 978     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 979     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 980     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 981     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 982     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 983     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 984     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 985     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 986     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 987     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 988     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 989     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 990     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 991     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 992     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 993     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 994     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 995     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 996     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
 997     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 998     config.h.in >win32/common/config.h-new
 999
1000
1001
1002 AC_OUTPUT
1003
1004 AG_GST_OUTPUT_PLUGINS
1005 ORC_OUTPUT
1006