configure.ac

   1 AC_PREREQ(2.53)
   2 AC_INIT([rygel],
   3         m4_esyscmd([GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version]),
   4         [http://bugzilla.gnome.org/enter_bug.cgi?product=Rygel])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6
   7 # require automake-1.11 for vala support
   8 AM_INIT_AUTOMAKE([1.11])
   9 AC_CONFIG_SRCDIR([src/rygel/rygel-root-device.vala])
  10 AM_CONFIG_HEADER([config.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AM_MAINTAINER_MODE
  13
  14 # Disable generation of static libraries
  15 AC_DISABLE_STATIC
  16
  17 AC_ISC_POSIX
  18 AC_PROG_CC
  19 AC_STDC_HEADERS
  20 AC_PROG_LIBTOOL
  21 AC_FUNC_MMAP
  22
  23 VALA_REQUIRED=0.9.5
  24 GUPNP_REQUIRED=0.13.4
  25 GUPNP_AV_REQUIRED=0.5.9
  26 GUPNP_DLNA_REQUIRED=0.3.0
  27 GUPNP_VALA_REQUIRED=0.6.11
  28 GSTREAMER_REQUIRED=0.10.23
  29 GSTREAMER_TAG_REQUIRED=0.10.28
  30 GSTREAMER_APP_REQUIRED=0.10.28
  31 GIO_REQUIRED=2.26
  32 GEE_REQUIRED=0.5.2
  33 UUID_REQUIRED=1.41.3
  34 LIBSOUP_REQUIRED=2.26.0
  35 LIBSQLITE3_REQUIRED=3.5
  36
  37 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  38 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  39 PKG_CHECK_MODULES(LIBGUPNP_DLNA, gupnp-dlna-1.0 >= $GUPNP_DLNA_REQUIRED)
  40 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  41 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  42 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  43 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  44 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  45
  46 # glib-genmarshal
  47 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  48 AC_SUBST(GLIB_GENMARSHAL)
  49
  50 AC_ARG_ENABLE(vala,
  51         [  --enable-vala          enable checks for vala],,
  52         enable_vala=no)
  53 AC_ARG_ENABLE(sql-debugging,
  54               [  --enable-sql-debugging         enable SQL statement debugging],,
  55                  enable_sql_debugging=no)
  56
  57 if test x$enable_sql_debugging = xyes ; then
  58     VALAFLAGS="$VALAFLAGS -D RYGEL_DEBUG_SQL"
  59 fi
  60
  61 # Enable check for Vala even if not asked to do so if stamp files are absent.
  62 if test ! -e src/rygel/rygel_vala.stamp -o \
  63         ! -e src/rygel/librygel_configuration_a_vala.stamp -o \
  64         ! -e src/ui/rygel_preferences_vala.stamp -o \
  65         ! -e src/plugins/playbin/librygel_playbin_la_vala.stamp -o \
  66         ! -e src/plugins/tracker/librygel_media_tracker_la_vala.stamp -o \
  67         ! -e src/plugins/test/librygel_test_la_vala.stamp -o \
  68         ! -e src/plugins/media-export/librygel_media_export_la_vala.stamp -o \
  69         ! -e src/plugins/mediathek/librygel_mediathek_la_vala.stamp -o \
  70         ! -e src/plugins/gst-launch/librygel_gst_launch_la_vala.stamp -o \
  71         ! -e src/plugins/mpris/librygel_mpris_la_vala.stamp -o \
  72         ! -e src/plugins/external/librygel_external_la_vala.stamp ; then
  73     enable_vala=yes
  74 fi
  75
  76 # Vala
  77 if test x$enable_vala = xyes ; then
  78     # check for vala
  79     AM_PROG_VALAC([$VALA_REQUIRED])
  80
  81     if test "x$VALAC" = "x"; then
  82         AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
  83     fi
  84
  85     PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
  86
  87     VALA_CHECK_PACKAGES([gupnp-1.0
  88                          gupnp-av-1.0
  89                          gupnp-dlna-1.0
  90                          gstreamer-0.10
  91                          gstreamer-discoverer-gupnp-dlna-0.10
  92                          gio-2.0
  93                          gee-1.0
  94                          posix])
  95 fi
  96
  97 VAPIDIR="${datadir}/vala/vapi"
  98 AC_SUBST(VAPIDIR)
  99
 100 # Maemo support
 101 AC_ARG_ENABLE(maemo,
 102         [  --enable-maemo          enable maemo support],,
 103         enable_maemo=no)
 104
 105 # Debugging
 106 AC_ARG_ENABLE(debug,
 107         [  --enable-debug          enable debugging],,
 108         enable_debug=no)
 109 if test "x$enable_debug" = "xyes"; then
 110         CFLAGS="$CFLAGS -O0 -g"
 111 fi
 112
 113 # Strict compiler
 114 AC_ARG_ENABLE(strict-cc,
 115         [  --enable-strict-cc          enable strict C compiler],,
 116         enable_strict_cc=no)
 117 if test "x$enable_strict_cc" = "xyes"; then
 118         CFLAGS="$CFLAGS -Wall -Werror"
 119 else
 120         CFLAGS="$CFLAGS -w"
 121 fi
 122
 123 # Run uninstalled
 124 AC_ARG_ENABLE(uninstalled,
 125         [  --enable-uninstalled          run uninstalled],,
 126         enable_uninstalled=no)
 127 if test "x$enable_uninstalled" = "xyes"; then
 128         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 129 fi
 130
 131 AC_MSG_CHECKING([which gtk+ version to compile against])
 132 AC_ARG_WITH([gtk],
 133   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
 134   [case "$with_gtk" in
 135      2.0|3.0) ;;
 136      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
 137    esac],
 138   [with_gtk=2.0])
 139 AC_MSG_RESULT([$with_gtk])
 140
 141 case "$with_gtk" in
 142   2.0) GTK_VAPI_VERSION=2.0
 143        GTK_REQUIRED=2.20.0
 144        ;;
 145   3.0) GTK_VAPI_VERSION=3.0
 146        GTK_REQUIRED=2.90.3
 147        ;;
 148 esac
 149
 150 # Check wether user wants to build UIs
 151 AC_ARG_WITH( ui,
 152   AC_HELP_STRING([--without-ui],[Do not build UI applications]),
 153   try_ui=$withval, try_ui=yes )
 154
 155 HAVE_GTK=no
 156 if test x$try_ui = xyes ; then
 157     dnl check for gtk
 158     PKG_CHECK_MODULES(GTK, gtk+-$GTK_VAPI_VERSION >= $GTK_REQUIRED ,
 159       [
 160         AC_SUBST(GTK_CFLAGS)
 161         AC_SUBST(GTK_LIBS)
 162         if test x$enable_vala = xyes ; then
 163                 VALA_CHECK_PACKAGES([gtk+-$GTK_VAPI_VERSION], [HAVE_GTK=yes])
 164         else
 165                 HAVE_GTK=yes
 166         fi
 167       ],
 168       [
 169         HAVE_GTK=no
 170         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 171         AC_MSG_WARN([UI applications will not be built.])
 172       ])
 173 else
 174     AC_MSG_NOTICE([UI applications disabled.])
 175 fi
 176
 177 if test x$HAVE_GTK = xno; then
 178   BUILD_UI=no
 179   with_gtk="n/a"
 180 else
 181   BUILD_UI=yes
 182   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 183 fi
 184
 185 AC_SUBST(HAVE_GTK)
 186 AC_SUBST(GTK_VAPI_VERSION)
 187 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 188
 189 # Build test plugin
 190 AC_ARG_ENABLE(test-plugin,
 191         [  --enable-test-plugin          build test plugin],,
 192         enable_test_plugin=no)
 193
 194 # Build Tracker plugin
 195 AC_ARG_ENABLE(tracker-plugin,
 196         [  --enable-tracker-plugin      build tracker plugin],,
 197         enable_tracker_plugin=yes)
 198
 199 # Build MediaExport plugin
 200 AC_ARG_ENABLE(media-export-plugin,
 201         [  --enable-media-export-plugin          build MediaExport plugin],,
 202         enable_media_export_plugin=yes)
 203
 204 # Build External plugin
 205 AC_ARG_ENABLE(external-plugin,
 206         [  --enable-external-plugin          build External plugin],,
 207         enable_external_plugin=yes)
 208
 209 # Build MPRIS2 plugin
 210 AC_ARG_ENABLE(mpris-plugin,
 211         [  --enable-mpris-plugin             build MPRIS2 plugin],,
 212         enable_mpris_plugin=yes)
 213
 214 # Build GstRenderer plugin
 215 AC_ARG_ENABLE(playbin-plugin,
 216         [  --enable-playbin_plugin          build Gstreamer Playbin plugin],,
 217         enable_playbin_plugin=yes)
 218
 219 # Build Mediathek plugin
 220 AC_ARG_ENABLE(mediathek-plugin,
 221         [  --enable-mediathek-plugin          build Mediathek plugin],,
 222         enable_mediathek_plugin=no)
 223
 224 # Build GstLaunch plugin
 225 AC_ARG_ENABLE(gst-launch-plugin,
 226         [  --enable-gst-launch-plugin          build Gstreamer launchline plugin],,
 227         enable_gst_launch_plugin=no)
 228
 229
 230 AC_SUBST(abs_top_builddir)
 231
 232 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 233 AM_CONDITIONAL([ENABLE_MAEMO], [test "x$enable_maemo" = "xyes"])
 234 AM_CONDITIONAL([BUILD_TEST_PLUGIN], [test "x$enable_test_plugin" = "xyes"])
 235 AM_CONDITIONAL([BUILD_TRACKER_PLUGIN],
 236                [test "x$enable_tracker_plugin" = "xyes"])
 237 AM_CONDITIONAL([BUILD_MEDIATHEK_PLUGIN], [test "x$enable_mediathek_plugin" = "xyes"])
 238 AM_CONDITIONAL([BUILD_MEDIA_EXPORT_PLUGIN], [test "x$enable_media_export_plugin" = "xyes"])
 239 AM_CONDITIONAL([BUILD_EXTERNAL_PLUGIN], [test "x$enable_external_plugin" = "xyes"])
 240 AM_CONDITIONAL([BUILD_MPRIS_PLUGIN], [test "x$enable_mpris_plugin" = "xyes"])
 241 AM_CONDITIONAL([BUILD_PLAYBIN_PLUGIN], [test "x$enable_playbin_plugin" = "xyes"])
 242 AM_CONDITIONAL([BUILD_GST_LAUNCH_PLUGIN], [test "x$enable_gst_launch_plugin" = "xyes"])
 243
 244 if test "x$enable_media_export_plugin" = "xyes";
 245 then
 246     PKG_CHECK_MODULES(LIBSQLITE3, sqlite3 >= $LIBSQLITE3_REQUIRED)
 247     PKG_CHECK_MODULES(GSTREAMER_TAG, gstreamer-tag-0.10 >= $GSTREAMER_TAG_REQUIRED);
 248     PKG_CHECK_MODULES(GSTREAMER_APP, gstreamer-app-0.10 >= $GSTREAMER_APP_REQUIRED);
 249     if test x$enable_vala = xyes ; then
 250         VALA_CHECK_PACKAGES([sqlite3
 251                              gstreamer-tag-0.10
 252                              gstreamer-app-0.10])
 253     fi
 254 fi
 255
 256 # Gettext
 257 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 258 AC_SUBST(GETTEXT_PACKAGE)
 259 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 260   [Define the gettext package to be used])
 261
 262 AM_GLIB_GNU_GETTEXT
 263 IT_PROG_INTLTOOL([0.35.0])
 264
 265 AC_SUBST(VALAFLAGS)
 266
 267 dnl Shave the output
 268 AM_SILENT_RULES([yes])
 269
 270 dnl documenation
 271 AC_PATH_PROG([XSLTPROC], [xsltproc])
 272 AM_CONDITIONAL([HAVE_XSLTPROC], [test x"$XSLTPROC" != x])
 273
 274 AC_SUBST(VERSION)
 275
 276 AC_OUTPUT([
 277 Makefile
 278 src/Makefile
 279 src/rygel/Makefile
 280 src/ui/Makefile
 281 src/plugins/Makefile
 282 src/plugins/media-export/Makefile
 283 src/plugins/external/Makefile
 284 src/plugins/mpris/Makefile
 285 src/plugins/gst-launch/Makefile
 286 src/plugins/mediathek/Makefile
 287 src/plugins/tracker/Makefile
 288 src/plugins/playbin/Makefile
 289 src/plugins/test/Makefile
 290 data/Makefile
 291 data/xml/Makefile
 292 data/icons/Makefile
 293 data/icons/32x32/Makefile
 294 data/icons/48x48/Makefile
 295 data/icons/120x120/Makefile
 296 data/icons/scalable/Makefile
 297 data/rygel.desktop.in
 298 data/rygel-preferences.desktop.in
 299 doc/Makefile
 300 po/Makefile.in
 301 rygel-1.0.pc
 302 tests/Makefile
 303 ])
 304
 305 echo "
 306
 307                     ${PACKAGE} ${VERSION}
 308                     ============
 309
 310
 311         Prefix:                 ${prefix}
 312         Source code location:   ${srcdir}
 313         Compiler:               ${CC}
 314         CFLAGS:                 ${CFLAGS}
 315         uninstalled:            ${enable_uninstalled}
 316         maemo support:          ${enable_maemo}
 317         preferences ui:         ${BUILD_UI}
 318         GTK+ version:           ${with_gtk}
 319         SQL debugging:          ${enable_sql_debugging}
 320     Plugins:
 321         test:                   ${enable_test_plugin}
 322         tracker:                ${enable_tracker_plugin}
 323         mediathek:              ${enable_mediathek_plugin}
 324         media-export            ${enable_media_export_plugin}
 325         external:               ${enable_external_plugin}
 326         MPRIS2:                 ${enable_mpris_plugin}
 327         gst-launch:             ${enable_gst_launch_plugin}
 328         playbin:                ${enable_playbin_plugin}
 329 "