configure.ac

   1 ## Copyright (c) 2009  Openismus GmbH  <http://www.openismus.com/>
   2 ##
   3 ## This file is part of libsigc++.
   4 ##
   5 ## libsigc++ is free software: you can redistribute it and/or modify it
   6 ## under the terms of the GNU Lesser General Public License as published
   7 ## by the Free Software Foundation, either version 2.1 of the License,
   8 ## or (at your option) any later version.
   9 ##
  10 ## libsigc++ is distributed in the hope that it will be useful, but
  11 ## WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  13 ## See the GNU Lesser General Public License for more details.
  14 ##
  15 ## You should have received a copy of the GNU Lesser General Public License
  16 ## along with this library.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_INIT([libsigc++], [2.99.2],
  19         [http://bugzilla.gnome.org/enter_bug.cgi?product=libsigc%2B%2B],
  20         [libsigc++], [http://libsigc.sourceforge.net/])
  21 AC_PREREQ([2.59])
  22
  23 AC_CONFIG_SRCDIR([sigc++/sigc++.h])
  24 AC_CONFIG_AUX_DIR([build])
  25 AC_CONFIG_MACRO_DIR([build])
  26 AC_CONFIG_HEADERS([config.h sigc++config.h])
  27
  28 AM_INIT_AUTOMAKE([1.9 -Wno-portability check-news dist-bzip2 no-define nostdinc tar-ustar])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
  30 AM_MAINTAINER_MODE
  31 AC_ARG_VAR([ACLOCAL_FLAGS], [aclocal flags, e.g. -I <macro dir>])
  32
  33 MM_PREREQ([0.9.8])
  34 MM_INIT_MODULE([sigc++-3.0])
  35 MM_CONFIG_DOCTOOL_DIR([docs])
  36
  37 AC_PROG_CXX
  38 MM_AX_CXX_COMPILE_STDCXX([14],[noext],[mandatory])
  39
  40 AC_DISABLE_STATIC
  41 LT_INIT([win32-dll])
  42
  43 AC_ARG_VAR([M4], [M4 macro processor command])
  44 AC_CHECK_PROGS([M4], [gm4 m4])
  45
  46 AS_IF([test "x$M4" = x],
  47       [AC_MSG_FAILURE([[The GNU M4 macro processor is required for building libsigc++.]])])
  48
  49 MM_ARG_ENABLE_DOCUMENTATION
  50 MM_ARG_WITH_TAGFILE_DOC([libstdc++.tag], [mm-common-libstdc++])
  51
  52 AC_LANG([C++])
  53
  54 AS_IF([test "x$config_error" = xyes],
  55       [AC_MSG_FAILURE([[One or more of the required C++ compiler features is missing.]])])
  56
  57 # Evaluate the --enable-warnings=level option.
  58 MM_ARG_ENABLE_WARNINGS([SIGC_WXXFLAGS],
  59                        [-Wall],
  60                        [-pedantic -Wall -Wextra -Wsuggest-override -Wshadow -Wzero-as-null-pointer-constant -Wformat-security])
  61
  62 # Offer the ability to omit some API from the library.
  63 MM_ARG_DISABLE_DEPRECATED_API([SIGCXX])
  64
  65 AC_CONFIG_FILES([Makefile
  66                  ${SIGCXX_MODULE_NAME}.pc:sigc++.pc.in
  67                  ${SIGCXX_MODULE_NAME}-uninstalled.pc:sigc++-uninstalled.pc.in
  68                  cmake/Makefile
  69                  sigc++/Makefile
  70                  examples/Makefile
  71                  tests/Makefile
  72                  docs/Makefile
  73                  docs/reference/Doxyfile
  74                  MSVC_Net2013/sigc.rc])
  75
  76 # Copy the generated configuration headers into the MSVC project directories.
  77 AC_CONFIG_COMMANDS([MSVC_Net2013/sigc++config.h],
  78                    [cp -f sigc++config.h MSVC_Net2013/sigc++config.h])
  79 AC_OUTPUT