configure.ac

   1 AC_PREREQ([2.68])
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/pre
   8 AC_INIT([GStreamer Good Plug-ins],[1.1.0.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer],[gst-plugins-good])
   9
  10 AG_GST_INIT
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_GIT="no", GST_GIT="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  23
  24 dnl define the output header for config
  25 AC_CONFIG_HEADERS([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE([enable])
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl use pretty build output with automake >= 1.11
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  35   [AM_DEFAULT_VERBOSITY=1
  36    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  37
  38 dnl our libraries and install dirs use GST_API_VERSION in the filename
  39 dnl to allow side-by-side installation of different API versions
  40 GST_API_VERSION=1.0
  41 AC_SUBST(GST_API_VERSION)
  42 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  43   [GStreamer API Version])
  44
  45 AG_GST_LIBTOOL_PREPARE
  46 AS_LIBTOOL(GST, 2, 0, 2)
  47
  48 dnl *** required versions of GStreamer stuff ***
  49 GST_REQ=1.1.0
  50 GSTPB_REQ=1.1.0
  51
  52 dnl *** autotools stuff ****
  53
  54 dnl allow for different autotools
  55 AS_AUTOTOOLS_ALTERNATE
  56
  57 dnl Add parameters for aclocal
  58 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  59
  60 dnl set up gettext
  61 dnl the version check needs to stay here because autopoint greps for it
  62 AM_GNU_GETTEXT_VERSION([0.17])
  63 AM_GNU_GETTEXT([external])
  64 AG_GST_GETTEXT([gst-plugins-good-$GST_API_VERSION])
  65
  66 dnl *** check for arguments to configure ***
  67
  68 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  69
  70 AG_GST_ARG_DEBUG
  71 AG_GST_ARG_PROFILING
  72 AG_GST_ARG_VALGRIND
  73 AG_GST_ARG_GCOV
  74
  75 AG_GST_ARG_EXAMPLES
  76
  77 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  78 AG_GST_ARG_WITH_PACKAGE_NAME
  79 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  80
  81 AG_GST_ARG_WITH_PLUGINS
  82
  83 AG_GST_ARG_ENABLE_EXTERNAL
  84
  85 AG_GST_ARG_ENABLE_EXPERIMENTAL
  86
  87 dnl *** checks for platform ***
  88
  89 dnl * hardware/architecture *
  90
  91 dnl common/m4/gst-arch.m4
  92 dnl check CPU type
  93 AG_GST_ARCH
  94
  95 dnl Determine endianness
  96 AC_C_BIGENDIAN
  97
  98 dnl *** checks for programs ***
  99
 100 dnl find a compiler
 101 AC_PROG_CC
 102 AC_PROG_CC_STDC
 103
 104 dnl determine c++ compiler
 105 AC_PROG_CXX
 106 dnl determine if c++ is available on this system
 107 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 108
 109 dnl determine c++ preprocessor
 110 dnl FIXME: do we need this ?
 111 AC_PROG_CXXCPP
 112
 113 AC_PROG_OBJC
 114
 115 dnl check if the compiler supports '-c' and '-o' options
 116 AM_PROG_CC_C_O
 117
 118 dnl find an assembler
 119 AM_PROG_AS
 120
 121 dnl check if the compiler supports do while(0) macros
 122 AG_GST_CHECK_DOWHILE_MACROS
 123
 124 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 125 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 126
 127 dnl check for documentation tools
 128 GTK_DOC_CHECK([1.12])
 129 AG_GST_PLUGIN_DOCS([1.12])
 130
 131 dnl *** checks for libraries ***
 132
 133 dnl check for libm, for sin()
 134 LT_LIB_M
 135 AC_SUBST(LIBM)
 136
 137 AC_CHECK_FUNCS(clock_gettime, [], [
 138   AC_CHECK_LIB(rt, clock_gettime, [
 139     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 140     LIBRT="-lrt"
 141     AC_SUBST([LIBRT])
 142   ])
 143 ])
 144
 145 dnl *** checks for header files ***
 146
 147 dnl check if we have ANSI C header files
 148 AC_HEADER_STDC
 149
 150 dnl used by ext/wavpack
 151 AX_CREATE_STDINT_H
 152
 153 dnl used in gst/udp
 154 AC_CHECK_HEADERS([sys/time.h])
 155
 156 dnl used in gst/udp
 157 AC_CHECK_HEADERS([sys/socket.h])
 158
 159 dnl *** checks for types/defines ***
 160
 161 dnl Check for FIONREAD ioctl declaration.  This check is needed
 162 dnl for the UDP plugin to build on Solaris
 163 GST_CHECK_FIONREAD
 164
 165 dnl *** checks for structures ***
 166
 167 dnl *** checks for compiler characteristics ***
 168
 169 dnl check if we have GCC inline-asm
 170 AS_GCC_INLINE_ASSEMBLY([HAVE_GCC_ASM=yes], [HAVE_GCC_ASM=no])
 171 if test x$HAVE_GCC_ASM = xyes ; then
 172   AC_DEFINE(HAVE_GCC_ASM, 1,
 173     [Define if compiler supports gcc inline assembly])
 174 fi
 175 AM_CONDITIONAL(HAVE_GCC_ASM, test "x$HAVE_GCC_ASM" = "xyes")
 176
 177 dnl *** checks for library functions ***
 178
 179 LIBS_SAVE=$LIBS
 180 LIBS="$LIBS $LIBM"
 181 AC_CHECK_FUNCS(rint sinh cosh asinh fpclass)
 182 LIBS=$LIBS_SAVE
 183
 184 dnl Check whether isinf() is defined by math.h
 185 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
 187 if test "$ac_cv_have_isinf" = "yes"
 188 then
 189     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
 190 fi
 191
 192 dnl Check for mmap (needed by electricfence plugin)
 193 AC_FUNC_MMAP
 194 AM_CONDITIONAL(GST_HAVE_MMAP, test "x$ac_cv_func_mmap_fixed_mapped" = "xyes")
 195
 196 dnl Check for mmap (needed by electricfence plugin)
 197
 198 AC_CHECK_TYPE([struct ip_mreqn], [
 199               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
 200               [#include <netinet/in.h>])
 201
 202 dnl *** checks for dependency libraries ***
 203
 204
 205 dnl GLib
 206 GLIB_REQ=2.32.0
 207 AG_GST_GLIB_CHECK([$GLIB_REQ])
 208
 209 dnl Orc
 210 ORC_CHECK([0.4.17])
 211
 212 dnl checks for gstreamer
 213 dnl uninstalled is selected preferentially -- see pkg-config(1)
 214 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 215 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 216 AG_GST_CHECK_GST_CONTROLLER($GST_API_VERSION, [$GST_REQ], yes)
 217 AG_GST_CHECK_GST_NET($GST_API_VERSION, [$GST_REQ], yes)
 218 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 219 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 220
 221 GST_TOOLS_DIR=`$PKG_CONFIG --variable=toolsdir gstreamer-$GST_API_VERSION`
 222 if test -z $GST_TOOLS_DIR; then
 223   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 224 fi
 225 AC_SUBST(GST_TOOLS_DIR)
 226
 227 AC_MSG_NOTICE(Using GStreamer Core Plugins in $GST_PLUGINS_DIR)
 228 AC_MSG_NOTICE(Using GStreamer Base Plugins in $GSTPB_PLUGINS_DIR)
 229
 230 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 231
 232 dnl Check for documentation xrefs
 233 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 234 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 235 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 236 AC_SUBST(GLIB_PREFIX)
 237 AC_SUBST(GST_PREFIX)
 238 AC_SUBST(GSTPB_PREFIX)
 239
 240 dnl GTK is optional and used in examples
 241 HAVE_GTK=no
 242 GTK_REQ=3.0.0
 243 if test "x$BUILD_EXAMPLES" = "xyes"; then
 244   PKG_CHECK_MODULES(GTK, gtk+-3.0 >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 245   dnl some examples need gtk+-x11
 246   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-3.0 >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 247   AC_SUBST(GTK_LIBS)
 248   AC_SUBST(GTK_CFLAGS)
 249 fi
 250 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 251 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 252
 253 dnl *** set variables based on configure arguments ***
 254
 255 dnl set license and copyright notice
 256 GST_LICENSE="LGPL"
 257 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 258 AC_SUBST(GST_LICENSE)
 259
 260 dnl set location of plugin directory
 261 AG_GST_SET_PLUGINDIR
 262
 263 dnl set release date/time
 264 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 265   ["${srcdir}/gst-plugins-good.doap"],
 266   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 267
 268 # set by AG_GST_PARSE_SUBSYSTEM_DISABLES above
 269 dnl make sure it doesn't complain about unused variables if debugging is disabled
 270 NO_WARNINGS=""
 271 AG_GST_CHECK_GST_DEBUG_DISABLED([NO_WARNINGS="-Wno-unused"], [NO_WARNINGS=""])
 272
 273 dnl define an ERROR_CFLAGS Makefile variable
 274 dnl -Wundef: too many broken headers
 275 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 276       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 277       -Wwrite-strings -Wold-style-definition -Waggregate-return
 278       -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 279       -Wnested-externs $NO_WARNINGS])
 280
 281 dnl define an ERROR_CXXFLAGS Makefile variable
 282 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 283         -Wmissing-declarations -Wredundant-decls
 284         -Wwrite-strings
 285         -Winit-self -Wmissing-include-dirs -Waddress -Wno-multichar
 286         $NO_WARNINGS])
 287
 288 dnl define an ERROR_OBJCFLAGS Makefile variable
 289 AG_GST_SET_ERROR_OBJCFLAGS($FATAL_WARNINGS, [
 290       -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 291       -Wwrite-strings -Wold-style-definition
 292       -Winit-self -Wmissing-include-dirs -Wno-multichar
 293       -Wnested-externs $NO_WARNINGS])
 294
 295 dnl define correct level for debugging messages
 296 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 297
 298 dnl used in examples
 299 AG_GST_DEFAULT_ELEMENTS
 300
 301 dnl *** plug-ins to include ***
 302
 303 dnl Non ported plugins (non-dependant, then dependant)
 304 dnl Make sure you have a space before and after all plugins
 305 GST_PLUGINS_NONPORTED="osx_audio "
 306 AC_SUBST(GST_PLUGINS_NONPORTED)
 307
 308 dnl these are all the gst plug-ins, compilable without additional libs
 309 dnl videofilter is at the top because others depend on it
 310 AG_GST_CHECK_PLUGIN(alpha)
 311 AG_GST_CHECK_PLUGIN(apetag)
 312 AG_GST_CHECK_PLUGIN(audiofx)
 313 AG_GST_CHECK_PLUGIN(audioparsers)
 314 AG_GST_CHECK_PLUGIN(auparse)
 315 AG_GST_CHECK_PLUGIN(autodetect)
 316 AG_GST_CHECK_PLUGIN(avi)
 317 AG_GST_CHECK_PLUGIN(cutter)
 318 AG_GST_CHECK_PLUGIN(debugutils)
 319 AG_GST_CHECK_PLUGIN(deinterlace)
 320 AG_GST_CHECK_PLUGIN(dtmf)
 321 AG_GST_CHECK_PLUGIN(effectv)
 322 AG_GST_CHECK_PLUGIN(equalizer)
 323 AG_GST_CHECK_PLUGIN(flv)
 324 AG_GST_CHECK_PLUGIN(flx)
 325 AG_GST_CHECK_PLUGIN(goom)
 326 AG_GST_CHECK_PLUGIN(goom2k1)
 327 AG_GST_CHECK_PLUGIN(icydemux)
 328 AG_GST_CHECK_PLUGIN(id3demux)
 329 AG_GST_CHECK_PLUGIN(imagefreeze)
 330 AG_GST_CHECK_PLUGIN(interleave)
 331 AG_GST_CHECK_PLUGIN(isomp4)
 332 AG_GST_CHECK_PLUGIN(law)
 333 AG_GST_CHECK_PLUGIN(level)
 334 AG_GST_CHECK_PLUGIN(matroska)
 335 AG_GST_CHECK_PLUGIN(monoscope)
 336 AG_GST_CHECK_PLUGIN(multifile)
 337 AG_GST_CHECK_PLUGIN(multipart)
 338 AG_GST_CHECK_PLUGIN(replaygain)
 339 AG_GST_CHECK_PLUGIN(rtp)
 340 AG_GST_CHECK_PLUGIN(rtpmanager)
 341 AG_GST_CHECK_PLUGIN(rtsp)
 342 AG_GST_CHECK_PLUGIN(shapewipe)
 343 AG_GST_CHECK_PLUGIN(smpte)
 344 AG_GST_CHECK_PLUGIN(spectrum)
 345 AG_GST_CHECK_PLUGIN(udp)
 346 AG_GST_CHECK_PLUGIN(videobox)
 347 AG_GST_CHECK_PLUGIN(videocrop)
 348 AG_GST_CHECK_PLUGIN(videofilter)
 349 AG_GST_CHECK_PLUGIN(videomixer)
 350 AG_GST_CHECK_PLUGIN(wavenc)
 351 AG_GST_CHECK_PLUGIN(wavparse)
 352 AG_GST_CHECK_PLUGIN(y4m)
 353
 354 dnl disable experimental plug-ins
 355 if test "x$BUILD_EXPERIMENTAL" != "xyes"; then
 356   AG_GST_DISABLE_PLUGIN(monoscope)
 357 fi
 358
 359 dnl *** sys plug-ins ***
 360
 361 echo
 362 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 363 echo
 364
 365 dnl DirectSound
 366 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRECTSOUND, true)
 367 AG_GST_CHECK_FEATURE(DIRECTSOUND, [DirectSound plug-in], directsoundsink, [
 368   HAVE_DIRECTSOUND="no"
 369   save_CFLAGS="$CFLAGS"
 370   save_LDFLAGS="$LDFLAGS"
 371   save_LIBS="$LIBS"
 372   CFLAGS="$CFLAGS $DIRECTSOUND_CFLAGS"
 373   LDFLAGS="$LDFLAGS $DIRECTSOUND_LDFLAGS"
 374   LIBS="$LIBS -ldsound -ldxerr9 -luser32"
 375   AC_MSG_CHECKING(for DirectSound LDFLAGS)
 376   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 377 #include <windows.h>
 378 #include <dxerr9.h>
 379 #include <dsound.h>
 380 ]], [[
 381   DXGetErrorString9 (0);
 382   DirectSoundCreate(NULL, NULL, NULL);
 383 ]])
 384 ],
 385     [HAVE_DIRECTSOUND="yes"],
 386     [HAVE_DIRECTSOUND="no"])
 387   AC_MSG_RESULT($HAVE_DIRECTSOUND)
 388   CFLAGS=$save_CFLAGS
 389   LDFLAGS=$save_LDFLAGS
 390   LIBS=$save_LIBS
 391
 392   if test "x$HAVE_DIRECTSOUND" = "xyes";  then
 393     dnl this is much more than we want
 394     DIRECTSOUND_LIBS="-ldsound -ldxerr9 -luser32"
 395     AC_SUBST(DIRECTSOUND_CFLAGS)
 396     AC_SUBST(DIRECTSOUND_LDFLAGS)
 397     AC_SUBST(DIRECTSOUND_LIBS)
 398   fi
 399   AC_SUBST(HAVE_DIRECTSOUND)
 400 ])
 401
 402 dnl *** Win32 WaveOut ***
 403 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVEFORM, true)
 404 AG_GST_CHECK_FEATURE(WAVEFORM, [Win32 WaveForm], waveformsink, [
 405   AC_CHECK_HEADER(mmsystem.h, HAVE_WAVEFORM="yes", HAVE_WAVEFORM="no", [#include <windows.h>])
 406 ])
 407
 408 dnl *** OSS audio *** (Linux, *BSD)
 409 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 410 AG_GST_CHECK_FEATURE(OSS, [OSS audio], ossaudio, [
 411  HAVE_OSS="yes"
 412 dnl Linux and newer BSD versions :
 413  AC_CHECK_HEADER(sys/soundcard.h, [
 414    AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 415    ] , [
 416 dnl Some old BSD versions and also newer OpenBSD versions :
 417    AC_CHECK_HEADER(soundcard.h, [
 418      AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 419      ], [
 420   dnl Some old BSD versions :
 421      AC_CHECK_HEADER(machine/soundcard.h, [
 422        AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,,
 423          [Define if OSS includes are in /machine/])
 424        ], [
 425        HAVE_OSS="no"
 426      ])
 427    ])
 428  ])
 429 ])
 430
 431 dnl *** oss4 ***
 432 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS4, true)
 433 AG_GST_CHECK_FEATURE(OSS4, [Open Sound System 4], oss4, [
 434   AC_MSG_CHECKING([Checking if we can build the OSS4 elements])
 435   AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/stat.h sys/types.h],
 436       [test -z "$OSS4_MISSING_HEADER" && HAVE_OSS4="yes"],
 437       [OSS4_MISSING_HEADER="yes";HAVE_OSS4="no"])
 438 ])
 439
 440 dnl *** Sun Audio ***
 441 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 442 AG_GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudio, [
 443   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 444 ])
 445
 446 dnl *** OSX Audio ***
 447 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 448 have_ios="no"
 449 AG_GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudio, [
 450   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 451     HAVE_OSX_AUDIO="yes",
 452     dnl *** Check for the iOS headers ***
 453     [AC_CHECK_HEADER(CoreAudio/CoreAudioTypes.h,
 454       [HAVE_OSX_AUDIO="YES";have_ios="yes"], HAVE_OSX_AUDIO="no"
 455     )])
 456 ])
 457 if test "x$have_ios" = "xyes"; then
 458   AC_DEFINE(HAVE_IOS, 1, [building for iOS platofrm])
 459 fi
 460 AM_CONDITIONAL(HAVE_IOS, test "x$have_ios" = "xyes")
 461
 462 dnl *** OS X video ***
 463 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 464 HAVE_OSX_VIDEO="no"
 465 AG_GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 466   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 467 ])
 468 dnl in case header OpenGL/gl.h is found on other platforms
 469 case "$host" in
 470   *-*darwin*)
 471     dnl do nothing
 472     ;;
 473   *)
 474     HAVE_OSX_VIDEO="no"
 475     ;;
 476 esac
 477
 478
 479 dnl *** Video 4 Linux 2 ***
 480 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 481 dnl renamed to GST_V4L2 because of some conflict with kernel headers
 482 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L2, true)
 483 AG_GST_CHECK_FEATURE(GST_V4L2, [Video 4 Linux 2], v4l2src, [
 484   AC_MSG_CHECKING([Checking for up to date v4l2 installation])
 485   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 486 #include <sys/types.h>
 487 #ifdef __sun /* Solaris */
 488 #include <sys/types.h>
 489 #include <sys/videodev2.h>
 490 #elif __FreeBSD__
 491 #include <linux/videodev2.h>
 492 #else /* Linux */
 493 #include <linux/types.h>
 494 #define _LINUX_TIME_H
 495 #define __user
 496 #include <linux/videodev2.h>
 497 #endif
 498 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 499 #error too early v4l2 version or no v4l2 at all
 500 #endif
 501     ]], [[
 502 return 0;
 503     ]])],[
 504       HAVE_GST_V4L2="yes"
 505       AC_MSG_RESULT(yes)
 506     ],[
 507       HAVE_GST_V4L2="no"
 508       AC_MSG_RESULT(no)
 509
 510       HAVE_VIDEODEV=no
 511       AC_CHECK_HEADER(linux/videodev2.h, [ HAVE_VIDEODEV=yes ],
 512       [
 513         AC_CHECK_HEADER(sys/videodev2.h, [ HAVE_VIDEODEV=yes ])
 514       ])
 515
 516       if test "x$HAVE_VIDEODEV" = "xyes"; then
 517         AC_MSG_WARN([video4linux2 headers were found, but they're old.])
 518         AC_MSG_WARN([Please update v4l2 to compile the v4l2 plugins])
 519       else
 520         AC_MSG_WARN([video4linux2 was not found])
 521       fi
 522     ])
 523
 524   if [ test x$HAVE_GST_V4L2 = xyes ]; then
 525     dnl check for missing v4l2_buffer declaration (see #135919)
 526     MISSING_DECL=0
 527     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 528     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 529 #include <sys/types.h>
 530 #ifdef __sun /* Solaris */
 531 #include <sys/types.h>
 532 #include <sys/videodev2.h>
 533 #elif __FreeBSD__
 534 #include <linux/videodev2.h>
 535 #else /* Linux */
 536 #include <linux/types.h>
 537 #define _LINUX_TIME_H
 538 #define __user
 539 #include <linux/videodev2.h>
 540 #endif
 541     ]], [[
 542 struct v4l2_buffer buf;
 543 buf.index = 0;
 544 return 0;
 545     ]])],[ AC_MSG_RESULT(yes) ],[ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 546     if [ test x$MISSING_DECL = x1 ]; then
 547       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 548     fi
 549
 550     dnl check for XOverlay libraries
 551     AG_GST_CHECK_XV
 552   fi
 553 ])
 554
 555 # Optional gudev for device probing
 556 AC_ARG_WITH([gudev],
 557   AS_HELP_STRING([--with-gudev],[device detection with gudev]),
 558   [],
 559   [with_gudev=check])
 560 if test x$HAVE_GST_V4L2 = xyes; then
 561   if test x$with_gudev != xno; then
 562       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 563           [ have_gudev=yes
 564             AC_DEFINE(HAVE_GUDEV, 1,
 565                [Whether gudev is available for device detection])
 566             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 567           ], [
 568           have_gudev=no
 569           ])
 570   else
 571     have_gudev=no
 572   fi
 573 fi
 574 AC_SUBST(GUDEV_CFLAGS)
 575 AC_SUBST(GUDEV_LIBS)
 576
 577 # Make libv4l2 non-automagic
 578 AC_ARG_WITH([libv4l2],
 579   AS_HELP_STRING([--with-libv4l2],[support video buffer conversion using libv4l2]),
 580   [],
 581   [with_libv4l2=check])
 582 if test x$HAVE_GST_V4L2 = xyes; then
 583   if test x$with_libv4l2 != xno; then
 584       PKG_CHECK_MODULES(LIBV4L2, libv4l2,
 585           [ have_libv4l2=yes
 586             AC_DEFINE(HAVE_LIBV4L2, 1,
 587                 [Whether libv4l2 is available for video buffer conversion])
 588           ], [
 589           have_libv4l2=no
 590           ])
 591   else
 592     have_libv4l2=no
 593   fi
 594 fi
 595
 596 # Check if v4l2 support dmabuf
 597 if test x$HAVE_GST_V4L2 = xyes; then
 598         AC_CHECK_DECLS(V4L2_MEMORY_DMABUF,,,[
 599                                         #include <sys/types.h>
 600                                         #ifdef __sun /* Solaris */
 601                                         #include <sys/types.h>
 602                                         #include <sys/videodev2.h>
 603                                         #elif __FreeBSD__
 604                                         #include <linux/videodev2.h>
 605                                         #else /* Linux */
 606                                         #include <linux/types.h>
 607                                         #define _LINUX_TIME_H
 608                                         #define __user
 609                                         #include <linux/videodev2.h>
 610                                         #endif
 611                                         ])
 612 fi
 613
 614 dnl Check for X11
 615 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 616 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 617                   [ximagesrc], [
 618   AC_PATH_XTRA
 619
 620   dnl now try to find the HEADER
 621   ac_cflags_save="$CFLAGS"
 622   ac_cppflags_save="$CPPFLAGS"
 623   CFLAGS="$CFLAGS $X_CFLAGS"
 624   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 625   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 626
 627   if test "x$HAVE_X" = "xno"
 628   then
 629     AC_MSG_NOTICE([cannot find X11 development files])
 630   else
 631     dnl this is much more than we want
 632     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 633     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 634     dnl it does not add the libs; therefore we add them here
 635     X_LIBS="$X_LIBS -lX11"
 636     AC_SUBST(X_CFLAGS)
 637     AC_SUBST(X_LIBS)
 638
 639     dnl check for Xfixes
 640     PKG_CHECK_MODULES(XFIXES, xfixes, HAVE_XFIXES="yes", HAVE_XFIXES="no")
 641     if test "x$HAVE_XFIXES" = "xyes"
 642     then
 643         XFIXES_CFLAGS="-DHAVE_XFIXES $XFIXES_CFLAGS"
 644     fi
 645     AC_SUBST(XFIXES_LIBS)
 646     AC_SUBST(XFIXES_CFLAGS)
 647
 648     dnl check for Xdamage
 649     PKG_CHECK_MODULES(XDAMAGE, xdamage, HAVE_XDAMAGE="yes", HAVE_XDAMAGE="no")
 650     if test "x$HAVE_XDAMAGE" = "xyes"
 651     then
 652         XDAMAGE_CFLAGS="-DHAVE_XDAMAGE $XDAMAGE_CFLAGS"
 653     fi
 654     AC_SUBST(XDAMAGE_LIBS)
 655     AC_SUBST(XDAMAGE_CFLAGS)
 656   fi
 657   AC_SUBST(HAVE_X)
 658   CFLAGS="$ac_cflags_save"
 659   CPPFLAGS="$ac_cppflags_save"
 660 ])
 661
 662 dnl FIXME: this should be rolled into the test above, it's just an additional
 663 dnl feature of the ximagesrc plug-in
 664 dnl This is the same as in gst-plugins-base
 665 dnl check for X Shm
 666 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 667 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 668   if test x$HAVE_X = xyes; then
 669     AC_CHECK_LIB(Xext, XShmAttach,
 670                  HAVE_XSHM="yes", HAVE_XSHM="no",
 671                  $X_LIBS)
 672     if test "x$HAVE_XSHM" = "xyes"; then
 673       XSHM_LIBS="-lXext"
 674     else
 675       dnl On AIX, it is in XextSam instead, but we still need -lXext
 676       AC_CHECK_LIB(XextSam, XShmAttach,
 677                    HAVE_XSHM="yes", HAVE_XSHM="no",
 678                    $X_LIBS)
 679       if test "x$HAVE_XSHM" = "xyes"; then
 680         XSHM_LIBS="-lXext -lXextSam"
 681       fi
 682     fi
 683   fi
 684 ], ,[
 685   AC_SUBST(HAVE_XSHM)
 686   AC_SUBST(XSHM_LIBS)
 687 ])
 688
 689 dnl for V4L2, we also need to know if we have XVIDEO
 690 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 691 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 692                   [], [
 693   AG_GST_CHECK_XV
 694 ])
 695
 696 dnl *** ext plug-ins ***
 697 dnl keep this list sorted alphabetically !
 698
 699 if test "x$BUILD_EXTERNAL" = "xyes"; then
 700
 701 echo
 702 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 703 echo
 704
 705 dnl *** aalib ***
 706 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 707 AG_GST_CHECK_FEATURE(AALIB, [aalib ASCII Art library], aasink, [
 708   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 709   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 710 ])
 711
 712 dnl *** cairo ***
 713 translit(dnm, m, l) AM_CONDITIONAL(USE_CAIRO, true)
 714 AG_GST_CHECK_FEATURE(CAIRO, [Cairo graphics rendering and gobject bindings], cairo, [
 715   AG_GST_PKG_CHECK_MODULES(CAIRO, cairo >= 1.10.0 cairo-gobject >= 1.10.0)
 716 ])
 717
 718 dnl *** FLAC ***
 719 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 720 AG_GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flac, [
 721   AG_GST_PKG_CHECK_MODULES(FLAC, flac >= 1.1.4)
 722 ])
 723
 724 dnl *** GDK pixbuf ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 726 AG_GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbuf, [
 727   AG_GST_PKG_CHECK_MODULES(GDK_PIXBUF, gdk-pixbuf-2.0 >= 2.8.0)
 728 ])
 729
 730 dnl *** Jack ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
 732 AG_GST_CHECK_FEATURE(JACK, Jack, jack, [
 733   PKG_CHECK_MODULES(JACK, jack >= 0.99.10, HAVE_JACK="yes", HAVE_JACK="no")
 734   AC_SUBST(JACK_CFLAGS)
 735   AC_SUBST(JACK_LIBS)
 736
 737   AG_GST_PKG_CHECK_MODULES(JACK_0_120_1, jack >= 0.120.1 jack < 1.0)
 738   if test x$HAVE_JACK_0_120_1 = xyes; then
 739     AC_DEFINE(HAVE_JACK_0_120_1, 1, [defined if jack >= 0.120.1 is available])
 740   fi
 741   AG_GST_PKG_CHECK_MODULES(JACK_1_9_7, jack >= 1.9.7)
 742   if test x$HAVE_JACK_1_9_7 = xyes; then
 743     AC_DEFINE(HAVE_JACK_1_9_7, 1, [defined if jack >= 1.9.7 is available])
 744   fi
 745
 746 ])
 747
 748 dnl *** jpeg ***
 749 dnl FIXME: we could use header checks here as well IMO
 750 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
 751 AG_GST_CHECK_FEATURE(JPEG, [jpeg library], jpeg, [
 752   AC_ARG_WITH(jpeg-mmx,
 753     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
 754   OLD_LIBS="$LIBS"
 755   if test x$with_jpeg_mmx != x; then
 756     LIBS="$LIBS -L$with_jpeg_mmx"
 757   fi
 758   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 759   JPEG_LIBS="$LIBS -ljpeg-mmx"
 760   LIBS="$OLD_LIBS"
 761   if test x$HAVE_JPEG != xyes; then
 762     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
 763     JPEG_LIBS="-ljpeg"
 764   fi
 765   AC_SUBST(JPEG_LIBS)
 766 ])
 767
 768 dnl *** libcaca ***
 769 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
 770 AG_GST_CHECK_FEATURE(LIBCACA, [libcaca coloured ASCII art], cacasink, [
 771   AG_GST_PKG_CHECK_MODULES(LIBCACA, caca)
 772 ])
 773
 774 dnl *** libdv ***
 775 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
 776 AG_GST_CHECK_FEATURE(LIBDV, [libdv DV demuxer/decoder], dv, [
 777   AG_GST_PKG_CHECK_MODULES(LIBDV, libdv >= 0.100)
 778 ])
 779
 780 dnl *** libpng ***
 781 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
 782 AG_GST_CHECK_FEATURE(LIBPNG, [Portable Network Graphics library], png, [
 783   AG_GST_PKG_CHECK_MODULES(LIBPNG, libpng >= 1.2)
 784 ])
 785
 786 dnl *** pulseaudio ***
 787 translit(dnm, m, l) AM_CONDITIONAL(USE_PULSE, true)
 788 AG_GST_CHECK_FEATURE(PULSE, [pulseaudio plug-in], pulseaudio, [
 789
 790   dnl used in ext/pulse/pulseutil.c
 791   AC_CHECK_HEADERS([process.h])
 792
 793   AG_GST_PKG_CHECK_MODULES(PULSE, libpulse >= 1.0)
 794 ])
 795
 796 dnl *** dv1394 ***
 797 translit(dnm, m, l) AM_CONDITIONAL(USE_DV1394, true)
 798 AG_GST_CHECK_FEATURE(DV1394, [raw1394 and avc1394 library], 1394, [
 799   dnl first test for libraw1394 >= 2.0.0
 800   AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 2.0.0)
 801   AG_GST_PKG_CHECK_MODULES(LIBIEC61883, libiec61883 >= 1.0.0)
 802   dnl now see how far we got
 803   if test x$HAVE_RAW1394 = xyes && \
 804      test x$HAVE_LIBIEC61883 = xyes; then
 805        AG_GST_CHECK_LIBHEADER(AVC1394,
 806         avc1394, avc1394_send_command, $RAW1394_LIBS,
 807         libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 808        AG_GST_CHECK_LIBHEADER(ROM1394,
 809         rom1394, rom1394_free_directory, $RAW1394_LIBS,
 810         libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 811        if test x$HAVE_AVC1394 = xyes && \
 812           test x$HAVE_AVC1394 = xyes && \
 813           test x$HAVE_ROM1394 = xyes; then
 814           HAVE_DV1394=yes
 815           DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS $LIBIEC61883_LIBS"
 816           DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 817           AC_SUBST(DV1394_CFLAGS)
 818           AC_SUBST(DV1394_LIBS)
 819         fi
 820   else
 821        if test x$HAVE_RAW1394 = xno; then
 822           AG_GST_PKG_CHECK_MODULES(RAW1394, libraw1394 >= 1.1.0)
 823           AG_GST_CHECK_LIBHEADER(AVC1394,
 824            avc1394, avc1394_send_command, $RAW1394_LIBS,
 825            libavc1394/avc1394.h, AVC1394_LIBS="-lavc1394")
 826           AG_GST_CHECK_LIBHEADER(ROM1394,
 827            rom1394, rom1394_free_directory, $RAW1394_LIBS,
 828            libavc1394/rom1394.h, ROM1394_LIBS="-lrom1394")
 829           if test x$HAVE_RAW1394 = xyes && \
 830              test x$HAVE_AVC1394 = xyes && \
 831              test x$HAVE_ROM1394 = xyes; then
 832              HAVE_DV1394=yes
 833              DV1394_LIBS="$RAW1394_LIBS $AVC1394_LIBS $ROM1394_LIBS"
 834              DV1394_CFLAGS="$RAW1394_CFLAGS"
 835              if test x$HAVE_LIBIEC61883 = xyes; then
 836                DV1394_CFLAGS="$RAW1394_CFLAGS $LIBIEC61883_CFLAGS -DHAVE_LIBIEC61883"
 837                DV1394_LIBS="$DV1394_LIBS $LIBIEC61883_LIBS"
 838              fi
 839              AC_SUBST(DV1394_CFLAGS)
 840              AC_SUBST(DV1394_LIBS)
 841            fi
 842          fi
 843   fi
 844 ])
 845 AM_CONDITIONAL(USE_LIBIEC61883, [ test "x${HAVE_LIBIEC61883}" = xyes ] )
 846
 847 dnl *** shout2 ***
 848 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
 849 AG_GST_CHECK_FEATURE(SHOUT2, [Shoutcast/Icecast client library], shout2, [
 850   AG_GST_PKG_CHECK_MODULES(SHOUT2, shout >= 2.0)
 851 ])
 852
 853 dnl *** soup ***
 854 translit(dnm, m, l) AM_CONDITIONAL(USE_SOUP, true)
 855 AG_GST_CHECK_FEATURE(SOUP, [soup http client plugin (2.4)], souphttpsrc, [
 856   PKG_CHECK_MODULES(SOUP, libsoup-2.4 >= 2.26.1, [HAVE_SOUP="yes"], [HAVE_SOUP="no"])
 857   AC_SUBST(SOUP_CFLAGS)
 858   AC_SUBST(SOUP_LIBS)
 859 ])
 860
 861 dnl *** speex >= 1.0.4 or >= 1.1.5 ***
 862 dnl   1.1.4 and earlier were not API/ABI compatible with 1.0
 863 dnl   1.1.6 is the first to use a .pc/pkg-config file ***
 864 dnl   speex_jitter.h is 1.1.x only
 865 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
 866 AG_GST_CHECK_FEATURE(SPEEX, [speex speech codec], speex, [
 867   AG_GST_PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6)
 868   if test $HAVE_SPEEX = no
 869   then
 870     AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex/speex.h, [
 871       AC_CHECK_HEADER(speex/speex_jitter.h, [
 872         dnl speex 1.1.x :
 873         AG_GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex/speex.h, [
 874           dnl speex 1.1.5 or + :
 875           HAVE_SPEEX="yes"
 876           SPEEX_LIBS="-lspeex"
 877           AC_SUBST(SPEEX_CFLAGS)
 878           AC_SUBST(SPEEX_LIBS)
 879         ],[
 880           HAVE_SPEEX="no"
 881         ])
 882       ],[
 883         dnl speex 1.0.x :
 884           AC_CHECK_DECL(SPEEX_GET_LOOKAHEAD, [
 885             dnl speex 1.0.4
 886             HAVE_SPEEX="yes"
 887             SPEEX_LIBS="-lspeex"
 888             AC_SUBST(SPEEX_CFLAGS)
 889             AC_SUBST(SPEEX_LIBS)
 890
 891             AC_DEFINE_UNQUOTED(SPEEX_1_0, 1,
 892               [defined if speex 1.0.x API detected])
 893         ],[
 894             HAVE_SPEEX="no"
 895             AC_MSG_NOTICE(You need at least 1.0.4 to compile the speex plugin)
 896         ], [
 897 #include <speex/speex.h>
 898         ])
 899       ])
 900     ])
 901   fi
 902 ])
 903
 904 dnl *** taglib ***
 905 translit(dnm, m, l) AM_CONDITIONAL(USE_TAGLIB, true)
 906 AG_GST_CHECK_FEATURE(TAGLIB, [taglib tagging library], taglib, [
 907   AG_GST_PKG_CHECK_MODULES(TAGLIB, taglib >= 1.5)
 908   if test "x$HAVE_CXX" != "xyes"; then
 909     USE_TAGLIB=false
 910     AC_MSG_NOTICE([Not building taglib plugin: no C++ compiler found])
 911   else
 912     dnl work around bug in taglib 1.5 headers, remove once there is a 1.6
 913     AS_CXX_COMPILER_FLAG([-Wno-attributes], [
 914         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS -Wno-attributes"
 915       ], [
 916         TAGLIB_CXXFLAGS="$TAGLIB_CFLAGS"
 917     ])
 918     AC_SUBST(TAGLIB_CXXFLAGS)
 919   fi
 920 ])
 921
 922 dnl *** vpx ***
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_VPX, vpx)
 924 AG_GST_CHECK_FEATURE(VPX, [VPX decoder], vpx, [
 925   PKG_CHECK_MODULES(VPX, vpx >= 1.1.0, [HAVE_VPX="yes"], [HAVE_VPX="no"])
 926
 927   if test $HAVE_VPX = "yes"; then
 928     OLD_LIBS="$LIBS"
 929     OLD_CFLAGS="$CFLAGS"
 930     CFLAGS="$CFLAGS $VPX_CFLAGS"
 931     LIBS="$LIBS $VPX_LIBS"
 932     AC_CHECK_LIB(vpx, vpx_codec_vp8_cx_algo, [
 933       HAVE_VP8=yes
 934       AC_DEFINE(HAVE_VP8_ENCODER, 1, [Defined if the VP8 encoder is available])
 935     ])
 936     AC_CHECK_LIB(vpx, vpx_codec_vp8_dx_algo, [
 937       HAVE_VP8=yes
 938       AC_DEFINE(HAVE_VP8_DECODER, 1, [Defined if the VP8 decoder is available])
 939     ])
 940     LIBS="$OLD_LIBS"
 941     CFLAGS="$OLD_CFLAGS"
 942   fi
 943   AC_SUBST(VPX_LIBS)
 944   AC_SUBST(VPX_CFLAGS)
 945 ])
 946
 947 dnl *** wavpack ***
 948 translit(dnm, m, l) AM_CONDITIONAL(USE_WAVPACK, true)
 949 AG_GST_CHECK_FEATURE(WAVPACK, [wavpack plug-in], wavpack, [
 950   PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.40.0, HAVE_WAVPACK=yes, [
 951     PKG_CHECK_MODULES(WAVPACK, wavpack >= 4.20, [
 952       HAVE_WAVPACK=yes
 953       AC_DEFINE(WAVPACK_OLD_API, 1, [old wavpack API])
 954     ],[
 955       HAVE_WAVPACK=no
 956     ])
 957   ])
 958   AC_SUBST(WAVPACK_CFLAGS)
 959   AC_SUBST(WAVPACK_LIBS)
 960 ])
 961
 962 dnl *** qtdemux & matroska prefer to have zlib ***
 963 translit(dnm, m, l) AM_CONDITIONAL(USE_ZLIB, true)
 964 AG_GST_CHECK_FEATURE(ZLIB, [zlib support for qtdemux/matroska],, [
 965   AG_GST_CHECK_LIBHEADER(ZLIB,
 966     z, uncompress,, zlib.h, [
 967     HAVE_ZLIB="yes"
 968     ZLIB_LIBS="-lz"
 969     AC_SUBST(ZLIB_LIBS)
 970   ])
 971 ])
 972
 973 dnl *** matroska prefers to have bz2 ***
 974 translit(dnm, m, l) AM_CONDITIONAL(USE_BZ2, true)
 975 AG_GST_CHECK_FEATURE(BZ2, [bz2 library for matroska ],, [
 976   AG_GST_CHECK_LIBHEADER(BZ2, bz2, BZ2_bzCompress, ,bzlib.h, BZ2_LIBS="-lbz2")
 977   AC_SUBST(BZ2_LIBS)
 978 ])
 979
 980 else
 981
 982 dnl not building plugins with external dependencies,
 983 dnl but we still need to set the conditionals
 984 AM_CONDITIONAL(USE_AALIB, false)
 985 AM_CONDITIONAL(USE_BZ2, false)
 986 AM_CONDITIONAL(USE_CAIRO, false)
 987 AM_CONDITIONAL(USE_DIRECTSOUND, false)
 988 AM_CONDITIONAL(USE_DV1394, false)
 989 AM_CONDITIONAL(USE_FLAC, false)
 990 AM_CONDITIONAL(USE_GDK_PIXBUF, false)
 991 AM_CONDITIONAL(USE_GST_V4L2, false)
 992 AM_CONDITIONAL(USE_JACK, false)
 993 AM_CONDITIONAL(USE_JPEG, false)
 994 AM_CONDITIONAL(USE_LIBCACA, false)
 995 AM_CONDITIONAL(USE_LIBDV, false)
 996 AM_CONDITIONAL(USE_LIBIEC61883, false)
 997 AM_CONDITIONAL(USE_LIBPNG, false)
 998 AM_CONDITIONAL(USE_OSS, false)
 999 AM_CONDITIONAL(USE_OSS4, false)
1000 AM_CONDITIONAL(USE_OSX_AUDIO, false)
1001 AM_CONDITIONAL(USE_OSX_VIDEO, false)
1002 AM_CONDITIONAL(USE_PULSE, false)
1003 AM_CONDITIONAL(USE_SHOUT2, false)
1004 AM_CONDITIONAL(USE_SOUP, false)
1005 AM_CONDITIONAL(USE_SPEEX, false)
1006 AM_CONDITIONAL(USE_SUNAUDIO, false)
1007 AM_CONDITIONAL(USE_TAGLIB, false)
1008 AM_CONDITIONAL(USE_VPX, false)
1009 AM_CONDITIONAL(USE_WAVEFORM, false)
1010 AM_CONDITIONAL(USE_WAVPACK, false)
1011 AM_CONDITIONAL(USE_X, false)
1012 AM_CONDITIONAL(USE_XSHM, false)
1013 AM_CONDITIONAL(USE_XVIDEO, false)
1014 AM_CONDITIONAL(USE_ZLIB, false)
1015
1016 fi dnl of EXT plugins
1017
1018 dnl *** finalize CFLAGS, LDFLAGS, LIBS
1019
1020 dnl Overview:
1021 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
1022 dnl GST_*:              flags shared by all built objects
1023 dnl GST_ALL_LDFLAGS:    linker flags shared by all
1024 dnl GST_LIB_LDFLAGS:    not needed, we don't install libraries
1025 dnl GST_LT_LDFLAGS:     library versioning of our libraries
1026 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
1027
1028 dnl GST_OPTION_CFLAGS
1029 if test "x$USE_DEBUG" = xyes; then
1030    PROFILE_CFLAGS="-g"
1031 fi
1032 AC_SUBST(PROFILE_CFLAGS)
1033
1034 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
1035   dnl Define _only_ for git (not pre-releases or releases)
1036   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
1037 else
1038   DEPRECATED_CFLAGS=""
1039 fi
1040 AC_SUBST(DEPRECATED_CFLAGS)
1041
1042 dnl every flag in GST_OPTION_CFLAGS, GST_OPTION_CXXFLAGS and GST_OPTION_OBJCFLAGS can be overridden
1043 dnl at make time with e.g. make ERROR_CFLAGS=""
1044 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1045 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1046 GST_OPTION_OBJCFLAGS="\$(WARNING_OBJCFLAGS) \$(ERROR_OBJCFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
1047 AC_SUBST(GST_OPTION_CFLAGS)
1048 AC_SUBST(GST_OPTION_CXXFLAGS)
1049 AC_SUBST(GST_OPTION_OBJCFLAGS)
1050
1051 dnl our libraries need to be versioned correctly
1052 AC_SUBST(GST_LT_LDFLAGS)
1053
1054 dnl FIXME: do we want to rename to GST_ALL_* ?
1055 dnl prefer internal headers to already installed ones
1056 dnl also add builddir include for enumtypes and marshal
1057 dnl add ERROR_CFLAGS, but overridable
1058 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
1059 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
1060 GST_OBJCFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_OBJCFLAGS)"
1061 GST_CFLAGS="-I\$(top_srcdir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
1062 AC_SUBST(GST_CFLAGS)
1063 AC_SUBST(GST_CXXFLAGS)
1064 AC_SUBST(GST_OBJCFLAGS)
1065 AC_SUBST(GST_LIBS)
1066
1067 dnl LDFLAGS really should only contain flags, not libs - they get added before
1068 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1069 GST_ALL_LDFLAGS="-no-undefined"
1070 AC_SUBST(GST_ALL_LDFLAGS)
1071
1072 dnl this really should only contain flags, not libs - they get added before
1073 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
1074 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
1075 AC_SUBST(GST_PLUGIN_LDFLAGS)
1076
1077 dnl *** output files ***
1078
1079 dnl keep this alphabetic per directory, please
1080 AC_CONFIG_FILES(
1081 Makefile
1082 gst/Makefile
1083 gst/alpha/Makefile
1084 gst/apetag/Makefile
1085 gst/audiofx/Makefile
1086 gst/audioparsers/Makefile
1087 gst/auparse/Makefile
1088 gst/autodetect/Makefile
1089 gst/avi/Makefile
1090 gst/cutter/Makefile
1091 gst/deinterlace/Makefile
1092 gst/dtmf/Makefile
1093 gst/debugutils/Makefile
1094 gst/effectv/Makefile
1095 gst/equalizer/Makefile
1096 gst/flv/Makefile
1097 gst/goom/Makefile
1098 gst/goom2k1/Makefile
1099 gst/id3demux/Makefile
1100 gst/icydemux/Makefile
1101 gst/imagefreeze/Makefile
1102 gst/interleave/Makefile
1103 gst/isomp4/Makefile
1104 gst/law/Makefile
1105 gst/level/Makefile
1106 gst/matroska/Makefile
1107 gst/monoscope/Makefile
1108 gst/multifile/Makefile
1109 gst/multipart/Makefile
1110 gst/replaygain/Makefile
1111 gst/rtp/Makefile
1112 gst/rtpmanager/Makefile
1113 gst/rtsp/Makefile
1114 gst/shapewipe/Makefile
1115 gst/smpte/Makefile
1116 gst/spectrum/Makefile
1117 gst/udp/Makefile
1118 gst/videobox/Makefile
1119 gst/videocrop/Makefile
1120 gst/videofilter/Makefile
1121 gst/videomixer/Makefile
1122 gst/wavenc/Makefile
1123 gst/wavparse/Makefile
1124 gst/flx/Makefile
1125 gst/y4m/Makefile
1126 ext/Makefile
1127 ext/aalib/Makefile
1128 ext/cairo/Makefile
1129 ext/dv/Makefile
1130 ext/flac/Makefile
1131 ext/gdk_pixbuf/Makefile
1132 ext/jack/Makefile
1133 ext/jpeg/Makefile
1134 ext/libcaca/Makefile
1135 ext/libpng/Makefile
1136 ext/pulse/Makefile
1137 ext/raw1394/Makefile
1138 ext/shout2/Makefile
1139 ext/soup/Makefile
1140 ext/speex/Makefile
1141 ext/taglib/Makefile
1142 ext/vpx/Makefile
1143 ext/wavpack/Makefile
1144 sys/Makefile
1145 sys/directsound/Makefile
1146 sys/oss/Makefile
1147 sys/oss4/Makefile
1148 sys/osxaudio/Makefile
1149 sys/osxvideo/Makefile
1150 sys/sunaudio/Makefile
1151 sys/v4l2/Makefile
1152 sys/waveform/Makefile
1153 sys/ximage/Makefile
1154 po/Makefile.in
1155 tests/Makefile
1156 tests/check/Makefile
1157 tests/examples/Makefile
1158 tests/examples/audiofx/Makefile
1159 tests/examples/cairo/Makefile
1160 tests/examples/equalizer/Makefile
1161 tests/examples/jack/Makefile
1162 tests/examples/level/Makefile
1163 tests/examples/pulse/Makefile
1164 tests/examples/rtp/Makefile
1165 tests/examples/shapewipe/Makefile
1166 tests/examples/spectrum/Makefile
1167 tests/examples/v4l2/Makefile
1168 tests/files/Makefile
1169 tests/icles/Makefile
1170 common/Makefile
1171 common/m4/Makefile
1172 m4/Makefile
1173 docs/Makefile
1174 docs/plugins/Makefile
1175 docs/version.entities
1176 pkgconfig/Makefile
1177 pkgconfig/gstreamer-plugins-good-uninstalled.pc
1178 gst-plugins-good.spec
1179 )
1180
1181 dnl Create the config.h file for Visual Studio builds
1182 dnl Beware of spaces and /'s in some of the shell variable contents.
1183 sed \
1184     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1185     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1186     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1187     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1188     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1189     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
1190     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1191     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1192     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1193     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1194     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1195     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1196     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1197     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1198     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1199     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1200     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1201     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1202     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1203     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1204     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1205     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1206     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1207     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1208     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1209     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1210     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1211     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1212     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
1213     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1214     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1215     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1216     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
1217     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
1218     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1219     config.h.in >win32/common/config.h-new
1220
1221 AC_OUTPUT
1222
1223 AG_GST_OUTPUT_PLUGINS
1224 ORC_OUTPUT
1225