configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [45])
  34 m4_define([glib_micro_version], [3])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADERS([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS:+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114 AC_USE_SYSTEM_EXTENSIONS
 115
 116 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 117
 118 AC_CANONICAL_HOST
 119
 120 dnl
 121
 122 AC_MSG_CHECKING([for Win32])
 123 LIB_EXE_MACHINE_FLAG=X86
 124 case "$host" in
 125   *-*-mingw*)
 126     glib_native_win32=yes
 127     glib_pid_type='void *'
 128     glib_cv_stack_grows=no
 129     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 130     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 131     # (Sorry, I don't know exactly what is the problem, but it is related to
 132     # floating point formatting and decimal point vs. comma.)
 133     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 134     # rigorous enough to notice, though.
 135     # So preset the autoconf cache variables.
 136     ac_cv_func_vsnprintf_c99=no
 137     ac_cv_func_snprintf_c99=no
 138     case "$host" in
 139     x86_64-*-*)
 140       LIB_EXE_MACHINE_FLAG=X64
 141       ;;
 142     esac
 143
 144     AC_DEFINE([_WIN32_WINNT], [0x0501], [Target the Windows XP API])
 145     ;;
 146   *)
 147     glib_native_win32=no
 148     glib_pid_type=int
 149     ;;
 150 esac
 151 case $host in
 152   *-*-linux*)
 153     glib_os_linux=yes
 154     ;;
 155 esac
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158
 159 AC_MSG_CHECKING([for the Android])
 160 case $host in
 161   *android*)
 162     glib_native_android="yes"
 163     ;;
 164   *)
 165     glib_native_android="no"
 166     ;;
 167 esac
 168 AC_MSG_RESULT([$glib_native_android])
 169
 170 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 171
 172 glib_have_carbon=no
 173 AC_MSG_CHECKING([for Mac OS X Carbon support])
 174 AC_TRY_CPP([
 175 #include <Carbon/Carbon.h>
 176 #include <CoreServices/CoreServices.h>
 177 ], glib_have_carbon=yes)
 178
 179 AC_MSG_RESULT([$glib_have_carbon])
 180
 181 glib_have_cocoa=no
 182 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 183 AC_TRY_CPP([
 184 #include <Cocoa/Cocoa.h>
 185 #ifdef GNUSTEP_BASE_VERSION
 186 #error "Detected GNUstep, not Cocoa"
 187 #endif
 188 ], glib_have_cocoa=yes)
 189
 190 AC_MSG_RESULT([$glib_have_cocoa])
 191
 192 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 193 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 194 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 195 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 196 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 197 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 198
 199 AS_IF([test "$glib_native_win32" = "yes"], [
 200   AC_CHECK_TOOL(WINDRES, windres, no)
 201   if test "$WINDRES" = no; then
 202     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 203   fi
 204   AC_CHECK_TOOL(NM, nm, no)
 205   if test "$NM" = no; then
 206     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 207   fi
 208   AC_CHECK_TOOL(RANLIB, ranlib, :)
 209   AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 210   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 211 ])
 212 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 213
 214 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 215   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 216   CARBON_LIBS="-Wl,-framework,Carbon"
 217   LDFLAGS="$LDFLAGS $CARBON_LIBS"
 218 ], [CARBON_LIBS=""])
 219
 220 AC_SUBST([CARBON_LIBS])
 221
 222 AS_IF([test "x$glib_have_cocoa" = "xyes"], [
 223   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 224   COCOA_LIBS="-Wl,-framework,Foundation"
 225   LDFLAGS="$LDFLAGS $COCOA_LIBS"
 226
 227   osx_version=`sw_vers -productVersion`
 228   osx_min_version="10.9.0"
 229   AC_MSG_CHECKING([OSX version >= $osx_min_version])
 230   AS_VERSION_COMPARE([$osx_version], [$osx_min_version], [
 231     AC_MSG_RESULT([no])
 232     AC_MSG_ERROR([OSX version is too old!])
 233   ])
 234   AC_MSG_RESULT([yes])
 235 ], [COCOA_LIBS=""])
 236
 237 AC_SUBST([COCOA_LIBS])
 238
 239 dnl declare --enable-* args and collect ac_help strings
 240 AC_ARG_ENABLE(debug,
 241               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 242                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 243               enable_debug=glib_debug_default)
 244
 245 AC_ARG_ENABLE(gc_friendly,
 246               [AS_HELP_STRING([--enable-gc-friendly],
 247                               [turn on garbage collector friendliness [default=no]])],,
 248               [enable_gc_friendly=no])
 249 AC_ARG_ENABLE(mem_pools,
 250               [AS_HELP_STRING([--disable-mem-pools],
 251                               [disable all glib memory pools])],,
 252               [disable_mem_pools=no])
 253 AC_ARG_ENABLE(rebuilds,
 254               [AS_HELP_STRING([--disable-rebuilds],
 255                               [disable all source autogeneration rules])],,
 256               [enable_rebuilds=yes])
 257
 258 GLIB_TESTS
 259
 260 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 261 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 262   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 263   AC_MSG_RESULT([yes])
 264 ], [ AC_MSG_RESULT([no]) ])
 265
 266 AC_MSG_CHECKING([whether to disable memory pools])
 267 AS_IF([test "x$disable_mem_pools" = "xno"], [
 268   AC_MSG_RESULT([no])
 269 ], [
 270   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 271   AC_MSG_RESULT([yes])
 272 ])
 273
 274 dnl location to install runtime libraries, e.g. ../../lib to install
 275 dnl to /lib if libdir is /usr/lib
 276 AC_ARG_WITH(runtime-libdir,
 277            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 278                            [install runtime libraries relative to libdir])],
 279            [],
 280            [with_runtime_libdir=""])
 281 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 282 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 283 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 284 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 285 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 286
 287 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 288 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 289 AC_LANG_SAVE
 290 AC_LANG_CPLUSPLUS
 291 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 292 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 293 AC_LANG_RESTORE
 294
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test "x$cflags_set" != "x" ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # option to specify python interpreter to use; this just sets $PYTHON, so that
 383 # we will fallback to reading $PYTHON if --with-python is not given, and
 384 # python.m4 will get the expected input
 385 AC_ARG_WITH(python,
 386             AS_HELP_STRING([--with-python=PATH],
 387                            [Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
 388             [PYTHON="$withval"], [])
 389 if test x"$PYTHON" = xyes; then
 390   AC_MSG_ERROR([--with-python option requires a path or program argument])
 391 fi
 392 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 393
 394
 395 dnl ***********************
 396 dnl *** Tests for iconv ***
 397 dnl ***********************
 398 dnl
 399 dnl We do this before the gettext checks, to avoid distortion
 400
 401 dnl On Windows we use a native implementation
 402
 403 AS_IF([ test x"$glib_native_win32" = xyes], [
 404   with_libiconv=native
 405 ], [
 406   AC_ARG_WITH(libiconv,
 407               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 408                               [use the libiconv library])],,
 409               [with_libiconv=maybe])
 410
 411   found_iconv=no
 412   case $with_libiconv in
 413     maybe)
 414       # Check in the C library first
 415       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 416       # Check if we have GNU libiconv
 417       if test $found_iconv = "no"; then
 418         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 419       fi
 420       # Check if we have a iconv in -liconv, possibly from vendor
 421       if test $found_iconv = "no"; then
 422         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 423       fi
 424       ;;
 425     no)
 426       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 427       ;;
 428     gnu|yes)
 429       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 430       ;;
 431     native)
 432       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 433       ;;
 434   esac
 435
 436   if test "x$found_iconv" = "xno" ; then
 437      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 438   fi
 439 ])
 440
 441 dnl
 442 dnl zlib support
 443 dnl
 444 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 445 AS_IF([test "x$found_zlib" = "xno"], [
 446   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 447   if test "x$found_zlib" = "xno" ; then
 448     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 449   fi
 450   ZLIB_LIBS='-lz'
 451   AC_SUBST(ZLIB_LIBS)
 452 ])
 453
 454 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 455 AC_SUBST(LIBFFI_CFLAGS)
 456 AC_SUBST(LIBFFI_LIBS)
 457
 458 dnl
 459 dnl gettext support
 460 dnl
 461
 462 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 463 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 464 GLIB_GNU_GETTEXT
 465
 466 if test "$gt_cv_have_gettext" != "yes" ; then
 467   AC_MSG_ERROR([
 468 *** You must have either have gettext support in your C library, or use the
 469 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 470 ])
 471 fi
 472
 473 LIBS="$INTLLIBS $LIBS"
 474
 475 GETTEXT_PACKAGE=glib20
 476 AC_SUBST(GETTEXT_PACKAGE)
 477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 478   [Define the gettext package to be used])
 479
 480 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 481
 482 dnl
 483 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 484 dnl
 485
 486 AS_IF([test x"$glib_native_win32" != xyes], [
 487   if test x$with_libiconv != xno ; then
 488     case " $INTLLIBS " in
 489     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 490     *) ICONV_LIBS="-liconv" ;;
 491     esac
 492   fi
 493 ])
 494 AC_SUBST(ICONV_LIBS)
 495
 496 case $with_libiconv in
 497   gnu)
 498     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 499     ;;
 500   native)
 501     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 502     ;;
 503 esac
 504
 505 dnl Initialize libtool
 506 LT_PREREQ([2.2])
 507 LT_INIT([disable-static win32-dll])
 508 dnl when using libtool 2.x create libtool early, because it's used in configure
 509 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 510
 511
 512 AS_IF([test "$glib_native_win32" = "yes"], [
 513   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 514     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 515   fi
 516   if test x$enable_static = xyes; then
 517     glib_win32_static_compilation=yes
 518     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 519 #define GOBJECT_STATIC_COMPILATION 1"
 520     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 521   fi
 522 ])
 523 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 524
 525 # Checks for library functions.
 526 AC_FUNC_ALLOCA
 527 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 528 AC_CHECK_FUNCS(timegm gmtime_r)
 529
 530 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 531   [AC_TRY_LINK([#include <unistd.h>
 532     extern int __libc_enable_secure;],
 533     [return __libc_enable_secure;],
 534    glib_cv_have_libc_enable_secure=yes,
 535    glib_cv_have_libc_enable_secure=no)])
 536 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 537    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 538      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 539 ])
 540
 541 AC_CHECK_SIZEOF(char)
 542 AC_CHECK_SIZEOF(short)
 543 AC_CHECK_SIZEOF(long)
 544 AC_CHECK_SIZEOF(int)
 545 AC_CHECK_SIZEOF(void *)
 546 AC_CHECK_SIZEOF(long long)
 547 AC_CHECK_SIZEOF(__int64)
 548
 549 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 550   [AC_TRY_LINK([#include <signal.h>
 551      #include <sys/types.h>
 552      sig_atomic_t val = 42;],
 553     [return val == 42 ? 0 : 1],
 554    ac_cv_type_sig_atomic_t=yes,
 555    ac_cv_type_sig_atomic_t=no)])
 556 if test x$ac_cv_type_sig_atomic_t = xyes; then
 557    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 558      [Define if you have the 'sig_atomic_t' type.])
 559 fi
 560
 561 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 562   :
 563 else
 564   AC_MSG_ERROR([
 565 *** GLib requires a 64 bit type. You might want to consider
 566 *** using the GNU C compiler.
 567 ])
 568 fi
 569
 570 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 571         # long long is a 64 bit integer.
 572         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 573         AC_CACHE_VAL(glib_cv_long_long_format,[
 574                 for format in ll q I64; do
 575                   AC_TRY_RUN([#include <stdio.h>
 576                         int main()
 577                         {
 578                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 579                           char buffer[1000];
 580                           sprintf (buffer, "%${format}u", a);
 581                           sscanf (buffer, "%${format}u", &b);
 582                           exit (b!=a);
 583                         }
 584                         ],
 585                         [glib_cv_long_long_format=${format}
 586                         break],
 587                         [],[:])
 588                 done])
 589         AS_IF([ test -n "$glib_cv_long_long_format"], [
 590           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 591           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 592           if test x"$glib_cv_long_long_format" = xI64; then
 593             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 594           fi
 595         ], [AC_MSG_RESULT(none)])
 596 ],[ test x$ac_cv_sizeof___int64 = x8], [
 597         # __int64 is a 64 bit integer.
 598         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 599         # We know this is MSVCRT.DLL, and what the formats are
 600         glib_cv_long_long_format=I64
 601         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 602         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 603         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 604 ])
 605
 606 AC_C_CONST
 607
 608 dnl
 609 dnl check in which direction the stack grows
 610 dnl
 611 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 612         AC_TRY_RUN([
 613         volatile int *a = 0, *b = 0;
 614         void f (int i) { volatile int x = 5; if (i == 0) b = &x; else f (i - 1); }
 615         int main () { volatile int y = 7; a = &y; f (100); return b > a ? 0 : 1; }
 616         ],
 617         glib_cv_stack_grows=yes
 618         ,
 619         glib_cv_stack_grows=no
 620         ,)
 621 ])
 622
 623 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 624 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 625 dnl actually supported.
 626 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 627         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 628         __inline int foo () { return 0; }
 629         int main () { return foo (); }
 630         ]])],
 631         glib_cv_has__inline=yes
 632         ,
 633         glib_cv_has__inline=no
 634         ,)
 635 ])
 636 case x$glib_cv_has__inline in
 637 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 638 esac
 639 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 640         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 641         __inline__ int foo () { return 0; }
 642         int main () { return foo (); }
 643         ]])],
 644         glib_cv_has__inline__=yes
 645         ,
 646         glib_cv_has__inline__=no
 647         ,)
 648 ])
 649 case x$glib_cv_has__inline__ in
 650 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 651 esac
 652 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 653         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 654         #undef inline
 655         inline int foo () { return 0; }
 656         int main () { return foo (); }
 657         ]])],
 658         glib_cv_hasinline=yes
 659         ,
 660         glib_cv_hasinline=no
 661         ,)
 662 ])
 663 case x$glib_cv_hasinline in
 664 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 665 esac
 666
 667 # if we can use inline functions in headers
 668 AC_MSG_CHECKING(if inline functions in headers work)
 669 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 670 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 671 #  undef inline
 672 #  define inline __inline__
 673 #elif !defined (G_HAVE_INLINE)
 674 #  undef inline
 675 #  if defined (G_HAVE___INLINE__)
 676 #    define inline __inline__
 677 #  elif defined (G_HAVE___INLINE)
 678 #    define inline __inline
 679 #  endif
 680 #endif
 681
 682 int glib_test_func2 (int);
 683
 684 static inline int
 685 glib_test_func1 (void) {
 686   return glib_test_func2 (1);
 687 }
 688
 689 int
 690 main (void) {
 691   int i = 1;
 692 }]])],[g_can_inline=yes],[g_can_inline=no])
 693 AC_MSG_RESULT($g_can_inline)
 694
 695 # check for flavours of varargs macros
 696 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 697 AC_TRY_COMPILE([],[
 698 int a(int p1, int p2, int p3);
 699 #define call_a(...) a(1,__VA_ARGS__)
 700 call_a(2,3);
 701 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 702 AC_MSG_RESULT($g_have_iso_c_varargs)
 703
 704 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 705 AS_IF([test "$CXX" = ""], [
 706 dnl No C++ compiler
 707   g_have_iso_cxx_varargs=no
 708 else
 709   AC_LANG_CPLUSPLUS
 710   AC_TRY_COMPILE([],[
 711 int a(int p1, int p2, int p3);
 712 #define call_a(...) a(1,__VA_ARGS__)
 713 call_a(2,3);
 714 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 715   AC_LANG_C
 716 ])
 717 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 718
 719 AC_MSG_CHECKING(for GNUC varargs macros)
 720 AC_TRY_COMPILE([],[
 721 int a(int p1, int p2, int p3);
 722 #define call_a(params...) a(1,params)
 723 call_a(2,3);
 724 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 725 AC_MSG_RESULT($g_have_gnuc_varargs)
 726
 727 # check for GNUC visibility support
 728 AC_MSG_CHECKING(for GNUC visibility attribute)
 729 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 730 void
 731 __attribute__ ((visibility ("hidden")))
 732      f_hidden (void)
 733 {
 734 }
 735 void
 736 __attribute__ ((visibility ("internal")))
 737      f_internal (void)
 738 {
 739 }
 740 void
 741 __attribute__ ((visibility ("protected")))
 742      f_protected (void)
 743 {
 744 }
 745 void
 746 __attribute__ ((visibility ("default")))
 747      f_default (void)
 748 {
 749 }
 750 int main (void)
 751 {
 752         f_hidden();
 753         f_internal();
 754         f_protected();
 755         f_default();
 756         return 0;
 757 }
 758 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 759 AC_MSG_RESULT($g_have_gnuc_visibility)
 760 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 761
 762 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 763 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 764 #else
 765 # include "error: this is not Sun Studio."
 766 #endif
 767 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 768 AC_MSG_RESULT($g_have_sunstudio_visibility)
 769 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 770
 771 # check for bytesex stuff
 772 AC_C_BIGENDIAN
 773 if test x$ac_cv_c_bigendian = xuniversal ; then
 774   AC_MSG_ERROR([Universal builds not supported: see https://bugs.gnome.org/742548])
 775 fi
 776
 777
 778 # check for header files
 779 AC_CHECK_HEADERS([sys/param.h sys/resource.h mach/mach_time.h])
 780 AC_CHECK_HEADERS([sys/select.h stdint.h inttypes.h sched.h malloc.h])
 781 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 782 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 783 AC_CHECK_HEADERS([linux/magic.h sys/prctl.h])
 784
 785 # Some versions of MSC lack these
 786 AC_CHECK_HEADERS([dirent.h sys/time.h])
 787
 788 # We don't care about this, but we need to keep including it in
 789 # glibconfig.h for backward compatibility
 790 AC_CHECK_HEADERS([values.h])
 791
 792 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 793 [#if HAVE_SYS_PARAM_H
 794  #include <sys/param.h>
 795  #endif
 796 ])
 797 AC_CHECK_FUNCS(sysctlbyname)
 798
 799 AC_HEADER_MAJOR
 800 AC_CHECK_HEADERS([xlocale.h])
 801
 802 # check for structure fields
 803 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 804 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 805 #include <sys/stat.h>
 806 #ifdef G_OS_UNIX
 807 #include <unistd.h>
 808 #endif
 809 #ifdef HAVE_SYS_STATFS_H
 810 #include <sys/statfs.h>
 811 #endif
 812 #ifdef HAVE_SYS_PARAM_H
 813 #include <sys/param.h>
 814 #endif
 815 #ifdef HAVE_SYS_MOUNT_H
 816 #include <sys/mount.h>
 817 #endif])
 818 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 819 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 820 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 821 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 822
 823 AC_STRUCT_DIRENT_D_TYPE
 824
 825 # Checks for libcharset
 826 AM_LANGINFO_CODESET
 827 gl_GLIBC21
 828
 829 # check additional type sizes
 830 AC_CHECK_SIZEOF(size_t)
 831
 832 dnl Try to figure out whether gsize should be long or int
 833 AC_MSG_CHECKING([for the appropriate definition for size_t])
 834
 835 case $ac_cv_sizeof_size_t in
 836   $ac_cv_sizeof_short)
 837       glib_size_type=short
 838       ;;
 839   $ac_cv_sizeof_int)
 840       glib_size_type=int
 841       ;;
 842   $ac_cv_sizeof_long)
 843       glib_size_type=long
 844       ;;
 845   $ac_cv_sizeof_long_long)
 846       glib_size_type='long long'
 847       ;;
 848   $ac_cv_sizeof__int64)
 849       glib_size_type='__int64'
 850       ;;
 851   *)  AC_MSG_ERROR([No type matching size_t in size])
 852       ;;
 853 esac
 854
 855 dnl If int/long are the same size, we see which one produces
 856 dnl warnings when used in the location as size_t. (This matters
 857 dnl on AIX with xlc)
 858 dnl
 859 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 860        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 861   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 862 #if defined(_AIX) && !defined(__GNUC__)
 863 #pragma options langlvl=stdc89
 864 #endif
 865 #include <stddef.h>
 866 int main ()
 867 {
 868   size_t s = 1;
 869   unsigned int *size_int = &s;
 870   return (int)*size_int;
 871 }
 872     ]])],glib_size_type=int,
 873       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 874 #if defined(_AIX) && !defined(__GNUC__)
 875 #pragma options langlvl=stdc89
 876 #endif
 877 #include <stddef.h>
 878 int main ()
 879 {
 880    size_t s = 1;
 881    unsigned long *size_long = &s;
 882    return (int)*size_long;
 883 }
 884         ]])],glib_size_type=long)])
 885 ])
 886
 887 AC_MSG_RESULT(unsigned $glib_size_type)
 888
 889 AC_CHECK_SIZEOF(ssize_t)
 890
 891 dnl Try to figure out whether gssize should be long or int
 892 AC_MSG_CHECKING([for the appropriate definition for ssize_t])
 893
 894 case $ac_cv_sizeof_ssize_t in
 895   $ac_cv_sizeof_short)
 896       glib_ssize_type=short
 897       ;;
 898   $ac_cv_sizeof_int)
 899       glib_ssize_type=int
 900       ;;
 901   $ac_cv_sizeof_long)
 902       glib_ssize_type=long
 903       ;;
 904   $ac_cv_sizeof_long_long)
 905       glib_ssize_type='long long'
 906       ;;
 907   $ac_cv_sizeof__int64)
 908       glib_ssize_type='__int64'
 909       ;;
 910   *)  AC_MSG_ERROR([No type matching ssize_t in size])
 911       ;;
 912 esac
 913
 914 dnl If int/long are the same size, we see which one produces
 915 dnl warnings when used in the location as ssize_t. (This matters
 916 dnl on Android where ssize_t is long and size_t is unsigned int)
 917 dnl
 918 AS_IF([test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_int &&
 919        test $ac_cv_sizeof_ssize_t = $ac_cv_sizeof_long], [
 920   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 921 #if defined(_AIX) && !defined(__GNUC__)
 922 #pragma options langlvl=stdc89
 923 #endif
 924 #include <stddef.h>
 925 #ifdef HAVE_INTTYPES_H
 926 # include <inttypes.h>
 927 #endif
 928 #ifdef HAVE_STDINT_H
 929 # include <stdint.h>
 930 #endif
 931 #include <sys/types.h>
 932 int main ()
 933 {
 934   ssize_t s = 1;
 935   int *size_int = &s;
 936   return (int)*size_int;
 937 }
 938     ]])],glib_ssize_type=int,
 939       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 940 #if defined(_AIX) && !defined(__GNUC__)
 941 #pragma options langlvl=stdc89
 942 #endif
 943 #include <stddef.h>
 944 #ifdef HAVE_INTTYPES_H
 945 # include <inttypes.h>
 946 #endif
 947 #ifdef HAVE_STDINT_H
 948 # include <stdint.h>
 949 #endif
 950 #include <sys/types.h>
 951 int main ()
 952 {
 953    ssize_t s = 1;
 954    long *size_long = &s;
 955    return (int)*size_long;
 956 }
 957         ]])],glib_ssize_type=long)])
 958 ])
 959
 960 AC_MSG_RESULT($glib_ssize_type)
 961
 962 # Check for some functions
 963 AC_CHECK_FUNCS(lstat strsignal vsnprintf stpcpy strcasecmp strncasecmp poll vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 964 AC_CHECK_FUNCS(lchmod lchown fchmod fchown utimes getresuid)
 965 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat fallocate)
 966 case $host_os in aix*) ac_cv_func_splice=no ;; esac # AIX splice() is something else
 967 AC_CHECK_FUNCS(splice)
 968 AC_CHECK_FUNCS(prlimit)
 969
 970 # To avoid finding a compatibility unusable statfs, which typically
 971 # successfully compiles, but warns to use the newer statvfs interface:
 972 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 973 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 974
 975 AC_MSG_CHECKING([whether to use statfs or statvfs])
 976 # Some systems have both statfs and statvfs, pick the most "native" for these
 977 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 978    [
 979    # on solaris and irix, statfs doesn't even have the f_bavail field
 980    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 981       [ac_cv_func_statfs=no],
 982    # else, at least on linux, statfs is the actual syscall
 983       [ac_cv_func_statvfs=no])
 984    ])
 985
 986 AS_IF([test x$ac_cv_func_statfs = xyes],
 987       [
 988          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 989          AC_MSG_RESULT([statfs])
 990       ],
 991       [test x$ac_cv_func_statvfs = xyes],
 992       [
 993          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
 994          AC_MSG_RESULT([statvfs])
 995       ],
 996       [  AC_MSG_RESULT([neither])])
 997
 998 AC_CHECK_HEADERS(crt_externs.h)
 999 AC_CHECK_FUNCS(_NSGetEnviron)
1000
1001 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1002
1003 # Internet address families
1004 if test $glib_native_win32 = yes; then
1005   glib_inet_includes=["
1006 #include <winsock2.h>
1007   "]
1008 else
1009   glib_inet_includes=["
1010 #include <sys/types.h>
1011 #include <sys/socket.h>
1012   "]
1013 fi
1014
1015 glib_failed=false
1016 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1017 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1018 # winsock defines this even though it doesn't support it
1019 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1020 if $glib_failed ; then
1021   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1022 fi
1023
1024 glib_failed=false
1025 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1026 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1027 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1028 if $glib_failed ; then
1029   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1030 fi
1031
1032 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex if_indextoname sendmmsg)
1033
1034 AS_IF([test $glib_native_win32 = yes], [
1035   # <wspiapi.h> in the Windows SDK and in mingw-w64 has wrappers for
1036   # inline workarounds for getaddrinfo, getnameinfo and freeaddrinfo if
1037   # they aren't present at run-time (on Windows 2000).
1038   AC_CHECK_HEADER([wspiapi.h], [WSPIAPI_INCLUDE="#include <wspiapi.h>"])
1039   AC_SUBST(WSPIAPI_INCLUDE)
1040 ], [
1041   # Android does not have C_IN in public headers, we define it wherever necessary
1042   AS_IF([test $glib_native_android != yes], [
1043     AC_MSG_CHECKING([if arpa/nameser_compat.h is needed])
1044     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1045                                         #include <arpa/nameser.h>],
1046                                        [int qclass = C_IN;])],
1047                       [AC_MSG_RESULT([no])],
1048                       [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
1049                                                            #include <arpa/nameser.h>
1050                                                            #include <arpa/nameser_compat.h>],
1051                                                           [int qclass = C_IN;])],
1052                                          [AC_MSG_RESULT([yes])
1053                                           NAMESER_COMPAT_INCLUDE="#include <arpa/nameser_compat.h>"],
1054                                          [AC_MSG_ERROR([could not compile test program either way])])])])
1055   AC_SUBST(NAMESER_COMPAT_INCLUDE)
1056
1057   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1058   NETWORK_LIBS=""
1059   AC_MSG_CHECKING([for res_query])
1060   AC_TRY_LINK([#include <sys/types.h>
1061                #include <netinet/in.h>
1062                #include <arpa/nameser.h>
1063                #include <resolv.h>
1064               ],[
1065                res_query("test", 0, 0, (void *)0, 0);
1066               ],[AC_MSG_RESULT([yes])],
1067               [save_libs="$LIBS"
1068                LIBS="-lresolv $LIBS"
1069                AC_TRY_LINK([#include <sys/types.h>
1070                             #include <netinet/in.h>
1071                             #include <arpa/nameser.h>
1072                             #include <resolv.h>
1073                            ],[
1074                             res_query("test", 0, 0, (void *)0, 0);
1075                            ],[AC_MSG_RESULT([in -lresolv])
1076                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1077                            [LIBS="-lbind $save_libs"
1078                             AC_TRY_LINK([#include <resolv.h>],
1079                                         [res_query("test", 0, 0, (void *)0, 0);],
1080                                         [AC_MSG_RESULT([in -lbind])
1081                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1082                                         [AC_MSG_ERROR(not found)])])
1083                LIBS="$save_libs"])
1084   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1085                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1086                                         [AC_MSG_ERROR(Could not find socket())]))
1087   save_libs="$LIBS"
1088   LIBS="$LIBS $NETWORK_LIBS"
1089   AC_MSG_CHECKING([for res_init])
1090   AC_TRY_LINK([#include <sys/types.h>
1091                #include <netinet/in.h>
1092                #include <arpa/nameser.h>
1093                #include <resolv.h>
1094               ],[
1095                res_init();
1096               ],[AC_MSG_RESULT([yes])
1097                  AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if you have the 'res_init' function.])
1098               ],[AC_MSG_RESULT([no])])
1099   LIBS="$save_libs"
1100 ])
1101 AC_SUBST(NETWORK_LIBS)
1102
1103 AC_CHECK_HEADER([linux/netlink.h],
1104                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1105                 [#include <sys/socket.h>])
1106 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1107
1108 AC_CHECK_TYPE([struct ip_mreqn], [
1109               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1110               [#include <netinet/in.h>])
1111
1112 case $host in
1113   *-*-solaris* )
1114      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1116      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1117      ;;
1118 esac
1119
1120 dnl
1121 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1122 dnl
1123 AS_IF([test "$ac_cv_func_statfs" = yes], [
1124   AC_MSG_CHECKING([number of arguments to statfs()])
1125   AC_TRY_COMPILE([#include <unistd.h>
1126   #ifdef HAVE_SYS_PARAM_H
1127   #include <sys/param.h>
1128   #endif
1129   #ifdef HAVE_SYS_VFS_H
1130   #include <sys/vfs.h>
1131   #endif
1132   #ifdef HAVE_SYS_MOUNT_H
1133   #include <sys/mount.h>
1134   #endif
1135   #ifdef HAVE_SYS_STATFS_H
1136   #include <sys/statfs.h>
1137   #endif], [struct statfs st;
1138   statfs(NULL, &st);],[
1139     AC_MSG_RESULT([2])
1140     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1141     AC_TRY_COMPILE([#include <unistd.h>
1142   #ifdef HAVE_SYS_PARAM_H
1143   #include <sys/param.h>
1144   #endif
1145   #ifdef HAVE_SYS_VFS_H
1146   #include <sys/vfs.h>
1147   #endif
1148   #ifdef HAVE_SYS_MOUNT_H
1149   #include <sys/mount.h>
1150   #endif
1151   #ifdef HAVE_SYS_STATFS_H
1152   #include <sys/statfs.h>
1153   #endif], [struct statfs st;
1154   statfs(NULL, &st, sizeof (st), 0);],[
1155       AC_MSG_RESULT([4])
1156       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1157       AC_MSG_RESULT(unknown)
1158       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1159 ])
1160
1161 dnl
1162 dnl open takes O_DIRECTORY as an option
1163 dnl
1164 AC_MSG_CHECKING([open() option O_DIRECTORY])
1165 AC_TRY_COMPILE([#include <fcntl.h>
1166 #include <sys/types.h>
1167 #include <sys/stat.h>],
1168 [open(0, O_DIRECTORY, 0);],[
1169         AC_MSG_RESULT([yes])
1170         AC_DEFINE(HAVE_OPEN_O_DIRECTORY, 1, [open option O_DIRECTORY])],[
1171         AC_MSG_RESULT([no])])
1172
1173 #
1174 # Check whether to use an included printf
1175 #
1176 AC_FUNC_VSNPRINTF_C99
1177 AC_FUNC_PRINTF_UNIX98
1178
1179 AC_ARG_ENABLE(included-printf,
1180               [AS_HELP_STRING([--enable-included-printf],
1181                               [use included printf [default=auto]])],
1182               enable_included_printf="$enableval")
1183
1184 need_included_printf=no
1185 if test "x$enable_included_printf" = "xyes" ; then
1186   need_included_printf=yes
1187 fi
1188 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1189   need_included_printf=yes
1190 fi
1191 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1192   need_included_printf=yes
1193 fi
1194 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1195    test -z "$glib_cv_long_long_format" ; then
1196   need_included_printf=yes
1197 fi
1198
1199 if test "x$enable_included_printf" = "xno" &&
1200    test "x$need_included_printf" = "xyes" ; then
1201   AC_MSG_ERROR([
1202 *** Your C library's printf doesn't appear to have the features that
1203 *** GLib needs, but you specified --enable-included-printf=no.])
1204 fi
1205
1206 enable_included_printf=$need_included_printf
1207
1208 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1209 AS_IF([test "$enable_included_printf" != "yes"], [
1210   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1211 ], [
1212   if test -z "$glib_cv_long_long_format" ; then
1213     glib_cv_long_long_format="ll"
1214   fi
1215   AC_DEFINE(HAVE_VASPRINTF,1)
1216 ])
1217
1218 # Checks needed for gnulib vasnprintf
1219 bh_C_SIGNED
1220 jm_AC_TYPE_LONG_LONG
1221 gt_TYPE_LONGDOUBLE
1222 gt_TYPE_WCHAR_T
1223 gt_TYPE_WINT_T
1224 AC_TYPE_SIZE_T
1225 AC_CHECK_TYPES(ptrdiff_t)
1226 jm_AC_TYPE_INTMAX_T
1227 AC_CHECK_FUNCS([snprintf wcslen])
1228 AC_FUNC_SNPRINTF_C99
1229
1230 # Check if <sys/select.h> needs to be included for fd_set
1231 AC_MSG_CHECKING([for fd_set])
1232 AC_TRY_COMPILE([#include <sys/types.h>],
1233         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1234 AS_IF([test "$gtk_ok" = "yes"], [
1235     AC_MSG_RESULT([yes, found in sys/types.h])
1236 ], [
1237     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1238     if test "$gtk_ok" = "yes"; then
1239         # *** FIXME: give it a different name
1240         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1241         AC_MSG_RESULT([yes, found in sys/select.h])
1242     else
1243         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1244         AC_MSG_RESULT(no)
1245     fi
1246 ])
1247
1248 dnl Check for nl_langinfo and CODESET
1249 AC_LANG_SAVE
1250 AC_LANG_C
1251 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1252         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1253                        [char *codeset = nl_langinfo (CODESET);])],
1254                 [glib_cv_langinfo_codeset=yes],
1255                 [glib_cv_langinfo_codeset=no])])
1256 if test x$glib_cv_langinfo_codeset = xyes; then
1257   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1258 fi
1259
1260 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1261 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1262         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1263                  [char *str;
1264                  str = nl_langinfo (PM_STR);
1265                  str = nl_langinfo (D_T_FMT);
1266                  str = nl_langinfo (D_FMT);
1267                  str = nl_langinfo (T_FMT);
1268                  str = nl_langinfo (T_FMT_AMPM);
1269                  str = nl_langinfo (MON_1);
1270                  str = nl_langinfo (ABMON_12);
1271                  str = nl_langinfo (DAY_1);
1272                  str = nl_langinfo (ABDAY_7);])],
1273                 [glib_cv_langinfo_time=yes],
1274                 [glib_cv_langinfo_time=no])])
1275 if test x$glib_cv_langinfo_time = xyes; then
1276   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1277 fi
1278
1279 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1280 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1281         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <langinfo.h>],
1282                 [char *str;
1283                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1284                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1285                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1286                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1287                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1288                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1289                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1290                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1291                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1292                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);])],
1293                 [glib_cv_langinfo_outdigit=yes],
1294                 [glib_cv_langinfo_outdigit=no])])
1295 if test x$glib_cv_langinfo_outdigit = xyes; then
1296   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1297 fi
1298 AC_LANG_RESTORE
1299
1300 dnl ****************************************
1301 dnl *** posix_memalign                   ***
1302 dnl ****************************************
1303 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1304 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1305     glib_cv_compliant_posix_memalign=0
1306     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1307         AC_TRY_RUN([
1308                 #define _XOPEN_SOURCE 600
1309                 #include <stdlib.h> /* posix_memalign() should be defined here */
1310                 /* some systems break if #include <malloc.h> used */
1311                 static void test_memalign (size_t boundary, size_t size) {
1312                     void *mem = 0;
1313                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1314                         exit (1);
1315                     else
1316                       free (mem);
1317                 }
1318                 int main() {
1319                     test_memalign (  128,   128 - 2 * sizeof (void*));
1320                     test_memalign (  256,   256 - 2 * sizeof (void*));
1321                     test_memalign (  512,   512 - 2 * sizeof (void*));
1322                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1323                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1324                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1325                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1326                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1327                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1328                     exit (0); /* success */
1329                 }
1330                 ],
1331             [glib_cv_compliant_posix_memalign=1], [], [:])
1332       :
1333     fi
1334     ])
1335 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1336     AC_MSG_RESULT(yes)
1337     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1338 ], [
1339     AC_MSG_RESULT(no)
1340 ])
1341
1342
1343 dnl ****************************************
1344 dnl *** strlcpy/strlcat                  ***
1345 dnl ****************************************
1346 # Check for strlcpy
1347 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1348 AC_TRY_RUN([#include <stdlib.h>
1349 #include <string.h>
1350 int main() {
1351   char p[10];
1352   (void) strlcpy (p, "hi", 10);
1353   if (strlcat (p, "bye", 0) != 3)
1354     return 1;
1355   return 0;
1356 }], glib_cv_have_strlcpy=yes,
1357     glib_cv_have_strlcpy=no,
1358     glib_cv_have_strlcpy=no)])
1359 if test "$glib_cv_have_strlcpy" = "yes"; then
1360     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1361 fi
1362
1363
1364 dnl **********************
1365 dnl *** va_copy checks ***
1366 dnl **********************
1367 dnl we currently check for all three va_copy possibilities, so we get
1368 dnl all results in config.log for bug reports.
1369 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1370         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1371 #include <stdlib.h>
1372         void f (int i, ...) {
1373         va_list args1, args2;
1374         va_start (args1, i);
1375         va_copy (args2, args1);
1376         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1377           exit (1);
1378         va_end (args1); va_end (args2);
1379         }
1380         int main() {
1381           f (0, 42);
1382           return 0;
1383         }]])],
1384         [glib_cv_va_copy=yes],
1385         [glib_cv_va_copy=no])
1386 ])
1387 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1388         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1389 #include <stdlib.h>
1390         void f (int i, ...) {
1391         va_list args1, args2;
1392         va_start (args1, i);
1393         __va_copy (args2, args1);
1394         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1395           exit (1);
1396         va_end (args1); va_end (args2);
1397         }
1398         int main() {
1399           f (0, 42);
1400           return 0;
1401         }]])],
1402         [glib_cv___va_copy=yes],
1403         [glib_cv___va_copy=no])
1404 ])
1405
1406 if test "x$glib_cv_va_copy" = "xyes"; then
1407   g_va_copy_func=va_copy
1408 else if test "x$glib_cv___va_copy" = "xyes"; then
1409   g_va_copy_func=__va_copy
1410 fi
1411 fi
1412
1413 if test -n "$g_va_copy_func"; then
1414   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1415 fi
1416
1417 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1418         AC_TRY_RUN([#include <stdarg.h>
1419 #include <stdlib.h>
1420         void f (int i, ...) {
1421         va_list args1, args2;
1422         va_start (args1, i);
1423         args2 = args1;
1424         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1425           exit (1);
1426         va_end (args1); va_end (args2);
1427         }
1428         int main() {
1429           f (0, 42);
1430           return 0;
1431         }],
1432         [glib_cv_va_val_copy=yes],
1433         [glib_cv_va_val_copy=no],
1434         [glib_cv_va_val_copy=yes])
1435 ])
1436
1437 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1438   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1439 ])
1440
1441 dnl ***********************
1442 dnl *** g_module checks ***
1443 dnl ***********************
1444 G_MODULE_LIBS=
1445 G_MODULE_LIBS_EXTRA=
1446 G_MODULE_PLUGIN_LIBS=
1447 if test x"$glib_native_win32" = xyes; then
1448   dnl No use for this on Win32
1449   G_MODULE_LDFLAGS=
1450 else
1451   export SED
1452   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1453 fi
1454 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1455 G_MODULE_NEED_USCORE=0
1456 G_MODULE_BROKEN_RTLD_GLOBAL=0
1457 G_MODULE_HAVE_DLERROR=0
1458 dnl *** force native WIN32 shared lib loader
1459 if test -z "$G_MODULE_IMPL"; then
1460   case "$host" in
1461   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1462   esac
1463 fi
1464 dnl *** force native AIX library loader
1465 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1466 if test -z "$G_MODULE_IMPL"; then
1467   case "$host" in
1468   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1469   esac
1470 fi
1471 dnl *** dlopen() and dlsym() in system libraries
1472 AS_IF([ test -z "$G_MODULE_IMPL"], [
1473         AC_CHECK_FUNC(dlopen,
1474                       [AC_CHECK_FUNC(dlsym,
1475                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1476                       [])
1477 ])
1478 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1479 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1480         AC_CHECK_FUNC(NSLinkModule,
1481                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1482                        G_MODULE_NEED_USCORE=1],
1483                       [])
1484 ])
1485 dnl *** dlopen() and dlsym() in libdl
1486 AS_IF([ test -z "$G_MODULE_IMPL"], [
1487         AC_CHECK_LIB(dl, dlopen,
1488                      [AC_CHECK_LIB(dl, dlsym,
1489                                    [G_MODULE_LIBS=-ldl
1490                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1491                      [])
1492 ])
1493 dnl *** additional checks for G_MODULE_IMPL_DL
1494 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1495         LIBS_orig="$LIBS"
1496         LDFLAGS_orig="$LDFLAGS"
1497         LIBS="$G_MODULE_LIBS $LIBS"
1498         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1499 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1500         echo "void glib_plugin_test(void) { }" > plugin.c
1501         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1502                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1503         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1504                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1505                 -shrext ".o" -avoid-version plugin.lo \
1506                 -rpath /dont/care >/dev/null 2>&1
1507         eval `./libtool --config | grep ^objdir`
1508         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1509                 glib_cv_rtldglobal_broken,[
1510                 AC_TRY_RUN([
1511 #include <dlfcn.h>
1512 #ifndef RTLD_GLOBAL
1513 #  define RTLD_GLOBAL 0
1514 #endif
1515 #ifndef RTLD_LAZY
1516 #  define RTLD_LAZY 0
1517 #endif
1518 int glib_plugin_test;
1519 int main () {
1520     void *handle, *global, *local;
1521     global = &glib_plugin_test;
1522     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1523     if (!handle) return 0;
1524     local = dlsym (handle, "glib_plugin_test");
1525     return global == local;
1526 }                       ],
1527                         [glib_cv_rtldglobal_broken=no],
1528                         [glib_cv_rtldglobal_broken=yes],
1529                         [glib_cv_rtldglobal_broken=no])
1530                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1531                 rmdir ${objdir} 2>/dev/null
1532         ])
1533         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1534                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1535         else
1536                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1537         fi
1538 dnl *** check whether we need preceeding underscores
1539         AC_CACHE_CHECK([for preceeding underscore in symbols],
1540                 glib_cv_uscore,[
1541                 AC_TRY_RUN([#include <dlfcn.h>
1542                 int glib_underscore_test (void) { return 42; }
1543                 int main() {
1544                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1545                   handle = dlopen ((void*)0, 0);
1546                   if (handle) {
1547                     f1 = dlsym (handle, "glib_underscore_test");
1548                     f2 = dlsym (handle, "_glib_underscore_test");
1549                   } return (!f2 || f1);
1550                 }],
1551                         [glib_cv_uscore=yes],
1552                         [glib_cv_uscore=no],
1553                         [])
1554                 rm -f plugin.c plugin.$ac_objext plugin.lo
1555         ])
1556         GLIB_ASSERT_SET(glib_cv_uscore)
1557         if test "x$glib_cv_uscore" = "xyes"; then
1558                 G_MODULE_NEED_USCORE=1
1559         else
1560                 G_MODULE_NEED_USCORE=0
1561         fi
1562
1563         LDFLAGS="$LDFLAGS_orig"
1564 dnl *** check for having dlerror()
1565         AC_CHECK_FUNC(dlerror,
1566                 [G_MODULE_HAVE_DLERROR=1],
1567                 [G_MODULE_HAVE_DLERROR=0])
1568         LIBS="$LIBS_orig"
1569 ])
1570 dnl *** done, have we got an implementation?
1571 if test -z "$G_MODULE_IMPL"; then
1572         G_MODULE_IMPL=0
1573         G_MODULE_SUPPORTED=false
1574 else
1575         G_MODULE_SUPPORTED=true
1576 fi
1577
1578 AC_MSG_CHECKING(for the suffix of module shared libraries)
1579 export SED
1580 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1581 eval $shrext_cmds
1582 module=yes eval std_shrext=$shrext_cmds
1583 # chop the initial dot
1584 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1585 AC_MSG_RESULT(.$glib_gmodule_suffix)
1586 # any reason it may fail?
1587 if test "x$glib_gmodule_suffix" = x; then
1588         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1589 fi
1590
1591 AC_SUBST(G_MODULE_SUPPORTED)
1592 AC_SUBST(G_MODULE_IMPL)
1593 AC_SUBST(G_MODULE_LIBS)
1594 AC_SUBST(G_MODULE_LIBS_EXTRA)
1595 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1596 AC_SUBST(G_MODULE_LDFLAGS)
1597 AC_SUBST(G_MODULE_HAVE_DLERROR)
1598 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1599 AC_SUBST(G_MODULE_NEED_USCORE)
1600 AC_SUBST(GLIB_DEBUG_FLAGS)
1601
1602 dnl **********************
1603 dnl *** g_spawn checks ***
1604 dnl **********************
1605
1606 AC_MSG_CHECKING(for gspawn implementation)
1607 case "$host" in
1608   *-*-mingw*)
1609     GSPAWN=gspawn-win32.lo
1610     ;;
1611   *)
1612     GSPAWN=gspawn.lo
1613     ;;
1614 esac
1615 AC_MSG_RESULT($GSPAWN)
1616 AC_SUBST(GSPAWN)
1617
1618 dnl *************************
1619 dnl *** GIOChannel checks ***
1620 dnl *************************
1621
1622 AC_MSG_CHECKING(for GIOChannel implementation)
1623 case "$host" in
1624   *-*-mingw*)
1625     GIO=giowin32.lo
1626     ;;
1627   *)
1628     GIO=giounix.lo
1629     ;;
1630 esac
1631 AC_MSG_RESULT($GIO)
1632 AC_SUBST(GIO)
1633
1634 dnl *********************************
1635 dnl *** Directory for GIO modules ***
1636 dnl *********************************
1637
1638 AC_ARG_WITH(gio-module-dir,
1639            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1640                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1641            [],
1642            [with_gio_module_dir='${libdir}/gio/modules'])
1643 GIO_MODULE_DIR=$with_gio_module_dir
1644 AC_SUBST(GIO_MODULE_DIR)
1645
1646 dnl **********************************
1647 dnl *** Check for libselinux (GIO) ***
1648 dnl **********************************
1649 AC_ARG_ENABLE(selinux,
1650               AS_HELP_STRING([--disable-selinux],
1651                              [build without selinux support]))
1652 msg_selinux=no
1653 SELINUX_LIBS=
1654 AS_IF([ test "x$enable_selinux" != "xno"], [
1655
1656  AC_CHECK_LIB(selinux, is_selinux_enabled,
1657    [AC_CHECK_HEADERS(selinux/selinux.h,
1658      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1659        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1660         SELINUX_LIBS="-lselinux"
1661         msg_selinux=yes])
1662      ])
1663    ])
1664 ])
1665 AC_SUBST(SELINUX_LIBS)
1666
1667 dnl *****************************
1668 dnl ** Check for inotify (GIO) **
1669 dnl *****************************
1670 inotify_support=no
1671 AC_CHECK_HEADERS([sys/inotify.h],
1672 [
1673   AC_CHECK_FUNCS(inotify_init1, [inotify_support=yes], [inotify_support=no])
1674 ])
1675
1676 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1677
1678 dnl ****************************
1679 dnl ** Check for kqueue (GIO) **
1680 dnl ****************************
1681 kqueue_support=no
1682 AC_CHECK_HEADERS([sys/event.h],
1683 [
1684         AC_CHECK_FUNCS(kqueue kevent, [kqueue_support=yes])
1685 ])
1686
1687 AM_CONDITIONAL(HAVE_KQUEUE, [test "$kqueue_support" = "yes"])
1688
1689 dnl ****************************
1690 dnl *** Checks for FAM (GIO) ***
1691 dnl ****************************
1692
1693 should_disable_fam=no
1694
1695 AC_ARG_ENABLE(fam,
1696               AS_HELP_STRING([--disable-fam],
1697                              [don't use fam for file system monitoring]),
1698                          [
1699                                 if test "x$enable_fam" = "xno"; then
1700                                         should_disable_fam=yes
1701                                 fi
1702                          ]
1703                          )
1704 fam_support=no
1705 FAM_LIBS=
1706 if test "x$should_disable_fam" = "xno"; then
1707 AC_CHECK_LIB(fam, FAMOpen,
1708   [AC_CHECK_HEADERS(fam.h,
1709     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1710      AC_CHECK_LIB(fam, FAMNoExists,
1711                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1712      FAM_LIBS="-lfam"]
1713      fam_support=yes,
1714     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1715   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1716 AC_SUBST(FAM_LIBS)
1717 fi
1718 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1719
1720
1721 dnl *****************************
1722 dnl *** Check for xattr (GIO) ***
1723 dnl *****************************
1724 AC_ARG_ENABLE(xattr,
1725               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1726 msg_xattr=no
1727 XATTR_LIBS=
1728 AS_IF([ test "x$enable_xattr" != "xno"], [
1729
1730 dnl either glibc or libattr can provide xattr support
1731
1732 dnl for both of them, we check for getxattr being in
1733 dnl the library and a valid xattr header.
1734
1735 dnl try glibc
1736  AC_CHECK_LIB(c, getxattr,
1737    [AC_CHECK_HEADERS(sys/xattr.h,
1738      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1739       msg_xattr=yes])
1740    ])
1741
1742   AS_IF([ test "x$msg_xattr" != "xyes"], [
1743 dnl   failure. try libattr
1744    AC_CHECK_LIB(attr, getxattr,
1745       [AC_CHECK_HEADERS(attr/xattr.h,
1746        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1747         XATTR_LIBS="-lattr"
1748         msg_xattr=yes])
1749       ])
1750   ])
1751
1752   AS_IF([ test "x$msg_xattr" = "xyes"], [
1753     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1754     AC_TRY_COMPILE([
1755       #include <stdio.h>
1756       #ifdef HAVE_SYS_TYPES_H
1757       #include <sys/types.h>
1758       #endif
1759       #ifdef HAVE_SYS_XATTR_H
1760       #include <sys/xattr.h>
1761       #elif HAVE_ATTR_XATTR_H
1762       #include <attr/xattr.h>
1763       #endif
1764     ],
1765     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1766     [
1767       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1768       AC_MSG_RESULT([yes])
1769     ],
1770     [AC_MSG_RESULT([no])]
1771     )
1772   ])
1773 ])
1774 AC_SUBST(XATTR_LIBS)
1775
1776 dnl ************************
1777 dnl *** check for libelf ***
1778 dnl ************************
1779 AC_ARG_ENABLE(libelf,
1780               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1781 AS_IF([ test "x$enable_libelf" != "xno"],[
1782 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1783 AS_IF([ test $have_libelf = maybe ], [
1784   glib_save_LIBS=$LIBS
1785   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1786   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1787   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1788   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1789   LIBS=$glib_save_LIBS
1790
1791   if test $have_libelf != no; then
1792     LIBELF_LIBS=-lelf
1793     have_libelf=yes
1794   fi
1795 ])
1796 ])
1797
1798 if test x$have_libelf = xyes; then
1799   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1800 fi
1801
1802 dnl ****************************************
1803 dnl *** platform dependent source checks ***
1804 dnl ****************************************
1805
1806 AC_MSG_CHECKING(for platform-dependent source)
1807 case "$host" in
1808   *-*-cygwin*|*-*-mingw*)
1809     PLATFORMDEP=gwin32.lo
1810     ;;
1811   *)
1812     PLATFORMDEP=
1813     ;;
1814 esac
1815 AC_MSG_RESULT($PLATFORMDEP)
1816 AC_SUBST(PLATFORMDEP)
1817
1818 AC_MSG_CHECKING([whether to compile timeloop])
1819 case "$host" in
1820   *-*-cygwin*|*-*-mingw*|*-*-minix)
1821     enable_timeloop=no
1822     ;;
1823   *)
1824     enable_timeloop=yes
1825     ;;
1826 esac
1827 AC_MSG_RESULT($enable_timeloop)
1828 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1829
1830 AC_MSG_CHECKING([if building for some Win32 platform])
1831 case "$host" in
1832   *-*-mingw*|*-*-cygwin*)
1833     platform_win32=yes
1834     ;;
1835   *)
1836     platform_win32=no
1837     ;;
1838 esac
1839 AC_MSG_RESULT($platform_win32)
1840 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1841
1842 dnl ***********************
1843 dnl *** g_thread checks ***
1844 dnl ***********************
1845
1846 AC_ARG_WITH(threads,
1847            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1848                            [specify a thread implementation to use])],
1849            [],
1850            [with_threads=yes])
1851
1852 dnl error and warning message
1853 dnl *************************
1854
1855 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1856
1857 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1858                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1859                 compilation now, but then your programs might not work.
1860                 Please provide information on how it is done on your system."
1861
1862 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1863                  "
1864
1865 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1866                   provide information on your thread implementation."
1867
1868 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1869                 functions will not be MT-safe during their first call because
1870                 there is no working 'getpwuid_r' on your system."
1871
1872 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1873                 because there is no 'localtime_r' on your system."
1874
1875 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1876                 linking threaded applications. As GLib cannot do that
1877                 automatically, you will get an linkg error everytime you are
1878                 not using the right compiler. In that case you have to relink
1879                 with the right compiler. Ususally just '_r' is appended
1880                 to the compiler name."
1881
1882 dnl determination of thread implementation
1883 dnl ***************************************
1884
1885 AC_MSG_CHECKING(for thread implementation)
1886
1887 have_threads=no
1888 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1889         AS_IF([ test "x$have_threads" = xno], [
1890                 AC_TRY_COMPILE([#include <pthread.h>],
1891                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1892                         have_threads=posix)
1893         ])
1894         # Tru64Unix requires -pthread to find pthread.h. See #103020
1895         if test "x$have_threads" = xno; then
1896                 glib_save_CPPFLAGS="$CPPFLAGS"
1897                 CPPFLAGS="$CPPFLAGS -pthread"
1898                 AC_TRY_COMPILE([#include <pthread.h>],
1899                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1900                        have_threads=posix)
1901                 CPPFLAGS="$glib_save_CPPFLAGS"
1902         fi
1903 ])
1904 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1905         case $host in
1906                 *-*-mingw*)
1907                 have_threads=win32
1908                 ;;
1909         esac
1910 fi
1911
1912 if test "x$have_threads" = xno; then
1913         AC_MSG_RESULT(none available)
1914         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1915 else
1916         AC_MSG_RESULT($have_threads)
1917 fi
1918
1919
1920 dnl determination of G_THREAD_CFLAGS
1921 dnl ********************************
1922
1923 G_THREAD_LIBS=
1924 G_THREAD_LIBS_EXTRA=
1925 G_THREAD_CFLAGS=
1926
1927 dnl
1928 dnl Test program for basic POSIX threads functionality
1929 dnl
1930 m4_define([glib_thread_test],[
1931 #include <pthread.h>
1932 int check_me = 0;
1933 void* func(void* data) {check_me = 42; return &check_me;}
1934 int main()
1935  { pthread_t t;
1936    void *ret;
1937    pthread_create (&t, $1, func, 0);
1938    pthread_join (t, &ret);
1939    return (check_me != 42 || ret != &check_me);
1940 }])
1941
1942 AS_IF([ test x"$have_threads" = xposix], [
1943   # First we test for posix, whether -pthread or -pthreads do the trick as
1944   # both CPPFLAG and LIBS.
1945   # One of them does for most gcc versions and some other platforms/compilers
1946   # too and could be considered as the canonical way to go.
1947   case $host in
1948     *-*-cygwin*|*-*-darwin*)
1949        # skip cygwin and darwin -pthread or -pthreads test
1950        ;;
1951     *-solaris*)
1952       # These compiler/linker flags work with both Sun Studio and gcc
1953       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1954       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1955       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1956       G_THREAD_LIBS="-lpthread -lthread"
1957       ;;
1958     *)
1959       for flag in pthread pthreads mt; do
1960         glib_save_CFLAGS="$CFLAGS"
1961         CFLAGS="$CFLAGS -$flag"
1962         AC_TRY_RUN(glib_thread_test(0),
1963                    glib_flag_works=yes,
1964                    glib_flag_works=no,
1965                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1966                                    glib_flag_works=yes,
1967                                    glib_flag_works=no)])
1968         CFLAGS="$glib_save_CFLAGS"
1969         if test $glib_flag_works = yes ; then
1970            G_THREAD_CFLAGS=-$flag
1971         G_THREAD_LIBS=-$flag
1972         break;
1973         fi
1974       done
1975        ;;
1976   esac
1977 ])
1978
1979 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
1980
1981   # The canonical -pthread[s] does not work. Try something different.
1982
1983   case $host in
1984         *-aix*)
1985                 if test x"$GCC" = xyes; then
1986                         # GCC 3.0 and above needs -pthread.
1987                         # Should be coverd by the case above.
1988                         # GCC 2.x and below needs -mthreads
1989                         G_THREAD_CFLAGS="-mthreads"
1990                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1991                 else
1992                         # We are probably using the aix compiler. Normaly a
1993                         # program would have to be compiled with the _r variant
1994                         # of the corresponding compiler, but we as GLib cannot
1995                         # do that: but the good news is that for compiling the
1996                         # only difference is the added -D_THREAD_SAFE compile
1997                         # option. This is according to the "C for AIX User's
1998                         # Guide".
1999                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2000                 fi
2001                 ;;
2002         *-sysv5uw7*) # UnixWare 7
2003                 # We are not using gcc with -pthread. Catched above.
2004                 G_THREAD_CFLAGS="-Kthread"
2005                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2006                 ;;
2007         *-mingw*)
2008                 # No flag needed when using MSVCRT.DLL
2009                 G_THREAD_CFLAGS=""
2010                 ;;
2011         *)
2012                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2013                 ;;
2014   esac
2015 ])
2016
2017 # if we are not finding the localtime_r function, then we probably are
2018 # not using the proper multithread flag
2019
2020 glib_save_CPPFLAGS="$CPPFLAGS"
2021 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2022
2023 # First we test, whether localtime_r is declared in time.h
2024 # directly. Then we test whether a macro localtime_r exists, in
2025 # which case localtime_r in the test program is replaced and thus
2026 # if we still find localtime_r in the output, it is not defined as
2027 # a macro.
2028
2029 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2030   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2031                                                            localtime_r(a,b)],
2032                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2033
2034 CPPFLAGS="$glib_save_CPPFLAGS"
2035
2036 AC_MSG_CHECKING(thread related cflags)
2037 AC_MSG_RESULT($G_THREAD_CFLAGS)
2038 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2039
2040 dnl determination of G_THREAD_LIBS
2041 dnl ******************************
2042
2043 AS_IF([test x$have_threads = xposix], [
2044           glib_save_CPPFLAGS="$CPPFLAGS"
2045           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2046           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2047             case $host in
2048               *-aix*)
2049                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2050                 # probably using the aix compiler.
2051                 AC_MSG_WARN($AIX_COMPILE_INFO)
2052                 ;;
2053               *)
2054                 G_THREAD_LIBS=error
2055                 glib_save_LIBS="$LIBS"
2056                 for thread_lib in "" pthread pthread32 pthreads thread; do
2057                         if test x"$thread_lib" = x; then
2058                                 add_thread_lib=""
2059                                 IN=""
2060                         else
2061                                 add_thread_lib="-l$thread_lib"
2062                                 IN=" in -l$thread_lib"
2063                         fi
2064                         if test x"$have_threads" = xposix; then
2065                                 defattr=0
2066                         else
2067                                 defattr=pthread_attr_default
2068                         fi
2069
2070                         LIBS="$add_thread_lib $glib_save_LIBS"
2071
2072                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2073                         AC_TRY_RUN(glib_thread_test($defattr),
2074                                    glib_result=yes,
2075                                    glib_result=no,
2076                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2077                                                    glib_result=yes,
2078                                                    glib_result=no)])
2079                         AC_MSG_RESULT($glib_result)
2080
2081                         if test "$glib_result" = "yes" ; then
2082                           G_THREAD_LIBS="$add_thread_lib"
2083                           break
2084                         fi
2085                 done
2086                 if test "x$G_THREAD_LIBS" = xerror; then
2087                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2088                 fi
2089                 LIBS="$glib_save_LIBS"
2090                 ;;
2091             esac
2092           ])
2093
2094           g_threads_impl="POSIX"
2095           AC_DEFINE([THREADS_POSIX], [1], [Use pthreads])
2096           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2097           CPPFLAGS="$glib_save_CPPFLAGS"
2098 ], [test x$have_threads = xwin32], [
2099            AC_DEFINE([THREADS_WIN32], [1], [Use w32 threads])
2100            g_threads_impl="WIN32"
2101 ], [
2102            AC_DEFINE([THREADS_NONE], [1], [Use no threads])
2103            g_threads_impl="NONE"
2104            G_THREAD_LIBS=error
2105 ])
2106 AM_CONDITIONAL(THREADS_POSIX, [test "$g_threads_impl" = "POSIX"])
2107 AM_CONDITIONAL(THREADS_WIN32, [test "$g_threads_impl" = "WIN32"])
2108 AM_CONDITIONAL(THREADS_NONE, [test "$g_threads_impl" = "NONE"])
2109
2110 if test "x$G_THREAD_LIBS" = xerror; then
2111         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2112 fi
2113
2114 AC_MSG_CHECKING(thread related libraries)
2115 AC_MSG_RESULT($G_THREAD_LIBS)
2116
2117 dnl check for mt safe function variants and some posix functions
2118 dnl ************************************************************
2119
2120 glib_save_LIBS="$LIBS"
2121 # we are not doing the following for now, as this might require glib
2122 # to always be linked with the thread libs on some platforms.
2123 # LIBS="$LIBS $G_THREAD_LIBS"
2124 AC_CHECK_FUNCS(localtime_r gmtime_r)
2125 AS_IF([ test "$glib_native_win32" != "yes"], [
2126         AC_CACHE_CHECK([for posix getpwuid_r],
2127                 ac_cv_func_posix_getpwuid_r,
2128                 [AC_TRY_RUN([
2129 #include <errno.h>
2130 #include <pwd.h>
2131 int main () {
2132     char buffer[10000];
2133     struct passwd pwd, *pwptr = &pwd;
2134     int error;
2135     errno = 0;
2136     error = getpwuid_r (0, &pwd, buffer,
2137                         sizeof (buffer), &pwptr);
2138    return (error < 0 && errno == ENOSYS)
2139            || error == ENOSYS;
2140 }                               ],
2141                         [ac_cv_func_posix_getpwuid_r=yes],
2142                         [ac_cv_func_posix_getpwuid_r=no])])
2143         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2144         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2145                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2146                         [Have POSIX function getpwuid_r])
2147         else
2148                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2149                         ac_cv_func_nonposix_getpwuid_r,
2150                         [AC_TRY_LINK([#include <pwd.h>],
2151                                 [char buffer[10000];
2152                                 struct passwd pwd;
2153                                 getpwuid_r (0, &pwd, buffer,
2154                                                 sizeof (buffer));],
2155                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2156                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2157                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2158                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2159                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2160                                 [Have non-POSIX function getpwuid_r])
2161                 fi
2162         fi
2163 ])
2164 AS_IF([ test "$glib_native_win32" != "yes"], [
2165         AC_CACHE_CHECK([for posix getgrgid_r],
2166                 ac_cv_func_posix_getgrgid_r,
2167                 [AC_TRY_RUN([
2168 #include <errno.h>
2169 #include <grp.h>
2170 int main () {
2171     char buffer[10000];
2172     struct group grp, *grpptr = &grp;
2173     int error;
2174     errno = 0;
2175     error = getgrgid_r (0, &grp, buffer,
2176                         sizeof (buffer), &grpptr);
2177    return (error < 0 && errno == ENOSYS)
2178            || error == ENOSYS;
2179 }                              ],
2180                        [ac_cv_func_posix_getgrgid_r=yes],
2181                        [ac_cv_func_posix_getgrgid_r=no])])
2182         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2183         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2184                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2185                         [Have POSIX function getgrgid_r])
2186         ], [
2187                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2188                         ac_cv_func_nonposix_getgrgid_r,
2189                         [AC_TRY_LINK([#include <grp.h>],
2190                                 [char buffer[10000];
2191                                 struct group grp;
2192                                 getgrgid_r (0, &grp, buffer,
2193                                 sizeof (buffer));],
2194                         [ac_cv_func_nonposix_getgrgid_r=yes],
2195                         [ac_cv_func_nonposix_getgrgid_r=no])])
2196                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2197                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2198                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2199                                 [Have non-POSIX function getgrgid_r])
2200                 fi
2201         ])
2202 ])
2203 LIBS="$G_THREAD_LIBS $LIBS"
2204 AS_IF([ test x"$have_threads" = xposix], [
2205         glib_save_CPPFLAGS="$CPPFLAGS"
2206         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2207         # This is not AC_CHECK_FUNC to also work with function
2208         # name mangling in header files.
2209         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2210         AC_LINK_IFELSE(
2211             [AC_LANG_PROGRAM(
2212                 [#include <pthread.h>],
2213                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2214             [AC_MSG_RESULT(yes)
2215              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2216                 [Have function pthread_attr_setstacksize])],
2217             [AC_MSG_RESULT(no)])
2218         AC_MSG_CHECKING(for pthread_condattr_setclock)
2219         AC_LINK_IFELSE(
2220             [AC_LANG_PROGRAM(
2221                 [#include <pthread.h>],
2222                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2223             [AC_MSG_RESULT(yes)
2224              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2225                 [Have function pthread_condattr_setclock])],
2226             [AC_MSG_RESULT(no)])
2227         AC_MSG_CHECKING(for pthread_cond_timedwait_relative_np)
2228         AC_LINK_IFELSE(
2229             [AC_LANG_PROGRAM(
2230                 [#include <pthread.h>],
2231                 [pthread_cond_timedwait_relative_np(NULL, NULL, NULL)])],
2232             [AC_MSG_RESULT(yes)
2233              AC_DEFINE(HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP,1,
2234                 [Have function pthread_cond_timedwait_relative_np])],
2235             [AC_MSG_RESULT(no)])
2236         dnl Sets thread names on OS X 10.6, iOS 3.2 (and higher)
2237         AC_MSG_CHECKING(for pthread_setname_np(const char*))
2238         AC_LINK_IFELSE(
2239             [AC_LANG_PROGRAM(
2240                 [#include <pthread.h>],
2241                 [pthread_setname_np("example")])],
2242             [AC_MSG_RESULT(yes)
2243              AC_DEFINE(HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID,1,
2244                 [Have function pthread_setname_np(const char*)])],
2245             [AC_MSG_RESULT(no)])
2246         CPPFLAGS="$glib_save_CPPFLAGS"
2247 ])
2248
2249 LIBS="$glib_save_LIBS"
2250
2251 # now spit out all the warnings.
2252 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2253    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2254         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2255 fi
2256 if test "$ac_cv_func_localtime_r" != "yes"; then
2257         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2258 fi
2259
2260 #
2261 # Hack to deal with:
2262 #
2263 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2264 #     building shared libraries with linux.
2265 #  b) FreeBSD doesn't do this either.
2266 #
2267 case $host in
2268   *android*)
2269     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2270     ;;
2271   *-*-freebsd*|*-*-linux*)
2272     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2273     ;;
2274   *)
2275     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2276     ;;
2277 esac
2278
2279 AC_SUBST(G_THREAD_CFLAGS)
2280 AC_SUBST(G_THREAD_LIBS)
2281 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2282 AC_SUBST(G_THREAD_LIBS_EXTRA)
2283
2284 AC_CHECK_FUNCS(clock_gettime, [], [
2285   AC_CHECK_LIB(rt, clock_gettime, [
2286     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2287     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2288   ])
2289 ])
2290
2291
2292 dnl ************************
2293 dnl *** g_atomic_* tests ***
2294 dnl ************************
2295
2296 dnl We need to decide at configure time if GLib will use real atomic
2297 dnl operations ("lock free") or emulated ones with a mutex.  This is
2298 dnl because we must put this information in glibconfig.h so we know if
2299 dnl it is safe or not to inline using compiler intrinsics directly from
2300 dnl the header.
2301 dnl
2302 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2303 dnl user is interested in knowing if they can use the atomic ops across
2304 dnl processes.
2305 dnl
2306 dnl We can currently support the atomic ops natively when building GLib
2307 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2308 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2309 dnl we are using GCC (and not mingw*).
2310 dnl
2311 dnl Note that the atomic ops are only available with GCC on x86 when
2312 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2313 dnl not available but would be available given the right flags, we want
2314 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2315 dnl that then to silently fall back on emulated atomic ops just because
2316 dnl the user had the wrong build environment.
2317
2318 dnl We may add other compilers here in the future...
2319
2320 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2321   case $host in
2322     *-*-mingw*)
2323       glib_cv_g_atomic_lock_free=yes
2324       ;;
2325     *)
2326       AC_TRY_LINK([],
2327                      [volatile int atomic = 2;\
2328                       __sync_bool_compare_and_swap (&atomic, 2, 3);],
2329                      [glib_cv_g_atomic_lock_free=yes],
2330                      [glib_cv_g_atomic_lock_free=no])
2331       if test "$glib_cv_g_atomic_lock_free" = "no"; then
2332         SAVE_CFLAGS="${CFLAGS}"
2333         CFLAGS="-march=i486"
2334         AC_TRY_LINK([],
2335                        [volatile int atomic = 2;\
2336                         __sync_bool_compare_and_swap (&atomic, 2, 3);],
2337                        [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2338                        [])
2339         CFLAGS="${SAVE_CFLAGS}"
2340       fi
2341       ;;
2342   esac])
2343
2344
2345 case $host in
2346   *-*-mingw*)
2347     ;;
2348   *)
2349     # Some compilers support atomic operations but do not define
2350     # __GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, like clang
2351     if test x"$glib_cv_g_atomic_lock_free" = xyes; then
2352       AC_TRY_LINK([],
2353                      [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2354                      [],
2355                      [AC_DEFINE(__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4, 1, [ compiler supports atomic operations])])
2356     fi
2357     ;;
2358  esac
2359
2360 dnl We need a more robust approach here...
2361 case $host_cpu in
2362   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2363     glib_memory_barrier_needed=no
2364     ;;
2365   sparc*|alpha*|powerpc*|ia64)
2366     glib_memory_barrier_needed=yes
2367     ;;
2368   *)
2369     glib_memory_barrier_needed=yes
2370     ;;
2371 esac
2372
2373 dnl ************************
2374 dnl ** Check for futex(2) **
2375 dnl ************************
2376 AC_CACHE_CHECK(for futex(2) system call,
2377     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2378 #include <linux/futex.h>
2379 #include <sys/syscall.h>
2380 #include <unistd.h>
2381 ],[
2382   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2383 ])],glib_cv_futex=yes,glib_cv_futex=no))
2384 if test x"$glib_cv_futex" = xyes; then
2385   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2386 fi
2387
2388 AC_CACHE_CHECK(for eventfd(2) system call,
2389     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2390 #include <sys/eventfd.h>
2391 #include <unistd.h>
2392 ],[
2393   eventfd (0, EFD_CLOEXEC);
2394 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2395 if test x"$glib_cv_eventfd" = x"yes"; then
2396   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2397 fi
2398 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2399
2400 dnl ****************************************
2401 dnl *** GLib POLL* compatibility defines ***
2402 dnl ****************************************
2403
2404 glib_poll_includes=["
2405 #include <sys/types.h>
2406 #include <poll.h>
2407 "]
2408
2409 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2410    test $ac_cv_func_poll = yes ], [
2411   glib_failed=false
2412   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2413   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2414   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2415   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2416   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2417   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2418   if $glib_failed ; then
2419     AC_MSG_ERROR([Could not determine values for POLL* constants])
2420   fi
2421 ], [
2422   glib_cv_value_POLLIN=1
2423   glib_cv_value_POLLOUT=4
2424   glib_cv_value_POLLPRI=2
2425   glib_cv_value_POLLERR=8
2426   glib_cv_value_POLLHUP=16
2427   glib_cv_value_POLLNVAL=32
2428 ])
2429
2430 AC_MSG_CHECKING([for broken poll])
2431 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2432         #include <stdlib.h>
2433         #include <fcntl.h>
2434         #include <poll.h>
2435         int main(void) {
2436           struct pollfd fds[1];
2437           int fd;
2438           fd = open("/dev/null", 1);
2439           fds[0].fd = fd;
2440           fds[0].events = POLLIN;
2441           fds[0].revents = 0;
2442           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2443                 exit(1);  /* Does not work for devices -- fail */
2444           }
2445           exit(0);
2446         }]])],
2447   [broken_poll=no],
2448   [broken_poll=yes
2449    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2450   [broken_poll="no (cross compiling)"])
2451 AC_MSG_RESULT($broken_poll)
2452
2453 dnl *********************
2454 dnl *** GRegex checks ***
2455 dnl *********************
2456
2457 PCRE_REQUIRED_VERSION=8.13
2458
2459 # Check if we should use the internal or the system-supplied pcre
2460 AC_ARG_WITH(pcre,
2461             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2462                             [whether to use system PCRE [default=internal]])])
2463
2464 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2465
2466 AS_IF([ test "x$with_pcre" = xsystem], [
2467   PKG_CHECK_MODULES(PCRE,
2468                     libpcre >= $PCRE_REQUIRED_VERSION)
2469   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2470                   glib_save_CFLAGS="$CFLAGS"
2471                   glib_save_LIBS="$LIBS"
2472                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2473                   AC_TRY_RUN([#include <pcre.h>
2474                               int main () {
2475                                 int support;
2476                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2477                                 if (!support)
2478                                   return 1;
2479                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2480                                 if (!support)
2481                                   return 1;
2482                                 return 0;
2483                               }],
2484                   glib_cv_pcre_has_unicode=yes,
2485                   glib_cv_pcre_has_unicode=no,
2486                   glib_cv_pcre_has_unicode=yes)
2487                   CFLAGS="$glib_save_CFLAGS"
2488                   LIBS="$glib_save_LIBS"
2489       ])
2490   if test "$glib_cv_pcre_has_unicode" = "no"; then
2491     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2492   fi
2493   AC_SUBST(PCRE_CFLAGS)
2494   AC_SUBST(PCRE_LIBS)
2495   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2496   PCRE_REQUIRES=libpcre
2497   AC_SUBST(PCRE_REQUIRES)
2498 ], [
2499   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2500   AS_IF([ test x"$GCC" = xyes], [
2501     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2502     save_CFLAGS="$CFLAGS"
2503     CFLAGS="$CFLAGS -Wno-pointer-sign"
2504     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2505                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2506     CFLAGS="$save_CFLAGS"
2507   ])
2508 ])
2509 AC_SUBST(PCRE_WARN_CFLAGS)
2510
2511 dnl **********************
2512 dnl *** Win32 API libs ***
2513 dnl **********************
2514
2515 case $host in
2516   *-*-cygwin*)
2517         G_LIBS_EXTRA="-luser32 -lkernel32"
2518     ;;
2519   *-*-mingw*)
2520         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2521     ;;
2522   *)
2523         G_LIBS_EXTRA=""
2524     ;;
2525 esac
2526 AC_SUBST(G_LIBS_EXTRA)
2527
2528 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2529 dnl since we need it for g_iconv()
2530
2531 AC_MSG_CHECKING([for EILSEQ])
2532 AC_TRY_COMPILE([
2533 #include <errno.h>
2534 ],
2535 [
2536 int error = EILSEQ;
2537 ], have_eilseq=yes, have_eilseq=no);
2538 AC_MSG_RESULT($have_eilseq)
2539
2540 dnl ******************************************************************
2541 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2542 dnl *** glib-compile-schemas in PATH                               ***
2543 dnl ******************************************************************
2544
2545 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2546
2547 AS_IF([ test $cross_compiling = yes ], [
2548   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2549   if test x$GLIB_GENMARSHAL = xno; then
2550     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2551   fi
2552
2553   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2554   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2555     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2556   fi
2557
2558   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2559   if test x$GLIB_COMPILE_RESOURCES = xno; then
2560     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2561   fi
2562 ])
2563
2564 dnl **************************
2565 dnl *** Checks for gtk-doc ***
2566 dnl **************************
2567 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2568 # it on it's own line.
2569 m4_ifdef([GTK_DOC_CHECK], [
2570 GTK_DOC_CHECK([1.20], [--flavour no-tmpl])
2571 ],[
2572 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2573 ])
2574
2575 AC_ARG_ENABLE(man,
2576               [AS_HELP_STRING([--enable-man],
2577                               [generate man pages [default=auto]])],,
2578               enable_man=maybe)
2579
2580 AS_IF([test "$enable_man" != no], [
2581   AC_PATH_PROG([XSLTPROC], [xsltproc])
2582   AS_IF([test -z "$XSLTPROC"], [
2583     AS_IF([test "$enable_man" = yes], [
2584       AC_MSG_ERROR([xsltproc is required for --enable-man])
2585     ])
2586     enable_man=no
2587   ])
2588 ])
2589
2590 AS_IF([ test "$enable_man" != no ], [
2591   dnl check for DocBook DTD in the local catalog
2592   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2593      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2594   AS_IF([test "$have_docbook_dtd" != yes], [
2595     AS_IF([test "$enable_man" = yes ], [
2596       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2597     ])
2598     enable_man=no
2599   ])
2600 ])
2601
2602 AS_IF([test "$enable_man" != no], [
2603   dnl check for DocBook XSL stylesheets in the local catalog
2604   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2605      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2606   AS_IF([ test "$have_docbook_style" != yes ], [
2607     AS_IF([ test "$enable_man" = yes ], [
2608       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2609     ])
2610     enable_man=no
2611   ])
2612 ])
2613
2614 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2615
2616 AC_MSG_CHECKING([whether to generate man pages])
2617 AS_IF([ test "$enable_man" != no ], [
2618   AC_MSG_RESULT([yes])
2619 ], [
2620   AC_MSG_RESULT([no])
2621 ])
2622
2623 dnl
2624 dnl Tracing
2625 dnl
2626
2627 AC_ARG_ENABLE([dtrace],
2628              [AS_HELP_STRING([--enable-dtrace],
2629                               [include tracing support for dtrace])])
2630 have_dtrace=no
2631 AC_MSG_CHECKING([whether to include dtrace tracing support])
2632 AS_IF([ test "x$enable_dtrace" != xno], [
2633   if test x$glib_have_carbon = xyes; then
2634     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2635   else
2636     AC_MSG_RESULT([yes])
2637     AC_CHECK_PROGS(DTRACE, dtrace)
2638     if test -z "$DTRACE"; then
2639       if test "x$enable_dtrace" = xyes; then
2640         AC_MSG_ERROR([dtrace not found])
2641       fi
2642     else
2643       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2644                       [if test "x$enable_dtrace" = xyes; then
2645                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2646                        fi])
2647     fi
2648   fi
2649 ], [
2650   AC_MSG_RESULT([no])
2651 ])
2652 if test "x$have_dtrace" = xyes; then
2653   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2654 fi
2655 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2656
2657 AC_MSG_CHECKING([whether to include systemtap tracing support])
2658 AC_ARG_ENABLE([systemtap],
2659              [AS_HELP_STRING([--enable-systemtap],
2660                               [include tracing support for systemtap])])
2661 have_systemtap=no
2662 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2663   have_systemtap=yes
2664 fi
2665 AC_MSG_RESULT(${have_systemtap})
2666
2667 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2668
2669 AC_ARG_WITH([tapset-install-dir],
2670             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2671                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2672             [if test "x${withval}" = x; then
2673                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2674              else
2675                ABS_TAPSET_DIR="${withval}"
2676               fi],
2677             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2678 AC_SUBST(ABS_TAPSET_DIR)
2679
2680 dnl ************************************
2681 dnl *** Enable lcov coverage reports ***
2682 dnl ************************************
2683
2684 AC_ARG_ENABLE(coverage,
2685   AS_HELP_STRING([--enable-coverage],
2686                  [enable coverage testing with gcov]),
2687   [use_gcov=$enableval], [use_gcov=no])
2688
2689 AS_IF([ test "x$use_gcov" = "xyes"], [
2690   dnl we need gcc:
2691   if test "$GCC" != "yes"; then
2692     AC_MSG_ERROR([GCC is required for --enable-coverage])
2693   fi
2694
2695   dnl Check if ccache is being used
2696   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2697   case `$SHTOOL path $CC` in
2698     *ccache*[)] gcc_ccache=yes;;
2699     *[)] gcc_ccache=no;;
2700   esac
2701
2702   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2703     AC_MSG_ERROR([ccache must be disabled when --enable-coverage option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2704   fi
2705
2706   ltp_version_list="1.6 1.7 1.8 1.9 1.10"
2707   AC_CHECK_PROG(LTP, lcov, lcov)
2708   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2709
2710   AS_IF([ test "$LTP" ], [
2711     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2712       glib_cv_ltp_version=invalid
2713       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2714       for ltp_check_version in $ltp_version_list; do
2715         if test "$ltp_version" = "$ltp_check_version"; then
2716           glib_cv_ltp_version="$ltp_check_version (ok)"
2717         fi
2718       done
2719     ])
2720   ], [
2721     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2722     AC_MSG_ERROR([$ltp_msg])
2723   ])
2724
2725   case $glib_cv_ltp_version in
2726     ""|invalid[)]
2727       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2728       AC_MSG_ERROR([$ltp_msg])
2729       LTP="exit 0;"
2730       ;;
2731   esac
2732
2733   if test -z "$LTP_GENHTML"; then
2734     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2735   fi
2736
2737   dnl Remove all optimization flags from CFLAGS
2738   changequote({,})
2739   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2740   changequote([,])
2741
2742   dnl Add the special gcc flags
2743   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2744   LDFLAGS="$LDFLAGS -lgcov"
2745 ])
2746
2747 dnl ******************************
2748 dnl *** output the whole stuff ***
2749 dnl ******************************
2750
2751 dnl this section will only be run if config.status is invoked with no
2752 dnl arguments, or with "glib/glibconfig.h" as an argument.
2753 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2754 [
2755         outfile=glib/glibconfig.h-tmp
2756         cat > $outfile <<\_______EOF
2757 /* glibconfig.h
2758  *
2759  * This is a generated file.  Please modify 'configure.ac'
2760  */
2761
2762 #ifndef __GLIBCONFIG_H__
2763 #define __GLIBCONFIG_H__
2764
2765 #include <glib/gmacros.h>
2766
2767 _______EOF
2768
2769         echo '#include <limits.h>' >> $outfile
2770         echo '#include <float.h>' >> $outfile
2771         if test x$glib_values_h = xyes; then
2772           echo '#include <values.h>' >> $outfile
2773         fi
2774         if test "$glib_header_alloca_h" = "yes"; then
2775           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2776         fi
2777         if test x$glib_included_printf != xyes; then
2778           echo "
2779 /* Specifies that GLib's g_print*() functions wrap the
2780  * system printf functions.  This is useful to know, for example,
2781  * when using glibc's register_printf_function().
2782  */" >> $outfile
2783           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2784         fi
2785
2786         cat >> $outfile <<_______EOF
2787
2788 G_BEGIN_DECLS
2789
2790 #define G_MINFLOAT      FLT_MIN
2791 #define G_MAXFLOAT      FLT_MAX
2792 #define G_MINDOUBLE     DBL_MIN
2793 #define G_MAXDOUBLE     DBL_MAX
2794 #define G_MINSHORT      SHRT_MIN
2795 #define G_MAXSHORT      SHRT_MAX
2796 #define G_MAXUSHORT     USHRT_MAX
2797 #define G_MININT        INT_MIN
2798 #define G_MAXINT        INT_MAX
2799 #define G_MAXUINT       UINT_MAX
2800 #define G_MINLONG       LONG_MIN
2801 #define G_MAXLONG       LONG_MAX
2802 #define G_MAXULONG      ULONG_MAX
2803
2804 _______EOF
2805
2806
2807         ### this should always be true in a modern C/C++ compiler
2808         ### and is statically asserted by glib-init.c
2809         cat >>$outfile <<_______EOF
2810 typedef signed char gint8;
2811 typedef unsigned char guint8;
2812 _______EOF
2813
2814
2815         if test -n "$gint16"; then
2816           cat >>$outfile <<_______EOF
2817 typedef signed $gint16 gint16;
2818 typedef unsigned $gint16 guint16;
2819 #define G_GINT16_MODIFIER $gint16_modifier
2820 #define G_GINT16_FORMAT $gint16_format
2821 #define G_GUINT16_FORMAT $guint16_format
2822 _______EOF
2823         fi
2824
2825
2826         if test -n "$gint32"; then
2827           cat >>$outfile <<_______EOF
2828 typedef signed $gint32 gint32;
2829 typedef unsigned $gint32 guint32;
2830 #define G_GINT32_MODIFIER $gint32_modifier
2831 #define G_GINT32_FORMAT $gint32_format
2832 #define G_GUINT32_FORMAT $guint32_format
2833 _______EOF
2834         fi
2835
2836         cat >>$outfile <<_______EOF
2837 #define G_HAVE_GINT64 1          /* deprecated, always true */
2838
2839 ${glib_extension}typedef signed $gint64 gint64;
2840 ${glib_extension}typedef unsigned $gint64 guint64;
2841
2842 #define G_GINT64_CONSTANT(val)  $gint64_constant
2843 #define G_GUINT64_CONSTANT(val) $guint64_constant
2844 _______EOF
2845
2846         if test x$gint64_format != x ; then
2847           cat >>$outfile <<_______EOF
2848 #define G_GINT64_MODIFIER $gint64_modifier
2849 #define G_GINT64_FORMAT $gint64_format
2850 #define G_GUINT64_FORMAT $guint64_format
2851 _______EOF
2852         else
2853           cat >>$outfile <<_______EOF
2854 #undef G_GINT64_MODIFIER
2855 #undef G_GINT64_FORMAT
2856 #undef G_GUINT64_FORMAT
2857 _______EOF
2858         fi
2859
2860         cat >>$outfile <<_______EOF
2861
2862 #define GLIB_SIZEOF_VOID_P $glib_void_p
2863 #define GLIB_SIZEOF_LONG   $glib_long
2864 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2865 #define GLIB_SIZEOF_SSIZE_T $glib_ssize_t
2866
2867 _______EOF
2868
2869         cat >>$outfile <<_______EOF
2870 typedef signed $glib_ssize_type_define gssize;
2871 typedef unsigned $glib_size_type_define gsize;
2872 #define G_GSIZE_MODIFIER $gsize_modifier
2873 #define G_GSSIZE_MODIFIER $gssize_modifier
2874 #define G_GSIZE_FORMAT $gsize_format
2875 #define G_GSSIZE_FORMAT $gssize_format
2876
2877 #define G_MAXSIZE       G_MAXU$glib_msize_type
2878 #define G_MINSSIZE      G_MIN$glib_mssize_type
2879 #define G_MAXSSIZE      G_MAX$glib_mssize_type
2880
2881 typedef gint64 goffset;
2882 #define G_MINOFFSET     G_MININT64
2883 #define G_MAXOFFSET     G_MAXINT64
2884
2885 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2886 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2887 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2888
2889 _______EOF
2890
2891         if test -z "$glib_unknown_void_p"; then
2892           cat >>$outfile <<_______EOF
2893
2894 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2895 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2896
2897 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2898 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2899
2900 typedef signed $glib_intptr_type_define gintptr;
2901 typedef unsigned $glib_intptr_type_define guintptr;
2902
2903 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2904 #define G_GINTPTR_FORMAT        $gintptr_format
2905 #define G_GUINTPTR_FORMAT       $guintptr_format
2906 _______EOF
2907         else
2908           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2909         fi
2910
2911
2912
2913         cat >>$outfile <<_______EOF
2914 #ifndef G_DISABLE_DEPRECATED
2915 #define g_ATEXIT(proc)  (atexit (proc))
2916 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END
2917 #endif
2918 $glib_defines
2919 $glib_os
2920 $glib_static_compilation
2921
2922 $glib_vacopy
2923
2924 #ifdef  __cplusplus
2925 #define G_HAVE_INLINE   1
2926 #else   /* !__cplusplus */
2927 $glib_inline
2928 #endif  /* !__cplusplus */
2929
2930 #ifdef  __cplusplus
2931 #define G_CAN_INLINE    1
2932 _______EOF
2933
2934         if test x$g_can_inline = xyes ; then
2935                 cat >>$outfile <<_______EOF
2936 #else   /* !__cplusplus */
2937 #define G_CAN_INLINE    1
2938 _______EOF
2939         fi
2940
2941         cat >>$outfile <<_______EOF
2942 #endif
2943
2944 _______EOF
2945
2946         if test x$g_have_iso_c_varargs = xyes ; then
2947                 cat >>$outfile <<_______EOF
2948 #ifndef __cplusplus
2949 # define G_HAVE_ISO_VARARGS 1
2950 #endif
2951 _______EOF
2952         fi
2953         if test x$g_have_iso_cxx_varargs = xyes ; then
2954                 cat >>$outfile <<_______EOF
2955 #ifdef __cplusplus
2956 # define G_HAVE_ISO_VARARGS 1
2957 #endif
2958 _______EOF
2959         fi
2960         if test x$g_have_gnuc_varargs = xyes ; then
2961                 cat >>$outfile <<_______EOF
2962
2963 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2964  * is passed ISO vararg support is turned off, and there is no work
2965  * around to turn it on, so we unconditionally turn it off.
2966  */
2967 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2968 #  undef G_HAVE_ISO_VARARGS
2969 #endif
2970
2971 #define G_HAVE_GNUC_VARARGS 1
2972 _______EOF
2973         fi
2974
2975         case x$g_stack_grows in
2976         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2977         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2978         esac
2979
2980
2981         echo >>$outfile
2982         if test x$g_have_eilseq = xno; then
2983                 cat >>$outfile <<_______EOF
2984 #ifndef EILSEQ
2985 /* On some pre-C99 systems, EILSEQ is not defined.
2986  * The correspondence between this and the corresponding definition
2987  * in libiconv is essential.
2988  */
2989 #  define EILSEQ ENOENT
2990 #endif
2991 _______EOF
2992
2993         fi
2994
2995         if test x$g_have_gnuc_visibility = xyes; then
2996                 cat >>$outfile <<_______EOF
2997 #define G_HAVE_GNUC_VISIBILITY 1
2998 _______EOF
2999         fi
3000                 cat >>$outfile <<_______EOF
3001 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3002 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3003 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3004 #define G_GNUC_INTERNAL __hidden
3005 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3006 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3007 #else
3008 #define G_GNUC_INTERNAL
3009 #endif
3010 _______EOF
3011
3012         echo >>$outfile
3013         cat >>$outfile <<_______EOF
3014 #define G_THREADS_ENABLED
3015 #define G_THREADS_IMPL_$g_threads_impl_def
3016 _______EOF
3017
3018         if test x"$g_memory_barrier_needed" != xno; then
3019           echo >>$outfile
3020           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3021         fi
3022         if test x"$g_atomic_lock_free" = xyes; then
3023           echo >>$outfile
3024           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3025         fi
3026         echo >>$outfile
3027         g_bit_sizes="16 32 64"
3028         for bits in $g_bit_sizes; do
3029           cat >>$outfile <<_______EOF
3030 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3031 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3032 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3033 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3034 _______EOF
3035         done
3036
3037         cat >>$outfile <<_______EOF
3038 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3039 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3040 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3041 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3042 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3043 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3044 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3045 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3046 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3047 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gssizebits}_TO_LE (val))
3048 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3049 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gssizebits}_TO_BE (val))
3050 #define G_BYTE_ORDER $g_byte_order
3051
3052 #define GLIB_SYSDEF_POLLIN =$g_pollin
3053 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3054 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3055 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3056 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3057 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3058
3059 #define G_MODULE_SUFFIX "$g_module_suffix"
3060
3061 typedef $g_pid_type GPid;
3062
3063 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3064 #define GLIB_SYSDEF_AF_INET $g_af_inet
3065 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3066
3067 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3068 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3069 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3070
3071 G_END_DECLS
3072
3073 #endif /* __GLIBCONFIG_H__ */
3074 _______EOF
3075
3076
3077         if cmp -s $outfile glib/glibconfig.h; then
3078           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3079           rm -f $outfile
3080         else
3081           mv $outfile glib/glibconfig.h
3082         fi
3083 ],[
3084
3085 # Note that if two cases are the same, case goes with the first one.
3086 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3087 # on variable expansion in case labels.  Look at the generated config.status
3088 # for a hint.
3089
3090 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3091   glib_header_alloca_h="$ac_cv_working_alloca_h"
3092 else
3093   glib_header_alloca_h="$ac_cv_header_alloca_h"
3094 fi
3095
3096 if test x$enable_included_printf = xyes ; then
3097   glib_included_printf=yes
3098 fi
3099
3100 case 2 in
3101 $ac_cv_sizeof_short)
3102   gint16=short
3103   gint16_modifier='"h"'
3104   gint16_format='"hi"'
3105   guint16_format='"hu"'
3106   ;;
3107 $ac_cv_sizeof_int)
3108   gint16=int
3109   gint16_modifier='""'
3110   gint16_format='"i"'
3111   guint16_format='"u"'
3112   ;;
3113 esac
3114 case 4 in
3115 $ac_cv_sizeof_short)
3116   gint32=short
3117   gint32_modifier='"h"'
3118   gint32_format='"hi"'
3119   guint32_format='"hu"'
3120   ;;
3121 $ac_cv_sizeof_int)
3122   gint32=int
3123   gint32_modifier='""'
3124   gint32_format='"i"'
3125   guint32_format='"u"'
3126   ;;
3127 $ac_cv_sizeof_long)
3128   gint32=long
3129   gint32_modifier='"l"'
3130   gint32_format='"li"'
3131   guint32_format='"lu"'
3132   ;;
3133 esac
3134 case 8 in
3135 $ac_cv_sizeof_int)
3136   gint64=int
3137   gint64_modifier='""'
3138   gint64_format='"i"'
3139   guint64_format='"u"'
3140   glib_extension=
3141   gint64_constant='(val)'
3142   guint64_constant='(val)'
3143   ;;
3144 $ac_cv_sizeof_long)
3145   gint64=long
3146   gint64_modifier='"l"'
3147   gint64_format='"li"'
3148   guint64_format='"lu"'
3149   glib_extension=
3150   gint64_constant='(val##L)'
3151   guint64_constant='(val##UL)'
3152   ;;
3153 $ac_cv_sizeof_long_long)
3154   gint64='long long'
3155   if test -n "$glib_cv_long_long_format"; then
3156     gint64_modifier='"'$glib_cv_long_long_format'"'
3157     gint64_format='"'$glib_cv_long_long_format'i"'
3158     guint64_format='"'$glib_cv_long_long_format'u"'
3159   fi
3160   glib_extension='G_GNUC_EXTENSION '
3161   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3162   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3163   ;;
3164 $ac_cv_sizeof___int64)
3165   gint64='__int64'
3166   if test -n "$glib_cv_long_long_format"; then
3167     gint64_modifier='"'$glib_cv_long_long_format'"'
3168     gint64_format='"'$glib_cv_long_long_format'i"'
3169     guint64_format='"'$glib_cv_long_long_format'u"'
3170   fi
3171   glib_extension=
3172   gint64_constant='(val##i64)'
3173   guint64_constant='(val##ui64)'
3174   ;;
3175 esac
3176 glib_size_t=$ac_cv_sizeof_size_t
3177 glib_ssize_t=$ac_cv_sizeof_ssize_t
3178 glib_size_type_define="$glib_size_type"
3179 glib_ssize_type_define="$glib_ssize_type"
3180 glib_void_p=$ac_cv_sizeof_void_p
3181 glib_long=$ac_cv_sizeof_long
3182
3183 case "$glib_size_type" in
3184 short)
3185   gsize_modifier='"h"'
3186   gsize_format='"hu"'
3187   glib_msize_type='SHRT'
3188   ;;
3189 int)
3190   gsize_modifier='""'
3191   gsize_format='"u"'
3192   glib_msize_type='INT'
3193   ;;
3194 long)
3195   gsize_modifier='"l"'
3196   gsize_format='"lu"'
3197   glib_msize_type='LONG'
3198   ;;
3199 "long long"|__int64)
3200   gsize_modifier='"I64"'
3201   gsize_format='"I64u"'
3202   glib_msize_type='INT64'
3203   ;;
3204 esac
3205
3206 case "$glib_ssize_type" in
3207 short)
3208   gssize_modifier='"h"'
3209   gssize_format='"hi"'
3210   glib_mssize_type='SHRT'
3211   ;;
3212 int)
3213   gssize_modifier='""'
3214   gssize_format='"i"'
3215   glib_mssize_type='INT'
3216   ;;
3217 long)
3218   gssize_modifier='"l"'
3219   gssize_format='"li"'
3220   glib_mssize_type='LONG'
3221   ;;
3222 "long long"|__int64)
3223   gssize_modifier='"I64"'
3224   gssize_format='"I64i"'
3225   glib_mssize_type='INT64'
3226   ;;
3227 esac
3228
3229 gintbits=`expr $ac_cv_sizeof_int \* 8`
3230 glongbits=`expr $ac_cv_sizeof_long \* 8`
3231 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3232 gssizebits=`expr $ac_cv_sizeof_ssize_t \* 8`
3233
3234 case $ac_cv_sizeof_void_p in
3235 $ac_cv_sizeof_int)
3236   glib_intptr_type_define=int
3237   gintptr_modifier='""'
3238   gintptr_format='"i"'
3239   guintptr_format='"u"'
3240   glib_gpi_cast='(gint)'
3241   glib_gpui_cast='(guint)'
3242   ;;
3243 $ac_cv_sizeof_long)
3244   glib_intptr_type_define=long
3245   gintptr_modifier='"l"'
3246   gintptr_format='"li"'
3247   guintptr_format='"lu"'
3248   glib_gpi_cast='(glong)'
3249   glib_gpui_cast='(gulong)'
3250   ;;
3251 $ac_cv_sizeof_long_long)
3252   glib_intptr_type_define='long long'
3253   gintptr_modifier='"I64"'
3254   gintptr_format='"I64i"'
3255   guintptr_format='"I64u"'
3256   glib_gpi_cast='(gint64)'
3257   glib_gpui_cast='(guint64)'
3258   ;;
3259 $ac_cv_sizeof___int64)
3260   glib_intptr_type_define=__int64
3261   gintptr_modifier='"I64"'
3262   gintptr_format='"I64i"'
3263   guintptr_format='"I64u"'
3264   glib_gpi_cast='(gint64)'
3265   glib_gpui_cast='(guint64)'
3266   ;;
3267 *)
3268   glib_unknown_void_p=yes
3269   ;;
3270 esac
3271
3272
3273 glib_defines="
3274 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3275 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3276 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3277 "
3278
3279 case xyes in
3280 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3281 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3282 *)                      glib_vacopy=''
3283 esac
3284
3285 if test x$glib_cv_va_val_copy = xno; then
3286   glib_vacopy="\$glib_vacopy
3287 #define G_VA_COPY_AS_ARRAY 1"
3288 fi
3289
3290 if test x$glib_cv_hasinline = xyes; then
3291     glib_inline='#define G_HAVE_INLINE 1'
3292 fi
3293 if test x$glib_cv_has__inline = xyes; then
3294     glib_inline="\$glib_inline
3295 #define G_HAVE___INLINE 1"
3296 fi
3297 if test x$glib_cv_has__inline__ = xyes; then
3298     glib_inline="\$glib_inline
3299 #define G_HAVE___INLINE__ 1"
3300 fi
3301
3302 g_have_gnuc_varargs=$g_have_gnuc_varargs
3303 g_have_iso_c_varargs=$g_have_iso_c_varargs
3304 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3305
3306 g_can_inline=$g_can_inline
3307 g_have_gnuc_visibility=$g_have_gnuc_visibility
3308 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3309
3310 if test x$ac_cv_c_bigendian = xyes; then
3311   g_byte_order=G_BIG_ENDIAN
3312   g_bs_native=BE
3313   g_bs_alien=LE
3314 else
3315   g_byte_order=G_LITTLE_ENDIAN
3316   g_bs_native=LE
3317   g_bs_alien=BE
3318 fi
3319
3320 g_pollin=$glib_cv_value_POLLIN
3321 g_pollout=$glib_cv_value_POLLOUT
3322 g_pollpri=$glib_cv_value_POLLPRI
3323 g_pollhup=$glib_cv_value_POLLHUP
3324 g_pollerr=$glib_cv_value_POLLERR
3325 g_pollnval=$glib_cv_value_POLLNVAL
3326
3327 # If a family is not found on the system, define that family to
3328 # a negative value, picking a different one for each undefined
3329 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3330 # This is needed because glib-mkenums doesn't handle optional
3331 # values in enums, and thus we have to have all existing values
3332 # defined in the enum.
3333 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3334   g_af_unix=$glib_cv_value_AF_UNIX
3335 else
3336   g_af_unix=-1
3337 fi
3338 g_af_inet=$glib_cv_value_AF_INET
3339 g_af_inet6=$glib_cv_value_AF_INET6
3340
3341 g_msg_peek=$glib_cv_value_MSG_PEEK
3342 g_msg_oob=$glib_cv_value_MSG_OOB
3343 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3344
3345 g_stack_grows=$glib_cv_stack_grows
3346
3347 g_have_eilseq=$have_eilseq
3348
3349 g_threads_impl_def=$g_threads_impl
3350
3351 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3352 g_memory_barrier_needed="$glib_memory_barrier_needed"
3353 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3354
3355 g_module_suffix="$glib_gmodule_suffix"
3356
3357 g_pid_type="$glib_pid_type"
3358 case $host in
3359   *-*-cygwin*)
3360     glib_os="#define G_OS_UNIX
3361 #define G_PLATFORM_WIN32
3362 #define G_WITH_CYGWIN"
3363     ;;
3364   *-*-mingw*)
3365     glib_os="#define G_OS_WIN32
3366 #define G_PLATFORM_WIN32"
3367     ;;
3368   *)
3369     glib_os="#define G_OS_UNIX"
3370     ;;
3371 esac
3372 glib_static_compilation=""
3373 if test x$glib_win32_static_compilation = xyes; then
3374   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3375 #define GOBJECT_STATIC_COMPILATION 1"
3376 fi
3377 ])
3378
3379 # Redo enough to get guint32 and guint64 for the alignment checks below
3380 case 4 in
3381 $ac_cv_sizeof_short)
3382   gint32=short
3383   ;;
3384 $ac_cv_sizeof_int)
3385   gint32=int
3386   ;;
3387 $ac_cv_sizeof_long)
3388   gint32=long
3389   ;;
3390 esac
3391 case 8 in
3392 $ac_cv_sizeof_int)
3393   gint64=int
3394   ;;
3395 $ac_cv_sizeof_long)
3396   gint64=long
3397   ;;
3398 $ac_cv_sizeof_long_long)
3399   gint64='long long'
3400   ;;
3401 $ac_cv_sizeof___int64)
3402   gint64='__int64'
3403   ;;
3404 esac
3405
3406 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3407 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3408 typedef unsigned $gint32 guint32;])
3409 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3410 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3411 typedef unsigned $gint64 guint64;])
3412 AC_CHECK_TYPE([unsigned long])
3413 AC_CHECK_ALIGNOF([unsigned long])
3414
3415 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3416 #
3417 # 1.2.14 required for dbus_message_set_serial
3418 PKG_CHECK_MODULES(DBUS1,
3419      dbus-1 >= 1.2.14,
3420      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3421      have_dbus1=no)
3422 AC_SUBST(DBUS1_CFLAGS)
3423 AC_SUBST(DBUS1_LIBS)
3424 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3425
3426 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3427 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3428
3429 dnl
3430 dnl Check for -Bsymbolic-functions linker flag used to avoid
3431 dnl intra-library PLT jumps, if available.
3432 dnl
3433
3434 AC_ARG_ENABLE(Bsymbolic,
3435               [AS_HELP_STRING([--disable-Bsymbolic],
3436                               [avoid linking with -Bsymbolic])],,
3437               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3438                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3439                LDFLAGS=-Wl,-Bsymbolic-functions
3440                LIBS=
3441                AC_TRY_LINK([], [return 0],
3442                            AC_MSG_RESULT(yes)
3443                            enable_Bsymbolic=yes,
3444                            AC_MSG_RESULT(no)
3445                            enable_Bsymbolic=no)
3446                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3447
3448 if test "x${enable_Bsymbolic}" = "xyes"; then
3449   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3450 fi
3451
3452 AC_SUBST(GLIB_LINK_FLAGS)
3453
3454 dnl
3455 dnl Check for -z,nodelete linker flag: the type system assumes that
3456 dnl libgobject stays loaded for the lifetime of the process.
3457 dnl Since ld.bfd does not treat wrong -z options as fatal by default,
3458 dnl we also try to check for the --fatal-warnings linker flag if
3459 dnl auto-detecting.
3460 dnl
3461
3462 AC_ARG_ENABLE([znodelete],
3463               [AS_HELP_STRING([--disable-znodelete],
3464                               [avoid linking with -z,nodelete])],,
3465               [SAVED_LDFLAGS="${LDFLAGS}" SAVED_LIBS="${LIBS}"
3466                AC_MSG_CHECKING([for --fatal-warnings linker flag])
3467                LDFLAGS=-Wl,--fatal-warnings
3468                LIBS=
3469                AC_TRY_LINK([], [return 0],
3470                            AC_MSG_RESULT(yes)
3471                            [ldflags_fatal=-Wl,--fatal-warnings],
3472                            AC_MSG_RESULT(no)
3473                            ldflags_fatal=)
3474                AC_MSG_CHECKING([for -z,nodelete linker flag])
3475                LDFLAGS="$ldflags_fatal -Wl,-z,nodelete"
3476                AC_TRY_LINK([], [return 0],
3477                            AC_MSG_RESULT(yes)
3478                            enable_znodelete=yes,
3479                            AC_MSG_RESULT(no)
3480                            enable_znodelete=no)
3481                LDFLAGS="${SAVED_LDFLAGS}" LIBS="${SAVED_LIBS}"])
3482
3483 if test "x${enable_znodelete}" = "xyes"; then
3484   GOBJECT_LINK_FLAGS=-Wl,-z,nodelete
3485 fi
3486
3487 AC_SUBST(GOBJECT_LINK_FLAGS)
3488
3489 dnl
3490 dnl Check for -fvisibility=hidden to determine if we can do GNU-style
3491 dnl visibility attributes for symbol export control
3492 dnl
3493 GLIB_HIDDEN_VISIBILITY_CFLAGS=""
3494 case "$host" in
3495   *-*-mingw*)
3496     dnl on mingw32 we do -fvisibility=hidden and __declspec(dllexport)
3497     AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) __declspec(dllexport) extern],
3498               [defines how to decorate public symbols while building])
3499     CFLAGS="${CFLAGS} -fvisibility=hidden"
3500     ;;
3501   *)
3502     dnl on other compilers, check if we can do -fvisibility=hidden
3503     SAVED_CFLAGS="${CFLAGS}"
3504     CFLAGS="-fvisibility=hidden"
3505     AC_MSG_CHECKING([for -fvisibility=hidden compiler flag])
3506     AC_TRY_COMPILE([], [return 0],
3507                    AC_MSG_RESULT(yes)
3508                    enable_fvisibility_hidden=yes,
3509                    AC_MSG_RESULT(no)
3510                    enable_fvisibility_hidden=no)
3511     CFLAGS="${SAVED_CFLAGS}"
3512
3513     AS_IF([test "${enable_fvisibility_hidden}" = "yes"], [
3514       AC_DEFINE([_GLIB_EXTERN], [__attribute__((visibility("default"))) extern],
3515                 [defines how to decorate public symbols while building])
3516       GLIB_HIDDEN_VISIBILITY_CFLAGS="-fvisibility=hidden"
3517     ])
3518     ;;
3519 esac
3520 AC_SUBST(GLIB_HIDDEN_VISIBILITY_CFLAGS)
3521
3522 dnl Compiler flags; macro originates from systemd
3523 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3524 AC_ARG_ENABLE(compile-warnings,
3525               [AS_HELP_STRING([--disable-compile-warnings],
3526                               [Don't use builtin compiler warnings])],,
3527                               enable_compile_warnings=yes)
3528 AS_IF([test "x$enable_compile_warnings" = xyes], [
3529   CC_CHECK_FLAGS_APPEND([GLIB_WARN_CFLAGS], [CFLAGS], [\
3530    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3531    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3532    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3533    -Werror=format=2 -Werror=missing-include-dirs])
3534 ])
3535 AC_SUBST(GLIB_WARN_CFLAGS)
3536
3537 #
3538 # Define variables corresponding to the correct include paths to use for
3539 # in-tree building.
3540 #
3541
3542 # for config.h:
3543 config_h_INCLUDES='-I$(top_builddir)'
3544 AC_SUBST(config_h_INCLUDES)
3545
3546 # glib:
3547 #   config.h
3548 #   $(top_builddir)/glib: for glibconfig.h
3549 #   $(top_srcdir)/glib:   for glib.h
3550 #   $(top_srcdir):        for everything
3551 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3552 AC_SUBST(glib_INCLUDES)
3553
3554 # gobject:
3555 #   same as glib
3556 gobject_INCLUDES='$(glib_INCLUDES)'
3557 AC_SUBST(gobject_INCLUDES)
3558
3559 # gmodule:
3560 #   glib includes
3561 #   $(top_srcdir)/gmodule: for gmodule.h
3562 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3563 AC_SUBST(gmodule_INCLUDES)
3564
3565 # gio:
3566 #   same as gmodule
3567 gio_INCLUDES='$(gmodule_INCLUDES)'
3568 AC_SUBST(gio_INCLUDES)
3569
3570
3571 AC_CONFIG_FILES([
3572 glib-2.0.pc
3573 gmodule-2.0.pc
3574 gmodule-export-2.0.pc
3575 gmodule-no-export-2.0.pc
3576 gthread-2.0.pc
3577 gobject-2.0.pc
3578 gio-2.0.pc
3579 gio-unix-2.0.pc
3580 gio-windows-2.0.pc
3581 glib-zip
3582 glib-gettextize
3583 Makefile
3584 build/Makefile
3585 build/win32/Makefile
3586 build/win32/dirent/Makefile
3587 build/win32/vs9/Makefile
3588 build/win32/vs10/Makefile
3589 build/win32/vs11/Makefile
3590 build/win32/vs12/Makefile
3591 glib/Makefile
3592 glib/glib.stp
3593 glib/libcharset/Makefile
3594 glib/gnulib/Makefile
3595 glib/pcre/Makefile
3596 glib/update-pcre/Makefile
3597 glib/tests/Makefile
3598 gmodule/Makefile
3599 gmodule/gmoduleconf.h
3600 gobject/Makefile
3601 gobject/gobject.stp
3602 gobject/glib-mkenums
3603 gobject/tests/Makefile
3604 gthread/Makefile
3605 gio/Makefile
3606 gio/gdbus-2.0/codegen/Makefile
3607 gio/gdbus-2.0/codegen/config.py
3608 gio/gnetworking.h
3609 gio/xdgmime/Makefile
3610 gio/inotify/Makefile
3611 gio/kqueue/Makefile
3612 gio/fam/Makefile
3613 gio/win32/Makefile
3614 gio/tests/Makefile
3615 gio/tests/gdbus-object-manager-example/Makefile
3616 gio/tests/services/Makefile
3617 gio/tests/services/org.gtk.GDBus.Examples.ObjectManager.service
3618 gio/tests/modules/Makefile
3619 po/Makefile.in
3620 docs/Makefile
3621 docs/reference/Makefile
3622 docs/reference/glib/Makefile
3623 docs/reference/glib/version.xml
3624 docs/reference/gobject/Makefile
3625 docs/reference/gobject/version.xml
3626 docs/reference/gio/Makefile
3627 docs/reference/gio/gdbus-object-manager-example/Makefile
3628 docs/reference/gio/version.xml
3629 tests/Makefile
3630 tests/gobject/Makefile
3631 tests/refcount/Makefile
3632 m4macros/Makefile
3633 ])
3634
3635 AC_CONFIG_COMMANDS([chmod-scripts],
3636 [chmod 0755 glib-zip
3637 chmod 0755 glib-gettextize
3638 chmod 0755 gobject/glib-mkenums])
3639
3640 # we want to invoke this macro solely so that the config.status script
3641 # and automake generated makefiles know about these generated files.
3642 # They are only needed to distcheck the package
3643 if false; then
3644   AC_CONFIG_FILES([
3645     INSTALL
3646     README
3647     config.h.win32
3648     glib/glibconfig.h.win32
3649     glib/makefile.msc
3650     glib/glib.rc
3651     gmodule/makefile.msc
3652     gmodule/gmodule.rc
3653     gobject/makefile.msc
3654     gobject/gobject.rc
3655     gthread/makefile.msc
3656     gthread/gthread.rc
3657     gio/gio.rc
3658     tests/makefile.msc
3659   ])
3660 fi
3661
3662 AC_OUTPUT