configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [7])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [31])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [6])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 if test "x$enable_tracker_backend" = "xyes"; then
  81         AC_DEFINE(HAVE_TRACKER, [1],
  82                   [Define as 1 if you have the Tracker backend])
  83 else
  84         AC_DEFINE(HAVE_TRACKER, [0],
  85                   [Define as 1 if you have the Tracker backend])
  86 fi
  87
  88 AC_ARG_ENABLE(eds-backend,
  89         AC_HELP_STRING([--enable-eds-backend],
  90                        [ build the E-D-S backend]),
  91         enable_eds_backend=$enableval,
  92         enable_eds_backend=yes )
  93
  94 if test "x$enable_eds_backend" = "xyes"; then
  95         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  96 else
  97         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  98 fi
  99
 100
 101 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 102
 103 # Automatically check the dependencies for the libsocialweb backend
 104 SW_CLIENT_REQUIRED=0.25.15
 105 AC_ARG_ENABLE(libsocialweb-backend,
 106         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 107                        [build the Libsocialweb backend (default: auto)]),
 108         enable_libsocialweb_backend=$enableval,
 109         enable_libsocialweb_backend=auto )
 110
 111 # this may be overwritten farther down
 112 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 113           [Define as 1 if you have the libsocialweb backend])
 114 if test "x$enable_libsocialweb_backend" != "xno"; then
 115   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 116       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 117   if test "x$have_libsocialweb_backend" = "xyes" -a \
 118           "x$enable_vala" = "xyes"; then
 119     VALA_CHECK_PACKAGES([telepathy-glib
 120                          gio-2.0
 121                          gee-1.0
 122                          libsocialweb-client],
 123         ,
 124         have_libsocialweb_backend="no")
 125   fi
 126
 127   if test "x$have_libsocialweb_backend" = "xyes"; then
 128     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 129               [Define if you have the libsocialweb backend])
 130   fi
 131 else
 132    have_libsocialweb_backend=no
 133 fi
 134
 135 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 136   "x$have_libsocialweb_backend" != "xyes"; then
 137     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 138 fi
 139
 140 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 141         [test "x$have_libsocialweb_backend" = "xyes"])
 142
 143 # -----------------------------------------------------------
 144 # Dependencies
 145 # -----------------------------------------------------------
 146
 147 GLIB_REQUIRED=2.24.0
 148 TP_GLIB_REQUIRED=0.13.1
 149 VALA_REQUIRED=0.15.1
 150 VALADOC_REQUIRED=0.3.1
 151 TRACKER_SPARQL_MAJOR=0.12
 152 TRACKER_SPARQL_REQUIRED=0.12.0
 153 GCONF2_REQUIRED=2.31
 154 EBOOK_REQUIRED=3.1.5
 155 EDATASERVER_REQUIRED=3.1.5
 156
 157 PKG_CHECK_MODULES([GLIB],
 158                   [glib-2.0 >= $GLIB_REQUIRED
 159                    gobject-2.0 >= $GLIB_REQUIRED])
 160 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 161 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 162 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 163 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 164
 165 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 166 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7],
 167                   have_gee_0_6_x="yes",
 168                   have_gee_0_6_x="no")
 169
 170 if test "x$have_gee_0_6_x" != "xyes"; then
 171     AC_MSG_ERROR([
 172 Gee 0.6.x required but not installed.
 173
 174 Note that Gee 0.8.x provides gee-0.8 (but gee-1.0 is, confusingly, provided by
 175 Gee 0.6.x)])
 176 fi
 177
 178 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 179
 180 if test x$enable_tracker_backend = xyes; then
 181         PKG_CHECK_MODULES([TRACKER_SPARQL],
 182                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 183                            $TRACKER_SPARQL_REQUIRED])
 184 fi
 185
 186 if test x$enable_eds_backend = xyes; then
 187         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 188         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 189 fi
 190
 191 #
 192 # Vala building options -- allows tarball builds without installing Vala
 193 #
 194 AC_ARG_ENABLE([vala],
 195               AS_HELP_STRING([--enable-vala],
 196                              [Enable building from the Vala sources]),
 197               [enable_vala=$enableval],
 198               [enable_vala=no])
 199
 200 # will be re-set as necessary below
 201 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 202 sd=${srcdir}/
 203
 204 # Force Vala for non-release builds
 205 m4_if(folks_released, [1], [],
 206     [
 207         enable_vala=yes
 208         echo "Vala compiler required for non-release builds; requiring Vala..."
 209     ])
 210
 211 # Force Vala if generated source is missing or outdated
 212 if test \
 213         ! -e ${sd}tools/folks_import_vala.stamp -o \
 214         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 215         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 216         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 217         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 218         ! -e ${sd}tests/lib/folks-test.vapi -o \
 219         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 220         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 221         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 222         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 223         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 224         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 225         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 226         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 227         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 228         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 229         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 230                 -o \
 231         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 232         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 233         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 234         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 235         ! -e ${sd}folks/folks-internal.h -o \
 236         ! -e ${sd}folks/folks-internal.vapi -o \
 237         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 238         ! -e ${sd}folks/folks.vapi -o \
 239         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 240         enable_vala=yes
 241         echo "Vala source needs to be re-compiled; requiring Vala..."
 242 fi
 243
 244 if test "x$enable_vala" = "xyes" ; then
 245         AM_PROG_VALAC([$VALA_REQUIRED])
 246         if test "x$VALAC" = "x"; then
 247               AC_MSG_ERROR([Vala requested but valac is not installed])
 248         fi
 249
 250         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 251         if test "x$VAPIGEN" = "x"; then
 252               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 253         fi
 254
 255         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 256         # automatically
 257         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 258         AC_SUBST([VALAFLAGS])
 259         AC_SUBST([VAPIGENFLAGS])
 260         AC_SUBST([VAPIDIR])
 261
 262         VALA_CHECK_PACKAGES([telepathy-glib
 263                              gio-2.0
 264                              gee-1.0])
 265
 266         if test x$enable_tracker_backend = xyes; then
 267           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 268         fi
 269
 270         if test x$enable_eds_backend = xyes; then
 271           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 272         fi
 273 fi
 274
 275 # this will set HAVE_INTROSPECTION
 276 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 277
 278 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 279
 280 # Various functions that we need (used in C code generated from Vala)
 281 AC_CHECK_FUNCS([memset])
 282 AC_CHECK_FUNCS([strstr])
 283
 284 # -----------------------------------------------------------
 285 # Backends
 286 # -----------------------------------------------------------
 287
 288 FOLKS_MODULE_VERSION=folks_module_version
 289 AC_SUBST([FOLKS_MODULE_VERSION])
 290 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 291
 292 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 293 AC_SUBST([BACKEND_DIR])
 294
 295 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 296 AC_SUBST([BACKEND_KF])
 297 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 298 AC_SUBST([BACKEND_TP])
 299
 300 if test x$have_libsocialweb_backend = xyes; then
 301   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 302   AC_SUBST([BACKEND_LIBSOCIALWEB])
 303 fi
 304
 305 if test x$enable_tracker_backend = xyes; then
 306   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 307   AC_SUBST([BACKEND_TRACKER])
 308 fi
 309
 310 if test x$enable_eds_backend = xyes; then
 311   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 312   AC_SUBST([BACKEND_EDS])
 313 fi
 314
 315 # All of the backend libraries in our tree; to be used by the tests
 316 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 317 if test x$have_libsocialweb_backend = xyes; then
 318   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 319   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 320 fi
 321 if test x$enable_tracker_backend = xyes; then
 322   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 323   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 324 fi
 325 if test x$enable_eds_backend = xyes; then
 326   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 327   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 328 fi
 329 AC_SUBST([BACKEND_UNINST_PATH])
 330
 331 # -----------------------------------------------------------
 332 # Tools
 333 # -----------------------------------------------------------
 334
 335 AC_ARG_ENABLE([import-tool],
 336               AS_HELP_STRING([--enable-import-tool],
 337                              [Enable building the meta-contact import tool]),
 338               [enable_import_tool=$enableval with_import_tool=$enableval],
 339               [enable_import_tool=maybe with_import_tool=no])
 340 AS_IF([test "$enable_import_tool" != "no"],
 341       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 342                          [with_import_tool=yes], [with_import_tool=no])])
 343 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 344       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 345 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 346
 347 # Readline's required for the folks-inspect program
 348 AC_ARG_ENABLE([inspect-tool],
 349               AS_HELP_STRING([--enable-inspect-tool],
 350                              [Enable building the data inspection tool]),
 351               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 352               [enable_inspect_tool=maybe with_inspect_tool=no])
 353 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 354       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 355                      using --enable-vala])])
 356 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 357       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 358                       --enable-vala])])
 359 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 360       [AC_CHECK_LIB([readline], [main],
 361                     [with_inspect_tool=yes], [with_inspect_tool=no],
 362                     [-lncurses])])
 363 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 364        "x$enable_vala" = "xyes"],
 365       [VALA_CHECK_PACKAGES([readline])
 366        LIBREADLINE="-lreadline -lncurses"
 367        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 368        AC_SUBST([LIBREADLINE])])
 369 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 370       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 371 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 372
 373 # -----------------------------------------------------------
 374 # Documentation
 375 # -----------------------------------------------------------
 376
 377 AC_ARG_ENABLE([docs],
 378               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 379               [enable_docs=$enableval], [enable_docs=no])
 380 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 381
 382 have_valadoc=no
 383 if test x$enable_docs = xyes; then
 384   # make sure the library is new enough and the program exists
 385   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 386   AC_PATH_PROG([VALADOC], [valadoc], [:])
 387   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 388 fi
 389 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 390
 391 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 392     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 393 fi
 394
 395 # -----------------------------------------------------------
 396 # Gettext
 397 # -----------------------------------------------------------
 398
 399 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 400 AC_SUBST(GETTEXT_PACKAGE)
 401 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 402 IT_PROG_INTLTOOL([0.35.0])
 403
 404 # -----------------------------------------------------------
 405 # Error flags
 406 # -----------------------------------------------------------
 407
 408 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 409 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 410 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 411
 412 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 413 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 414
 415 AC_ARG_ENABLE([debug],
 416               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 417               [enable_debug=$enableval], [enable_debug=yes])
 418
 419 AC_ARG_ENABLE([Werror],
 420               AS_HELP_STRING([--disable-Werror],
 421                              [compile without -Werror (normally enabled in
 422                               development builds)]),
 423               [werror=$enableval], [werror=yes])
 424
 425 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 426 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 427                  [wno_missing_field_initializers=yes],
 428                  [wno_missing_field_initializers=no])
 429 AS_COMPILER_FLAG([-Wno-unused-parameter],
 430                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 431
 432 m4_if(folks_released, [1], [],
 433     [
 434         if test x$werror = xyes; then
 435             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 436         fi
 437         if test x$wextra = xyes -a \
 438             x$wno_missing_field_initializers = xyes -a \
 439             x$wno_unused_parameter = xyes; then
 440             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 441                 -Wno-missing-field-initializers -Wno-unused-parameter"
 442         fi
 443     ])
 444
 445 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 446 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 447 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 448 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 449                                           -Wmissing-prototypes"])
 450 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 451                                             -Wmissing-declarations"])
 452 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 453                                          -Wstrict-prototypes"])
 454
 455 AC_SUBST([ERROR_CFLAGS])
 456
 457 # -----------------------------------------------------------
 458 # Code coverage flags
 459 # -----------------------------------------------------------
 460
 461 AC_ARG_ENABLE([code-coverage],
 462               AS_HELP_STRING([--enable-code-coverage],
 463                              [compile with code coverage code]),
 464               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 465
 466 # Only enable code coverage if this isn't a release.
 467 m4_if(folks_released, [1], [],
 468     [
 469         if test "x$GCC" = "xyes"; then
 470             if test "x$enable_code_coverage" = "xyes"; then
 471                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 472                 CODE_COVERAGE_LDFLAGS="-lgcov"
 473             fi
 474         fi
 475     ])
 476
 477 AC_SUBST([CODE_COVERAGE_CFLAGS])
 478 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 479
 480 # Vala-related flags
 481 AS_IF([test "x$enable_vala" = "xyes"],
 482       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 483                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 484        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 485
 486 # Disable -g if we're building with code coverage enabled, since Vala's
 487 # insertion of #line directives into .c files confuses lcov. For the moment,
 488 # we'll have to do with looking at code coverage of the generated C files only.
 489 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 490 m4_if(folks_released, [1], [],
 491     [
 492         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 493             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 494         fi
 495     ])
 496
 497 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 498 AC_SUBST([ERROR_VALAFLAGS])
 499
 500 # -----------------------------------------------------------
 501 # Final output
 502 # -----------------------------------------------------------
 503
 504 AC_CONFIG_FILES([
 505     backends/telepathy/lib/folks-telepathy.pc
 506     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 507     backends/tracker/lib/folks-tracker.pc
 508     backends/tracker/lib/folks-tracker-uninstalled.pc
 509     backends/eds/lib/folks-eds.pc
 510     backends/eds/lib/folks-eds-uninstalled.pc
 511     folks/folks.pc
 512     folks/folks-uninstalled.pc
 513     Makefile
 514     backends/Makefile
 515     backends/key-file/Makefile
 516     backends/libsocialweb/Makefile
 517     backends/libsocialweb/lib/Makefile
 518     backends/libsocialweb/lib/folks-libsocialweb.pc
 519     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 520     backends/telepathy/Makefile
 521     backends/telepathy/lib/Makefile
 522     backends/tracker/Makefile
 523     backends/tracker/lib/Makefile
 524     backends/eds/Makefile
 525     backends/eds/lib/Makefile
 526     folks/Makefile
 527     docs/Makefile
 528     po/Makefile.in
 529     tests/Makefile
 530     tests/data/Makefile
 531     tests/data/gconf.path
 532     tests/folks/Makefile
 533     tests/key-file/Makefile
 534     tests/libsocialweb/Makefile
 535     tests/telepathy/Makefile
 536     tests/tracker/Makefile
 537     tests/lib/Makefile
 538     tests/lib/folks-test-uninstalled.pc
 539     tests/lib/key-file/Makefile
 540     tests/lib/libsocialweb/Makefile
 541     tests/lib/libsocialweb/session.conf
 542     tests/eds/Makefile
 543     tests/lib/eds/Makefile
 544     tests/lib/telepathy/Makefile
 545     tests/lib/tracker/Makefile
 546     tests/lib/telepathy/contactlist/Makefile
 547     tests/lib/telepathy/contactlist/session.conf
 548     tests/tools/Makefile
 549     tools/Makefile
 550     tools/inspect/Makefile
 551 ])
 552
 553 AC_OUTPUT
 554
 555 echo "
 556 Configure summary:
 557
 558         Vala........................:  ${enable_vala}
 559         Vala Compiler...............:  ${VALAC}
 560         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 561         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 562         Prefix......................:  ${prefix}
 563         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 564         Documentation...............:  ${have_valadoc}
 565         Import tool.................:  ${with_import_tool}
 566         Inspector tool..............:  ${with_inspect_tool}
 567         Tracker backend.............:  ${enable_tracker_backend}
 568         Libsocialweb backend........:  ${have_libsocialweb_backend}
 569         E-D-S backend...............:  ${enable_eds_backend}
 570
 571 "