configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl we don't specify PACKAGE and VERSION because AS_VERSION puts it together
   5 AC_INIT
   6
   7 dnl when going to/from release please set the nano (fourth number) right !
   8 dnl releases only do Wall, cvs and prerelease does Werror too
   9 AS_VERSION(gst-plugins-base, GST_PLUGINS_BASE_VERSION, 0, 9, 4, 1,
  10     GST_CVS="no", GST_CVS="yes")
  11
  12 dnl can autoconf find the source ?
  13 AC_CONFIG_SRCDIR([gst/sine/gstsinesrc.c])
  14
  15 dnl define the output header for config
  16 AM_CONFIG_HEADER([config.h])
  17
  18 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  19 AM_MAINTAINER_MODE
  20
  21 dnl sets host_* variables
  22 AC_CANONICAL_HOST
  23
  24 dnl initialize automake
  25 dnl FIXME: this is deprecated use, we should move PACKAGE and VERSION to
  26 dnl AC_INIT, but then we need to parse the version to pass to AS_VERSION
  27 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  28
  29 dnl our libraries and install dirs use major.minor as a version
  30 GST_MAJORMINOR=$GST_PLUGINS_BASE_VERSION_MAJOR.$GST_PLUGINS_BASE_VERSION_MINOR
  31 dnl we override it here if we need to for the release candidate of new series
  32 # GST_MAJORMINOR=0.9
  33 AC_SUBST(GST_MAJORMINOR)
  34
  35 dnl CURRENT, REVISION, AGE
  36 dnl - library source changed -> increment REVISION
  37 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  38 dnl - interfaces added -> increment AGE
  39 dnl - interfaces removed -> AGE = 0
  40 dnl sets GST_LT_LDFLAGS
  41 AS_LIBTOOL(GST, 2, 0, 0)
  42 AS_LIBTOOL_TAGS
  43 AM_PROG_LIBTOOL
  44
  45 dnl *** autotools stuff ****
  46
  47 dnl allow for different autotools
  48 AS_AUTOTOOLS_ALTERNATE
  49
  50 dnl Add parameters for aclocal
  51 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  52
  53 dnl set up gettext
  54 dnl the version check needs to stay here because autopoint greps for it
  55 AM_GNU_GETTEXT_VERSION([0.11.5])
  56 AM_GNU_GETTEXT([external])
  57 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  58
  59 dnl *** check for arguments to configure ***
  60
  61 GST_ARG_DEBUG
  62 GST_ARG_PROFILING
  63 GST_ARG_VALGRIND
  64 GST_ARG_GCOV
  65
  66 GST_ARG_EXAMPLES
  67
  68 GST_ARG_WITH_PKG_CONFIG_PATH
  69 GST_ARG_WITH_PACKAGE_NAME([GStreamer Base Plug-ins])
  70 GST_ARG_WITH_PACKAGE_ORIGIN
  71
  72 dnl these are all the gst plug-ins, compilable without additional libs
  73 GST_PLUGINS_ALL="\
  74         adder \
  75         audioconvert \
  76         audiorate \
  77         audioresample \
  78         audiotestsrc \
  79         ffmpegcolorspace \
  80         playback \
  81         sine \
  82         typefind \
  83         videotestsrc \
  84         videorate \
  85         videoscale \
  86         volume \
  87         "
  88 AC_SUBST(GST_PLUGINS_ALL)
  89
  90 GST_PLUGINS_SELECTED=""
  91
  92 AC_ARG_WITH(plugins,
  93     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
  94     [for i in `echo $withval | tr , ' '`; do
  95         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
  96         then
  97             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
  98         else
  99             echo "plug-in $i not recognized, ignoring..."
 100         fi
 101     done],
 102     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 103
 104 AC_SUBST(GST_PLUGINS_SELECTED)
 105
 106
 107 dnl ext plug-ins; plug-ins that have external dependencies
 108 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 109   [HAVE_EXTERNAL=yes], enabled,
 110   [
 111     AC_MSG_NOTICE(building external plug-ins)
 112     BUILD_EXTERNAL="yes"
 113   ],[
 114     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 115     BUILD_EXTERNAL="no"
 116   ])
 117 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 118
 119 dnl *** checks for platform ***
 120
 121 dnl * hardware/architecture *
 122
 123 dnl common/m4/gst-arch.m4
 124 dnl check CPU type
 125 GST_ARCH
 126
 127 dnl *** checks for programs ***
 128
 129 dnl find a compiler
 130 AC_PROG_CC
 131
 132 dnl determine c++ compiler
 133 AC_PROG_CXX
 134 dnl determine if c++ is available on this system
 135 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 136
 137 dnl determine c++ preprocessor
 138 dnl FIXME: do we need this ?
 139 AC_PROG_CXXCPP
 140
 141 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 142 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 143
 144 dnl check for documentation tools
 145 GTK_DOC_CHECK([1.3])
 146 AS_PATH_PYTHON([2.1])
 147
 148 dnl *** checks for libraries ***
 149
 150 dnl For interactive UNIX (a Sun thing)
 151 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 152 AC_ISC_POSIX
 153
 154 dnl *** checks for header files ***
 155
 156 dnl check if we have ANSI C header files
 157 AC_HEADER_STDC
 158
 159 dnl used in gst/ffmpegcolorspace/mem.c
 160 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 161 AC_CHECK_HEADERS([malloc.h])
 162
 163 dnl used in gst/subparse/gstsubparse.c
 164 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 165 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 166
 167 dnl used in gst/tcp
 168 AC_CHECK_HEADERS([sys/socket.h],
 169   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 170 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 171
 172
 173 dnl ffmpegcolorspace includes _stdint.h
 174 AX_CREATE_STDINT_H
 175
 176 dnl *** checks for types/defines ***
 177
 178 dnl Check for FIONREAD ioctl declaration
 179 dnl used in gst/tcp
 180 GST_CHECK_FIONREAD
 181
 182 dnl *** checks for structures ***
 183
 184 dnl *** checks for compiler characteristics ***
 185
 186 dnl make sure we can use "inline" from C code
 187 AC_C_INLINE
 188
 189 dnl *** checks for library functions ***
 190
 191 dnl Check for fast float to int casting as defined in C99
 192 dnl used in gst-libs/gst/floatcast/floatcast.h
 193 AC_C99_FUNC_LRINT
 194 AC_C99_FUNC_LRINTF
 195
 196 dnl Check for a way to display the function name in debug output
 197 GST_CHECK_FUNCTION
 198
 199 dnl *** checks for dependancy libraries ***
 200
 201 dnl GLib is required
 202 GST_GLIB_CHECK([2.6])
 203
 204 dnl liboil is required
 205 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.2, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 206 if test "x${HAVE_LIBOIL}" != xyes ; then
 207   AC_ERROR([liboil-0.3 is required])
 208 fi
 209
 210 dnl checks for gstreamer
 211 dnl uninstalled is selected preferentially -- see pkg-config(1)
 212 GST_REQ=0.9.3
 213 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 214 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 215 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 216 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 217 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 218
 219 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 220 dnl check for "check", unit testing library/header
 221 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 222 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 223
 224
 225 dnl GTK is optional and used in examples
 226 HAVE_GTK=NO
 227 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 228 if test "x$HAVE_GTK_22" = "xyes"; then
 229   HAVE_GTK=yes
 230   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 231   AC_SUBST(GTK_VERSION)
 232   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 233   AC_SUBST(GTK_BASE_DIR)
 234 else
 235   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 236 fi
 237 if test "x$HAVE_GTK_20" = "xyes"; then
 238   HAVE_GTK=yes
 239 fi
 240 GTK_CFLAGS=$GTK2_CFLAGS
 241 GTK_LIBS=$GTK2_LIBS
 242 AC_SUBST(GTK_LIBS)
 243 AC_SUBST(GTK_CFLAGS)
 244 AC_SUBST(HAVE_GTK)
 245 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 246
 247 dnl *** set variables based on configure arguments ***
 248
 249 dnl set license and copyright notice
 250 GST_LICENSE="LGPL"
 251 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 252 AC_SUBST(GST_LICENSE)
 253
 254 dnl set location of plugin directory
 255 GST_SET_PLUGINDIR
 256
 257 dnl define an ERROR_CFLAGS Makefile variable
 258 GST_SET_ERROR_CFLAGS($GST_CVS)
 259
 260 dnl define correct level for debugging messages
 261 GST_SET_LEVEL_DEFAULT($GST_CVS)
 262
 263 dnl decide on default elements
 264 dnl FIXME: provide configure-time options for this
 265 dnl FIXME: describe where exactly this gets used
 266 dnl FIXME: decide if it's a problem that this could point to sinks from
 267 dnl        depending plugin modules
 268 DEFAULT_AUDIOSINK="alsasink"
 269 DEFAULT_VIDEOSINK="xvimagesink"
 270 DEFAULT_AUDIOSRC="alsasrc"
 271 DEFAULT_VIDEOSRC="v4lsrc"
 272 DEFAULT_VISUALIZER="goom"
 273 case "$host" in
 274   *-sun-* | *pc-solaris* )
 275     DEFAULT_AUDIOSINK="sunaudiosink"
 276     DEFAULT_VIDEOSINK="ximagesink"
 277     DEFAULT_AUDIOSRC="sunaudiosrc"
 278     ;;
 279   *-darwin* )
 280     DEFAULT_AUDIOSINK="osxaudiosink"
 281     DEFAULT_AUDIOSRC="osxaudiosrc"
 282     DEFAULT_VIDEOSINK="osxvideosink"
 283     ;;
 284 esac
 285
 286 AC_SUBST(DEFAULT_AUDIOSINK)
 287 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSINK, "$DEFAULT_AUDIOSINK",
 288   [Default audio sink])
 289 AC_SUBST(DEFAULT_AUDIOSRC)
 290 AC_DEFINE_UNQUOTED(DEFAULT_AUDIOSRC, "$DEFAULT_AUDIOSRC",
 291   [Default audio source])
 292 AC_SUBST(DEFAULT_VIDEOSINK)
 293 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSINK, "$DEFAULT_VIDEOSINK",
 294   [Default video sink])
 295 AC_SUBST(DEFAULT_VIDEOSRC)
 296 AC_DEFINE_UNQUOTED(DEFAULT_VIDEOSRC, "$DEFAULT_VIDEOSRC",
 297   [Default video source])
 298 AC_SUBST(DEFAULT_VISUALIZER)
 299 AC_DEFINE_UNQUOTED(DEFAULT_VISUALIZER, "$DEFAULT_VISUALIZER",
 300   [Default visualizer])
 301
 302 dnl *** sys plug-ins ***
 303
 304 echo
 305 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 306 echo
 307
 308 dnl *** X11 ***
 309 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 310 GST_CHECK_FEATURE(X, [X libraries and plugins],
 311                   [ximagesink], [
 312   AC_PATH_XTRA
 313   ac_cflags_save="$CFLAGS"
 314   ac_cppflags_save="$CPPFLAGS"
 315   CFLAGS="$CFLAGS $X_CFLAGS"
 316   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 317
 318   dnl now try to find the HEADER
 319   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 320
 321   if test "x$HAVE_X" = "xno"
 322   then
 323     AC_MSG_NOTICE([cannot find X11 development files])
 324   else
 325     dnl this is much more than we want
 326     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 327     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 328     dnl it does not add the libs; therefore we add them here
 329     X_LIBS="$X_LIBS -lX11"
 330     AC_SUBST(X_CFLAGS)
 331     AC_SUBST(X_LIBS)
 332   fi
 333   AC_SUBST(HAVE_X)
 334   CFLAGS="$ac_cflags_save"
 335   CPPFLAGS="$ac_cppflags_save"
 336 ])
 337
 338 dnl *** XVideo ***
 339 dnl Look for the PIC library first, Debian requires it.
 340 dnl Check debian-devel archives for gory details.
 341 dnl 20020110:
 342 dnl At the moment XFree86 doesn't distribute shared libXv due
 343 dnl to unstable API.  On many platforms you CAN NOT link a shared
 344 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 345 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 346 dnl version of the static lib for plug-ins to link to when it is
 347 dnl inappropriate to link the main application to libXv directly.
 348 dnl FIXME: add check if this platform can support linking to a
 349 dnl        non-PIC libXv, if not then don not use Xv.
 350 dnl FIXME: perhaps warn user if they have a shared libXv since
 351 dnl        this is an error until XFree86 starts shipping one
 352
 353 dnl Check for Xv extension
 354 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 355 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 356                   [xvimagesink], [
 357   if test x$HAVE_X = xyes; then
 358     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 359                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 360                  $X_LIBS -lXext)
 361
 362     if test x$HAVE_XVIDEO = xyes; then
 363       XVIDEO_LIBS="-lXv_pic -lXext"
 364       AC_SUBST(XVIDEO_LIBS)
 365     else
 366       dnl try again using something else if we didn't find it first
 367       if test x$HAVE_XVIDEO = xno; then
 368         AC_CHECK_LIB(Xv, XvQueryExtension,
 369                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 370                    $X_LIBS -lXext)
 371
 372         if test x$HAVE_XVIDEO = xyes; then
 373           XVIDEO_LIBS="-lXv -lXext"
 374           AC_SUBST(XVIDEO_LIBS)
 375         fi
 376       fi
 377     fi
 378   fi
 379 ])
 380
 381 dnl check for X Shm
 382 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 383 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 384   if test x$HAVE_X = xyes; then
 385     AC_CHECK_LIB(Xext, XShmAttach,
 386                  HAVE_XSHM="yes", HAVE_XSHM="no",
 387                  $X_LIBS)
 388     if test "x$HAVE_XSHM" = "xyes"; then
 389       XSHM_LIBS="-lXext"
 390     else
 391       dnl On AIX, it is in XextSam instead, but we still need -lXext
 392       AC_CHECK_LIB(XextSam, XShmAttach,
 393                    HAVE_XSHM="yes", HAVE_XSHM="no",
 394                    $X_LIBS)
 395       if test "x$HAVE_XSHM" = "xyes"; then
 396         XSHM_LIBS="-lXext -lXextSam"
 397       fi
 398     fi
 399   fi
 400 ], , [
 401   AC_SUBST(HAVE_XSHM)
 402   AC_SUBST(XSHM_LIBS)
 403 ] )
 404
 405 dnl v4l/v4l2 checks have been moved down because they require X
 406
 407 dnl *** Video 4 Linux ***
 408 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 409 dnl renamed to GST_V4L in accordance with V4L2 below
 410 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 411 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 412   # first check X
 413   HAVE_GST_V4L="no"
 414   if test "$HAVE_X" = "yes"
 415   then
 416     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 417 #include <sys/types.h>
 418 #define _LINUX_TIME_H
 419 #define __user
 420 #include <linux/videodev.h>
 421     ])
 422   fi
 423 ])
 424
 425 dnl *** ext plug-ins ***
 426 dnl keep this list sorted alphabetically !
 427
 428 if test "x$BUILD_EXTERNAL" = "xyes"; then
 429
 430 echo
 431 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 432 echo
 433
 434 dnl *** alsa ***
 435 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 436 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 437   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 438     HAVE_ALSA="yes"
 439     AC_SUBST(ALSA_CFLAGS)
 440     AC_SUBST(ALSA_LIBS)
 441   ], [
 442     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 443   ])
 444 ])
 445
 446 dnl *** CDParanoia ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 448 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 449   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 450                       cdda_open, -lm,
 451                       cdda_interface.h,
 452                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 453                       HEADER_DIR="no"
 454                       FOUND_CDPARANOIA="yes")
 455   if test "x$FOUND_CDPARANOIA" != "xyes";
 456   then
 457     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 458                         cdda_open, -lm,
 459                         cdda/cdda_interface.h,
 460                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 461                         HEADER_DIR="yes"
 462                         FOUND_CDPARANOIA="yes")
 463   fi
 464   if test "x$HEADER_DIR" = "xyes";
 465   then
 466     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 467                        defined if cdda headers are in a cdda/ directory)
 468   fi
 469   AC_SUBST(CDPARANOIA_LIBS)
 470 ])
 471 dnl FIXME : add second check somehow if that is necessary
 472 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 473 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 474
 475 dnl *** Gnome VFS ***
 476 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 477 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 478   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 479   AC_SUBST(GNOME_VFS_CFLAGS)
 480   AC_SUBST(GNOME_VFS_LIBS)
 481 ])
 482
 483 dnl *** libvisual ***
 484 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 485 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
 486   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
 487   AC_SUBST(LIBVISUAL_CFLAGS)
 488   AC_SUBST(LIBVISUAL_LIBS)
 489 ])
 490
 491 dnl *** ogg ***
 492 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 493 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
 494   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
 495     HAVE_OGG="yes"
 496     AC_SUBST(OGG_CFLAGS)
 497     AC_SUBST(OGG_LIBS)
 498   ], [
 499     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 500     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 501   ])
 502 ])
 503
 504 dnl *** theora ***
 505 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 506 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
 507   PKG_CHECK_MODULES(THEORA, theora, [
 508     HAVE_THEORA="yes"
 509     AC_SUBST(THEORA_LIBS)
 510     AC_SUBST(THEORA_CFLAGS)
 511   ], [
 512     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 513     AC_SUBST(THEORA_LIBS)
 514   ])
 515 ])
 516
 517 dnl *** vorbis ***
 518 dnl AM_PATH_VORBIS only takes two options
 519 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 520 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
 521   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
 522     HAVE_VORBIS="yes"
 523   ], [
 524     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 525     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 526   ])
 527 ])
 528 if test "x$HAVE_VORBIS" = "xyes"; then
 529   ac_cflags_save="$CFLAGS"
 530   dnl FIXME: does this work on non-gcc? -- Company
 531   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 532   CFLAGS="-Wall -Werror"
 533   AC_COMPILE_IFELSE(
 534     AC_LANG_PROGRAM([
 535 #include <vorbis/codec.h>
 536                      ],[
 537 vorbis_dsp_state *v;
 538
 539 vorbis_synthesis_restart (v);
 540                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 541   if test "x$HAVE_VSR" = "xyes"; then
 542     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 543                        [defined if vorbis_synthesis_restart is present])
 544   fi
 545   CFLAGS="$ac_cflags_save"
 546 fi
 547
 548 fi dnl of EXT plugins
 549
 550 dnl ######################################################################
 551 dnl # Check command line parameters, and set shell variables accordingly #
 552 dnl ######################################################################
 553
 554 dnl seeking needs freetype, so check for it here
 555 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 556   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 557 ])
 558 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 559 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 560 AC_SUBST(FT2_CFLAGS)
 561 AC_SUBST(FT2_LIBS)
 562
 563 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 564
 565 dnl Overview:
 566 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 567 dnl GST_*:              flags shared by all built objects
 568 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 569 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 570
 571 dnl GST_OPTION_CFLAGS
 572 if test "x$USE_DEBUG" = xyes; then
 573    PROFILE_CFLAGS="-g"
 574 fi
 575 AC_SUBST(PROFILE_CFLAGS)
 576
 577 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 578 AC_SUBST(DEPRECATED_CFLAGS)
 579
 580 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 581 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 582 AC_SUBST(GST_OPTION_CFLAGS)
 583
 584 dnl our libraries need to be versioned correctly
 585 AC_SUBST(GST_LT_LDFLAGS)
 586
 587 dnl FIXME: do we want to rename to GST_ALL_* ?
 588 dnl prefer internal headers to already installed ones
 589 dnl also add builddir include for enumtypes and marshal
 590 dnl add ERROR_CFLAGS, but overridable
 591 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 592 AC_SUBST(GST_CFLAGS)
 593 AC_SUBST(GST_LIBS)
 594
 595 dnl this really should only contain flags, not libs - they get added before
 596 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 597 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' -no-undefined"
 598 AC_SUBST(GST_PLUGIN_LDFLAGS)
 599
 600 dnl *** output files ***
 601
 602 AC_CONFIG_FILES(
 603 Makefile
 604 gst-plugins-base.spec
 605 gst/Makefile
 606 gst/adder/Makefile
 607 gst/audioconvert/Makefile
 608 gst/audiorate/Makefile
 609 gst/audioresample/Makefile
 610 gst/audiotestsrc/Makefile
 611 gst/ffmpegcolorspace/Makefile
 612 gst/playback/Makefile
 613 gst/sine/Makefile
 614 gst/subparse/Makefile
 615 gst/tcp/Makefile
 616 gst/typefind/Makefile
 617 gst/videotestsrc/Makefile
 618 gst/videorate/Makefile
 619 gst/videoscale/Makefile
 620 gst/volume/Makefile
 621 sys/Makefile
 622 sys/ximage/Makefile
 623 sys/xvimage/Makefile
 624 sys/v4l/Makefile
 625 ext/Makefile
 626 ext/alsa/Makefile
 627 ext/cdparanoia/Makefile
 628 ext/gnomevfs/Makefile
 629 ext/libvisual/Makefile
 630 ext/ogg/Makefile
 631 ext/theora/Makefile
 632 ext/vorbis/Makefile
 633 gst-libs/Makefile
 634 gst-libs/gst/Makefile
 635 gst-libs/gst/audio/Makefile
 636 gst-libs/gst/floatcast/Makefile
 637 gst-libs/gst/interfaces/Makefile
 638 gst-libs/gst/net/Makefile
 639 gst-libs/gst/riff/Makefile
 640 gst-libs/gst/rtp/Makefile
 641 gst-libs/gst/tag/Makefile
 642 gst-libs/gst/video/Makefile
 643 gst-libs/ext/Makefile
 644 examples/seeking/Makefile
 645 examples/Makefile
 646 tools/Makefile
 647 pkgconfig/Makefile
 648 pkgconfig/gstreamer-plugins-base.pc
 649 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 650 check/Makefile
 651 docs/Makefile
 652 docs/libs/Makefile
 653 docs/plugins/Makefile
 654 docs/version.entities
 655 po/Makefile.in
 656 common/Makefile
 657 common/m4/Makefile
 658 m4/Makefile
 659 )
 660 AC_OUTPUT
 661
 662 echo "configure: *** Core plug-ins, always built:"
 663 ( for i in $GST_PLUGINS_ALL; do echo -e '\t'$i; done ) | sort
 664 echo
 665 echo -n "configure: *** Plug-ins relying on libraries that will be built:"
 666 echo -e "$GST_PLUGINS_YES" | sort
 667 echo
 668 echo -n "configure: *** Plug-ins relying on libraries that will NOT be built:"
 669 echo -e "$GST_PLUGINS_NO" | sort
 670 echo
 671 if test "x$BUILD_EXTERNAL" = "xno"; then
 672   echo "configure: *** No external plug-ins will be built"
 673 fi