configure.ac

   1 # get rid of that stupid cache mechanism
   2 rm -f config.cache
   3
   4 AC_INIT([ecore], [0.9.9.063], [enlightenment-devel@lists.sourceforge.net])
   5 release="ver-pre-svn-05"
   6 AC_PREREQ([2.52])
   7 AC_CONFIG_SRCDIR([configure.ac])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AC_CANONICAL_BUILD
  10 AC_CANONICAL_HOST
  11 AC_ISC_POSIX
  12
  13 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  14 AM_CONFIG_HEADER([config.h])
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_GNU_SOURCE
  18
  19 AC_LIBTOOL_WIN32_DLL
  20 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  21 AC_PROG_LIBTOOL
  22
  23 VMAJ=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $1);}'`
  24 VMIN=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $2);}'`
  25 VMIC=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $3);}'`
  26 SNAP=`echo $PACKAGE_VERSION | awk -F. '{printf("%s", $4);}'`
  27 version_info=`expr $VMAJ + $VMIN`":$VMIC:$VMIN"
  28 AC_SUBST(version_info)
  29
  30 AM_GNU_GETTEXT_VERSION([0.12.1])
  31 AM_GNU_GETTEXT([external])
  32
  33 EFL_CHECK_PATH_MAX
  34
  35 case "$host_os" in
  36    mingw32ce* | cegcc*)
  37       ;;
  38    *)
  39       ecore_config_release_info="-release $release"
  40       ecore_con_release_info="-release $release"
  41       ecore_directfb_release_info="-release $release"
  42       ecore_evas_release_info="-release $release"
  43       ecore_fb_release_info="-release $release"
  44       ecore_file_release_info="-release $release"
  45       ecore_imf_evas_release_info="-release $release"
  46       ecore_imf_release_info="-release $release"
  47       ecore_input_release_info="-release $release"
  48       ecore_input_evas_release_info="-release $release"
  49       ecore_ipc_release_info="-release $release"
  50       ecore_job_release_info="-release $release"
  51       ecore_quartz_release_info="-release $release"
  52       ecore_release_info="-release $release"
  53       ecore_sdl_release_info="-release $release"
  54       ecore_txt_release_info="-release $release"
  55       ecore_win32_release_info="-release $release"
  56       ecore_x_release_info="-release $release"
  57       ;;
  58 esac
  59 AC_SUBST(ecore_config_release_info)
  60 AC_SUBST(ecore_con_release_info)
  61 AC_SUBST(ecore_directfb_release_info)
  62 AC_SUBST(ecore_evas_release_info)
  63 AC_SUBST(ecore_fb_release_info)
  64 AC_SUBST(ecore_file_release_info)
  65 AC_SUBST(ecore_imf_evas_release_info)
  66 AC_SUBST(ecore_imf_release_info)
  67 AC_SUBST(ecore_input_release_info)
  68 AC_SUBST(ecore_input_evas_release_info)
  69 AC_SUBST(ecore_ipc_release_info)
  70 AC_SUBST(ecore_job_release_info)
  71 AC_SUBST(ecore_quartz_release_info)
  72 AC_SUBST(ecore_release_info)
  73 AC_SUBST(ecore_sdl_release_info)
  74 AC_SUBST(ecore_txt_release_info)
  75 AC_SUBST(ecore_win32_release_info)
  76 AC_SUBST(ecore_wince_release_info)
  77 AC_SUBST(ecore_x_release_info)
  78
  79 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "$shrext_cmds", [Suffix for shared objects])
  80
  81
  82 ### Default options with respect to host
  83
  84 # dependencies and options
  85 want_curl="no"
  86 want_abstract_sockets="no"
  87 want_gnutls="no"
  88 want_openssl="no"
  89 want_cares="no"
  90 want_cipher="no"
  91 want_signature="no"
  92 want_poll="yes"
  93 want_inotify="no"
  94 want_notify_win32="no"
  95 want_tslib="no"
  96 want_glib="no"
  97
  98 # core modules
  99 want_ecore_job="yes"
 100 want_ecore_txt="yes"
 101 want_ecore_con="no"
 102 want_ecore_ipc="no"
 103 want_ecore_file="yes"
 104 want_ecore_config="no"
 105 want_ecore_imf="no"
 106 want_ecore_input="yes"
 107
 108 # graphic system modules
 109 want_evas_simple_x11="no"
 110 want_ecore_x_xcb="no"
 111 want_ecore_x="no"
 112 want_ecore_win32="no"
 113 want_ecore_quartz="no"
 114 want_ecore_sdl="no"
 115 want_ecore_fb="no"
 116 want_ecore_directfb="no"
 117 want_ecore_wince="no"
 118
 119 # ecore_evas modules
 120 want_ecore_evas="yes"
 121 want_ecore_evas_software_buffer="yes"
 122 want_ecore_evas_software_x11="no"
 123 want_ecore_evas_xrender_x11="no"
 124 want_ecore_evas_opengl_x11="no"
 125 want_ecore_evas_software_16_x11="no"
 126 want_ecore_evas_software_xcb="no"
 127 want_ecore_evas_xrender_xcb="no"
 128 want_ecore_evas_software_gdi="no"
 129 want_ecore_evas_software_ddraw="no"
 130 want_ecore_evas_direct3d="no"
 131 want_ecore_evas_opengl_glew="no"
 132 want_ecore_evas_software_16_ddraw="no"
 133 want_ecore_evas_quartz="no"
 134 want_ecore_evas_software_sdl="no"
 135 want_ecore_evas_directfb="no"
 136 want_ecore_evas_fb="no"
 137 want_ecore_evas_software_16_wince="no"
 138
 139 case "$host_os" in
 140    mingw32ce* | cegcc*)
 141       want_ecore_wince="yes"
 142       want_ecore_evas_software_16_wince="yes"
 143       ;;
 144    mingw*)
 145       want_notify_win32="yes"
 146       want_curl="yes"
 147       want_glib="auto"
 148       want_ecore_imf="yes"
 149       want_ecore_win32="yes"
 150       want_ecore_evas_software_gdi="yes"
 151       want_ecore_evas_software_ddraw="yes"
 152       want_ecore_evas_direct3d="yes"
 153       want_ecore_evas_opengl_glew="yes"
 154       want_ecore_evas_software_16_ddraw="auto"
 155       want_ecore_evas_software_sdl="yes"
 156       ;;
 157    darwin*)
 158       want_curl="yes"
 159       want_glib="auto"
 160       want_gnutls="auto"
 161       want_openssl="auto"
 162       want_ecore_con="yes"
 163       want_ecore_ipc="yes"
 164       want_ecore_config="yes"
 165       want_ecore_imf="yes"
 166       want_ecore_quartz="yes"
 167       want_ecore_evas_quartz="yes"
 168       want_ecore_evas_software_sdl="yes"
 169       ;;
 170    *)
 171       want_curl="yes"
 172       want_glib="auto"
 173       want_abstract_sockets="yes"
 174       want_gnutls="auto"
 175       want_openssl="auto"
 176       want_cipher="yes"
 177       want_signature="yes"
 178       want_inotify="yes"
 179       want_tslib="yes"
 180       want_ecore_con="yes"
 181       want_ecore_ipc="yes"
 182       want_ecore_config="yes"
 183       want_ecore_imf="yes"
 184       want_ecore_x="yes"
 185       want_ecore_evas_software_x11="yes"
 186       want_ecore_evas_xrender_x11="yes"
 187       want_ecore_evas_opengl_x11="yes"
 188       want_ecore_evas_software_16_x11="yes"
 189       want_ecore_evas_software_xcb="yes"
 190       want_ecore_evas_xrender_xcb="yes"
 191       want_ecore_evas_software_sdl="yes"
 192       want_ecore_evas_directfb="yes"
 193       want_ecore_evas_fb="yes"
 194       ;;
 195 esac
 196
 197 requirements_ecore=""
 198 requirements_ecore_con=""
 199 requirements_ecore_config=""
 200 requirements_ecore_directfb=""
 201 requirements_ecore_evas=""
 202 requirements_ecore_fb=""
 203 requirements_ecore_file=""
 204 requirements_ecore_imf=""
 205 requirements_ecore_imf_evas=""
 206 requirements_ecore_input=""
 207 requirements_ecore_input_evas=""
 208 requirements_ecore_ipc=""
 209 requirements_ecore_job=""
 210 requirements_ecore_quartz=""
 211 requirements_ecore_sdl=""
 212 requirements_ecore_txt=""
 213 requirements_ecore_x=""
 214 requirements_ecore_win32=""
 215 requirements_ecore_wince=""
 216
 217 ### Additional options to configure
 218
 219 # abstract sockets (ecore_con.c)
 220 AC_ARG_ENABLE([abstract-sockets],
 221    [AC_HELP_STRING([--disable-abstract-sockets], [disable abstract sockets.])],
 222    [
 223     if test "x${enableval}" = "xyes" ; then
 224        want_abstract_sockets="yes"
 225     else
 226        want_abstract_sockets="no"
 227     fi
 228    ],
 229    [want_abstract_sockets="yes"])
 230
 231 if test "x${want_abstract_sockets}" = "xyes" ; then
 232    AC_DEFINE([HAVE_ABSTRACT_SOCKETS], [1], [Have abstract sockets namespace])
 233 fi
 234
 235 # Simple X11 build/link
 236
 237 AC_ARG_ENABLE(simple-x11,
 238   AC_HELP_STRING([--enable-simple-x11], [enable simple x11 linking]),
 239   [want_evas_simple_x11=$enableval])
 240
 241 # XIM
 242 AC_ARG_ENABLE([xim],
 243    [AC_HELP_STRING([--enable-xim], [enable X Input Method.])],
 244    [
 245     if test "x${enableval}" = "xyes" ; then
 246        want_xim="yes"
 247     else
 248        want_xim="no"
 249     fi
 250    ],
 251    [want_xim="no"])
 252
 253 if test "x${want_xim}" = "xyes" ; then
 254    AC_DEFINE([ENABLE_XIM], [1], [Enable X Input Method])
 255 fi
 256
 257
 258 ### Checks for programs
 259
 260 m4_ifdef([AC_PROG_OBJC],
 261    [
 262     AC_PROG_OBJC
 263     _AM_DEPENDENCIES(OBJC)
 264    ],
 265    [
 266     AC_CHECK_TOOL([OBJC], [gcc])
 267     AC_SUBST([OBJC])
 268     AC_SUBST([OBJCFLAGS])
 269    ])
 270 AC_PROG_CXX
 271 AC_PROG_CC
 272
 273 have_gnu_objc=${ac_cv_objc_compiler_gnu}
 274
 275 # doxygen program for documentation building
 276
 277 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 278
 279 # The first call to PKG_CHECK_MODULES is done conditionally,
 280 # so we should include this here:
 281 PKG_PROG_PKG_CONFIG
 282
 283 # Check whether pkg-config supports Requires.private
 284 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 285    pkgconfig_requires_private="Requires.private"
 286 else
 287    pkgconfig_requires_private="Requires"
 288 fi
 289 AC_SUBST(pkgconfig_requires_private)
 290
 291
 292 ### Checks for libraries
 293
 294 # Evil library for compilation on Windows
 295
 296 case "$host_os" in
 297    mingw* | cegcc*)
 298       PKG_CHECK_MODULES([EVIL], [evil])
 299       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if Evil library is installed])
 300       requirements_ecore="evil ${requirements_ecore}"
 301       requirements_ecore_evas="evil ${requirements_ecore_evas}"
 302       requirements_ecore_file="evil ${requirements_ecore_file}"
 303       requirements_ecore_imf="evil ${requirements_ecore_imf}"
 304       requirements_ecore_imf_evas="evil ${requirements_ecore_imf_evas}"
 305       requirements_ecore_job="evil ${requirements_ecore_job}"
 306       requirements_ecore_txt="evil ${requirements_ecore_txt}"
 307       EFL_ECORE_BUILD="-DEFL_ECORE_BUILD"
 308       EFL_ECORE_JOB_BUILD="-DEFL_ECORE_JOB_BUILD"
 309       EFL_ECORE_TXT_BUILD="-DEFL_ECORE_TXT_BUILD"
 310       EFL_ECORE_FILE_BUILD="-DEFL_ECORE_FILE_BUILD"
 311       EFL_ECORE_EVAS_BUILD="-DEFL_ECORE_EVAS_BUILD"
 312       EFL_ECORE_IMF_BUILD="-DEFL_ECORE_IMF_BUILD"
 313       EFL_ECORE_INPUT_BUILD="-DEFL_ECORE_INPUT_BUILD"
 314       ;;
 315 esac
 316
 317 have_win32=""
 318 have_wince=""
 319 case "$host_os" in
 320    mingw32ce* | cegcc*)
 321       EFL_ECORE_WINCE_BUILD="-DEFL_ECORE_WINCE_BUILD"
 322       requirements_ecore_wince="evil ${requirements_ecore_wince}"
 323       have_wince="yes"
 324       ;;
 325    mingw*)
 326       EFL_ECORE_WIN32_BUILD="-DEFL_ECORE_WIN32_BUILD"
 327       EFL_ECORE_SDL_BUILD="-DEFL_ECORE_SDL_BUILD"
 328       requirements_ecore_win32="evil ${requirements_ecore_win32}"
 329       requirements_ecore_sdl="evil ${requirements_ecore_sdl}"
 330       have_win32="yes"
 331       ;;
 332 esac
 333
 334 AC_SUBST(EFL_ECORE_BUILD)
 335 AC_SUBST(EFL_ECORE_JOB_BUILD)
 336 AC_SUBST(EFL_ECORE_TXT_BUILD)
 337 AC_SUBST(EFL_ECORE_FILE_BUILD)
 338 AC_SUBST(EFL_ECORE_EVAS_BUILD)
 339 AC_SUBST(EFL_ECORE_IMF_BUILD)
 340 AC_SUBST(EFL_ECORE_INPUT_BUILD)
 341 AC_SUBST(EFL_ECORE_WINCE_BUILD)
 342 AC_SUBST(EFL_ECORE_WIN32_BUILD)
 343 AC_SUBST(EFL_ECORE_SDL_BUILD)
 344
 345 AM_CONDITIONAL(ECORE_HAVE_WINCE, test "x${have_wince}" = "xyes")
 346 AM_CONDITIONAL(ECORE_HAVE_WIN32, test "x${have_win32}" = "xyes")
 347
 348 WIN32_LIBS=""
 349 case "$host_os" in
 350    mingw32ce* | cegcc*)
 351       WIN32_LIBS="-lws2"
 352       dlopen_libs="-ldl"
 353       ;;
 354    mingw*)
 355       WIN32_LIBS="-lws2_32"
 356       dlopen_libs="-ldl"
 357       ;;
 358    *)
 359       AC_CHECK_LIB(dl, dlopen, dlopen_libs=-ldl)
 360       ;;
 361 esac
 362 AC_SUBST(WIN32_LIBS)
 363 AC_SUBST(dlopen_libs)
 364
 365 # Eina library
 366
 367 PKG_CHECK_MODULES(EINA, [eina-0])
 368 #FIXME check all the requirements when the eina move will be finished
 369 requirements_ecore="eina-0 ${requirements_ecore}"
 370 requirements_ecore_con="ecore eina-0 ${requirements_ecore_con}"
 371 requirements_ecore_config="ecore eina-0 ${requirements_ecore_config}"
 372 requirements_ecore_directfb="ecore eina-0 ${requirements_ecore_directfb}"
 373 requirements_ecore_evas="ecore eina-0 ${requirements_ecore_evas}"
 374 requirements_ecore_fb="ecore eina-0 ${requirements_ecore_fb}"
 375 requirements_ecore_file="ecore eina-0 ${requirements_ecore_file}"
 376 requirements_ecore_imf="ecore eina-0 ${requirements_ecore_imf}"
 377 requirements_ecore_imf_evas="ecore eina-0 ${requirements_ecore_imf_evas}"
 378 requirements_ecore_input="ecore eina-0 ${requirements_ecore_input}"
 379 requirements_ecore_input_evas="ecore eina-0 ${requirements_ecore_input_evas}"
 380 requirements_ecore_ipc="ecore eina-0 ${requirements_ecore_ipc}"
 381 requirements_ecore_job="ecore eina-0 ${requirements_ecore_job}"
 382 requirements_ecore_quartz="ecore eina-0 ${requirements_ecore_quartz}"
 383 requirements_ecore_sdl="ecore eina-0 ${requirements_ecore_sdl}"
 384 requirements_ecore_win32="ecore eina-0 ${requirements_ecore_win32}"
 385 requirements_ecore_wince="ecore eina-0 ${requirements_ecore_wince}"
 386 requirements_ecore_x="ecore eina-0 ${requirements_ecore_x}"
 387
 388
 389 # glib support (main loop integration)
 390 AC_ARG_ENABLE([glib],
 391    [AC_HELP_STRING([--disable-glib], [enable glib support. @<:@default=detect@:>@])],
 392    [want_glib=$enableval], [])
 393
 394 if test "x$want_glib" != "xno"; then
 395    PKG_CHECK_MODULES([GLIB], [glib-2.0], [have_glib="yes"], [have_glib="no"])
 396 else
 397    have_glib="no"
 398 fi
 399 if test "x$want_glib" = "xyes" -a "x$have_glib" = "xno"; then
 400    AC_MSG_ERROR([GLib support requested, but no GLib found by pkg-config.])
 401 elif test "x$have_glib" = "xyes"; then
 402    AC_DEFINE(HAVE_GLIB, [1], [Have GLib])
 403    requirements_ecore="glib-2.0 ${requirements_ecore}"
 404 fi
 405
 406
 407 # iconv library (ecore_txt)
 408
 409 iconv_cflags=""
 410 iconv_libs=""
 411 have_iconv="no"
 412 AC_ARG_WITH([iconv-link],
 413    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 414    [
 415     iconv_libs=$withval
 416     have_iconv="yes"
 417    ])
 418
 419 AC_MSG_CHECKING(for explicit iconv link options)
 420 if test "x${iconv_libs}" = "x" ; then
 421    AC_MSG_RESULT([no explicit iconv link option])
 422 else
 423    AC_MSG_RESULT([$iconv_libs])
 424 fi
 425
 426 AM_ICONV
 427
 428 if test "x${have_iconv}" = "xno" && test "x${am_cv_func_iconv}" = "xyes" ; then
 429    iconv_cflags=${LIBICONV}
 430    iconv_libs=${LTLIBICONV}
 431    have_iconv="yes"
 432 fi
 433
 434 AC_SUBST(iconv_cflags)
 435 AC_SUBST(iconv_libs)
 436
 437
 438 # SDL library (ecore_sdl)
 439
 440 have_sdl="no"
 441 SDL_CONFIG="sdl-config"
 442 AC_ARG_WITH([sdl-config],
 443    [AC_HELP_STRING([--with-sdl-config=PATH], [use sdl-config specified])],
 444    [
 445     SDL_CONFIG=$withval
 446     AC_MSG_NOTICE([using ${SDL_CONFIG} for sdl-config])
 447    ])
 448
 449 AC_PATH_PROG([SDL_CONFIG], ["sdl-config"], [""], [$PATH])
 450
 451 if test -z "$SDL_CONFIG" ; then
 452    SDL_CFLAGS=`$SDL_CONFIG --cflags`
 453    SDL_LIBS=`$SDL_CONFIG --libs`
 454    AC_SUBST(SDL_CFLAGS)
 455    AC_SUBST(SDL_LIBS)
 456    have_sdl="no"
 457 else
 458    PKG_CHECK_MODULES([SDL], [sdl >= 1.2.0], [have_sdl="yes"], [have_sdl="no"])
 459 fi
 460
 461 if test "x${have_sdl}" = "xyes" ; then
 462    PKG_CHECK_EXISTS([sdl >= 1.3.0],
 463       [AC_DEFINE(BUILD_ECORE_EVAS_SDL_130, 1, [Support for SVN SDL])])
 464 fi
 465
 466
 467 # DirectFB library (ecore_directfb)
 468
 469 PKG_CHECK_MODULES([DIRECTFB],
 470    [directfb >= 0.9.16],
 471    [have_directfb="yes"],
 472    [have_directfb="no"])
 473
 474
 475 # Eet library (ecore_config)
 476
 477 PKG_CHECK_MODULES([EET],
 478    [eet >= 1.0.0],
 479    [have_eet="yes"],
 480    [have_eet="no"])
 481
 482
 483 # Xlib and XCB (ecore_x)
 484
 485 have_x="no"
 486 have_ecore_x="no"
 487 have_ecore_x_xlib="no"
 488 have_ecore_x_xcb="no"
 489
 490 x_dir="";
 491 x_includes="";
 492 x_cflags="";
 493 x_libs="";
 494
 495 ecore_x_libs_private=""
 496
 497 AC_ARG_ENABLE(ecore-x-xcb,
 498    [AC_HELP_STRING([--enable-ecore-x-xcb],
 499        [enable the ecore_x module with XCB backend. [[default=disabled]]])],
 500    [want_ecore_x_xcb=$enableval],
 501    [want_ecore_x_xcb="no"])
 502
 503 AC_MSG_CHECKING(whether ecore_x with XCB backend is to be built)
 504 AC_MSG_RESULT($want_ecore_x_xcb)
 505
 506 if test "x$want_ecore_x_xcb" = "xyes" ; then
 507   PKG_CHECK_MODULES(XCB, xcb xcb-icccm xcb-image xcb-keysyms pixman-1,
 508     [ have_ecore_x_xcb="yes"
 509       requirements_ecore_x="xcb xcb-icccm xcb-image xcb-keysyms pixman-1 ${requirements_ecore_x}" ],
 510     [ have_ecore_x_xcb="no" ])
 511
 512   if test "x$have_ecore_x_xcb" = "xyes" ; then
 513     PKG_CHECK_MODULES(XCB_COMPOSITE, xcb-composite,
 514       [ have_ecore_x_xcb_composite="yes"
 515         requirements_ecore_x="xcb-composite ${requirements_ecore_x}"
 516         AC_DEFINE(ECORE_XCB_COMPOSITE, 1, [Build support for XCB composite]) ],
 517       [ have_ecore_x_xcb_composite="no" ])
 518
 519     PKG_CHECK_MODULES(XCB_DAMAGE, xcb-damage,
 520       [ have_ecore_x_xcb_damage="yes"
 521         requirements_ecore_x="xcb-damage ${requirements_ecore_x}"
 522         AC_DEFINE(ECORE_XCB_DAMAGE, 1, [Build support for XCB damage]) ],
 523       [ have_ecore_x_xcb_damage="no" ])
 524
 525     PKG_CHECK_MODULES(XCB_DPMS, xcb-dpms,
 526       [ have_ecore_x_xcb_dpms="yes"
 527         requirements_ecore_x="xcb-dpms ${requirements_ecore_x}"
 528         AC_DEFINE(ECORE_XCB_DPMS, 1, [Build support for XCB dpms]) ],
 529       [ have_ecore_x_xcb_dpms="no" ])
 530
 531     PKG_CHECK_MODULES(XCB_RANDR, xcb-randr,
 532       [ have_ecore_x_xcb_randr="yes"
 533         requirements_ecore_x="xcb-randr ${requirements_ecore_x}"
 534         AC_DEFINE(ECORE_XCB_RANDR, 1, [Build support for XCB randr]) ],
 535       [ have_ecore_x_xcb_randr="no" ])
 536
 537     PKG_CHECK_MODULES(XCB_RENDER, xcb-render,
 538       [ have_ecore_x_xcb_render="yes"
 539         requirements_ecore_x="xcb-render ${requirements_ecore_x}"
 540         AC_DEFINE(ECORE_XCB_RENDER, 1, [Build support for XCB render]) ],
 541       [ have_ecore_x_xcb_render="no" ])
 542
 543     PKG_CHECK_MODULES(XCB_SCREENSAVER, xcb-screensaver,
 544       [ have_ecore_x_xcb_screensaver="yes"
 545         requirements_ecore_x="xcb-screensaver ${requirements_ecore_x}"
 546         AC_DEFINE(ECORE_XCB_SCREENSAVER, 1, [Build support for XCB screensaver]) ],
 547       [ have_ecore_x_xcb_screensaver="no" ])
 548
 549     PKG_CHECK_MODULES(XCB_SHAPE, xcb-shape,
 550       [ have_ecore_x_xcb_shape="yes"
 551         requirements_ecore_x="xcb-shape ${requirements_ecore_x}"
 552         AC_DEFINE(ECORE_XCB_SHAPE, 1, [Build support for XCB shape]) ],
 553       [ have_ecore_x_xcb_shape="no" ])
 554
 555     PKG_CHECK_MODULES(XCB_SYNC, xcb-sync,
 556       [ have_ecore_x_xcb_sync="yes"
 557         requirements_ecore_x="xcb-sync ${requirements_ecore_x}"
 558         AC_DEFINE(ECORE_XCB_SYNC, 1, [Build support for XCB sync]) ],
 559       [ have_ecore_x_xcb_sync="no" ])
 560
 561     PKG_CHECK_MODULES(XCB_XFIXES, xcb-xfixes,
 562       [ have_ecore_x_xcb_xfixes="yes"
 563         requirements_ecore_x="xcb-xfixes ${requirements_ecore_x}"
 564         AC_DEFINE(ECORE_XCB_FIXES, 1, [Build support for XCB xfixes]) ],
 565       [ have_ecore_x_xcb_xfixes="no" ])
 566
 567     PKG_CHECK_MODULES(XCB_XINERAMA, xcb-xinerama,
 568       [ have_ecore_x_xcb_xinerama="yes"
 569         requirements_ecore_x="xcb-xinerama ${requirements_ecore_x}"
 570         AC_DEFINE(ECORE_XCB_XINERAMA, 1, [Build support for XCB xinerama]) ],
 571       [ have_ecore_x_xcb_xinerama="no" ])
 572
 573     PKG_CHECK_MODULES(XCB_XPRINT, xcb-xprint,
 574       [ have_ecore_x_xcb_xprint="yes"
 575         requirements_ecore_x="xcb-xprint ${requirements_ecore_x}"
 576         AC_DEFINE(ECORE_XCB_XPRINT, 1, [Build support for XCB xprint]) ],
 577       [ have_ecore_x_xcb_xprint="no" ])
 578
 579     PKG_CHECK_MODULES(XCB_XTEST, xcb-xtest,
 580       [ have_ecore_x_xcb_xtest="yes"
 581         requirements_ecore_x="xcb-xtest ${requirements_ecore_x}"
 582         AC_DEFINE(ECORE_XCB_XTEST, 1, [Build support for XCB xtest]) ],
 583       [ have_ecore_x_xcb_xtest="no" ])
 584
 585     AC_DEFINE(HAVE_ECORE_X_XCB, 1, [Defined to 1 if XCB is enabled.])
 586
 587     x_cflags=$XCB_CFLAGS
 588     x_libs=$XCB_LIBS
 589     have_x="yes"
 590
 591     have_ecore_x_xcb_define="-DHAVE_ECORE_X_XCB"
 592     AC_SUBST(have_ecore_x_xcb_define)
 593   fi
 594 fi
 595
 596 if ! test "x$have_ecore_x_xcb" = "xyes" ; then
 597   AC_PATH_XTRA
 598   AC_CHECK_HEADER(X11/X.h,
 599     [
 600      if test "x$want_evas_simple_x11" = "xyes"; then
 601        x_libs="${x_libs} -lX11 -lXext"
 602      else
 603        x_dir=${x_dir:-/usr/X11R6}
 604        x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 605        x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 606      fi
 607      have_ecore_x_xlib="yes"
 608     ]
 609   )
 610
 611   if test "x$have_ecore_x_xlib" = "xyes"; then
 612     Xcursor_libs=""
 613     Xcursor_cflags=""
 614     use_Xcursor="no"
 615     PCFLAGS=$CFLAGS
 616     CFLAGS="$x_cflags $x_includes"
 617     AC_CHECK_HEADER(X11/Xcursor/Xcursor.h,
 618       [
 619         AC_CHECK_LIB(Xcursor, XcursorImageLoadCursor,
 620           [
 621             AC_DEFINE(ECORE_XCURSOR, 1, [Build support for Xcursor])
 622             Xcursor_cflags=""
 623             Xcursor_libs="-lXcursor"
 624             use_Xcursor="yes"
 625           ], [
 626             Xcursor_cflags=""
 627             Xcursor_libs=""
 628             use_Xcursor="no"
 629           ], [
 630             $x_libs -lXrender
 631           ]
 632         )
 633       ], [
 634         Xcursor_cflags=""
 635         Xcursor_libs=""
 636         use_Xcursor="no"
 637       ], [
 638         #include <X11/Xlib.h>
 639       ]
 640     )
 641     CFLAGS=$PCFLAGS
 642
 643     AC_SUBST(Xcursor_cflags)
 644     AC_SUBST(Xcursor_libs)
 645
 646     ECORE_CHECK_X_EXTENSION([Xkb], [XKB.h], [X11], [XkbSetDetectableAutoRepeat])
 647     ECORE_CHECK_X_EXTENSION([Xcomposite], [Xcomposite.h], [Xcomposite], [XCompositeQueryExtension])
 648     ECORE_CHECK_X_EXTENSION([Xdamage], [Xdamage.h], [Xdamage], [XDamageSubtract])
 649     ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xdpms], [DPMSQueryExtension])
 650     if test "x$use_xdpms" = "xno" ; then
 651       ECORE_CHECK_X_EXTENSION([Xdpms], [dpms.h], [Xext], [DPMSQueryExtension])
 652     fi
 653     ECORE_CHECK_X_EXTENSION([Xfixes], [Xfixes.h], [Xfixes], [XFixesExpandRegion])
 654     ECORE_CHECK_X_EXTENSION([Xinerama], [Xinerama.h], [Xinerama], [XineramaQueryScreens])
 655     ECORE_CHECK_X_EXTENSION([Xprint], [Print.h], [Xp], [XpQueryScreens])
 656     ECORE_CHECK_X_EXTENSION([Xrandr], [Xrandr.h], [Xrandr], [XRRGetScreenResourcesCurrent])
 657     ECORE_CHECK_X_EXTENSION([Xrender], [Xrender.h], [Xrender], [XRenderFindVisualFormat])
 658     ECORE_CHECK_X_EXTENSION([Xtest], [XTest.h], [Xtst], [XTestFakeKeyEvent])
 659     ECORE_CHECK_X_EXTENSION([Xss], [scrnsaver.h], [Xss], [XScreenSaverSelectInput])
 660
 661     ecore_x_libs_private="${Xcursor_libs} ${XKB_LIBS} ${XCOMPOSITE_LIBS} ${XDAMAGE_LIBS} ${XDPMS_LIBS} ${XFIXES_LIBS} ${XINERAMA_LIBS} ${XPRINT_LIBS} ${XRANDR_LIBS} ${XRENDER_LIBS} ${XTEST_LIBS} ${XSS_LIBS} "
 662
 663     AC_DEFINE(HAVE_ECORE_X_XLIB, 1, [Defined to 1 if Xlib is enabled.])
 664     have_x="yes"
 665
 666     have_ecore_x_xlib="yes"
 667   fi
 668 fi
 669
 670 AC_SUBST(x_cflags)
 671 AC_SUBST(x_includes)
 672 AC_SUBST(x_libs)
 673 AC_SUBST(ecore_x_libs_private)
 674
 675 AM_CONDITIONAL(BUILD_ECORE_X_XLIB, test $have_ecore_x_xlib = yes)
 676 AM_CONDITIONAL(BUILD_ECORE_X_XCB, test $have_ecore_x_xcb = yes)
 677
 678
 679 # Evas library (ecore_config, ecore_input_evas, ecore_imf_evas and ecore_evas)
 680
 681 PKG_CHECK_MODULES([EVAS], [evas >= 0.9.9],
 682    [have_evas="yes"],
 683    [have_evas="no"])
 684
 685
 686 ### Checks for header files
 687
 688 AC_HEADER_SYS_WAIT
 689
 690 case "$host_os" in
 691    mingw* | cegcc*)
 692       AC_DEFINE(HAVE_DLFCN_H, 1, [Define to 1 if you have the <dlfcn.h> header file.])
 693       AC_DEFINE(HAVE_SYS_MMAN_H, 1, [Define to 1 if you have the <sys/mman.h> header file.])
 694       AC_DEFINE(HAVE_SYS_TIME_H, 1, [Define to 1 if you have the <sys/time.h> header file.])
 695       ;;
 696    *)
 697       AC_CHECK_HEADERS([dlfcn.h features.h langinfo.h locale.h netdb.h netinet/in.h sys/time.h sys/mman.h signal.h sys/resource.h])
 698       ;;
 699 esac
 700
 701 # Framebuffer (ecore_fb)
 702 have_fb="no"
 703 AC_CHECK_HEADER([linux/fb.h],
 704    [AC_CHECK_HEADER([linux/input.h], [have_fb="yes"])])
 705
 706 # Quartz header files (ecore_quartz)
 707
 708 quartz_ldflags="";
 709 have_quartz="no"
 710
 711 if test "x${have_gnu_objc}" = "xyes" ; then
 712    AC_LANG_PUSH([Objective C])
 713    AC_CHECK_HEADER([Cocoa/Cocoa.h],
 714       [
 715        have_quartz="yes"
 716        quartz_ldflags="-framework Cocoa"
 717       ],
 718       [have_quartz="no"])
 719    AC_LANG_POP([Objective C])
 720 fi
 721
 722 AC_SUBST(quartz_ldflags)
 723
 724 # basic pthread support
 725
 726 EFL_CHECK_PTHREAD([have_pthread="yes"], [have_pthread="no"])
 727
 728 ### Checks for types
 729 AC_CHECK_SIZEOF(int, 4)
 730 AC_CHECK_SIZEOF(long, 4)
 731
 732
 733 ### Checks for structures
 734
 735
 736 ### Checks for compiler characteristics
 737 AM_PROG_CC_STDC
 738 AC_C_CONST
 739 AC_C_BIGENDIAN
 740 AC_HEADER_STDC
 741 AC_C___ATTRIBUTE__
 742
 743 WIN32_CPPFLAGS=""
 744 WIN32_CFLAGS=""
 745 case "$host_os" in
 746    mingw32ce*)
 747       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 748       ;;
 749    cegcc*)
 750       WIN32_CPPFLAGS="-D_WIN32_WCE=0x0420"
 751       WIN32_CFLAGS="-mwin32"
 752       ;;
 753    mingw*)
 754       WIN32_CPPFLAGS="-D_WIN32_WINNT=0x0500"
 755       ;;
 756 esac
 757 AC_SUBST(WIN32_CPPFLAGS)
 758 AC_SUBST(WIN32_CFLAGS)
 759
 760
 761 ### Checks for linker characteristics
 762
 763 # use --enable-auto-import on Windows
 764
 765 lt_enable_auto_import=""
 766 case "$host_os" in
 767    mingw* | cegcc*)
 768       lt_enable_auto_import="-Wl,--enable-auto-import"
 769       ;;
 770 esac
 771 AC_SUBST(lt_enable_auto_import)
 772
 773 ### Checks for library functions
 774 AC_FUNC_ALLOCA
 775 AC_CHECK_FUNCS(gettimeofday strlcpy)
 776
 777 have_atfile_source=auto
 778 AC_ARG_ENABLE(atfile-source,
 779         AC_HELP_STRING([--disable-atfile-source],
 780                        [disable use of atfile source functions as openat and mkdirat @<:@default=detect@:>@]),
 781         [have_atfile_source=$enableval], [have_atfile_source=auto])
 782
 783 if test "x$have_atfile_source" != "xno"; then
 784         AC_CHECK_FUNCS(mkdirat,
 785                 [
 786                 have_atfile_source=yes
 787                 AC_DEFINE(HAVE_ATFILE_SOURCE, 1, [mkdirat exists])
 788                 ],
 789                 [
 790                 if test "x$have_atfile_source" = "xyes"; then
 791                         AC_MSG_ERROR([required atfile-source but no mkdirat()])
 792                 fi
 793                 have_atfile_source=no
 794                 ])
 795 fi
 796
 797 ### Ecore modules
 798
 799 ## Core modules
 800
 801 # ecore_job
 802 ECORE_CHECK_MODULE([Job], [${want_ecore_job}])
 803
 804 # ecore_txt
 805 ECORE_CHECK_MODULE([Txt], [${want_ecore_txt}], [$have_iconv])
 806
 807 # ecore_con
 808 ECORE_CHECK_MODULE([Con], [${want_ecore_con}])
 809
 810 have_curl="no"
 811 have_gnutls="no"
 812 have_openssl="no"
 813 have_cares="no"
 814 if test "x${have_ecore_con}" = "xyes" ; then
 815
 816    ECORE_CHECK_CURL([${want_curl}],
 817       [
 818        have_curl="yes"
 819        requirements_ecore_con="libcurl ${requirements_ecore_con}"
 820       ],
 821       [have_curl="no"])
 822
 823    ECORE_CHECK_GNUTLS([${want_gnutls}],
 824       [have_gnutls="yes"],
 825       [have_gnutls="no"])
 826
 827    ECORE_CHECK_OPENSSL([${want_openssl}],
 828       [have_openssl="yes"],
 829       [have_openssl="no"])
 830
 831    if test "x${have_gnutls}" = "xyes" ; then
 832       requirements_ecore_con="gnutls ${requirements_ecore_con}"
 833       # no need to add it to req_ecore_ipc, since they
 834       # depends on ecore_con anyway.
 835    else
 836       if test "x${have_openssl}" = "xyes" ; then
 837          requirements_ecore_con="openssl ${requirements_ecore_con}"
 838          # no need to add it to req_ecore_ipc, since they
 839          # depends on ecore_con anyway.
 840       fi
 841    fi
 842
 843    ECORE_CHECK_CARES([${want_cares}],
 844       [
 845        have_cares="yes"
 846        requirements_ecore_con="libcares ${requirements_ecore_con}"
 847       ],
 848       [have_cares="no"])
 849
 850 fi
 851
 852 AM_CONDITIONAL([HAVE_CARES], [test "x${have_cares}" = "xyes"])
 853
 854 # ecore_ipc
 855 ECORE_CHECK_MODULE([Ipc], [${want_ecore_ipc}], [${have_ecore_con}],
 856    [requirements_ecore_ipc="ecore-con ${requirements_ecore_ipc}"])
 857
 858 # ecore_file
 859 ECORE_CHECK_MODULE([File], [${want_ecore_file}])
 860
 861 have_poll="no"
 862 have_inotify="no"
 863 have_notify_win32="no"
 864 if test "x${have_ecore_file}" = "xyes" ; then
 865    ECORE_CHECK_POLL([${want_poll}], [have_poll="yes"], [have_poll="no"])
 866    ECORE_CHECK_INOTIFY([${want_inotify}], [have_inotify="yes"], [have_inotify="no"])
 867    ECORE_CHECK_NOTIFY_WIN32([${want_notify_win32}], [have_notify_win32="yes"], [have_notify_win32="no"])
 868
 869    if test "x${have_ecore_con}" = "xyes" ; then
 870       requirements_ecore_file="ecore-con ${requirements_ecore_file}"
 871    fi
 872 fi
 873
 874 # ecore_config
 875 ecore_config_deps="no"
 876 if test "x${have_eet}" = "xyes" -a "x${have_evas}"  -a "x${have_ecore_ipc}" ; then
 877    ecore_config_deps="yes"
 878 fi
 879
 880 ECORE_CHECK_MODULE([Config], [${want_ecore_config}], [${ecore_config_deps}],
 881    [requirements_ecore_config="ecore-ipc evas eet ${requirements_ecore_config}"])
 882
 883 # ecore_imf
 884
 885 ECORE_CHECK_MODULE([IMF], [${want_ecore_imf}])
 886
 887 # ecore_imf_evas
 888
 889 ecore_imf_evas_deps="no"
 890 if test "x${have_ecore_imf}" = "xyes" -a "x${have_evas}" = "xyes" ; then
 891    ecore_imf_evas_deps="yes"
 892 fi
 893
 894 ECORE_CHECK_MODULE([IMF_EVAS], [${want_ecore_imf}], [${ecore_imf_evas_deps}],
 895    [requirements_ecore_imf_evas="ecore-imf evas ${requirements_ecore_imf_evas}"])
 896
 897 # ecore_input{_evas}
 898 ECORE_CHECK_MODULE([Input], [${want_ecore_input}])
 899 ECORE_CHECK_MODULE([Input_Evas], [${want_ecore_input}], [${have_evas}],
 900    [requirements_ecore_input_evas="ecore-input evas ${requirements_ecore_input}"])
 901
 902 ## Graphic systems
 903
 904 # ecore_x{cb}
 905
 906 ecore_x_deps="no"
 907 if test "x${have_x}" = "xyes" -a \
 908         "x${have_ecore_input}" = "xyes" -a \
 909         "x${have_ecore_txt}" = "xyes" ; then
 910    ecore_x_deps="yes"
 911 fi
 912
 913 ECORE_CHECK_MODULE([X], [${want_ecore_x}], [${ecore_x_deps}],
 914   [
 915    ecore_x_libs="$ecore_x_libs $x_libs"
 916    requirements_ecore_x="ecore-input ecore-txt ${requirements_ecore_x}"
 917   ])
 918
 919 # ecore_win32
 920
 921 ECORE_CHECK_MODULE([Win32], [${want_ecore_win32}], [${have_ecore_input}],
 922    [
 923     ecore_win32_libs="-lole32 -lgdi32"
 924     requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"
 925    ])
 926 AC_SUBST(ecore_win32_libs)
 927
 928 # ecore_quartz
 929
 930 ecore_quartz_deps="no"
 931 if test "x${have_ecore_input}" = "xyes" -a "x${have_quartz}" = "xyes" ; then
 932    ecore_quartz_deps="yes"
 933 fi
 934
 935 ECORE_CHECK_MODULE([QUARTZ], [${want_ecore_quartz}], [${ecore_quartz_deps}],
 936    [requirements_ecore_quartz="ecore-input ${requirements_ecore_quartz}"])
 937
 938 # ecore_sdl
 939
 940 ecore_sdl_deps="no"
 941 if test "x${have_sdl}" = "xyes" -a "x${have_ecore_input}" = "xyes" ; then
 942    ecore_sdl_deps="yes"
 943 fi
 944
 945 ECORE_CHECK_MODULE([SDL], [${want_ecore_sdl}], [${ecore_sdl_deps}],
 946    [requirements_ecore_sdl="ecore-input ${requirements_ecore_sdl}"])
 947
 948 # ecore_fb
 949 ECORE_CHECK_MODULE([FB], [${want_ecore_fb}], [$have_fb])
 950
 951 if test "x${have_ecore_fb}" = "xyes" ; then
 952    ECORE_CHECK_TSLIB([${want_tslib}],
 953       [
 954        have_tslib="yes"
 955        requirements_ecore_fb="${_tslib_requirement} ${requirements_ecore_fb}"
 956       ],
 957       [have_tslib="no"])
 958 fi
 959
 960 # ecore_directfb
 961
 962 ECORE_CHECK_MODULE([DirectFB], [${want_ecore_directfb}], [${have_directfb}],
 963    [requirements_ecore_directfb="directfb ${requirements_ecore_directfb}"])
 964
 965 # ecore_wince
 966
 967 ECORE_CHECK_MODULE([WinCE], [${want_ecore_wince}], [${have_ecore_input}],
 968    [requirements_ecore_win32="ecore-input ${requirements_ecore_win32}"])
 969
 970 ## Ecore Evas
 971
 972 # ecore_evas
 973
 974 ecore_evas_deps="no"
 975 if test "x${have_evas}" = "xyes" -a "x${have_ecore_input}" = "xyes" -a "x${have_ecore_input_evas}" = "xyes" ; then
 976    ecore_evas_deps="yes"
 977 fi
 978
 979 ECORE_CHECK_MODULE([Evas], [${want_ecore_evas}], [${ecore_evas_deps}],
 980   [requirements_ecore_evas="ecore-input ecore-input-evas evas ${requirements_ecore_evas}"])
 981
 982 # ecore_evas_buffer
 983
 984 ECORE_EVAS_CHECK_MODULE([software-buffer],
 985    [${want_ecore_evas_software_buffer}],
 986    [Software Buffer],
 987    [yes])
 988
 989 # ecore_evas_x11
 990
 991 # ecore_evas_software_x11
 992
 993 ECORE_EVAS_CHECK_MODULE([software-x11],
 994    [${want_ecore_evas_software_x11}],
 995    [Software X11],
 996    [${have_ecore_x}])
 997
 998 have_ecore_evas_software_xlib=no"
 999 have_ecore_evas_software_xcb=no"
1000 if test "x$have_ecore_evas_software_x11" = "xyes" ; then
1001    have_ecore_evas_software_xlib=`${PKG_CONFIG} --variable=Xlib evas-software-x11`
1002    if test "x${have_ecore_evas_software_xlib}" = "xyes" -a "x${have_ecore_x_xlib}" = "xyes" ; then
1003       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XLIB, 1, [Evas Software Xlib Engine Support])
1004    fi
1005    have_ecore_evas_software_xcb=`${PKG_CONFIG} --variable=XCB evas-software-x11`
1006    if test "x$have_ecore_evas_software_xcb" = "xyes" -a "x${have_ecore_x_xcb}" = "xyes" ; then
1007       AC_DEFINE(BUILD_ECORE_EVAS_SOFTWARE_XCB, 1, [Evas Software XCB Engine Support])
1008    fi
1009 fi
1010
1011 # ecore_evas_xrender_x11
1012
1013 ECORE_EVAS_CHECK_MODULE([xrender-x11],
1014    [${want_ecore_evas_xrender_x11}],
1015    [XRender Xlib],
1016    [${have_ecore_x_xlib}])
1017
1018 # ecore_evas_opengl_x11
1019
1020 ECORE_EVAS_CHECK_MODULE([opengl-x11],
1021    [${want_ecore_evas_opengl_x11}],
1022    [OpenGL Xlib],
1023    [${have_ecore_x_xlib}])
1024
1025 # ecore_evas_software_x11 16 bits
1026
1027 ECORE_EVAS_CHECK_MODULE([software-16-x11],
1028    [${want_ecore_evas_software_16_x11}],
1029    [Software Xlib 16 bits],
1030    [${have_ecore_x_xlib}])
1031
1032 # ecore_evas_xrender_xcb
1033
1034 ECORE_EVAS_CHECK_MODULE([xrender-xcb],
1035    [${want_ecore_evas_xrender_xcb}],
1036    [XRender XCB],
1037    [${ecore_evas_xcb_deps}])
1038
1039 if test "x$have_ecore_evas_software_x11" = "xyes" -o \
1040         "x$have_ecore_evas_xrender_x11" = "xyes" -o \
1041         "x$have_ecore_evas_opengl_x11" = "xyes" -o \
1042         "x$have_ecore_evas_software_16_x11" = "xyes" -o \
1043         "x$have_ecore_evas_software_xcb" = "xyes" -o \
1044         "x$have_ecore_evas_xrender_xcb" = "xyes"; then
1045    AC_DEFINE(BUILD_ECORE_EVAS_X11, 1, [Support for X Window Engines in Ecore_Evas])
1046    requirements_ecore_evas="ecore-x ${requirements_ecore_evas}"
1047 fi
1048
1049 # ecore_evas_win32
1050
1051 ECORE_EVAS_CHECK_MODULE([software-gdi],
1052    [${want_ecore_evas_software_gdi}],
1053    [Software GDI],
1054    [${have_ecore_win32}])
1055
1056 ECORE_EVAS_CHECK_MODULE([software-ddraw],
1057    [${want_ecore_evas_software_ddraw}],
1058    [Software DirectDraw],
1059    [${have_ecore_win32}])
1060
1061 ECORE_EVAS_CHECK_MODULE([direct3d],
1062    [${want_ecore_evas_direct3d}],
1063    [Direct3d],
1064    [${have_ecore_win32}])
1065
1066 ECORE_EVAS_CHECK_MODULE([opengl-glew],
1067    [${want_ecore_evas_opengl_glew}],
1068    [Glew OpenGL],
1069    [${have_ecore_win32}])
1070
1071 ECORE_EVAS_CHECK_MODULE([software-16-ddraw],
1072    [${want_ecore_evas_software_16_ddraw}],
1073    [16 bpp Software DirectDraw],
1074    [${have_ecore_win32}])
1075
1076 if test "x${have_ecore_evas_software_gdi}" = "xyes" -o \
1077         "x${have_ecore_evas_software_ddraw}" = "xyes" -o \
1078         "x${have_ecore_evas_direct3d}" = "xyes" -o \
1079         "x${have_ecore_evas_opengl_glew}" = "xyes" -o \
1080         "x${have_ecore_evas_software_16_ddraw}" = "xyes" ; then
1081    AC_DEFINE(BUILD_ECORE_EVAS_WIN32, 1, [Support for Win32 Engine in Ecore_Evas])
1082    requirements_ecore_evas="ecore-win32 ${requirements_ecore_evas}"
1083 fi
1084
1085 # ecore_evas_quartz
1086
1087 ECORE_EVAS_CHECK_MODULE([quartz],
1088    [${want_ecore_evas_quartz}],
1089    [Quartz],
1090    [${have_ecore_quartz}],
1091    [requirements_ecore_evas="ecore-quartz ${requirements_ecore_evas}"])
1092
1093 # ecore_evas_software_sdl
1094
1095 ECORE_EVAS_CHECK_MODULE([software-sdl],
1096    [${want_ecore_evas_software_sdl}],
1097    [Software SDL],
1098    [${have_ecore_sdl}],
1099    [requirements_ecore_evas="ecore-sdl ${requirements_ecore_evas}"])
1100
1101 # ecore_evas_directfb
1102
1103 ECORE_EVAS_CHECK_MODULE([directfb],
1104    [${want_ecore_evas_directfb}],
1105    [DirectFB],
1106    [${have_ecore_directfb}],
1107    [requirements_ecore_evas="ecore-directfb ${requirements_ecore_evas}"])
1108
1109 # ecore_evas_fb
1110
1111 ECORE_EVAS_CHECK_MODULE([fb],
1112    [${want_ecore_evas_fb}],
1113    [Linux Framebuffer],
1114    [${have_ecore_fb}],
1115    [requirements_ecore_evas="ecore-fb ${requirements_ecore_evas}"])
1116
1117 # ecore_evas_wince
1118
1119 ECORE_EVAS_CHECK_MODULE([software-16-wince],
1120    [${want_ecore_evas_software_16_wince}],
1121    [16 bpp Software Windows CE],
1122    [${have_ecore_wince}],
1123    [requirements_ecore_evas="ecore-wince ${requirements_ecore_evas}"])
1124
1125
1126
1127 ### requirements
1128
1129 AC_SUBST(requirements_ecore)
1130 AC_SUBST(requirements_ecore_con)
1131 AC_SUBST(requirements_ecore_config)
1132 AC_SUBST(requirements_ecore_directfb)
1133 AC_SUBST(requirements_ecore_evas)
1134 AC_SUBST(requirements_ecore_fb)
1135 AC_SUBST(requirements_ecore_file)
1136 AC_SUBST(requirements_ecore_imf)
1137 AC_SUBST(requirements_ecore_imf_evas)
1138 AC_SUBST(requirements_ecore_input)
1139 AC_SUBST(requirements_ecore_input_evas)
1140 AC_SUBST(requirements_ecore_ipc)
1141 AC_SUBST(requirements_ecore_job)
1142 AC_SUBST(requirements_ecore_quartz)
1143 AC_SUBST(requirements_ecore_sdl)
1144 AC_SUBST(requirements_ecore_txt)
1145 AC_SUBST(requirements_ecore_x)
1146 AC_SUBST(requirements_ecore_win32)
1147 AC_SUBST(requirements_ecore_wince)
1148
1149 AC_OUTPUT([
1150 Makefile
1151 ecore-con.pc
1152 ecore-config.pc
1153 ecore-directfb.pc
1154 ecore-evas.pc
1155 ecore-fb.pc
1156 ecore-file.pc
1157 ecore-imf.pc
1158 ecore-imf-evas.pc
1159 ecore-ipc.pc
1160 ecore-job.pc
1161 ecore-txt.pc
1162 ecore-x.pc
1163 ecore-input.pc
1164 ecore-input-evas.pc
1165 ecore-win32.pc
1166 ecore-sdl.pc
1167 ecore-quartz.pc
1168 ecore-wince.pc
1169 ecore.pc
1170 doc/ecore.dox
1171 doc/Makefile
1172 src/Makefile
1173 src/bin/Makefile
1174 src/lib/Makefile
1175 src/lib/ecore/Makefile
1176 src/lib/ecore_job/Makefile
1177 src/lib/ecore_x/Makefile
1178 src/lib/ecore_x/xlib/Makefile
1179 src/lib/ecore_x/xcb/Makefile
1180 src/lib/ecore_fb/Makefile
1181 src/lib/ecore_sdl/Makefile
1182 src/lib/ecore_quartz/Makefile
1183 src/lib/ecore_evas/Makefile
1184 src/lib/ecore_con/Makefile
1185 src/lib/ecore_imf/Makefile
1186 src/lib/ecore_imf_evas/Makefile
1187 src/lib/ecore_input/Makefile
1188 src/lib/ecore_input_evas/Makefile
1189 src/lib/ecore_ipc/Makefile
1190 src/lib/ecore_txt/Makefile
1191 src/lib/ecore_config/Makefile
1192 src/lib/ecore_file/Makefile
1193 src/lib/ecore_directfb/Makefile
1194 src/lib/ecore_win32/Makefile
1195 src/lib/ecore_wince/Makefile
1196 README
1197 ecore.spec
1198 po/Makefile.in
1199 ])
1200
1201 echo
1202 echo "$PACKAGE $VERSION"
1203 echo
1204 echo "Optional Modules:"
1205 echo
1206 echo " Core:"
1207 echo
1208 echo "  Ecore........................: always"
1209 echo "    Thread support.............: $have_pthread"
1210 echo "    GLib support...............: $have_glib"
1211 echo "  Ecore_Job....................: $have_ecore_job"
1212 echo "  Ecore_Txt....................: $have_ecore_txt"
1213 echo "  Ecore_Con....................: $have_ecore_con"
1214 if test "x$have_ecore_con" = "xyes" ; then
1215   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1216 if test "x$have_gnutls" = "xyes" ; then
1217   echo " (disabled)"
1218 else
1219   echo
1220 fi
1221   echo "    GnuTLS.....................: $have_gnutls"
1222   echo "    CURL.......................: $have_curl"
1223   echo "    Abstract Sockets...........: $want_abstract_sockets"
1224   echo "    c-ares.....................: $have_cares"
1225 fi
1226 echo "  Ecore_Ipc....................: $have_ecore_ipc"
1227 if test "x$have_ecore_ipc" = "xyes" ; then
1228   echo $ECHO_N "    OpenSSL....................: $have_openssl $ECHO_C"
1229 if test "x$have_gnutls" = "xyes" ; then
1230   echo " (disabled)"
1231 else
1232   echo
1233 fi
1234   echo "    GnuTLS.....................: $have_gnutls"
1235 fi
1236 echo "  Ecore_File...................: $have_ecore_file"
1237 if test "x$have_ecore_file" = "xyes" ; then
1238   echo "    Inotify....................: $have_inotify"
1239   echo "    Windows notification.......: $have_notify_win32"
1240   echo "    Poll.......................: $have_poll"
1241   echo "    CURL.......................: $have_curl"
1242 fi
1243 echo "  Ecore_Config.................: $have_ecore_config"
1244 echo "  Ecore_IMF....................: $have_ecore_imf"
1245 echo "  Ecore_IMF_Evas...............: $have_ecore_imf_evas"
1246 echo "  Ecore_Input..................: $have_ecore_input"
1247 echo "  Ecore_Input_Evas.............: $have_ecore_input_evas"
1248
1249 echo
1250 echo " Graphic systems:"
1251 echo
1252
1253 if test "x$have_ecore_x" = "xyes" ; then
1254   if test "x$have_ecore_x_xcb" = "xyes" ; then
1255     echo "  Ecore_X (XCB backend)........: $have_ecore_x_xcb"
1256     echo "    Xprint.....................: $have_ecore_x_xcb_xprint"
1257     echo "    Xinerama...................: $have_ecore_x_xcb_xinerama"
1258     echo "    Xrandr.....................: $have_ecore_x_xcb_randr"
1259     echo "    Xscreensaver...............: $have_ecore_x_xcb_screensaver"
1260     echo "    Xshape.....................: $have_ecore_x_xcb_shape"
1261     echo "    Xsync......................: $have_ecore_x_xcb_sync"
1262     echo "    Xrender....................: $have_ecore_x_xcb_render"
1263     echo "    Xcomposite.................: $have_ecore_x_xcb_composite"
1264     echo "    Xfixes.....................: $have_ecore_x_xcb_xfixes"
1265     echo "    Xdamage....................: $have_ecore_x_xcb_damage"
1266     echo "    Xdpms......................: $have_ecore_x_xcb_dpms"
1267     echo "    Xtest......................: $have_ecore_x_xcb_xtest"
1268   else
1269     echo "  Ecore_X (Xlib backend).......: $have_ecore_x"
1270     echo "    Xcursor....................: $use_Xcursor"
1271     echo "    Xkb........................: $use_xkb"
1272     echo "    Xprint.....................: $use_xprint"
1273     echo "    Xinerama...................: $use_xinerama"
1274     echo "    Xrandr.....................: $use_xrandr"
1275     echo "    Xscreensaver...............: $use_xss"
1276     echo "    Xrender....................: $use_xrender"
1277     echo "    Xcomposite.................: $use_xcomposite"
1278     echo "    Xfixes.....................: $use_xfixes"
1279     echo "    Xdamage....................: $use_xdamage"
1280     echo "    Xdpms......................: $use_xdpms"
1281     echo "    Xtest......................: $use_xtest"
1282     echo "    XIM........................: $want_xim"
1283   fi
1284 else
1285   echo "  Ecore_X......................: $have_ecore_x"
1286 fi
1287 echo "  Ecore_Win32..................: $have_ecore_win32"
1288 echo "  Ecore_Quartz.................: $have_ecore_quartz"
1289 echo "  Ecore_SDL....................: $have_ecore_sdl"
1290 echo "  Ecore_FB.....................: $have_ecore_fb"
1291 if test "x${have_ecore_fb}" = "xyes" ; then
1292   echo "    Touchscreen................: $have_tslib"
1293 fi
1294 echo "  Ecore_DirectFB...............: $have_ecore_directfb"
1295 echo "  Ecore_WinCE..................: $have_ecore_wince"
1296
1297 echo
1298 echo " Ecore Evas:"
1299 echo
1300
1301 echo "  Ecore_Evas...................: $have_ecore_evas"
1302 if test "x${have_ecore_evas}" = "xyes" ; then
1303   echo "    Software Memory Buffer.....: $have_ecore_evas_software_buffer"
1304   if test "x${have_ecore_evas_software_x11}" = "xyes" ; then
1305     if test "x${have_ecore_evas_software_xlib}" = "xyes" ; then
1306       echo "    Software X11...............: $have_ecore_evas_software_x11 (Xlib)"
1307     fi
1308     if test "x${have_ecore_evas_software_xcb}" = "xyes" ; then
1309       echo "    Software X11...............: $have_ecore_evas_software_x11 (XCB)"
1310     fi
1311   else
1312     echo "    Software X11...............: $have_ecore_evas_software_x11"
1313   fi
1314   echo "    XRender X11................: $have_ecore_evas_xrender_x11"
1315   echo "    OpenGL X11.................: $have_ecore_evas_opengl_x11"
1316   echo "    XRender XCB................: $have_ecore_evas_xrender_xcb"
1317   echo "    Software GDI...............: $have_ecore_evas_software_gdi"
1318   echo "    Software DirectDraw........: $have_ecore_evas_software_ddraw"
1319   echo "    Direct3D...................: $have_ecore_evas_direct3d"
1320   echo "    OpenGL Glew................: $have_ecore_evas_opengl_glew"
1321   echo "    Quartz.....................: $have_ecore_evas_quartz"
1322   echo "    Software SDL...............: $have_ecore_evas_software_sdl"
1323   echo "    DirectFB...................: $have_ecore_evas_directfb"
1324   echo "    Software Framebuffer.......: $have_ecore_evas_fb"
1325   echo "    Software 16bit X11.........: $have_ecore_evas_software_16_x11"
1326   echo "    Software 16bit DirectDraw..: $have_ecore_evas_software_16_ddraw"
1327   echo "    Software 16bit WinCE.......: $have_ecore_evas_software_16_wince"
1328 fi
1329 echo
1330 echo " Documentation.................: ${build_doc}"
1331 echo
1332 echo " Compilation...................: make (or gmake)"
1333 if test "x${build_doc}" = "xyes" ; then
1334    echo " Build of the documentation....: make doc"
1335 fi
1336 echo
1337 echo " Installation..................: make install"
1338 echo
1339 echo "    prefix.....................: $prefix"
1340 echo
1341
1342 echo
1343 echo "Compilation............: make (or gmake)"
1344 echo "  CPPFLAGS.............: $CPPFLAGS"
1345 echo "  CFLAGS...............: $CFLAGS"
1346 echo "  CXXFLAGS.............: $CXXFLAGS"
1347 echo "  LDFLAGS..............: $LDFLAGS"
1348 echo
1349 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
1350 echo "  prefix...............: $prefix"
1351 echo