configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([Rygel],
   3         [m4_esyscmd(GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version)],
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel],
   5         [rygel],
   6         [http://live.gnome.org/Rygel])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AC_CONFIG_SRCDIR([src/librygel-core/rygel-root-device.vala])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_SEARCH_LIBS([strerror],[cposix])
  14 AC_PROG_CC
  15 AC_HEADER_STDC
  16 AC_FUNC_MMAP
  17
  18 AC_SUBST(abs_top_builddir)
  19 AC_SUBST(VERSION)
  20
  21 dnl Initialize automake
  22 AM_INIT_AUTOMAKE([1.11.1 tar-ustar no-dist-gzip dist-xz -Wno-portability])
  23 AM_MAINTAINER_MODE([enable])
  24
  25 dnl Initialize libtool
  26 dnl Disable generation of static libraries
  27 LT_PREREQ([2.2.6])
  28 LT_INIT([dlopen disable-static])
  29
  30 dnl Required versions of library packages
  31 dnl Not all of these are actually used, depending on the configure options.
  32 GLIB_REQUIRED=2.31.13
  33 LIBXML_REQUIRED=2.7
  34 VALA_REQUIRED=0.18.0
  35 VALADOC_REQUIRED=0.2
  36 GSSDP_REQUIRED=0.13.0
  37 GUPNP_REQUIRED=0.19.0
  38 GUPNP_AV_REQUIRED=0.11.4
  39 GUPNP_DLNA_REQUIRED=0.7.0
  40 GSTREAMER_REQUIRED=1.0
  41 GSTPBU_REQUIRED=1.0
  42 GIO_REQUIRED=2.26
  43 GEE_REQUIRED=0.8.0
  44 UUID_REQUIRED=1.41.3
  45 LIBSOUP_REQUIRED=2.34.0
  46 GTK_REQUIRED=2.90.3
  47
  48 dnl Additional requirements for media-export plugin
  49 GSTREAMER_TAG_REQUIRED=1.0
  50 GSTREAMER_APP_REQUIRED=1.0
  51 LIBSQLITE3_REQUIRED=3.5
  52
  53 dnl Additional requirements for tracker plugin
  54 TRACKER_SPARQL_REQUIRED_MIN=0.14.0
  55
  56 PKG_CHECK_MODULES(LIBGLIB, glib-2.0 >= $GLIB_REQUIRED)
  57 VALAFLAGS="--target-glib=2.32 $VALAFLAGS"
  58
  59 PKG_CHECK_MODULES(LIBGSSDP, gssdp-1.0 >= $GSSDP_REQUIRED)
  60 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  61 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  62 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  63 PKG_CHECK_MODULES(GEE, gee-0.8 >= $GEE_REQUIRED)
  64 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  65 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  66 PKG_CHECK_MODULES(LIBXML, libxml-2.0 >= $LIBXML_REQUIRED)
  67
  68 dnl Media engine to use
  69 BUILT_ENGINES="librygel-media-engine-simple"
  70
  71 dnl Disabling the gstreamer media_engine also disables
  72 dnl anything else that uses gstreamer.
  73 AC_ARG_WITH([media_engine],
  74             AS_HELP_STRING(
  75                 [--with-media-engine=@<:@gstreamer|simple@:>@],
  76                 [Media Engine to use]),
  77             [with_media_engine="$withval"],
  78             [with_media_engine="gstreamer"])
  79
  80 AS_IF([test "x$with_media_engine" = "xgstreamer"],
  81       [
  82         PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.1 >= $GUPNP_DLNA_REQUIRED)
  83         PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-1.0 >= $GSTREAMER_REQUIRED)
  84         PKG_CHECK_MODULES(GSTREAMER_BASE, gstreamer-base-1.0 >= $GSTREAMER_REQUIRED)
  85         PKG_CHECK_MODULES(GST_PBU, gstreamer-pbutils-1.0 >= $GSTPBU_REQUIRED)
  86         enable_gstreamer="yes"
  87         BUILT_ENGINES="$BUILT_ENGINES;librygel-media-engine-gst"
  88       ],
  89       [enable_gstreamer="no"])
  90 AM_CONDITIONAL([HAVE_GSTREAMER],[test "x$enable_gstreamer" = "xyes"])
  91 AC_SUBST([BUILT_ENGINES])
  92
  93 dnl Add plugins
  94 RYGEL_ADD_PLUGIN([external],[MediaServer2 DBus consumer],[yes])
  95 RYGEL_ADD_PLUGIN([mpris],[MPRIS2 DBus consumer],[yes])
  96 RYGEL_ADD_PLUGIN([mediathek],[ZDF Mediathek],[no])
  97 RYGEL_ADD_PLUGIN([tracker],[Tracker],[yes])
  98
  99 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 100       [
 101         RYGEL_ADD_PLUGIN([playbin],[GStreamer playbin],[yes])
 102         RYGEL_ADD_PLUGIN([media-export],[MediaExport],[yes])
 103         RYGEL_ADD_PLUGIN([gst-launch],[GStreamer launchline],[no])
 104         RYGEL_ADD_STAMP([src/media-engines/gstreamer/librygel_media_engine_gst_la_vala.stamp])
 105         RYGEL_ADD_STAMP([src/librygel-renderer-gst/librygel_renderer_gst_2_0_la_vala.stamp])
 106       ],
 107       [
 108         RYGEL_DISABLE_PLUGIN([playbin])
 109         RYGEL_DISABLE_PLUGIN([media-export])
 110         RYGEL_DISABLE_PLUGIN([gst-launch])
 111       ])
 112
 113 dnl Example plugins:
 114 AC_ARG_ENABLE([example-plugins],
 115               AS_HELP_STRING([--enable-example-plugins],[enable example plugins]),,
 116               enable_example_plugins=no)
 117 AM_CONDITIONAL([BUILD_EXAMPLE_PLUGINS], [test "x$[]enable_example_plugins" = "xyes"])
 118
 119 dnl Explicitly add stamp files for targets that are not plugins
 120 RYGEL_ADD_STAMP([src/librygel-core/librygel_core_2_0_la_vala.stamp])
 121 RYGEL_ADD_STAMP([src/librygel-server/librygel_server_2_0_la_vala.stamp])
 122 RYGEL_ADD_STAMP([src/librygel-renderer/librygel_renderer_2_0_la_vala.stamp])
 123 RYGEL_ADD_STAMP([src/rygel/rygel_vala.stamp])
 124 RYGEL_ADD_STAMP([src/ui/rygel_preferences_vala.stamp])
 125 RYGEL_ADD_STAMP([src/media-engines/simple/librygel_media_engine_simple_la_vala.stamp])
 126
 127 RYGEL_CHECK_VALA([$VALA_REQUIRED],
 128                  [gupnp-1.0
 129                   gupnp-av-1.0
 130                   gio-2.0
 131                   gee-0.8
 132                   posix])
 133
 134 AS_IF([test "x$with_media_engine" = "xgstreamer"],
 135       [
 136         RYGEL_CHECK_PACKAGES([gupnp-dlna-1.1 gstreamer-1.0
 137                               gstreamer-pbutils-1.0])
 138       ])
 139
 140 dnl Debugging
 141 AC_ARG_ENABLE(debug,
 142         AS_HELP_STRING([--enable-debug],[enable debugging]),,
 143         enable_debug=no)
 144 if test "x$enable_debug" = "xyes"; then
 145         CFLAGS="$CFLAGS -O0 -g"
 146         RYGEL_DEBUG_VALAFLAGS="-g"
 147 fi
 148
 149 AC_SUBST(RYGEL_DEBUG_VALAFLAGS)
 150
 151 dnl Strict compiler
 152 AC_ARG_ENABLE(strict-cc,
 153         AS_HELP_STRING([--enable-strict-cc],[enable strict C compiler]),,
 154         enable_strict_cc=no)
 155 if test "x$enable_strict_cc" = "xyes"; then
 156         CFLAGS="$CFLAGS -Wall -Werror"
 157 else
 158         CFLAGS="$CFLAGS -w"
 159 fi
 160
 161 dnl Run uninstalled
 162 AC_ARG_ENABLE(uninstalled,
 163     AS_HELP_STRING([--enable-uninstalled],[run uninstalled]),,
 164         enable_uninstalled=no)
 165 if test "x$enable_uninstalled" = "xyes"; then
 166         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 167 fi
 168 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 169
 170 dnl Check wether user wants to build UIs
 171 AC_ARG_WITH( ui,
 172   AS_HELP_STRING([--without-ui],[Do not build UI applications]),
 173   try_ui=$withval, try_ui=yes )
 174
 175 HAVE_GTK=no
 176 if test x$try_ui = xyes ; then
 177     dnl check for gtk
 178     PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQUIRED,
 179       [
 180         RYGEL_CHECK_PACKAGES([gtk+-3.0], [HAVE_GTK=yes])
 181       ],
 182       [
 183         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 184         AC_MSG_WARN([UI applications will not be built.])
 185       ])
 186 else
 187     AC_MSG_NOTICE([UI applications disabled.])
 188 fi
 189
 190 AM_CONDITIONAL(BUILD_UI, test "x$HAVE_GTK" = "xyes")
 191
 192 dnl Tests
 193 AC_ARG_ENABLE([tests],
 194               AS_HELP_STRING([--enable-tests],[always build tests]),,
 195               enable_tests=no)
 196 AM_CONDITIONAL([ALWAYS_TEST], [test "x$enable_tests" = "xyes"])
 197
 198 dnl Generate coverage data
 199 AC_ARG_ENABLE([coverage],
 200   AS_HELP_STRING([--enable-coverage],
 201                  [Generate converage reports for unit tests]),
 202   [],
 203   [enable_coverage=no])
 204 AM_CONDITIONAL([ENABLE_COVERAGE],[test "x$enable_coverage" != "xno"])
 205 AS_IF([test "x$enable_coverage" != "xno"],
 206   [
 207     AC_PATH_PROG([LCOV], [lcov])
 208     AC_PATH_PROG([GENHTML], [genhtml])
 209     AC_SUBST([COVERAGE_LIBS],["-lgcov"])
 210     AC_SUBST([COVERAGE_CFLAGS],["-fprofile-arcs -ftest-coverage"])
 211     AC_SUBST(COVERAGE_VALAFLAGS,["-g"])
 212   ]
 213 )
 214
 215 dnl Check additional requirements for MediaExport plugins
 216 if test "x$enable_media_export_plugin" = "xyes";
 217 then
 218     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 219     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-1.0 >= $GSTREAMER_TAG_REQUIRED);
 220     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-1.0 >= $GSTREAMER_APP_REQUIRED);
 221     RYGEL_CHECK_PACKAGES([sqlite3 gstreamer-tag-1.0 gstreamer-app-1.0])
 222     AC_CHECK_HEADER([unistr.h],
 223                     AC_CHECK_LIB([unistring],
 224                                  [u8_strcoll],
 225                                  [have_unistring=yes],[have_unistring=no]))
 226     if test "x$have_unistring" = "xyes"; then
 227         AC_DEFINE([HAVE_UNISTRING],[1],[Use libunistring for collation])
 228         COLLATION_CFLAGS=
 229         COLLATION_LIBS=-lunistring
 230         AC_SUBST([COLLATION_CFLAGS])
 231         AC_SUBST([COLLATION_LIBS])
 232     fi
 233 fi
 234
 235 AS_IF([test "x$enable_tracker_plugin" = "xyes"],
 236   [
 237     tracker_api_version="0.14"
 238     PKG_CHECK_MODULES(TRACKER_SPARQL,
 239                       tracker-sparql-0.14 >= $TRACKER_SPARQL_REQUIRED_MIN,
 240                       [tracker_api_version="0.14"],
 241                       [tracker_api_version=""])
 242     AS_IF([test "x$[]tracker_api_version" = "x"],
 243           [
 244             PKG_CHECK_MODULES(TRACKER_SPARQL,
 245                               tracker-sparql-0.15 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 246                               [tracker_api_version="0.15"],
 247                               [tracker_api_version=""])
 248           ])
 249     AS_IF([test "x$[]tracker_api_version" = "x"],
 250           [
 251             PKG_CHECK_MODULES(TRACKER_SPARQL,
 252                               tracker-sparql-0.16 >=  $TRACKER_SPARQL_REQUIRED_MIN,
 253                               [tracker_api_version="0.16"],
 254                               [])
 255           ])
 256     AS_IF([test "x$enable_vala" = "xyes"],
 257           [VALA_CHECK_PACKAGES([tracker-sparql-$tracker_api_version])])
 258     TRACKER_API_VERSION=$tracker_api_version
 259     AC_SUBST(TRACKER_API_VERSION)
 260   ])
 261
 262 dnl Gettext
 263 GETTEXT_PACKAGE=rygel
 264 AC_SUBST(GETTEXT_PACKAGE)
 265 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 266   [Define the gettext package to be used])
 267
 268 AM_GLIB_GNU_GETTEXT
 269 IT_PROG_INTLTOOL([0.40.0])
 270
 271 dnl Shave the output
 272 AM_SILENT_RULES([yes])
 273
 274 dnl documenation
 275 AC_PATH_PROG([XSLTPROC], [xsltproc])
 276 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 277
 278 dnl Use valadoc for API documentation:
 279 dnl This is on by default when using autogen.sh
 280 dnl (so it is not on by default when building from a tarball with configure.)
 281 AC_ARG_ENABLE(valadoc,
 282   AS_HELP_STRING([--enable-valadoc[=@<:@no/auto/yes@:>@]], [Enable valadoc support]),,
 283     [enable_valadoc=no])
 284
 285 found_valadoc=no
 286 AS_IF([test "x$enable_valadoc" != "xno"], [
 287     AC_PATH_PROG(VALADOC, valadoc, :)
 288     AS_IF([test -x "$VALADOC"], [
 289       found_valadoc=yes
 290       AC_SUBST(VALADOC)
 291       PKG_CHECK_MODULES([GTKDOC],[gtk-doc >= 1.0])
 292     ], [
 293       AS_IF([test "x$enable_valadoc" == "xyes"], AC_MSG_ERROR([Unable to find valadoc]))
 294     ])
 295   ])
 296
 297 AM_CONDITIONAL(ENABLE_VALADOC, test x$found_valadoc = xyes)
 298
 299 AC_CONFIG_FILES([
 300 Makefile
 301 src/Makefile
 302 src/librygel-core/Makefile
 303 src/librygel-renderer/Makefile
 304 src/librygel-renderer-gst/Makefile
 305 src/librygel-server/Makefile
 306 src/rygel/Makefile
 307 src/ui/Makefile
 308 src/media-engines/Makefile
 309 src/media-engines/gstreamer/Makefile
 310 src/media-engines/simple/Makefile
 311 src/plugins/Makefile
 312 data/Makefile
 313 data/xml/Makefile
 314 data/xml/MediaServer3.xml.in
 315 data/xml/MediaRenderer2.xml.in
 316 data/icons/Makefile
 317 data/icons/32x32/Makefile
 318 data/icons/48x48/Makefile
 319 data/icons/120x120/Makefile
 320 data/icons/128x128/Makefile
 321 data/icons/scalable/Makefile
 322 data/rygel.desktop.in
 323 data/rygel-preferences.desktop.in
 324 doc/Makefile
 325 doc/reference/Makefile
 326 doc/reference/librygel-core/Makefile
 327 doc/reference/librygel-renderer/Makefile
 328 doc/reference/librygel-server/Makefile
 329 doc/reference/librygel-renderer-gst/Makefile
 330 po/Makefile.in
 331 rygel-core-2.0.pc
 332 rygel-renderer-2.0.pc
 333 rygel-server-2.0.pc
 334 rygel-renderer-gst-2.0.pc
 335 tests/Makefile
 336 examples/Makefile
 337 examples/renderer-plugins/Makefile
 338 examples/renderer-plugins/vala/Makefile
 339 examples/renderer-plugins/C/Makefile
 340 examples/server-plugins/Makefile
 341 examples/server-plugins/vala/Makefile
 342 examples/server-plugins/C/Makefile
 343 ])
 344 AC_OUTPUT
 345
 346 echo "
 347
 348                     ${PACKAGE} ${VERSION}
 349                     ============
 350
 351
 352         Prefix:                 ${prefix}
 353         Source code location:   ${srcdir}
 354         Compiler:               ${CC}
 355         CFLAGS:                 ${CFLAGS}
 356         VALAFLAGS:              ${VALAFLAGS}
 357         uninstalled:            ${enable_uninstalled}
 358         preferences ui:         ${HAVE_GTK}
 359         Media Engine:           ${with_media_engine}
 360     Plugins:
 361         examples:               ${enable_example_plugins}
 362         tracker:                ${enable_tracker_plugin}
 363             version:            ${tracker_api_version}
 364         mediathek:              ${enable_mediathek_plugin}
 365         media-export            ${enable_media_export_plugin}
 366         external:               ${enable_external_plugin}
 367         MPRIS2:                 ${enable_mpris_plugin}
 368         gst-launch:             ${enable_gst_launch_plugin}
 369         playbin:                ${enable_playbin_plugin}
 370 "