configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl initialize autoconf
   4 dnl when going to/from release please set the nano (fourth number) right !
   5 dnl releases only do Wall, git and prerelease does Werror too
   6 AC_INIT(GStreamer, 0.10.23.1,
   7     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
   8     gstreamer)
   9 AG_GST_INIT
  10
  11 dnl initialize automake (we require GNU make)
  12 AM_INIT_AUTOMAKE([-Wno-portability])
  13
  14 dnl define PACKAGE_VERSION_* variables
  15 AS_VERSION
  16
  17 dnl check if this is a release version
  18 AS_NANO(GST_GIT="no", GST_GIT="yes")
  19
  20 dnl can autoconf find the source ?
  21 AC_CONFIG_SRCDIR([gst/gst.c])
  22
  23 dnl define the output header for config
  24 AM_CONFIG_HEADER([config.h])
  25
  26 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  27 AM_MAINTAINER_MODE
  28
  29 dnl sets host_* variables
  30 AC_CANONICAL_HOST
  31
  32 dnl our libraries and install dirs use major.minor as a version
  33 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  34 dnl we override it here for release candidates for a new series
  35 GST_MAJORMINOR=0.10
  36 AC_SUBST(GST_MAJORMINOR)
  37 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR",
  38   [library major.minor version])
  39
  40 dnl CURRENT, REVISION, AGE
  41 dnl - library source changed -> increment REVISION
  42 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  43 dnl - interfaces added -> increment AGE
  44 dnl - interfaces removed -> AGE = 0
  45 dnl sets GST_LT_LDFLAGS
  46 AS_LIBTOOL(GST, 20, 0, 20)
  47
  48 dnl FIXME: this macro doesn't actually work;
  49 dnl the generated libtool script has no support for the listed tags.
  50 dnl So this needs to be fixed first if we want to use this
  51 dnl AS_LIBTOOL_TAGS
  52
  53 AC_LIBTOOL_WIN32_DLL
  54 AM_PROG_LIBTOOL
  55
  56 dnl *** autotools stuff ****
  57
  58 dnl allow for different autotools
  59 AS_AUTOTOOLS_ALTERNATE
  60
  61 dnl Add parameters for aclocal
  62 AC_SUBST(ACLOCAL_AMFLAGS, "-I common/m4")
  63
  64 dnl set up gettext
  65 dnl the version check needs to stay here because autopoint greps for it
  66 AM_GNU_GETTEXT_VERSION([0.17])
  67 AM_GNU_GETTEXT([external])
  68 AG_GST_GETTEXT([gstreamer-$GST_MAJORMINOR])
  69
  70 dnl *** check for arguments to configure ***
  71
  72 dnl subsystems - can influence other decisions so needs to be high up
  73 dnl we need to AM_CONDITIONAL them here for automake 1.6.x compatibility
  74 AG_GST_CHECK_SUBSYSTEM_DISABLE(GST_DEBUG,[debugging subsystem])
  75 AM_CONDITIONAL(GST_DISABLE_GST_DEBUG, test "x$GST_DISABLE_GST_DEBUG" = "xyes")
  76 AG_GST_CHECK_SUBSYSTEM_DISABLE(LOADSAVE,[pipeline XML load/save])
  77 AM_CONDITIONAL(GST_DISABLE_LOADSAVE, test "x$GST_DISABLE_LOADSAVE" = "xyes")
  78 dnl define a substitution to use in docs/gst/gstreamer.types
  79 if test "x$GST_DISABLE_LOADSAVE" = "xyes"
  80 then
  81   GST_LOADSAVE_DOC_TYPES="%"
  82 else
  83   GST_LOADSAVE_DOC_TYPES=
  84 fi
  85 AC_SUBST(GST_LOADSAVE_DOC_TYPES)
  86 AG_GST_CHECK_SUBSYSTEM_DISABLE(PARSE,[command-line parser])
  87 AM_CONDITIONAL(GST_DISABLE_PARSE, test "x$GST_DISABLE_PARSE" = "xyes")
  88 if test "x$GST_DISABLE_PARSE" = xyes; then
  89   AC_DEFINE(GST_DISABLE_PARSE, 1,
  90     [Define if pipeline parsing code is disabled])
  91 fi
  92 AG_GST_CHECK_SUBSYSTEM_DISABLE(OPTION_PARSING,[option parsing when gst_init])
  93 AM_CONDITIONAL(GST_DISABLE_OPTION_PARSING, test "x$GST_DISABLE_OPTION_PARSING" = "xyes")
  94 if test "x$GST_DISABLE_OPTION_PARSING" = xyes; then
  95   AC_DEFINE(GST_DISABLE_OPTION_PARSING, 1,
  96     [Define if option parsing is disabled])
  97 fi
  98 AG_GST_CHECK_SUBSYSTEM_DISABLE(TRACE,[tracing subsystem])
  99 AM_CONDITIONAL(GST_DISABLE_TRACE, test "x$GST_DISABLE_TRACE" = "xyes")
 100 AG_GST_CHECK_SUBSYSTEM_DISABLE(ALLOC_TRACE,[allocation tracing])
 101 AM_CONDITIONAL(GST_DISABLE_ALLOC_TRACE, test "x$GST_DISABLE_ALLOC_TRACE" = "xyes")
 102 AG_GST_CHECK_SUBSYSTEM_DISABLE(REGISTRY,[plugin registry])
 103 AM_CONDITIONAL(GST_DISABLE_REGISTRY, test "x$GST_DISABLE_REGISTRY" = "xyes")
 104 dnl define a substitution to use in docs/gst/gstreamer.types
 105 if test "x$GST_DISABLE_REGISTRY" = "xyes"
 106 then
 107   GST_REGISTRY_DOC_TYPES="%"
 108 else
 109   GST_REGISTRY_DOC_TYPES=
 110 fi
 111 AC_SUBST(GST_REGISTRY_DOC_TYPES)
 112 AG_GST_CHECK_SUBSYSTEM_DISABLE(NET,[network distribution])
 113 AM_CONDITIONAL(GST_DISABLE_NET, test "x$GST_DISABLE_NET" = "xyes")
 114 AG_GST_CHECK_SUBSYSTEM_DISABLE(PLUGIN,[plugin])
 115 AM_CONDITIONAL(GST_DISABLE_PLUGIN, test "x$GST_DISABLE_PLUGIN" = "xyes")
 116
 117 AG_GST_ARG_DEBUG
 118 AG_GST_ARG_PROFILING
 119 AG_GST_ARG_VALGRIND
 120 AG_GST_ARG_GCOV
 121
 122 AG_GST_ARG_EXAMPLES
 123
 124 AG_GST_ARG_WITH_PKG_CONFIG_PATH
 125 AG_GST_ARG_WITH_PACKAGE_NAME
 126 AG_GST_ARG_WITH_PACKAGE_ORIGIN
 127
 128 dnl building of tests
 129 AC_ARG_ENABLE(tests,
 130   AC_HELP_STRING([--disable-tests], [disable building test apps]),
 131   [
 132     case "${enableval}" in
 133       yes) BUILD_TESTS=yes ;;
 134       no)  BUILD_TESTS=no ;;
 135       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 136     esac
 137   ],
 138 [BUILD_TESTS=yes]) dnl Default value
 139 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
 140
 141 dnl tests known to fail
 142 AC_ARG_ENABLE(failing-tests,
 143   AC_HELP_STRING([--disable-failing-tests],
 144     [disable building tests known to fail]),
 145   [
 146     case "${enableval}" in
 147       yes) BUILD_FAILING_TESTS=yes ;;
 148       no)  BUILD_FAILING_TESTS=no ;;
 149       *)   AC_MSG_ERROR(bad value ${enableval} for --disable-failing-tests) ;;
 150     esac
 151   ],
 152   [BUILD_FAILING_TESTS=no]) dnl Default value
 153 AM_CONDITIONAL(BUILD_FAILING_TESTS, test "x$BUILD_FAILING_TESTS" = "xyes")
 154 if test x$BUILD_FAILING_TESTS = xyes; then
 155   AC_MSG_WARN([building tests known to fail, use --disable-failing-tests to disable])
 156 else
 157   AC_MSG_WARN([Sissy ! By asking to not build the tests known to fail, you hereby waive your right to customer support.  If you do not agree with this EULA, please press Ctrl-C before the next line is printed.  By allowing the next line to be printed, you expressly acknowledge your acceptance of this EULA.])
 158 fi
 159
 160 dnl poison destroyed objects
 161 AC_ARG_ENABLE(poisoning,
 162   AC_HELP_STRING([--enable-poisoning],
 163     [enable poisoning of deallocated objects]),
 164   [
 165     case "${enableval}" in
 166       yes) USE_POISONING=yes ;;
 167       no)  USE_POISONING=no ;;
 168       *)   AC_MSG_ERROR(bad value ${enableval} for --enable-poisoning) ;;
 169     esac
 170   ],
 171   [USE_POISONING=no]) dnl Default value
 172 if test "x$USE_POISONING" = xyes; then
 173   AC_DEFINE(USE_POISONING, 1,
 174     [Define if we should poison deallocated memory])
 175 fi
 176
 177 dnl *** checks for platform ***
 178
 179 dnl * hardware/architecture *
 180
 181 dnl common/m4/gst-arch.m4
 182 dnl check CPU type
 183 AG_GST_ARCH
 184 dnl substitution for win32/common/config.h
 185 HOST_CPU=$host_cpu
 186 AC_SUBST(HOST_CPU)
 187
 188 dnl common/m4/gst-arch.m4
 189 dnl check for unaligned access
 190 AG_GST_UNALIGNED_ACCESS
 191 dnl create a configure variable for gst/gstconfig.h
 192 if test x${as_cv_unaligned_access} = xyes ; then
 193   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 1"
 194 else
 195   GST_HAVE_UNALIGNED_ACCESS_DEFINE="#define GST_HAVE_UNALIGNED_ACCESS 0"
 196 fi
 197 AC_SUBST(GST_HAVE_UNALIGNED_ACCESS_DEFINE)
 198
 199 dnl check for platform specific settings
 200 case $host_os in
 201      rhapsody*)
 202         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 203         ;;
 204      darwin*)
 205         AC_DEFINE_UNQUOTED(GST_EXTRA_MODULE_SUFFIX, [".dylib"], [Extra platform specific plugin suffix])
 206         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 207         ;;
 208      cygwin*)
 209         AC_DEFINE_UNQUOTED(GST_HAVE_UNSAFE_FORK, 1, [Defined when registry scanning through fork is unsafe])
 210         ;;
 211      mingw* | msvc* | mks*)
 212         dnl HAVE_WIN32 currently means "disable POSIXisms".
 213         AC_DEFINE_UNQUOTED(HAVE_WIN32, 1, [Defined if compiling for Windows])
 214
 215         dnl define __MSVCRT_VERSION__ version if not set already by the
 216         dnl compiler (ie. mostly for mingw). This is needed for things like
 217         dnl __stat64 to be available. If set by the compiler, ensure it's
 218         dnl new enough - we need at least WinXP SP2.
 219         AC_TRY_COMPILE([ ], [ return __MSVCRT_VERSION__; ], [
 220             AC_TRY_COMPILE([ ], [
 221               #if __MSVCRT_VERSION__ < 0x0601
 222               #error "MSVCRT too old"
 223               #endif
 224             ], [
 225               AC_MSG_NOTICE([MSVCRT version looks ok])
 226             ], [
 227               AC_MSG_ERROR([MSVCRT version too old, need at least WinXP SP2])
 228             ])
 229         ], [
 230           AC_MSG_NOTICE([Setting MSVCRT version to 0x0601])
 231           AC_DEFINE_UNQUOTED(__MSVCRT_VERSION__, 0x0601, [We need at least WinXP SP2 for __stat64])
 232         ])
 233         ;;
 234      *)
 235         ;;
 236 esac
 237
 238 dnl * software *
 239
 240 dnl check for large file support
 241 dnl affected plugins must include config.h
 242 AC_SYS_LARGEFILE
 243
 244 dnl *** checks for programs ***
 245
 246 dnl find a compiler
 247 AC_PROG_CC
 248
 249 dnl check if the compiler supports '-c' and '-o' options
 250 AM_PROG_CC_C_O
 251
 252 dnl find an assembler
 253 AM_PROG_AS
 254
 255 dnl Perl is used in building documentation and in the version checks
 256 AC_PATH_PROG(PERL_PATH, perl, no)
 257 if test x$PERL_PATH = xno; then
 258   AC_MSG_ERROR(Could not find perl)
 259 fi
 260
 261 dnl we require flex and bison for building the parser
 262 if test "x$GST_DISABLE_PARSE" != xyes; then
 263   AG_GST_BISON_CHECK
 264   AG_GST_FLEX_CHECK
 265 fi
 266
 267 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 268 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 269
 270 dnl check for documentation tools
 271 AG_GST_DOCBOOK_CHECK
 272 GTK_DOC_CHECK([1.3])
 273 AS_PATH_PYTHON([2.1])
 274 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 275
 276 dnl *** checks for libraries ***
 277
 278 dnl check for libm, for sin()
 279 AC_CHECK_LIBM
 280 AC_SUBST(LIBM)
 281
 282 dnl *** checks for header files ***
 283
 284 dnl check if we have ANSI C header files
 285 AC_HEADER_STDC
 286
 287 dnl Check for ucontext.h
 288 AC_CHECK_HEADERS([ucontext.h])
 289
 290 dnl Check for sys/socket.h
 291 AC_CHECK_HEADERS([sys/socket.h], HAVE_SYS_SOCKET_H=yes)
 292 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 293
 294 dnl check for sys/times.h for tests/examples/adapter/
 295 AC_CHECK_HEADERS([sys/times.h], HAVE_SYS_TIMES_H=yes)
 296 AC_CHECK_HEADERS([unistd.h], HAVE_UNISTD_H=yes)
 297 AM_CONDITIONAL(HAVE_SYS_TIMES_H_AND_UNISTD_H, test "x$HAVE_SYS_TIMES_H" = "xyes" -a "x$HAVE_UNISTD_H" = "xyes")
 298
 299 dnl Check for process.h for getpid() on win32
 300 AC_CHECK_HEADERS([process.h])
 301
 302 dnl Check for sys/utsname.h for uname
 303 AC_CHECK_HEADERS([sys/utsname.h])
 304
 305 dnl Check for stdio_ext.f for __fbufsize
 306 AC_CHECK_HEADERS([stdio_ext.h])
 307
 308 dnl Check for valgrind.h
 309 dnl separate from HAVE_VALGRIND because you can have the program, but not
 310 dnl the dev package
 311 AC_CHECK_HEADERS([valgrind/valgrind.h], HAVE_VALGRIND_H=yes)
 312
 313 dnl used in gst/gstpoll.c
 314 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 315 AM_CONDITIONAL(HAVE_WINSOCK2_H, test "x$HAVE_WINSOCK2_H" = "xyes")
 316 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 317   WIN32_LIBS="-lws2_32"
 318   AC_SUBST(WIN32_LIBS)
 319 fi
 320
 321 dnl *** checks for types/defines ***
 322
 323 dnl *** checks for structures ***
 324
 325 dnl *** checks for compiler characteristics ***
 326
 327 dnl make sure we can use "inline" from C code
 328 AC_C_INLINE
 329
 330 OPT_CFLAGS=
 331 dnl Check for some compiler flags that optimize our code.
 332 if test "x$GCC" = xyes; then
 333   AS_COMPILER_FLAG(-fno-common, OPT_CFLAGS="$OPT_CFLAGS -fno-common")
 334 fi
 335
 336 dnl FIXME: decide what kind of flag this is, maybe it's not an optimization
 337 dnl flag
 338 dnl check if we should use -Wa,-mregnames on PowerPC, so we can use
 339 dnl symbolic register names in inline asm
 340 if test x$HAVE_CPU_PPC = xyes ; then
 341   AS_COMPILER_FLAG(["-Wa,-mregnames"],
 342     [OPT_CFLAGS="$OPT_CFLAGS -Wa,-mregnames"])
 343 fi
 344
 345 dnl *** checks for library functions ***
 346
 347 AC_CHECK_FUNCS([sigaction])
 348
 349 dnl we use fork in the registry code
 350 AC_CHECK_FUNCS([fork])
 351
 352 dnl check for fseeko()
 353 AC_FUNC_FSEEKO
 354 dnl check for ftello()
 355 AC_CHECK_FUNCS([ftello])
 356
 357 AC_CHECK_FUNCS([fgetpos])
 358 AC_CHECK_FUNCS([fsetpos])
 359
 360 dnl check for poll(), ppoll() and pselect()
 361 AC_CHECK_FUNCS([poll])
 362 AC_CHECK_FUNCS([ppoll])
 363 AC_CHECK_FUNCS([pselect])
 364
 365 dnl check for mmap()
 366 AC_FUNC_MMAP
 367 AM_CONDITIONAL(HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 368
 369 dnl Check for POSIX timers
 370 AC_CHECK_FUNCS(clock_gettime, [], [
 371   AC_CHECK_LIB(rt, clock_gettime, [
 372     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 373     LIBS="$LIBS -lrt"
 374   ])
 375 ])
 376
 377 AC_CACHE_CHECK(for posix timers, gst_cv_posix_timers,
 378     AC_TRY_COMPILE([
 379 #include <time.h>
 380 #ifdef HAVE_UNISTD_H
 381 #include <unistd.h>
 382 #endif
 383     ], [
 384 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 385 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 386 #endif
 387       return 0;
 388     ], [
 389       gst_cv_posix_timers=yes
 390     ], [
 391       gst_cv_posix_timers=no
 392     ])
 393 )
 394
 395 if test "$gst_cv_posix_timers" = "yes"; then
 396   AC_DEFINE(HAVE_POSIX_TIMERS,1,[Have posix timers])
 397   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 1"
 398 else
 399   GST_HAVE_POSIX_TIMERS_DEFINE="#define GST_HAVE_POSIX_TIMERS 0"
 400 fi
 401 AC_SUBST(GST_HAVE_POSIX_TIMERS_DEFINE)
 402 AM_CONDITIONAL(GST_HAVE_POSIX_TIMERS, test "$gst_cv_posix_timers" = "yes")
 403
 404 AC_CACHE_CHECK(for monotonic clock, gst_cv_monotonic_clock,
 405     AC_TRY_COMPILE([
 406 #include <time.h>
 407 #ifdef HAVE_UNISTD_H
 408 #include <unistd.h>
 409 #endif
 410     ], [
 411 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 412 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 413 #endif
 414       return 0;
 415     ], [
 416       gst_cv_monotonic_clock=yes
 417     ], [
 418       gst_cv_monotonic_clock=no
 419     ])
 420 )
 421
 422 if test "$gst_cv_monotonic_clock" = "yes"; then
 423   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 424   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 1"
 425 else
 426   GST_HAVE_MONOTONIC_CLOCK_DEFINE="#define GST_HAVE_MONOTONIC_CLOCK 0"
 427 fi
 428 AC_SUBST(GST_HAVE_MONOTONIC_CLOCK_DEFINE)
 429 AM_CONDITIONAL(GST_HAVE_MONOTONIC_CLOCK, test "$gst_cv_monotonic_clock" = "yes")
 430
 431 dnl Check for a way to display the function name in debug output
 432 AG_GST_CHECK_FUNCTION
 433
 434 dnl test for register_printf_specifier or register_printf_function
 435 AC_CHECK_FUNCS([register_printf_specifier register_printf_function],
 436     [HAVE_PRINTF_EXTENSION=yes])
 437
 438 if test "$HAVE_PRINTF_EXTENSION" = yes; then
 439   GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"P\""
 440   GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"Q\""
 441   GST_USING_PRINTF_EXTENSION_DEFINE="#define GST_USING_PRINTF_EXTENSION"
 442   AC_DEFINE(HAVE_PRINTF_EXTENSION, 1,
 443       [Defined if we have printf specifier extensions available])
 444 else
 445     GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE="#define GST_PTR_FORMAT \"p\""
 446     GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE="#define GST_SEGMENT_FORMAT \"p\""
 447     GST_USING_PRINTF_EXTENSION_DEFINE="#undef GST_USING_PRINTF_EXTENSION"
 448 fi
 449 AC_SUBST(GST_PRINTF_EXTENSION_POINTER_FORMAT_DEFINE)
 450 AC_SUBST(GST_PRINTF_EXTENSION_SEGMENT_FORMAT_DEFINE)
 451 AC_SUBST(GST_USING_PRINTF_EXTENSION_DEFINE)
 452
 453 dnl test if we have dladdr(); we use it for debugging; see gst/gstinfo.c
 454 save_cflags="$CFLAGS"
 455 CFLAGS="$CFLAGS -D_GNU_SOURCE"
 456 AC_CHECK_LIB(dl, dladdr,
 457    AC_DEFINE(HAVE_DLADDR, 1, [Defined if we have dladdr ()])
 458    LIBS="$LIBS -ldl")
 459 CFLAGS="$save_cflags"
 460
 461 dnl *** checks for socket and nsl libraries ***
 462 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 463 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 464
 465 dnl check for inet_aton()
 466 save_libs="$LIBS"
 467 AC_CHECK_FUNC(inet_aton, ,
 468    AC_CHECK_LIB(nsl, inet_aton, ,
 469       AC_CHECK_LIB(socket, inet_aton, ,
 470          AC_CHECK_LIB(resolv, inet_aton, ,[AC_DEFINE(NO_INET_ATON, 1, [Define if you have no native inet_aton() function.])]))))
 471 INET_ATON_LIBS=$LIBS
 472 AC_SUBST(INET_ATON_LIBS)
 473 LIBS="$save_libs"
 474
 475 dnl *** checks for dependency libraries ***
 476
 477 dnl GLib
 478 GLIB_REQ=2.16
 479
 480 AG_GST_GLIB_CHECK([$GLIB_REQ])
 481
 482 dnl FIXME: 0.11: Guess we need to keep this around until 0.11
 483 GST_HAVE_GLIB_2_8_DEFINE="#define GST_HAVE_GLIB_2_8 1"
 484 AC_SUBST(GST_HAVE_GLIB_2_8_DEFINE)
 485
 486 dnl Check for glib2 without extra fat, useful for the unversioned tool frontends
 487 PKG_CHECK_MODULES(GLIB_ONLY, glib-2.0 >= $GLIB_REQ)
 488
 489 dnl Check for documentation xrefs
 490 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 491 AC_SUBST(GLIB_PREFIX)
 492
 493 dnl libxml 2 is optional in some cases
 494 if test "x$GST_DISABLE_LOADSAVE" = "xyes" -a "x$GST_DISABLE_REGISTRY" = "xyes"
 495 then
 496   AC_MSG_NOTICE([XML registry and load/save are disabled, not checking for libxml2])
 497   GST_DISABLE_XML_DEFINE="#define GST_DISABLE_XML 1"
 498 else
 499   dnl check for libxml2 with minimum req version
 500   AG_GST_LIBXML2_CHECK(2.4.9)
 501   GST_DISABLE_XML_DEFINE="/* #undef GST_DISABLE_XML */"
 502 fi
 503 AC_SUBST(GST_DISABLE_XML_DEFINE)
 504
 505 dnl check for "check", unit testing library/header
 506 if test "$cross_compiling" != yes; then
 507   AM_PATH_CHECK(0.9.2,
 508       HAVE_CHECK=yes,
 509       HAVE_CHECK=no)
 510 else
 511   HAVE_CHECK=no
 512 fi
 513 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 514
 515 dnl pkg-config check that for libcheck that works for cross-compiling
 516 dnl but not normal compilation on Fedora & Ubuntu:
 517 dnl PKG_CHECK_MODULES(CHECK, check >= 0.9.2,
 518 dnl   AM_CONDITIONAL(HAVE_CHECK, true),
 519 dnl   AM_CONDITIONAL(HAVE_CHECK, false)
 520 dnl )
 521
 522 dnl *** set variables based on configure arguments
 523
 524 dnl set license and copyright notice
 525 GST_LICENSE="LGPL"
 526 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 527 AC_SUBST(GST_LICENSE)
 528
 529 dnl define LIBDIR, GST_DATADIR so we can inform people where we live
 530 AS_AC_EXPAND(LIBDIR, $libdir)
 531 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [library dir])
 532 AS_AC_EXPAND(DATADIR, $datadir)
 533 AC_DEFINE_UNQUOTED(GST_DATADIR, "$DATADIR", [data dir])
 534
 535 dnl set location of plugin directory
 536 AG_GST_SET_PLUGINDIR
 537
 538 dnl FIXME: add LIBXML_PKG here if we use it
 539 GST_PKG_DEPS="glib-2.0, gobject-2.0, gmodule-no-export-2.0, gthread-2.0"
 540 AC_SUBST(GST_PKG_DEPS)
 541
 542 dnl define an ERROR_CFLAGS Makefile variable
 543 AG_GST_SET_ERROR_CFLAGS($GST_GIT)
 544
 545 dnl define correct level for debugging messages
 546 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 547
 548 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 549
 550 dnl Overview:
 551 dnl GST_OPTION_CFLAGS:  common cflags for profiling, debugging, errors, ...
 552 dnl GST_ALL_*:          vars shared by all built objects
 553 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 554 dnl GST_OBJ_*:          additional vars to link to the core library
 555 dnl                     include GST_ALL_*
 556 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 557 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 558
 559 dnl GST_OPTION_CFLAGS
 560 if test "x$USE_DEBUG" = xyes; then
 561    PROFILE_CFLAGS="-g"
 562 fi
 563 AC_SUBST(PROFILE_CFLAGS)
 564
 565 # GST_DISABLE_DEPRECATED: hide the visibility of deprecated
 566 # functionality from the API that gstreamer uses
 567 # GST_REMOVE_DEPRECATED: don't compile deprecated functionality (breaks ABI)
 568 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 569   dnl Define _only_ when compiling from git (not for pre-releases or releases)
 570   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 571 else
 572   DEPRECATED_CFLAGS=""
 573 fi
 574 AC_SUBST(DEPRECATED_CFLAGS)
 575
 576 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time via e.g.
 577 dnl make DEPRECATED_CFLAGS=''
 578 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 579 AC_SUBST(GST_OPTION_CFLAGS)
 580
 581 dnl GST_ALL_*
 582 dnl vars common to for all internal objects (core libs, elements, applications)
 583 dnl CFLAGS:
 584 dnl - XML needs to be added because xmlPtr is used in core
 585 dnl - src and build dirs need to be added because every piece that gets built
 586 dnl   will need the GStreamer source and generated headers
 587 dnl LIBS: XML doesn't need to be added because we don't explicitly use symbols
 588 dnl       from LibXML except for in the core library
 589 GST_ALL_CFLAGS="-I\$(top_srcdir)/libs -I\$(top_srcdir) -I\$(top_builddir) $GLIB_CFLAGS $XML_CFLAGS \$(GST_OPTION_CFLAGS)"
 590
 591 dnl FIXME: check if LTLIBINTL is needed everywhere
 592 dnl I presume it is given that it contains the symbols that _() stuff maps to
 593 GST_ALL_LIBS="$GLIB_LIBS $LTLIBINTL \$(GCOV_LIBS)"
 594
 595 dnl LDFLAGS really should only contain flags, not libs - they get added before
 596 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 597 GST_ALL_LDFLAGS="-no-undefined"
 598
 599 AC_SUBST(GST_ALL_CFLAGS)
 600 AC_SUBST(GST_ALL_LIBS)
 601 AC_SUBST(GST_ALL_LDFLAGS)
 602
 603 dnl GST_LIB_LDFLAGS
 604 dnl linker flags shared by all libraries
 605 dnl LDFLAGS modifier defining exported symbols from built libraries
 606 GST_LIB_LDFLAGS="-export-symbols-regex \^[_]*\(gst_\|Gst\|GST_\).*"
 607 AC_SUBST(GST_LIB_LDFLAGS)
 608 dnl Version of the linker flags specifically for libgstcheck to support the boonky extra symbols it exports.
 609 GST_CHECK_LIB_LDFLAGS="-export-symbols-regex \^\([_]*\(gst_\|Gst\|GST_\).*\|check_\(debug\|mutex\|cond\)\|buffers\|mutex\|start_cond\|sync_cond\|thread_list\)$"
 610 dnl HACK: add non-portable --export-dynamic if we have GNU ld (needed on my debian stable, tpm)
 611 if test "x$ac_cv_prog_gnu_ld" = "xyes" -o "x$acl_cv_prog_gnu_ld" = "xyes" ; then
 612   GST_CHECK_LIB_LDFLAGS="-Wl,--export-dynamic $GST_CHECK_LIB_LDFLAGS"
 613 fi
 614 AC_SUBST(GST_CHECK_LIB_LDFLAGS)
 615
 616 dnl GST_OBJ_*
 617 dnl default vars for all internal objects built on libgstreamer
 618 dnl includes GST_ALL_*
 619 GST_OBJ_CFLAGS="\$(GST_ALL_CFLAGS)"
 620 GST_OBJ_LIBS="\$(top_builddir)/gst/libgstreamer-$GST_MAJORMINOR.la \$(GST_ALL_LIBS)"
 621 AC_SUBST(GST_OBJ_CFLAGS)
 622 AC_SUBST(GST_OBJ_LIBS)
 623
 624 dnl GST_PLUGIN_LDFLAGS
 625 dnl LDFLAGS for plugins; includes GST_ALL_LDFLAGS
 626 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 627 AC_SUBST(GST_PLUGIN_LDFLAGS, "$GST_PLUGIN_LDFLAGS")
 628
 629 SHAVE_INIT([common],[enable])
 630
 631 AC_CONFIG_FILES(
 632 Makefile
 633 common/shave
 634 common/shave-libtool
 635 gst/Makefile
 636 gst/gstconfig.h
 637 gst/gstversion.h
 638 gst/parse/Makefile
 639 libs/Makefile
 640 libs/gst/Makefile
 641 libs/gst/base/Makefile
 642 libs/gst/check/Makefile
 643 libs/gst/controller/Makefile
 644 libs/gst/dataprotocol/Makefile
 645 libs/gst/net/Makefile
 646 plugins/Makefile
 647 plugins/indexers/Makefile
 648 plugins/elements/Makefile
 649 po/Makefile.in
 650 tests/Makefile
 651 tests/benchmarks/Makefile
 652 tests/check/Makefile
 653 tests/misc/Makefile
 654 tests/examples/Makefile
 655 tests/examples/adapter/Makefile
 656 tests/examples/controller/Makefile
 657 tests/examples/stepping/Makefile
 658 tests/examples/helloworld/Makefile
 659 tests/examples/launch/Makefile
 660 tests/examples/manual/Makefile
 661 tests/examples/metadata/Makefile
 662 tests/examples/queue/Makefile
 663 tests/examples/streams/Makefile
 664 tests/examples/typefind/Makefile
 665 tests/examples/xml/Makefile
 666 tools/Makefile
 667 common/Makefile
 668 common/m4/Makefile
 669 docs/Makefile
 670 docs/design/Makefile
 671 docs/faq/Makefile
 672 docs/gst/Makefile
 673 docs/gst/gstreamer.types
 674 docs/libs/Makefile
 675 docs/plugins/Makefile
 676 docs/manual/Makefile
 677 docs/pwg/Makefile
 678 docs/slides/Makefile
 679 docs/xsl/Makefile
 680 docs/version.entities
 681 pkgconfig/Makefile
 682 stamp.h
 683 pkgconfig/gstreamer.pc
 684 pkgconfig/gstreamer-uninstalled.pc
 685 pkgconfig/gstreamer-base.pc
 686 pkgconfig/gstreamer-base-uninstalled.pc
 687 pkgconfig/gstreamer-check.pc
 688 pkgconfig/gstreamer-check-uninstalled.pc
 689 pkgconfig/gstreamer-controller.pc
 690 pkgconfig/gstreamer-controller-uninstalled.pc
 691 pkgconfig/gstreamer-dataprotocol.pc
 692 pkgconfig/gstreamer-dataprotocol-uninstalled.pc
 693 pkgconfig/gstreamer-net.pc
 694 pkgconfig/gstreamer-net-uninstalled.pc
 695 gst-element-check.m4
 696 gstreamer.spec
 697 )
 698
 699 dnl Create the config.h file for Visual Studio builds
 700 dnl Beware of spaces and /'s in some of the shell variable contents.
 701 sed \
 702     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 703     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 704     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 705     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 706     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 707     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 708     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 709     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 710     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 711     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 712     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 713     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 714     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 715     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 716     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 717     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 718     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 719     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 720     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 721     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 722     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 723     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 724     -e 's/.* PACKAGE$/#define PACKAGE "gstreamer"/' \
 725     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 726     -e 's/.* PACKAGE_NAME$/#define PACKAGE_NAME "'$PACKAGE_NAME'"/' \
 727     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 728     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 729     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 730     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
 731     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 732     config.h.in >win32/common/config.h-new
 733
 734 AC_OUTPUT
 735
 736 dnl negate for output
 737 if test "x${GST_DISABLE_GST_DEBUG}" = "xno"; then enable_gst_debug="yes"; fi
 738 if test "x${GST_DISABLE_LOADSAVE}" = "xno"; then enable_loadsave="yes"; fi
 739 if test "x${GST_DISABLE_PARSE}" = "xno"; then enable_parse="yes"; fi
 740 if test "x${GST_DISABLE_OPTION_PARSING}" = "xno"; then enable_option_parsing="yes"; fi
 741 if test "x${GST_DISABLE_TRACE}" = "xno"; then enable_trace="yes"; fi
 742 if test "x${GST_DISABLE_ALLOC_TRACE}" = "xno"; then enable_alloc_trace="yes"; fi
 743 if test "x${GST_DISABLE_PLUGIN}" = "xno"; then enable_plugin="yes"; fi
 744 if test "x${GST_DISABLE_REGISTRY}" = "xno"; then enable_registry="yes"; fi
 745 if test "x${GST_DISABLE_NET}" = "xno"; then enable_net="yes"; fi
 746
 747 echo "
 748
 749 Configuration
 750         Version                    : ${VERSION}
 751         Source code location       : ${srcdir}
 752         Prefix                     : ${prefix}
 753         Compiler                   : ${SHAVE_SAVED_CC}
 754         Package name               : ${GST_PACKAGE_NAME}
 755         Package origin             : ${GST_PACKAGE_ORIGIN}
 756
 757         Documentation (manuals)    : ${enable_docbook}
 758         Documentation (API)        : ${enable_gtk_doc}
 759
 760         Debug Logging              : ${enable_gst_debug}
 761         Pipeline XML load/save     : ${enable_loadsave}
 762         Command-line parser        : ${enable_parse}
 763         Option parsing in gst_init : ${enable_option_parsing}
 764         Tracing subsystem          : ${enable_trace}
 765         Allocation tracing         : ${enable_alloc_trace}
 766         Plugin registry            : ${enable_registry}
 767         Plugin support             : ${enable_plugin}
 768         Network support            : ${enable_net}
 769
 770         Debug                      : ${USE_DEBUG}
 771         Profiling                  : ${USE_PROFILING}
 772
 773         Building examples          : ${BUILD_EXAMPLES}
 774         Building test apps         : ${BUILD_TESTS}
 775         Building tests that fail   : ${BUILD_FAILING_TESTS}
 776 "