configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AC_CONFIG_AUX_DIR([build-aux])
  30 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules color-tests dist-xz tar-ustar])
  31
  32 AS_IF([! test -n "$VERSION"], [
  33    AC_MSG_ERROR([git-version-gen failed])
  34 ])
  35
  36 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  37 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  38
  39 AC_SUBST(PA_MAJOR, pa_major)
  40 AC_SUBST(PA_MINOR, pa_minor)
  41 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  42
  43 AC_SUBST(PA_API_VERSION, 12)
  44 AC_SUBST(PA_PROTOCOL_VERSION, 28)
  45
  46 # The stable ABI for client applications, for the version info x:y:z
  47 # always will hold y=z
  48 AC_SUBST(LIBPULSE_VERSION_INFO, [16:2:16])
  49
  50 # A simplified, synchronous, ABI-stable interface for client
  51 # applications, for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:4:0])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  57
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  60
  61 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  62
  63 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  64     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  65     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  66 ])
  67
  68 AM_SILENT_RULES([yes])
  69
  70
  71 #### Checks for programs. ####
  72
  73 # mkdir -p
  74
  75 AC_PROG_MKDIR_P
  76
  77 # CC
  78
  79 AC_PROG_CC
  80 AC_PROG_CC_C99
  81 AM_PROG_CC_C_O
  82 # Only required if you want the WebRTC canceller -- no runtime dep on
  83 # libstdc++ otherwise
  84 AC_PROG_CXX
  85 AC_PROG_GCC_TRADITIONAL
  86 AC_USE_SYSTEM_EXTENSIONS
  87
  88 # M4
  89
  90 AC_CHECK_PROGS([M4], gm4 m4, no)
  91 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  92
  93 # pkg-config
  94
  95 PKG_PROG_PKG_CONFIG
  96
  97 # gettext
  98
  99 if test "x$enable_nls" != "xno"; then
 100 IT_PROG_INTLTOOL([0.35.0])
 101
 102 AM_GNU_GETTEXT_VERSION([0.18.1])
 103 AM_GNU_GETTEXT([external])
 104
 105 GETTEXT_PACKAGE=pulseaudio
 106 AC_SUBST([GETTEXT_PACKAGE])
 107 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 108
 109 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 110 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 111 else
 112 # workaround till an intltool m4 bug is fixed upstream
 113 # (https://bugs.launchpad.net/intltool/+bug/904647)
 114 USE_NLS=no
 115 AC_SUBST(USE_NLS)
 116 fi
 117
 118
 119 #### Determine host OS ####
 120
 121 os_is_linux=0
 122 os_is_win32=0
 123 os_is_darwin=0
 124
 125 AC_MSG_CHECKING([host operating system])
 126 case "$host_os" in
 127     linux*)
 128         AC_MSG_RESULT([linux])
 129         os_is_linux=1
 130     ;;
 131     darwin*)
 132         AC_MSG_RESULT([darwin])
 133         os_is_darwin=1
 134         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 135     ;;
 136     mingw*)
 137         AC_MSG_RESULT([win32])
 138         os_is_win32=1
 139         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 140     ;;
 141     *)
 142         AC_MSG_RESULT([unknown])
 143     ;;
 144 esac
 145
 146 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 147 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 148 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 149
 150 # Platform specific hacks
 151 case "$host_os" in
 152     darwin* )
 153         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 154     ;;
 155     mingw* )
 156         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 157     ;;
 158     solaris* )
 159         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 160         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 161     ;;
 162 esac
 163
 164
 165 #### Compiler flags ####
 166
 167 AX_APPEND_COMPILE_FLAGS(
 168     [-Wall -W -Wextra -pipe -Wno-long-long -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 169     [], [-pedantic -Werror])
 170
 171 # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 172 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [AX_APPEND_FLAG(["-DFASTPATH"], [CPPFLAGS])])
 173
 174
 175 #### Linker flags ####
 176
 177 # Check whether the linker supports the -version-script option.
 178 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 179 # so that it is expanded the right way in every subdir.
 180 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 181     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 182 AC_SUBST([VERSIONING_LDFLAGS])
 183
 184 # Use immediate (now) bindings; avoids the funky re-call in itself.
 185 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 186 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 187 AC_SUBST([IMMEDIATE_LDFLAGS])
 188
 189 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 190 # so we request the nodelete flag to be enabled.
 191 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 192 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 193 AC_SUBST([NODELETE_LDFLAGS])
 194
 195 # Check for the proper way to build libraries that have no undefined symbols
 196 case $host in
 197     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 198     # are requested, as different implementations are present.
 199     *-freebsd* | *-openbsd*) ;;
 200     *)
 201         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 202             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 203         done
 204     ;;
 205 esac
 206 AC_SUBST([NOUNDEFINED_LDFLAGS])
 207
 208
 209 #### Atomic operations ####
 210
 211 # Native atomic operation support
 212 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 213     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 214
 215 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 216     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 217
 218 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 219     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 220 fi
 221
 222 # If everything else fails use libatomic_ops
 223 need_libatomic_ops=yes
 224
 225 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 226     pulseaudio_cv_sync_bool_compare_and_swap, [
 227     AC_LINK_IFELSE(
 228         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 229         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 230         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 231     ])
 232
 233 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 234     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 235     need_libatomic_ops=no
 236 else
 237     # HW specific atomic ops stuff
 238     AC_MSG_CHECKING([architecture for native atomic operations])
 239     case $host in
 240         arm*)
 241             AC_MSG_RESULT([arm])
 242             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 243             # The Linux kernel helper functions have been there since 2.6.16. However
 244             # compile time checking for kernel version in cross compile environment
 245             # (which is usually the case for arm cpu) is tricky (or impossible).
 246             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 247                 AC_MSG_RESULT([yes])
 248                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 249                 need_libatomic_ops=no
 250             else
 251                 AC_MSG_RESULT([no])
 252                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 253                     pulseaudio_cv_support_arm_atomic_ops, [
 254                     AC_COMPILE_IFELSE(
 255                         AC_LANG_PROGRAM([], [[
 256                             volatile int a=0;
 257                             int o=0, n=1, r;
 258                             asm volatile ("ldrex    %0, [%1]\n"
 259                                           "subs  %0, %0, %2\n"
 260                                           "strexeq %0, %3, [%1]\n"
 261                                           : "=&r" (r)
 262                                           : "r" (&a), "Ir" (o), "r" (n)
 263                                           : "cc");
 264                             return (a==1 ? 0 : -1);
 265                         ]]),
 266                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 267                         [pulseaudio_cv_support_arm_atomic_ops=no])
 268                 ])
 269                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 270                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 271                     need_libatomic_ops=no
 272                 ])
 273             fi
 274         ;;
 275         *-netbsdelf5*)
 276             AC_MSG_RESULT([yes])
 277             need_libatomic_ops=no
 278         ;;
 279         *-freebsd*)
 280             AC_MSG_RESULT([yes])
 281             need_libatomic_ops=no
 282         ;;
 283         *)
 284             AC_MSG_RESULT([unknown])
 285         ;;
 286     esac
 287 fi
 288
 289 # If we're on ARM, check for the ARMV6 instructions we need */
 290 case $host in
 291   arm*)
 292     AC_CACHE_CHECK([support for required armv6 instructions],
 293       pulseaudio_cv_support_armv6,
 294       [AC_COMPILE_IFELSE(
 295          AC_LANG_PROGRAM([],
 296            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 297              asm volatile ("ldr r0, %2 \n"
 298                            "ldr r2, %3 \n"
 299                            "ldr r3, %4 \n"
 300                            "ssat r1, #8, r0 \n"
 301                            "str r1, %0 \n"
 302                            "pkhbt r1, r3, r2, LSL #8 \n"
 303                            "str r1, %1 \n"
 304                            : "=m" (a), "=m" (b)
 305                            : "m" (a), "m" (b), "m" (c)
 306                            : "r0", "r1", "r2", "r3", "cc");
 307              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 308            ]]),
 309          [pulseaudio_cv_support_armv6=yes],
 310          [pulseaudio_cv_support_armv6=no])
 311       ])
 312     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 313         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 314       ])
 315   ;;
 316   *)
 317   ;;
 318 esac
 319
 320 #### NEON optimisations ####
 321 AC_ARG_ENABLE([neon-opt],
 322     AS_HELP_STRING([--enable-neon-opt], [Enable NEON optimisations on ARM CPUs that support it]))
 323
 324 AS_IF([test "x$enable_neon_opt" != "xno"],
 325     [save_CFLAGS="$CFLAGS"; CFLAGS="-mfpu=neon $CFLAGS"
 326      AC_COMPILE_IFELSE(
 327         AC_LANG_PROGRAM([[#include <arm_neon.h>]], []),
 328         [
 329          HAVE_NEON=1
 330          NEON_CFLAGS="-mfpu=neon"
 331         ],
 332         [
 333          HAVE_NEON=0
 334          NEON_CFLAGS=
 335         ])
 336      CFLAGS="$save_CFLAGS"
 337     ],
 338     [HAVE_NEON=0])
 339
 340 AS_IF([test "x$enable_neon_opt" = "xyes" && test "x$HAVE_NEON" = "x0"],
 341       [AC_MSG_ERROR([*** Compiler does not support -mfpu=neon or CFLAGS override -mfpu])])
 342
 343 AC_SUBST(HAVE_NEON)
 344 AC_SUBST(NEON_CFLAGS)
 345 AM_CONDITIONAL([HAVE_NEON], [test "x$HAVE_NEON" = x1])
 346 AS_IF([test "x$HAVE_NEON" = "x1"], AC_DEFINE([HAVE_NEON], 1, [Have NEON support?]))
 347
 348
 349 #### libtool stuff ####
 350
 351 LT_PREREQ(2.4)
 352 LT_INIT([dlopen win32-dll disable-static])
 353
 354 dnl As an extra safety device, check for lt_dladvise_init() which is
 355 dnl only implemented in libtool 2.x, and refine as we go if we have
 356 dnl refined requirements.
 357 dnl
 358 dnl Check the header files first since the system may have a
 359 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 360 dnl soon as possible.
 361 dnl
 362 dnl We don't need any special variable for this though, since the user
 363 dnl can give the proper place to find libltdl through the standard
 364 dnl variables like LDFLAGS and CPPFLAGS.
 365
 366 AC_CHECK_HEADER([ltdl.h],
 367     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 368     [LIBLTDL=])
 369
 370 AS_IF([test "x$LIBLTDL" = "x"],
 371     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.4 or later installed.])])
 372 AC_SUBST([LIBLTDL])
 373
 374
 375 ###################################
 376 #   Basic environment checks      #
 377 ###################################
 378
 379 #### Checks for header files. ####
 380
 381 # ISO
 382 AC_HEADER_STDC
 383
 384 # POSIX
 385 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 386     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 387     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 388     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 389 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 390                  [#include <sys/types.h>
 391                   #if HAVE_NETINET_IN_H
 392                   # include <netinet/in.h>
 393                   #endif
 394                   #if HAVE_NETINET_IN_SYSTM_H
 395                   # include <netinet/in_systm.h>
 396                   #endif
 397                  ])
 398 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 399 AC_SUBST(HAVE_SYS_RESOURCE_H)
 400 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 401 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 402 AC_SUBST(HAVE_AF_UNIX)
 403
 404 # Linux
 405 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 406 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 407
 408 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 409
 410 # Solaris
 411 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 412
 413 # Windows
 414 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 415
 416 # NetBSD
 417 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 418
 419 # Other
 420 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 421 AC_CHECK_HEADERS_ONCE([byteswap.h])
 422 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 423 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 424 AC_CHECK_HEADERS_ONCE([execinfo.h])
 425 AC_CHECK_HEADERS_ONCE([langinfo.h])
 426 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 427
 428
 429 #### Typdefs, structures, etc. ####
 430
 431 AC_C_CONST
 432 AC_C_BIGENDIAN
 433 AC_TYPE_PID_T
 434 AC_TYPE_SIZE_T
 435 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 436 AC_TYPE_OFF_T
 437
 438 AC_TYPE_UID_T
 439 AC_CHECK_DECLS(environ)
 440
 441 # SIGXCPU
 442 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 443 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 444 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 445
 446 # INADDR_NONE, Solaris lacks this
 447 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 448     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 449         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 450
 451
 452 # _Bool
 453 AC_CACHE_CHECK([whether $CC knows _Bool],
 454     pulseaudio_cv__Bool,
 455     [AC_COMPILE_IFELSE(
 456         AC_LANG_PROGRAM([], [[_Bool b;]]),
 457         [pulseaudio_cv__Bool=yes],
 458         [pulseaudio_cv__Bool=no])
 459     ])
 460
 461 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 462
 463
 464 #### Thread support ####
 465
 466 AX_TLS
 467 AS_IF([test "$ac_cv_tls" == "__thread"],
 468     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 469
 470 # Win32 build breaks with win32 pthread installed
 471 AS_IF([test "x$os_is_win32" != "x1"],
 472   [AX_PTHREAD])
 473
 474 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 475     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 476
 477
 478 #### Check for libs ####
 479
 480 # ISO
 481 AC_SEARCH_LIBS([pow], [m])
 482
 483 # POSIX
 484 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 485 AC_SEARCH_LIBS([dlopen], [dl])
 486 AC_SEARCH_LIBS([shm_open], [rt])
 487 AC_SEARCH_LIBS([inet_ntop], [nsl])
 488 AC_SEARCH_LIBS([timer_create], [rt])
 489 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 490 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 491 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 492
 493 # BSD
 494 AC_SEARCH_LIBS([connect], [socket])
 495 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 496
 497 # Darwin/OS X
 498 if test "x$os_is_darwin" = "x1" ; then
 499     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 500     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 501     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 502         [LIBS="$LIBS -framework CoreServices"],
 503         [AC_CHECK_HEADERS([/System/Library/Frameworks/CoreServices.framework/Headers/CoreServices.h],
 504             [LIBS="$LIBS -framework CoreServices"],
 505             [AC_MSG_ERROR([CoreServices.h header file not found])]
 506         )]
 507     )
 508
 509     AC_MSG_RESULT([ok])
 510     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 511     HAVE_BONJOUR=1
 512 fi
 513
 514 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 515
 516 # Windows
 517 AC_SEARCH_LIBS([regexec], [pcreposix])
 518 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 519 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 520
 521
 522 #### Check for functions ####
 523
 524 # ISO
 525 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 526
 527 # POSIX
 528 AC_FUNC_FORK
 529 AC_FUNC_GETGROUPS
 530 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 531     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 532     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 533     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 534 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 535 AC_SUBST(HAVE_MKFIFO)
 536 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 537
 538 # X/OPEN
 539 AC_CHECK_FUNCS_ONCE([readlink])
 540
 541 # SUSv2
 542 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 543
 544 # SUSv3
 545 AC_CHECK_FUNCS_ONCE([strerror_r])
 546
 547 # BSD
 548 AC_CHECK_FUNCS_ONCE([lstat])
 549
 550 # Non-standard
 551 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 552
 553 AC_FUNC_ALLOCA
 554
 555 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 556 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 557
 558 # Large File-Support (LFS)
 559 AC_SYS_LARGEFILE
 560 # Check for open64 to know if the current system does have open64() and similar functions
 561 AC_CHECK_FUNCS_ONCE([open64])
 562
 563
 564 ###################################
 565 #      External libraries         #
 566 ###################################
 567
 568 #### [lib]iconv ####
 569
 570 AM_ICONV
 571
 572 #### X11 (optional) ####
 573
 574 AC_ARG_ENABLE([x11],
 575     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 576
 577 AS_IF([test "x$enable_x11" != "xno"],
 578     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 579     HAVE_X11=0)
 580
 581 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 582     [AC_MSG_ERROR([*** X11 not found])])
 583
 584 AC_SUBST(HAVE_X11)
 585 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 586 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 587
 588 #### Capabilities (optional) ####
 589
 590 CAP_LIBS=''
 591
 592 AC_ARG_WITH([caps],
 593     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 594
 595 if test "x${with_caps}" != "xno"; then
 596     AC_SEARCH_LIBS([cap_init], [cap], [], [
 597                     if test "x${with_caps}" = "xyes" ; then
 598                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 599                     fi])
 600     AC_CHECK_HEADERS([sys/capability.h], [], [
 601                     if test "x${with_caps}" = "xyes" ; then
 602                         AC_MSG_ERROR([*** POSIX caps headers not found])
 603                     fi])
 604 fi
 605
 606 #### Valgrind (optional) ####
 607
 608 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 609
 610 #### check unit tests ####
 611
 612 AC_ARG_ENABLE([tests],
 613     AS_HELP_STRING([--disable-tests],[Disable unit tests]))
 614
 615 AS_IF([test "x$enable_tests" != "xno"],
 616     [PKG_CHECK_MODULES(LIBCHECK, [ check ], HAVE_LIBCHECK=1, HAVE_LIBCHECK=0)],
 617     HAVE_LIBCHECK=0)
 618
 619 AS_IF([test "x$enable_tests" = "xyes" && test "x$HAVE_LIBCHECK" = "x0"],
 620     [AC_MSG_ERROR([*** check library not found])])
 621
 622 AM_CONDITIONAL([HAVE_TESTS], [test "x$HAVE_LIBCHECK" = x1])
 623
 624 #### json parsing ####
 625
 626 PKG_CHECK_MODULES(LIBJSON, [ json-c >= 0.11 ], [],
 627                   [PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])])
 628
 629 #### Sound file ####
 630
 631 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 632
 633 #### atomic-ops ####
 634
 635 AC_MSG_CHECKING([whether we need libatomic_ops])
 636 if test "x$need_libatomic_ops" = "xyes"; then
 637     AC_MSG_RESULT([yes])
 638     AC_CHECK_HEADERS([atomic_ops.h],
 639         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 640         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 641
 642     # Win32 does not need the lib and breaks horribly if we try to include it
 643     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 644 else
 645     AC_MSG_RESULT([no])
 646 fi
 647
 648 #### Libsamplerate support (optional) ####
 649
 650 AC_ARG_ENABLE([samplerate],
 651     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 652
 653 AS_IF([test "x$enable_samplerate" != "xno"],
 654     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 655     HAVE_LIBSAMPLERATE=0)
 656
 657 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 658     [AC_MSG_ERROR([*** Libsamplerate not found])])
 659
 660 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 661 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 662
 663 #### Database support ####
 664
 665 AC_ARG_WITH([database],
 666     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 667
 668
 669 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 670     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 671     HAVE_TDB=0)
 672 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 673
 674 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 675     [AC_MSG_ERROR([*** tdb not found])])
 676
 677
 678 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 679     [
 680         HAVE_GDBM=1
 681         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 682         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 683     ],
 684     HAVE_GDBM=0)
 685 AS_IF([test "x$HAVE_GDBM" = "x1"],
 686     [
 687         with_database=gdbm
 688         GDBM_CFLAGS=
 689         GDBM_LIBS=-lgdbm
 690     ])
 691
 692 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 693     [AC_MSG_ERROR([*** gdbm not found])])
 694
 695
 696 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 697     HAVE_SIMPLEDB=1,
 698     HAVE_SIMPLEDB=0)
 699 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 700
 701 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 702     AC_MSG_ERROR([*** missing database backend]))
 703
 704
 705 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 706 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 707
 708 AC_SUBST(GDBM_CFLAGS)
 709 AC_SUBST(GDBM_LIBS)
 710 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 711 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 712
 713 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 714 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 715
 716 #### OSS support (optional) ####
 717
 718 AC_ARG_ENABLE([oss-output],
 719     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 720
 721 AC_ARG_ENABLE([oss-wrapper],
 722     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 723
 724 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 725     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 726     HAVE_OSS=0)
 727
 728 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 729     [AC_MSG_ERROR([*** OSS support not found])])
 730
 731 AS_IF([test "x$enable_oss_output" != "xno"],
 732     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 733     HAVE_OSS_OUTPUT=0)
 734
 735 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 736     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 737     HAVE_OSS_WRAPPER=0)
 738
 739 AC_SUBST(HAVE_OSS_OUTPUT)
 740 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 741 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 742 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 743 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 744
 745 #### CoreAudio support (optional) ####
 746
 747 AC_ARG_ENABLE([coreaudio-output],
 748     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 749
 750 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 751     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 752     HAVE_COREAUDIO=0)
 753
 754 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 755     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 756
 757 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 758
 759 #### ALSA support (optional) ####
 760
 761 AC_ARG_ENABLE([alsa],
 762     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 763
 764 AS_IF([test "x$enable_alsa" != "xno"],
 765     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.24 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 766     HAVE_ALSA=0)
 767
 768 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 769     [AC_MSG_ERROR([*** Needed alsa >= 1.0.24 support not found])])
 770
 771 AC_SUBST(HAVE_ALSA)
 772 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 773 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 774
 775 #### EsounD support (optional) ####
 776
 777 AC_ARG_ENABLE([esound],
 778     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 779 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 780 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 781
 782 #### Solaris audio support (optional) ####
 783
 784 AC_ARG_ENABLE([solaris],
 785     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 786
 787 AS_IF([test "x$enable_solaris" != "xno"],
 788     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 789     HAVE_SOLARIS=0)
 790
 791 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 792     [AC_MSG_ERROR([*** Solaris audio support not found])])
 793
 794 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 795 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 796
 797 #### WaveOut audio support (optional) ####
 798
 799 AC_ARG_ENABLE([waveout],
 800     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 801
 802 AS_IF([test "x$enable_waveout" != "xno"],
 803     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 804     HAVE_WAVEOUT=0)
 805
 806 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 807     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 808
 809 AC_SUBST(HAVE_WAVEOUT)
 810 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 811 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 812
 813 #### GLib 2 support (optional) ####
 814
 815 AC_ARG_ENABLE([glib2],
 816     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 817
 818 AS_IF([test "x$enable_glib2" != "xno"],
 819     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 820     HAVE_GLIB20=0)
 821
 822 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 823     [AC_MSG_ERROR([*** GLib 2 support not found])])
 824
 825 AC_SUBST(HAVE_GLIB20)
 826 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 827 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 828
 829 #### GTK3 support (optional) ####
 830
 831 AC_ARG_ENABLE([gtk3],
 832     AS_HELP_STRING([--disable-gtk3],[Disable optional Gtk+ 3 support]))
 833
 834 AS_IF([test "x$enable_gtk3" != "xno"],
 835     [PKG_CHECK_MODULES(GTK30, [ gtk+-3.0 ], HAVE_GTK30=1, HAVE_GTK30=0)],
 836     HAVE_GTK30=0)
 837
 838 AS_IF([test "x$enable_gtk3" = "xyes" && test "x$HAVE_GTK30" = "x0"],
 839     [AC_MSG_ERROR([*** Gtk+ 3 support not found])])
 840
 841 AM_CONDITIONAL([HAVE_GTK30], [test "x$HAVE_GTK30" = x1])
 842 AS_IF([test "x$HAVE_GTK30" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 843
 844 #### GConf support (optional) ####
 845
 846 AC_ARG_ENABLE([gconf],
 847     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 848
 849 AS_IF([test "x$enable_gconf" != "xno"],
 850     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 851     HAVE_GCONF=0)
 852
 853 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 854     [AC_MSG_ERROR([*** GConf support not found])])
 855
 856 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 857
 858 #### Avahi support (optional) ####
 859
 860 AC_ARG_ENABLE([avahi],
 861     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 862
 863 AS_IF([test "x$enable_avahi" != "xno"],
 864     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 865     HAVE_AVAHI=0)
 866
 867 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 868     [AC_MSG_ERROR([*** Avahi support not found])])
 869
 870 AC_SUBST(HAVE_AVAHI)
 871 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 872
 873 #### JACK (optional) ####
 874
 875 AC_ARG_ENABLE([jack],
 876     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 877
 878 AS_IF([test "x$enable_jack" != "xno"],
 879     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 880     HAVE_JACK=0)
 881
 882 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 883     [AC_MSG_ERROR([*** JACK support not found])])
 884
 885 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 886
 887 #### Async DNS support (optional) ####
 888
 889 AC_ARG_ENABLE([asyncns],
 890     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 891
 892 AS_IF([test "x$enable_asyncns" != "xno"],
 893     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 894     HAVE_LIBASYNCNS=0)
 895
 896 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 897     [AC_MSG_ERROR([*** Async DNS support not found])])
 898
 899 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 900 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 901
 902 #### TCP wrappers (optional) ####
 903
 904 AC_ARG_ENABLE([tcpwrap],
 905     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 906
 907 AS_IF([test "x$enable_tcpwrap" != "xno"],
 908     [
 909         ACX_LIBWRAP
 910         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 911     ],
 912     HAVE_TCPWRAP=0)
 913
 914 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 915     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 916
 917 AC_SUBST(LIBWRAP_LIBS)
 918
 919 #### LIRC support (optional) ####
 920
 921 AC_ARG_ENABLE([lirc],
 922     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 923
 924 LIRC_CFLAGS=
 925 LIRC_LIBS=
 926
 927 AS_IF([test "x$enable_lirc" != "xno"],
 928     [
 929         HAVE_LIRC=1
 930         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 931         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 932     ],
 933     HAVE_LIRC=0)
 934
 935 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 936     [AC_MSG_ERROR([*** LIRC support not found])])
 937
 938 AC_SUBST(LIRC_CFLAGS)
 939 AC_SUBST(LIRC_LIBS)
 940 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 941
 942 #### D-Bus support (optional) ####
 943
 944 AC_ARG_ENABLE([dbus],
 945     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 946
 947 AS_IF([test "x$enable_dbus" != "xno"],
 948     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.4.12 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 949     HAVE_DBUS=0)
 950
 951 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 952     [AC_MSG_ERROR([*** D-Bus not available or too old version])])
 953
 954 AS_IF([test "x$HAVE_DBUS" = "x1"],
 955     [
 956         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 957         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 958         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 959         CFLAGS="$save_CFLAGS"
 960         LIBS="$save_LIBS"
 961     ])
 962
 963 AC_SUBST(HAVE_DBUS)
 964 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 965 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 966
 967 PA_MACHINE_ID="${sysconfdir}/machine-id"
 968 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 969 PA_MACHINE_ID_FALLBACK="${localstatedir}/lib/dbus/machine-id"
 970 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
 971               [Fallback machine-id file])
 972
 973 #### BlueZ support (optional, dependant on D-Bus) ####
 974
 975 AC_ARG_ENABLE([bluez],
 976     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
 977
 978 AS_IF([test "x$enable_bluez" != "xno"],
 979     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 4.99 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 980     HAVE_BLUEZ=0)
 981 AS_IF([test "x$enable_bluez" != "xno"],
 982     [PKG_CHECK_MODULES(SBC, [ sbc >= 1.0 ], HAVE_SBC=1, HAVE_SBC=0)],
 983     HAVE_SBC=0)
 984 AS_IF([test "x$HAVE_SBC" != "x1"], HAVE_BLUEZ=0)
 985 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
 986
 987 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
 988     [AC_MSG_ERROR([*** BLUEZ support not found (requires BlueZ, sbc, and D-Bus)])])
 989
 990 AC_SUBST(HAVE_BLUEZ)
 991 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 992
 993 #### UDEV support (optional) ####
 994
 995 AC_ARG_ENABLE([udev],
 996     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
 997
 998 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 999     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
1000     HAVE_UDEV=0)
1001
1002 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1003     [AC_MSG_ERROR([*** UDEV support not found])])
1004
1005 AC_SUBST(HAVE_UDEV)
1006 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1007 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1008
1009 #### HAL compat support (optional, dependant on UDEV) ####
1010
1011 AC_ARG_ENABLE([hal-compat],
1012     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1013
1014 AS_IF([test "x$enable_hal_compat" != "xno"],
1015     [AS_IF([test "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1016     HAVE_HAL_COMPAT=0)
1017
1018 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1019 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1020
1021 #### IPv6 connection support (optional) ####
1022
1023 AC_ARG_ENABLE([ipv6],
1024     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1025
1026 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1027
1028 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1029
1030 #### OpenSSL support (optional) ####
1031
1032 AC_ARG_ENABLE([openssl],
1033     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1034
1035 AS_IF([test "x$enable_openssl" != "xno"],
1036     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1037     HAVE_OPENSSL=0)
1038
1039 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1040     [AC_MSG_ERROR([*** OpenSSL support not found])])
1041
1042 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1043 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1044
1045 #### FFTW (optional) ####
1046
1047 AC_ARG_WITH([fftw],
1048     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1049
1050 AS_IF([test "x$with_fftw" != "xno"],
1051     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1052     HAVE_FFTW=0)
1053
1054 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1055     [AC_MSG_ERROR([*** FFTW support not found])])
1056
1057 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1058
1059 #### speex (optional) ####
1060
1061 AC_ARG_WITH([speex],
1062     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1063
1064 AS_IF([test "x$with_speex" != "xno"],
1065     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1066     HAVE_SPEEX=0)
1067
1068 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1069     [AC_MSG_ERROR([*** speex support not found])])
1070
1071 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1072 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1073
1074 #### Xen support (optional) ####
1075
1076 AC_ARG_ENABLE([xen],
1077     AS_HELP_STRING([--disable-xen],[Disable optional Xen paravirtualized driver]))
1078
1079 XEN_CFLAGS=
1080 XEN_LIBS=
1081
1082 AS_IF([test "x$enable_xen" != "xno"],
1083     [
1084         HAVE_XEN=1
1085         AC_CHECK_HEADER(xenctrl.h, [], [HAVE_XEN=0])
1086         AC_CHECK_HEADER(xs.h, [], [HAVE_XEN=0])
1087         AC_CHECK_LIB(xenctrl, xc_interface_open, [XEN_LIBS="$XEN_LIBS -lxenctrl"], [HAVE_XEN=0])
1088         AC_CHECK_LIB(xenstore, xs_domain_open, [XEN_LIBS="$XEN_LIBS -lxenstore"], [HAVE_XEN=0])
1089     ],
1090     HAVE_XEN=0)
1091
1092 AS_IF([test "x$enable_xen" = "xyes" && test "x$HAVE_XEN" = "x0"],
1093     [AC_MSG_ERROR([*** Xen development headers or libraries not found])])
1094
1095 AC_SUBST(XEN_CFLAGS)
1096 AC_SUBST(XEN_LIBS)
1097 AM_CONDITIONAL([HAVE_XEN], [test "x$HAVE_XEN" = x1])
1098
1099 #### gcov support (optional) #####
1100
1101 AC_ARG_ENABLE([gcov],
1102     AS_HELP_STRING([--enable-gcov],[Enable optional gcov coverage analysis]))
1103
1104 GCOV_CFLAGS=
1105 GCOV_LIBS=" -lgcov"
1106
1107 AS_IF([test "x$enable_gcov" = "xyes"],
1108     [
1109         HAVE_GCOV=1
1110         GCOV_CFLAGS="$GCOV_CFLAGS -fprofile-arcs -ftest-coverage"
1111         GCOV_LIBS="$GCOV_LIBS -fprofile-arcs"
1112     ],
1113     HAVE_GCOV=0)
1114
1115 AC_SUBST(GCOV_CFLAGS)
1116 AC_SUBST(GCOV_LIBS)
1117 AM_CONDITIONAL([HAVE_GCOV], [test "x$HAVE_GCOV" = x1])
1118
1119 #### ORC (optional) ####
1120
1121 ORC_CHECK([0.4.11])
1122
1123 #### systemd support (optional) ####
1124
1125 AC_ARG_ENABLE([systemd],
1126     AS_HELP_STRING([--disable-systemd],[Disable optional systemd support]))
1127
1128 AS_IF([test "x$enable_systemd" != "xno"],
1129     [PKG_CHECK_MODULES(SYSTEMD, [ libsystemd-login ], HAVE_SYSTEMD=1, HAVE_SYSTEMD=0)],
1130     HAVE_SYSTEMD=0)
1131
1132 AS_IF([test "x$enable_systemd" = "xyes" && test "x$HAVE_SYSTEMD" = "x0"],
1133     [AC_MSG_ERROR([*** Needed systemd support not found])])
1134
1135 AC_SUBST(HAVE_SYSTEMD)
1136 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$HAVE_SYSTEMD" = x1])
1137 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], AC_DEFINE([HAVE_SYSTEMD], 1, [Have SYSTEMD?]))
1138
1139 #### Build and Install man pages ####
1140
1141 AC_ARG_ENABLE([manpages],
1142     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1143
1144 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1145
1146 #### PulseAudio system group & user  #####
1147
1148 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1149 if test -z "$with_system_user" ; then
1150     PA_SYSTEM_USER=pulse
1151 else
1152     PA_SYSTEM_USER=$with_system_user
1153 fi
1154 AC_SUBST(PA_SYSTEM_USER)
1155 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1156
1157 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1158 if test -z "$with_system_group" ; then
1159     PA_SYSTEM_GROUP=pulse
1160 else
1161     PA_SYSTEM_GROUP=$with_system_group
1162 fi
1163 AC_SUBST(PA_SYSTEM_GROUP)
1164 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1165
1166 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1167 if test -z "$with_access_group" ; then
1168     PA_ACCESS_GROUP=pulse-access
1169 else
1170     PA_ACCESS_GROUP=$with_access_group
1171 fi
1172 AC_SUBST(PA_ACCESS_GROUP)
1173 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1174
1175 AC_ARG_ENABLE([per-user-esound-socket],
1176     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1177
1178 if test "x$enable_per_user_esound_socket" != "xno"; then
1179     USE_PER_USER_ESOUND_SOCKET=1
1180     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1181 else
1182     USE_PER_USER_ESOUND_SOCKET=0
1183 fi
1184
1185 #### PulseAudio system runtime dir ####
1186
1187 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1188 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1189 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1190 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1191 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1192 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1193
1194 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1195 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1196
1197 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1198 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1199
1200 AC_SUBST(PA_SOEXT, [.so])
1201
1202 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1203 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1204
1205 #### Mac OSX specific stuff #####
1206
1207 AC_ARG_ENABLE(mac-universal,
1208     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1209     enable_mac_universal=$enableval, enable_mac_universal="no")
1210
1211 AC_ARG_WITH(mac-version-min,
1212     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1213     mac_version_min=$withval, mac_version_min="10.5")
1214
1215 AC_ARG_WITH(mac-sysroot,
1216     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1217     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1218
1219 if test "x$os_is_darwin" = "x1" ; then
1220     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1221     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1222
1223     if test "x$enable_mac_universal" = "xyes" ; then
1224         mac_arches="-arch i386 -arch x86_64"
1225         LDFLAGS="$LDFLAGS $mac_arches"
1226         CFLAGS="$CFLAGS $mac_arches"
1227     fi
1228 fi
1229
1230 AC_ARG_ENABLE([webrtc-aec],
1231     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1232
1233 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1234     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1235     [HAVE_WEBRTC=0])
1236
1237 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1238     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1239
1240 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1241
1242 AC_ARG_ENABLE([adrian-aec],
1243     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1244 AS_IF([test "x$enable_adrian_aec" != "xno"],
1245     [HAVE_ADRIAN_EC=1])
1246 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1247
1248
1249
1250 ###################################
1251 #            Output               #
1252 ###################################
1253
1254 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1255
1256 # Check whether to build tests by default (as compile-test) or not
1257 AC_ARG_ENABLE([default-build-tests],
1258     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1259 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1260
1261 AC_ARG_ENABLE([legacy-database-entry-format],
1262         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1263 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1264         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1265 fi
1266 AC_DEFINE([WIBBLE], 1, [Just a test.])
1267
1268 AC_ARG_ENABLE([static-bins],
1269     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1270 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1271
1272 AC_ARG_WITH(
1273         [preopen-mods],
1274         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1275         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1276 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1277 if test "x$PREOPEN_MODS" != "xall" ; then
1278     tmpLIBS=""
1279     for mod in $PREOPEN_MODS; do
1280         tmpLIBS="$tmpLIBS module-$mod.la"
1281     done
1282     PREOPEN_MODS="$tmpLIBS"
1283     AC_SUBST(PREOPEN_MODS)
1284 fi
1285
1286 AC_ARG_WITH(
1287         [module-dir],
1288         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1289         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1290
1291 AC_SUBST(modlibexecdir)
1292 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1293
1294 AC_ARG_WITH(
1295         [udev-rules-dir],
1296         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1297         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1298
1299 AC_SUBST(udevrulesdir)
1300
1301 AC_ARG_ENABLE([force-preopen],
1302     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1303
1304 if test "x$enable_force_preopen" = "xyes"; then
1305     FORCE_PREOPEN=yes
1306 else
1307     FORCE_PREOPEN=no
1308 fi
1309
1310 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1311
1312 AC_CONFIG_FILES([
1313 Makefile
1314 src/Makefile
1315 man/Makefile
1316 libpulse.pc
1317 libpulse-simple.pc
1318 libpulse-mainloop-glib.pc
1319 doxygen/Makefile
1320 doxygen/doxygen.conf
1321 src/pulse/version.h
1322 po/Makefile.in
1323 man/pulseaudio.1.xml
1324 man/esdcompat.1.xml
1325 man/pax11publish.1.xml
1326 man/paplay.1.xml
1327 man/pacat.1.xml
1328 man/pacmd.1.xml
1329 man/pactl.1.xml
1330 man/pasuspender.1.xml
1331 man/padsp.1.xml
1332 man/pulse-daemon.conf.5.xml
1333 man/pulse-client.conf.5.xml
1334 man/default.pa.5.xml
1335 man/pulse-cli-syntax.5.xml
1336 man/start-pulseaudio-kde.1.xml
1337 man/start-pulseaudio-x11.1.xml
1338 ])
1339
1340 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1341 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1342 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1343 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1344 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1345     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1346 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1347     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1348 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1349     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1350
1351 # CMake related ProjectConfig files
1352 PA_LIBDIR="$libdir"
1353 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1354 PA_INCDIR="$includedir"
1355 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1356
1357 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1358     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1359 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1360
1361 AC_OUTPUT
1362
1363 # ==========================================================================
1364
1365 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1366 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1367 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1368 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1369 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1370 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1371 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1372 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1373 AS_IF([test "x$HAVE_GTK30" = "x1"], ENABLE_GTK30=yes, ENABLE_GTK30=no)
1374 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1375 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1376 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1377 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1378 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1379 AS_IF([test "x$HAVE_XEN" = "x1"], ENABLE_XEN=yes, ENABLE_XEN=no)
1380 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1381 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1382 AS_IF([test "x$HAVE_SYSTEMD" = "x1"], ENABLE_SYSTEMD=yes, ENABLE_SYSTEMD=no)
1383 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1384 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1385 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1386 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1387 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1388 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1389 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1390 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1391 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1392 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1393 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1394 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1395 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1396 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1397 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1398 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1399 AS_IF([test "x$HAVE_GCOV" = "x1"], ENABLE_GCOV=yes, ENABLE_GCOV=no)
1400 AS_IF([test "x$HAVE_LIBCHECK" = "x1"], ENABLE_TESTS=yes, ENABLE_TESTS=no)
1401 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1402
1403 echo "
1404  ---{ $PACKAGE_NAME $VERSION }---
1405
1406     prefix:                        ${prefix}
1407     sysconfdir:                    ${sysconfdir}
1408     localstatedir:                 ${localstatedir}
1409     modlibexecdir:                 ${modlibexecdir}
1410     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1411     System State Path:             ${PA_SYSTEM_STATE_PATH}
1412     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1413     Compiler:                      ${CC}
1414     CFLAGS:                        ${CFLAGS}
1415     LIBS:                          ${LIBS}
1416
1417     Enable X11:                    ${ENABLE_X11}
1418     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1419     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1420     Enable EsounD:                 ${ENABLE_ESOUND}
1421     Enable Alsa:                   ${ENABLE_ALSA}
1422     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1423     Enable Solaris:                ${ENABLE_SOLARIS}
1424     Enable WaveOut:                ${ENABLE_WAVEOUT}
1425     Enable GLib 2.0:               ${ENABLE_GLIB20}
1426     Enable Gtk+ 3.0:               ${ENABLE_GTK30}
1427     Enable GConf:                  ${ENABLE_GCONF}
1428     Enable Avahi:                  ${ENABLE_AVAHI}
1429     Enable Jack:                   ${ENABLE_JACK}
1430     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1431     Enable LIRC:                   ${ENABLE_LIRC}
1432     Enable Xen PV driver:          ${ENABLE_XEN}
1433     Enable D-Bus:                  ${ENABLE_DBUS}
1434       Enable BlueZ:                ${ENABLE_BLUEZ}
1435     Enable udev:                   ${ENABLE_UDEV}
1436       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1437     Enable systemd login:          ${ENABLE_SYSTEMD}
1438     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1439     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1440     Enable IPv6:                   ${ENABLE_IPV6}
1441     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1442     Enable fftw:                   ${ENABLE_FFTW}
1443     Enable orc:                    ${ENABLE_ORC}
1444     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1445     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1446     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1447     Enable gcov coverage:          ${ENABLE_GCOV}
1448     Enable unit tests:             ${ENABLE_TESTS}
1449     Database
1450       tdb:                         ${ENABLE_TDB}
1451       gdbm:                        ${ENABLE_GDBM}
1452       simple database:             ${ENABLE_SIMPLEDB}
1453
1454     System User:                   ${PA_SYSTEM_USER}
1455     System Group:                  ${PA_SYSTEM_GROUP}
1456     Access Group:                  ${PA_ACCESS_GROUP}
1457     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1458     Force preopen:                 ${FORCE_PREOPEN}
1459     Preopened modules:             ${PREOPEN_MODS}
1460
1461     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1462 "
1463
1464 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1465 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1466 fi
1467
1468 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1469    echo "
1470 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1471 You do not have D-Bus support enabled. It is strongly recommended
1472 that you enable D-Bus support if your platform supports it.
1473 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1474 to the Device Reservation Protocol to speak to JACK, Bluetooth
1475 support and even a native control protocol for communicating and
1476 controling the PulseAudio daemon itself.
1477 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1478 "
1479 fi
1480
1481 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1482    echo "
1483 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1484 You do not have udev support enabled. It is strongly recommended
1485 that you enable udev support if your platform supports it as it is
1486 the primary method used to detect hardware audio devices (on Linux)
1487 and is thus a critical part of PulseAudio on that platform.
1488 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1489 "
1490 fi
1491
1492 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1493    echo "
1494 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1495 You do not have speex support enabled. It is strongly recommended
1496 that you enable speex support if your platform supports it as it is
1497 the primary method used for audio resampling and is thus a critical
1498 part of PulseAudio on that platform.
1499 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1500 "
1501 fi